qcsrc/common/weapons/weapon/rifle.qc

   1 #include "rifle.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Rifle, Weapon)
   4 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails);
   5 /* impulse   */ ATTRIB(Rifle, impulse, int, 7);
   6 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   7 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   8 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
   9 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
  14 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
  15 /* reticle   */ ATTRIB(Rifle, w_reticle, string, "gfx/reticle_nex");
  16 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
  17 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
  18 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
  19
  20 #define X(BEGIN, P, END, class, prefix) \
  21         BEGIN(class) \
  22                 P(class, prefix, ammo, float, BOTH) \
  23                 P(class, prefix, animtime, float, BOTH) \
  24                 P(class, prefix, bullethail, float, BOTH) \
  25                 P(class, prefix, burstcost, float, BOTH) \
  26                 P(class, prefix, bursttime, float, NONE) \
  27                 P(class, prefix, damage, float, BOTH) \
  28                 P(class, prefix, force, float, BOTH) \
  29                 P(class, prefix, refire, float, BOTH) \
  30                 P(class, prefix, reload, float, SEC) \
  31                 P(class, prefix, reload_ammo, float, NONE) \
  32         P(class, prefix, reload_time, float, NONE) \
  33                 P(class, prefix, secondary, float, NONE) \
  34                 P(class, prefix, shots, float, BOTH) \
  35                 P(class, prefix, solidpenetration, float, BOTH) \
  36                 P(class, prefix, spread, float, BOTH) \
  37         P(class, prefix, switchdelay_drop, float, NONE) \
  38         P(class, prefix, switchdelay_raise, float, NONE) \
  39                 P(class, prefix, tracer, float, BOTH) \
  40         P(class, prefix, weaponreplace, string, NONE) \
  41         P(class, prefix, weaponstartoverride, float, NONE) \
  42         P(class, prefix, weaponstart, float, NONE) \
  43         P(class, prefix, weaponthrowable, float, NONE) \
  44         END()
  45     W_PROPS(X, Rifle, rifle)
  46 #undef X
  47 ENDCLASS(Rifle)
  48 REGISTER_WEAPON(RIFLE, rifle, NEW(Rifle));
  49
  50
  51 #ifdef SVQC
  52 .float rifle_accumulator;
  53 #endif
  54 #endif
  55 #ifdef IMPLEMENTATION
  56 #ifdef SVQC
  57 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
  58 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
  59 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
  60
  61 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
  62 {
  63         float i;
  64
  65         W_DecreaseAmmo(thiswep, actor, pAmmo, weaponentity);
  66
  67         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  68
  69         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  70
  71         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
  72         {
  73                 w_shotdir = v_forward;
  74                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
  75         }
  76
  77         for(i = 0; i < pShots; ++i)
  78                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  79
  80         if(autocvar_g_casings >= 2)
  81     {
  82         makevectors(actor.v_angle); // for some reason, this is lost
  83                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  84     }
  85 }
  86
  87 void W_Rifle_Attack(entity actor, .entity weaponentity)
  88 {
  89         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
  90 }
  91
  92 void W_Rifle_Attack2(entity actor, .entity weaponentity)
  93 {
  94         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
  95 }
  96
  97 .void(entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
  98 .WFRAME rifle_bullethail_frame;
  99 .float rifle_bullethail_animtime;
 100 .float rifle_bullethail_refire;
 101 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 102 {
 103         float r, af;
 104
 105         Weapon sw = actor.(weaponentity).m_switchweapon; // make it not detect weapon changes as reason to abort firing
 106         int slot = weaponslot(weaponentity);
 107         af = ATTACK_FINISHED(actor, slot);
 108         actor.(weaponentity).m_switchweapon = actor.(weaponentity).m_weapon;
 109         ATTACK_FINISHED(actor, slot) = time;
 110         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
 111         if(actor.(weaponentity).m_switchweapon == actor.(weaponentity).m_weapon)
 112                 actor.(weaponentity).m_switchweapon = sw;
 113         if(r)
 114         {
 115                 actor.rifle_bullethail_attackfunc(actor, weaponentity);
 116                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 117         }
 118         else
 119         {
 120                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 121         }
 122 }
 123
 124 void W_Rifle_BulletHail(entity actor, .entity weaponentity, float mode, void(entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
 125 {
 126         // if we get here, we have at least one bullet to fire
 127         AttackFunc(actor, weaponentity);
 128         if(mode)
 129         {
 130                 // continue hail
 131                 actor.rifle_bullethail_attackfunc = AttackFunc;
 132                 actor.rifle_bullethail_frame = fr;
 133                 actor.rifle_bullethail_animtime = animtime;
 134                 actor.rifle_bullethail_refire = refire;
 135                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
 136         }
 137         else
 138         {
 139                 // just one shot
 140                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
 141         }
 142 }
 143
 144 .float bot_secondary_riflemooth;
 145
 146 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 147 {
 148     PHYS_INPUT_BUTTON_ATCK(actor) = false;
 149     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 150     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
 151         actor.bot_secondary_riflemooth = 0;
 152     if(actor.bot_secondary_riflemooth == 0)
 153     {
 154         if(bot_aim(actor, 1000000, 0, 0.001, false))
 155         {
 156             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 157             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
 158         }
 159     }
 160     else
 161     {
 162         if(bot_aim(actor, 1000000, 0, 0.001, false))
 163         {
 164             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 165             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
 166         }
 167     }
 168 }
 169 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 170 {
 171     if(autocvar_g_balance_rifle_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 172         thiswep.wr_reload(thiswep, actor, weaponentity);
 173     } else
 174     {
 175         actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
 176         if(fire & 1)
 177         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 178         if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 179         {
 180             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 181             W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 182             actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 183         }
 184         if(fire & 2)
 185         {
 186             if(WEP_CVAR(rifle, secondary))
 187             {
 188                 if(WEP_CVAR_SEC(rifle, reload)) {
 189                     thiswep.wr_reload(thiswep, actor, weaponentity);
 190                 } else
 191                 {
 192                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 193                     if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 194                     {
 195                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 196                         W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 197                         actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 198                     }
 199                 }
 200             }
 201         }
 202     }
 203 }
 204 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 205 {
 206     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(rifle, ammo);
 207     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 208     return ammo_amount;
 209 }
 210 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 211 {
 212     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(rifle, ammo);
 213     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 214     return ammo_amount;
 215 }
 216 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
 217 {
 218     actor.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 219 }
 220 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 221 {
 222     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
 223 }
 224 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 225 {
 226     return WEAPON_THINKING_WITH_PORTALS;
 227 }
 228 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 229 {
 230     if(w_deathtype & HITTYPE_SECONDARY)
 231     {
 232         if(w_deathtype & HITTYPE_BOUNCE)
 233             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 234         else
 235             return WEAPON_RIFLE_MURDER_HAIL;
 236     }
 237     else
 238     {
 239         if(w_deathtype & HITTYPE_BOUNCE)
 240             return WEAPON_RIFLE_MURDER_PIERCING;
 241         else
 242             return WEAPON_RIFLE_MURDER;
 243     }
 244 }
 245 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 246 {
 247     return PHYS_INPUT_BUTTON_ATCK2(actor) && WEP_CVAR(rifle, secondary) == 0;
 248 }
 249
 250 #endif
 251 #ifdef CSQC
 252
 253 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
 254 {
 255     vector org2;
 256     org2 = w_org + w_backoff * 2;
 257     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 258     if(!w_issilent)
 259     {
 260         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 261     }
 262 }
 263 METHOD(Rifle, wr_init, void(entity thiswep))
 264 {
 265     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 266     {
 267         precache_pic("gfx/reticle_nex");
 268     }
 269 }
 270 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 271 {
 272     if(button_zoom || zoomscript_caught)
 273     {
 274         return true;
 275     }
 276     else
 277     {
 278         // no weapon specific image for this weapon
 279         return false;
 280     }
 281 }
 282
 283 #endif
 284 #endif