qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12 float allowed_to_spawn;
  13 float ca_players;
  14 float required_ca_players;
  15 .float caplayer;
  16
  17 void PutObserverInServer();
  18 void PutClientInServer();
  19 void(entity e) ReturnFlag;
  20 void dom_controlpoint_setup();
  21 void onslaught_generator_reset();
  22 void onslaught_controlpoint_reset();
  23 void func_breakable_reset();
  24 void assault_objective_reset();
  25 void target_assault_roundend_reset();
  26
  27 /**
  28  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  29  * Sets the 'warmup' global variable.
  30  */
  31 void reset_map(float dorespawn)
  32 {
  33         entity oldself;
  34         oldself = self;
  35
  36         if(g_arena && cvar("g_arena_warmup"))
  37                 warmup = time + cvar("g_arena_warmup");
  38         else if(g_ca) {
  39                 warmup = time + cvar("g_ca_warmup");
  40                 allowed_to_spawn = 1;
  41         }
  42
  43         lms_lowest_lives = 999;
  44         lms_next_place = player_count;
  45
  46         race_ReadyRestart();
  47
  48         for(self = world; (self = nextent(self)); )
  49         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  50         {
  51                 if(self.reset)
  52                 {
  53                         self.reset();
  54                         continue;
  55                 }
  56
  57                 if(self.team_saved)
  58                         self.team = self.team_saved;
  59
  60                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  61                 {
  62                         stopsound(self, CHAN_PAIN);
  63                         remove(self);
  64                 }
  65         }
  66
  67         // Waypoints and assault start come LAST
  68         for(self = world; (self = nextent(self)); )
  69         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  70         {
  71                 if(self.reset2)
  72                 {
  73                         self.reset2();
  74                         continue;
  75                 }
  76         }
  77
  78         // Moving the player reset code here since the player-reset depends
  79         // on spawnpoint entities which have to be reset first --blub
  80         if(dorespawn)
  81         FOR_EACH_CLIENT(self) {
  82                 if(self.flags & FL_CLIENT)                              // reset all players
  83                 {
  84                         if(g_arena)
  85                         {
  86                                 if(self.spawned)
  87                                         PutClientInServer();
  88                                 else
  89                                         PutObserverInServer();
  90                         }
  91                         else if(g_ca && self.caplayer) {
  92                                 self.classname = "player";
  93                                 PutClientInServer();
  94                         }
  95                         else
  96                         {
  97                                 /*
  98                                 only reset players if a restart countdown is active
  99                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 100                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 101                                 sv_ready_restart_after_countdown is not used and countdown is still running
 102                                 */
 103                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 104                                 {
 105                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 106                                         if (self.classname == "player") {
 107                                                 //PlayerScore_Clear(self);
 108                                                 if(g_lms)
 109                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 110                                                 self.killcount = 0;
 111                                                 //stop the player from moving so that he stands still once he gets respawned
 112                                                 self.velocity = '0 0 0';
 113                                                 self.avelocity = '0 0 0';
 114                                                 self.movement = '0 0 0';
 115                                                 PutClientInServer();
 116                                         }
 117                                 }
 118                         }
 119                 }
 120         }
 121
 122         if(g_keyhunt)
 123                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round")+(game_starttime - time), "", kh_StartRound);
 124
 125         if(g_arena)
 126         if(champion && champion.classname == "player" && player_count > 1)
 127                 UpdateFrags(champion, +1);
 128
 129         if(g_ca)
 130         if(champion && champion.classname == "player" && player_count > 1)
 131                 TeamScore_AddToTeam(champion.team, SP_SCORE, 1);
 132
 133         self = oldself;
 134 }
 135
 136 void Spawnqueue_Insert(entity e)
 137 {
 138         if(e.spawnqueue_in)
 139                 return;
 140         dprint(strcat("Into queue: ", e.netname, "\n"));
 141         e.spawnqueue_in = TRUE;
 142         e.spawnqueue_prev = spawnqueue_last;
 143         e.spawnqueue_next = world;
 144         if(spawnqueue_last)
 145                 spawnqueue_last.spawnqueue_next = e;
 146         spawnqueue_last = e;
 147         if(!spawnqueue_first)
 148                 spawnqueue_first = e;
 149 }
 150
 151 void Spawnqueue_Remove(entity e)
 152 {
 153         if(!e.spawnqueue_in)
 154                 return;
 155         dprint(strcat("Out of queue: ", e.netname, "\n"));
 156         e.spawnqueue_in = FALSE;
 157         if(e == spawnqueue_first)
 158                 spawnqueue_first = e.spawnqueue_next;
 159         if(e == spawnqueue_last)
 160                 spawnqueue_last = e.spawnqueue_prev;
 161         if(e.spawnqueue_prev)
 162                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 163         if(e.spawnqueue_next)
 164                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 165         e.spawnqueue_next = world;
 166         e.spawnqueue_prev = world;
 167 }
 168
 169 void Spawnqueue_Unmark(entity e)
 170 {
 171         if(!e.spawned)
 172                 return;
 173         e.spawned = FALSE;
 174         numspawned = numspawned - 1;
 175 }
 176
 177 void Spawnqueue_Mark(entity e)
 178 {
 179         if(e.spawned)
 180                 return;
 181         e.spawned = TRUE;
 182         numspawned = numspawned + 1;
 183 }
 184
 185 /**
 186  * If roundbased arena game mode is active, it centerprints the texts for the
 187  * player when player is waiting for the countdown to finish.
 188  * Blocks the players movement while countdown is active.
 189  * Unblocks the player once the countdown is over.
 190  *
 191  * Called in PlayerPostThink()
 192  */
 193 float roundStartTime_prev; // prevent networkspam
 194 void Arena_Warmup()
 195 {
 196         float f;
 197         string msg;
 198
 199         if((!g_arena && !g_ca) || (g_arena && !arena_roundbased) || (time < game_starttime))
 200                 return;
 201
 202         f = floor(warmup - time + 1);
 203
 204         allowed_to_spawn = 0;
 205
 206         if(inWarmupStage)
 207                 allowed_to_spawn = 1;
 208
 209         msg = NEWLINES;
 210         if(time < warmup && !inWarmupStage)
 211         {
 212                 if (g_ca)
 213                         allowed_to_spawn = 1;
 214                 if(champion && g_arena)
 215                         msg = strcat("The Champion is ", champion.netname, "^7\n");
 216                         //centerprint(self, strcat(msg, "The Champion is ", champion.netname, "^7\n"));
 217
 218                 if(f != roundStartTime_prev) {
 219                         msg = strcat(msg, "Round will start in ", ftos(f),"\n");
 220                         //centerprint(self, strcat("Round will start in ", ftos(f),"\n"));
 221                         roundStartTime_prev = f;
 222                         if(f == 5)
 223                                 Announce("prepareforbattle");
 224                         else if(f == 3)
 225                                 Announce("3");
 226                         else if(f == 2)
 227                                 Announce("2");
 228                         else if(f == 1)
 229                                 Announce("1");
 230
 231                         centerprint(self, msg);
 232                 }
 233
 234                 if (g_arena) {
 235                         if(self.spawned && self.classname == "player")
 236                                 self.movetype = MOVETYPE_NONE;
 237
 238                         self.velocity = '0 0 0';
 239                         self.avelocity = '0 0 0';
 240                         self.movement = '0 0 0';
 241                         //self.fixangle = TRUE;
 242                 }
 243         }
 244
 245         else if(f > -1 && f != roundStartTime_prev)
 246         {
 247                 roundStartTime_prev = f;
 248                 Announce("begin");
 249                 centerprint(self, "^1Begin!\n");
 250
 251                 if(g_ca) {
 252                         ca_players = 0;
 253
 254                         FOR_EACH_PLAYER(self)
 255                                 ca_players += 1;
 256                 }
 257         }
 258
 259         if(self.classname == "player" && self.health > 0)
 260                 self.movetype = MOVETYPE_WALK;
 261 }
 262
 263 float next_round;
 264 /**
 265  * This function finds out whether an arena round is over 1 player is left.
 266  * It determines the last player who's still alive and saves it's entity reference
 267  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 268  *
 269  * Gets called in StartFrame()
 270  */
 271 void Spawnqueue_Check()
 272 {
 273         if(time < warmup + 1 || inWarmupStage)
 274                 return;
 275
 276         if(g_ca) {
 277                 // check the amount of spawned players in each team
 278                 float redspawned, bluespawned;
 279                 FOR_EACH_PLAYER(self) {
 280                         if (self.team == COLOR_TEAM1) redspawned += 1;
 281                         else if (self.team == COLOR_TEAM2) bluespawned += 1;
 282                 }
 283
 284                 required_ca_players = max(2, fabs(cvar("bot_vs_human") + 1));
 285
 286                 if(ca_players < required_ca_players && (redspawned && bluespawned)) {
 287                         reset_map(TRUE);
 288                 }
 289                 else if(ca_players < required_ca_players) {
 290                         FOR_EACH_PLAYER(self)
 291                                 centerprint(self, strcat("^1Need at least 1 player in each team to play CA", "^7\n"));
 292
 293                         allowed_to_spawn = 1;
 294                         return;
 295                 }
 296                 else if(!next_round) {
 297                         if((redspawned && !bluespawned) || (bluespawned && !redspawned)) {
 298                                 next_round = time + 5;
 299
 300                                 champion = find(world, classname, "player");
 301                                 string champion_team;
 302                                 if(champion.team == COLOR_TEAM1) {
 303                                         champion_team = "^1Red team";
 304                                         play2all("ctf/red_capture.wav");
 305                                 }
 306                                 else if(champion.team == COLOR_TEAM2) {
 307                                         champion_team = "^4Blue team";
 308                                         play2all("ctf/blue_capture.wav");
 309                                 }
 310                                 FOR_EACH_CLIENT(self) centerprint(self, strcat(champion_team, "^7 wins the round.", "^7\n"));
 311                         }
 312                         else if(!redspawned && !bluespawned) {
 313                                 FOR_EACH_CLIENT(self) centerprint(self, strcat("^7Round tied.", "^7\n"));
 314                                 next_round = time + 5;
 315                         }
 316                 }
 317
 318                 if((next_round && next_round < time))
 319                 {
 320                         next_round = 0;
 321                         reset_map(TRUE);
 322                 }
 323         } else { // arena
 324                 //extend next_round if it isn't set yet and only 1 player is spawned
 325                 if(!next_round)
 326                 if(numspawned < 2)
 327                         next_round = time + 3;
 328
 329                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 330                 {
 331                         next_round = 0;
 332
 333                         if(arena_roundbased)
 334                         {
 335                                 champion = find(world, classname, "player");
 336                                 while(champion && champion.deadflag)
 337                                         champion = find(champion, classname, "player");
 338                                 reset_map(TRUE);
 339                         }
 340
 341                         while(numspawned < maxspawned && spawnqueue_first)
 342                         {
 343                                 self = spawnqueue_first;
 344
 345                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 346
 347                                 Spawnqueue_Remove(self);
 348                                 Spawnqueue_Mark(self);
 349
 350                                 self.classname = "player";
 351                                 PutClientInServer();
 352                         }
 353                 }
 354         }
 355 }