qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SHOCKWAVE,
   4 /* function  */ W_Shockwave,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 2,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_LOW,
   9 /* color     */ '0.5 0.25 0',
  10 /* modelname */ "shotgun",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairshotgun 0.7",
  13 /* wepimg    */ "weaponshotgun",
  14 /* refname   */ "shockwave",
  15 /* wepname   */ _("Shockwave")
  16 );
  17
  18 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) SHOCKWAVE_SETTINGS_LIST(w_cvar, w_prop, SHOCKWAVE, shockwave)
  19 #define SHOCKWAVE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, blast_animtime) \
  21         w_cvar(id, sn, NONE, blast_damage) \
  22         w_cvar(id, sn, NONE, blast_distance) \
  23         w_cvar(id, sn, NONE, blast_edgedamage) \
  24         w_cvar(id, sn, NONE, blast_force) \
  25         w_cvar(id, sn, NONE, blast_force_forwardbias) \
  26         w_cvar(id, sn, NONE, blast_force_zscale) \
  27         w_cvar(id, sn, NONE, blast_jump_damage) \
  28         w_cvar(id, sn, NONE, blast_jump_edgedamage) \
  29         w_cvar(id, sn, NONE, blast_jump_force) \
  30         w_cvar(id, sn, NONE, blast_jump_force_velocitybias) \
  31         w_cvar(id, sn, NONE, blast_jump_force_zscale) \
  32         w_cvar(id, sn, NONE, blast_jump_multiplier_accuracy) \
  33         w_cvar(id, sn, NONE, blast_jump_multiplier_distance) \
  34         w_cvar(id, sn, NONE, blast_jump_multiplier_min) \
  35         w_cvar(id, sn, NONE, blast_jump_radius) \
  36         w_cvar(id, sn, NONE, blast_multiplier_accuracy) \
  37         w_cvar(id, sn, NONE, blast_multiplier_distance) \
  38         w_cvar(id, sn, NONE, blast_multiplier_min) \
  39         w_cvar(id, sn, NONE, blast_refire) \
  40         w_cvar(id, sn, NONE, blast_splash_damage) \
  41         w_cvar(id, sn, NONE, blast_splash_edgedamage) \
  42         w_cvar(id, sn, NONE, blast_splash_force) \
  43         w_cvar(id, sn, NONE, blast_splash_force_forwardbias) \
  44         w_cvar(id, sn, NONE, blast_splash_multiplier_accuracy) \
  45         w_cvar(id, sn, NONE, blast_splash_multiplier_distance) \
  46         w_cvar(id, sn, NONE, blast_splash_multiplier_min) \
  47         w_cvar(id, sn, NONE, blast_splash_radius) \
  48         w_cvar(id, sn, NONE, blast_spread_max) \
  49         w_cvar(id, sn, NONE, blast_spread_min) \
  50         w_cvar(id, sn, NONE, melee_animtime) \
  51         w_cvar(id, sn, NONE, melee_damage) \
  52         w_cvar(id, sn, NONE, melee_delay) \
  53         w_cvar(id, sn, NONE, melee_force) \
  54         w_cvar(id, sn, NONE, melee_multihit) \
  55         w_cvar(id, sn, NONE, melee_no_doubleslap) \
  56         w_cvar(id, sn, NONE, melee_nonplayerdamage) \
  57         w_cvar(id, sn, NONE, melee_range) \
  58         w_cvar(id, sn, NONE, melee_refire) \
  59         w_cvar(id, sn, NONE, melee_swing_side) \
  60         w_cvar(id, sn, NONE, melee_swing_up) \
  61         w_cvar(id, sn, NONE, melee_time) \
  62         w_cvar(id, sn, NONE, melee_traces) \
  63         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  64         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  65         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  66         w_prop(id, sn, float,  weaponstart, weaponstart) \
  67         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  68         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  69
  70 #ifdef SVQC
  71 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  72 #endif
  73 #else
  74 #ifdef SVQC
  75 void spawnfunc_weapon_shockwave(void)
  76 {
  77         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
  78         if(autocvar_sv_q3acompat_machineshotgunswap)
  79         if(self.classname != "droppedweapon")
  80         {
  81                 weapon_defaultspawnfunc(WEP_MACHINEGUN);
  82                 return;
  83         }
  84         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  85 }
  86
  87 #define MAX_SHOCKWAVE_HITS 10
  88 #define DEBUG_SHOCKWAVE
  89
  90 .float swing_prev;
  91 .entity swing_alreadyhit;
  92 .float shockwave_blasttime;
  93 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
  94 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
  95 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
  96
  97 // MELEE ATTACK MODE
  98 void W_Shockwave_Melee_Think(void)
  99 {
 100         // declarations
 101         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 102         entity target_victim;
 103         vector targpos;
 104
 105         // check to see if we can still continue, otherwise give up now
 106         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 107         {
 108                 remove(self);
 109                 return;
 110         }
 111
 112         // set start time of melee
 113         if(!self.cnt)
 114         {
 115                 self.cnt = time;
 116                 W_PlayStrengthSound(self.realowner);
 117         }
 118
 119         // update values for v_* vectors
 120         makevectors(self.realowner.v_angle);
 121
 122         // calculate swing percentage based on time
 123         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 124         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 125         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 126
 127         // perform the traces needed for this frame
 128         for(i=self.swing_prev; i < f; ++i)
 129         {
 130                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 131
 132                 targpos = (self.realowner.origin + self.realowner.view_ofs
 133                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 134                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 135                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 136
 137                 WarpZone_traceline_antilag(
 138                         self.realowner,
 139                         (self.realowner.origin + self.realowner.view_ofs),
 140                         targpos,
 141                         FALSE,
 142                         self.realowner,
 143                         ANTILAG_LATENCY(self.realowner)
 144                 );
 145
 146                 // draw lightning beams for debugging
 147                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 148                 te_customflash(targpos, 40,  2, '1 1 1');
 149
 150                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body" || (trace_ent.flags & FL_MONSTER));
 151
 152                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self if necessary
 153                         && (trace_ent.takedamage == DAMAGE_AIM)
 154                         && (trace_ent != self.swing_alreadyhit)
 155                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 156                 {
 157                         target_victim = trace_ent; // so it persists through other calls
 158
 159                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
 160                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
 161                         else
 162                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
 163
 164                         // trigger damage with this calculated info
 165                         Damage(
 166                                 target_victim,
 167                                 self.realowner,
 168                                 self.realowner,
 169                                 swing_damage,
 170                                 (WEP_SHOCKWAVE | HITTYPE_SECONDARY),
 171                                 (self.realowner.origin + self.realowner.view_ofs),
 172                                 (v_forward * WEP_CVAR(shockwave, melee_force))
 173                         );
 174
 175                         // handle accuracy
 176                         if(accuracy_isgooddamage(self.realowner, target_victim))
 177                                 { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 178
 179                         #ifdef DEBUG_SHOCKWAVE
 180                         print(sprintf(
 181                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.\n",
 182                                 self.realowner.netname,
 183                                 target_victim.netname,
 184                                 swing_damage,
 185                                 swing_factor,
 186                                 time
 187                         ));
 188                         #endif
 189
 190                         // allow multiple hits with one swing, but not against the same player twice
 191                         if(WEP_CVAR(shockwave, melee_multihit))
 192                         {
 193                                 self.swing_alreadyhit = target_victim;
 194                                 continue; // move along to next trace
 195                         }
 196                         else
 197                         {
 198                                 remove(self);
 199                                 return;
 200                         }
 201                 }
 202         }
 203
 204         if(time >= self.cnt + meleetime)
 205         {
 206                 // melee is finished
 207                 remove(self);
 208                 return;
 209         }
 210         else
 211         {
 212                 // set up next frame
 213                 self.swing_prev = i;
 214                 self.nextthink = time;
 215         }
 216 }
 217
 218 void W_Shockwave_Melee(void)
 219 {
 220         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 221         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 222
 223         entity meleetemp;
 224         meleetemp = spawn();
 225         meleetemp.owner = meleetemp.realowner = self;
 226         meleetemp.think = W_Shockwave_Melee_Think;
 227         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 228         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 229 }
 230
 231 // SHOCKWAVE ATTACK MODE
 232 float W_Shockwave_Attack_CheckSpread(
 233         vector targetorg,
 234         vector nearest_on_line,
 235         vector sw_shotorg,
 236         vector attack_endpos)
 237 {
 238         float spreadlimit;
 239         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 240         float distance_from_line = vlen(targetorg - nearest_on_line);
 241
 242         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 243         spreadlimit =
 244                 (
 245                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 246                         +
 247                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 248                 );
 249
 250         if(
 251                 (spreadlimit && (distance_from_line <= spreadlimit))
 252                 &&
 253                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 254         )
 255                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 256         else
 257                 { return FALSE; }
 258 }
 259
 260 float W_Shockwave_Attack_IsVisible(
 261         entity head,
 262         vector nearest_on_line,
 263         vector sw_shotorg,
 264         vector attack_endpos)
 265 {
 266         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 267         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 268         vector corner;
 269         float i;
 270
 271         // STEP ONE: Check if the nearest point is clear
 272         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 273         {
 274                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 275                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 276         }
 277
 278         // STEP TWO: Check if shotorg to center point is clear
 279         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 280         {
 281                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 282                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 283         }
 284
 285         // STEP THREE: Check each corner to see if they are clear
 286         for(i=1; i<=8; ++i)
 287         {
 288                 corner = get_corner_position(head, i);
 289                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 290                 {
 291                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 292                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 293                 }
 294         }
 295
 296         return FALSE;
 297 }
 298
 299 float W_Shockwave_Attack_CheckHit(
 300         float queue,
 301         entity head,
 302         vector final_force,
 303         float final_damage)
 304 {
 305         if(!head) { return FALSE; }
 306         float i;
 307
 308         for(i = 0; i <= queue; ++i)
 309         {
 310                 if(shockwave_hit[i] == head)
 311                 {
 312                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 313                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 314                         return FALSE;
 315                 }
 316         }
 317
 318         shockwave_hit[queue] = head;
 319         shockwave_hit_force[queue] = final_force;
 320         shockwave_hit_damage[queue] = final_damage;
 321         return TRUE;
 322 }
 323
 324 void W_Shockwave_Attack(void)
 325 {
 326         // declarations
 327         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 328         float final_damage;
 329         vector final_force, center, vel;
 330         entity head;
 331
 332         float i, queue = 0;
 333
 334         // set up the shot direction
 335         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 336         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 337         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 338         vector attack_hitpos = trace_endpos;
 339         float distance_to_end = vlen(w_shotorg - attack_endpos);
 340         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 341         //entity transform = WarpZone_trace_transform;
 342
 343         // do the firing effect now
 344         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 345         Damage_DamageInfo(
 346                 attack_hitpos,
 347                 WEP_CVAR(shockwave, blast_splash_damage),
 348                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 349                 WEP_CVAR(shockwave, blast_splash_radius),
 350                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 351                 WEP_SHOCKWAVE,
 352                 0,
 353                 self
 354         );
 355
 356         // splash damage/jumping trace
 357         head = WarpZone_FindRadius(
 358                 attack_hitpos,
 359                 max(
 360                         WEP_CVAR(shockwave, blast_splash_radius),
 361                         WEP_CVAR(shockwave, blast_jump_radius)
 362                 ),
 363                 FALSE
 364         );
 365
 366         while(head)
 367         {
 368                 if(head.takedamage)
 369                 {
 370                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 371
 372                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 373                         {
 374                                 // ========================
 375                                 //  BLAST JUMP CALCULATION
 376                                 // ========================
 377
 378                                 // calculate importance of distance and accuracy for this attack
 379                                 multiplier_from_accuracy = (1 -
 380                                         (distance_to_head ?
 381                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
 382                                                 :
 383                                                 0
 384                                         )
 385                                 );
 386                                 multiplier_from_distance = (1 -
 387                                         (distance_to_hit ?
 388                                                 min(1, (distance_to_hit / distance_to_end))
 389                                                 :
 390                                                 0
 391                                         )
 392                                 );
 393                                 multiplier =
 394                                         max(
 395                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 396                                                 (
 397                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 398                                                         +
 399                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 400                                                 )
 401                                         );
 402
 403                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 404                                 final_damage =
 405                                         (
 406                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 407                                                 +
 408                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 409                                         );
 410
 411                                 // figure out the direction of force
 412                                 vel = normalize(combine_to_vector(head.velocity_x, head.velocity_y, 0));
 413                                 vel *=
 414                                         (
 415                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 416                                                 *
 417                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 418                                         );
 419                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 420
 421                                 // now multiply the direction by force units
 422                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 423                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 424
 425                                 // trigger damage with this calculated info
 426                                 Damage(
 427                                         head,
 428                                         self,
 429                                         self,
 430                                         final_damage,
 431                                         WEP_SHOCKWAVE,
 432                                         head.origin,
 433                                         final_force
 434                                 );
 435
 436                                 #ifdef DEBUG_SHOCKWAVE
 437                                 print(sprintf(
 438                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 439                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 440                                         multiplier,
 441                                         final_damage,
 442                                         vlen(final_force),
 443                                         multiplier_from_accuracy,
 444                                         multiplier_from_distance
 445                                 ));
 446                                 #endif
 447                         }
 448                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 449                         {
 450                                 // ==========================
 451                                 //  BLAST SPLASH CALCULATION
 452                                 // ==========================
 453
 454                                 // calculate importance of distance and accuracy for this attack
 455                                 multiplier_from_accuracy = (1 -
 456                                         (distance_to_head ?
 457                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
 458                                                 :
 459                                                 0
 460                                         )
 461                                 );
 462                                 multiplier_from_distance = (1 -
 463                                         (distance_to_hit ?
 464                                                 min(1, (distance_to_hit / distance_to_end))
 465                                                 :
 466                                                 0
 467                                         )
 468                                 );
 469                                 multiplier =
 470                                         max(
 471                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 472                                                 (
 473                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 474                                                         +
 475                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 476                                                 )
 477                                         );
 478
 479                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 480                                 final_damage =
 481                                         (
 482                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 483                                                 +
 484                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 485                                         );
 486
 487                                 // figure out the direction of force
 488                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
 489                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
 490                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 491
 492                                 // now multiply the direction by force units
 493                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
 494                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 495
 496                                 // queue damage with this calculated info
 497                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 498
 499                                 #ifdef DEBUG_SHOCKWAVE
 500                                 print(sprintf(
 501                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
 502                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 503                                         multiplier,
 504                                         final_damage,
 505                                         vlen(final_force),
 506                                         multiplier_from_accuracy,
 507                                         multiplier_from_distance
 508                                 ));
 509                                 #endif
 510                         }
 511                 }
 512                 head = head.chain;
 513         }
 514
 515         // cone damage trace
 516         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 517         while(head)
 518         {
 519                 if((head != self) && head.takedamage)
 520                 {
 521                         // ========================
 522                         //  BLAST CONE CALCULATION
 523                         // ========================
 524
 525                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 526                         center = CENTER_OR_VIEWOFS(head);
 527
 528                         // find the closest point on the enemy to the center of the attack
 529                         float ang; // angle between shotdir and h
 530                         float h; // hypotenuse, which is the distance between attacker to head
 531                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 532
 533                         h = vlen(center - self.origin);
 534                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 535                         a = h * cos(ang);
 536                         // WEAPONTODO: replace with simpler method
 537
 538                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 539                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 540
 541                         if((vlen(head.WarpZone_findradius_dist) <= WEP_CVAR(shockwave, blast_distance))
 542                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 543                         {
 544                                 // calculate importance of distance and accuracy for this attack
 545                                 multiplier_from_accuracy = (1 -
 546                                         W_Shockwave_Attack_CheckSpread(
 547                                                 nearest_to_attacker,
 548                                                 nearest_on_line,
 549                                                 w_shotorg,
 550                                                 attack_endpos
 551                                         )
 552                                 );
 553                                 multiplier_from_distance = (1 -
 554                                         (distance_to_hit ?
 555                                                 min(1, (vlen(head.WarpZone_findradius_dist) / distance_to_end))
 556                                                 :
 557                                                 0
 558                                         )
 559                                 );
 560                                 multiplier =
 561                                         max(
 562                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 563                                                 (
 564                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 565                                                         +
 566                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 567                                                 )
 568                                         );
 569
 570                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 571                                 final_damage =
 572                                         (
 573                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
 574                                                 +
 575                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
 576                                         );
 577
 578                                 // figure out the direction of force
 579                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
 580                                 final_force = normalize(center - (nearest_on_line - final_force));
 581                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 582
 583                                 // now multiply the direction by force units
 584                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
 585                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 586
 587                                 // queue damage with this calculated info
 588                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 589
 590                                 #ifdef DEBUG_SHOCKWAVE
 591                                 print(sprintf(
 592                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
 593                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 594                                         multiplier,
 595                                         final_damage,
 596                                         vlen(final_force),
 597                                         multiplier_from_accuracy,
 598                                         multiplier_from_distance
 599                                 ));
 600                                 #endif
 601                         }
 602                 }
 603                 head = head.chain;
 604         }
 605
 606         for(i = 1; i <= queue; ++i)
 607         {
 608                 head = shockwave_hit[i-1];
 609                 final_force = shockwave_hit_force[i-1];
 610                 final_damage = shockwave_hit_damage[i-1];
 611
 612                 Damage(
 613                         head,
 614                         self,
 615                         self,
 616                         final_damage,
 617                         WEP_SHOCKWAVE,
 618                         head.origin,
 619                         final_force
 620                 );
 621
 622                 if(accuracy_isgooddamage(self.realowner, head))
 623                 {
 624                         print("wtf\n");
 625                         accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, final_damage);
 626                 }
 627
 628                 #ifdef DEBUG_SHOCKWAVE
 629                 print(sprintf(
 630                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
 631                         self.netname,
 632                         final_damage,
 633                         vlen(final_force)
 634                 ));
 635                 #endif
 636
 637                 shockwave_hit[i-1] = world;
 638                 shockwave_hit_force[i-1] = '0 0 0';
 639                 shockwave_hit_damage[i-1] = 0;
 640         }
 641 }
 642
 643 float W_Shockwave(float req)
 644 {
 645         switch(req)
 646         {
 647                 case WR_AIM:
 648                 {
 649                         if(vlen(self.origin - self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 650                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 651                         else
 652                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 653
 654                         return TRUE;
 655                 }
 656                 case WR_THINK:
 657                 {
 658                         if(self.BUTTON_ATCK)
 659                         {
 660                                 if(time >= self.shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
 661                                 {
 662                                         if(weapon_prepareattack(0, WEP_CVAR(shockwave, blast_animtime)))
 663                                         {
 664                                                 W_Shockwave_Attack();
 665                                                 self.shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor();
 666                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
 667                                         }
 668                                 }
 669                         }
 670                         else if(self.BUTTON_ATCK2)
 671                         {
 672                                 //if(self.clip_load >= 0) // we are not currently reloading
 673                                 if(!self.crouch) // no crouchmelee please
 674                                 if(weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 675                                 {
 676                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 677                                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 678                                 }
 679                         }
 680
 681                         return TRUE;
 682                 }
 683                 case WR_INIT:
 684                 {
 685                         precache_model("models/uziflash.md3");
 686                         precache_model("models/weapons/g_shockwave.md3");
 687                         precache_model("models/weapons/v_shockwave.md3");
 688                         precache_model("models/weapons/h_shockwave.iqm");
 689                         precache_sound("misc/itempickup.wav");
 690                         precache_sound("weapons/shockwave_fire.wav");
 691                         precache_sound("weapons/shockwave_melee.wav");
 692                         SHOCKWAVE_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 693                         return TRUE;
 694                 }
 695                 case WR_CHECKAMMO1:
 696                 case WR_CHECKAMMO2:
 697                 {
 698                         // shockwave has infinite ammo
 699                         return TRUE;
 700                 }
 701                 case WR_CONFIG:
 702                 {
 703                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 704                         return TRUE;
 705                 }
 706                 case WR_SUICIDEMESSAGE:
 707                 {
 708                         return WEAPON_THINKING_WITH_PORTALS;
 709                 }
 710                 case WR_KILLMESSAGE:
 711                 {
 712                         if(w_deathtype & HITTYPE_SECONDARY)
 713                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 714                         else
 715                                 return WEAPON_SHOCKWAVE_MURDER;
 716                 }
 717         }
 718         return FALSE;
 719 }
 720 #endif
 721 #ifdef CSQC
 722 float W_Shockwave(float req)
 723 {
 724         switch(req)
 725         {
 726                 case WR_IMPACTEFFECT:
 727                 {
 728                         vector org2;
 729                         org2 = w_org + w_backoff * 2;
 730                         pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1); // WEAPONTODO: replace with proper impact effect
 731                         return TRUE;
 732                 }
 733                 case WR_INIT:
 734                 {
 735                         //precache_sound("weapons/ric1.wav");
 736                         //precache_sound("weapons/ric2.wav");
 737                         //precache_sound("weapons/ric3.wav");
 738                         return FALSE;
 739                 }
 740                 case WR_ZOOMRETICLE:
 741                 {
 742                         // no weapon specific image for this weapon
 743                         return FALSE;
 744                 }
 745         }
 746         return FALSE;
 747 }
 748 #endif
 749 #endif