qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Arc, Weapon)
   4 /* ammotype  */ ATTRIB(Arc, ammo_field, .int, ammo_cells);
   5 /* impulse   */ ATTRIB(Arc, impulse, int, 3);
   6 /* flags     */ ATTRIB(Arc, spawnflags, int, WEP_FLAG_NORMAL);
   7 /* rating    */ ATTRIB(Arc, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(Arc, wpcolor, vector, '1 1 1');
   9 /* modelname */ ATTRIB(Arc, mdl, string, "arc");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Arc, m_model, Model, MDL_ARC_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Arc, w_crosshair, string, "gfx/crosshairhlac");
  14 /* crosshair */ ATTRIB(Arc, w_crosshair_size, float, 0.7);
  15 /* wepimg    */ ATTRIB(Arc, model2, string, "weaponarc");
  16 /* refname   */ ATTRIB(Arc, netname, string, "arc");
  17 /* wepname   */ ATTRIB(Arc, m_name, string, _("Arc"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, bolt, float, NONE) \
  22                 P(class, prefix, bolt_ammo, float, NONE) \
  23         P(class, prefix, bolt_damageforcescale, float, NONE) \
  24         P(class, prefix, bolt_damage, float, NONE) \
  25         P(class, prefix, bolt_edgedamage, float, NONE) \
  26         P(class, prefix, bolt_force, float, NONE) \
  27         P(class, prefix, bolt_health, float, NONE) \
  28         P(class, prefix, bolt_lifetime, float, NONE) \
  29         P(class, prefix, bolt_radius, float, NONE) \
  30         P(class, prefix, bolt_refire, float, NONE) \
  31         P(class, prefix, bolt_speed, float, NONE) \
  32         P(class, prefix, bolt_spread, float, NONE) \
  33                 P(class, prefix, beam_ammo, float, NONE) \
  34         P(class, prefix, beam_animtime, float, NONE) \
  35         P(class, prefix, beam_botaimlifetime, float, NONE) \
  36         P(class, prefix, beam_botaimspeed, float, NONE) \
  37         P(class, prefix, beam_damage, float, NONE) \
  38         P(class, prefix, beam_degreespersegment, float, NONE) \
  39         P(class, prefix, beam_distancepersegment, float, NONE) \
  40         P(class, prefix, beam_falloff_halflifedist, float, NONE) \
  41         P(class, prefix, beam_falloff_maxdist, float, NONE) \
  42         P(class, prefix, beam_falloff_mindist, float, NONE) \
  43         P(class, prefix, beam_force, float, NONE) \
  44         P(class, prefix, beam_healing_amax, float, NONE) \
  45         P(class, prefix, beam_healing_aps, float, NONE) \
  46         P(class, prefix, beam_healing_hmax, float, NONE) \
  47         P(class, prefix, beam_healing_hps, float, NONE) \
  48         P(class, prefix, beam_heat, float, NONE) /* heat increase per second (primary) */ \
  49         P(class, prefix, beam_maxangle, float, NONE) \
  50         P(class, prefix, beam_nonplayerdamage, float, NONE) \
  51         P(class, prefix, beam_range, float, NONE) \
  52         P(class, prefix, beam_refire, float, NONE) \
  53         P(class, prefix, beam_returnspeed, float, NONE) \
  54         P(class, prefix, beam_tightness, float, NONE) \
  55         P(class, prefix, burst_ammo, float, NONE) \
  56         P(class, prefix, burst_damage, float, NONE) \
  57         P(class, prefix, burst_healing_aps, float, NONE) \
  58         P(class, prefix, burst_healing_hps, float, NONE) \
  59         P(class, prefix, burst_heat, float, NONE) /* heat increase per second (secondary) */ \
  60         P(class, prefix, cooldown, float, NONE) /* heat decrease per second when resting */ \
  61         P(class, prefix, cooldown_release, float, NONE) /* delay weapon re-use when releasing button */ \
  62         P(class, prefix, overheat_max, float, NONE) /* maximum heat before jamming */ \
  63         P(class, prefix, overheat_min, float, NONE) /* minimum heat to wait for cooldown */ \
  64         P(class, prefix, switchdelay_drop, float, NONE) \
  65         P(class, prefix, switchdelay_raise, float, NONE) \
  66         P(class, prefix, weaponreplace, string, NONE) \
  67         P(class, prefix, weaponstartoverride, float, NONE) \
  68         P(class, prefix, weaponstart, float, NONE) \
  69         P(class, prefix, weaponthrowable, float, NONE) \
  70     END()
  71     W_PROPS(X, Arc, arc)
  72 #undef X
  73
  74 ENDCLASS(Arc)
  75 REGISTER_WEAPON(ARC, arc, NEW(Arc));
  76
  77
  78 #ifdef GAMEQC
  79 const float ARC_MAX_SEGMENTS = 20;
  80 vector arc_shotorigin[4];
  81 .vector beam_start;
  82 .vector beam_dir;
  83 .vector beam_wantdir;
  84 .int beam_type;
  85
  86 const int ARC_BT_MISS =        0x00;
  87 const int ARC_BT_WALL =        0x01;
  88 const int ARC_BT_HEAL =        0x02;
  89 const int ARC_BT_HIT =         0x03;
  90 const int ARC_BT_BURST_MISS =  0x10;
  91 const int ARC_BT_BURST_WALL =  0x11;
  92 const int ARC_BT_BURST_HEAL =  0x12;
  93 const int ARC_BT_BURST_HIT =   0x13;
  94 const int ARC_BT_BURSTMASK =   0x10;
  95
  96 const int ARC_SF_SETTINGS =    BIT(0);
  97 const int ARC_SF_START =       BIT(1);
  98 const int ARC_SF_WANTDIR =     BIT(2);
  99 const int ARC_SF_BEAMDIR =     BIT(3);
 100 const int ARC_SF_BEAMTYPE =    BIT(4);
 101 const int ARC_SF_LOCALMASK =   ARC_SF_START | ARC_SF_WANTDIR | ARC_SF_BEAMDIR;
 102 #endif
 103 #ifdef SVQC
 104 .entity arc_beam;
 105 .bool arc_BUTTON_ATCK_prev; // for better animation control
 106 .float beam_prev;
 107 .float beam_initialized;
 108 .float beam_bursting;
 109 .float beam_teleporttime;
 110 .float beam_heat; // (beam) amount of heat produced
 111 .float arc_overheat; // (dropped arc/player) time during which it's too hot
 112 .float arc_cooldown; // (dropped arc/player) cooling speed
 113 .float arc_heat_percent = _STAT(ARC_HEAT);
 114 .float arc_smoke_sound;
 115 #endif
 116 #ifdef CSQC
 117
 118 .vector beam_color;
 119 .float beam_alpha;
 120 .float beam_thickness;
 121 .entity beam_traileffect;
 122 .entity beam_hiteffect;
 123 .float beam_hitlight[4]; // 0: radius, 123: rgb
 124 .entity beam_muzzleeffect;
 125 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 126 .string beam_image;
 127
 128 .entity beam_muzzleentity;
 129
 130 .float beam_degreespersegment;
 131 .float beam_distancepersegment;
 132 .float beam_usevieworigin;
 133 .float beam_initialized;
 134 .float beam_maxangle;
 135 .float beam_range;
 136 .float beam_returnspeed;
 137 .float beam_tightness;
 138 .vector beam_shotorigin;
 139
 140 entity Draw_ArcBeam_callback_entity;
 141 float Draw_ArcBeam_callback_last_thickness;
 142 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 143 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 144 #endif
 145 #endif
 146 #ifdef IMPLEMENTATION
 147 #ifdef SVQC
 148 spawnfunc(weapon_arc) { weapon_defaultspawnfunc(this, WEP_ARC); }
 149
 150 bool W_Arc_Beam_Send(entity this, entity to, int sf)
 151 {
 152         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 153
 154         // Truncate information when this beam is displayed to the owner client
 155         // - The owner client has no use for beam start position or directions,
 156         //    it always figures this information out for itself with csqc code.
 157         // - Spectating the owner also truncates this information.
 158         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
 159         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 160
 161         WriteByte(MSG_ENTITY, sf);
 162         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
 163
 164         if(sf & ARC_SF_SETTINGS) // settings information
 165         {
 166                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 167                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 168                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 169                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 170                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 171                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 172
 173                 WriteByte(MSG_ENTITY, drawlocal);
 174                 WriteByte(MSG_ENTITY, etof(this.owner));
 175         }
 176         if(sf & ARC_SF_START) // starting location
 177         {
 178                 WriteCoord(MSG_ENTITY, this.beam_start.x);
 179                 WriteCoord(MSG_ENTITY, this.beam_start.y);
 180                 WriteCoord(MSG_ENTITY, this.beam_start.z);
 181         }
 182         if(sf & ARC_SF_WANTDIR) // want/aim direction
 183         {
 184                 WriteCoord(MSG_ENTITY, this.beam_wantdir.x);
 185                 WriteCoord(MSG_ENTITY, this.beam_wantdir.y);
 186                 WriteCoord(MSG_ENTITY, this.beam_wantdir.z);
 187         }
 188         if(sf & ARC_SF_BEAMDIR) // beam direction
 189         {
 190                 WriteCoord(MSG_ENTITY, this.beam_dir.x);
 191                 WriteCoord(MSG_ENTITY, this.beam_dir.y);
 192                 WriteCoord(MSG_ENTITY, this.beam_dir.z);
 193         }
 194         if(sf & ARC_SF_BEAMTYPE) // beam type
 195         {
 196                 WriteByte(MSG_ENTITY, this.beam_type);
 197         }
 198
 199         return true;
 200 }
 201
 202 void Reset_ArcBeam(entity player, vector forward)
 203 {
 204         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 205         {
 206                 .entity weaponentity = weaponentities[slot];
 207                 if(!player.(weaponentity).arc_beam)
 208                         continue;
 209                 player.(weaponentity).arc_beam.beam_dir = forward;
 210                 player.(weaponentity).arc_beam.beam_teleporttime = time;
 211         }
 212 }
 213
 214 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
 215 {
 216         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 217         {
 218                 player.arc_overheat = 0;
 219                 return 0;
 220         }
 221
 222         if ( player.(weaponentity).arc_beam )
 223                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 224
 225         if ( player.arc_overheat > time )
 226         {
 227                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 228                         * player.arc_cooldown;
 229         }
 230
 231         return 0;
 232 }
 233 void Arc_Player_SetHeat(entity player, .entity weaponentity)
 234 {
 235         player.arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
 236         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 237 }
 238
 239 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
 240 {
 241         this.event_damage = func_null;
 242         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, directhitentity);
 243
 244         delete(this);
 245 }
 246
 247 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 248 {
 249         W_Arc_Bolt_Explode(this, trigger);
 250 }
 251
 252 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 253 {
 254         if(this.health <= 0)
 255                 return;
 256
 257         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 258                 return; // g_projectiles_damage says to halt
 259
 260         this.health = this.health - damage;
 261         this.angles = vectoangles(this.velocity);
 262
 263         if(this.health <= 0)
 264                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 265 }
 266
 267 void W_Arc_Bolt_Touch(entity this, entity toucher)
 268 {
 269         PROJECTILE_TOUCH(this, toucher);
 270         this.use(this, NULL, toucher);
 271 }
 272
 273 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 274 {
 275         entity missile;
 276
 277         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 278
 279         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage));
 280
 281         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 282
 283         missile = new(missile);
 284         missile.owner = missile.realowner = actor;
 285         missile.bot_dodge = true;
 286         IL_PUSH(g_bot_dodge, missile);
 287         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 288
 289         missile.takedamage = DAMAGE_YES;
 290         missile.health = WEP_CVAR(arc, bolt_health);
 291         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 292         missile.event_damage = W_Arc_Bolt_Damage;
 293         missile.damagedbycontents = true;
 294
 295         settouch(missile, W_Arc_Bolt_Touch);
 296         missile.use = W_Arc_Bolt_Explode_use;
 297         setthink(missile, adaptor_think2use_hittype_splash);
 298         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 299         PROJECTILE_MAKETRIGGER(missile);
 300         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 301         setorigin(missile, w_shotorg);
 302         setsize(missile, '0 0 0', '0 0 0');
 303
 304         set_movetype(missile, MOVETYPE_FLY);
 305         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 306
 307         missile.angles = vectoangles(missile.velocity);
 308         missile.flags = FL_PROJECTILE;
 309         missile.missile_flags = MIF_SPLASH;
 310
 311         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 312
 313         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 314 }
 315
 316 void W_Arc_Beam_Think(entity this)
 317 {
 318         .entity weaponentity = this.weaponentity_fld;
 319         if(this != this.owner.(weaponentity).arc_beam)
 320         {
 321                 delete(this);
 322                 return;
 323         }
 324
 325         float burst = 0;
 326         if( (PHYS_INPUT_BUTTON_ATCK2(this.owner) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 327         {
 328                 if(!this.beam_bursting)
 329                         this.beam_bursting = true;
 330                 burst = ARC_BT_BURSTMASK;
 331         }
 332
 333         Weapon thiswep = WEP_ARC;
 334
 335         if(
 336                 !IS_PLAYER(this.owner)
 337                 ||
 338                 (this.owner.(thiswep.ammo_field) <= 0 && !(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 339                 ||
 340                 IS_DEAD(this.owner)
 341                 ||
 342                 forbidWeaponUse(this.owner)
 343                 ||
 344                 (!PHYS_INPUT_BUTTON_ATCK(this.owner) && !burst )
 345                 ||
 346                 this.owner.vehicle
 347                 ||
 348                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 349         )
 350         {
 351                 if ( WEP_CVAR(arc, cooldown) > 0 )
 352                 {
 353                         float cooldown_speed = 0;
 354                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 355                         {
 356                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 357                         }
 358                         else if ( !burst )
 359                         {
 360                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 361                         }
 362
 363                         if ( cooldown_speed )
 364                         {
 365                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 366                                         this.owner.arc_overheat = time + this.beam_heat / cooldown_speed;
 367                                 this.owner.arc_cooldown = cooldown_speed;
 368                         }
 369
 370                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 371                         {
 372                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 373                                         this.beam_start, this.beam_wantdir, 1 );
 374                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 375                         }
 376                 }
 377
 378                 if(this == this.owner.(weaponentity).arc_beam) { this.owner.(weaponentity).arc_beam = NULL; }
 379                 entity own = this.owner;
 380                 Weapon w = WEP_ARC;
 381                 if(!w.wr_checkammo1(w, own, weaponentity) && !w.wr_checkammo2(w, own, weaponentity))
 382                 if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 383                 {
 384                         // note: this doesn't force the switch
 385                         W_SwitchToOtherWeapon(own, weaponentity);
 386                 }
 387                 delete(this);
 388                 return;
 389         }
 390
 391         // decrease ammo
 392         float coefficient = frametime;
 393         if(!(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 394         {
 395                 float rootammo;
 396                 if(burst)
 397                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 398                 else
 399                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 400
 401                 if(rootammo)
 402                 {
 403                         coefficient = min(coefficient, this.owner.(thiswep.ammo_field) / rootammo);
 404                         this.owner.(thiswep.ammo_field) = max(0, this.owner.(thiswep.ammo_field) - (rootammo * frametime));
 405                 }
 406         }
 407         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 408         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 409
 410         makevectors(this.owner.v_angle);
 411
 412         W_SetupShot_Range(
 413                 this.owner,
 414                 weaponentity, // TODO
 415                 true,
 416                 0,
 417                 SND_Null,
 418                 0,
 419                 WEP_CVAR(arc, beam_damage) * coefficient,
 420                 WEP_CVAR(arc, beam_range)
 421         );
 422
 423         // After teleport, "lock" the beam until the teleport is confirmed.
 424         if (time < this.beam_teleporttime + ANTILAG_LATENCY(this.owner)) {
 425                 w_shotdir = this.beam_dir;
 426         }
 427
 428         // network information: shot origin and want/aim direction
 429         if(this.beam_start != w_shotorg)
 430         {
 431                 this.SendFlags |= ARC_SF_START;
 432                 this.beam_start = w_shotorg;
 433         }
 434         if(this.beam_wantdir != w_shotdir)
 435         {
 436                 this.SendFlags |= ARC_SF_WANTDIR;
 437                 this.beam_wantdir = w_shotdir;
 438         }
 439
 440         if(!this.beam_initialized)
 441         {
 442                 this.beam_dir = w_shotdir;
 443                 this.beam_initialized = true;
 444         }
 445
 446         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 447         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 448         // might have to make some special accomodation so that it only uses view_right and view_up
 449
 450         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 451
 452         float segments;
 453         if(this.beam_dir != w_shotdir)
 454         {
 455                 // calculate how much we're going to move the end of the beam to the want position
 456                 // WEAPONTODO (server and client):
 457                 // blendfactor never actually becomes 0 in this situation, which is a problem
 458                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 459                 // eachother, however they never actually become the same value with this method.
 460                 // Perhaps we should do some form of rounding/snapping?
 461                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 462                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 463                 {
 464                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 465                         float blendfactor = bound(
 466                                 0,
 467                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 468                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 469                         );
 470                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 471                 }
 472                 else
 473                 {
 474                         // the radius is not too far yet, no worries :D
 475                         float blendfactor = bound(
 476                                 0,
 477                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 478                                 1
 479                         );
 480                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 481                 }
 482
 483                 // network information: beam direction
 484                 this.SendFlags |= ARC_SF_BEAMDIR;
 485
 486                 // calculate how many segments are needed
 487                 float max_allowed_segments;
 488
 489                 if(WEP_CVAR(arc, beam_distancepersegment))
 490                 {
 491                         max_allowed_segments = min(
 492                                 ARC_MAX_SEGMENTS,
 493                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 494                         );
 495                 }
 496                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 497
 498                 if(WEP_CVAR(arc, beam_degreespersegment))
 499                 {
 500                         segments = bound(
 501                                 1,
 502                                 (
 503                                         min(
 504                                                 angle,
 505                                                 WEP_CVAR(arc, beam_maxangle)
 506                                         )
 507                                         /
 508                                         WEP_CVAR(arc, beam_degreespersegment)
 509                                 ),
 510                                 max_allowed_segments
 511                         );
 512                 }
 513                 else { segments = 1; }
 514         }
 515         else { segments = 1; }
 516
 517         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 518         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 519
 520         float i;
 521         float new_beam_type = 0;
 522         vector last_origin = w_shotorg;
 523         for(i = 1; i <= segments; ++i)
 524         {
 525                 // WEAPONTODO (client):
 526                 // In order to do nice fading and pointing on the starting segment, we must always
 527                 // have that drawn as a separate triangle... However, that is difficult to do when
 528                 // keeping in mind the above problems and also optimizing the amount of segments
 529                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 530
 531                 vector new_origin = bezier_quadratic_getpoint(
 532                         w_shotorg,
 533                         beam_controlpoint,
 534                         beam_endpos,
 535                         i / segments);
 536                 vector new_dir = normalize(new_origin - last_origin);
 537
 538                 WarpZone_traceline_antilag(
 539                         this.owner,
 540                         last_origin,
 541                         new_origin,
 542                         MOVE_NORMAL,
 543                         this.owner,
 544                         ANTILAG_LATENCY(this.owner)
 545                 );
 546
 547                 // Do all the transforms for warpzones right now, as we already
 548                 // "are" in the post-trace system (if we hit a player, that's
 549                 // always BEHIND the last passed wz).
 550                 last_origin = trace_endpos;
 551                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 552                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 553                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 554                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 555
 556                 float is_player = (
 557                         IS_PLAYER(trace_ent)
 558                         ||
 559                         trace_ent.classname == "body"
 560                         ||
 561                         IS_MONSTER(trace_ent)
 562                 );
 563
 564                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 565                 {
 566                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 567                         // NO. trace_endpos should be just fine. If not,
 568                         // that's an engine bug that needs proper debugging.
 569                         vector hitorigin = trace_endpos;
 570
 571                         float falloff = ExponentialFalloff(
 572                                 WEP_CVAR(arc, beam_falloff_mindist),
 573                                 WEP_CVAR(arc, beam_falloff_maxdist),
 574                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 575                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 576                         );
 577
 578                         if(is_player && SAME_TEAM(this.owner, trace_ent))
 579                         {
 580                                 float roothealth, rootarmor;
 581                                 if(burst)
 582                                 {
 583                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 584                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 585                                 }
 586                                 else
 587                                 {
 588                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 589                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 590                                 }
 591
 592                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 593                                 {
 594                                         trace_ent.health = min(
 595                                                 trace_ent.health + (roothealth * coefficient),
 596                                                 WEP_CVAR(arc, beam_healing_hmax)
 597                                         );
 598                                 }
 599                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 600                                 {
 601                                         trace_ent.armorvalue = min(
 602                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 603                                                 WEP_CVAR(arc, beam_healing_amax)
 604                                         );
 605                                 }
 606
 607                                 // stop rot, set visual effect
 608                                 if(roothealth || rootarmor)
 609                                 {
 610                                         trace_ent.pauserothealth_finished = max(
 611                                                 trace_ent.pauserothealth_finished,
 612                                                 time + autocvar_g_balance_pause_health_rot
 613                                         );
 614                                         trace_ent.pauserotarmor_finished = max(
 615                                                 trace_ent.pauserotarmor_finished,
 616                                                 time + autocvar_g_balance_pause_armor_rot
 617                                         );
 618                                         new_beam_type = ARC_BT_HEAL;
 619                                 }
 620                         }
 621                         else
 622                         {
 623                                 float rootdamage;
 624                                 if(is_player)
 625                                 {
 626                                         if(burst)
 627                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 628                                         else
 629                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 630                                 }
 631                                 else
 632                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 633
 634                                 if(accuracy_isgooddamage(this.owner, trace_ent))
 635                                 {
 636                                         accuracy_add(
 637                                                 this.owner,
 638                                                 WEP_ARC.m_id,
 639                                                 0,
 640                                                 rootdamage * coefficient * falloff
 641                                         );
 642                                 }
 643
 644                                 Damage(
 645                                         trace_ent,
 646                                         this.owner,
 647                                         this.owner,
 648                                         rootdamage * coefficient * falloff,
 649                                         WEP_ARC.m_id,
 650                                         hitorigin,
 651                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 652                                 );
 653
 654                                 new_beam_type = ARC_BT_HIT;
 655                         }
 656                         break;
 657                 }
 658                 else if(trace_fraction != 1)
 659                 {
 660                         // we collided with geometry
 661                         new_beam_type = ARC_BT_WALL;
 662                         break;
 663                 }
 664         }
 665
 666         // te_explosion(trace_endpos);
 667
 668         // if we're bursting, use burst visual effects
 669         new_beam_type |= burst;
 670
 671         // network information: beam type
 672         if(new_beam_type != this.beam_type)
 673         {
 674                 this.SendFlags |= ARC_SF_BEAMTYPE;
 675                 this.beam_type = new_beam_type;
 676         }
 677
 678         this.owner.(weaponentity).beam_prev = time;
 679         this.nextthink = time;
 680 }
 681
 682 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 683 {
 684
 685         // only play fire sound if 1 sec has passed since player let go the fire button
 686         if(time - actor.(weaponentity).beam_prev > 1)
 687                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 688
 689         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 690         beam.weaponentity_fld = weaponentity;
 691         beam.solid = SOLID_NOT;
 692         setthink(beam, W_Arc_Beam_Think);
 693         beam.owner = actor;
 694         set_movetype(beam, MOVETYPE_NONE);
 695         beam.bot_dodge = true;
 696         IL_PUSH(g_bot_dodge, beam);
 697         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 698         beam.beam_bursting = burst;
 699         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 700
 701         getthink(beam)(beam);
 702 }
 703 void Arc_Smoke(entity actor, .entity weaponentity)
 704 {
 705         makevectors(actor.v_angle);
 706         W_SetupShot_Range(actor,weaponentity,true,0,SND_Null,0,0,0);
 707
 708         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 709         if ( actor.arc_overheat > time )
 710         {
 711                 if ( random() < actor.arc_heat_percent )
 712                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 713                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 714                 {
 715                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 716                         if ( !actor.arc_smoke_sound )
 717                         {
 718                                 actor.arc_smoke_sound = 1;
 719                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 720                         }
 721                 }
 722         }
 723         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 724                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 725         {
 726                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 727                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 728                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 729         }
 730
 731         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 732                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || actor.(weaponentity).m_switchweapon != WEP_ARC )
 733         {
 734                 actor.arc_smoke_sound = 0;
 735                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 736         }
 737 }
 738
 739 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 740 {
 741     if(WEP_CVAR(arc, beam_botaimspeed))
 742     {
 743         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 744                 actor,
 745                 weaponentity,
 746             WEP_CVAR(arc, beam_botaimspeed),
 747             0,
 748             WEP_CVAR(arc, beam_botaimlifetime),
 749             false
 750         );
 751     }
 752     else
 753     {
 754         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 755                 actor,
 756                 weaponentity,
 757             1000000,
 758             0,
 759             0.001,
 760             false
 761         );
 762     }
 763 }
 764 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 765 {
 766     Arc_Player_SetHeat(actor, weaponentity);
 767     Arc_Smoke(actor, weaponentity);
 768
 769     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 770
 771     if (time >= actor.arc_overheat)
 772     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 773     {
 774
 775         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 776         {
 777             #if 0
 778             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 779                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 780             else
 781             #endif
 782                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 783         }
 784
 785         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 786         {
 787             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 788             {
 789                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 790
 791                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 792                 {
 793                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 794                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 795                 }
 796             }
 797         }
 798
 799         return;
 800     }
 801     else if(fire & 2)
 802     {
 803         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(arc, bolt_refire)))
 804         {
 805             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 806             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 807         }
 808     }
 809
 810     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 811     {
 812         int slot = weaponslot(weaponentity);
 813         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 814         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 815         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 816     }
 817     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 818
 819     #if 0
 820     if(fire & 2)
 821     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 822     {
 823         W_Arc_Attack2();
 824         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 825         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 826         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 827     }
 828     #endif
 829 }
 830 METHOD(Arc, wr_init, void(entity thiswep))
 831 {
 832     if(!arc_shotorigin[0])
 833     {
 834         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 835         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 836         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 837         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 838     }
 839 }
 840 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 841 {
 842     return ((!WEP_CVAR(arc, beam_ammo)) || (actor.(thiswep.ammo_field) > 0));
 843 }
 844 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 845 {
 846     if(WEP_CVAR(arc, bolt))
 847     {
 848         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(arc, bolt_ammo);
 849         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 850         return ammo_amount;
 851     }
 852     else
 853         return WEP_CVAR(arc, overheat_max) > 0 &&
 854             ((!WEP_CVAR(arc, burst_ammo)) || (actor.(thiswep.ammo_field) > 0));
 855 }
 856 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 857 {
 858     if(w_deathtype & HITTYPE_SECONDARY)
 859         return WEAPON_ARC_MURDER_SPRAY;
 860     else
 861         return WEAPON_ARC_MURDER;
 862 }
 863 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 864 {
 865     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 866     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 867     actor.arc_overheat = 0;
 868     actor.arc_cooldown = 0;
 869     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 870 }
 871 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 872 {
 873     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 874         weapon_dropevent_item.arc_overheat > time )
 875     {
 876         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 877         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 878     }
 879 }
 880 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 881 {
 882     actor.arc_overheat = 0;
 883     actor.arc_cooldown = 0;
 884     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 885     {
 886         .entity weaponentity = weaponentities[slot];
 887         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 888     }
 889 }
 890 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 891 {
 892     actor.arc_overheat = 0;
 893     actor.arc_cooldown = 0;
 894     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 895 }
 896 #endif
 897 #ifdef CSQC
 898 bool autocvar_cl_arcbeam_teamcolor = true;
 899
 900 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 901 {
 902     if(w_deathtype & HITTYPE_SECONDARY)
 903     {
 904         vector org2;
 905         org2 = w_org + w_backoff * 6;
 906         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 907         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 908     }
 909 }
 910
 911 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 912 {
 913         entity beam = Draw_ArcBeam_callback_entity;
 914         vector transformed_view_org;
 915         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 916
 917         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 918         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 919         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 920
 921         vector hitorigin;
 922
 923         // draw segment
 924         #if 0
 925         if(trace_fraction != 1)
 926         {
 927                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 928                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 929                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 930         }
 931         else
 932         {
 933                 hitorigin = hit;
 934         }
 935         #else
 936         hitorigin = hit;
 937         #endif
 938
 939         // decide upon thickness
 940         float thickness = beam.beam_thickness;
 941
 942         // draw primary beam render
 943         vector top    = hitorigin + (thickdir * thickness);
 944         vector bottom = hitorigin - (thickdir * thickness);
 945
 946         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 947         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 948
 949         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 950         R_PolygonVertex(
 951                 top,
 952                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 953                 beam.beam_color,
 954                 beam.beam_alpha
 955         );
 956         R_PolygonVertex(
 957                 last_top,
 958                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 959                 beam.beam_color,
 960                 beam.beam_alpha
 961         );
 962         R_PolygonVertex(
 963                 last_bottom,
 964                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 965                 beam.beam_color,
 966                 beam.beam_alpha
 967         );
 968         R_PolygonVertex(
 969                 bottom,
 970                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 971                 beam.beam_color,
 972                 beam.beam_alpha
 973         );
 974         R_EndPolygon();
 975
 976         // draw trailing particles
 977         // NOTES:
 978         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 979         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 980         if(beam.beam_traileffect)
 981         {
 982                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 983         }
 984
 985         // set up for the next
 986         Draw_ArcBeam_callback_last_thickness = thickness;
 987         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 988         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 989 }
 990
 991 void Reset_ArcBeam()
 992 {
 993         entity e;
 994         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 995                 e.beam_initialized = false;
 996         }
 997         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 998                 e.beam_initialized = false;
 999         }
