qcsrc/lib/csqcmodel/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  * Copyright (c) 2015 Micah Talkiewicz
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy
   6  * of this software and associated documentation files (the "Software"), to
   7  * deal in the Software without restriction, including without limitation the
   8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9  * sell copies of the Software, and to permit persons to whom the Software is
  10  * furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  */
  23 #include "cl_player.qh"
  24
  25 #include "cl_model.qh"
  26 #include "common.qh"
  27 #include "interpolate.qh"
  28 #include "../../client/defs.qh"
  29 #include "../../client/main.qh"
  30 #include "../../common/constants.qh"
  31 #include "../../common/physics.qh"
  32 #include "../../common/stats.qh"
  33 #include "../../common/triggers/trigger/viewloc.qh"
  34 #include "../../common/util.qh"
  35 #include "../../common/viewloc.qh"
  36
  37 float autocvar_cl_movement_errorcompensation = 0;
  38
  39 // engine stuff
  40 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  41
  42 vector csqcplayer_origin, csqcplayer_velocity;
  43 float csqcplayer_sequence;
  44 int player_pmflags;
  45 float csqcplayer_moveframe;
  46 vector csqcplayer_predictionerroro;
  47 vector csqcplayer_predictionerrorv;
  48 float csqcplayer_predictionerrortime;
  49 float csqcplayer_predictionerrorfactor;
  50
  51 vector CSQCPlayer_GetPredictionErrorO()
  52 {
  53         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  54         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  55 }
  56
  57 vector CSQCPlayer_GetPredictionErrorV()
  58 {
  59         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  60         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  61 }
  62
  63 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  64 {
  65         // error too big to compensate, we LIKELY hit a teleport or a
  66         // jumppad, or it's a jump time disagreement that'll get fixed
  67         // next frame
  68
  69         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  70         /*
  71         // commented out as this one did not help
  72         if(onground_diff)
  73         {
  74                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  75                 return;
  76         }
  77         */
  78         if(vlen(o) > 32 || vlen(v) > 192)
  79         {
  80                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  81                 return;
  82         }
  83
  84         if(!autocvar_cl_movement_errorcompensation)
  85         {
  86                 csqcplayer_predictionerrorfactor = 0;
  87                 return;
  88         }
  89
  90         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  91         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  92         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ticrate;
  93         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  94 }
  95
  96 void CSQCPlayer_Unpredict(entity this)
  97 {
  98         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
  99         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)\n", csqcplayer_status);
 100         this.origin = csqcplayer_origin;
 101         this.velocity = csqcplayer_velocity;
 102         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
 103         this.flags = player_pmflags;
 104 }
 105
 106 void CSQCPlayer_SetMinsMaxs(entity this)
 107 {
 108         if (this.flags & FL_DUCKED)
 109         {
 110                 this.mins = PL_CROUCH_MIN;
 111                 this.maxs = PL_CROUCH_MAX;
 112                 this.view_ofs = PL_CROUCH_VIEW_OFS;
 113         }
 114         else
 115         {
 116                 this.mins = PL_MIN;
 117                 this.maxs = PL_MAX;
 118                 this.view_ofs = PL_VIEW_OFS;
 119         }
 120 }
 121
 122 void CSQCPlayer_SavePrediction(entity this)
 123 {
 124         player_pmflags = this.flags;
 125         csqcplayer_origin = this.origin;
 126         csqcplayer_velocity = this.velocity;
 127         csqcplayer_sequence = servercommandframe;
 128         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 129 }
 130
 131 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
 132 void _Movetype_Physics_Frame(entity this, float movedt);
 133
 134 void Movetype_Physics_Spam(entity this)  // optimized
 135 {
 136         _Movetype_Physics_Frame(this, PHYS_INPUT_TIMELENGTH);
 137         if(wasfreed(this))
 138                 return;
 139
 140         this.avelocity = this.move_avelocity;
 141         this.velocity = this.move_velocity;
 142         this.angles = this.move_angles;
 143         setorigin(this, this.move_origin);
 144 }
 145
 146 void CSQCPlayer_Physics(entity this)
 147 {
 148         if(autocvar_cl_movement)
 149         {
 150                 CSQC_ClientMovement_PlayerMove_Frame(this);
 151
 152                 if(autocvar_cl_movement == 3)
 153                 {
 154                         this.move_origin = this.origin;
 155                         this.move_angles = this.angles;
 156                         this.move_movetype = MOVETYPE_WALK; // temp
 157                         this.move_velocity = this.velocity;
 158                         this.move_avelocity = this.avelocity;
 159                         Movetype_Physics_Spam(this);
 160                 }
 161         }
 162 }
 163
 164 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
 165 {
 166         CSQCPlayer_Unpredict(this);
 167         if (apply_error)
 168         {
 169                 this.origin += CSQCPlayer_GetPredictionErrorO();
 170                 this.velocity += CSQCPlayer_GetPredictionErrorV();
 171         }
 172         CSQCPlayer_SetMinsMaxs(this);
 173
 174         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 175
 176 #if 0
 177         // we don't need this
 178         // darkplaces makes servercommandframe == 0 in these cases anyway
 179         if (getstatf(STAT_HEALTH) <= 0)
 180         {
 181                 csqcplayer_moveframe = clientcommandframe;
 182                 getinputstate(csqcplayer_moveframe-1);
 183                 LOG_INFO("the Weird code path got hit\n");
 184                 return;
 185         }
 186 #endif
 187
 188         if (csqcplayer_moveframe >= endframe)
 189         {
 190                 getinputstate(csqcplayer_moveframe - 1);
 191         }
 192         else
 193         {
 194                 do
 195                 {
 196                         if (!getinputstate(csqcplayer_moveframe)) break;
 197                         CSQCPlayer_Physics(this);
 198                         CSQCPlayer_SetMinsMaxs(this);
 199                         ++csqcplayer_moveframe;
 200                 }
 201                 while (csqcplayer_moveframe < endframe);
 202         }
 203
 204         // add in anything that was applied after (for low packet rate protocols)
 205         input_angles = view_angles;
 206 }
 207
 208 bool CSQCPlayer_IsLocalPlayer(entity this)
 209 {
 210         return (this == csqcplayer);
 211 }
 212
 213 void CSQCPlayer_SetViewLocation()
 214 {
 215         viewloc_SetViewLocation();
 216 }
 217
 218 /** Called once per CSQC_UpdateView() */
 219 void CSQCPlayer_SetCamera()
 220 {
 221         const vector v0 = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 222         const float vh = getstati(STAT_VIEWHEIGHT);
 223         const vector pl_viewofs = PL_VIEW_OFS;
 224         const vector pl_viewofs_crouch = PL_CROUCH_VIEW_OFS;
 225         const entity e = csqcplayer;
 226         if (e)
 227         {
 228                 if (servercommandframe == 0 || clientcommandframe == 0)
 229                 {
 230                         InterpolateOrigin_Do(e);
 231                         e.view_ofs = '0 0 1' * vh;
 232
 233                         // get crouch state from the server
 234                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 235                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 236
 237                         // get onground state from the server
 238                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 239
 240                         CSQCPlayer_SetMinsMaxs(e);
 241
 242                         // override it back just in case
 243                         e.view_ofs = '0 0 1' * vh;
 244
 245                         // set velocity
 246                         e.velocity = v0;
 247                 }
 248                 else
 249                 {
 250                         const int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 251                         InterpolateOrigin_Do(e);
 252                         e.iflags = flg;
 253
 254                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 255                         {
 256                                 const vector o = e.origin;
 257                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 258                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
 259                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - boolean(e.flags & FL_ONGROUND));
 260                                 e.origin = o;
 261                                 e.velocity = v0;
 262
 263                                 // get crouch state from the server
 264                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 265                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 266
 267                                 // get onground state from the server
 268                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 269
 270                                 CSQCPlayer_SavePrediction(e);
 271                         }
 272                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 273
 274 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 275                         // get crouch state from the server (LAG)
 276                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 277                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 278 #endif
 279                         CSQCPlayer_SetMinsMaxs(e);
 280
 281                         e.angles_y = input_angles.y;
 282                 }
 283
 284                 // relink
 285                 setorigin(e, e.origin);
 286         }
 287
 288         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
 289         if (view)
 290         {
 291                 if (view != csqcplayer)
 292                 {
 293                         InterpolateOrigin_Do(view);
 294                         view.view_ofs = '0 0 1' * vh;
 295                 }
 296                 int refdefflags = 0;
 297                 if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
 298                 if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
 299                 // note: these two only work in WIP2, but are harmless in WIP1
 300                 if (getstati(STAT_HEALTH) <= 0) refdefflags |= REFDEFFLAG_DEAD;
 301                 if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
 302                 V_CalcRefdef(view, refdefflags);
 303         }
 304         else
 305         {
 306                 // FIXME by CSQC spec we have to do this:
 307                 // but it breaks chase cam
 308                 /*
 309                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
 310                 setproperty(VF_ANGLES, view_angles);
 311                 */
 312         }
 313         CSQCPLAYER_HOOK_POSTCAMERASETUP();
 314 }
 315
 316 void CSQCPlayer_Remove()
 317 {
 318         csqcplayer = NULL;
 319         cvar_settemp("cl_movement_replay", "1");
 320 }
 321
 322 bool CSQCPlayer_PreUpdate(entity this)
 323 {
 324         if (this != csqcplayer) return false;
 325         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
 326         return true;
 327 }
 328
 329 bool CSQCPlayer_PostUpdate(entity this)
 330 {
 331         if (this.entnum != player_localnum + 1) return false;
 332         csqcplayer = this;
 333         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 334         cvar_settemp("cl_movement_replay", "0");
 335         this.entremove = CSQCPlayer_Remove;
 336         return true;
 337 }