qcsrc/csqcmodel/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22
  23 // generic CSQC model code
  24
  25 #define CSQCMODEL_IF(cond)
  26 #define CSQCMODEL_ENDIF
  27 #define CSQCMODEL_PROPERTY(flag,r,w,f) \
  28         .float csqcmodel_##f;
  29 #define CSQCMODEL_PROPERTY_SCALED(flag,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,r,w,f)
  30         ALLPROPERTIES
  31 #undef CSQCMODEL_PROPERTY_SCALED
  32 #undef CSQCMODEL_PROPERTY
  33 #undef CSQCMODEL_ENDIF
  34 #undef CSQCMODEL_IF
  35
  36 float CSQCModel_Send(entity to, float sf)
  37 {
  38         // some nice flags for CSQCMODEL_IF
  39         float isplayer = (self.flags & FL_CLIENT);
  40         float islocalplayer = (self == to);
  41         float isnolocalplayer = (isplayer && (self != to));
  42
  43         WriteByte(MSG_ENTITY, ENT_CLIENT_MODEL);
  44         WriteShort(MSG_ENTITY, sf);
  45
  46 #define CSQCMODEL_IF(cond) if(cond) {
  47 #define CSQCMODEL_ENDIF }
  48 #define CSQCMODEL_PROPERTY(flag,r,w,f) \
  49         if(sf & flag) \
  50         { \
  51                 w(MSG_ENTITY, self.csqcmodel_##f); \
  52         }
  53 #define CSQCMODEL_PROPERTY_SCALED(flag,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,r,w,f)
  54         ALLPROPERTIES
  55 #undef CSQCMODEL_PROPERTY_SCALED
  56 #undef CSQCMODEL_PROPERTY
  57 #undef CSQCMODEL_ENDIF
  58 #undef CSQCMODEL_IF
  59
  60         return TRUE;
  61 }
  62
  63 void CSQCModel_CheckUpdate()
  64 {
  65         // some nice flags for CSQCMODEL_IF
  66         float isplayer = (self.flags & FL_CLIENT);
  67         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  68         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  69
  70         float tmp;
  71
  72         if(self.effects & EF_RESTARTANIM_BIT)
  73         {
  74                 self.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  75                 self.effects &~= EF_RESTARTANIM_BIT;
  76         }
  77
  78         if(self.effects & EF_TELEPORT_BIT)
  79         {
  80                 self.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  81                 self.effects &~= EF_TELEPORT_BIT;
  82         }
  83
  84 #define CSQCMODEL_IF(cond) if(cond) {
  85 #define CSQCMODEL_ENDIF }
  86 #define CSQCMODEL_PROPERTY(flag,r,w,f) \
  87         tmp = self.f; \
  88         if(tmp != self.csqcmodel_##f) \
  89         { \
  90                 self.csqcmodel_##f = tmp; \
  91                 self.SendFlags |= flag; \
  92         }
  93 #define CSQCMODEL_PROPERTY_SCALED(flag,r,w,f,s,mi,ma) \
  94         tmp = bound(mi, s * self.f, ma); \
  95         if(tmp != self.csqcmodel_##f) \
  96         { \
  97                 self.csqcmodel_##f = tmp; \
  98                 self.SendFlags |= flag; \
  99         }
 100         ALLPROPERTIES
 101 #undef CSQCMODEL_PROPERTY_SCALED
 102 #undef CSQCMODEL_PROPERTY
 103 #undef CSQCMODEL_ENDIF
 104 #undef CSQCMODEL_IF
 105 }
 106
 107 void CSQCModel_LinkEntity()
 108 {
 109         self.SendEntity = CSQCModel_Send;
 110         self.SendFlags = 0xFFFFFF;
 111 }
 112
 113 void CSQCModel_UnlinkEntity()
 114 {
 115         self.SendEntity = func_null;
 116 }