qcsrc/lib/oo.qh

   1 #pragma once
   2
   3 #include "misc.qh"
   4 #include "nil.qh"
   5 #include "static.qh"
   6
   7 #ifdef MENUQC
   8         #define NULL (0, null_entity)
   9 #else
  10         #define NULL (0, world)
  11 #endif
  12
  13 .vector origin;
  14 .bool pure_data;
  15 /** @deprecated use new_pure or NEW(class) */
  16 #define make_pure(e) \
  17         MACRO_BEGIN \
  18         { \
  19                 (e).pure_data = true; \
  20         } MACRO_END
  21 #define make_impure(e) \
  22         MACRO_BEGIN \
  23         { \
  24                 (e).pure_data = false; \
  25         } MACRO_END
  26 #define is_pure(e) ((e).pure_data)
  27
  28 .string classname;
  29 /** Location entity was spawned from in source */
  30 .string sourceLoc;
  31 entity _spawn();
  32
  33 #ifndef SPAWN_PURE
  34 #define SPAWN_PURE 0
  35 #endif
  36
  37 // pure entities: need no .origin
  38 #if SPAWN_PURE
  39 entity spawn_pure() = #600;
  40 #else
  41 #define spawn_pure() _spawn()
  42 #endif
  43
  44 entity __spawn(string _classname, string _sourceLoc, bool pure)
  45 {
  46         entity this = pure ? spawn_pure() : _spawn();
  47         this.classname = _classname;
  48         this.sourceLoc = _sourceLoc;
  49         if (pure) {
  50                 make_pure(this);
  51                 #ifdef CSQC
  52                 setorigin(this, '0 0 10000');
  53                 #endif
  54                 #ifdef SVQC
  55         setorigin(this, '0 0 -10000');
  56         #endif
  57         }
  58         return this;
  59 }
  60
  61
  62 #define entityclass(...) EVAL_entityclass(OVERLOAD_(entityclass, __VA_ARGS__))
  63 #define EVAL_entityclass(...) __VA_ARGS__
  64 #define entityclass_1(name) entityclass_2(name, Object)
  65 #ifndef QCC_SUPPORT_ENTITYCLASS
  66         #define entityclass_2(name, base) USING(name, entity)
  67         #define class(name)
  68         #define _new(class, pure) __spawn( #class, __FILE__ ":" STR(__LINE__), pure)
  69 #else
  70         #define entityclass_2(name, base) entityclass name : base {}
  71         #define class(name) [[class(name)]]
  72         #define _new(class, pure) ((class) __spawn( #class, __FILE__ ":" STR(__LINE__), pure))
  73 #endif
  74 /** entities you care about seeing (.origin works) */
  75 #define new(class) _new(class, false)
  76 /** purely logical entities (.origin doesn't work) */
  77 #define new_pure(class) _new(class, true)
  78 #define spawn() __spawn("entity", __FILE__ ":" STR(__LINE__), false)
  79
  80 #define delete(this) MACRO_BEGIN { \
  81     entity _this = (this); \
  82     void(entity) _dtor = _this.dtor; \
  83     if (_dtor) _dtor(_this); else remove(_this); \
  84     /* this = NULL; */  \
  85 } MACRO_END
  86
  87 entity _clearentity_ent;
  88 STATIC_INIT(clearentity)
  89 {
  90         _clearentity_ent = new_pure(clearentity);
  91 }
  92 void clearentity(entity e)
  93 {
  94 #ifdef CSQC
  95                 int n = e.entnum;
  96 #endif
  97         bool was_pure = is_pure(e);
  98         copyentity(_clearentity_ent, e);
  99         if (!was_pure) make_impure(e);
 100 #ifdef CSQC
 101                 e.entnum = n;
 102 #endif
 103 }
 104
 105 // Classes have a `spawn##cname(entity)` constructor
 106 // The parameter is used across [[accumulate]] functions
 107
 108 .bool transmute;
 109
 110 // Macros to hide this implementation detail:
 111 #ifdef __STDC__
 112         #define NEW(cname, ...) \
 113                 OVERLOAD_(spawn##cname, new_pure(cname) P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 114
 115     #define _TRANSMUTE(cname, this, ...) \
 116         OVERLOAD_(spawn##cname, this P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 117
 118         #define CONSTRUCT(cname, ...) \
 119                 OVERLOAD_(spawn##cname, this P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 120 #else
 121         #define NEW(cname, ...) \
 122                 OVERLOAD(spawn##cname, new_pure(cname),##__VA_ARGS__)
 123
 124     #define _TRANSMUTE(cname, this, ...) \
 125         OVERLOAD(spawn##cname, this,##__VA_ARGS__)
 126
 127         #define CONSTRUCT(cname, ...) \
 128                 OVERLOAD(spawn##cname, this,##__VA_ARGS__)
 129 #endif
 130
 131 #define TRANSMUTE(cname, this, ...) MACRO_BEGIN \
 132     entity _e = (this); \
 133     if (_e.vtblbase != cname##_vtbl) { \
 134         _e.transmute = true; \
 135         _e.classname = #cname; \
 136         _TRANSMUTE(cname, _e, __VA_ARGS__); \
 137     } \
 138     MACRO_END
 139
 140 #define CONSTRUCTOR(cname, ...) \
 141         cname OVERLOAD(spawn##cname, cname this, __VA_ARGS__) \
 142         { \
 143                 return = this; \
 144         } \
 145         [[accumulate]] cname OVERLOAD(spawn##cname, cname this, __VA_ARGS__)
 146
 147 .string vtblname;
 148 .entity vtblbase;
 149
 150 void RegisterClasses() {}
 151 STATIC_INIT(RegisterClasses)
 152 {
 153         RegisterClasses();
 154 }
 155
 156 #define VTBL(cname, base) \
 157         _INIT_STATIC(cname); \
 158         entity cname##_vtbl; \
 159         void cname##_vtbl_init() \
 160         { \
 161                 cname e = new_pure(vtbl); \
 162                 spawn##cname##_static(e); \
 163                 e.vtblname = #cname; \
 164                 /* Top level objects refer to themselves */ \
 165                 e.vtblbase = base##_vtbl ? base##_vtbl : e; \
 166                 cname##_vtbl = e; \
 167         } \
 168         ACCUMULATE_FUNCTION(RegisterClasses, cname##_vtbl_init)
 169
 170 #define _INIT_STATIC(cname) [[accumulate]] void spawn##cname##_static(cname this)
 171 #define INIT(cname) [[accumulate]] cname spawn##cname##_1(cname this)
 172
 173 #define CLASS(cname, base)                  \
 174         entityclass(cname, base);               \
 175         class(cname).bool instanceOf##cname;    \
 176     bool is_##cname(entity e) { return e.instanceOf##cname; } \
 177         VTBL(cname, base)                       \
 178         _INIT_STATIC(cname)                     \
 179         {                                       \
 180                 if (cname##_vtbl && !this.transmute)\
 181                 {                                   \
 182                         copyentity(cname##_vtbl, this); \
 183                         return;                         \
 184                 }                                   \
 185                 spawn##base##_static(this);         \
 186                 this.instanceOf##cname = true;      \
 187         }                                       \
 188         INIT(cname)                             \
 189         {                                       \
 190                 /* Only statically initialize the current class, it contains everything it inherits */ \
 191                 if (cname##_vtbl.vtblname == this.classname) \
 192                 {                                   \
 193                         spawn##cname##_static(this);    \
 194                         this.transmute = false;         \
 195                         this.classname = #cname;        \
 196                         this.vtblname = string_null;    \
 197                         this.vtblbase = cname##_vtbl;   \
 198                 }                                   \
 199                 spawn##base##_1(this);              \
 200         }
 201
 202 #define METHOD_REFERENCE(cname, name) \
 203         cname##_##name
 204
 205 #define STATIC_METHOD(cname, name, prototype) \
 206         prototype METHOD_REFERENCE(cname, name)
 207
 208 #define METHOD(cname, name, prototype) \
 209         STATIC_METHOD(cname, name, prototype); \
 210         class(cname) .prototype name; \
 211         _INIT_STATIC(cname) \
 212         { \
 213                 this.name = METHOD_REFERENCE(cname, name); \
 214         } \
 215         STATIC_METHOD(cname, name, prototype)
 216
 217 #define DESTRUCTOR(cname) \
 218         STATIC_METHOD(cname, dtorimpl, void(cname this)); \
 219     METHOD(cname, dtor, void(cname this)) \
 220     { \
 221         METHOD_REFERENCE(cname, dtorimpl)(this); \
 222         this.instanceOf##cname = false; \
 223         entity super = SUPER(cname); \
 224         if (super != cname##_vtbl) super.dtor(this); \
 225     } \
 226         STATIC_METHOD(cname, dtorimpl, void(cname this))
 227
 228 #define ATTRIB(cname, name, type, val)      \
 229         class(cname).type name;                \
 230         INIT(cname) \
 231         { \
 232                 noref bool strzone; /* Error on strzone() calls. */ \
 233                 this.name = val; \
 234         }
 235
 236 #define STATIC_ATTRIB(cname, name, type, val) \
 237         type cname##_##name; \
 238         _INIT_STATIC(cname) \
 239         { \
 240                 noref bool strzone; /* Error on strzone() calls. */ \
 241                 cname##_##name = val; \
 242         }
 243
 244 // cleanup potentially zoned strings from base classes
 245
 246 #define ATTRIB_STRZONE(cname, name, type, val)      \
 247         class(cname).type name;                \
 248         INIT(cname) \
 249         { \
 250                 if (this.name) \
 251                         strunzone(this.name); \
 252                 this.name = strzone(val); \
 253         }
 254
 255 #define STATIC_ATTRIB_STRZONE(cname, name, type, val) \
 256         type cname##_##name; \
 257         _INIT_STATIC(cname) \
 258         { \
 259         if (cname##_##name) \
 260             strunzone(cname##_##name); \
 261                 cname##_##name = val; \
 262         }
 263
 264 #define ATTRIBARRAY(cname, name, type, cnt) \
 265         class(cname).type name[cnt];
 266
 267 #define ENDCLASS(cname) \
 268         INIT(cname) \
 269         { \
 270                 return this; \
 271         }
 272
 273 #define SUPER(cname) (cname##_vtbl.vtblbase)
 274
 275 #define spawn_static(this)
 276 #define spawn_1(this)
 277 #define _vtbl NULL
 278 CLASS(Object, );
 279     DESTRUCTOR(Object) { remove(this); }
 280     #define remove(this) delete(this)
 281         METHOD(Object, describe, string(Object this))
 282         {
 283             TC(Object, this);
 284                 string s = _("No description");
 285                 if (cvar("developer"))
 286                 {
 287                         for (int i = 0, n = numentityfields(); i < n; ++i)
 288                         {
 289                                 string value = getentityfieldstring(i, this);
 290                                 if (value != "") s = sprintf("%s\n%s = %s", s, entityfieldname(i), value);
 291                         }
 292                 }
 293                 return s;
 294         }
 295         METHOD(Object, display, void(Object this, void(string name, string icon) returns))
 296         {
 297             TC(Object, this);
 298                 returns(sprintf("entity %i", this), "nopreview_map");
 299         }
 300 ENDCLASS(Object)
 301 #undef spawn_static
 302 #undef spawn_1
 303 #undef _vtbl