qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/net_linked.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/state.qh>
  15 #include <common/items/_mod.qh>
  16 #include <common/wepent.qh>
  17
  18 #include <common/triggers/teleporters.qh>
  19 #include <common/triggers/trigger/jumppads.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 .float speed;
  24
  25 void havocbot_ai(entity this)
  26 {
  27         if(this.draggedby)
  28                 return;
  29
  30         if(bot_execute_commands(this))
  31                 return;
  32
  33         if (bot_strategytoken == this)
  34         if (!bot_strategytoken_taken)
  35         {
  36                 if(this.havocbot_blockhead)
  37                 {
  38                         this.havocbot_blockhead = false;
  39                 }
  40                 else
  41                 {
  42                         if (!this.jumppadcount)
  43                                 this.havocbot_role(this); // little too far down the rabbit hole
  44                 }
  45
  46                 // TODO: tracewalk() should take care of this job (better path finding under water)
  47                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  48                 if(!(IS_DEAD(this)))
  49                 if(!this.goalcurrent)
  50                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  51                 {
  52                         // Look for the closest waypoint out of water
  53                         entity newgoal = NULL;
  54                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  55                         {
  56                                 if(it.origin.z < this.origin.z)
  57                                         continue;
  58
  59                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  60                                         continue;
  61
  62                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  63                                         continue;
  64
  65                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  66
  67                                 if(trace_fraction < 1)
  68                                         continue;
  69
  70                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  71                                         newgoal = it;
  72                         });
  73
  74                         if(newgoal)
  75                         {
  76                         //      te_wizspike(newgoal.origin);
  77                                 navigation_pushroute(this, newgoal);
  78                         }
  79                 }
  80
  81                 // token has been used this frame
  82                 bot_strategytoken_taken = true;
  83         }
  84
  85         if(IS_DEAD(this))
  86                 return;
  87
  88         havocbot_chooseenemy(this);
  89
  90         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  91         {
  92                 .entity weaponentity = weaponentities[slot];
  93                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  94                 if(this.(weaponentity).bot_chooseweapontime < time)
  95                 {
  96                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  97                         havocbot_chooseweapon(this, weaponentity);
  98                 }
  99         }
 100         havocbot_aim(this);
 101         lag_update(this);
 102         if (this.bot_aimtarg)
 103         {
 104                 this.aistatus |= AI_STATUS_ATTACKING;
 105                 this.aistatus &= ~AI_STATUS_ROAMING;
 106
 107                 if(this.weapons)
 108                 {
 109                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 110                         {
 111                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 112                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 113                         }
 114                         else
 115                         {
 116                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 117                                 {
 118                                         .entity weaponentity = weaponentities[slot];
 119                                         Weapon w = this.(weaponentity).m_weapon;
 120                                         if(w == WEP_Null && slot != 0)
 121                                                 continue;
 122                                         w.wr_aim(w, this, weaponentity);
 123                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 124                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 125                                 }
 126                         }
 127                 }
 128                 else
 129                 {
 130                         if(IS_PLAYER(this.bot_aimtarg))
 131                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 132                 }
 133         }
 134         else if (this.goalcurrent)
 135         {
 136                 this.aistatus |= AI_STATUS_ROAMING;
 137                 this.aistatus &= ~AI_STATUS_ATTACKING;
 138
 139                 vector now,v,next;//,heading;
 140                 float aimdistance,skillblend,distanceblend,blend;
 141                 next = now = ( (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5) - (this.origin + this.view_ofs);
 142                 aimdistance = vlen(now);
 143                 //heading = this.velocity;
 144                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 145                 if(
 146                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 147                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 148                 )
 149                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 150
 151                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 152                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 153                 blend = skillblend * (1-distanceblend);
 154                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 155                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 156                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 157                 v = now + blend * (next - now);
 158                 //dprint(etos(this), " ");
 159                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 160                 //v = now * (distanceblend) + next * (1-distanceblend);
 161                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 162                         v.z = 0;
 163                 //dprint("walk at:", vtos(v), "\n");
 164                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 165                 bot_aimdir(this, v, -1);
 166         }
 167         havocbot_movetogoal(this);
 168
 169         // if the bot is not attacking, consider reloading weapons
 170         if (!(this.aistatus & AI_STATUS_ATTACKING))
 171         {
 172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 173                 {
 174                         .entity weaponentity = weaponentities[slot];
 175
 176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 177                                 continue;
 178
 179                         // we are currently holding a weapon that's not fully loaded, reload it
 180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 182                                 this.impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 183
 184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 185                         // the code above executes next frame, starting the reloading then
 186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 188                         {
 189                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 190                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 191                                         {
 192                                                 this.(weaponentity).m_switchweapon = it;
 193                                                 break;
 194                                         }
 195                                 ));
 196                         }
 197                 }
 198         }
 199 }
 200
 201 void havocbot_keyboard_movement(entity this, vector destorg)
 202 {
 203         vector keyboard;
 204         float blend, maxspeed;
 205         float sk;
 206
 207         sk = skill + this.bot_moveskill;
 208
 209         maxspeed = autocvar_sv_maxspeed;
 210
 211         if (time < this.havocbot_keyboardtime)
 212                 return;
 213
 214         this.havocbot_keyboardtime =
 215                 max(
 216                         this.havocbot_keyboardtime
 217                                 + 0.05/max(1, sk+this.havocbot_keyboardskill)
 218                                 + random()*0.025/max(0.00025, skill+this.havocbot_keyboardskill)
 219                 , time);
 220         keyboard = this.movement * (1.0 / maxspeed);
 221
 222         float trigger, trigger1;
 223         blend = bound(0,sk*0.1,1);
 224         trigger = autocvar_bot_ai_keyboard_threshold;
 225         trigger1 = 0 - trigger;
 226
 227         // categorize forward movement
 228         // at skill < 1.5 only forward
 229         // at skill < 2.5 only individual directions
 230         // at skill < 4.5 only individual directions, and forward diagonals
 231         // at skill >= 4.5, all cases allowed
 232         if (keyboard.x > trigger)
 233         {
 234                 keyboard.x = 1;
 235                 if (sk < 2.5)
 236                         keyboard.y = 0;
 237         }
 238         else if (keyboard.x < trigger1 && sk > 1.5)
 239         {
 240                 keyboard.x = -1;
 241                 if (sk < 4.5)
 242                         keyboard.y = 0;
 243         }
 244         else
 245         {
 246                 keyboard.x = 0;
 247                 if (sk < 1.5)
 248                         keyboard.y = 0;
 249         }
 250         if (sk < 4.5)
 251                 keyboard.z = 0;
 252
 253         if (keyboard.y > trigger)
 254                 keyboard.y = 1;
 255         else if (keyboard.y < trigger1)
 256                 keyboard.y = -1;
 257         else
 258                 keyboard.y = 0;
 259
 260         if (keyboard.z > trigger)
 261                 keyboard.z = 1;
 262         else if (keyboard.z < trigger1)
 263                 keyboard.z = -1;
 264         else
 265                 keyboard.z = 0;
 266
 267         this.havocbot_keyboard = keyboard * maxspeed;
 268         if (this.havocbot_ducktime>time) PHYS_INPUT_BUTTON_CROUCH(this) = true;
 269
 270         keyboard = this.havocbot_keyboard;
 271         blend = bound(0,vlen(destorg-this.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 272         //dprint("movement ", vtos(this.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 273         this.movement = this.movement + (keyboard - this.movement) * blend;
 274 }
 275
 276 void havocbot_bunnyhop(entity this, vector dir)
 277 {
 278         float bunnyhopdistance;
 279         vector deviation;
 280         float maxspeed;
 281         vector gco, gno;
 282
 283         // Don't jump when attacking
 284         if(this.aistatus & AI_STATUS_ATTACKING)
 285                 return;
 286
 287         if(IS_PLAYER(this.goalcurrent))
 288                 return;
 289
 290         maxspeed = autocvar_sv_maxspeed;
 291
 292         if(this.aistatus & AI_STATUS_DANGER_AHEAD)
 293         {
 294                 this.aistatus &= ~AI_STATUS_RUNNING;
 295                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 296                 this.bot_canruntogoal = 0;
 297                 this.bot_timelastseengoal = 0;
 298                 return;
 299         }
 300
 301         if(this.waterlevel > WATERLEVEL_WETFEET)
 302         {
 303                 this.aistatus &= ~AI_STATUS_RUNNING;
 304                 return;
 305         }
 306
 307         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 308         {
 309                 this.bot_canruntogoal = 0;
 310                 this.bot_timelastseengoal = 0;
 311         }
 312
 313         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 314         bunnyhopdistance = vlen(this.origin - gco);
 315
 316         // Run only to visible goals
 317         if(IS_ONGROUND(this))
 318         if(this.speed==maxspeed)
 319         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 320         {
 321                         this.bot_lastseengoal = this.goalcurrent;
 322
 323                         // seen it before
 324                         if(this.bot_timelastseengoal)
 325                         {
 326                                 // for a period of time
 327                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 328                                 {
 329                                         float checkdistance;
 330                                         checkdistance = true;
 331
 332                                         // don't run if it is too close
 333                                         if(this.bot_canruntogoal==0)
 334                                         {
 335                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 336                                                         this.bot_canruntogoal = 1;
 337                                                 else
 338                                                         this.bot_canruntogoal = -1;
 339                                         }
 340
 341                                         if(this.bot_canruntogoal != 1)
 342                                                 return;
 343
 344                                         if(this.aistatus & AI_STATUS_ROAMING)
 345                                         if(this.goalcurrent.classname=="waypoint")
 346                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 347                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 348                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 349                                         {
 350                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 351                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 352                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 353                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 354
 355                                                 if(fabs(deviation.y) < 20)
 356                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 357                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 358                                                 {
 359                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 360                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 361                                                         {
 362                                                                 checkdistance = false;
 363                                                         }
 364                                                 }
 365                                         }
 366
 367                                         if(checkdistance)
 368                                         {
 369                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 370                                                 // increase stop distance in case the goal is on a slope or a lower platform
 371                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 372                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 373                                         }
 374                                         else
 375                                         {
 376                                                 this.aistatus |= AI_STATUS_RUNNING;
 377                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 378                                         }
 379                                 }
 380                         }
 381                         else
 382                         {
 383                                 this.bot_timelastseengoal = time;
 384                         }
 385         }
 386         else
 387         {
 388                 this.bot_timelastseengoal = 0;
 389         }
 390
 391 #if 0
 392         // Release jump button
 393         if(!cvar("sv_pogostick"))
 394         if((IS_ONGROUND(this)) == 0)
 395         {
 396                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 397                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 398
 399                 // Strafe
 400                 if(this.aistatus & AI_STATUS_RUNNING)
 401                 if(vlen(this.velocity)>maxspeed)
 402                 {
 403                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 404                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 405                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 406
 407                         if(fabs(deviation.y)>10)
 408                                 this.movement_x = 0;
 409
 410                         if(deviation.y>10)
 411                                 this.movement_y = maxspeed * -1;
 412                         else if(deviation.y<10)
 413                                 this.movement_y = maxspeed;
 414
 415                 }
 416         }
 417 #endif
 418 }
 419
 420 void havocbot_movetogoal(entity this)
 421 {
 422         vector destorg;
 423         vector diff;
 424         vector dir;
 425         vector flatdir;
 426         vector m1;
 427         vector m2;
 428         vector evadeobstacle;
 429         vector evadelava;
 430         float s;
 431         float maxspeed;
 432         vector gco;
 433         //float dist;
 434         vector dodge;
 435         //if (this.goalentity)
 436         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 437         this.movement = '0 0 0';
 438         maxspeed = autocvar_sv_maxspeed;
 439
 440         // Jetpack navigation
 441         if(this.goalcurrent)
 442         if(this.navigation_jetpack_goal)
 443         if(this.goalcurrent==this.navigation_jetpack_goal)
 444         if(this.ammo_fuel)
 445         {
 446                 if(autocvar_bot_debug_goalstack)
 447                 {
 448                         debuggoalstack(this);
 449                         te_wizspike(this.navigation_jetpack_point);
 450                 }
 451
 452                 // Take off
 453                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 454                 {
 455                         // Brake almost completely so it can get a good direction
 456                         if(vdist(this.velocity, >, 10))
 457                                 return;
 458                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 459                 }
 460
 461                 makevectors(this.v_angle.y * '0 1 0');
 462                 dir = normalize(this.navigation_jetpack_point - this.origin);
 463
 464                 // Landing
 465                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 466                 {
 467                         // Calculate brake distance in xy
 468                         float db, v, d;
 469                         vector dxy;
 470
 471                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 472                         d = vlen(dxy);
 473                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 474                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 475                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 476                         if(d < db || d < 500)
 477                         {
 478                                 // Brake
 479                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 480                                 {
 481                                         this.movement_x = dir * v_forward * -maxspeed;
 482                                         return;
 483                                 }
 484                                 // Switch to normal mode
 485                                 this.navigation_jetpack_goal = NULL;
 486                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 487                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 488                                 return;
 489                         }
 490                 }
 491                 else if(checkpvs(this.origin,this.goalcurrent))
 492                 {
 493                         // If I can see the goal switch to landing code
 494                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 495                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 496                         return;
 497                 }
 498
 499                 // Flying
 500                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 501                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 502                 {
 503                         this.movement_x = dir * v_forward * maxspeed;
 504                         this.movement_y = dir * v_right * maxspeed;
 505                 }
 506                 return;
 507         }
 508
 509         // Handling of jump pads
 510         if(this.jumppadcount)
 511         {
 512                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 513                 // but with some randomness so it can try out different paths
 514                 if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 515                 {
 516                         if(fabs(this.velocity.z)<50)
 517                         {
 518                                 entity newgoal = NULL;
 519                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 520                                 {
 521                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 522
 523                                         if(trace_fraction < 1)
 524                                                 continue;
 525
 526                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 527                                                 newgoal = it;
 528                                 });
 529
 530                                 if(newgoal)
 531                                 {
 532                                         this.ignoregoal = this.goalcurrent;
 533                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 534                                         navigation_clearroute(this);
 535                                         navigation_routetogoal(this, newgoal, this.origin);
 536                                         if(autocvar_bot_debug_goalstack)
 537                                                 debuggoalstack(this);
 538                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 539                                 }
 540                         }
 541                         else
 542                                 return;
 543                 }
 544                 else
 545                 {
 546                         if(this.velocity.z>0)
 547                         {
 548                                 float threshold;
 549                                 vector velxy = this.velocity; velxy_z = 0;
 550                                 threshold = maxspeed * 0.2;
 551                                 if(vdist(velxy, <, threshold))
 552                                 {
 553                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 554                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 555                                 }
 556                                 return;
 557                         }
 558
 559                         // Don't chase players while using a jump pad
 560                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 561                                 return;
 562                 }
 563         }
 564         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 565                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 566
 567         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 568         if(skill>6)
 569         if (!(IS_ONGROUND(this)))
 570         {
 571                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 572                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 573                 if(this.items & IT_JETPACK)
 574                 {
 575                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 576                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 577                         {
 578                                 if(this.velocity.z<0)
 579                                 {
 580                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 581                                 }
 582                         }
 583                         else
 584                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 585
 586                         // If there is no goal try to move forward
 587
 588                         if(this.goalcurrent==NULL)
 589                                 dir = v_forward;
 590                         else
 591                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 592
 593                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 594                         float xyspeed = xyvelocity * dir;
 595
 596                         if(xyspeed < (maxspeed / 2))
 597                         {
 598                                 makevectors(this.v_angle.y * '0 1 0');
 599                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 600                                 if(trace_fraction==1)
 601                                 {
 602                                         this.movement_x = dir * v_forward * maxspeed;
 603                                         this.movement_y = dir * v_right * maxspeed;
 604                                         if (skill < 10)
 605                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 606                                 }
 607                         }
 608
 609                         this.havocbot_blockhead = true;
 610
 611                         return;
 612                 }
 613                 else if(this.health>WEP_CVAR(devastator, damage)*0.5)
 614                 {
 615                         if(this.velocity.z < 0)
 616                         {
 617                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 618                                 {
 619                                         .entity weaponentity = weaponentities[slot];
 620
 621                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 622                                                 continue;
 623
 624                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 625                                         {
 626                                                 this.movement_x = maxspeed;
 627
 628                                                 if(this.rocketjumptime)
 629                                                 {
 630                                                         if(time > this.rocketjumptime)
 631                                                         {
 632                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 633                                                                 this.rocketjumptime = 0;
 634                                                         }
 635                                                         return;
 636                                                 }
 637
 638                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 639                                                 this.v_angle_x = 90;
 640                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 641                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 642                                                 return;
 643                                         }
 644                                 }
 645                         }
 646                 }
 647                 else
 648                 {
 649                         // If there is no goal try to move forward
 650                         if(this.goalcurrent==NULL)
 651                                 this.movement_x = maxspeed;
 652                 }
 653         }
 654
 655         // If we are under water with no goals, swim up
 656         if(this.waterlevel)
 657         if(this.goalcurrent==NULL)
 658         {
 659                 dir = '0 0 0';
 660                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 661                         dir.z = 1;
 662                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 663                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 664                 else
 665                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 666                 makevectors(this.v_angle.y * '0 1 0');
 667                 this.movement_x = dir * v_forward * maxspeed;
 668                 this.movement_y = dir * v_right * maxspeed;
 669                 this.movement_z = dir * v_up * maxspeed;
 670         }
 671
 672         // if there is nowhere to go, exit
 673         if (this.goalcurrent == NULL)
 674                 return;
 675
 676         navigation_poptouchedgoals(this);
 677
 678         // if ran out of goals try to use an alternative goal or get a new strategy asap
 679         if(this.goalcurrent == NULL)
 680         {
 681                 this.bot_strategytime = 0;
 682                 return;
 683         }
 684
 685
 686         if(autocvar_bot_debug_goalstack)
 687                 debuggoalstack(this);
 688
 689         m1 = this.goalcurrent.origin + this.goalcurrent.mins;
 690         m2 = this.goalcurrent.origin + this.goalcurrent.maxs;
 691         destorg = this.origin;
 692         destorg.x = bound(m1_x, destorg.x, m2_x);
 693         destorg.y = bound(m1_y, destorg.y, m2_y);
 694         destorg.z = bound(m1_z, destorg.z, m2_z);
 695         diff = destorg - this.origin;
 696         //dist = vlen(diff);
 697         dir = normalize(diff);
 698         flatdir = diff;flatdir.z = 0;
 699         flatdir = normalize(flatdir);
 700         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 701
 702         //if (this.bot_dodgevector_time < time)
 703         {
 704         //      this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 705         //      this.bot_dodgevector_jumpbutton = 1;
 706                 evadeobstacle = '0 0 0';
 707                 evadelava = '0 0 0';
 708
 709                 if (this.waterlevel)
 710                 {
 711                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 712                         {
 713                         //      flatdir_z = 1;
 714                                 this.aistatus |= AI_STATUS_OUT_WATER;
 715                         }
 716                         else
 717                         {
 718                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 719                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 720                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 721                                 else
 722                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 723                         }
 724                         dir = normalize(flatdir);
 725                         makevectors(this.v_angle.y * '0 1 0');
 726                 }
 727                 else
 728                 {
 729                         if(this.aistatus & AI_STATUS_OUT_WATER)
 730                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 731
 732                         // jump if going toward an obstacle that doesn't look like stairs we
 733                         // can walk up directly
 734                         tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.2, false, this);
 735                         if (trace_fraction < 1)
 736                         if (trace_plane_normal.z < 0.7)
 737                         {
 738                                 s = trace_fraction;
 739                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + this.velocity * 0.2 + stepheightvec, false, this);
 740                                 if (trace_fraction < s + 0.01)
 741                                 if (trace_plane_normal.z < 0.7)
 742                                 {
 743                                         s = trace_fraction;
 744                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + this.velocity * 0.2 + jumpstepheightvec, false, this);
 745                                         if (trace_fraction > s)
 746                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 747                                 }
 748                         }
 749
 750                         // avoiding dangers and obstacles
 751                         vector dst_ahead = this.origin + this.view_ofs + this.velocity * 0.5;
 752                         vector dst_down = dst_ahead - '0 0 3000';
 753
 754                         // Look ahead
 755                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 756
 757                         // Check head-banging against walls
 758                         if(vdist(this.origin + this.view_ofs - trace_endpos, <, 25) && !(this.aistatus & AI_STATUS_OUT_WATER))
 759                         {
 760                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 761                                 if(this.facingwalltime && time > this.facingwalltime)
 762                                 {
 763                                         this.ignoregoal = this.goalcurrent;
 764                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 765                                         this.bot_strategytime = 0;
 766                                         return;
 767                                 }
 768                                 else
 769                                 {
 770                                         this.facingwalltime = time + 0.05;
 771                                 }
 772                         }
 773                         else
 774                         {
 775                                 this.facingwalltime = 0;
 776
 777                                 if(this.ignoregoal != NULL && time > this.ignoregoaltime)
 778                                 {
 779                                         this.ignoregoal = NULL;
 780                                         this.ignoregoaltime = 0;
 781                                 }
 782                         }
 783
 784                         // Check for water/slime/lava and dangerous edges
 785                         // (only when the bot is on the ground or jumping intentionally)
 786                         this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 787
 788                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 789                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 790                         {
 791                                 // Look downwards
 792                                 traceline(dst_ahead , dst_down, true, NULL);
 793                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 794                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 795                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 796                                 {
 797                                         s = pointcontents(trace_endpos + '0 0 1');
 798                                         if (s != CONTENT_SOLID)
 799                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 800                                                 evadelava = normalize(this.velocity) * -1;
 801                                         else if (s == CONTENT_SKY)
 802                                                 evadeobstacle = normalize(this.velocity) * -1;
 803                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 804                                         {
 805                                                 // the traceline check isn't enough but is good as optimization,
 806                                                 // when not true (most of the time) this tracebox call is avoided
 807                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 808                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 809                                                 {
 810                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 811                                                         {
 812                                                                 // the goal is probably on an upper platform, assume bot can't get there
 813                                                                 LOG_TRACE("bot ", this.netname, " avoided the goal ", this.goalcurrent.classname, " ", etos(this.goalcurrent), " because it led to a dangerous path; goal stack cleared");
 814                                                                 navigation_clearroute(this);
 815                                                                 this.bot_strategytime = 0;
 816                                                         }
 817                                                         else
 818                                                                 evadelava = normalize(this.velocity) * -1;
 819                                                 }
 820                                         }
 821                                 }
 822                         }
 823
 824                         dir = flatdir;
 825                         evadeobstacle.z = 0;
 826                         evadelava.z = 0;
 827                         makevectors(this.v_angle.y * '0 1 0');
 828
 829                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 830                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 831                 }
 832
 833                 dodge = havocbot_dodge(this);
 834                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 835                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 836                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 837                 if(IS_PLAYER(trace_ent))
 838                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 839
 840                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 841         //      this.bot_dodgevector = dir;
 842         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 843         }
 844
 845         if(time < this.ladder_time)
 846         {
 847                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 848                 {
 849                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 850                                 dir.z = 1;
 851                 }
 852                 else
 853                 {
 854                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 855                                 dir.z = -1;
 856                 }
 857         }
 858
 859         //dir = this.bot_dodgevector;
 860         //if (this.bot_dodgevector_jumpbutton)
 861         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 862         this.movement_x = dir * v_forward * maxspeed;
 863         this.movement_y = dir * v_right * maxspeed;
 864         this.movement_z = dir * v_up * maxspeed;
 865
 866         // Emulate keyboard interface
 867         if (skill < 10)
 868                 havocbot_keyboard_movement(this, destorg);
 869
 870         // Bunnyhop!
 871 //      if(this.aistatus & AI_STATUS_ROAMING)
 872         if(this.goalcurrent)
 873         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 874                 havocbot_bunnyhop(this, dir);
 875
 876         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 877         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 878         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 879 }
 880
 881 entity havocbot_gettarget(entity this, bool secondary)
 882 {
 883         entity best = NULL;
 884         vector eye = CENTER_OR_VIEWOFS(this);
 885         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 886         {
 887                 vector v = CENTER_OR_VIEWOFS(it);
 888                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 889                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 890                 if(bot_shouldattack(this, it))
 891                 {
 892                         traceline(eye, v, true, this);
 893                         if (trace_ent == it || trace_fraction >= 1)
 894                                 best = it;
 895                 }
 896         });
 897
 898         return best;
 899 }
 900
 901 void havocbot_chooseenemy(entity this)
 902 {
 903         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 904         {
 905                 this.enemy = NULL;
 906                 return;
 907         }
 908         if (this.enemy)
 909         {
 910                 if (!bot_shouldattack(this, this.enemy))
 911                 {
 912                         // enemy died or something, find a new target
 913                         this.enemy = NULL;
 914                         this.havocbot_chooseenemy_finished = time;
 915                 }
 916                 else if (this.havocbot_stickenemy)
 917                 {
 918                         // tracking last chosen enemy
 919                         // if enemy is visible
 920                         // and not really really far away
 921                         // and we're not severely injured
 922                         // then keep tracking for a half second into the future
 923                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 924                         if (trace_ent == this.enemy || trace_fraction == 1)
 925                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 926                         if (this.health > 30)
 927                         {
 928                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 929                                 this.havocbot_chooseenemy_finished = time + 0.5;
 930                                 return;
 931                         }
 932                         // enemy isn't visible, or is far away, or we're injured severely
 933                         // so stop preferring this enemy
 934                         // (it will still take a half second until a new one is chosen)
 935                         this.havocbot_stickenemy = 0;
 936                 }
 937         }
 938         if (time < this.havocbot_chooseenemy_finished)
 939                 return;
 940         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 941         vector eye = this.origin + this.view_ofs;
 942         entity best = NULL;
 943         float bestrating = 100000000;
 944
 945         // Backup hit flags
 946         int hf = this.dphitcontentsmask;
 947
 948         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 949
 950         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 951
 952         bool scan_transparent = false;
 953         bool scan_secondary_targets = false;
 954         bool have_secondary_targets = false;
 955         while(true)
 956         {
 957                 scan_secondary_targets = false;
 958 LABEL(scan_targets)
 959                 IL_EACH(g_bot_targets, it.bot_attack,
 960                 {
 961                         if(!scan_secondary_targets)
 962                         {
 963                                 if(it.classname == "misc_breakablemodel")
 964                                 {
 965                                         have_secondary_targets = true;
 966                                         continue;
 967                                 }
 968                         }
 969                         else if(it.classname != "misc_breakablemodel")
 970                                 continue;
 971
 972                         vector v = (it.absmin + it.absmax) * 0.5;
 973                         float rating = vlen2(v - eye);
 974                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 975                         if (bestrating > rating)
 976                         if (bot_shouldattack(this, it))
 977                         {
 978                                 traceline(eye, v, true, this);
 979                                 if (trace_ent == it || trace_fraction >= 1)
 980                                 {
 981                                         best = it;
 982                                         bestrating = rating;
 983                                 }
 984                         }
 985                 });
 986
 987                 if(!best && have_secondary_targets && !scan_secondary_targets)
 988                 {
 989                         scan_secondary_targets = true;
 990                         // restart the loop
 991                         bestrating = 100000000;
 992                         goto scan_targets;
 993                 }
 994
 995                 // I want to do a second scan if no enemy was found or I don't have weapons
 996                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
 997                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
 998                         break;
 999                 if(scan_transparent)
1000                         break;
1001
1002                 // Set flags to see through transparent objects
1003                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1004
1005                 scan_transparent = true;
1006         }
1007
1008         // Restore hit flags
1009         this.dphitcontentsmask = hf;
1010
1011         this.enemy = best;
1012         this.havocbot_stickenemy = true;
1013         if(best && best.classname == "misc_breakablemodel")
1014                 this.havocbot_stickenemy = false;
1015 }
1016
1017 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1018 {
1019         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1020         // so skip this for them, or they'll never get to reload their weapons at all.
1021         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1022         if(skill < 5)
1023                 return false;
1024
1025         // if this weapon is scheduled for reloading, don't switch to it during combat
1026         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1027         {
1028                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1029                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1030                                 return true; // other weapon available
1031                 ));
1032         }
1033
1034         return false;
1035 }
1036
1037 void havocbot_chooseweapon(entity this, .entity weaponentity)
1038 {
1039         int i;
1040
1041         // ;)
1042         if(g_weaponarena_weapons == WEPSET(TUBA))
1043         {
1044                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1045                 return;
1046         }
1047
1048         // TODO: clean this up by moving it to weapon code
1049         if(this.enemy==NULL)
1050         {
1051                 // If no weapon was chosen get the first available weapon
1052                 if(this.(weaponentity).m_weapon==WEP_Null)
1053                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1054                         if(client_hasweapon(this, it, weaponentity, true, false))
1055                         {
1056                                 this.(weaponentity).m_switchweapon = it;
1057                                 return;
1058                         }
1059                 ));
1060                 return;
1061         }
1062
1063         // Do not change weapon during the next second after a combo
1064         float f = time - this.lastcombotime;
1065         if(f < 1)
1066                 return;
1067
1068         float w;
1069         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1070
1071         // Should it do a weapon combo?
1072         float af, ct, combo_time, combo;
1073
1074         af = ATTACK_FINISHED(this, 0);
1075         ct = autocvar_bot_ai_weapon_combo_threshold;
1076
1077         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1078         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1079         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1080
1081         combo = false;
1082
1083         if(autocvar_bot_ai_weapon_combo)
1084         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1085         if(af > combo_time)
1086         {
1087                 combo = true;
1088                 this.lastcombotime = time;
1089         }
1090
1091         distance *= pow(2, this.bot_rangepreference);
1092
1093         // Custom weapon list based on distance to the enemy
1094         if(bot_custom_weapon){
1095
1096                 // Choose weapons for far distance
1097                 if ( distance > bot_distance_far ) {
1098                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1099                                 w = bot_weapons_far[i];
1100                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1101                                 {
1102                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1103                                                 continue;
1104                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1105                                         return;
1106                                 }
1107                         }
1108                 }
1109
1110                 // Choose weapons for mid distance
1111                 if ( distance > bot_distance_close) {
1112                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1113                                 w = bot_weapons_mid[i];
1114                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1115                                 {
1116                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1117                                                 continue;
1118                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1119                                         return;
1120                                 }
1121                         }
1122                 }
1123
1124                 // Choose weapons for close distance
1125                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1126                         w = bot_weapons_close[i];
1127                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1128                         {
1129                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1130                                         continue;
1131                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1132                                 return;
1133                         }
1134                 }
1135         }
1136 }
1137
1138 void havocbot_aim(entity this)
1139 {
1140         vector myvel, enemyvel;
1141 //      if(this.flags & FL_INWATER)
1142 //              return;
1143         if (time < this.nextaim)
1144                 return;
1145         this.nextaim = time + 0.1;
1146         myvel = this.velocity;
1147         if (!this.waterlevel)
1148                 myvel.z = 0;
1149         if (this.enemy)
1150         {
1151                 enemyvel = this.enemy.velocity;
1152                 if (!this.enemy.waterlevel)
1153                         enemyvel.z = 0;
1154                 lag_additem(this, time + this.ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1155         }
1156         else
1157                 lag_additem(this, time + this.ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1158 }
1159
1160 bool havocbot_moveto_refresh_route(entity this)
1161 {
1162         // Refresh path to goal if necessary
1163         entity wp;
1164         wp = this.havocbot_personal_waypoint;
1165         navigation_goalrating_start(this);
1166         navigation_routerating(this, wp, 10000, 10000);
1167         navigation_goalrating_end(this);
1168         return this.navigation_hasgoals;
1169 }
1170
1171 float havocbot_moveto(entity this, vector pos)
1172 {
1173         entity wp;
1174
1175         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1176         {
1177                 // Step 4: Move to waypoint
1178                 if(this.havocbot_personal_waypoint==NULL)
1179                 {
1180                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1181                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1182                         return CMD_STATUS_ERROR;
1183                 }
1184
1185                 if (!bot_strategytoken_taken)
1186                 if(this.havocbot_personal_waypoint_searchtime<time)
1187                 {
1188                         bot_strategytoken_taken = true;
1189                         if(havocbot_moveto_refresh_route(this))
1190                         {
1191                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1192                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1193                                 this.havocbot_personal_waypoint_failcounter = 0;
1194                         }
1195                         else
1196                         {
1197                                 this.havocbot_personal_waypoint_failcounter += 1;
1198                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1199                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1200                                 {
1201                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1202                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1203                                         delete(this.havocbot_personal_waypoint);
1204                                         return CMD_STATUS_ERROR;
1205                                 }
1206                                 else
1207                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1208                         }
1209                 }
1210
1211                 if(autocvar_bot_debug_goalstack)
1212                         debuggoalstack(this);
1213
1214                 // Heading
1215                 vector dir = ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - (this.origin + this.view_ofs);
1216                 dir.z = 0;
1217                 bot_aimdir(this, dir, -1);
1218
1219                 // Go!
1220                 havocbot_movetogoal(this);
1221
1222                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1223                 {
1224                         // Step 5: Waypoint reached
1225                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1226                         delete(this.havocbot_personal_waypoint);
1227                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1228                         return CMD_STATUS_FINISHED;
1229                 }
1230
1231                 return CMD_STATUS_EXECUTING;
1232         }
1233
1234         // Step 2: Linking waypoint
1235         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1236         {
1237                 // Wait until it is linked
1238                 if(!this.havocbot_personal_waypoint.wplinked)
1239                 {
1240                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1241                         return CMD_STATUS_EXECUTING;
1242                 }
1243
1244                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1245                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1246                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1247
1248                 // Step 3: Route to waypoint
1249                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1250
1251                 return CMD_STATUS_EXECUTING;
1252         }
1253
1254         // Step 1: Spawning waypoint
1255         wp = waypoint_spawnpersonal(this, pos);
1256         if(wp==NULL)
1257         {
1258                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1259                 return CMD_STATUS_ERROR;
1260         }
1261
1262         this.havocbot_personal_waypoint = wp;
1263         this.havocbot_personal_waypoint_failcounter = 0;
1264         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1265
1266         // if pos is inside a teleport, then let's mark it as teleport waypoint
1267         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1268         {
1269                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1270                 this.lastteleporttime = 0;
1271         });
1272
1273 /*
1274         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1275                 print("routing to a teleporter\n");
1276         else
1277                 print("routing to a non-teleporter\n");
1278 */
1279
1280         return CMD_STATUS_EXECUTING;
1281 }
1282
1283 float havocbot_resetgoal(entity this)
1284 {
1285         navigation_clearroute(this);
1286         return CMD_STATUS_FINISHED;
1287 }
1288
1289 void havocbot_setupbot(entity this)
1290 {
1291         this.bot_ai = havocbot_ai;
1292         this.cmd_moveto = havocbot_moveto;
1293         this.cmd_resetgoal = havocbot_resetgoal;
1294
1295         havocbot_chooserole(this);
1296 }
1297
1298 vector havocbot_dodge(entity this)
1299 {
1300         // LordHavoc: disabled because this is too expensive
1301         return '0 0 0';
1302 #if 0
1303         entity head;
1304         vector dodge, v, n;
1305         float danger, bestdanger, vl, d;
1306         dodge = '0 0 0';
1307         bestdanger = -20;
1308         // check for dangerous objects near bot or approaching bot
1309         head = findchainfloat(bot_dodge, true);
1310         while(head)
1311         {
1312                 if (head.owner != this)
1313                 {
1314                         vl = vlen(head.velocity);
1315                         if (vl > autocvar_sv_maxspeed * 0.3)
1316                         {
1317                                 n = normalize(head.velocity);
1318                                 v = this.origin - head.origin;
1319                                 d = v * n;
1320                                 if (d > (0 - head.bot_dodgerating))
1321                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1322                                 {
1323                                         // calculate direction and distance from the flight path, by removing the forward axis
1324                                         v = v - (n * (v * n));
1325                                         danger = head.bot_dodgerating - vlen(v);
1326                                         if (bestdanger < danger)
1327                                         {
1328                                                 bestdanger = danger;
1329                                                 // dodge to the side of the object
1330                                                 dodge = normalize(v);
1331                                         }
1332                                 }
1333                         }
1334                         else
1335                         {
1336                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1337                                 if (bestdanger < danger)
1338                                 {
1339                                         bestdanger = danger;
1340                                         dodge = normalize(this.origin - head.origin);
1341                                 }
1342                         }
1343                 }
1344                 head = head.chain;
1345         }
1346         return dodge;
1347 #endif
1348 }