qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  78         {
  79                 CS(this).movement = '0 0 0';
  80                 this.bot_nextthink = time + 0.5;
  81                 return;
  82         }
  83
  84         if (this.fixangle)
  85         {
  86                 this.v_angle = this.angles;
  87                 this.v_angle_z = 0;
  88                 this.fixangle = false;
  89         }
  90
  91         this.dmg_take = 0;
  92         this.dmg_save = 0;
  93         this.dmg_inflictor = NULL;
  94
  95         // calculate an aiming latency based on the skill setting
  96         // (simulated network latency + naturally delayed reflexes)
  97         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  98         // minimum ping 20+10 random
  99         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 100         // skill 10 = ping 0.2 (adrenaline)
 101         // skill 0 = ping 0.7 (slightly drunk)
 102
 103         // clear buttons
 104         PHYS_INPUT_BUTTON_ATCK(this) = false;
 105         PHYS_INPUT_BUTTON_JUMP(this) = false;
 106         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 107         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 108         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 109         PHYS_INPUT_BUTTON_HOOK(this) = false;
 110         PHYS_INPUT_BUTTON_INFO(this) = false;
 111         PHYS_INPUT_BUTTON_DRAG(this) = false;
 112         PHYS_INPUT_BUTTON_CHAT(this) = false;
 113         PHYS_INPUT_BUTTON_USE(this) = false;
 114
 115         if (time < game_starttime)
 116         {
 117                 // block the bot during the countdown to game start
 118                 CS(this).movement = '0 0 0';
 119                 this.bot_nextthink = game_starttime;
 120                 return;
 121         }
 122
 123         // if dead, just wait until we can respawn
 124         if (IS_DEAD(this))
 125         {
 126                 if (bot_waypoint_queue_owner == this)
 127                         bot_waypoint_queue_owner = NULL;
 128                 this.aistatus = 0;
 129                 CS(this).movement = '0 0 0';
 130                 if (this.deadflag == DEAD_DEAD)
 131                 {
 132                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 133                         navigation_goalrating_timeout_force(this);
 134                 }
 135         }
 136         else if(this.aistatus & AI_STATUS_STUCK)
 137                 navigation_unstuck(this);
 138
 139         // now call the current bot AI (havocbot for example)
 140         this.bot_ai(this);
 141 }
 142
 143 void bot_setnameandstuff(entity this)
 144 {
 145         string readfile, s;
 146         float file, tokens, prio;
 147
 148         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 149         string name, prefix, suffix;
 150
 151         if(autocvar_g_campaign)
 152         {
 153                 prefix = "";
 154                 suffix = "";
 155         }
 156         else
 157         {
 158                 prefix = autocvar_bot_prefix;
 159                 suffix = autocvar_bot_suffix;
 160         }
 161
 162         file = fopen(autocvar_bot_config_file, FILE_READ);
 163
 164         if(file < 0)
 165         {
 166                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 167                 readfile = "";
 168         }
 169         else
 170         {
 171                 RandomSelection_Init();
 172                 while((readfile = fgets(file)))
 173                 {
 174                         if(substring(readfile, 0, 2) == "//")
 175                                 continue;
 176                         if(substring(readfile, 0, 1) == "#")
 177                                 continue;
 178                         tokens = tokenizebyseparator(readfile, "\t");
 179                         if(tokens == 0)
 180                                 continue;
 181                         s = argv(0);
 182                         prio = 1;
 183                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 184                                 if(s == it.cleanname)
 185                                 {
 186                                         prio = 0;
 187                                         break;
 188                                 }
 189                         });
 190                         RandomSelection_AddString(readfile, 1, prio);
 191                 }
 192                 readfile = RandomSelection_chosen_string;
 193                 fclose(file);
 194         }
 195
 196         tokens = tokenizebyseparator(readfile, "\t");
 197         if(argv(0) != "") bot_name = argv(0);
 198         else bot_name = "Bot";
 199
 200         if(argv(1) != "") bot_model = argv(1);
 201         else bot_model = "";
 202
 203         if(argv(2) != "") bot_skin = argv(2);
 204         else bot_skin = "0";
 205
 206         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 207         else bot_shirt = ftos(floor(random() * 15));
 208
 209         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 210         else bot_pants = ftos(floor(random() * 15));
 211
 212         this.bot_forced_team = stof(argv(5));
 213
 214         prio = 6;
 215
 216         #define READSKILL(f, w, r) MACRO_BEGIN { \
 217                 if(argv(prio) != "") \
 218                         this.f = stof(argv(prio)) * w; \
 219                 else \
 220                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 221                 prio++; \
 222         } MACRO_END
 223         //print(bot_name, ": ping=", argv(9), "\n");
 224
 225         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 226         READSKILL(bot_moveskill, 2, 0); // move skill
 227         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 228
 229         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 230
 231         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 232         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 233         READSKILL(bot_rangepreference, 1, 0); // read skill
 234
 235         READSKILL(bot_aimskill, 2, 0); // aim skill
 236         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 237         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 238
 239         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 240         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 241
 242         this.bot_config_loaded = true;
 243
 244         // this is really only a default, JoinBestTeam is called later
 245         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 246         this.bot_preferredcolors = this.clientcolors;
 247
 248         // pick the name
 249         if (autocvar_bot_usemodelnames)
 250                 name = bot_model;
 251         else
 252                 name = bot_name;
 253
 254         // number bots with identical names
 255         int j = 0;
 256         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 257                 if(it.cleanname == name)
 258                         ++j;
 259         });
 260         if (j)
 261                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 262         else
 263                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 264
 265         this.cleanname = strzone(name);
 266
 267         // pick the model and skin
 268         if(substring(bot_model, -4, 1) != ".")
 269                 bot_model = strcat(bot_model, ".iqm");
 270         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 271         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 272 }
 273
 274 void bot_custom_weapon_priority_setup()
 275 {
 276         float tokens, i, w;
 277
 278         bot_custom_weapon = false;
 279
 280         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 281                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 282                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 283                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 284         )
 285                 return;
 286
 287         // Parse distances
 288         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 289
 290         if (tokens!=2)
 291                 return;
 292
 293         bot_distance_far = stof(argv(0));
 294         bot_distance_close = stof(argv(1));
 295
 296         if(bot_distance_far < bot_distance_close){
 297                 bot_distance_far = stof(argv(1));
 298                 bot_distance_close = stof(argv(0));
 299         }
 300
 301         // Initialize list of weapons
 302         bot_weapons_far[0] = -1;
 303         bot_weapons_mid[0] = -1;
 304         bot_weapons_close[0] = -1;
 305
 306         // Parse far distance weapon priorities
 307         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 308
 309         int c = 0;
 310         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 311                 w = stof(argv(i));
 312                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 313                         bot_weapons_far[c] = w;
 314                         ++c;
 315                 }
 316         }
 317         if(c < Weapons_COUNT)
 318                 bot_weapons_far[c] = -1;
 319
 320         // Parse mid distance weapon priorities
 321         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 322
 323         c = 0;
 324         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 325                 w = stof(argv(i));
 326                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 327                         bot_weapons_mid[c] = w;
 328                         ++c;
 329                 }
 330         }
 331         if(c < Weapons_COUNT)
 332                 bot_weapons_mid[c] = -1;
 333
 334         // Parse close distance weapon priorities
 335         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 336
 337         c = 0;
 338         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 339                 w = stof(argv(i));
 340                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 341                         bot_weapons_close[c] = w;
 342                         ++c;
 343                 }
 344         }
 345         if(c < Weapons_COUNT)
 346                 bot_weapons_close[c] = -1;
 347
 348         bot_custom_weapon = true;
 349 }
 350
 351 void bot_endgame()
 352 {
 353         bot_relinkplayerlist();
 354         entity e = bot_list;
 355         while (e)
 356         {
 357                 setcolor(e, e.bot_preferredcolors);
 358                 e = e.nextbot;
 359         }
 360         // if dynamic waypoints are ever implemented, save them here
 361 }
 362
 363 void bot_relinkplayerlist()
 364 {
 365         player_count = 0;
 366         currentbots = 0;
 367         bot_list = NULL;
 368
 369         entity prevbot = NULL;
 370         FOREACH_CLIENT(true,
 371         {
 372                 ++player_count;
 373
 374                 if(IS_BOT_CLIENT(it))
 375                 {
 376                         if(prevbot)
 377                                 prevbot.nextbot = it;
 378                         else
 379                                 bot_list = it;
 380                         prevbot = it;
 381                         ++currentbots;
 382                 }
 383         });
 384         if(prevbot)
 385                 prevbot.nextbot = NULL;
 386         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 387         bot_strategytoken = bot_list;
 388         bot_strategytoken_taken = true;
 389 }
 390
 391 void bot_clientdisconnect(entity this)
 392 {
 393         if (!IS_BOT_CLIENT(this))
 394                 return;
 395         bot_clearqueue(this);
 396         strfree(this.cleanname);
 397         strfree(this.netname_freeme);
 398         strfree(this.playermodel_freeme);
 399         strfree(this.playerskin_freeme);
 400         if(this.bot_cmd_current)
 401                 delete(this.bot_cmd_current);
 402         if(bot_waypoint_queue_owner == this)
 403                 bot_waypoint_queue_owner = NULL;
 404 }
 405
 406 void bot_clientconnect(entity this)
 407 {
 408         if (!IS_BOT_CLIENT(this)) return;
 409         this.bot_preferredcolors = this.clientcolors;
 410         this.bot_nextthink = time - random();
 411         this.lag_func = bot_lagfunc;
 412         this.isbot = true;
 413         this.createdtime = this.bot_nextthink;
 414
 415         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 416         {
 417                 bot_setnameandstuff(this);
 418                 bot_setclientfields(this);
 419         }
 420
 421         if(this.bot_forced_team==1)
 422                 this.team = NUM_TEAM_1;
 423         else if(this.bot_forced_team==2)
 424                 this.team = NUM_TEAM_2;
 425         else if(this.bot_forced_team==3)
 426                 this.team = NUM_TEAM_3;
 427         else if(this.bot_forced_team==4)
 428                 this.team = NUM_TEAM_4;
 429         else
 430                 JoinBestTeam(this, true);
 431
 432         havocbot_setupbot(this);
 433 }
 434
 435 void bot_removefromlargestteam()
 436 {
 437         CheckAllowedTeams(NULL);
 438         GetTeamCounts(NULL);
 439
 440         entity best = NULL;
 441         float besttime = 0;
 442         int bestcount = 0;
 443
 444         int bcount = 0;
 445         FOREACH_CLIENT(it.isbot,
 446         {
 447                 ++bcount;
 448
 449                 if(!best)
 450                 {
 451                         best = it;
 452                         besttime = it.createdtime;
 453                 }
 454
 455                 int thiscount = 0;
 456
 457                 switch(it.team)
 458                 {
 459                         case NUM_TEAM_1: thiscount = c1; break;
 460                         case NUM_TEAM_2: thiscount = c2; break;
 461                         case NUM_TEAM_3: thiscount = c3; break;
 462                         case NUM_TEAM_4: thiscount = c4; break;
 463                 }
 464
 465                 if(thiscount > bestcount)
 466                 {
 467                         bestcount = thiscount;
 468                         besttime = it.createdtime;
 469                         best = it;
 470                 }
 471                 else if(thiscount == bestcount && besttime < it.createdtime)
 472                 {
 473                         besttime = it.createdtime;
 474                         best = it;
 475                 }
 476         });
 477         if(!bcount)
 478                 return; // no bots to remove
 479         currentbots = currentbots - 1;
 480         dropclient(best);
 481 }
 482
 483 void bot_removenewest()
 484 {
 485         if(teamplay)
 486         {
 487                 bot_removefromlargestteam();
 488                 return;
 489         }
 490
 491         float besttime = 0;
 492         entity best = NULL;
 493         int bcount = 0;
 494
 495         FOREACH_CLIENT(it.isbot,
 496         {
 497                 ++bcount;
 498
 499                 if(!best)
 500                 {
 501                         best = it;
 502                         besttime = it.createdtime;
 503                 }
 504
 505                 if(besttime < it.createdtime)
 506                 {
 507                         besttime = it.createdtime;
 508                         best = it;
 509                 }
 510         });
 511
 512         if(!bcount)
 513                 return; // no bots to remove
 514
 515         currentbots = currentbots - 1;
 516         dropclient(best);
 517 }
 518
 519 void autoskill(float factor)
 520 {
 521         float bestbot;
 522         float bestplayer;
 523
 524         bestbot = -1;
 525         bestplayer = -1;
 526         FOREACH_CLIENT(IS_PLAYER(it), {
 527                 if(IS_REAL_CLIENT(it))
 528                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 529                 else
 530                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 531         });
 532
 533         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 534         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 535         if(bestbot < 0 || bestplayer < 0)
 536         {
 537                 LOG_DEBUG("not doing anything");
 538                 // don't return, let it reset all counters below
 539         }
 540         else if(bestbot <= bestplayer * factor - 2)
 541         {
 542                 if(autocvar_skill < 17)
 543                 {
 544                         LOG_DEBUG("2 frags difference, increasing skill");
 545                         cvar_set("skill", ftos(autocvar_skill + 1));
 546                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 547                 }
 548         }
 549         else if(bestbot >= bestplayer * factor + 2)
 550         {
 551                 if(autocvar_skill > 0)
 552                 {
 553                         LOG_DEBUG("2 frags difference, decreasing skill");
 554                         cvar_set("skill", ftos(autocvar_skill - 1));
 555                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 556                 }
 557         }
 558         else
 559         {
 560                 LOG_DEBUG("not doing anything");
 561                 return;
 562                 // don't reset counters, wait for them to accumulate
 563         }
 564
 565         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 566 }
 567
 568 void bot_calculate_stepheightvec()
 569 {
 570         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 571         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 572         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 573 }
 574
 575 float bot_fixcount()
 576 {
 577         int activerealplayers = 0;
 578         int realplayers = 0;
 579         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 580                 activerealplayers = M_ARGV(0, int);
 581                 realplayers = M_ARGV(1, int);
 582         } else {
 583                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 584                         if(IS_PLAYER(it))
 585                                 ++activerealplayers;
 586                         ++realplayers;
 587                 });
 588         }
 589
 590         int bots;
 591         // add/remove bots if needed to make sure there are at least
 592         // minplayers+bot_number, or remove all bots if no one is playing
 593         // But don't remove bots immediately on level change, as the real players
 594         // usually haven't rejoined yet
 595         bots_would_leave = false;
 596         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 597                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 598         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 599         {
 600                 float realminplayers, minplayers;
 601                 realminplayers = autocvar_minplayers;
 602                 minplayers = max(0, floor(realminplayers));
 603
 604                 float realminbots, minbots;
 605                 realminbots = autocvar_bot_number;
 606                 minbots = max(0, floor(realminbots));
 607
 608                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 609                 if(bots > minbots)
 610                         bots_would_leave = true;
 611         }
 612         else
 613         {
 614                 // if there are no players, remove bots
 615                 bots = 0;
 616         }
 617
 618         // only add one bot per frame to avoid utter chaos
 619         if(time > botframe_nextthink)
 620         {
 621                 if (currentbots < bots)
 622                 {
 623                         if (bot_spawn() == NULL)
 624                         {
 625                                 bprint("Can not add bot, server full.\n");
 626                                 return false;
 627                         }
 628                 }
 629                 while (currentbots > bots)
 630                         bot_removenewest();
 631         }
 632
 633         return true;
 634 }
 635
 636 void bot_remove_from_bot_list(entity this)
 637 {
 638         entity e = bot_list;
 639         entity prev_bot = NULL;
 640         while (e)
 641         {
 642                 if(e == this)
 643                 {
 644                         if(!prev_bot)
 645                                 bot_list = this.nextbot;
 646                         else
 647                                 prev_bot.nextbot = this.nextbot;
 648                         if(bot_strategytoken == this)
 649                         {
 650                                 bot_strategytoken = this.nextbot;
 651                                 bot_strategytoken_taken = true;
 652                         }
 653                         this.nextbot = NULL;
 654                         break;
 655                 }
 656                 prev_bot = e;
 657                 e = e.nextbot;
 658         }
 659 }
 660
 661 void bot_clear(entity this)
 662 {
 663         bot_remove_from_bot_list(this);
 664         if(bot_waypoint_queue_owner == this)
 665                 bot_waypoint_queue_owner = NULL;
 666         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 667 }
 668
 669 void bot_serverframe()
 670 {
 671         if (intermission_running && currentbots > 0)
 672         {
 673                 // after the end of the match all bots stay unless all human players disconnect
 674                 int realplayers = 0;
 675                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 676                 if (!realplayers)
 677                 {
 678                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 679                         currentbots = 0;
 680                 }
 681                 return;
 682         }
 683
 684         if (game_stopped)
 685                 return;
 686
 687         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 688         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 689         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 690         // either intentionally or automatically (sv_spectate 0)
 691         if (time < 2.5)
 692         {
 693                 currentbots = -1;
 694                 return;
 695         }
 696
 697         if (currentbots == -1)
 698         {
 699                 // count bots already in the server from the previous match
 700                 currentbots = 0;
 701                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 702         }
 703
 704         if(autocvar_skill != skill)
 705         {
 706                 float wpcost_update = false;
 707                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 708                         wpcost_update = true;
 709                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 710                         wpcost_update = true;
 711
 712                 skill = autocvar_skill;
 713                 if (wpcost_update)
 714                         waypoint_updatecost_foralllinks();
 715         }
 716
 717         bot_calculate_stepheightvec();
 718         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 719
 720         if(time > autoskill_nextthink)
 721         {
 722                 float a;
 723                 a = autocvar_skill_auto;
 724                 if(a)
 725                         autoskill(a);
 726                 autoskill_nextthink = time + 5;
 727         }
 728
 729         if(time > botframe_nextthink)
 730         {
 731                 if(!bot_fixcount())
 732                         botframe_nextthink = time + 10;
 733         }
 734
 735         if(botframe_spawnedwaypoints)
 736         {
 737                 if(autocvar_waypoint_benchmark)
 738                         localcmd("quit\n");
 739         }
 740
 741         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 742         if (botframe_spawnedwaypoints)
 743         {
 744                 if(botframe_cachedwaypointlinks)
 745                 {
 746                         if(!botframe_loadedforcedlinks)
 747                                 waypoint_load_links_hardwired();
 748                 }
 749                 else
 750                 {
 751                         // TODO: Make this check cleaner
 752                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 753                         {
 754                                 waypoint_save_links();
 755                                 break;
 756                         });
 757                 }
 758         }
 759         else
 760         {
 761                 botframe_spawnedwaypoints = true;
 762                 waypoint_loadall();
 763                 waypoint_load_links();
 764         }
 765
 766         if (bot_list)
 767         {
 768                 // cycle the goal token from one bot to the next each frame
 769                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 770                 //  frame, which causes choppy framerates)
 771                 if (bot_strategytoken_taken)
 772                 {
 773                         // give goal token to the first bot without goals; if all bots don't have
 774                         // any goal (or are dead/frozen) simply give it to the next one
 775                         bot_strategytoken_taken = false;
 776                         entity bot_strategytoken_save = bot_strategytoken;
 777                         while (true)
 778                         {
 779                                 if (bot_strategytoken)
 780                                         bot_strategytoken = bot_strategytoken.nextbot;
 781                                 if (!bot_strategytoken)
 782                                         bot_strategytoken = bot_list;
 783
 784                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 785                                         && !bot_strategytoken.goalcurrent)
 786                                         break;
 787
 788                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 789                                         break;
 790                                 if (bot_strategytoken == bot_strategytoken_save)
 791                                         bot_strategytoken_save = NULL; // looped through all the bots
 792                         }
 793                 }
 794
 795                 if (botframe_nextdangertime < time)
 796                 {
 797                         float interval;
 798                         interval = autocvar_bot_ai_dangerdetectioninterval;
 799                         if (botframe_nextdangertime < time - interval * 1.5)
 800                                 botframe_nextdangertime = time;
 801                         botframe_nextdangertime = botframe_nextdangertime + interval;
 802                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 803                 }
 804         }
 805
 806         if (autocvar_g_waypointeditor)
 807                 botframe_showwaypointlinks();
 808
 809         if (autocvar_g_waypointeditor_auto)
 810                 botframe_autowaypoints();
 811
 812         if(time > bot_cvar_nextthink)
 813         {
 814                 if(currentbots>0)
 815                         bot_custom_weapon_priority_setup();
 816                 bot_cvar_nextthink = time + 5;
 817         }
 818 }