qcsrc/menu/xonotic/hudskinlist.qc

   1 #ifndef HUDSKINLIST_H
   2 #define HUDSKINLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticHUDSkinList, XonoticListBox)
   5         METHOD(XonoticHUDSkinList, configureXonoticHUDSkinList, void(entity));
   6         ATTRIB(XonoticHUDSkinList, rowsPerItem, float, 1)
   7         METHOD(XonoticHUDSkinList, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(XonoticHUDSkinList, draw, void(entity));
   9         METHOD(XonoticHUDSkinList, drawListBoxItem, void(entity, int, vector, bool, bool));
  10         METHOD(XonoticHUDSkinList, getHUDSkins, void(entity));
  11         METHOD(XonoticHUDSkinList, setHUDSkin, void(entity));
  12         METHOD(XonoticHUDSkinList, hudskinName, string(entity, float));
  13         METHOD(XonoticHUDSkinList, hudskinPath, string(entity, float));
  14         METHOD(XonoticHUDSkinList, hudskinTitle, string(entity, float));
  15         METHOD(XonoticHUDSkinList, hudskinAuthor, string(entity, float));
  16         METHOD(XonoticHUDSkinList, doubleClickListBoxItem, void(entity, float, vector));
  17         METHOD(XonoticHUDSkinList, keyDown, float(entity, float, float, float));
  18         METHOD(XonoticHUDSkinList, destroy, void(entity));
  19         METHOD(XonoticHUDSkinList, showNotify, void(entity));
  20
  21         ATTRIB(XonoticHUDSkinList, listHUDSkin, float, -1)
  22         ATTRIB(XonoticHUDSkinList, realFontSize, vector, '0 0 0')
  23         ATTRIB(XonoticHUDSkinList, columnNameOrigin, float, 0)
  24         ATTRIB(XonoticHUDSkinList, columnNameSize, float, 0)
  25         ATTRIB(XonoticHUDSkinList, realUpperMargin, float, 0)
  26         ATTRIB(XonoticHUDSkinList, origin, vector, '0 0 0')
  27         ATTRIB(XonoticHUDSkinList, itemAbsSize, vector, '0 0 0')
  28
  29         ATTRIB(XonoticHUDSkinList, filterString, string, string_null)
  30         ATTRIB(XonoticHUDSkinList, delayedRefreshTime, float, 0)
  31         ATTRIB(XonoticHUDSkinList, savedName, string, string_null)
  32 ENDCLASS(XonoticHUDSkinList)
  33
  34 #ifndef IMPLEMENTATION
  35 // public:
  36 entity hudskinlist;
  37 entity makeXonoticHUDSkinList();
  38 void SaveHUDSkin_Click(entity btn, entity me);
  39 void SetHUDSkin_Click(entity btn, entity me);
  40 #endif
  41 void HUDSkinList_Refresh_Click(entity btn, entity me);
  42 void HUDSkinList_Filter_Change(entity box, entity me);
  43 void HUDSkinList_SavedName_Change(entity box, entity me);
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47
  48 entity makeXonoticHUDSkinList()
  49 {
  50         entity me;
  51         me = NEW(XonoticHUDSkinList);
  52         me.configureXonoticHUDSkinList(me);
  53         return me;
  54 }
  55
  56 void XonoticHUDSkinList_configureXonoticHUDSkinList(entity me)
  57 {
  58         me.configureXonoticListBox(me);
  59         me.getHUDSkins(me);
  60 }
  61
  62 const float HUDSKINPARM_NAME = 0;
  63 const float HUDSKINPARM_PATH = 1;
  64 const float HUDSKINPARM_TITLE = 2;
  65 const float HUDSKINPARM_AUTHOR = 3;
  66 const float HUDSKINPARM_COUNT = 4;
  67 string XonoticHUDSkinList_hudskinName(entity me, float i)
  68 {
  69         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_NAME);
  70 }
  71 string XonoticHUDSkinList_hudskinPath(entity me, float i)
  72 {
  73         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_PATH);
  74 }
  75 string XonoticHUDSkinList_hudskinTitle(entity me, float i)
  76 {
  77         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_TITLE);
  78 }
  79 string XonoticHUDSkinList_hudskinAuthor(entity me, float i)
  80 {
  81         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_AUTHOR);
  82 }
  83
  84 void getAllHUDSkins(entity me, string subdir)
  85 {
  86         string s;
  87         if(me.filterString)
  88                 s = me.filterString;
  89         else
  90                 s = "*";
  91         s = strcat(subdir, "hud_", s, ".cfg");
  92         float strlen_subdir = strlen(subdir);
  93         subdir = strzone(subdir);
  94
  95         float list, i, n;
  96         list = search_begin(s, false, true);
  97         if(list >= 0)
  98         {
  99                 string filename;
 100                 n = search_getsize(list);
 101                 int bufsize = buf_getsize(me.listHUDSkin);
 102                 for(i = 0; i < n; ++i)
 103                 {
 104                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_PATH, subdir);
 105                         filename = search_getfilename(list, i);
 106                         s = substring(filename, strlen_subdir + 4, (strlen(filename) - strlen_subdir - 4 - 4)); // remove "hud_" prefix and ".cfg" suffix
 107                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_NAME, s);
 108
 109                         int fh = fopen(filename, FILE_READ);
 110                         if(fh < 0)
 111                                 continue;
 112                         while((s = fgets(fh)) && substring(s, 0, 2) == "//")
 113                         {
 114                                 tokenize_console(substring(s, 2, -1));
 115                                 if(argv(0) == "title")
 116                                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_TITLE, argv(1));
 117                                 else if(argv(0) == "author")
 118                                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_AUTHOR, argv(1));
 119                         }
 120                         fclose(fh);
 121                 }
 122                 search_end(list);
 123         }
 124         if(subdir)
 125                 strunzone(subdir);
 126 }
 127
 128 void XonoticHUDSkinList_getHUDSkins(entity me)
 129 {
 130         if (me.listHUDSkin >= 0)
 131                 buf_del(me.listHUDSkin);
 132         me.listHUDSkin = buf_create();
 133         if (me.listHUDSkin < 0)
 134         {
 135                 me.nItems = 0;
 136                 return;
 137         }
 138         getAllHUDSkins(me, "");
 139         getAllHUDSkins(me, "data/");
 140         me.nItems = buf_getsize(me.listHUDSkin) / HUDSKINPARM_COUNT;
 141 }
 142
 143 void XonoticHUDSkinList_destroy(entity me)
 144 {
 145         if(me.nItems > 0)
 146                 buf_del(me.listHUDSkin);
 147 }
 148
 149 void XonoticHUDSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 150 {
 151         me.itemAbsSize = '0 0 0';
 152         SUPER(XonoticHUDSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 153
 154         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 155         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 156         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 157
 158         me.columnNameOrigin = me.realFontSize.x;
 159         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 160 }
 161
 162 void XonoticHUDSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 163 {
 164         string s, s2;
 165         if(isSelected)
 166                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 167         else if(isFocused)
 168         {
 169                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 170                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 171         }
 172
 173         s = me.hudskinTitle(me, i);
 174         if(s == "")
 175                 s = me.hudskinName(me, i);
 176         s2 = me.hudskinAuthor(me, i);
 177         if(s2 != "")
 178                 s = strcat(s, " (", s2, ")");
 179         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 180         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 1);
 181 }
 182
 183 void XonoticHUDSkinList_showNotify(entity me)
 184 {
 185         me.getHUDSkins(me);
 186 }
 187
 188 void HUDSkinList_Refresh_Click(entity btn, entity me)
 189 {
 190         me.getHUDSkins(me);
 191         me.setSelected(me, 0); //always select the first element after a list update
 192 }
 193
 194 void HUDSkinList_SavedName_Change(entity box, entity me)
 195 {
 196         if(me.savedName)
 197                 strunzone(me.savedName);
 198
 199         if(box.text != "")
 200                 me.savedName = strzone(box.text);
 201         else
 202                 me.savedName = string_null;
 203 }
 204
 205 void HUDSkinList_Filter_Change(entity box, entity me)
 206 {
 207         if(me.filterString)
 208                 strunzone(me.filterString);
 209
 210         if(box.text != "")
 211         {
 212                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 213                         me.filterString = strzone(box.text);
 214                 else
 215                         me.filterString = strzone(strcat("*", box.text, "*"));
 216         }
 217         else
 218                 me.filterString = string_null;
 219
 220         me.getHUDSkins(me);
 221 }
 222
 223 void SaveHUDSkin_Click(entity btn, entity me)
 224 {
 225         string s = me.savedName;
 226         if(s == "")
 227                 s = "myconfig";
 228         localcmd(sprintf("hud save \"%s\"\n", s));
 229         me.delayedRefreshTime = time + 1;
 230 }
 231
 232 void XonoticHUDSkinList_draw(entity me)
 233 {
 234         if(me.delayedRefreshTime > 0 && me.delayedRefreshTime < time)
 235         {
 236                 HUDSkinList_Refresh_Click(NULL, me);
 237                 me.delayedRefreshTime = 0;
 238         }
 239         SUPER(XonoticHUDSkinList).draw(me);
 240 }
 241
 242 void XonoticHUDSkinList_setHUDSkin(entity me)
 243 {
 244         string cfg = strcat(me.hudskinPath(me, me.selectedItem), "hud_", me.hudskinName(me, me.selectedItem), ".cfg");
 245         localcmd("exec \"", cfg, "\"\n");
 246 }
 247
 248 void SetHUDSkin_Click(entity btn, entity me)
 249 {
 250         me.setHUDSkin(me);
 251 }
 252
 253 void XonoticHUDSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 254 {
 255         m_play_click_sound(MENU_SOUND_EXECUTE);
 256         me.setHUDSkin(me);
 257 }
 258
 259 float XonoticHUDSkinList_keyDown(entity me, float scan, float ascii, float shift)
 260 {
 261         if(scan == K_ENTER || scan == K_KP_ENTER)
 262         {
 263                 me.setHUDSkin(me);
 264                 return 1;
 265         }
 266         else
 267         {
 268                 return SUPER(XonoticHUDSkinList).keyDown(me, scan, ascii, shift);
 269         }
 270 }
 271 #endif
 272