qcsrc/lib/csqcmodel/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22 #include "sv_model.qh"
  23
  24 #include "common.qh"
  25
  26 // generic CSQC model code
  27
  28 bool CSQCModel_Send(entity this, entity to, int sf)
  29 {
  30         // some nice flags for CSQCMODEL_IF
  31         noref bool isplayer = IS_CLIENT(this);
  32         noref bool islocalplayer = (this == to);
  33         noref bool isnolocalplayer = (isplayer && (this != to));
  34
  35         int psf = 0;
  36         psf = BITSET(psf, ISPLAYER_ENT, isplayer);
  37         psf = BITSET(psf, ISPLAYER_LOCAL, islocalplayer);
  38
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_MODEL);
  40         WriteInt24_t(MSG_ENTITY, sf);
  41         WriteByte(MSG_ENTITY, psf);
  42
  43 #define CSQCMODEL_IF(cond) if(cond) {
  44 #define CSQCMODEL_ENDIF }
  45 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  46         if(sf & flag) \
  47         { \
  48                 w(MSG_ENTITY, this.csqcmodel_##f); \
  49         }
  50 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
  51         ALLPROPERTIES
  52 #undef CSQCMODEL_PROPERTY_SCALED
  53 #undef CSQCMODEL_PROPERTY
  54 #undef CSQCMODEL_ENDIF
  55 #undef CSQCMODEL_IF
  56
  57         return true;
  58 }
  59
  60 #if CSQCPLAYER_FORCE_UPDATES
  61 .float csqcmodel_nextforcedupdate;
  62 #endif
  63 void CSQCModel_CheckUpdate(entity e)
  64 {
  65         // some nice flags for CSQCMODEL_IF
  66         noref float isplayer = IS_CLIENT(e);
  67         noref float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  68         noref float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  69
  70 #if CSQCPLAYER_FORCE_UPDATES
  71         if(isplayer && time > e.csqcmodel_nextforcedupdate)
  72         {
  73                 e.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
  74                 e.csqcmodel_nextforcedupdate = time + (1 / (CSQCPLAYER_FORCE_UPDATES)) * (0.5 + random()); // ensure about 4 origin sends per sec
  75         }
  76 #endif
  77
  78         if(e.effects & EF_RESTARTANIM_BIT)
  79         {
  80                 e.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  81                 e.effects &= ~EF_RESTARTANIM_BIT;
  82         }
  83
  84         if(e.effects & EF_TELEPORT_BIT)
  85         {
  86                 e.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  87                 e.effects &= ~EF_TELEPORT_BIT;
  88         }
  89
  90 #define CSQCMODEL_IF(cond) if(cond) {
  91 #define CSQCMODEL_ENDIF }
  92 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  93         { \
  94                 t tmp = e.f; \
  95                 if(tmp != e.csqcmodel_##f) \
  96                 { \
  97                         e.csqcmodel_##f = tmp; \
  98                         e.SendFlags |= flag; \
  99                 } \
 100         }
 101 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
 102         { \
 103                 t tmp = rint(bound(mi, s * e.f, ma) - mi); \
 104                 if(tmp != e.csqcmodel_##f) \
 105                 { \
 106                         e.csqcmodel_##f = tmp; \
 107                         e.SendFlags |= flag; \
 108                 } \
 109         }
 110         ALLPROPERTIES
 111 #undef CSQCMODEL_PROPERTY_SCALED
 112 #undef CSQCMODEL_PROPERTY
 113 #undef CSQCMODEL_ENDIF
 114 #undef CSQCMODEL_IF
 115 }
 116
 117 void CSQCModel_LinkEntity(entity e)
 118 {
 119         setSendEntity(e, CSQCModel_Send);
 120         e.SendFlags = 0xFFFFFF;
 121         CSQCModel_CheckUpdate(e);
 122 }
 123
 124 void CSQCModel_UnlinkEntity(entity e)
 125 {
 126         setSendEntity(e, func_null);
 127 }