1000 }
1001
1002 void Draw_ArcBeam(entity this)
1003 {
1004         float dt = time - this.move_time;
1005         this.move_time = time;
1006         if(dt <= 0) { return; }
1007
1008         if(!this.beam_usevieworigin)
1009         {
1010                 InterpolateOrigin_Do(this);
1011         }
1012
1013         // origin = beam starting origin
1014         // v_angle = wanted/aim direction
1015         // angles = current direction of beam
1016
1017         vector start_pos;
1018         vector wantdir; //= view_forward;
1019         vector beamdir; //= this.beam_dir;
1020
1021         float segments;
1022         if(this.beam_usevieworigin)
1023         {
1024                 // WEAPONTODO:
1025                 // Currently we have to replicate nearly the same method of figuring
1026                 // out the shotdir that the server does... Ideally in the future we
1027                 // should be able to acquire this from a generalized function built
1028                 // into a weapon system for client code.
1029
1030                 // find where we are aiming
1031                 makevectors(warpzone_save_view_angles);
1032                 vector forward = v_forward;
1033                 vector right = v_right;
1034                 vector up = v_up;
1035
1036                 // decide upon start position
1037                 if(this.beam_usevieworigin == 2)
1038                         { start_pos = warpzone_save_view_origin; }
1039                 else
1040                         { start_pos = this.origin; }
1041
1042                 // trace forward with an estimation
1043                 WarpZone_TraceLine(
1044                         start_pos,
1045                         start_pos + forward * this.beam_range,
1046                         MOVE_NOMONSTERS,
1047                         this
1048                 );
1049
1050                 // untransform in case our trace went through a warpzone
1051                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
1052
1053                 // un-adjust trueaim if shotend is too close
1054                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
1055                         end_pos = start_pos + (forward * g_trueaim_minrange);
1056
1057                 // move shot origin to the actual gun muzzle origin
1058                 vector origin_offset =
1059                           right * -this.beam_shotorigin.y
1060                         + up * this.beam_shotorigin.z;
1061
1062                 start_pos = start_pos + origin_offset;
1063
1064                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
1065                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
1066                 start_pos = trace_endpos;
1067
1068                 // calculate the aim direction now
1069                 wantdir = normalize(end_pos - start_pos);
1070
1071                 if(!this.beam_initialized)
1072                 {
1073                         this.beam_dir = wantdir;
1074                         this.beam_initialized = true;
1075                 }
1076
1077                 if(this.beam_dir != wantdir)
1078                 {
1079                         // calculate how much we're going to move the end of the beam to the want position
1080                         // WEAPONTODO (server and client):
1081                         // blendfactor never actually becomes 0 in this situation, which is a problem
1082                         // regarding precision... this means that this.beam_dir and w_shotdir approach
1083                         // eachother, however they never actually become the same value with this method.
1084                         // Perhaps we should do some form of rounding/snapping?
1085                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
1086                         if(angle && (angle > this.beam_maxangle))
1087                         {
1088                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
1089                                 float blendfactor = bound(
1090                                         0,
1091                                         (1 - (this.beam_returnspeed * frametime)),
1092                                         min(this.beam_maxangle / angle, 1)
1093                                 );
1094                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1095                         }
1096                         else
1097                         {
1098                                 // the radius is not too far yet, no worries :D
1099                                 float blendfactor = bound(
1100                                         0,
1101                                         (1 - (this.beam_returnspeed * frametime)),
1102                                         1
1103                                 );
1104                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1105                         }
1106
1107                         // calculate how many segments are needed
1108                         float max_allowed_segments;
1109
1110                         if(this.beam_distancepersegment)
1111                         {
1112                                 max_allowed_segments = min(
1113                                         ARC_MAX_SEGMENTS,
1114                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1115                                 );
1116                         }
1117                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1118
1119                         if(this.beam_degreespersegment)
1120                         {
1121                                 segments = bound(
1122                                         1,
1123                                         (
1124                                                 min(
1125                                                         angle,
1126                                                         this.beam_maxangle
1127                                                 )
1128                                                 /
1129                                                 this.beam_degreespersegment
1130                                         ),
1131                                         max_allowed_segments
1132                                 );
1133                         }
1134                         else { segments = 1; }
1135                 }
1136                 else { segments = 1; }
1137
1138                 // set the beam direction which the rest of the code will refer to
1139                 beamdir = this.beam_dir;
1140
1141                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1142                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1143         }
1144         else
1145         {
1146                 // set the values from the provided info from the networked entity
1147                 start_pos = this.origin;
1148                 wantdir = this.v_angle;
1149                 beamdir = this.angles;
1150
1151                 if(beamdir != wantdir)
1152                 {
1153                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1154
1155                         // calculate how many segments are needed
1156                         float max_allowed_segments;
1157
1158                         if(this.beam_distancepersegment)
1159                         {
1160                                 max_allowed_segments = min(
1161                                         ARC_MAX_SEGMENTS,
1162                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1163                                 );
1164                         }
1165                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1166
1167                         if(this.beam_degreespersegment)
1168                         {
1169                                 segments = bound(
1170                                         1,
1171                                         (
1172                                                 min(
1173                                                         angle,
1174                                                         this.beam_maxangle
1175                                                 )
1176                                                 /
1177                                                 this.beam_degreespersegment
1178                                         ),
1179                                         max_allowed_segments
1180                                 );
1181                         }
1182                         else { segments = 1; }
1183                 }
1184                 else { segments = 1; }
1185         }
1186
1187         setorigin(this, start_pos);
1188         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1189
1190         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1191         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1192
1193         Draw_ArcBeam_callback_entity = this;
1194         Draw_ArcBeam_callback_last_thickness = 0;
1195         Draw_ArcBeam_callback_last_top = start_pos;
1196         Draw_ArcBeam_callback_last_bottom = start_pos;
1197
1198         vector last_origin = start_pos;
1199         vector original_start_pos = start_pos;
1200
1201         float i;
1202         for(i = 1; i <= segments; ++i)
1203         {
1204                 // WEAPONTODO (client):
1205                 // In order to do nice fading and pointing on the starting segment, we must always
1206                 // have that drawn as a separate triangle... However, that is difficult to do when
1207                 // keeping in mind the above problems and also optimizing the amount of segments
1208                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1209
1210                 vector new_origin = bezier_quadratic_getpoint(
1211                         start_pos,
1212                         beam_controlpoint,
1213                         beam_endpos,
1214                         i / segments);
1215
1216                 WarpZone_TraceBox_ThroughZone(
1217                         last_origin,
1218                         '0 0 0',
1219                         '0 0 0',
1220                         new_origin,
1221                         MOVE_NORMAL,
1222                         NULL,
1223                         NULL,
1224                         Draw_ArcBeam_callback
1225                 );
1226
1227                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1228                 // system (if we hit a player, that's always BEHIND the last passed wz).
1229                 last_origin = trace_endpos;
1230                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1231                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1232                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1233                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1234                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1235                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1236
1237                 if(trace_fraction < 1) { break; }
1238         }
1239
1240         // visual effects for startpoint and endpoint
1241         if(this.beam_hiteffect)
1242         {
1243                 // FIXME we really should do this on the server so it actually
1244                 // matches gameplay. What this client side stuff is doing is no
1245                 // more than guesswork.
1246                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1247                 pointparticles(
1248                         this.beam_hiteffect,
1249                         last_origin,
1250                         beamdir * -1,
1251                         frametime * 2
1252                 );
1253         }
1254         if(this.beam_hitlight[0])
1255         {
1256                 adddynamiclight(
1257                         last_origin,
1258                         this.beam_hitlight[0],
1259                         vec3(
1260                                 this.beam_hitlight[1],
1261                                 this.beam_hitlight[2],
1262                                 this.beam_hitlight[3]
1263                         )
1264                 );
1265         }
1266         if(this.beam_muzzleeffect)
1267         {
1268                 pointparticles(
1269                         this.beam_muzzleeffect,
1270                         original_start_pos + wantdir * 20,
1271                         wantdir * 1000,
1272                         frametime * 0.1
1273                 );
1274         }
1275         if(this.beam_muzzlelight[0])
1276         {
1277                 adddynamiclight(
1278                         original_start_pos + wantdir * 20,
1279                         this.beam_muzzlelight[0],
1280                         vec3(
1281                                 this.beam_muzzlelight[1],
1282                                 this.beam_muzzlelight[2],
1283                                 this.beam_muzzlelight[3]
1284                         )
1285                 );
1286         }
1287
1288         // cleanup
1289         Draw_ArcBeam_callback_entity = NULL;
1290         Draw_ArcBeam_callback_last_thickness = 0;
1291         Draw_ArcBeam_callback_last_top = '0 0 0';
1292         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1293 }
1294
1295 void Remove_ArcBeam(entity this)
1296 {
1297         delete(this.beam_muzzleentity);
1298         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1299 }
1300
1301 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1302 {
1303         int sf = ReadByte();
1304         int slot = ReadByte();
1305         entity flash;
1306
1307         if(isnew)
1308         {
1309                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1310
1311                 this.beam_shotorigin = arc_shotorigin[gunalign];
1312
1313                 // set other main attributes of the beam
1314                 this.draw = Draw_ArcBeam;
1315                 IL_PUSH(g_drawables, this);
1316                 this.entremove = Remove_ArcBeam;
1317                 this.move_time = time;
1318                 loopsound(this, CH_SHOTS_SINGLE, SND(ARC_LOOP), VOL_BASE, ATTEN_NORM);
1319
1320                 flash = spawn();
1321                 flash.owner = this;
1322                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1323                 flash.drawmask = MASK_NORMAL;
1324                 flash.solid = SOLID_NOT;
1325                 flash.avelocity_z = 5000;
1326                 setattachment(flash, this, "");
1327                 setorigin(flash, '0 0 0');
1328
1329                 this.beam_muzzleentity = flash;
1330         }
1331         else
1332         {
1333                 flash = this.beam_muzzleentity;
1334         }
1335
1336         if(sf & ARC_SF_SETTINGS) // settings information
1337         {
1338                 this.beam_degreespersegment = ReadShort();
1339                 this.beam_distancepersegment = ReadShort();
1340                 this.beam_maxangle = ReadShort();
1341                 this.beam_range = ReadCoord();
1342                 this.beam_returnspeed = ReadShort();
1343                 this.beam_tightness = (ReadByte() / 10);
1344
1345                 if(ReadByte())
1346                 {
1347                         if(autocvar_chase_active)
1348                                 { this.beam_usevieworigin = 1; }
1349                         else // use view origin
1350                                 { this.beam_usevieworigin = 2; }
1351                 }
1352                 else
1353                 {
1354                         this.beam_usevieworigin = 0;
1355                 }
1356
1357                 this.sv_entnum = ReadByte();
1358         }
1359
1360         if(!this.beam_usevieworigin)
1361         {
1362                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1363                 this.iflags = IFLAG_ORIGIN;
1364
1365                 InterpolateOrigin_Undo(this);
1366         }
1367
1368         if(sf & ARC_SF_START) // starting location
1369         {
1370                 this.origin_x = ReadCoord();
1371                 this.origin_y = ReadCoord();
1372                 this.origin_z = ReadCoord();
1373         }
1374         else if(this.beam_usevieworigin) // infer the location from player location
1375         {
1376                 if(this.beam_usevieworigin == 2)
1377                 {
1378                         // use view origin
1379                         this.origin = view_origin;
1380                 }
1381                 else
1382                 {
1383                         // use player origin so that third person display still works
1384                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1385                 }
1386         }
1387
1388         setorigin(this, this.origin);
1389
1390         if(sf & ARC_SF_WANTDIR) // want/aim direction
1391         {
1392                 this.v_angle_x = ReadCoord();
1393                 this.v_angle_y = ReadCoord();
1394                 this.v_angle_z = ReadCoord();
1395         }
1396
1397         if(sf & ARC_SF_BEAMDIR) // beam direction
1398         {
1399                 this.angles_x = ReadCoord();
1400                 this.angles_y = ReadCoord();
1401                 this.angles_z = ReadCoord();
1402         }
1403
1404         if(sf & ARC_SF_BEAMTYPE) // beam type
1405         {
1406                 this.beam_type = ReadByte();
1407
1408                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1409                 switch(this.beam_type)
1410                 {
1411                         case ARC_BT_MISS:
1412                         {
1413                                 this.beam_color = beamcolor;
1414                                 this.beam_alpha = 0.5;
1415                                 this.beam_thickness = 8;
1416                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1417                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1418                                 this.beam_hitlight[0] = 0;
1419                                 this.beam_hitlight[1] = 1;
1420                                 this.beam_hitlight[2] = 1;
1421                                 this.beam_hitlight[3] = 1;
1422                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1423                                 this.beam_muzzlelight[0] = 0;
1424                                 this.beam_muzzlelight[1] = 1;
1425                                 this.beam_muzzlelight[2] = 1;
1426                                 this.beam_muzzlelight[3] = 1;
1427                                 if(this.beam_muzzleeffect)
1428                                 {
1429                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1430                                         flash.alpha = this.beam_alpha;
1431                                         flash.colormod = this.beam_color;
1432                                         flash.scale = 0.5;
1433                                 }
1434                                 break;
1435                         }
1436                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1437                         {
1438                                 this.beam_color = beamcolor;
1439                                 this.beam_alpha = 0.5;
1440                                 this.beam_thickness = 8;
1441                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1442                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1443                                 this.beam_hitlight[0] = 0;
1444                                 this.beam_hitlight[1] = 1;
1445                                 this.beam_hitlight[2] = 1;
1446                                 this.beam_hitlight[3] = 1;
1447                                 this.beam_muzzleeffect = NULL; // (EFFECT_GRENADE_MUZZLEFLASH);
1448                                 this.beam_muzzlelight[0] = 0;
1449                                 this.beam_muzzlelight[1] = 1;
1450                                 this.beam_muzzlelight[2] = 1;
1451                                 this.beam_muzzlelight[3] = 1;
1452                                 this.beam_image = "particles/lgbeam";
1453                                 if(this.beam_muzzleeffect)
1454                                 {
1455                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1456                                         flash.alpha = this.beam_alpha;
1457                                         flash.colormod = this.beam_color;
1458                                         flash.scale = 0.5;
1459                                 }
1460                                 break;
1461                         }
1462                         case ARC_BT_HEAL:
1463                         {
1464                                 this.beam_color = beamcolor;
1465                                 this.beam_alpha = 0.5;
1466                                 this.beam_thickness = 8;
1467                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1468                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1469                                 this.beam_hitlight[0] = 0;
1470                                 this.beam_hitlight[1] = 1;
1471                                 this.beam_hitlight[2] = 1;
1472                                 this.beam_hitlight[3] = 1;
1473                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1474                                 this.beam_muzzlelight[0] = 0;
1475                                 this.beam_muzzlelight[1] = 1;
1476                                 this.beam_muzzlelight[2] = 1;
1477                                 this.beam_muzzlelight[3] = 1;
1478                                 this.beam_image = "particles/lgbeam";
1479                                 if(this.beam_muzzleeffect)
1480                                 {
1481                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1482                                         flash.alpha = this.beam_alpha;
1483                                         flash.colormod = this.beam_color;
1484                                         flash.scale = 0.5;
1485                                 }
1486                                 break;
1487                         }
1488                         case ARC_BT_HIT:
1489                         {
1490                                 this.beam_color = beamcolor;
1491                                 this.beam_alpha = 0.5;
1492                                 this.beam_thickness = 8;
1493                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1494                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1495                                 this.beam_hitlight[0] = 20;
1496                                 this.beam_hitlight[1] = 1;
1497                                 this.beam_hitlight[2] = 0;
1498                                 this.beam_hitlight[3] = 0;
1499                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1500                                 this.beam_muzzlelight[0] = 50;
1501                                 this.beam_muzzlelight[1] = 1;
1502                                 this.beam_muzzlelight[2] = 0;
1503                                 this.beam_muzzlelight[3] = 0;
1504                                 this.beam_image = "particles/lgbeam";
1505                                 if(this.beam_muzzleeffect)
1506                                 {
1507                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1508                                         flash.alpha = this.beam_alpha;
1509                                         flash.colormod = this.beam_color;
1510                                         flash.scale = 0.5;
1511                                 }
1512                                 break;
1513                         }
1514                         case ARC_BT_BURST_MISS:
1515                         {
1516                                 this.beam_color = beamcolor;
1517                                 this.beam_alpha = 0.5;
1518                                 this.beam_thickness = 14;
1519                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1520                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1521                                 this.beam_hitlight[0] = 0;
1522                                 this.beam_hitlight[1] = 1;
1523                                 this.beam_hitlight[2] = 1;
1524                                 this.beam_hitlight[3] = 1;
1525                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1526                                 this.beam_muzzlelight[0] = 0;
1527                                 this.beam_muzzlelight[1] = 1;
1528                                 this.beam_muzzlelight[2] = 1;
1529                                 this.beam_muzzlelight[3] = 1;
1530                                 this.beam_image = "particles/lgbeam";
1531                                 if(this.beam_muzzleeffect)
1532                                 {
1533                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1534                                         flash.alpha = this.beam_alpha;
1535                                         flash.colormod = this.beam_color;
1536                                         flash.scale = 0.5;
1537                                 }
1538                                 break;
1539                         }
1540                         case ARC_BT_BURST_WALL:
1541                         {
1542                                 this.beam_color = beamcolor;
1543                                 this.beam_alpha = 0.5;
1544                                 this.beam_thickness = 14;
1545                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1546                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1547                                 this.beam_hitlight[0] = 0;
1548                                 this.beam_hitlight[1] = 1;
1549                                 this.beam_hitlight[2] = 1;
1550                                 this.beam_hitlight[3] = 1;
1551                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1552                                 this.beam_muzzlelight[0] = 0;
1553                                 this.beam_muzzlelight[1] = 1;
1554                                 this.beam_muzzlelight[2] = 1;
1555                                 this.beam_muzzlelight[3] = 1;
1556                                 this.beam_image = "particles/lgbeam";
1557                                 if(this.beam_muzzleeffect)
1558                                 {
1559                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1560                                         flash.alpha = this.beam_alpha;
1561                                         flash.colormod = this.beam_color;
1562                                         flash.scale = 0.5;
1563                                 }
1564                                 break;
1565                         }
1566                         case ARC_BT_BURST_HEAL:
1567                         {
1568                                 this.beam_color = beamcolor;
1569                                 this.beam_alpha = 0.5;
1570                                 this.beam_thickness = 14;
1571                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1572                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1573                                 this.beam_hitlight[0] = 0;
1574                                 this.beam_hitlight[1] = 1;
1575                                 this.beam_hitlight[2] = 1;
1576                                 this.beam_hitlight[3] = 1;
1577                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1578                                 this.beam_muzzlelight[0] = 0;
1579                                 this.beam_muzzlelight[1] = 1;
1580                                 this.beam_muzzlelight[2] = 1;
1581                                 this.beam_muzzlelight[3] = 1;
1582                                 this.beam_image = "particles/lgbeam";
1583                                 if(this.beam_muzzleeffect)
1584                                 {
1585                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1586                                         flash.alpha = this.beam_alpha;
1587                                         flash.colormod = this.beam_color;
1588                                         flash.scale = 0.5;
1589                                 }
1590                                 break;
1591                         }
1592                         case ARC_BT_BURST_HIT:
1593                         {
1594                                 this.beam_color = beamcolor;
1595                                 this.beam_alpha = 0.5;
1596                                 this.beam_thickness = 14;
1597                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1598                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1599                                 this.beam_hitlight[0] = 0;
1600                                 this.beam_hitlight[1] = 1;
1601                                 this.beam_hitlight[2] = 1;
1602                                 this.beam_hitlight[3] = 1;
1603                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1604                                 this.beam_muzzlelight[0] = 0;
1605                                 this.beam_muzzlelight[1] = 1;
1606                                 this.beam_muzzlelight[2] = 1;
1607                                 this.beam_muzzlelight[3] = 1;
1608                                 this.beam_image = "particles/lgbeam";
1609                                 if(this.beam_muzzleeffect)
1610                                 {
1611                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1612                                         flash.alpha = this.beam_alpha;
1613                                         flash.colormod = this.beam_color;
1614                                         flash.scale = 0.5;
1615                                 }
1616                                 break;
1617                         }
1618
1619                         // shouldn't be possible, but lets make it colorful if it does :D
1620                         default:
1621                         {
1622                                 this.beam_color = randomvec();
1623                                 this.beam_alpha = 1;
1624                                 this.beam_thickness = 8;
1625                                 this.beam_traileffect = NULL;
1626                                 this.beam_hiteffect = NULL;
1627                                 this.beam_hitlight[0] = 0;
1628                                 this.beam_hitlight[1] = 1;
1629                                 this.beam_hitlight[2] = 1;
1630                                 this.beam_hitlight[3] = 1;
1631                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1632                                 this.beam_muzzlelight[0] = 0;
1633                                 this.beam_muzzlelight[1] = 1;
1634                                 this.beam_muzzlelight[2] = 1;
1635                                 this.beam_muzzlelight[3] = 1;
1636                                 this.beam_image = "particles/lgbeam";
1637                                 if(this.beam_muzzleeffect)
1638                                 {
1639                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1640                                         flash.alpha = this.beam_alpha;
1641                                         flash.colormod = this.beam_color;
1642                                         flash.scale = 0.5;
1643                                 }
1644                                 break;
1645                         }
1646                 }
1647         }
1648
1649         if(!this.beam_usevieworigin)
1650         {
1651                 InterpolateOrigin_Note(this);
1652         }
1653         return true;
1654 }
1655
1656 #endif
1657 #endif