qcsrc/server/bot/default/havocbot/roles.qc

   1 #include "roles.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "havocbot.qh"
   6
   7 #include "../cvars.qh"
   8
   9 #include "../bot.qh"
  10 #include "../navigation.qh"
  11
  12 .float max_armorvalue;
  13 .float havocbot_role_timeout;
  14
  15 .void(entity this) havocbot_previous_role;
  16 .void(entity this) havocbot_role;
  17
  18 void havocbot_goalrating_waypoints(entity this, float ratingscale, vector org, float sradius)
  19 {
  20         // rate waypoints only if there's no alternative goal
  21         if(navigation_bestgoal)
  22                 return;
  23
  24         float f;
  25         float range = 500;
  26         sradius = max(range, (0.5 + random() * 0.5) * sradius);
  27         while(sradius > 100)
  28         {
  29                 IL_EACH(g_waypoints, vdist(it.origin - org, <, sradius)
  30                         && vdist(it.origin - org, >, max(100, sradius - range))
  31                         && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
  32                 {
  33                         if(vdist(it.origin - this.wp_goal_prev0.origin, <, range * 1.5))
  34                                 f = 0.1;
  35                         else if(vdist(it.origin - this.wp_goal_prev1.origin, <, range * 1.5))
  36                                 f = 0.1;
  37                         else
  38                                 f = 0.5 + random() * 0.5;
  39                         navigation_routerating(this, it, ratingscale * f, 2000);
  40                 });
  41                 if(navigation_bestgoal)
  42                         break;
  43                 sradius -= range;
  44         }
  45 };
  46
  47 bool havocbot_goalrating_item_can_be_left_to_teammate(entity this, entity player, entity item)
  48 {
  49         if (item.health && player.health <= this.health) {return true;}
  50         if (item.armorvalue && player.armorvalue <= this.armorvalue) {return true;}
  51         if (item.weapons && !(player.weapons & item.weapons)) {return true;}
  52         if (item.ammo_shells && player.ammo_shells <= this.ammo_shells) {return true;}
  53         if (item.ammo_nails && player.ammo_nails <= this.ammo_nails) {return true;}
  54         if (item.ammo_rockets && player.ammo_rockets <= this.ammo_rockets) {return true;}
  55         if (item.ammo_cells && player.ammo_cells <= this.ammo_cells) {return true;}
  56         if (item.ammo_plasma && player.ammo_plasma <= this.ammo_plasma) {return true;}
  57         if (item.itemdef.instanceOfPowerup) {return true;}
  58
  59         return false;
  60 };
  61
  62 bool havocbot_goalrating_item_pickable_check_players(entity this, vector org, entity item, vector item_org)
  63 {
  64         if(!teamplay)
  65                 return true;
  66
  67         // actually these variables hold the squared distances in order to optimize code
  68         float friend_distance = FLOAT_MAX;
  69         float enemy_distance = FLOAT_MAX;
  70         float dist;
  71
  72         FOREACH_CLIENT(IS_PLAYER(it) && it != this && !IS_DEAD(it),
  73         {
  74                 if (it.team == this.team)
  75                 {
  76                         if (!IS_REAL_CLIENT(it))
  77                                 continue;
  78
  79                         dist = vlen2(it.origin - item_org);
  80                         if(dist > friend_distance)
  81                                 continue;
  82
  83                         if(havocbot_goalrating_item_can_be_left_to_teammate(this, it, item))
  84                         {
  85                                 friend_distance = dist;
  86                                 continue;
  87                         }
  88                 }
  89                 else
  90                 {
  91                         // If enemy only track distances
  92                         // TODO: track only if visible ?
  93                         dist = vlen2(it.origin - item_org);
  94                         if(dist < enemy_distance)
  95                                 enemy_distance = dist;
  96                 }
  97         });
  98
  99         // Rate the item only if no one needs it, or if an enemy is closer to it
 100         if ((enemy_distance < friend_distance && vlen2(item_org - org) < enemy_distance) ||
 101                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ** 2))
 102                 return true;
 103         return false;
 104 };
 105
 106 void havocbot_goalrating_items(entity this, float ratingscale, vector org, float sradius)
 107 {
 108         float rating;
 109         vector o;
 110         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
 111
 112         IL_EACH(g_items, it.bot_pickup,
 113         {
 114                 if(!it.solid)
 115                 {
 116                         if(!autocvar_bot_ai_timeitems)
 117                                 continue;
 118                         if(!it.scheduledrespawntime)
 119                                 continue;
 120                         if(it.respawntime < max(11, autocvar_bot_ai_timeitems_minrespawndelay))
 121                                 continue;
 122                         if(it.respawntimejitter && !it.itemdef.instanceOfPowerup)
 123                                 continue;
 124
 125                         float t = 0;
 126                         if(it.itemdef.instanceOfPowerup)
 127                                 t = bound(0, skill / 10, 1) * 6;
 128                         else if(skill >= 9)
 129                                 t = 4;
 130
 131                         if(time < it.scheduledrespawntime - t)
 132                                 continue;
 133
 134                         it.bot_pickup_respawning = true;
 135                 }
 136                 o = (it.absmin + it.absmax) * 0.5;
 137                 if(vdist(o - org, >, sradius) || (it == this.ignoregoal && time < this.ignoregoaltime) )
 138                         continue;
 139
 140                 // Check if the item can be picked up safely
 141                 if(it.classname == "droppedweapon")
 142                 {
 143                         if(!IS_ONGROUND(it))
 144                                 continue;
 145                         traceline(o, o + '0 0 -1500', true, NULL);
 146
 147                         if(IN_LAVA(trace_endpos + '0 0 1'))
 148                                 continue;
 149
 150                         // this tracebox_hits_trigger_hurt call isn't needed:
 151                         // dropped weapons are removed as soon as they fall on a trigger_hurt
 152                         // and can't be rated while they are in the air
 153                         //if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
 154                         //      continue;
 155                 }
 156                 else
 157                 {
 158                         if(IN_LAVA(it.origin + (it.mins + it.maxs) * 0.5))
 159                                 continue;
 160                 }
 161
 162                 if(!havocbot_goalrating_item_pickable_check_players(this, org, it, o))
 163                         continue;
 164
 165                 rating = it.bot_pickupevalfunc(this, it);
 166
 167                 if(rating > 0)
 168                         navigation_routerating(this, it, rating * ratingscale, 2000);
 169         });
 170 }
 171
 172 #define BOT_RATING_ENEMY 2500
 173 void havocbot_goalrating_enemyplayers(entity this, float ratingscale, vector org, float sradius)
 174 {
 175         if (autocvar_bot_nofire)
 176                 return;
 177
 178         // don't chase players if we're under water
 179         if(this.waterlevel>WATERLEVEL_WETFEET)
 180                 return;
 181
 182         ratingscale = ratingscale * 0.00005; // enemies are rated around 20000 already
 183
 184         float t;
 185         FOREACH_CLIENT(IS_PLAYER(it) && bot_shouldattack(this, it), {
 186                 // TODO: Merge this logic with the bot_shouldattack function
 187                 if(vdist(it.origin - org, <, 100) || vdist(it.origin - org, >, sradius))
 188                         continue;
 189
 190                 // rate only visible enemies
 191                 /*
 192                 traceline(this.origin + this.view_ofs, it.origin, MOVE_NOMONSTERS, this);
 193                 if (trace_fraction < 1 || trace_ent != it)
 194                         continue;
 195                 */
 196
 197                 t = ((this.health + this.armorvalue) - (it.health + it.armorvalue)) / 150;
 198                 t = bound(0, 1 + t, 3);
 199                 if (skill > 3)
 200                 {
 201                         if (time < this.strength_finished - 1) t += 0.5;
 202                         if (time < it.strength_finished - 1) t -= 0.5;
 203                         if (time < this.invincible_finished - 1) t += 0.2;
 204                         if (time < it.invincible_finished - 1) t -= 0.4;
 205                 }
 206                 t += max(0, 8 - skill) * 0.05; // less skilled bots attack more mindlessly
 207                 ratingscale *= t;
 208                 if (ratingscale > 0)
 209                         navigation_routerating(this, it, ratingscale * BOT_RATING_ENEMY, 2000);
 210         });
 211 }
 212
 213 // legacy bot role for standard gamemodes
 214 // go to best items
 215 void havocbot_role_generic(entity this)
 216 {
 217         if(IS_DEAD(this))
 218                 return;
 219
 220         if (navigation_goalrating_timeout(this))
 221         {
 222                 navigation_goalrating_start(this);
 223                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 224                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 225                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 226                 navigation_goalrating_end(this);
 227
 228                 navigation_goalrating_timeout_set(this);
 229         }
 230 }
 231
 232 void havocbot_chooserole_generic(entity this)
 233 {
 234         this.havocbot_role = havocbot_role_generic;
 235 }
 236
 237 void havocbot_chooserole(entity this)
 238 {
 239         LOG_TRACE("choosing a role...");
 240         navigation_goalrating_timeout_force(this);
 241         if(!MUTATOR_CALLHOOK(HavocBot_ChooseRole, this))
 242                 havocbot_chooserole_generic(this);
 243 }