qcsrc/menu/xonotic/playlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticPlayList, configureXonoticPlayList, void(entity))
   4         ATTRIB(XonoticPlayList, rowsPerItem, float, 1)
   5         METHOD(XonoticPlayList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticPlayList, draw, void(entity))
   7         METHOD(XonoticPlayList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticPlayList, stopSound, void(entity))
   9         METHOD(XonoticPlayList, startSound, void(entity, float))
  10         METHOD(XonoticPlayList, pauseSound, void(entity))
  11         METHOD(XonoticPlayList, clickListBoxItem, void(entity, float, vector))
  12         METHOD(XonoticPlayList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticPlayList, mouseDrag, float(entity, vector))
  14
  15         METHOD(XonoticPlayList, addToPlayList, void(entity, string))
  16         METHOD(XonoticPlayList, removeFromPlayList, void(entity, string))
  17         ATTRIB(XonoticPlayList, playingTrack, string, string_null)
  18
  19         ATTRIB(XonoticPlayList, realFontSize, vector, '0 0 0')
  20         ATTRIB(XonoticPlayList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticPlayList, columnNameSize, float, 0)
  22         ATTRIB(XonoticPlayList, columnNumberOrigin, float, 0)
  23         ATTRIB(XonoticPlayList, columnNumberSize, float, 0)
  24         ATTRIB(XonoticPlayList, realUpperMargin, float, 0)
  25         ATTRIB(XonoticPlayList, origin, vector, '0 0 0')
  26         ATTRIB(XonoticPlayList, itemAbsSize, vector, '0 0 0')
  27
  28         ATTRIB(XonoticPlayList, lastClickedSound, float, -1)
  29         ATTRIB(XonoticPlayList, lastClickedTime, float, 0)
  30 ENDCLASS(XonoticPlayList)
  31
  32 entity makeXonoticPlayList();
  33 void StopSound_Click(entity btn, entity me);
  34 void StartSound_Click(entity btn, entity me);
  35 void PauseSound_Click(entity btn, entity me);
  36 void PrevSound_Click(entity btn, entity me);
  37 void NextSound_Click(entity btn, entity me);
  38 #endif
  39
  40 #ifdef IMPLEMENTATION
  41
  42 entity makeXonoticPlayList()
  43 {
  44         entity me;
  45         me = spawnXonoticPlayList();
  46         me.configureXonoticPlayList(me);
  47         return me;
  48 }
  49
  50 void XonoticPlayList_configureXonoticPlayList(entity me)
  51 {
  52         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  53         me.configureXonoticListBox(me);
  54 }
  55
  56 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  57 {
  58         me.itemAbsSize = '0 0 0';
  59         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  60
  61         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  62         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  63         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  64
  65         me.columnNumberOrigin = 0;
  66         me.columnNumberSize = 3 * me.realFontSize_x;
  67
  68         me.columnNameOrigin = me.columnNumberSize + me.realFontSize_x;
  69         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize_x;
  70 }
  71
  72 void XonoticPlayList_addToPlayList(entity me, string track)
  73 {
  74         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  75         if(me.nItems == 0)
  76         {
  77                 cvar_set("music_playlist_list0", track);
  78                 return;
  79         }
  80         float i;
  81         for(i = 0; i < me.nItems; ++i)
  82         {
  83                 if(argv(i) == track)
  84                         return; // track is already in playlist
  85         }
  86         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  87 }
  88
  89 void XonoticPlayList_removeFromPlayList(entity me, string track)
  90 {
  91         float i;
  92         string s = "";
  93         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  94         if(me.nItems == 0)
  95                 return;
  96         for(i = 0; i < me.nItems; ++i)
  97         {
  98                 if(argv(i) == track)
  99                 if(cvar("music_playlist_current0") != i) // forbid removing the current playing track, otherwise pause button will resume from another track
 100                 {
 101                         if(cvar("music_playlist_current0") > i)
 102                                 cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
 103                         continue;
 104                 }
 105                 s = strcat(s, " ", argv(i));
 106         }
 107         if(s == "")
 108                 cvar_set("music_playlist_list0", "");
 109         else
 110                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); //remove initial space
 111 }
 112
 113 float XonoticPlayList_mouseDrag(entity me, vector pos)
 114 {
 115         float f, i;
 116         i = me.selectedItem;
 117         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 118
 119         if(me.pressed != 1) // don't change priority if the person is just scrolling
 120         {
 121                 if(me.selectedItem != i)
 122                 {
 123                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 124                         float c = cvar("music_playlist_current0");
 125                         if(c == i)
 126                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 127                         else if(c == me.selectedItem)
 128                                 cvar_set("music_playlist_current0", ftos(i));
 129                 }
 130         }
 131
 132         return f;
 133 }
 134
 135 void XonoticPlayList_draw(entity me)
 136 {
 137         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 138         SUPER(XonoticPlayList).draw(me);
 139 }
 140
 141 void XonoticPlayList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 142 {
 143         string s;
 144         if(isSelected)
 145                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 146
 147         if(argv(i) == me.playingTrack)
 148         {
 149                 float f = cvar("music_playlist_sampleposition0");
 150                 if(f == 0 || (((time * 2) & 1) && f > 0))
 151                         draw_Text(me.realUpperMargin * eY + (me.columnNumberOrigin + me.columnNumberSize) * eX, chr(0xE000 + 141), me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 152         }
 153
 154         s = ftos(i+1);
 155         draw_CenterText(me.realUpperMargin * eY + (me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 156
 157         s = draw_TextShortenToWidth(argv(i), me.columnNameSize, 0, me.realFontSize);
 158         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 159 }
 160
 161 void XonoticPlayList_stopSound(entity me)
 162 {
 163         // STOP: list 0 is disabled by setting the index to -1
 164         // we set sampleposition0 to -1 to indicate that music is stopped
 165         if(cvar("music_playlist_index") != -1) // == 0 doesn't work when paused
 166         {
 167                 cvar_set("music_playlist_index", "-1");
 168                 localcmd("\nwait; music_playlist_sampleposition0 -1\n");
 169                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 170         }
 171 }
 172
 173 void StopSound_Click(entity btn, entity me)
 174 {
 175         me.stopSound(me);
 176 }
 177
 178 void XonoticPlayList_startSound(entity me, float offset)
 179 {
 180         float f;
 181         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 182         if(offset)
 183         {
 184                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 185                 if(f == cvar("music_playlist_current0"))
 186                         return;
 187         }
 188         else
 189                 f = me.selectedItem;
 190         if(me.playingTrack)
 191                 strunzone(me.playingTrack);
 192         me.playingTrack = strzone(argv(f));
 193         // START: list 0 is disabled by setting the index to 999
 194         // we set current0 to the selected track and sampleposition0 to 0 to forget value saved by the engine
 195         // then we switch back to list 0
 196         cvar_set("music_playlist_index", "999");
 197         cvar_set("music_playlist_current0", ftos(f));
 198         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 199 }
 200
 201 void StartSound_Click(entity btn, entity me)
 202 {
 203         me.startSound(me, 0);
 204 }
 205
 206 void PrevSound_Click(entity btn, entity me)
 207 {
 208         me.startSound(me, -1);
 209 }
 210
 211 void NextSound_Click(entity btn, entity me)
 212 {
 213         me.startSound(me, +1);
 214 }
 215
 216 void XonoticPlayList_pauseSound(entity me)
 217 {
 218         // PAUSE: list 0 is disabled by setting the index to 999
 219         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 220         // RESUME: list 0 is enabled by setting the index to 0
 221         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 222         if(cvar("music_playlist_index") == 0)
 223                 localcmd("\nmusic_playlist_index 999\n");
 224         else
 225                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 226 }
 227
 228 void PauseSound_Click(entity btn, entity me)
 229 {
 230         me.pauseSound(me);
 231 }
 232
 233 void XonoticPlayList_clickListBoxItem(entity me, float i, vector where)
 234 {
 235         if(i == me.lastClickedSound)
 236                 if(time < me.lastClickedTime + 0.3)
 237                 {
 238                         // DOUBLE CLICK!
 239                         me.setSelected(me, i);
 240                         me.startSound(me, 0);
 241                 }
 242         me.lastClickedSound = i;
 243         me.lastClickedTime = time;
 244 }
 245
 246 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 247 {
 248         if(scan == K_ENTER || scan == K_KP_ENTER) {
 249                 me.startSound(me, 0);
 250                 return 1;
 251         }
 252         else if(scan == K_SPACE) {
 253                 me.pauseSound(me);
 254                 return 1;
 255         }
 256         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 257                 me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 258                 me.removeFromPlayList(me, argv(me.selectedItem));
 259                 return 1;
 260         }
 261         else
 262                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 263 }
 264 #endif
 265