qcsrc/menu/gamecommand.qc

   1 void GameCommand_Init()
   2 {
   3         // make gg call menu QC theCommands
   4         localcmd("alias qc_cmd \"menu_cmd $*\"\n");
   5 }
   6
   7 string _dumptree_space;
   8 void _dumptree_open(entity pass, entity me)
   9 {
  10         string s;
  11         s = me.toString(me);
  12         if(s == "")
  13                 s = me.classname;
  14         else
  15                 s = strcat(me.classname, ": ", s);
  16         print(_dumptree_space, etos(me), " (", s, ")");
  17         if(me.firstChild)
  18         {
  19                 print(" {\n");
  20                 _dumptree_space = strcat(_dumptree_space, "  ");
  21         }
  22         else
  23                 print("\n");
  24 }
  25 void _dumptree_close(entity pass, entity me)
  26 {
  27         if(me.firstChild)
  28         {
  29                 _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
  30                 print(_dumptree_space, "}\n");
  31         }
  32 }
  33
  34 float curl_uri_get_pos;
  35 float curl_uri_get_exec[URI_GET_CURL_END - URI_GET_CURL + 1];
  36 string curl_uri_get_cvar[URI_GET_CURL_END - URI_GET_CURL + 1];
  37 void Curl_URI_Get_Callback(float id, float status, string data)
  38 {
  39         float i;
  40         float do_exec;
  41         string do_cvar;
  42         i = id - URI_GET_CURL;
  43         do_exec = curl_uri_get_exec[i];
  44         do_cvar = curl_uri_get_cvar[i];
  45         if(status != 0)
  46         {
  47                 print(sprintf(_("error: status is %d\n"), status));
  48                 return;
  49         }
  50         if(do_exec)
  51                 localcmd(data);
  52         if(do_cvar)
  53                 cvar_set(do_cvar, data);
  54         if(!do_exec && !do_cvar)
  55                 print(data);
  56 }
  57
  58 void GameCommand(string theCommand)
  59 {
  60         float argc;
  61         argc = tokenize_console(theCommand);
  62
  63         if(argv(0) == "help" || argc == 0)
  64         {
  65                 print(_("Usage: menu_cmd command..., where possible commands are:\n"));
  66                 print(_("  sync - reloads all cvars on the current menu page\n"));
  67                 print(_("  directmenu ITEM - select a menu item as main item\n"));
  68                 GameCommand_Generic("help");
  69                 return;
  70         }
  71
  72         if(GameCommand_Generic(theCommand))
  73                 return;
  74
  75         if(argv(0) == "sync")
  76         {
  77                 updateCompression();
  78                 updateConwidths();
  79                 loadAllCvars(main);
  80                 return;
  81         }
  82
  83         if(argv(0) == "directmenu") if(argc == 2)
  84         {
  85                 // switch to a menu item
  86                 if(!isdemo()) // don't allow this command in demos
  87                         m_goto(argv(1));
  88                 return;
  89         }
  90
  91         if(argv(0) == "directpanelhudmenu")
  92         {
  93                 // switch to a menu item
  94                 m_goto(strcat("HUD", argv(1)));
  95                 return;
  96         }
  97
  98         if(argv(0) == "skinselect")
  99         {
 100                 m_goto_skin_selector();
 101                 return;
 102         }
 103
 104         if(argv(0) == "languageselect")
 105         {
 106                 m_goto_language_selector();
 107                 return;
 108         }
 109
 110         if(argv(0) == "videosettings")
 111         {
 112                 m_goto_video_settings();
 113                 return;
 114         }
 115
 116         if(argv(0) == "dumptree")
 117         {
 118                 _dumptree_space = "";
 119                 depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
 120                 return;
 121         }
 122
 123         if(argv(0) == "curl")
 124         {
 125                 float do_exec;
 126                 string do_cvar;
 127                 float key;
 128                 float i, j;
 129                 string url;
 130                 float buf;
 131                 float r;
 132
 133                 do_exec = FALSE;
 134                 do_cvar = string_null;
 135                 key = -1;
 136
 137                 for(i = 1; i+1 < argc; ++i)
 138                 {
 139                         if(argv(i) == "--cvar" && i+2 < argc)
 140                         {
 141                                 ++i;
 142                                 do_cvar = argv(i);
 143                                 continue;
 144                         }
 145                         if(argv(i) == "--exec")
 146                         {
 147                                 do_exec = TRUE;
 148                                 continue;
 149                         }
 150                         if(argv(i) == "--key" && i+2 < argc)
 151                         {
 152                                 ++i;
 153                                 key = stof(argv(i));
 154                                 continue;
 155                         }
 156                         break;
 157                 }
 158
 159                 // now, argv(i) is the URL
 160                 // following args may be POST parameters
 161                 url = argv(i);
 162                 ++i;
 163                 buf = buf_create();
 164                 j = 0;
 165                 for(; i+1 < argc; i += 2)
 166                         bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 167                 if(i < argc)
 168                         bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 169
 170                 if(j == 0) // no args: GET
 171                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 172                 else // with args: POST
 173                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 174
 175                 if(r)
 176                 {
 177                         curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 178                         curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 179                         curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 180                 }
 181                 else
 182                         print(_("error creating curl handle\n"));
 183
 184                 buf_del(buf);
 185
 186                 return;
 187         }
 188
 189 #if 0
 190         if(argv(0) == "tokentest")
 191         {
 192                 string s;
 193                 float i, n;
 194
 195                 print("SANE tokenizer:\n");
 196                 s = cvar_string("tokentest");
 197                 n = tokenize_console_force_builtin(s);
 198                 for(i = -n; i < n; ++i)
 199                 {
 200                         print("token ", ftos(i), ": '", argv(i), "' = ");
 201                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 202                 }
 203                 print(".\n");
 204
 205                 print("INSANE tokenizer:\n");
 206                 s = cvar_string("tokentest");
 207                 n = tokenize(s);
 208                 for(i = -n; i < n; ++i)
 209                 {
 210                         print("token ", ftos(i), ": '", argv(i), "' = ");
 211                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 212                 }
 213                 print(".\n");
 214
 215                 print("EMULATED tokenizer:\n");
 216                 s = cvar_string("tokentest");
 217                 n = tokenize_console_force_emulation(s);
 218                 for(i = -n; i < n; ++i)
 219                 {
 220                         print("token ", ftos(i), ": '", argv(i), "' = ");
 221                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 222                 }
 223                 print(".\n");
 224                 return;
 225         }
 226 #endif
 227
 228         print(_("Invalid command. For a list of supported commands, try menu_cmd help.\n"));
 229 }