qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         //if (this.bot_painintensity > 0)
  78         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  79
  80         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  81         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  82
  83         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  84         {
  85                 CS(this).movement = '0 0 0';
  86                 this.bot_nextthink = time + 0.5;
  87                 return;
  88         }
  89
  90         if (this.fixangle)
  91         {
  92                 this.v_angle = this.angles;
  93                 this.v_angle_z = 0;
  94                 this.fixangle = false;
  95         }
  96
  97         this.dmg_take = 0;
  98         this.dmg_save = 0;
  99         this.dmg_inflictor = NULL;
 100
 101         // calculate an aiming latency based on the skill setting
 102         // (simulated network latency + naturally delayed reflexes)
 103         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 104         // minimum ping 20+10 random
 105         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 106         // skill 10 = ping 0.2 (adrenaline)
 107         // skill 0 = ping 0.7 (slightly drunk)
 108
 109         // clear buttons
 110         PHYS_INPUT_BUTTON_ATCK(this) = false;
 111         PHYS_INPUT_BUTTON_JUMP(this) = false;
 112         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 113         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 114         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 115         PHYS_INPUT_BUTTON_HOOK(this) = false;
 116         PHYS_INPUT_BUTTON_INFO(this) = false;
 117         PHYS_INPUT_BUTTON_DRAG(this) = false;
 118         PHYS_INPUT_BUTTON_CHAT(this) = false;
 119         PHYS_INPUT_BUTTON_USE(this) = false;
 120
 121         if (time < game_starttime)
 122         {
 123                 // block the bot during the countdown to game start
 124                 CS(this).movement = '0 0 0';
 125                 this.bot_nextthink = game_starttime;
 126                 return;
 127         }
 128
 129         // if dead, just wait until we can respawn
 130         if (IS_DEAD(this))
 131         {
 132                 CS(this).movement = '0 0 0';
 133                 if (this.deadflag == DEAD_DEAD)
 134                 {
 135                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 136                         navigation_goalrating_timeout_force(this);
 137                 }
 138         }
 139         else if(this.aistatus & AI_STATUS_STUCK)
 140                 navigation_unstuck(this);
 141
 142         // now call the current bot AI (havocbot for example)
 143         this.bot_ai(this);
 144 }
 145
 146 void bot_setnameandstuff(entity this)
 147 {
 148         string readfile, s;
 149         float file, tokens, prio;
 150
 151         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 152         string name, prefix, suffix;
 153
 154         if(autocvar_g_campaign)
 155         {
 156                 prefix = "";
 157                 suffix = "";
 158         }
 159         else
 160         {
 161                 prefix = autocvar_bot_prefix;
 162                 suffix = autocvar_bot_suffix;
 163         }
 164
 165         file = fopen(autocvar_bot_config_file, FILE_READ);
 166
 167         if(file < 0)
 168         {
 169                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 170                 readfile = "";
 171         }
 172         else
 173         {
 174                 RandomSelection_Init();
 175                 while((readfile = fgets(file)))
 176                 {
 177                         if(substring(readfile, 0, 2) == "//")
 178                                 continue;
 179                         if(substring(readfile, 0, 1) == "#")
 180                                 continue;
 181                         tokens = tokenizebyseparator(readfile, "\t");
 182                         if(tokens == 0)
 183                                 continue;
 184                         s = argv(0);
 185                         prio = 1;
 186                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 187                                 if(s == it.cleanname)
 188                                 {
 189                                         prio = 0;
 190                                         break;
 191                                 }
 192                         });
 193                         RandomSelection_AddString(readfile, 1, prio);
 194                 }
 195                 readfile = RandomSelection_chosen_string;
 196                 fclose(file);
 197         }
 198
 199         tokens = tokenizebyseparator(readfile, "\t");
 200         if(argv(0) != "") bot_name = argv(0);
 201         else bot_name = "Bot";
 202
 203         if(argv(1) != "") bot_model = argv(1);
 204         else bot_model = "";
 205
 206         if(argv(2) != "") bot_skin = argv(2);
 207         else bot_skin = "0";
 208
 209         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 210         else bot_shirt = ftos(floor(random() * 15));
 211
 212         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 213         else bot_pants = ftos(floor(random() * 15));
 214
 215         this.bot_forced_team = stof(argv(5));
 216
 217         prio = 6;
 218
 219         #define READSKILL(f, w, r) MACRO_BEGIN { \
 220                 if(argv(prio) != "") \
 221                         this.f = stof(argv(prio)) * w; \
 222                 else \
 223                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 224                 prio++; \
 225         } MACRO_END
 226         //print(bot_name, ": ping=", argv(9), "\n");
 227
 228         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 229         READSKILL(bot_moveskill, 2, 0); // move skill
 230         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 231
 232         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 233
 234         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 235         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 236         READSKILL(bot_rangepreference, 1, 0); // read skill
 237
 238         READSKILL(bot_aimskill, 2, 0); // aim skill
 239         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 240         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 241
 242         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 243         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 244
 245         this.bot_config_loaded = true;
 246
 247         // this is really only a default, JoinBestTeam is called later
 248         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 249         this.bot_preferredcolors = this.clientcolors;
 250
 251         // pick the name
 252         if (autocvar_bot_usemodelnames)
 253                 name = bot_model;
 254         else
 255                 name = bot_name;
 256
 257         // number bots with identical names
 258         int j = 0;
 259         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 260                 if(it.cleanname == name)
 261                         ++j;
 262         });
 263         if (j)
 264                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 265         else
 266                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 267
 268         this.cleanname = strzone(name);
 269
 270         // pick the model and skin
 271         if(substring(bot_model, -4, 1) != ".")
 272                 bot_model = strcat(bot_model, ".iqm");
 273         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 274         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 275 }
 276
 277 void bot_custom_weapon_priority_setup()
 278 {
 279         float tokens, i, w;
 280
 281         bot_custom_weapon = false;
 282
 283         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 284                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 285                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 286                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 287         )
 288                 return;
 289
 290         // Parse distances
 291         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 292
 293         if (tokens!=2)
 294                 return;
 295
 296         bot_distance_far = stof(argv(0));
 297         bot_distance_close = stof(argv(1));
 298
 299         if(bot_distance_far < bot_distance_close){
 300                 bot_distance_far = stof(argv(1));
 301                 bot_distance_close = stof(argv(0));
 302         }
 303
 304         // Initialize list of weapons
 305         bot_weapons_far[0] = -1;
 306         bot_weapons_mid[0] = -1;
 307         bot_weapons_close[0] = -1;
 308
 309         // Parse far distance weapon priorities
 310         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 311
 312         int c = 0;
 313         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 314                 w = stof(argv(i));
 315                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 316                         bot_weapons_far[c] = w;
 317                         ++c;
 318                 }
 319         }
 320         if(c < Weapons_COUNT)
 321                 bot_weapons_far[c] = -1;
 322
 323         // Parse mid distance weapon priorities
 324         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 325
 326         c = 0;
 327         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 328                 w = stof(argv(i));
 329                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 330                         bot_weapons_mid[c] = w;
 331                         ++c;
 332                 }
 333         }
 334         if(c < Weapons_COUNT)
 335                 bot_weapons_mid[c] = -1;
 336
 337         // Parse close distance weapon priorities
 338         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 339
 340         c = 0;
 341         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 342                 w = stof(argv(i));
 343                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 344                         bot_weapons_close[c] = w;
 345                         ++c;
 346                 }
 347         }
 348         if(c < Weapons_COUNT)
 349                 bot_weapons_close[c] = -1;
 350
 351         bot_custom_weapon = true;
 352 }
 353
 354 void bot_endgame()
 355 {
 356         bot_relinkplayerlist();
 357         entity e = bot_list;
 358         while (e)
 359         {
 360                 setcolor(e, e.bot_preferredcolors);
 361                 e = e.nextbot;
 362         }
 363         // if dynamic waypoints are ever implemented, save them here
 364 }
 365
 366 void bot_relinkplayerlist()
 367 {
 368         player_count = 0;
 369         currentbots = 0;
 370         bot_list = NULL;
 371
 372         entity prevbot = NULL;
 373         FOREACH_CLIENT(true,
 374         {
 375                 ++player_count;
 376
 377                 if(IS_BOT_CLIENT(it))
 378                 {
 379                         if(prevbot)
 380                                 prevbot.nextbot = it;
 381                         else
 382                                 bot_list = it;
 383                         prevbot = it;
 384                         ++currentbots;
 385                 }
 386         });
 387         if(prevbot)
 388                 prevbot.nextbot = NULL;
 389         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 390         bot_strategytoken = bot_list;
 391         bot_strategytoken_taken = true;
 392 }
 393
 394 void bot_clientdisconnect(entity this)
 395 {
 396         if (!IS_BOT_CLIENT(this))
 397                 return;
 398         bot_clearqueue(this);
 399         if(this.cleanname)
 400                 strunzone(this.cleanname);
 401         if(this.netname_freeme)
 402                 strunzone(this.netname_freeme);
 403         if(this.playermodel_freeme)
 404                 strunzone(this.playermodel_freeme);
 405         if(this.playerskin_freeme)
 406                 strunzone(this.playerskin_freeme);
 407         this.cleanname = string_null;
 408         this.netname_freeme = string_null;
 409         this.playermodel_freeme = string_null;
 410         this.playerskin_freeme = string_null;
 411         if(this.bot_cmd_current)
 412                 delete(this.bot_cmd_current);
 413         if(bot_waypoint_queue_owner == this)
 414                 bot_waypoint_queue_owner = NULL;
 415 }
 416
 417 void bot_clientconnect(entity this)
 418 {
 419         if (!IS_BOT_CLIENT(this)) return;
 420         this.bot_preferredcolors = this.clientcolors;
 421         this.bot_nextthink = time - random();
 422         this.lag_func = bot_lagfunc;
 423         this.isbot = true;
 424         this.createdtime = this.bot_nextthink;
 425
 426         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 427         {
 428                 bot_setnameandstuff(this);
 429                 bot_setclientfields(this);
 430         }
 431
 432         if(this.bot_forced_team==1)
 433                 this.team = NUM_TEAM_1;
 434         else if(this.bot_forced_team==2)
 435                 this.team = NUM_TEAM_2;
 436         else if(this.bot_forced_team==3)
 437                 this.team = NUM_TEAM_3;
 438         else if(this.bot_forced_team==4)
 439                 this.team = NUM_TEAM_4;
 440         else
 441                 JoinBestTeamForBalance(this, true);
 442
 443         havocbot_setupbot(this);
 444 }
 445
 446 void bot_removefromlargestteam()
 447 {
 448         CheckAllowedTeams(NULL);
 449         GetTeamCounts(NULL);
 450
 451         entity best = NULL;
 452         float besttime = 0;
 453         int bestcount = 0;
 454
 455         int bcount = 0;
 456         FOREACH_CLIENT(it.isbot,
 457         {
 458                 ++bcount;
 459
 460                 if(!best)
 461                 {
 462                         best = it;
 463                         besttime = it.createdtime;
 464                 }
 465
 466                 int thiscount = 0;
 467
 468                 if (Team_IsValidTeam(it.team))
 469                 {
 470                         thiscount = Team_GetNumberOfPlayers(Team_GetTeam(it.team));
 471                 }
 472
 473                 if(thiscount > bestcount)
 474                 {
 475                         bestcount = thiscount;
 476                         besttime = it.createdtime;
 477                         best = it;
 478                 }
 479                 else if(thiscount == bestcount && besttime < it.createdtime)
 480                 {
 481                         besttime = it.createdtime;
 482                         best = it;
 483                 }
 484         });
 485         if(!bcount)
 486                 return; // no bots to remove
 487         currentbots = currentbots - 1;
 488         dropclient(best);
 489 }
 490
 491 void bot_removenewest()
 492 {
 493         if(teamplay)
 494         {
 495                 bot_removefromlargestteam();
 496                 return;
 497         }
 498
 499         float besttime = 0;
 500         entity best = NULL;
 501         int bcount = 0;
 502
 503         FOREACH_CLIENT(it.isbot,
 504         {
 505                 ++bcount;
 506
 507                 if(!best)
 508                 {
 509                         best = it;
 510                         besttime = it.createdtime;
 511                 }
 512
 513                 if(besttime < it.createdtime)
 514                 {
 515                         besttime = it.createdtime;
 516                         best = it;
 517                 }
 518         });
 519
 520         if(!bcount)
 521                 return; // no bots to remove
 522
 523         currentbots = currentbots - 1;
 524         dropclient(best);
 525 }
 526
 527 void autoskill(float factor)
 528 {
 529         float bestbot;
 530         float bestplayer;
 531
 532         bestbot = -1;
 533         bestplayer = -1;
 534         FOREACH_CLIENT(IS_PLAYER(it), {
 535                 if(IS_REAL_CLIENT(it))
 536                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 537                 else
 538                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 539         });
 540
 541         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 542         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 543         if(bestbot < 0 || bestplayer < 0)
 544         {
 545                 LOG_DEBUG("not doing anything");
 546                 // don't return, let it reset all counters below
 547         }
 548         else if(bestbot <= bestplayer * factor - 2)
 549         {
 550                 if(autocvar_skill < 17)
 551                 {
 552                         LOG_DEBUG("2 frags difference, increasing skill");
 553                         cvar_set("skill", ftos(autocvar_skill + 1));
 554                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 555                 }
 556         }
 557         else if(bestbot >= bestplayer * factor + 2)
 558         {
 559                 if(autocvar_skill > 0)
 560                 {
 561                         LOG_DEBUG("2 frags difference, decreasing skill");
 562                         cvar_set("skill", ftos(autocvar_skill - 1));
 563                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 564                 }
 565         }
 566         else
 567         {
 568                 LOG_DEBUG("not doing anything");
 569                 return;
 570                 // don't reset counters, wait for them to accumulate
 571         }
 572
 573         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 574 }
 575
 576 void bot_calculate_stepheightvec()
 577 {
 578         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 579         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 580         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 581 }
 582
 583 float bot_fixcount()
 584 {
 585         int activerealplayers = 0;
 586         int realplayers = 0;
 587         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 588                 activerealplayers = M_ARGV(0, int);
 589                 realplayers = M_ARGV(1, int);
 590         } else {
 591                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 592                         if(IS_PLAYER(it))
 593                                 ++activerealplayers;
 594                         ++realplayers;
 595                 });
 596         }
 597
 598         int bots;
 599         // add/remove bots if needed to make sure there are at least
 600         // minplayers+bot_number, or remove all bots if no one is playing
 601         // But don't remove bots immediately on level change, as the real players
 602         // usually haven't rejoined yet
 603         bots_would_leave = false;
 604         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 605                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 606         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 607         {
 608                 float realminplayers, minplayers;
 609                 realminplayers = autocvar_minplayers;
 610                 minplayers = max(0, floor(realminplayers));
 611
 612                 float realminbots, minbots;
 613                 realminbots = autocvar_bot_number;
 614                 minbots = max(0, floor(realminbots));
 615
 616                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 617                 if(bots > minbots)
 618                         bots_would_leave = true;
 619         }
 620         else
 621         {
 622                 // if there are no players, remove bots
 623                 bots = 0;
 624         }
 625
 626         // only add one bot per frame to avoid utter chaos
 627         if(time > botframe_nextthink)
 628         {
 629                 if (currentbots < bots)
 630                 {
 631                         if (bot_spawn() == NULL)
 632                         {
 633                                 bprint("Can not add bot, server full.\n");
 634                                 return false;
 635                         }
 636                 }
 637                 while (currentbots > bots)
 638                         bot_removenewest();
 639         }
 640
 641         return true;
 642 }
 643
 644 void bot_remove_from_bot_list(entity this)
 645 {
 646         entity e = bot_list;
 647         entity prev_bot = NULL;
 648         while (e)
 649         {
 650                 if(e == this)
 651                 {
 652                         if(!prev_bot)
 653                                 bot_list = this.nextbot;
 654                         else
 655                                 prev_bot.nextbot = this.nextbot;
 656                         if(bot_strategytoken == this)
 657                         {
 658                                 bot_strategytoken = this.nextbot;
 659                                 bot_strategytoken_taken = true;
 660                         }
 661                         this.nextbot = NULL;
 662                         break;
 663                 }
 664                 prev_bot = e;
 665                 e = e.nextbot;
 666         }
 667 }
 668
 669 void bot_clear(entity this)
 670 {
 671         bot_remove_from_bot_list(this);
 672         if(bot_waypoint_queue_owner == this)
 673                 bot_waypoint_queue_owner = NULL;
 674         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 675 }
 676
 677 void bot_serverframe()
 678 {
 679         if (intermission_running && currentbots > 0)
 680         {
 681                 // after the end of the match all bots stay unless all human players disconnect
 682                 int realplayers = 0;
 683                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 684                 if (!realplayers)
 685                 {
 686                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 687                         currentbots = 0;
 688                 }
 689                 return;
 690         }
 691
 692         if (game_stopped)
 693                 return;
 694
 695         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 696         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 697         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 698         // either intentionally or automatically (sv_spectate 0)
 699         if (time < 2.5)
 700         {
 701                 currentbots = -1;
 702                 return;
 703         }
 704
 705         if (currentbots == -1)
 706         {
 707                 // count bots already in the server from the previous match
 708                 currentbots = 0;
 709                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 710         }
 711
 712         if(autocvar_skill != skill)
 713         {
 714                 float wpcost_update = false;
 715                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 716                         wpcost_update = true;
 717                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 718                         wpcost_update = true;
 719
 720                 skill = autocvar_skill;
 721                 if (wpcost_update)
 722                         waypoint_updatecost_foralllinks();
 723         }
 724
 725         bot_calculate_stepheightvec();
 726         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 727
 728         if(time > autoskill_nextthink)
 729         {
 730                 float a;
 731                 a = autocvar_skill_auto;
 732                 if(a)
 733                         autoskill(a);
 734                 autoskill_nextthink = time + 5;
 735         }
 736
 737         if(time > botframe_nextthink)
 738         {
 739                 if(!bot_fixcount())
 740                         botframe_nextthink = time + 10;
 741         }
 742
 743         if(botframe_spawnedwaypoints)
 744         {
 745                 if(autocvar_waypoint_benchmark)
 746                         localcmd("quit\n");
 747         }
 748
 749         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 750         if (botframe_spawnedwaypoints)
 751         {
 752                 if(botframe_cachedwaypointlinks)
 753                 {
 754                         if(!botframe_loadedforcedlinks)
 755                                 waypoint_load_links_hardwired();
 756                 }
 757                 else
 758                 {
 759                         // TODO: Make this check cleaner
 760                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 761                         {
 762                                 waypoint_save_links();
 763                                 break;
 764                         });
 765                 }
 766         }
 767         else
 768         {
 769                 botframe_spawnedwaypoints = true;
 770                 waypoint_loadall();
 771                 waypoint_load_links();
 772         }
 773
 774         if (bot_list)
 775         {
 776                 // cycle the goal token from one bot to the next each frame
 777                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 778                 //  frame, which causes choppy framerates)
 779                 if (bot_strategytoken_taken)
 780                 {
 781                         // give goal token to the first bot without goals; if all bots don't have
 782                         // any goal (or are dead/frozen) simply give it to the next one
 783                         bot_strategytoken_taken = false;
 784                         entity bot_strategytoken_save = bot_strategytoken;
 785                         while (true)
 786                         {
 787                                 if (bot_strategytoken)
 788                                         bot_strategytoken = bot_strategytoken.nextbot;
 789                                 if (!bot_strategytoken)
 790                                         bot_strategytoken = bot_list;
 791
 792                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 793                                         && !bot_strategytoken.goalcurrent)
 794                                         break;
 795
 796                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 797                                         break;
 798                                 if (bot_strategytoken == bot_strategytoken_save)
 799                                         bot_strategytoken_save = NULL; // looped through all the bots
 800                         }
 801                 }
 802
 803                 if (botframe_nextdangertime < time)
 804                 {
 805                         float interval;
 806                         interval = autocvar_bot_ai_dangerdetectioninterval;
 807                         if (botframe_nextdangertime < time - interval * 1.5)
 808                                 botframe_nextdangertime = time;
 809                         botframe_nextdangertime = botframe_nextdangertime + interval;
 810                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 811                 }
 812         }
 813
 814         if (autocvar_g_waypointeditor)
 815                 botframe_showwaypointlinks();
 816
 817         if (autocvar_g_waypointeditor_auto)
 818                 botframe_autowaypoints();
 819
 820         if(time > bot_cvar_nextthink)
 821         {
 822                 if(currentbots>0)
 823                         bot_custom_weapon_priority_setup();
 824                 bot_cvar_nextthink = time + 5;
 825         }
 826 }