qcsrc/lib/csqcmodel/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22 #include "sv_model.qh"
  23
  24 #include "common.qh"
  25 #include <common/animdecide.qh>
  26 #include <common/constants.qh>
  27 #include <common/util.qh>
  28 #include <server/constants.qh>
  29 #include <server/defs.qh>
  30
  31 // generic CSQC model code
  32
  33 bool CSQCModel_Send(entity to, int sf)
  34 {
  35     SELFPARAM();
  36         // some nice flags for CSQCMODEL_IF
  37         float isplayer = (IS_CLIENT(self));
  38         float islocalplayer = (self == to);
  39         float isnolocalplayer = (isplayer && (self != to));
  40
  41         unused_float = isplayer;
  42         unused_float = islocalplayer;
  43         unused_float = isnolocalplayer;
  44
  45         WriteHeader(MSG_ENTITY, ENT_CLIENT_MODEL);
  46         WriteInt24_t(MSG_ENTITY, sf);
  47
  48 #define CSQCMODEL_IF(cond) if(cond) {
  49 #define CSQCMODEL_ENDIF }
  50 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  51         if(sf & flag) \
  52         { \
  53                 w(MSG_ENTITY, self.csqcmodel_##f); \
  54         }
  55 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
  56         ALLPROPERTIES
  57 #undef CSQCMODEL_PROPERTY_SCALED
  58 #undef CSQCMODEL_PROPERTY
  59 #undef CSQCMODEL_ENDIF
  60 #undef CSQCMODEL_IF
  61
  62         return true;
  63 }
  64
  65 #if CSQCPLAYER_FORCE_UPDATES
  66 .float csqcmodel_nextforcedupdate;
  67 #endif
  68 void CSQCModel_CheckUpdate(entity e)
  69 {
  70         // some nice flags for CSQCMODEL_IF
  71         float isplayer = (IS_CLIENT(e));
  72         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  73         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  74
  75         unused_float = isplayer;
  76         unused_float = islocalplayer;
  77         unused_float = isnolocalplayer;
  78
  79 #if CSQCPLAYER_FORCE_UPDATES
  80         if(isplayer && time > e.csqcmodel_nextforcedupdate)
  81         {
  82                 e.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
  83                 e.csqcmodel_nextforcedupdate = time + (1 / (CSQCPLAYER_FORCE_UPDATES)) * (0.5 + random()); // ensure about 4 origin sends per sec
  84         }
  85 #endif
  86
  87         if(e.effects & EF_RESTARTANIM_BIT)
  88         {
  89                 e.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  90                 e.effects &= ~EF_RESTARTANIM_BIT;
  91         }
  92
  93         if(e.effects & EF_TELEPORT_BIT)
  94         {
  95                 e.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  96                 e.effects &= ~EF_TELEPORT_BIT;
  97         }
  98
  99 #define CSQCMODEL_IF(cond) if(cond) {
 100 #define CSQCMODEL_ENDIF }
 101 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
 102         { \
 103                 t tmp = e.f; \
 104                 if(tmp != e.csqcmodel_##f) \
 105                 { \
 106                         e.csqcmodel_##f = tmp; \
 107                         e.SendFlags |= flag; \
 108                 } \
 109         }
 110 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
 111         { \
 112                 t tmp = rint(bound(mi, s * e.f, ma) - mi); \
 113                 if(tmp != e.csqcmodel_##f) \
 114                 { \
 115                         e.csqcmodel_##f = tmp; \
 116                         e.SendFlags |= flag; \
 117                 } \
 118         }
 119         ALLPROPERTIES
 120 #undef CSQCMODEL_PROPERTY_SCALED
 121 #undef CSQCMODEL_PROPERTY
 122 #undef CSQCMODEL_ENDIF
 123 #undef CSQCMODEL_IF
 124 }
 125
 126 void CSQCModel_LinkEntity(entity e)
 127 {
 128         e.SendEntity = CSQCModel_Send;
 129         e.SendFlags = 0xFFFFFF;
 130         CSQCModel_CheckUpdate(e);
 131 }
 132
 133 void CSQCModel_UnlinkEntity(entity e)
 134 {
 135         e.SendEntity = func_null;
 136 }