qcsrc/menu/menu.qc

   1 #include "menu.qh"
   2
   3 #include "item.qh"
   4
   5 #include "anim/animhost.qh"
   6
   7 #include "item/dialog.qh"
   8 #include "item/listbox.qh"
   9 #include "item/nexposee.qh"
  10
  11 #include "xonotic/commandbutton.qh"
  12 #include "xonotic/mainwindow.qh"
  13 #include "xonotic/serverlist.qh"
  14 #include "xonotic/slider_resolution.qh"
  15
  16 .string cvarName;
  17
  18 #include "xonotic/util.qh"
  19
  20 #include <common/items/_mod.qh>
  21 #include <common/weapons/_all.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/mutators/base.qh>
  24
  25 int mouseButtonsPressed;
  26 vector menuMousePos;
  27 int menuShiftState;
  28 float menuPrevTime;
  29 float menuAlpha;
  30 float menuLogoAlpha;
  31 float prevMenuAlpha;
  32 bool menuInitialized;
  33 bool menuNotTheFirstFrame;
  34 int menuMouseMode;
  35
  36 float conwidth_s, conheight_s;
  37 float vidwidth_s, vidheight_s, vidpixelheight_s;
  38 float realconwidth, realconheight;
  39
  40 void m_sync()
  41 {
  42         updateCompression();
  43         vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw
  44
  45         loadAllCvars(main);
  46 }
  47
  48 void m_gamestatus()
  49 {
  50         gamestatus = 0;
  51         if (isserver()) gamestatus |= GAME_ISSERVER;
  52         if (clientstate() == CS_CONNECTED || isdemo()) gamestatus |= GAME_CONNECTED;
  53         if (cvar("developer") > 0) gamestatus |= GAME_DEVELOPER;
  54 }
  55
  56 void m_init()
  57 {
  58         bool restarting = false;
  59         cvar_set("_menu_alpha", "0");
  60         prvm_language = cvar_string("prvm_language");
  61         if (prvm_language == "")
  62         {
  63                 prvm_language = "en";
  64                 cvar_set("prvm_language", prvm_language);
  65                 localcmd("\nmenu_restart\n");
  66                 restarting = true;
  67         }
  68         prvm_language = strzone(prvm_language);
  69         cvar_set("_menu_prvm_language", prvm_language);
  70
  71 #ifdef WATERMARK
  72                 LOG_TRACEF("^4MQC Build information: ^1%s", WATERMARK);
  73 #endif
  74
  75         // list all game dirs (TEST)
  76         if (cvar("developer") > 0)
  77         {
  78                 for (int i = 0; ; ++i)
  79                 {
  80                         string s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  81                         if (!s) break;
  82                         LOG_TRACE(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  83                 }
  84         }
  85
  86         // needs to be done so early because of the constants they create
  87         static_init();
  88         static_init_late();
  89         static_init_precache();
  90
  91         RegisterSLCategories();
  92
  93         float ddsload = cvar("r_texture_dds_load");
  94         float texcomp = cvar("gl_texturecompression");
  95         updateCompression();
  96         if (ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression")) localcmd("\nr_restart\n");
  97
  98         if (!restarting)
  99         {
 100                 if (cvar("_menu_initialized"))  // always show menu after menu_restart
 101                         m_display();
 102                 else m_hide();
 103                 cvar_set("_menu_initialized", "1");
 104         }
 105 }
 106
 107 const float MENU_ASPECT = 1280 / 1024;
 108
 109 void draw_reset_cropped()
 110 {
 111         draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
 112 }
 113 void draw_reset_full()
 114 {
 115         draw_reset(realconwidth, realconheight, 0, 0);
 116 }
 117
 118 void UpdateConWidthHeight(float w, float h, float p)
 119 {
 120         if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
 121         {
 122                 if (updateConwidths(w, h, p)) localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
 123                 vidwidth_s = w;
 124                 vidheight_s = h;
 125                 vidpixelheight_s = p;
 126         }
 127         conwidth_s = conwidth;
 128         conheight_s = conheight;
 129         realconwidth = cvar("vid_conwidth");
 130         realconheight = cvar("vid_conheight");
 131         if (realconwidth / realconheight > MENU_ASPECT)
 132         {
 133                 // widescreen
 134                 conwidth = realconheight * MENU_ASPECT;
 135                 conheight = realconheight;
 136         }
 137         else
 138         {
 139                 // squarescreen
 140                 conwidth = realconwidth;
 141                 conheight = realconwidth / MENU_ASPECT;
 142         }
 143         if (main)
 144         {
 145                 if (conwidth_s != conwidth || conheight_s != conheight)
 146                 {
 147                         draw_reset_cropped();
 148                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 149                 }
 150         }
 151         else
 152         {
 153                 vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // retry next frame
 154         }
 155 }
 156
 157 string m_goto_buffer;
 158 void m_init_delayed()
 159 {
 160         draw_reset_cropped();
 161
 162         menuInitialized = false;
 163         if (!preMenuInit()) return;
 164         menuInitialized = true;
 165
 166         int fh = -1;
 167         if (cvar_string("menu_skin") != "")
 168         {
 169                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 170                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 171         }
 172         if (fh < 0 && cvar_defstring("menu_skin") != "")
 173         {
 174                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
 175                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 176                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 177         }
 178         if (fh < 0)
 179         {
 180                 draw_currentSkin = "gfx/menu/default";
 181                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 182         }
 183         if (fh < 0) error("cannot load any menu skin\n");
 184         draw_currentSkin = strzone(draw_currentSkin);
 185         for (string s; (s = fgets(fh)); )
 186         {
 187                 // these two are handled by skinlist.qc
 188                 if (substring(s, 0, 6) == "title ") continue;
 189                 if (substring(s, 0, 7) == "author ") continue;
 190                 int n = tokenize_console(s);
 191                 if (n < 2) continue;
 192                 Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 193         }
 194         fclose(fh);
 195
 196         int glob = search_begin(strcat(draw_currentSkin, "/*.tga"), true, true);
 197         if (glob >= 0)
 198         {
 199                 for (int i = 0, n = search_getsize(glob); i < n; ++i)
 200                         precache_pic(search_getfilename(glob, i));
 201                 search_end(glob);
 202         }
 203
 204         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 205
 206         anim = NEW(AnimHost);
 207         main = NEW(MainWindow);
 208         main.configureMainWindow(main);
 209
 210         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 211         main.focused = true;
 212         menuShiftState = 0;
 213         menuMousePos = '0.5 0.5 0';
 214
 215         m_sync();
 216
 217         if (m_goto_buffer)
 218         {
 219                 m_goto(m_goto_buffer);
 220                 strfree(m_goto_buffer);
 221         }
 222
 223         if (Menu_Active) m_display();  // delayed menu display
 224 }
 225
 226 void m_keyup(float key, float ascii)
 227 {
 228         if (!menuInitialized) return;
 229         if (!Menu_Active) return;
 230         draw_reset_cropped();
 231         main.keyUp(main, key, ascii, menuShiftState);
 232         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 233         {
 234                 --mouseButtonsPressed;
 235                 if (!mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 236                 if (mouseButtonsPressed < 0)
 237                 {
 238                         mouseButtonsPressed = 0;
 239                         LOG_TRACE("Warning: released an already released button");
 240                 }
 241         }
 242         if (key == K_ALT) menuShiftState &= ~S_ALT;
 243         if (key == K_CTRL) menuShiftState &= ~S_CTRL;
 244         if (key == K_SHIFT) menuShiftState &= ~S_SHIFT;
 245 }
 246
 247 void m_keydown(float key, float ascii)
 248 {
 249         if (!menuInitialized) return;
 250         if (!Menu_Active) return;
 251
 252         if (menuMouseMode && key >= K_MOUSE1 && key <= K_MOUSE3)
 253         {
 254                 // detect a click outside of the game window
 255                 vector p = getmousepos();
 256                 if (p.x < 0 || p.x > realconwidth || p.y < 0 || p.y > realconheight)
 257                 {
 258                         ++mouseButtonsPressed;
 259                         return;
 260                 }
 261         }
 262
 263         if (keyGrabber)
 264         {
 265                 entity e = keyGrabber;
 266                 keyGrabber = NULL;
 267                 e.keyGrabbed(e, key, ascii);
 268         }
 269         else
 270         {
 271                 draw_reset_cropped();
 272                 if (!mouseButtonsPressed && key >= K_MOUSE1 && key <= K_MOUSE3)
 273                         main.mousePress(main, menuMousePos);
 274                 if (!main.keyDown(main, key, ascii, menuShiftState))
 275                 {
 276                         // disable menu on unhandled ESC
 277                         if (key == K_ESCAPE)
 278                                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))  // don't back out to console only
 279                                         m_hide();
 280                 }
 281         }
 282         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 283         {
 284                 ++mouseButtonsPressed;
 285                 if (mouseButtonsPressed > 10)
 286                 {
 287                         mouseButtonsPressed = 10;
 288                         LOG_TRACE("Warning: pressed an already pressed button");
 289                 }
 290         }
 291         if (key == K_ALT) menuShiftState |= S_ALT;
 292         if (key == K_CTRL) menuShiftState |= S_CTRL;
 293         if (key == K_SHIFT) menuShiftState |= S_SHIFT;
 294 }
 295
 296 enum {
 297         SCALEMODE_CROP,
 298         SCALEMODE_LETTERBOX,
 299         SCALEMODE_WIDTH,
 300         SCALEMODE_HEIGHT,
 301         SCALEMODE_STRETCH,
 302 };
 303 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
 304 {
 305         vector sz = draw_PictureSize(img);
 306         bool width_is_larger = (sz.x * draw_scale.y >= sz.y * draw_scale.x);
 307         vector isz_w = '1 0 0' + '0 1 0' * ((sz.y / sz.x) * (draw_scale.x / draw_scale.y));
 308         vector isz_h = '0 1 0' + '1 0 0' * ((sz.x / sz.y) * (draw_scale.y / draw_scale.x));
 309         vector isz;
 310         switch (scalemode)
 311         {
 312                 default:
 313                 case SCALEMODE_CROP:
 314                         isz = (width_is_larger ? isz_h : isz_w);
 315                         break;
 316                 case SCALEMODE_LETTERBOX:
 317                         isz = (width_is_larger ? isz_w : isz_h);
 318                         break;
 319                 case SCALEMODE_WIDTH:
 320                         isz = isz_w;
 321                         break;
 322                 case SCALEMODE_HEIGHT:
 323                         isz = isz_h;
 324                         break;
 325                 case SCALEMODE_STRETCH:
 326                         isz = '1 1 0';
 327                         break;
 328         }
 329         vector org = eX * (algn.x * (1 - isz.x)) + eY * (algn.y * (1 - isz.y));
 330         draw_Picture(org, img, isz, '1 1 1', a);
 331 }
 332
 333 void drawBackground(string img, float a, string algn, float force1)
 334 {
 335         if (main.mainNexposee.ModalController_state == 0) return;
 336         vector v = '0 0 0';
 337         int scalemode = SCALEMODE_CROP;
 338         int len = strlen(algn);
 339         for (int i = 0, l = 0; i < len; ++i)
 340         {
 341                 string c = substring(algn, i, 1);
 342                 switch (c)
 343                 {
 344                         case "c":
 345                                 scalemode = SCALEMODE_CROP;
 346                                 goto nopic;
 347                         case "l":
 348                                 scalemode = SCALEMODE_LETTERBOX;
 349                                 goto nopic;
 350                         case "h":
 351                                 scalemode = SCALEMODE_HEIGHT;
 352                                 goto nopic;
 353                         case "w":
 354                                 scalemode = SCALEMODE_WIDTH;
 355                                 goto nopic;
 356                         case "s":
 357                                 scalemode = SCALEMODE_STRETCH;
 358                                 goto nopic;
 359                         case "1": case "4": case "7":
 360                                 v.x = 0.0;
 361                                 break;
 362                         case "2": case "5": case "8":
 363                                 v.x = 0.5;
 364                                 break;
 365                         case "3": case "6": case "9":
 366                                 v.x = 1.0;
 367                                 break;
 368                         default:
 369                                 v.x = random();
 370                                 break;
 371                 }
 372                 switch (c)
 373                 {
 374                         case "7": case "8": case "9":
 375                                 v.y = 0.0;
 376                                 break;
 377                         case "4": case "5": case "6":
 378                                 v.y = 0.5;
 379                                 break;
 380                         case "1": case "2": case "3":
 381                                 v.y = 1.0;
 382                                 break;
 383                         default:
 384                                 v.y = random();
 385                                 break;
 386                 }
 387                 if (l == 0)
 388                 {
 389                         draw_Picture_Aligned(v, scalemode, img, a);
 390                 }
 391                 else if (force1)
 392                 {
 393                         // force all secondary layers to use alpha 1. Prevents ugly issues
 394                         // with overlap. It's a flag because it cannot be used for the
 395                         // ingame background
 396                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), 1);
 397                 }
 398                 else
 399                 {
 400                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), a);
 401                 }
 402                 ++l;
 403 LABEL(nopic)
 404         }
 405 }
 406
 407 int menu_tooltips;
 408 int menu_tooltips_old;
 409 vector menuTooltipAveragedMousePos;
 410 entity menuTooltipItem;
 411 vector menuTooltipOrigin;
 412 vector menuTooltipSize;
 413 float menuTooltipAlpha;
 414 string menuTooltipText;
 415 int menuTooltipState;  // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 416 bool m_testmousetooltipbox(vector pos)
 417 {
 418         return !(
 419             (pos.x >= menuTooltipOrigin.x && pos.x < menuTooltipOrigin.x + menuTooltipSize.x)
 420             && (pos.y >= menuTooltipOrigin.y && pos.y < menuTooltipOrigin.y + menuTooltipSize.y)
 421                 );
 422 }
 423 bool m_testtooltipbox(vector tooltippos)
 424 {
 425         if (tooltippos.x < 0) return false;
 426         if (tooltippos.y < 0) return false;
 427         if (tooltippos.x + menuTooltipSize.x > 1) return false;
 428         if (tooltippos.y + menuTooltipSize.y > 1) return false;
 429         menuTooltipOrigin = tooltippos;
 430         return true;
 431 }
 432 bool m_allocatetooltipbox(vector pos)
 433 {
 434         vector avoidplus;
 435         avoidplus.x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
 436         avoidplus.y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
 437         avoidplus.z = 0;
 438
 439         vector avoidminus;
 440         avoidminus.x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize.x;
 441         avoidminus.y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize.y;
 442         avoidminus.z = 0;
 443
 444         // bottom right
 445         vector v = pos + avoidplus;
 446         if (m_testtooltipbox(v)) return true;
 447
 448         // bottom center
 449         v.x = pos.x - menuTooltipSize.x * 0.5;
 450         if (m_testtooltipbox(v)) return true;
 451
 452         // bottom left
 453         v.x = pos.x - avoidminus.x;
 454         if (m_testtooltipbox(v)) return true;
 455
 456         // top left
 457         v.y = pos.y - avoidminus.y;
 458         if (m_testtooltipbox(v)) return true;
 459
 460         // top center
 461         v.x = pos.x - menuTooltipSize.x * 0.5;
 462         if (m_testtooltipbox(v)) return true;
 463
 464         // top right
 465         v.x = pos.x + avoidplus.x;
 466         if (m_testtooltipbox(v)) return true;
 467
 468         return false;
 469 }
 470 entity m_findtooltipitem(entity root, vector pos)
 471 {
 472         entity best = NULL;
 473         for (entity it = root; it.instanceOfContainer; )
 474         {
 475                 while (it.instanceOfNexposee && it.focusedChild)
 476                 {
 477                         it = it.focusedChild;
 478                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 479                 }
 480                 if (it.instanceOfNexposee)
 481                 {
 482                         it = it.itemFromPoint(it, pos);
 483                         if (it.tooltip) best = it;
 484                         else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 485                         it = NULL;
 486                 }
 487                 else if (it.instanceOfModalController)
 488                 {
 489                         it = it.focusedChild;
 490                 }
 491                 else
 492                 {
 493                         it = it.itemFromPoint(it, pos);
 494                 }
 495                 if (!it) break;
 496                 if (it.tooltip) best = it;
 497                 else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 498                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 499         }
 500
 501         return best;
 502 }
 503 string gettooltip()
 504 {
 505         if (menu_tooltips == 2)
 506         {
 507                 string s;
 508                 if (menuTooltipItem.cvarName)
 509                 {
 510                         if (getCvarsMulti(menuTooltipItem)) s =
 511                                     strcat("[", menuTooltipItem.cvarName, " ", getCvarsMulti(menuTooltipItem), "]");
 512                         else s = strcat("[", menuTooltipItem.cvarName, "]");
 513                 }
 514                 else if (menuTooltipItem.onClickCommand)
 515                 {
 516                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
 517                 }
 518                 else
 519                 {
 520                         return menuTooltipItem.tooltip;
 521                 }
 522                 if (menuTooltipItem.tooltip) return strcat(menuTooltipItem.tooltip, " ", s);
 523                 return s;
 524         }
 525         return menuTooltipItem.tooltip;
 526 }
 527 void m_tooltip(vector pos)
 528 {
 529         static string prev_tooltip;
 530         entity it;
 531         menu_tooltips = cvar("menu_tooltips");
 532         if (!menu_tooltips)
 533         {
 534                 // don't return immediately, fade out the active tooltip first
 535                 if (menuTooltipItem == NULL) return;
 536                 it = NULL;
 537                 menu_tooltips_old = menu_tooltips;
 538         }
 539         else
 540         {
 541                 float f = bound(0, frametime * 2, 1);
 542                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 543                 if (vdist(pos - menuTooltipAveragedMousePos, <, 0.01))
 544                 {
 545                         it = m_findtooltipitem(main, pos);
 546
 547                         if (it.instanceOfListBox && it.isScrolling(it)) it = NULL;
 548
 549                         if (it && prev_tooltip != it.tooltip)
 550                         {
 551                                 // fade out if tooltip of a certain item has changed
 552                                 menuTooltipState = 3;
 553                                 strcpy(prev_tooltip, it.tooltip);
 554                         }
 555                         else if (menuTooltipItem && !m_testmousetooltipbox(pos))
 556                         {
 557                                 menuTooltipState = 3;  // fade out if mouse touches it
 558                         }
 559                 }
 560                 else
 561                 {
 562                         it = NULL;
 563                 }
 564         }
 565         vector fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 566
 567         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 568         if (it != menuTooltipItem)
 569         {
 570                 switch (menuTooltipState)
 571                 {
 572                         case 0:
 573                                 if (menuTooltipItem)
 574                                 {
 575                                         // another item: fade out first
 576                                         menuTooltipState = 2;
 577                                 }
 578                                 else
 579                                 {
 580                                         // new item: fade in
 581                                         menuTooltipState = 1;
 582                                         menuTooltipItem = it;
 583
 584                                         menuTooltipOrigin.x = -1;  // unallocated
 585
 586                                         strcpy(menuTooltipText, gettooltip());
 587
 588                                         int i = 0;
 589                                         float w = 0;
 590                                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i)
 591                                         {
 592                                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 593                                                 if (i == 16)
 594                                                         s = "...";
 595                                                 float f = draw_TextWidth(s, false, fontsize);
 596                                                 if (f > w) w = f;
 597                                         }
 598                                         menuTooltipSize.x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 599                                         menuTooltipSize.y = i * fontsize.y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 600                                         menuTooltipSize.z = 0;
 601                                 }
 602                                 break;
 603                         case 1:
 604                                 // changing item while fading in: fade out first
 605                                 menuTooltipState = 2;
 606                                 break;
 607                         case 2:
 608                                 // changing item while fading out: can't
 609                                 break;
 610                 }
 611         }
 612         else if (menuTooltipState == 2)  // re-fade in?
 613         {
 614                 menuTooltipState = 1;
 615         }
 616
 617         switch (menuTooltipState)
 618         {
 619                 case 1:  // fade in
 620                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 621                         if (menuTooltipAlpha == 1) menuTooltipState = 0;
 622                         break;
 623                 case 2:  // fade out
 624                 case 3:  // forced fade out
 625                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 626                         if (menuTooltipAlpha == 0)
 627                         {
 628                                 menuTooltipState = 0;
 629                                 menuTooltipItem = NULL;
 630                         }
 631                         break;
 632         }
 633
 634         if (menuTooltipItem == NULL)
 635         {
 636                 strfree(menuTooltipText);
 637                 return;
 638         }
 639         else
 640         {
 641                 if (menu_tooltips != menu_tooltips_old)
 642                 {
 643                         if (menu_tooltips != 0 && menu_tooltips_old != 0) menuTooltipItem = NULL; // reload tooltip next frame
 644                         menu_tooltips_old = menu_tooltips;
 645                 }
 646                 else if (menuTooltipOrigin.x < 0)                                             // unallocated?
 647                 {
 648                         m_allocatetooltipbox(pos);
 649                 }
 650                 if (menuTooltipOrigin.x >= 0)
 651                 {
 652                         // draw the tooltip!
 653                         vector p = SKINBORDER_TOOLTIP;
 654                         p.x *= 1 / conwidth;
 655                         p.y *= 1 / conheight;
 656                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 657                         p = menuTooltipOrigin;
 658                         p.x += SKINMARGIN_TOOLTIP_x / conwidth;
 659                         p.y += SKINMARGIN_TOOLTIP_y / conheight;
 660                         int i = 0;
 661                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i, p.y += fontsize.y)
 662                         {
 663                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 664                                 if (i == 16)
 665                                         s = "...";
 666                                 draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, false);
 667                         }
 668                 }
 669         }
 670 }
 671
 672 float autocvar_menu_force_on_disconnection;
 673 void m_draw(float width, float height)
 674 {
 675         if (autocvar_menu_force_on_disconnection > 0)
 676         {
 677                 static float connected_time;
 678                 if (clientstate() == CS_DISCONNECTED)
 679                 {
 680                         if (connected_time && time - connected_time > autocvar_menu_force_on_disconnection)
 681                         {
 682                                 m_toggle(true);
 683                                 connected_time = 0;
 684                         }
 685                 }
 686                 else
 687                         connected_time = time;
 688         }
 689
 690         m_gamestatus();
 691
 692         execute_next_frame();
 693
 694         menuMouseMode = cvar("menu_mouse_absolute");
 695
 696         if (anim) anim.tickAll(anim);
 697
 698         UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));
 699
 700         if (!menuInitialized)
 701         {
 702                 // TODO draw an info image about this situation
 703                 m_init_delayed();
 704                 return;
 705         }
 706         if (!menuNotTheFirstFrame)
 707         {
 708                 menuNotTheFirstFrame = true;
 709                 if (Menu_Active && !cvar("menu_video_played"))
 710         {
 711             localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.wav\n");
 712             menuLogoAlpha = -0.8;  // no idea why, but when I start this at zero, it jumps instead of fading FIXME
 713         }
 714                 // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
 715                 localcmd("set menu_video_played 1\n");
 716         }
 717
 718         float t = gettime();
 719         float realFrametime = frametime = min(0.2, t - menuPrevTime);
 720         menuPrevTime = t;
 721         time += frametime;
 722
 723         t = cvar("menu_slowmo");
 724         if (t)
 725         {
 726                 frametime *= t;
 727                 realFrametime *= t;
 728         }
 729         else
 730         {
 731                 t = 1;
 732         }
 733
 734         if (Menu_Active)
 735         {
 736                 if (getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU)
 737                     && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 738                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 739                 else m_hide();
 740         }
 741
 742         if (cvar("cl_capturevideo")) frametime = t / cvar("cl_capturevideo_fps");  // make capturevideo work smoothly
 743
 744         prevMenuAlpha = menuAlpha;
 745         if (Menu_Active)
 746         {
 747                 if (menuAlpha == 0 && menuLogoAlpha < 2)
 748                 {
 749                         menuLogoAlpha += 2 * frametime;
 750                 }
 751                 else
 752                 {
 753                         menuAlpha = min(1, menuAlpha + 5 * frametime);
 754                         menuLogoAlpha = 2;
 755                 }
 756         }
 757         else
 758         {
 759                 menuAlpha = max(0, menuAlpha - 5 * frametime);
 760                 menuLogoAlpha = 2;
 761         }
 762
 763         draw_reset_cropped();
 764
 765         if (!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 766         {
 767                 if (menuLogoAlpha > 0)
 768                 {
 769                         draw_reset_full();
 770                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
 771                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, true);
 772                         draw_reset_cropped();
 773                         if (menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 774                         {
 775                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 776                                 draw_drawMousePointer(menuMousePos);
 777                                 draw_alpha = 1;
 778                         }
 779                 }
 780         }
 781         else if (SKINALPHA_BACKGROUND_INGAME)
 782         {
 783                 if (menuAlpha > 0)
 784                 {
 785                         draw_reset_full();
 786                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME,
 787                                 SKINALIGN_BACKGROUND_INGAME, false);
 788                         draw_reset_cropped();
 789                 }
 790         }
 791
 792         if (menuAlpha != prevMenuAlpha) cvar_set("_menu_alpha", ftos(menuAlpha));
 793
 794         draw_reset_cropped();
 795         preMenuDraw();
 796         draw_reset_cropped();
 797
 798         if (menuAlpha <= 0)
 799         {
 800                 if (prevMenuAlpha > 0) main.initializeDialog(main, main.firstChild);
 801                 draw_reset_cropped();
 802                 postMenuDraw();
 803                 return;
 804         }
 805
 806         draw_alpha *= menuAlpha;
 807
 808         if (menuMouseMode)
 809         {
 810                 vector rawMousePos = getmousepos();
 811                 vector newMouse = globalToBox(rawMousePos, draw_shift, draw_scale);
 812                 if (rawMousePos != '0 0 0' && newMouse != menuMousePos)
 813                 {
 814                         menuMousePos = newMouse;
 815                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 816                         else main.mouseMove(main, menuMousePos);
 817                 }
 818         }
 819         else if (frametime > 0)
 820         {
 821                 vector dMouse = getmousepos() * (frametime / realFrametime);  // for capturevideo
 822                 if (dMouse != '0 0 0')
 823                 {
 824                         vector minpos = globalToBox('0 0 0', draw_shift, draw_scale);
 825                         vector maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
 826                         dMouse = globalToBoxSize(dMouse, draw_scale);
 827                         menuMousePos += dMouse * cvar("menu_mouse_speed");
 828                         menuMousePos.x = bound(minpos.x, menuMousePos.x, maxpos.x);
 829                         menuMousePos.y = bound(minpos.y, menuMousePos.y, maxpos.y);
 830                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 831                         else main.mouseMove(main, menuMousePos);
 832                 }
 833         }
 834         main.draw(main);
 835
 836         m_tooltip(menuMousePos);
 837
 838         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 839
 840         draw_drawMousePointer(menuMousePos);
 841
 842         draw_reset_cropped();
 843         postMenuDraw();
 844
 845         frametime = 0;
 846         IL_ENDFRAME();
 847 }
 848
 849 void m_display()
 850 {
 851         Menu_Active = true;
 852         setkeydest(KEY_MENU);
 853         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 854
 855         if (!menuInitialized) return;
 856
 857         if (mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 858         mouseButtonsPressed = 0;
 859
 860         main.focusEnter(main);
 861         main.showNotify(main);
 862 }
 863
 864 void m_hide()
 865 {
 866         Menu_Active = false;
 867         setkeydest(KEY_GAME);
 868         setmousetarget(MT_CLIENT);
 869
 870         if (!menuInitialized) return;
 871
 872         main.focusLeave(main);
 873         main.hideNotify(main);
 874 }
 875
 876 void m_toggle(int mode)
 877 {
 878         if (Menu_Active)
 879         {
 880                 if (mode == 1) return;
 881                 m_hide();
 882         }
 883         else
 884         {
 885                 if (mode == 0) return;
 886                 m_display();
 887         }
 888 }
 889
 890 void Shutdown()
 891 {
 892         m_hide();
 893         FOREACH_ENTITY_ORDERED(it.destroy, {
 894                 if (it.classname == "vtbl") continue;
 895                 it.destroy(it);
 896         });
 897 }
 898
 899 void m_focus_item_chain(entity outermost, entity innermost)
 900 {
 901         if (innermost.parent != outermost) m_focus_item_chain(outermost, innermost.parent);
 902         innermost.parent.setFocus(innermost.parent, innermost);
 903 }
 904
 905 void m_activate_window(entity wnd)
 906 {
 907         entity par = wnd.parent;
 908         if (par) m_activate_window(par);
 909
 910         if (par.instanceOfModalController)
 911         {
 912                 if (wnd.tabSelectingButton)
 913                         // tabs
 914                         TabButton_Click(wnd.tabSelectingButton, wnd);
 915                 else
 916                         // root
 917                         par.initializeDialog(par, wnd);
 918         }
 919         else if (par.instanceOfNexposee)
 920         {
 921                 // nexposee (sorry for violating abstraction here)
 922                 par.selectedChild = wnd;
 923                 par.animationState = 1;
 924                 Container_setFocus(par, NULL);
 925         }
 926         else if (par.instanceOfContainer)
 927         {
 928                 // other containers
 929                 if (par.focused) par.setFocus(par, wnd);
 930         }
 931 }
 932
 933 void m_setpointerfocus(entity wnd)
 934 {
 935         if (!wnd.instanceOfContainer) return;
 936         entity focus = wnd.preferredFocusedGrandChild(wnd);
 937         if (!focus) return;
 938         menuMousePos = focus.origin + 0.5 * focus.size;
 939         menuMousePos.x *= 1 / conwidth;
 940         menuMousePos.y *= 1 / conheight;
 941         entity par = wnd.parent;
 942         if (par.focused) par.setFocus(par, wnd);
 943         if (wnd.focused) m_focus_item_chain(wnd, focus);
 944 }
 945
 946 void m_goto(string itemname)
 947 {
 948         if (!menuInitialized)
 949         {
 950                 strcpy(m_goto_buffer, itemname);
 951                 return;
 952         }
 953         if (itemname == "")  // this can be called by GameCommand
 954         {
 955                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 956                 {
 957                         m_hide();
 958                 }
 959                 else
 960                 {
 961                         m_activate_window(main.mainNexposee);
 962                         m_display();
 963                 }
 964         }
 965         else
 966         {
 967                 entity e;
 968                 for (e = NULL; (e = find(e, name, itemname)); )
 969                         if (e.classname != "vtbl") break;
 970
 971                 if ((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
 972                 {
 973                         if(!Menu_Active)
 974                                 e.hideMenuOnClose = true;
 975                         m_hide();
 976                         m_activate_window(e);
 977                         m_setpointerfocus(e);
 978                         m_display();
 979                 }
 980         }
 981 }
 982
 983 void m_play_focus_sound()
 984 {
 985         static float menuLastFocusSoundTime;
 986         if (cvar("menu_sounds") < 2) return;
 987         if (time - menuLastFocusSoundTime <= 0.25) return;
 988         localsound(MENU_SOUND_FOCUS);
 989         menuLastFocusSoundTime = time;
 990 }
 991
 992 void m_play_click_sound(string soundfile)
 993 {
 994         if (!cvar("menu_sounds")) return;
 995         localsound(soundfile);
 996 }