qcsrc/server/bot/bot.qc

   1 #include "bot.qh"
   2 #include "aim.qh"
   3 #include "navigation.qh"
   4 #include "waypoints.qh"
   5
   6 #include "aim.qc"
   7 #include "navigation.qc"
   8 #include "waypoints.qc"
   9 #include "scripting.qc"
  10
  11 #include "havocbot/havocbot.qc"
  12
  13 entity bot_spawn()
  14 {
  15         local entity oldself, bot;
  16         bot = spawnclient();
  17         if (bot)
  18         {
  19                 currentbots = currentbots + 1;
  20                 oldself = self;
  21                 self = bot;
  22                 bot_setnameandstuff();
  23                 ClientConnect();
  24                 PutClientInServer();
  25                 self = oldself;
  26         }
  27         return bot;
  28 };
  29
  30 void bot_think()
  31 {
  32         if (self.bot_nextthink > time)
  33                 return;
  34
  35         self.flags &~= FL_GODMODE;
  36         if(autocvar_bot_god)
  37                 self.flags |= FL_GODMODE;
  38
  39         self.bot_nextthink = self.bot_nextthink + autocvar_bot_ai_thinkinterval * pow(0.5, self.bot_aiskill);
  40         //if (self.bot_painintensity > 0)
  41         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
  42
  43         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
  44         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
  45
  46         if (autocvar_g_campaign && !campaign_bots_may_start)
  47         {
  48                 self.nextthink = time + 0.5;
  49                 return;
  50         }
  51
  52         if (self.fixangle)
  53         {
  54                 self.v_angle = self.angles;
  55                 self.v_angle_z = 0;
  56                 self.fixangle = FALSE;
  57         }
  58
  59         self.dmg_take = 0;
  60         self.dmg_save = 0;
  61         self.dmg_inflictor = world;
  62
  63         // calculate an aiming latency based on the skill setting
  64         // (simulated network latency + naturally delayed reflexes)
  65         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  66         // minimum ping 20+10 random
  67         self.ping = bound(0,0.07 - bound(0, (skill + self.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  68         // skill 10 = ping 0.2 (adrenaline)
  69         // skill 0 = ping 0.7 (slightly drunk)
  70
  71         // clear buttons
  72         self.BUTTON_ATCK = 0;
  73         self.button1 = 0;
  74         self.BUTTON_JUMP = 0;
  75         self.BUTTON_ATCK2 = 0;
  76         self.BUTTON_ZOOM = 0;
  77         self.BUTTON_CROUCH = 0;
  78         self.BUTTON_HOOK = 0;
  79         self.BUTTON_INFO = 0;
  80         self.button8 = 0;
  81         self.BUTTON_CHAT = 0;
  82         self.BUTTON_USE = 0;
  83
  84         if (time < game_starttime)
  85         {
  86                 // block the bot during the countdown to game start
  87                 self.movement = '0 0 0';
  88                 self.nextthink = game_starttime;
  89                 return;
  90         }
  91
  92         // if dead, just wait until we can respawn
  93         if (self.deadflag)
  94         {
  95                 if (self.deadflag == DEAD_DEAD)
  96                 {
  97                         self.BUTTON_JUMP = 1; // press jump to respawn
  98                         self.bot_strategytime = 0;
  99                 }
 100         }
 101
 102         //
 103         if(self.aistatus & AI_STATUS_STUCK)
 104                 navigation_unstuck();
 105
 106         // now call the current bot AI (havocbot for example)
 107         self.bot_ai();
 108 };
 109
 110 void bot_setnameandstuff()
 111 {
 112         string readfile, s;
 113         float file, tokens, prio;
 114         entity p;
 115
 116         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 117         string name, prefix, suffix;
 118
 119         if(autocvar_g_campaign)
 120         {
 121                 prefix = "";
 122                 suffix = "";
 123         }
 124         else
 125         {
 126                 prefix = autocvar_bot_prefix;
 127                 suffix = autocvar_bot_suffix;
 128         }
 129
 130         file = fopen(autocvar_bot_config_file, FILE_READ);
 131
 132         if(file < 0)
 133                 print(strcat("Error: Can not open the bot configuration file '",autocvar_bot_config_file,"'\n"));
 134         else
 135         {
 136                 RandomSelection_Init();
 137                 for(;;)
 138                 {
 139                         readfile = fgets(file);
 140                         if(!readfile)
 141                                 break;
 142                         if(substring(readfile, 0, 2) == "//")
 143                                 continue;
 144                         if(substring(readfile, 0, 1) == "#")
 145                                 continue;
 146                         tokens = tokenizebyseparator(readfile, "\t");
 147                         s = argv(0);
 148                         prio = 1;
 149                         FOR_EACH_CLIENT(p)
 150                         {
 151                                 if(clienttype(p) == CLIENTTYPE_BOT)
 152                                 if(s == p.cleanname)
 153                                 {
 154                                         prio = 0;
 155                                         break;
 156                                 }
 157                         }
 158                         RandomSelection_Add(world, 0, readfile, 1, prio);
 159                 }
 160                 readfile = RandomSelection_chosen_string;
 161                 fclose(file);
 162         }
 163
 164         tokens = tokenizebyseparator(readfile, "\t");
 165         if(argv(0) != "") bot_name = argv(0);
 166         else bot_name = "Bot";
 167
 168         if(argv(1) != "") bot_model = argv(1);
 169         else bot_model = "";
 170
 171         if(argv(2) != "") bot_skin = argv(2);
 172         else bot_skin = "0";
 173
 174         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 175         else bot_shirt = ftos(floor(random() * 15));
 176
 177         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 178         else bot_pants = ftos(floor(random() * 15));
 179
 180         self.bot_forced_team = stof(argv(5));
 181
 182         prio = 6;
 183
 184         #define READSKILL(f,w,r) if(argv(prio) != "") self.f = stof(argv(prio)) * (w); else self.f = (!autocvar_g_campaign) * (2 * random() - 1) * (r) * (w); ++prio
 185         //print(bot_name, ": ping=", argv(9), "\n");
 186
 187         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 188         READSKILL(bot_moveskill, 2, 0); // move skill
 189         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 190
 191         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 192
 193         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 194         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 195         READSKILL(bot_rangepreference, 1, 0); // read skill
 196
 197         READSKILL(bot_aimskill, 2, 0); // aim skill
 198         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 199         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 200
 201         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 202         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 203
 204         self.bot_config_loaded = TRUE;
 205
 206         // this is really only a default, JoinBestTeam is called later
 207         setcolor(self, stof(bot_shirt) * 16 + stof(bot_pants));
 208         self.bot_preferredcolors = self.clientcolors;
 209
 210         // pick the name
 211         if (autocvar_bot_usemodelnames)
 212                 name = bot_model;
 213         else
 214                 name = bot_name;
 215
 216         // number bots with identical names
 217         float i;
 218         i = 0;
 219         FOR_EACH_CLIENT(p)
 220         {
 221                 if(clienttype(p) == CLIENTTYPE_BOT)
 222                         if(p.cleanname == name)
 223                                 ++i;
 224         }
 225         if (i)
 226                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, "(", ftos(i), ")", suffix));
 227         else
 228                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, suffix));
 229
 230         self.cleanname = strzone(name);
 231
 232         // pick the model and skin
 233         if(substring(bot_model, -4, 1) != ".")
 234                 bot_model = strcat(bot_model, ".iqm");
 235         self.playermodel = self.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 236         self.playerskin = self.playerskin_freeme = strzone(bot_skin);
 237
 238         self.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
 239         self.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
 240 };
 241
 242 void bot_custom_weapon_priority_setup()
 243 {
 244         local float tokens, i, c, w;
 245
 246         bot_custom_weapon = FALSE;
 247
 248         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 249                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 250                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 251                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 252         )
 253                 return;
 254
 255         // Parse distances
 256         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 257
 258         if (tokens!=2)
 259                 return;
 260
 261         bot_distance_far = stof(argv(0));
 262         bot_distance_close = stof(argv(1));
 263
 264         if(bot_distance_far < bot_distance_close){
 265                 bot_distance_far = stof(argv(1));
 266                 bot_distance_close = stof(argv(0));
 267         }
 268
 269         // Initialize list of weapons
 270         bot_weapons_far[0] = -1;
 271         bot_weapons_mid[0] = -1;
 272         bot_weapons_close[0] = -1;
 273
 274         // Parse far distance weapon priorities
 275         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 276
 277         c = 0;
 278         for(i=0; i < tokens && c < WEP_COUNT; ++i){
 279                 w = stof(argv(i));
 280                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 281                         bot_weapons_far[c] = w;
 282                         ++c;
 283                 }
 284         }
 285         if(c < WEP_COUNT)
 286                 bot_weapons_far[c] = -1;
 287
 288         // Parse mid distance weapon priorities
 289         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 290
 291         c = 0;
 292         for(i=0; i < tokens && c < WEP_COUNT; ++i){
 293                 w = stof(argv(i));
 294                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 295                         bot_weapons_mid[c] = w;
 296                         ++c;
 297                 }
 298         }
 299         if(c < WEP_COUNT)
 300                 bot_weapons_mid[c] = -1;
 301
 302         // Parse close distance weapon priorities
 303         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 304
 305         c = 0;
 306         for(i=0; i < tokens && i < WEP_COUNT; ++i){
 307                 w = stof(argv(i));
 308                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 309                         bot_weapons_close[c] = w;
 310                         ++c;
 311                 }
 312         }
 313         if(c < WEP_COUNT)
 314                 bot_weapons_close[c] = -1;
 315
 316         bot_custom_weapon = TRUE;
 317 };
 318
 319 void bot_endgame()
 320 {
 321         local entity e;
 322         //dprint("bot_endgame\n");
 323         e = bot_list;
 324         while (e)
 325         {
 326                 setcolor(e, e.bot_preferredcolors);
 327                 e = e.nextbot;
 328         }
 329         // if dynamic waypoints are ever implemented, save them here
 330 };
 331
 332 void bot_relinkplayerlist()
 333 {
 334         local entity e;
 335         local entity prevbot;
 336         player_count = 0;
 337         currentbots = 0;
 338         player_list = e = findchainflags(flags, FL_CLIENT);
 339         bot_list = world;
 340         prevbot = world;
 341         while (e)
 342         {
 343                 player_count = player_count + 1;
 344                 e.nextplayer = e.chain;
 345                 if (clienttype(e) == CLIENTTYPE_BOT)
 346                 {
 347                         if (prevbot)
 348                                 prevbot.nextbot = e;
 349                         else
 350                         {
 351                                 bot_list = e;
 352                                 bot_list.nextbot = world;
 353                         }
 354                         prevbot = e;
 355                         currentbots = currentbots + 1;
 356                 }
 357                 e = e.chain;
 358         }
 359         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
 360         bot_strategytoken = bot_list;
 361         bot_strategytoken_taken = TRUE;
 362 };
 363
 364 void bot_clientdisconnect()
 365 {
 366         if (clienttype(self) != CLIENTTYPE_BOT)
 367                 return;
 368         if(self.cleanname)
 369                 strunzone(self.cleanname);
 370         if(self.netname_freeme)
 371                 strunzone(self.netname_freeme);
 372         if(self.playermodel_freeme)
 373                 strunzone(self.playermodel_freeme);
 374         if(self.playerskin_freeme)
 375                 strunzone(self.playerskin_freeme);
 376         self.cleanname = string_null;
 377         self.netname_freeme = string_null;
 378         self.playermodel_freeme = string_null;
 379         self.playerskin_freeme = string_null;
 380         remove(self.bot_cmd_current);
 381         if(navigation_wander_owner==self)
 382                 navigation_wander_owner = world;
 383 }
 384
 385 void bot_clientconnect()
 386 {
 387         if (clienttype(self) != CLIENTTYPE_BOT)
 388                 return;
 389         self.bot_preferredcolors = self.clientcolors;
 390         self.bot_nextthink = time - random();
 391         self.lag_func = bot_lagfunc;
 392         self.isbot = TRUE;
 393         self.createdtime = self.nextthink;
 394
 395         if(!self.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 396                 bot_setnameandstuff();
 397
 398         if(self.bot_forced_team==1)
 399                 self.team = COLOR_TEAM1;
 400         else if(self.bot_forced_team==2)
 401                 self.team = COLOR_TEAM2;
 402         else if(self.bot_forced_team==3)
 403                 self.team = COLOR_TEAM3;
 404         else if(self.bot_forced_team==4)
 405                 self.team = COLOR_TEAM4;
 406         else
 407                 JoinBestTeam(self, FALSE, TRUE);
 408
 409         havocbot_setupbot();
 410 };
 411
 412 void bot_removefromlargestteam()
 413 {
 414         local float besttime, bestcount, thiscount;
 415         local entity best, head;
 416         CheckAllowedTeams(world);
 417         GetTeamCounts(world);
 418         head = findchainfloat(isbot, TRUE);
 419         if (!head)
 420                 return;
 421         best = head;
 422         besttime = head.createdtime;
 423         bestcount = 0;
 424         while (head)
 425         {
 426                 if(head.team == COLOR_TEAM1)
 427                         thiscount = c1;
 428                 else if(head.team == COLOR_TEAM2)
 429                         thiscount = c2;
 430                 else if(head.team == COLOR_TEAM3)
 431                         thiscount = c3;
 432                 else if(head.team == COLOR_TEAM4)
 433                         thiscount = c4;
 434                 else
 435                         thiscount = 0;
 436                 if (thiscount > bestcount)
 437                 {
 438                         bestcount = thiscount;
 439                         besttime = head.createdtime;
 440                         best = head;
 441                 }
 442                 else if (thiscount == bestcount && besttime < head.createdtime)
 443                 {
 444                         besttime = head.createdtime;
 445                         best = head;
 446                 }
 447                 head = head.chain;
 448         }
 449         currentbots = currentbots - 1;
 450         dropclient(best);
 451 };
 452
 453 void bot_removenewest()
 454 {
 455         local float besttime;
 456         local entity best, head;
 457
 458         if(teams_matter)
 459         {
 460                 bot_removefromlargestteam();
 461                 return;
 462         }
 463
 464         head = findchainfloat(isbot, TRUE);
 465         if (!head)
 466                 return;
 467         best = head;
 468         besttime = head.createdtime;
 469         while (head)
 470         {
 471                 if (besttime < head.createdtime)
 472                 {
 473                         besttime = head.createdtime;
 474                         best = head;
 475                 }
 476                 head = head.chain;
 477         }
 478         currentbots = currentbots - 1;
 479         dropclient(best);
 480 };
 481
 482 void autoskill(float factor)
 483 {
 484         float bestbot;
 485         float bestplayer;
 486         entity head;
 487
 488         bestbot = -1;
 489         bestplayer = -1;
 490         FOR_EACH_PLAYER(head)
 491         {
 492                 if(clienttype(head) == CLIENTTYPE_REAL)
 493                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
 494                 else
 495                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
 496         }
 497
 498         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
 499         dprint("best bot got ", ftos(bestbot), "; ");
 500         if(bestbot < 0 || bestplayer < 0)
 501         {
 502                 dprint("not doing anything\n");
 503                 // don't return, let it reset all counters below
 504         }
 505         else if(bestbot <= bestplayer * factor - 2)
 506         {
 507                 if(autocvar_skill < 17)
 508                 {
 509                         dprint("2 frags difference, increasing skill\n");
 510                         cvar_set("skill", ftos(autocvar_skill + 1));
 511                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 512                 }
 513         }
 514         else if(bestbot >= bestplayer * factor + 2)
 515         {
 516                 if(autocvar_skill > 0)
 517                 {
 518                         dprint("2 frags difference, decreasing skill\n");
 519                         cvar_set("skill", ftos(autocvar_skill - 1));
 520                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 521                 }
 522         }
 523         else
 524         {
 525                 dprint("not doing anything\n");
 526                 return;
 527                 // don't reset counters, wait for them to accumulate
 528         }
 529
 530         FOR_EACH_PLAYER(head)
 531                 head.totalfrags_lastcheck = head.totalfrags;
 532 }
 533
 534 void bot_serverframe()
 535 {
 536         float realplayers, bots, activerealplayers;
 537         entity head;
 538
 539         if (intermission_running)
 540                 return;
 541
 542         if (time < 2)
 543                 return;
 544
 545         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 546         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 547
 548         if(time > autoskill_nextthink)
 549         {
 550                 float a;
 551                 a = autocvar_skill_auto;
 552                 if(a)
 553                         autoskill(a);
 554                 autoskill_nextthink = time + 5;
 555         }
 556
 557         activerealplayers = 0;
 558         realplayers = 0;
 559
 560         FOR_EACH_REALCLIENT(head)
 561         {
 562                 if(head.classname == "player" || g_lms || g_arena || g_ca)
 563                         ++activerealplayers;
 564                 ++realplayers;
 565         }
 566
 567         // add/remove bots if needed to make sure there are at least
 568         // minplayers+bot_number, or remove all bots if no one is playing
 569         // But don't remove bots immediately on level change, as the real players
 570         // usually haven't rejoined yet
 571         bots_would_leave = FALSE;
 572         if (teams_matter && autocvar_bot_vs_human && (c3==-1 && c4==-1))
 573                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 574         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 575         {
 576                 float realminplayers, minplayers;
 577                 realminplayers = autocvar_minplayers;
 578                 minplayers = max(0, floor(realminplayers));
 579
 580                 float realminbots, minbots;
 581                 realminbots = autocvar_bot_number;
 582                 minbots = max(0, floor(realminbots));
 583
 584                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 585                 if(bots > minbots)
 586                         bots_would_leave = TRUE;
 587         }
 588         else
 589         {
 590                 // if there are no players, remove bots
 591                 bots = 0;
 592         }
 593
 594         bot_ignore_bots = autocvar_bot_ignore_bots;
 595
 596         // only add one bot per frame to avoid utter chaos
 597         if(time > botframe_nextthink)
 598         {
 599                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
 600                 while (currentbots < bots)
 601                 {
 602                         if (bot_spawn() == world)
 603                         {
 604                                 bprint("Can not add bot, server full.\n");
 605                                 botframe_nextthink = time + 10;
 606                                 break;
 607                         }
 608                 }
 609                 while (currentbots > bots)
 610                         bot_removenewest();
 611         }
 612
 613         if(botframe_spawnedwaypoints)
 614         {
 615                 if(autocvar_waypoint_benchmark)
 616                         localcmd("quit\n");
 617         }
 618
 619         if (currentbots > 0 || autocvar_g_waypointeditor)
 620         if (botframe_spawnedwaypoints)
 621         {
 622                 if(botframe_cachedwaypointlinks)
 623                 {
 624                         if(!botframe_loadedforcedlinks)
 625                                 waypoint_load_links_hardwired();
 626                 }
 627                 else
 628                 {
 629                         // TODO: Make this check cleaner
 630                         local entity wp = findchain(classname, "waypoint");
 631                         if(time - wp.nextthink > 10)
 632                                 waypoint_save_links();
 633                 }
 634         }
 635         else
 636         {
 637                 botframe_spawnedwaypoints = TRUE;
 638                 waypoint_loadall();
 639                 if(!waypoint_load_links())
 640                         waypoint_schedulerelinkall();
 641         }
 642
 643         if (bot_list)
 644         {
 645                 // cycle the goal token from one bot to the next each frame
 646                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 647                 //  frame, which causes choppy framerates)
 648                 if (bot_strategytoken_taken)
 649                 {
 650                         bot_strategytoken_taken = FALSE;
 651                         if (bot_strategytoken)
 652                                 bot_strategytoken = bot_strategytoken.nextbot;
 653                         if (!bot_strategytoken)
 654                                 bot_strategytoken = bot_list;
 655                 }
 656
 657                 if (botframe_nextdangertime < time)
 658                 {
 659                         local float interval;
 660                         interval = autocvar_bot_ai_dangerdetectioninterval;
 661                         if (botframe_nextdangertime < time - interval * 1.5)
 662                                 botframe_nextdangertime = time;
 663                         botframe_nextdangertime = botframe_nextdangertime + interval;
 664                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 665                 }
 666         }
 667
 668         if (autocvar_g_waypointeditor)
 669                 botframe_showwaypointlinks();
 670
 671         if(time > bot_cvar_nextthink)
 672         {
 673                 if(currentbots>0)
 674                         bot_custom_weapon_priority_setup();
 675                 bot_cvar_nextthink = time + 5;
 676         }
 677 };