qcsrc/common/wepent.qc

   1 #include "wepent.qh"
   2
   3 #define WEPENT_SET_NORMAL(var, x) MACRO_BEGIN \
   4         var = x; \
   5 MACRO_END
   6
   7 // #define PROP(public, fld, set, sv, cl)
   8 #define WEPENT_NETPROPS(PROP) PROP(false, sv_entnum, WEPENT_SET_NORMAL, {}, {}) /* sentinel */ \
   9         PROP(false, m_switchweapon, WEPENT_SET_NORMAL, \
  10         { WriteByte(chan, this.m_switchweapon.m_id); }, \
  11         { (viewmodels[this.m_wepent_slot]).switchweapon = Weapons_from(ReadByte()); }) \
  12     \
  13     PROP(false, m_switchingweapon, WEPENT_SET_NORMAL, \
  14         { WriteByte(chan, this.m_switchingweapon.m_id); }, \
  15         { (viewmodels[this.m_wepent_slot]).switchingweapon = Weapons_from(ReadByte()); }) \
  16     \
  17     PROP(false, m_weapon, WEPENT_SET_NORMAL, \
  18         { WriteByte(chan, this.m_weapon.m_id); }, \
  19         { (viewmodels[this.m_wepent_slot]).activeweapon = Weapons_from(ReadByte()); }) \
  20     \
  21     PROP(false, m_alpha, WEPENT_SET_NORMAL, \
  22         { WriteByte(chan, rint(bound(-1, 254 * this.m_alpha, 254) - -1)); }, \
  23         { (viewmodels[this.m_wepent_slot]).alpha = (ReadByte() + -1) / 254; }) \
  24     \
  25     PROP(false, vortex_charge, WEPENT_SET_NORMAL, \
  26         { WriteByte(chan, this.vortex_charge * 16); }, \
  27         { (viewmodels[this.m_wepent_slot]).vortex_charge = ReadByte() / 16; }) \
  28     \
  29     PROP(false, oknex_charge, WEPENT_SET_NORMAL, \
  30         { WriteByte(chan, this.oknex_charge * 16); }, \
  31         { (viewmodels[this.m_wepent_slot]).oknex_charge = ReadByte() / 16; }) \
  32     \
  33     PROP(false, m_gunalign, WEPENT_SET_NORMAL, \
  34         { WriteByte(chan, this.m_gunalign); }, \
  35         { (viewmodels[this.m_wepent_slot]).m_gunalign = ReadByte(); }) \
  36     \
  37     PROP(false, porto_v_angle_held, WEPENT_SET_NORMAL, \
  38         { WriteByte(chan, this.porto_v_angle_held); if(this.porto_v_angle_held) { \
  39                  WriteAngle(chan, this.porto_v_angle.x); WriteAngle(chan, this.porto_v_angle.y); \
  40                 } }, \
  41         { (viewmodels[this.m_wepent_slot]).angles_held_status = ReadByte(); if((viewmodels[this.m_wepent_slot]).angles_held_status) { \
  42                 (viewmodels[this.m_wepent_slot]).angles_held_x = ReadAngle(); (viewmodels[this.m_wepent_slot]).angles_held_y = ReadAngle(); (viewmodels[this.m_wepent_slot]).angles_held_z = 0; } \
  43                 else { (viewmodels[this.m_wepent_slot]).angles_held = '0 0 0'; } }) \
  44     \
  45     PROP(false, tuba_instrument, WEPENT_SET_NORMAL, \
  46         { WriteByte(chan, this.tuba_instrument); }, \
  47         { (viewmodels[this.m_wepent_slot]).tuba_instrument = ReadByte(); }) \
  48     \
  49     PROP(false, hagar_load, WEPENT_SET_NORMAL, \
  50         { WriteByte(chan, this.hagar_load); }, \
  51         { (viewmodels[this.m_wepent_slot]).hagar_load = ReadByte(); }) \
  52     \
  53     PROP(false, minelayer_mines, WEPENT_SET_NORMAL, \
  54         { WriteByte(chan, this.minelayer_mines); }, \
  55         { (viewmodels[this.m_wepent_slot]).minelayer_mines = ReadByte(); }) \
  56     \
  57     PROP(false, arc_heat_percent, WEPENT_SET_NORMAL, \
  58         { WriteByte(chan, this.arc_heat_percent * 16); }, \
  59         { (viewmodels[this.m_wepent_slot]).arc_heat_percent = ReadByte() / 16; }) \
  60     \
  61     PROP(false, vortex_chargepool_ammo, WEPENT_SET_NORMAL, \
  62         { WriteByte(chan, this.vortex_chargepool_ammo * 16); }, \
  63         { (viewmodels[this.m_wepent_slot]).vortex_chargepool_ammo = ReadByte() / 16; }) \
  64     \
  65     PROP(false, clip_load, WEPENT_SET_NORMAL, \
  66         { WriteShort(chan, this.clip_load); }, \
  67         { (viewmodels[this.m_wepent_slot]).clip_load = ReadShort(); }) \
  68     \
  69     PROP(false, clip_size, WEPENT_SET_NORMAL, \
  70         { WriteShort(chan, this.clip_size); }, \
  71         { (viewmodels[this.m_wepent_slot]).clip_size = ReadShort(); }) \
  72     \
  73         /**/
  74
  75 #ifdef SVQC
  76
  77         int WEPENT_PUBLICMASK = 0;
  78         STATIC_INIT(WEPENT_PUBLICMASK)
  79         {
  80                 int i = 0;
  81                 #define X(public, fld, set, sv, cl) { \
  82                         if (public) { \
  83                                 WEPENT_PUBLICMASK |= BIT(i); \
  84                         } \
  85                         i += 1; \
  86                 }
  87                 WEPENT_NETPROPS(X);
  88         #undef X
  89                 if (i >= BITS(16 - 1)) LOG_FATAL("Exceeded WEPENT_NETPROPS limit");
  90         }
  91
  92         bool _wepent_send(entity this, entity to, int sf, int chan)
  93         {
  94                 sf |= this.m_forceupdate;
  95                 this.m_forceupdate = 0;
  96                 if (chan == MSG_ENTITY)
  97                         WriteHeader(chan, ENT_CLIENT_WEPENT);
  98                 else
  99                         WriteHeader(chan, CLIENT_WEPENT);
 100                 .entity weaponentity = this.owner.weaponentity_fld;
 101                 WriteByte(chan, weaponslot(weaponentity));
 102                 WriteShort(chan, sf);
 103                 int i = 0;
 104                 #define X(public, fld, set, sv, cl) { \
 105                         if (sf & BIT(i)) { \
 106                                 sv; \
 107                         } \
 108                         i += 1; \
 109                 }
 110                 WEPENT_NETPROPS(X);
 111         #undef X
 112                 return true;
 113         }
 114
 115         bool wepent_send(entity this, entity to, int sf)
 116         {
 117                 return _wepent_send(this, to, sf, MSG_ENTITY);
 118         }
 119
 120         void wepent_think(entity this)
 121         {
 122                 if(wasfreed(this.owner) || !this.owner)
 123                 {
 124                         delete(this);
 125                         return;
 126                 }
 127
 128                 this.nextthink = time;
 129
 130                 entity o = this.owner;
 131
 132                 int i = 0;
 133                 #define X(public, fld, set, sv, cl) { \
 134                         if (this.fld != o.fld) { \
 135                                 set(this.fld, o.fld); \
 136                                 this.SendFlags |= BIT(i); \
 137                         } \
 138                         i += 1; \
 139                 }
 140                 WEPENT_NETPROPS(X);
 141         #undef X
 142         }
 143
 144         bool wepent_customize(entity this, entity client)
 145         {
 146                 entity e = WaypointSprite_getviewentity(client);
 147                 .entity weaponentity = this.owner.weaponentity_fld;
 148                 return e.(weaponentity) == this.owner;
 149         }
 150
 151         void wepent_link(entity wep)
 152         {
 153                 entity e = new(wepent_sender);
 154                 e.owner = wep;
 155                 setthink(e, wepent_think);
 156                 e.nextthink = time;
 157                 //e.drawonlytoclient = wep.owner;
 158                 setcefc(e, wepent_customize);
 159                 Net_LinkEntity(e, false, 0, wepent_send);
 160         }
 161
 162 #endif
 163
 164 #ifdef CSQC
 165
 166         bool ReadWepent(entity this)
 167         {
 168                 int slot = ReadByte();
 169                 this.m_wepent_slot = slot;
 170                 viewmodels[slot].m_wepent_slot = slot;
 171                 int sf = ReadShort();
 172                 int i = 0;
 173                 #define X(public, fld, set, sv, cl) { \
 174                         if (sf & BIT(i)) { \
 175                                 cl; \
 176                         } \
 177                         i += 1; \
 178                 }
 179                 WEPENT_NETPROPS(X);
 180         #undef X
 181                 return true;
 182         }
 183
 184         NET_HANDLE(ENT_CLIENT_WEPENT, bool isnew)
 185         {
 186                 if (isnew)
 187                         this.classname = "wepent_receiver";
 188                 return ReadWepent(this);
 189         }
 190
 191         NET_HANDLE(CLIENT_WEPENT, bool isnew)
 192         {
 193                 return ReadWepent(NULL);
 194         }
 195
 196 #endif