qcsrc/common/weapons/weapon/rifle.qc

   1 #include "rifle.qh"
   2
   3 #ifdef SVQC
   4 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
   5 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
   6 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
   7
   8 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
   9 {
  10         float i;
  11
  12         W_DecreaseAmmo(thiswep, actor, pAmmo, weaponentity);
  13
  14         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  15
  16         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  17
  18         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
  19         {
  20                 w_shotdir = v_forward;
  21                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
  22         }
  23
  24         for(i = 0; i < pShots; ++i)
  25                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  26
  27         if(autocvar_g_casings >= 2)
  28     {
  29         makevectors(actor.v_angle); // for some reason, this is lost
  30                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  31     }
  32 }
  33
  34 void W_Rifle_Attack(entity actor, .entity weaponentity)
  35 {
  36         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
  37 }
  38
  39 void W_Rifle_Attack2(entity actor, .entity weaponentity)
  40 {
  41         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
  42 }
  43
  44 .void(entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
  45 .WFRAME rifle_bullethail_frame;
  46 .float rifle_bullethail_animtime;
  47 .float rifle_bullethail_refire;
  48 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  49 {
  50         float r, af;
  51
  52         Weapon sw = actor.(weaponentity).m_switchweapon; // make it not detect weapon changes as reason to abort firing
  53         int slot = weaponslot(weaponentity);
  54         af = ATTACK_FINISHED(actor, slot);
  55         actor.(weaponentity).m_switchweapon = actor.(weaponentity).m_weapon;
  56         ATTACK_FINISHED(actor, slot) = time;
  57         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
  58         if(actor.(weaponentity).m_switchweapon == actor.(weaponentity).m_weapon)
  59                 actor.(weaponentity).m_switchweapon = sw;
  60         if(r)
  61         {
  62                 actor.rifle_bullethail_attackfunc(actor, weaponentity);
  63                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
  64         }
  65         else
  66         {
  67                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
  68         }
  69 }
  70
  71 void W_Rifle_BulletHail(entity actor, .entity weaponentity, float mode, void(entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
  72 {
  73         // if we get here, we have at least one bullet to fire
  74         AttackFunc(actor, weaponentity);
  75         if(mode)
  76         {
  77                 // continue hail
  78                 actor.rifle_bullethail_attackfunc = AttackFunc;
  79                 actor.rifle_bullethail_frame = fr;
  80                 actor.rifle_bullethail_animtime = animtime;
  81                 actor.rifle_bullethail_refire = refire;
  82                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
  83         }
  84         else
  85         {
  86                 // just one shot
  87                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
  88         }
  89 }
  90
  91 .float bot_secondary_riflemooth;
  92
  93 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  94 {
  95     PHYS_INPUT_BUTTON_ATCK(actor) = false;
  96     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
  97     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
  98         actor.bot_secondary_riflemooth = 0;
  99     if(actor.bot_secondary_riflemooth == 0)
 100     {
 101         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
 102         {
 103             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 104             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
 105         }
 106     }
 107     else
 108     {
 109         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
 110         {
 111             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 112             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
 113         }
 114     }
 115 }
 116 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 117 {
 118     if(autocvar_g_balance_rifle_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 119         thiswep.wr_reload(thiswep, actor, weaponentity);
 120     } else
 121     {
 122         actor.(weaponentity).rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.(weaponentity).rifle_accumulator, time);
 123         if(fire & 1)
 124         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 125         if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 126         {
 127             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 128             W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 129             actor.(weaponentity).rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 130         }
 131         if(fire & 2)
 132         {
 133             if(WEP_CVAR(rifle, secondary))
 134             {
 135                 if(WEP_CVAR_SEC(rifle, reload)) {
 136                     thiswep.wr_reload(thiswep, actor, weaponentity);
 137                 } else
 138                 {
 139                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 140                     if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 141                     {
 142                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 143                         W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 144                         actor.(weaponentity).rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 145                     }
 146                 }
 147             }
 148         }
 149     }
 150 }
 151 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 152 {
 153     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(rifle, ammo);
 154     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 155     return ammo_amount;
 156 }
 157 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 158 {
 159     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(rifle, ammo);
 160     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 161     return ammo_amount;
 162 }
 163 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
 164 {
 165     actor.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 166 }
 167 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 168 {
 169     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
 170 }
 171 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 172 {
 173     return WEAPON_THINKING_WITH_PORTALS;
 174 }
 175 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 176 {
 177     if(w_deathtype & HITTYPE_SECONDARY)
 178     {
 179         if(w_deathtype & HITTYPE_BOUNCE)
 180             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 181         else
 182             return WEAPON_RIFLE_MURDER_HAIL;
 183     }
 184     else
 185     {
 186         if(w_deathtype & HITTYPE_BOUNCE)
 187             return WEAPON_RIFLE_MURDER_PIERCING;
 188         else
 189             return WEAPON_RIFLE_MURDER;
 190     }
 191 }
 192 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 193 {
 194     return PHYS_INPUT_BUTTON_ATCK2(actor) && WEP_CVAR(rifle, secondary) == 0;
 195 }
 196
 197 #endif
 198 #ifdef CSQC
 199
 200 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
 201 {
 202     vector org2;
 203     org2 = w_org + w_backoff * 2;
 204     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 205     if(!w_issilent)
 206     {
 207         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 208     }
 209 }
 210 METHOD(Rifle, wr_init, void(entity thiswep))
 211 {
 212     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 213     {
 214         precache_pic("gfx/reticle_nex");
 215     }
 216 }
 217 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 218 {
 219     if(button_zoom || zoomscript_caught)
 220     {
 221         return true;
 222     }
 223     else
 224     {
 225         // no weapon specific image for this weapon
 226         return false;
 227     }
 228 }
 229
 230 #endif