qcsrc/lib/vector.qh

   1 #pragma once
   2
   3 noref vector _vlen2;
   4 #define vlen2(v) (_vlen2 = (v), dotproduct(_vlen2, _vlen2))
   5
   6 #if 1
   7 noref float _vdist_f;
   8 /** Vector distance comparison, avoids sqrt() */
   9 #define vdist(v, cmp, f) (vlen2(v) cmp (_vdist_f = (f), _vdist_f * _vdist_f))
  10 #else
  11 #define vdist(v, cmp, f) (vlen(v) cmp (f))
  12 #endif
  13
  14 #if 1
  15 #define dotproduct(a, b) ((a) * (b))
  16 #else
  17 noref vector _dotproduct_a, _dotproduct_b;
  18 #define dotproduct(a, b) \
  19         (_dotproduct_a = (a), _dotproduct_b = (b), \
  20           _dotproduct_a.x * _dotproduct_b.x \
  21         + _dotproduct_a.y * _dotproduct_b.y \
  22         + _dotproduct_a.z * _dotproduct_b.z)
  23 #endif
  24
  25 #if 1
  26 #define cross(a, b) ((a) >< (b))
  27 #else
  28 [[eraseable]]
  29 vector cross(vector a, vector b)
  30 {
  31         return
  32                 '1 0 0' * (a.y * b.z - a.z * b.y)
  33         +       '0 1 0' * (a.z * b.x - a.x * b.z)
  34         +       '0 0 1' * (a.x * b.y - a.y * b.x);
  35 }
  36 #endif
  37
  38 noref vector _vmul_a, _vmul_b;
  39 #define vmul(a, b) \
  40     (_vmul_a = (a), _vmul_b = (b), \
  41           '1 0 0' * (_vmul_a.x * _vmul_b.x) \
  42         + '0 1 0' * (_vmul_a.y * _vmul_b.y) \
  43         + '0 0 1' * (_vmul_a.z * _vmul_b.z))
  44
  45 const vector eX = '1 0 0';
  46 const vector eY = '0 1 0';
  47 const vector eZ = '0 0 1';
  48
  49 [[eraseable]]
  50 vector randompos(vector m1, vector m2)
  51 {
  52         vector v;
  53         m2 = m2 - m1;
  54         v_x = m2_x * random() + m1_x;
  55         v_y = m2_y * random() + m1_y;
  56         v_z = m2_z * random() + m1_z;
  57         return v;
  58 }
  59
  60 [[eraseable]]
  61 float vlen_maxnorm2d(vector v)
  62 {
  63         return max(v.x, v.y, -v.x, -v.y);
  64 }
  65
  66 [[eraseable]]
  67 float vlen_minnorm2d(vector v)
  68 {
  69         return min(max(v.x, -v.x), max(v.y, -v.y));
  70 }
  71
  72 [[eraseable]]
  73 float dist_point_line(vector p, vector l0, vector ldir)
  74 {
  75         ldir = normalize(ldir);
  76
  77         // remove the component in line direction
  78         p = p - (p * ldir) * ldir;
  79
  80         // vlen of the remaining vector
  81         return vlen(p);
  82 }
  83
  84 /** requires that m2>m1 in all coordinates, and that m4>m3 */
  85 [[eraseable]]
  86 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) { return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z; }
  87
  88 /** requires the same as boxesoverlap, but is a stronger condition */
  89 [[eraseable]]
  90 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) { return smins.x >= bmins.x && smaxs.x <= bmaxs.x && smins.y >= bmins.y && smaxs.y <= bmaxs.y && smins.z >= bmins.z && smaxs.z <= bmaxs.z; }
  91
  92 #define PITCH(v) ((v).x)
  93 #define YAW(v) ((v).y)
  94 #define ROLL(v) ((v).z)
  95
  96 #define MAKEVECTORS(f, angles, forward, right, up) MACRO_BEGIN { \
  97         f(angles); \
  98         forward = v_forward; \
  99         right = v_right; \
 100         up = v_up; \
 101 } MACRO_END
 102
 103 noref vector _vec2;
 104 #define vec2(...) EVAL(OVERLOAD(vec2, __VA_ARGS__))
 105 #define vec2_1(v) (_vec2 = (v), _vec2.z = 0, _vec2)
 106 #define vec2_2(x, y) (_vec2_x = (x), _vec2_y = (y), _vec2)
 107
 108 noref vector _vec3;
 109 #define vec3(_x, _y, _z) (_vec3.x = (_x), _vec3.y = (_y), _vec3.z = (_z), _vec3)
 110
 111 [[eraseable]]
 112 vector Rotate(vector v, float a)
 113 {
 114         float a_sin = sin(a), a_cos = cos(a);
 115         vector r = '0 0 0';
 116         r.x =      v.x * a_cos + v.y * a_sin;
 117         r.y = -1 * v.x * a_sin + v.y * a_cos;
 118         return r;
 119 }
 120
 121 noref vector _yinvert;
 122 #define yinvert(v) (_yinvert = (v), _yinvert.y = 1 - _yinvert.y, _yinvert)
 123
 124 /**
 125  * @param dir the directional vector
 126  * @param norm the normalized normal
 127  * @returns dir reflected by norm
 128  */
 129 [[eraseable]]
 130 vector reflect(vector dir, vector norm)
 131 {
 132         return dir - 2 * (dir * norm) * norm;
 133 }
 134
 135 /**
 136  * clip vel along the plane defined by norm (assuming 0 distance away), bounciness determined by bounce 0..1
 137  */
 138 [[eraseable]]
 139 vector vec_reflect(vector vel, vector norm, float bounce)
 140 {
 141         return vel - (1 + bounce) * (vel * norm) * norm;
 142 }
 143
 144 [[eraseable]]
 145 vector vec_epsilon(vector this, float eps)
 146 {
 147         if (this.x > -eps && this.x < eps) this.x = 0;
 148         if (this.y > -eps && this.y < eps) this.y = 0;
 149         if (this.z > -eps && this.z < eps) this.z = 0;
 150         return this;
 151 }
 152
 153 #define ClipVelocity(in, normal, out, overbounce) \
 154         (out = vec_epsilon(vec_reflect(in, normal, (overbounce) - 1), 0.1))
 155
 156 #ifdef GAMEQC
 157         [[eraseable]]
 158         vector get_corner_position(entity box, int corner)
 159         {
 160                 switch (corner)
 161                 {
 162                         case 1: return vec3(box.absmin.x, box.absmin.y, box.absmin.z);
 163                         case 2: return vec3(box.absmax.x, box.absmin.y, box.absmin.z);
 164                         case 3: return vec3(box.absmin.x, box.absmax.y, box.absmin.z);
 165                         case 4: return vec3(box.absmin.x, box.absmin.y, box.absmax.z);
 166                         case 5: return vec3(box.absmax.x, box.absmax.y, box.absmin.z);
 167                         case 6: return vec3(box.absmin.x, box.absmax.y, box.absmax.z);
 168                         case 7: return vec3(box.absmax.x, box.absmin.y, box.absmax.z);
 169                         case 8: return vec3(box.absmax.x, box.absmax.y, box.absmax.z);
 170                         default: return '0 0 0';
 171                 }
 172         }
 173
 174         [[eraseable]]
 175         vector NearestPointOnBox(entity box, vector org)
 176         {
 177                 vector m1 = box.mins + box.origin;
 178                 vector m2 = box.maxs + box.origin;
 179
 180                 vector ret;
 181                 ret.x = bound(m1.x, org.x, m2.x);
 182                 ret.y = bound(m1.y, org.y, m2.y);
 183                 ret.z = bound(m1.z, org.z, m2.z);
 184                 return ret;
 185         }
 186 #endif