qcsrc/menu/xonotic/cvarlist.qc

   1 #include "cvarlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "../item/checkbox.qh"
   5 #include "../item/container.qh"
   6 #include "../item/checkbox.qh"
   7
   8 entity makeXonoticCvarList()
   9 {
  10         entity me;
  11         me = NEW(XonoticCvarList);
  12         me.configureXonoticCvarList(me);
  13         return me;
  14 }
  15 void XonoticCvarList_configureXonoticCvarList(entity me)
  16 {
  17         me.configureXonoticListBox(me);
  18         me.handle = buf_create();
  19         me.nItems = 0;
  20 }
  21 void CvarList_Load(entity me, string filter)
  22 {
  23         if(me.handle < 0)
  24                 return;
  25
  26         buf_cvarlist(me.handle, filter, "_");
  27         me.nItems = buf_getsize(me.handle);
  28         if(autocvar_menu_cvarlist_onlymodified)
  29         {
  30                 float newbuf = buf_create();
  31                 for (int i = 0; i < me.nItems; ++i)
  32                 {
  33                         string k = bufstr_get(me.handle, i);
  34                         if(cvar_string(k) != cvar_defstring(k))
  35                                 bufstr_add(newbuf, k, false);
  36                 }
  37                 buf_del(me.handle);
  38                 me.handle = newbuf;
  39                 me.nItems = buf_getsize(me.handle);
  40         }
  41 }
  42 void XonoticCvarList_showNotify(entity me)
  43 {
  44         bool force_initial_selection = false;
  45         if(me.handle >= 0 && me.nItems <= 0) // me.handle not loaded yet?
  46                 force_initial_selection = true;
  47         CvarList_Load(me, me.controlledTextbox.text);
  48         if(force_initial_selection)
  49                 me.setSelected(me, 0);
  50 }
  51 void XonoticCvarList_hideNotify(entity me)
  52 {
  53         if(me.handle)
  54                 buf_del(me.handle);
  55         me.handle = buf_create();
  56         me.nItems = 0;
  57 }
  58 void XonoticCvarList_destroy(entity me)
  59 {
  60         if(me.handle)
  61                 buf_del(me.handle);
  62 }
  63 string autocvar_menu_forced_saved_cvars;
  64 string autocvar_menu_reverted_nonsaved_cvars;
  65 float XonoticCvarList_updateCvarType(entity me)
  66 {
  67         float t;
  68         t = cvar_type(me.cvarName);
  69         me.cvarType = "";
  70         float needsForcing;
  71         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
  72         {
  73                 me.cvarType = strcat(me.cvarType, ", ", _("forced to be saved to config.cfg"));
  74                 needsForcing = 0;
  75         }
  76         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, me.cvarName))
  77         {
  78                 // Currently claims to be saved, but won't be on next startup.
  79                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  80                 needsForcing = 1;
  81         }
  82         else if(t & CVAR_TYPEFLAG_SAVED)
  83         {
  84                 me.cvarType = strcat(me.cvarType, ", ", _("will be saved to config.cfg"));
  85                 needsForcing = 0;
  86         }
  87         else
  88         {
  89                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  90                 needsForcing = 1;
  91         }
  92         if(t & CVAR_TYPEFLAG_PRIVATE)
  93                 me.cvarType = strcat(me.cvarType, ", ", _("private"));
  94         if(t & CVAR_TYPEFLAG_ENGINE)
  95                 me.cvarType = strcat(me.cvarType, ", ", _("engine setting"));
  96         if(t & CVAR_TYPEFLAG_READONLY)
  97                 me.cvarType = strcat(me.cvarType, ", ", _("read only"));
  98         me.cvarType = strzone(substring(me.cvarType, 2, strlen(me.cvarType) - 2));
  99         me.cvarTypeBox.setText(me.cvarTypeBox, me.cvarType);
 100         return needsForcing;
 101 }
 102 void XonoticCvarList_setSelected(entity me, float i)
 103 {
 104         string s;
 105
 106         SUPER(XonoticCvarList).setSelected(me, i);
 107         if(me.nItems == 0)
 108                 return;
 109
 110         if(me.cvarType)
 111                 strunzone(me.cvarType);
 112         strcpy(me.cvarName, bufstr_get(me.handle, me.selectedItem));
 113         strcpy(me.cvarDescription, cvar_description(me.cvarName));
 114         strcpy(me.cvarDefault, cvar_defstring(me.cvarName));
 115         me.cvarNameBox.setText(me.cvarNameBox, me.cvarName);
 116         me.cvarDescriptionBox.setText(me.cvarDescriptionBox, me.cvarDescription);
 117         float needsForcing = me.updateCvarType(me);
 118         me.cvarDefaultBox.setText(me.cvarDefaultBox, me.cvarDefault);
 119
 120         // this one can handle tempstrings
 121         s = cvar_string(me.cvarName);
 122         me.cvarNeedsForcing = 0;
 123         me.cvarValueBox.setText(me.cvarValueBox, s);
 124         me.cvarNeedsForcing = needsForcing;
 125         me.cvarValueBox.cursorPos = strlen(s);
 126 }
 127 void CvarList_Filter_Change(entity box, entity me)
 128 {
 129         CvarList_Load(me, box.text);
 130         me.setSelected(me, 0);
 131 }
 132 void CvarList_Filter_ModifiedCvars(entity box, entity me)
 133 {
 134         cvar_set("menu_cvarlist_onlymodified", ftos(!autocvar_menu_cvarlist_onlymodified));
 135         box.setChecked(box, autocvar_menu_cvarlist_onlymodified);
 136         CvarList_Load(me, me.controlledTextbox.text);
 137         me.setSelected(me, 0);
 138 }
 139 void XonoticCvarList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 140 {
 141         SUPER(XonoticCvarList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 142
 143         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 144         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 145         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 146
 147         me.columnNameOrigin = 0;
 148         me.columnValueSize = me.realFontSize.x * 20;
 149         me.columnNameSize = 1 - me.columnValueSize - me.realFontSize.x;
 150         me.columnValueOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 151 }
 152 void XonoticCvarList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 153 {
 154         string k, v, d;
 155         float t;
 156
 157         vector theColor;
 158         float theAlpha;
 159
 160         string s;
 161
 162         if(isSelected)
 163                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 164         else if(isFocused)
 165         {
 166                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 167                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 168         }
 169
 170         k = bufstr_get(me.handle, i);
 171
 172         v = cvar_string(k);
 173         d = cvar_defstring(k);
 174         t = cvar_type(k);
 175         if(strhasword(autocvar_menu_forced_saved_cvars, k))
 176                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 177         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, k))
 178                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 179         else if(t & CVAR_TYPEFLAG_SAVED)
 180                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 181         else
 182                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 183         if(v == d)
 184                 theColor = SKINCOLOR_CVARLIST_UNCHANGED;
 185         else
 186                 theColor = SKINCOLOR_CVARLIST_CHANGED;
 187
 188         s = draw_TextShortenToWidth(k, me.columnNameSize, 0, me.realFontSize);
 189         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 190         s = draw_TextShortenToWidth(v, me.columnValueSize, 0, me.realFontSize);
 191         draw_Text(me.realUpperMargin * eY + me.columnValueOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 192 }
 193
 194 float XonoticCvarList_keyDown(entity me, float scan, float ascii, float shift)
 195 {
 196         if (scan == K_MOUSE3 || ((shift & S_CTRL) && scan == K_SPACE))
 197         {
 198                 CvarList_Revert_Click(NULL, me);
 199                 return 1;
 200         }
 201         else if(scan == K_ENTER)
 202         {
 203                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 204                 return 1;
 205         }
 206         else if(SUPER(XonoticCvarList).keyDown(me, scan, ascii, shift))
 207                 return 1;
 208         else if(!me.controlledTextbox)
 209                 return 0;
 210         else
 211                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
 212 }
 213
 214 float XonoticCvarList_mouseRelease(entity me, vector pos)
 215 {
 216         if(me.pressed == 2)
 217                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 218         return SUPER(XonoticCvarList).mouseRelease(me, pos);
 219 }
 220
 221 void CvarList_Value_Change(entity box, entity me)
 222 {
 223         cvar_set(me.cvarNameBox.text, box.text);
 224         if(me.cvarNeedsForcing)
 225         {
 226                 localcmd(sprintf("\nseta %1$s \"$%1$s\"\n", me.cvarName));
 227                 cvar_set("menu_reverted_nonsaved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_reverted_nonsaved_cvars, " ")), 1, -2));
 228                 if (autocvar_menu_forced_saved_cvars == "")
 229                         cvar_set("menu_forced_saved_cvars", me.cvarName);
 230                 else
 231                         cvar_set("menu_forced_saved_cvars", strcat(autocvar_menu_forced_saved_cvars, " ", me.cvarName));
 232                 me.cvarNeedsForcing = 0;
 233                 me.updateCvarType(me);
 234         }
 235 }
 236
 237 void CvarList_Revert_Click(entity btn, entity me)
 238 {
 239         me.cvarValueBox.setText(me.cvarValueBox, me.cvarDefault);
 240         me.cvarValueBox.cursorPos = strlen(me.cvarDefault);
 241         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
 242         {
 243                 cvar_set("menu_forced_saved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_forced_saved_cvars, " ")), 1, -2));
 244                 if (autocvar_menu_reverted_nonsaved_cvars == "")
 245                         cvar_set("menu_reverted_nonsaved_cvars", me.cvarName);
 246                 else
 247                         cvar_set("menu_reverted_nonsaved_cvars", strcat(autocvar_menu_reverted_nonsaved_cvars, " ", me.cvarName));
 248         }
 249         me.cvarNeedsForcing = me.updateCvarType(me);
 250 }
 251
 252 void CvarList_End_Editing(entity box, entity me)
 253 {
 254         box.parent.setFocus(box.parent, me);
 255 }