qcsrc/common/weapons/weapon/seeker.qc

   1 #include "seeker.qh"
   2
   3 #ifdef SVQC
   4
   5 // ============================
   6 // Begin: Missile functions, these are general functions to be manipulated by other code
   7 // ============================
   8 void W_Seeker_Missile_Explode(entity this, entity directhitentity)
   9 {
  10         this.event_damage = func_null;
  11         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), NULL, NULL, WEP_CVAR(seeker, missile_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  12
  13         delete(this);
  14 }
  15
  16 void W_Seeker_Missile_Explode_think(entity this)
  17 {
  18         W_Seeker_Missile_Explode(this, NULL);
  19 }
  20
  21 void W_Seeker_Missile_Touch(entity this, entity toucher)
  22 {
  23         PROJECTILE_TOUCH(this, toucher);
  24
  25         W_Seeker_Missile_Explode(this, toucher);
  26 }
  27
  28 void W_Seeker_Missile_Think(entity this)
  29 {
  30         entity e;
  31         vector desireddir, olddir, newdir, eorg;
  32         float turnrate;
  33         float dist;
  34         float spd;
  35
  36         if(time > this.cnt)
  37         {
  38                 this.projectiledeathtype |= HITTYPE_SPLASH;
  39                 W_Seeker_Missile_Explode(this, NULL);
  40         }
  41
  42         spd = vlen(this.velocity);
  43         spd = bound(
  44                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
  45                 WEP_CVAR(seeker, missile_speed_max),
  46                 spd + WEP_CVAR(seeker, missile_accel) * frametime
  47         );
  48
  49         if(this.enemy != NULL)
  50                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
  51                         this.enemy = NULL;
  52
  53         if(this.enemy != NULL)
  54         {
  55                 e               = this.enemy;
  56                 eorg            = 0.5 * (e.absmin + e.absmax);
  57                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
  58                 desireddir      = normalize(eorg - this.origin);
  59                 olddir          = normalize(this.velocity); // get my current direction
  60                 dist            = vlen(eorg - this.origin);
  61
  62                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
  63                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
  64                 {
  65                         // Is it a better idea (shorter distance) to trace to the target itself?
  66                         if( vdist(this.origin + olddir * this.wait, <, dist))
  67                                 traceline(this.origin, this.origin + olddir * this.wait, false, this);
  68                         else
  69                                 traceline(this.origin, eorg, false, this);
  70
  71                         // Setup adaptive tracelength
  72                         this.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(this.origin - trace_endpos), this.wait = WEP_CVAR(seeker, missile_smart_trace_max));
  73
  74                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
  75                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
  76                 }
  77
  78                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
  79                 this.velocity = newdir * spd; // make me fly in the new direction at my flight speed
  80         }
  81         else
  82                 dist = 0;
  83
  84         // Proxy
  85         if(WEP_CVAR(seeker, missile_proxy))
  86         {
  87                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
  88                 {
  89                         if(this.autoswitch == 0)
  90                         {
  91                                 this.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
  92                         }
  93                         else
  94                         {
  95                                 if(this.autoswitch <= time)
  96                                 {
  97                                         W_Seeker_Missile_Explode(this, NULL);
  98                                         this.autoswitch = 0;
  99                                 }
 100                         }
 101                 }
 102                 else
 103                 {
 104                         if(this.autoswitch != 0)
 105                                 this.autoswitch = 0;
 106                 }
 107         }
 108         ///////////////
 109
 110         if(IS_DEAD(this.enemy))
 111         {
 112                 this.enemy = NULL;
 113                 this.cnt = time + 1 + (random() * 4);
 114                 this.nextthink = this.cnt;
 115                 return;
 116         }
 117
 118         //this.angles = vectoangles(this.velocity);                     // turn model in the new flight direction
 119         this.nextthink = time;// + 0.05; // csqc projectiles
 120         UpdateCSQCProjectile(this);
 121 }
 122
 123
 124
 125 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 126 {
 127         if(this.health <= 0)
 128                 return;
 129
 130         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 131                 return; // g_projectiles_damage says to halt
 132
 133         if(this.realowner == attacker)
 134                 this.health = this.health - (damage * 0.25);
 135         else
 136                 this.health = this.health - damage;
 137
 138         if(this.health <= 0)
 139                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
 140 }
 141
 142 /*
 143 void W_Seeker_Missile_Animate(entity this)
 144 {
 145         this.frame = this.frame +1;
 146         this.nextthink = time + 0.05;
 147
 148         if(this.enemy != NULL)
 149                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 150                         this.enemy = NULL;
 151
 152         if(this.frame == 5)
 153         {
 154                 this.think           = W_Seeker_Missile_Think;
 155                 this.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 156
 157                 if(autocvar_g_balance_seeker_missile_proxy)
 158                         this.move_movetype    = MOVETYPE_BOUNCEMISSILE;
 159                 else
 160                         this.move_movetype    = MOVETYPE_FLYMISSILE;
 161         }
 162
 163         UpdateCSQCProjectile(this);
 164 }
 165 */
 166
 167 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, .entity weaponentity, vector f_diff, entity m_target)
 168 {
 169         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, missile_ammo), weaponentity);
 170
 171         makevectors(actor.v_angle);
 172         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
 173         w_shotorg += f_diff;
 174         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 175
 176         //actor.detornator         = false;
 177
 178         entity missile                 = new(seeker_missile);
 179         missile.owner           = missile.realowner = actor;
 180         missile.bot_dodge       = true;
 181         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 182
 183         setthink(missile, W_Seeker_Missile_Think);
 184         settouch(missile, W_Seeker_Missile_Touch);
 185         missile.event_damage    = W_Seeker_Missile_Damage;
 186         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 187         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 188         missile.enemy           = m_target;
 189         missile.solid           = SOLID_BBOX;
 190         missile.scale           = 2;
 191         missile.takedamage      = DAMAGE_YES;
 192         missile.weaponentity_fld = weaponentity;
 193         missile.health          = WEP_CVAR(seeker, missile_health);
 194         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 195         missile.damagedbycontents = true;
 196         IL_PUSH(g_damagedbycontents, missile);
 197         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 198
 199         if(missile.enemy != NULL)
 200                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 201         else
 202                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 203
 204
 205         setorigin(missile, w_shotorg);
 206         setsize(missile, '-4 -4 -4', '4 4 4');
 207         set_movetype(missile, MOVETYPE_FLYMISSILE);
 208         missile.flags = FL_PROJECTILE;
 209         IL_PUSH(g_projectiles, missile);
 210         IL_PUSH(g_bot_dodge, missile);
 211         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 212
 213         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 214
 215         missile.angles = vectoangles(missile.velocity);
 216
 217         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 218
 219         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 220 }
 221
 222 // ============================
 223 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 224 // ============================
 225 void W_Seeker_Flac_Explode(entity this, entity directhitentity)
 226 {
 227         this.event_damage = func_null;
 228
 229         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), NULL, NULL, WEP_CVAR(seeker, flac_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
 230
 231         delete(this);
 232 }
 233
 234 void W_Seeker_Flac_Touch(entity this, entity toucher)
 235 {
 236         W_Seeker_Flac_Explode(this, toucher);
 237 }
 238
 239 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 240 {
 241         W_Seeker_Flac_Explode(this, trigger);
 242 }
 243
 244 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor, .entity weaponentity)
 245 {
 246         entity missile;
 247         vector f_diff;
 248         float c;
 249
 250         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, flac_ammo), weaponentity);
 251
 252         c = actor.(weaponentity).bulletcounter % 4;
 253         switch(c)
 254         {
 255                 case 0:
 256                         f_diff = '-1.25 -3.75 0';
 257                         break;
 258                 case 1:
 259                         f_diff = '+1.25 -3.75 0';
 260                         break;
 261                 case 2:
 262                         f_diff = '-1.25 +3.75 0';
 263                         break;
 264                 case 3:
 265                 default:
 266                         f_diff = '+1.25 +3.75 0';
 267                         break;
 268         }
 269         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 270         w_shotorg += f_diff;
 271
 272         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 273
 274         missile                                 = new(missile);
 275         missile.owner                   = missile.realowner = actor;
 276         missile.bot_dodge               = true;
 277         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 278         settouch(missile, W_Seeker_Flac_Touch);
 279         missile.use                     = W_Seeker_Flac_Explode_use;
 280         setthink(missile, adaptor_think2use_hittype_splash);
 281         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 282         missile.solid                   = SOLID_BBOX;
 283         set_movetype(missile, MOVETYPE_FLY);
 284         missile.projectiledeathtype = WEP_SEEKER.m_id;
 285         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 286         missile.weaponentity_fld = weaponentity;
 287         missile.flags = FL_PROJECTILE;
 288         IL_PUSH(g_projectiles, missile);
 289         IL_PUSH(g_bot_dodge, missile);
 290         missile.missile_flags       = MIF_SPLASH;
 291
 292         // csqc projectiles
 293         //missile.angles                                = vectoangles(missile.velocity);
 294         //missile.scale = 0.4; // BUG: the model is too big
 295
 296         setorigin(missile, w_shotorg);
 297         setsize(missile, '-2 -2 -2', '2 2 2');
 298
 299         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 300         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 301
 302         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 303 }
 304
 305 // ============================
 306 // Begin: Tag and rocket controllers
 307 // ============================
 308 entity W_Seeker_Tagged_Info(entity isowner, .entity weaponentity, entity istarget)
 309 {
 310         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == isowner,
 311         {
 312                 if(it.tag_target == istarget && it.weaponentity_fld == weaponentity)
 313                         return it;
 314         });
 315
 316         return NULL;
 317 }
 318
 319 void W_Seeker_Attack(entity actor, .entity weaponentity)
 320 {
 321         entity closest_target = NULL;
 322
 323         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == actor,
 324         {
 325                 if(closest_target)
 326                 {
 327                         if(vlen2(actor.origin - it.tag_target.origin) < vlen2(actor.origin - closest_target.origin))
 328                                 closest_target = it.tag_target;
 329                 }
 330                 else
 331                         closest_target = it.tag_target;
 332         });
 333
 334         if(closest_target)
 335         {
 336                 traceline(actor.origin + actor.view_ofs, closest_target.origin, MOVE_NOMONSTERS, actor);
 337                 if(!closest_target || (trace_fraction < 1 && trace_ent != closest_target))
 338                         closest_target = NULL;
 339         }
 340
 341         W_Seeker_Fire_Missile(WEP_SEEKER, actor, weaponentity, '0 0 0', closest_target);
 342 }
 343
 344 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 345 {
 346         float c;
 347         entity oldenemy;
 348         this.cnt = this.cnt - 1;
 349
 350         Weapon thiswep = WEP_SEEKER;
 351         .entity weaponentity = this.weaponentity_fld;
 352         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && GetResourceAmount(this.realowner, thiswep.ammo_type) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER))
 353         {
 354                 delete(this);
 355                 return;
 356         }
 357
 358         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor(this.realowner);
 359
 360         entity own = this.realowner;
 361
 362         oldenemy = own.enemy;
 363         own.enemy = this.enemy;
 364
 365         c = own.cnt % 4;
 366         switch(c)
 367         {
 368                 case 0:
 369                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 -3.75 0', own.enemy); // TODO
 370                         break;
 371                 case 1:
 372                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 -3.75 0', own.enemy); // TODO
 373                         break;
 374                 case 2:
 375                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 +3.75 0', own.enemy); // TODO
 376                         break;
 377                 case 3:
 378                 default:
 379                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 +3.75 0', own.enemy); // TODO
 380                         break;
 381         }
 382
 383         own.enemy = oldenemy;
 384 }
 385
 386 void W_Seeker_Tracker_Think(entity this)
 387 {
 388         .entity weaponentity = this.weaponentity_fld;
 389         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 390         if((IS_DEAD(this.realowner)) || (IS_DEAD(this.tag_target)) || (this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER)
 391         || (time > this.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 392         {
 393                 if(this)
 394                 {
 395                         WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
 396                         delete(this);
 397                 }
 398                 return;
 399         }
 400
 401         // Update the think method information
 402         this.nextthink = time;
 403 }
 404
 405 // ============================
 406 // Begin: Tag projectile
 407 // ============================
 408 void W_Seeker_Tag_Explode(entity this)
 409 {
 410         //if(other==this.realowner)
 411         //    return;
 412         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 413
 414         delete(this);
 415 }
 416
 417 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 418 {
 419         if(this.health <= 0)
 420                 return;
 421         this.health = this.health - damage;
 422         if(this.health <= 0)
 423                 W_Seeker_Tag_Explode(this);
 424 }
 425
 426 void W_Seeker_Tag_Touch(entity this, entity toucher)
 427 {
 428         vector dir;
 429         vector org2;
 430         entity e;
 431
 432         PROJECTILE_TOUCH(this, toucher);
 433
 434         dir     = normalize(this.realowner.origin - this.origin);
 435         org2    = findbetterlocation(this.origin, 8);
 436
 437         te_knightspike(org2);
 438
 439         this.event_damage = func_null;
 440         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 441
 442         if(toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
 443         {
 444                 // check to see if this person is already tagged by me
 445                 .entity weaponentity = this.weaponentity_fld;
 446                 entity tag = W_Seeker_Tagged_Info(this.realowner, weaponentity, toucher);
 447
 448                 if(tag != NULL)
 449                 {
 450                         if(toucher.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 451                                 WaypointSprite_Kill(toucher.wps_tag_tracker);
 452
 453                         tag.tag_time = time;
 454                 }
 455                 else
 456                 {
 457                         //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
 458                         e             = new(tag_tracker);
 459                         e.weaponentity_fld = this.weaponentity_fld;
 460                         e.cnt         = WEP_CVAR(seeker, missile_count);
 461                         e.owner       = this.owner;
 462                         e.realowner   = this.realowner;
 463                         IL_PUSH(g_seeker_trackers, e);
 464
 465                         if(WEP_CVAR(seeker, type) == 1)
 466                         {
 467                                 e.tag_target  = toucher;
 468                                 e.tag_time    = time;
 469                                 setthink(e, W_Seeker_Tracker_Think);
 470                         }
 471                         else
 472                         {
 473                                 e.enemy     = toucher;
 474                                 setthink(e, W_Seeker_Vollycontroller_Think);
 475                         }
 476
 477                         e.nextthink   = time;
 478                 }
 479
 480                 if(WEP_CVAR(seeker, type) == 1)
 481                 {
 482                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
 483                         WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 484                 }
 485         }
 486
 487         delete(this);
 488         return;
 489 }
 490
 491 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor, .entity weaponentity)
 492 {
 493         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, tag_ammo), weaponentity);
 494
 495         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 496
 497         entity missile          = new(seeker_tag);
 498         missile.weaponentity_fld = weaponentity;
 499         missile.owner           = missile.realowner = actor;
 500         missile.bot_dodge       = true;
 501         missile.bot_dodgerating = 50;
 502         settouch(missile, W_Seeker_Tag_Touch);
 503         setthink(missile, SUB_Remove);
 504         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 505         set_movetype(missile, MOVETYPE_FLY);
 506         missile.solid           = SOLID_BBOX;
 507
 508         missile.takedamage       = DAMAGE_YES;
 509         missile.event_damage     = W_Seeker_Tag_Damage;
 510         missile.health           = WEP_CVAR(seeker, tag_health);
 511         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 512
 513         setorigin(missile, w_shotorg);
 514         setsize(missile, '-2 -2 -2', '2 2 2');
 515
 516         missile.flags = FL_PROJECTILE;
 517         IL_PUSH(g_projectiles, missile);
 518         IL_PUSH(g_bot_dodge, missile);
 519         //missile.missile_flags = MIF_..?;
 520
 521         set_movetype(missile, MOVETYPE_FLY);
 522         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 523         missile.angles = vectoangles(missile.velocity);
 524
 525         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 526
 527         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 528 }
 529
 530 // ============================
 531 // Begin: Genereal weapon functions
 532 // ============================
 533
 534 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 535 {
 536     if(WEP_CVAR(seeker, type) == 1)
 537         if(W_Seeker_Tagged_Info(actor, weaponentity, actor.enemy) != NULL)
 538             PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 539         else
 540             PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 541     else
 542         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 543 }
 544 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 545 {
 546     if(autocvar_g_balance_seeker_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 547         thiswep.wr_reload(thiswep, actor, weaponentity);
 548     } else if(fire & 1)
 549     {
 550         if(WEP_CVAR(seeker, type) == 1)
 551         {
 552             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 553             {
 554                 W_Seeker_Attack(actor, weaponentity);
 555                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 556             }
 557         }
 558         else
 559         {
 560             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 561             {
 562                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 563                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 564             }
 565         }
 566     }
 567
 568     else if(fire & 2)
 569     {
 570         if(WEP_CVAR(seeker, type) == 1)
 571         {
 572             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 573             {
 574                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 575                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 576             }
 577         }
 578         else
 579         {
 580             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 581             {
 582                 W_Seeker_Fire_Flac(thiswep, actor, weaponentity);
 583                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 584             }
 585         }
 586     }
 587 }
 588 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 589 {
 590     float ammo_amount;
 591     if(WEP_CVAR(seeker, type) == 1)
 592     {
 593         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, missile_ammo);
 594         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 595     }
 596     else
 597     {
 598         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 599         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 600     }
 601     return ammo_amount;
 602 }
 603 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 604 {
 605     float ammo_amount;
 606     if(WEP_CVAR(seeker, type) == 1)
 607     {
 608         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 609         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 610     }
 611     else
 612     {
 613         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, flac_ammo);
 614         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 615     }
 616     return ammo_amount;
 617 }
 618 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 619 {
 620     W_Reload(actor, weaponentity, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 621 }
 622 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 623 {
 624     return WEAPON_SEEKER_SUICIDE;
 625 }
 626 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 627 {
 628     if(w_deathtype & HITTYPE_SECONDARY)
 629         return WEAPON_SEEKER_MURDER_TAG;
 630     else
 631         return WEAPON_SEEKER_MURDER_SPRAY;
 632 }
 633
 634 #endif
 635 #ifdef CSQC
 636
 637 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 638 {
 639     vector org2;
 640     org2 = w_org + w_backoff * 6;
 641     if(w_deathtype & HITTYPE_BOUNCE)
 642     {
 643         if(w_deathtype & HITTYPE_SECONDARY)
 644         {
 645             if(!w_issilent)
 646                 sound(actor, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 647         }
 648         else
 649         {
 650             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 651             if(!w_issilent)
 652             {
 653                 if(w_random<0.15)
 654                     sound(actor, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 655                 else if(w_random<0.7)
 656                     sound(actor, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 657                 else
 658                     sound(actor, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 659             }
 660         }
 661     }
 662     else
 663     {
 664         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 665         if(!w_issilent)
 666         {
 667             if(w_random<0.15)
 668                 sound(actor, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 669             else if(w_random<0.7)
 670                 sound(actor, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 671             else
 672                 sound(actor, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 673         }
 674     }
 675 }
 676
 677 #endif