qcsrc/menu/xonotic/hudskinlist.qc

   1 #ifndef HUDSKINLIST_H
   2 #define HUDSKINLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticHUDSkinList, XonoticListBox)
   5         METHOD(XonoticHUDSkinList, configureXonoticHUDSkinList, void(entity));
   6         ATTRIB(XonoticHUDSkinList, rowsPerItem, float, 1)
   7         METHOD(XonoticHUDSkinList, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(XonoticHUDSkinList, draw, void(entity));
   9         METHOD(XonoticHUDSkinList, drawListBoxItem, void(entity, int, vector, bool, bool));
  10         METHOD(XonoticHUDSkinList, getHUDSkins, void(entity));
  11         METHOD(XonoticHUDSkinList, setHUDSkin, void(entity));
  12         METHOD(XonoticHUDSkinList, hudskinName, string(entity, float));
  13         METHOD(XonoticHUDSkinList, hudskinPath, string(entity, float));
  14         METHOD(XonoticHUDSkinList, hudskinTitle, string(entity, float));
  15         METHOD(XonoticHUDSkinList, hudskinAuthor, string(entity, float));
  16         METHOD(XonoticHUDSkinList, doubleClickListBoxItem, void(entity, float, vector));
  17         METHOD(XonoticHUDSkinList, keyDown, float(entity, float, float, float));
  18         METHOD(XonoticHUDSkinList, destroy, void(entity));
  19         METHOD(XonoticHUDSkinList, showNotify, void(entity));
  20
  21         ATTRIB(XonoticHUDSkinList, listHUDSkin, float, -1)
  22         ATTRIB(XonoticHUDSkinList, realFontSize, vector, '0 0 0')
  23         ATTRIB(XonoticHUDSkinList, columnNameOrigin, float, 0)
  24         ATTRIB(XonoticHUDSkinList, columnNameSize, float, 0)
  25         ATTRIB(XonoticHUDSkinList, realUpperMargin, float, 0)
  26         ATTRIB(XonoticHUDSkinList, origin, vector, '0 0 0')
  27         ATTRIB(XonoticHUDSkinList, itemAbsSize, vector, '0 0 0')
  28
  29         ATTRIB(XonoticHUDSkinList, filterString, string, string_null)
  30         ATTRIB(XonoticHUDSkinList, delayedRefreshTime, float, 0)
  31 ENDCLASS(XonoticHUDSkinList)
  32
  33 #ifndef IMPLEMENTATION
  34 // public:
  35 entity hudskinlist;
  36 entity makeXonoticHUDSkinList();
  37 void SaveHUDSkin_Click(entity btn, entity me);
  38 void SetHUDSkin_Click(entity btn, entity me);
  39 #endif
  40 void HUDSkinList_Refresh_Click(entity btn, entity me);
  41 void HUDSkinList_Filter_Change(entity box, entity me);
  42 #endif
  43
  44 #ifdef IMPLEMENTATION
  45
  46 entity makeXonoticHUDSkinList()
  47 {
  48         entity me;
  49         me = NEW(XonoticHUDSkinList);
  50         me.configureXonoticHUDSkinList(me);
  51         return me;
  52 }
  53
  54 void XonoticHUDSkinList_configureXonoticHUDSkinList(entity me)
  55 {
  56         me.configureXonoticListBox(me);
  57         me.getHUDSkins(me);
  58 }
  59
  60 const float HUDSKINPARM_NAME = 0;
  61 const float HUDSKINPARM_PATH = 1;
  62 const float HUDSKINPARM_TITLE = 2;
  63 const float HUDSKINPARM_AUTHOR = 3;
  64 const float HUDSKINPARM_COUNT = 4;
  65 string XonoticHUDSkinList_hudskinName(entity me, float i)
  66 {
  67         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_NAME);
  68 }
  69 string XonoticHUDSkinList_hudskinPath(entity me, float i)
  70 {
  71         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_PATH);
  72 }
  73 string XonoticHUDSkinList_hudskinTitle(entity me, float i)
  74 {
  75         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_TITLE);
  76 }
  77 string XonoticHUDSkinList_hudskinAuthor(entity me, float i)
  78 {
  79         return bufstr_get(me.listHUDSkin, i * HUDSKINPARM_COUNT + HUDSKINPARM_AUTHOR);
  80 }
  81
  82 void getAllHUDSkins(entity me, string subdir)
  83 {
  84         string s;
  85         if(me.filterString)
  86                 s = me.filterString;
  87         else
  88                 s = "*";
  89         s = strcat(subdir, "hud_", s, ".cfg");
  90         float strlen_subdir = strlen(subdir);
  91         subdir = strzone(subdir);
  92
  93         float list, i, n;
  94         list = search_begin(s, false, true);
  95         if(list >= 0)
  96         {
  97                 string filename;
  98                 n = search_getsize(list);
  99                 int bufsize = buf_getsize(me.listHUDSkin);
 100                 for(i = 0; i < n; ++i)
 101                 {
 102                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_PATH, subdir);
 103                         filename = search_getfilename(list, i);
 104                         s = substring(filename, strlen_subdir + 4, (strlen(filename) - strlen_subdir - 4 - 4)); // remove "hud_" prefix and ".cfg" suffix
 105                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_NAME, s);
 106
 107                         int fh = fopen(filename, FILE_READ);
 108                         if(fh < 0)
 109                                 continue;
 110                         while((s = fgets(fh)) && substring(s, 0, 2) == "//")
 111                         {
 112                                 tokenize_console(substring(s, 2, -1));
 113                                 if(argv(0) == "title")
 114                                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_TITLE, argv(1));
 115                                 else if(argv(0) == "author")
 116                                         bufstr_set(me.listHUDSkin, bufsize + i * HUDSKINPARM_COUNT + HUDSKINPARM_AUTHOR, argv(1));
 117                         }
 118                         fclose(fh);
 119                 }
 120                 search_end(list);
 121         }
 122         if(subdir)
 123                 strunzone(subdir);
 124 }
 125
 126 void XonoticHUDSkinList_getHUDSkins(entity me)
 127 {
 128         if (me.listHUDSkin >= 0)
 129                 buf_del(me.listHUDSkin);
 130         me.listHUDSkin = buf_create();
 131         if (me.listHUDSkin < 0)
 132         {
 133                 me.nItems = 0;
 134                 return;
 135         }
 136         getAllHUDSkins(me, "");
 137         getAllHUDSkins(me, "data/");
 138         me.nItems = buf_getsize(me.listHUDSkin) / HUDSKINPARM_COUNT;
 139 }
 140
 141 void XonoticHUDSkinList_destroy(entity me)
 142 {
 143         if(me.nItems > 0)
 144                 buf_del(me.listHUDSkin);
 145 }
 146
 147 void XonoticHUDSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 148 {
 149         me.itemAbsSize = '0 0 0';
 150         SUPER(XonoticHUDSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 151
 152         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 153         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 154         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 155
 156         me.columnNameOrigin = me.realFontSize.x;
 157         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 158 }
 159
 160 void XonoticHUDSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 161 {
 162         string s, s2;
 163         if(isSelected)
 164                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 165         else if(isFocused)
 166         {
 167                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 168                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 169         }
 170
 171         s = me.hudskinTitle(me, i);
 172         if(s == "")
 173                 s = me.hudskinName(me, i);
 174         s2 = me.hudskinAuthor(me, i);
 175         if(s2 != "")
 176                 s = strcat(s, " (", s2, ")");
 177         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 178         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 1);
 179 }
 180
 181 void XonoticHUDSkinList_showNotify(entity me)
 182 {
 183         me.getHUDSkins(me);
 184 }
 185
 186 void HUDSkinList_Refresh_Click(entity btn, entity me)
 187 {
 188         me.getHUDSkins(me);
 189         me.setSelected(me, 0); //always select the first element after a list update
 190 }
 191
 192 void HUDSkinList_Filter_Change(entity box, entity me)
 193 {
 194         if(me.filterString)
 195                 strunzone(me.filterString);
 196
 197         if(box.text != "")
 198         {
 199                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 200                         me.filterString = strzone(box.text);
 201                 else
 202                         me.filterString = strzone(strcat("*", box.text, "*"));
 203         }
 204         else
 205                 me.filterString = string_null;
 206
 207         me.getHUDSkins(me);
 208 }
 209
 210 void SaveHUDSkin_Click(entity btn, entity me)
 211 {
 212         localcmd("hud save myconfig\n");
 213         me.delayedRefreshTime = time + 1;
 214 }
 215
 216 void XonoticHUDSkinList_draw(entity me)
 217 {
 218         if(me.delayedRefreshTime > 0 && me.delayedRefreshTime < time)
 219         {
 220                 HUDSkinList_Refresh_Click(NULL, me);
 221                 me.delayedRefreshTime = 0;
 222         }
 223         SUPER(XonoticHUDSkinList).draw(me);
 224 }
 225
 226 void XonoticHUDSkinList_setHUDSkin(entity me)
 227 {
 228         string cfg = strcat(me.hudskinPath(me, me.selectedItem), "hud_", me.hudskinName(me, me.selectedItem), ".cfg");
 229         localcmd("exec \"", cfg, "\"\n");
 230 }
 231
 232 void SetHUDSkin_Click(entity btn, entity me)
 233 {
 234         me.setHUDSkin(me);
 235 }
 236
 237 void XonoticHUDSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 238 {
 239         m_play_click_sound(MENU_SOUND_EXECUTE);
 240         me.setHUDSkin(me);
 241 }
 242
 243 float XonoticHUDSkinList_keyDown(entity me, float scan, float ascii, float shift)
 244 {
 245         if(scan == K_ENTER || scan == K_KP_ENTER)
 246         {
 247                 me.setHUDSkin(me);
 248                 return 1;
 249         }
 250         else
 251         {
 252                 return SUPER(XonoticHUDSkinList).keyDown(me, scan, ascii, shift);
 253         }
 254 }
 255 #endif
 256