qcsrc/menu/xonotic/languagelist.qc

   1 #include "languagelist.qh"
   2 #ifndef LANGUAGELIST_H
   3 #define LANGUAGELIST_H
   4 #include "listbox.qc"
   5 CLASS(XonoticLanguageList, XonoticListBox)
   6         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity));
   7         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   8         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, int, vector, bool, bool));
   9         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector));
  10         METHOD(XonoticLanguageList, setSelected, void(entity, float));
  11         METHOD(XonoticLanguageList, loadCvars, void(entity));
  12         METHOD(XonoticLanguageList, saveCvars, void(entity));
  13
  14         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  15         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  18         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  19         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  20
  21         METHOD(XonoticLanguageList, doubleClickListBoxItem, void(entity, float, vector));
  22         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)); // enter handling
  23
  24         METHOD(XonoticLanguageList, destroy, void(entity));
  25
  26         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  27         METHOD(XonoticLanguageList, getLanguages, void(entity));
  28         METHOD(XonoticLanguageList, setLanguage, void(entity));
  29         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float));
  30
  31         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  32 ENDCLASS(XonoticLanguageList)
  33
  34 entity makeXonoticLanguageList();
  35 void SetLanguage_Click(entity btn, entity me);
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 const float LANGPARM_ID = 0;
  41 const float LANGPARM_NAME = 1;
  42 const float LANGPARM_NAME_LOCALIZED = 2;
  43 const float LANGPARM_PERCENTAGE = 3;
  44 const float LANGPARM_COUNT = 4;
  45
  46 entity makeXonoticLanguageList()
  47 {
  48         entity me;
  49         me = NEW(XonoticLanguageList);
  50         me.configureXonoticLanguageList(me);
  51         return me;
  52 }
  53
  54 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  55 {
  56         me.configureXonoticListBox(me);
  57         me.getLanguages(me);
  58         me.loadCvars(me);
  59 }
  60
  61 void XonoticLanguageList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  62 {
  63         string s, p;
  64         if(isSelected)
  65                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  66         else if(isFocused)
  67         {
  68                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  69                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  70         }
  71
  72         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  73
  74         vector save_fontscale = draw_fontscale;
  75         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
  76         draw_fontscale.x *= f;
  77         vector fs = me.realFontSize;
  78         fs.x *= f;
  79         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  80         draw_fontscale = save_fontscale;
  81
  82         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  83         if(p != "")
  84         {
  85                 vector save_fontscale = draw_fontscale;
  86                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
  87                 draw_fontscale.x *= f;
  88                 vector fs = me.realFontSize;
  89                 fs.x *= f;
  90                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  91                 draw_fontscale = save_fontscale;
  92         }
  93 }
  94
  95 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  96 {
  97         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  98         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  99         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 100         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 101         me.columnPercentageSize = me.realFontSize.x * 3;
 102         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
 103         me.columnNameOrigin = 0;
 104         me.columnNameSize = me.columnPercentageOrigin;
 105 }
 106
 107 void XonoticLanguageList_setSelected(entity me, float i)
 108 {
 109         SUPER(XonoticLanguageList).setSelected(me, i);
 110         me.saveCvars(me);
 111 }
 112
 113 void XonoticLanguageList_loadCvars(entity me)
 114 {
 115         string s;
 116         float i, n;
 117         s = cvar_string("_menu_prvm_language");
 118         n = me.nItems;
 119
 120         // default to English
 121         for(i = 0; i < n; ++i)
 122         {
 123                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 124                 {
 125                         SUPER(XonoticLanguageList).setSelected(me, i);
 126                         break;
 127                 }
 128         }
 129
 130         // otherwise, find the language
 131         for(i = 0; i < n; ++i)
 132         {
 133                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 134                 {
 135                         SUPER(XonoticLanguageList).setSelected(me, i);
 136                         break;
 137                 }
 138         }
 139
 140         // save it off (turning anything unknown into "en")
 141         me.saveCvars(me);
 142 }
 143
 144 void XonoticLanguageList_saveCvars(entity me)
 145 {
 146         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 147 }
 148
 149 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
 150 {
 151         m_play_click_sound(MENU_SOUND_EXECUTE);
 152         me.setLanguage(me);
 153 }
 154
 155 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 156 {
 157         if(scan == K_ENTER || scan == K_KP_ENTER)
 158         {
 159                 m_play_click_sound(MENU_SOUND_EXECUTE);
 160                 me.setLanguage(me);
 161                 return 1;
 162         }
 163         else
 164                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 165 }
 166
 167 void XonoticLanguageList_destroy(entity me)
 168 {
 169         buf_del(me.languagelist);
 170 }
 171
 172 void XonoticLanguageList_getLanguages(entity me)
 173 {
 174         float buf, i, n, fh;
 175         string s;
 176
 177         buf = buf_create();
 178
 179         fh = fopen("languages.txt", FILE_READ);
 180         i = 0;
 181         while((s = fgets(fh)))
 182         {
 183                 n = tokenize_console(s);
 184                 if(n < 3)
 185                         continue;
 186                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 187                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 188                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, argv(2));
 189                 string percent = argv(3);
 190                 if(percent && percent != "100%")
 191                         bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 192                 ++i;
 193         }
 194         fclose(fh);
 195
 196         me.languagelist = buf;
 197         me.nItems = i;
 198 }
 199
 200 void XonoticLanguageList_setLanguage(entity me)
 201 {
 202         if(prvm_language != cvar_string("_menu_prvm_language"))
 203         {
 204                 if(!(gamestatus & GAME_CONNECTED))
 205                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 206                 else
 207                         DialogOpenButton_Click(me, main.languageWarningDialog);
 208         }
 209 }
 210
 211 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 212 {
 213         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 214 }
 215
 216 void SetLanguage_Click(entity btn, entity me)
 217 {
 218         me.setLanguage(me);
 219 }
 220
 221 #endif