qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "waypoints.qh"
   9
  10 #include <common/t_items.qh>
  11
  12 #include <common/items/_mod.qh>
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/triggers/trigger/jumppads.qh>
  17
  18 .float speed;
  19
  20 void navigation_goalrating_timeout_set(entity this)
  21 {
  22         if(IS_MOVABLE(this.goalentity))
  23                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval_movingtarget;
  24         else
  25                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  26 }
  27
  28 // use this when current goal must be discarded immediately
  29 void navigation_goalrating_timeout_force(entity this)
  30 {
  31         navigation_goalrating_timeout_expire(this, 0);
  32 }
  33
  34 // use this when current goal can be kept for a short while to increase the chance
  35 // of bot touching a waypoint, which helps to find a new goal more efficiently
  36 void navigation_goalrating_timeout_expire(entity this, float seconds)
  37 {
  38         if (seconds <= 0)
  39                 this.bot_strategytime = 0;
  40         else if (this.bot_strategytime > time + seconds)
  41                 this.bot_strategytime = time + seconds;
  42 }
  43
  44 bool navigation_goalrating_timeout(entity this)
  45 {
  46         return this.bot_strategytime < time;
  47 }
  48
  49 #define MAX_CHASE_DISTANCE 700
  50 bool navigation_goalrating_timeout_can_be_anticipated(entity this)
  51 {
  52         if(time > this.bot_strategytime - (IS_MOVABLE(this.goalentity) ? 3 : 2))
  53                 return true;
  54
  55         if (this.goalentity.bot_pickup && time > this.bot_strategytime - 5)
  56         {
  57                 vector gco = (this.goalentity.absmin + this.goalentity.absmax) * 0.5;
  58                 if(!havocbot_goalrating_item_pickable_check_players(this, this.origin, this.goalentity, gco))
  59                 {
  60                         this.ignoregoal = this.goalentity;
  61                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
  62                         return true;
  63                 }
  64         }
  65         return false;
  66 }
  67
  68 void navigation_dynamicgoal_init(entity this, bool initially_static)
  69 {
  70         this.navigation_dynamicgoal = true;
  71         this.bot_basewaypoint = this.nearestwaypoint;
  72         if(initially_static)
  73                 this.nearestwaypointtimeout = -1;
  74         else
  75                 this.nearestwaypointtimeout = time;
  76 }
  77
  78 void navigation_dynamicgoal_set(entity this)
  79 {
  80         this.nearestwaypointtimeout = time;
  81         if (this.nearestwaypoint)
  82                 this.nearestwaypointtimeout += 2;
  83 }
  84
  85 void navigation_dynamicgoal_unset(entity this)
  86 {
  87         if(this.bot_basewaypoint)
  88                 this.nearestwaypoint = this.bot_basewaypoint;
  89         this.nearestwaypointtimeout = -1;
  90 }
  91
  92 // returns point of ent closer to org
  93 vector get_closer_dest(entity ent, vector org)
  94 {
  95         vector dest = '0 0 0';
  96         if ((ent.classname != "waypoint") || ent.wpisbox)
  97         {
  98                 vector wm1 = ent.origin + ent.mins;
  99                 vector wm2 = ent.origin + ent.maxs;
 100                 dest.x = bound(wm1.x, org.x, wm2.x);
 101                 dest.y = bound(wm1.y, org.y, wm2.y);
 102                 dest.z = bound(wm1.z, org.z, wm2.z);
 103         }
 104         else
 105                 dest = ent.origin;
 106         return dest;
 107 }
 108
 109 void set_tracewalk_dest(entity ent, vector org, bool fix_player_dest)
 110 {
 111         if ((ent.classname != "waypoint") || ent.wpisbox)
 112         {
 113                 vector wm1 = ent.origin + ent.mins;
 114                 vector wm2 = ent.origin + ent.maxs;
 115                 if (IS_PLAYER(ent) || IS_MONSTER(ent))
 116                 {
 117                         // move destination point out of player bbox otherwise tracebox always fails
 118                         // (if bot_navigation_ignoreplayers is false)
 119                         wm1 += vec2(PL_MIN_CONST) + '-1 -1 0';
 120                         wm2 += vec2(PL_MAX_CONST) + '1 1 0';
 121                 }
 122                 // set destination point to x and y coords of ent that are closer to org
 123                 // z coord is set to ent's min height
 124                 tracewalk_dest.x = bound(wm1.x, org.x, wm2.x);
 125                 tracewalk_dest.y = bound(wm1.y, org.y, wm2.y);
 126                 tracewalk_dest.z = wm1.z;
 127                 tracewalk_dest_height = wm2.z - wm1.z; // destination height
 128         }
 129         else
 130         {
 131                 tracewalk_dest = ent.origin;
 132                 tracewalk_dest_height = 0;
 133         }
 134         if (fix_player_dest && IS_PLAYER(ent) && !IS_ONGROUND(ent))
 135         {
 136                 // snap player to the ground
 137                 if (org.x == tracewalk_dest.x && org.y == tracewalk_dest.y)
 138                 {
 139                         // bot is right under the player
 140                         tracebox(ent.origin, ent.mins, ent.maxs, ent.origin - '0 0 700', MOVE_NORMAL, ent);
 141                         tracewalk_dest = trace_endpos;
 142                         tracewalk_dest_height = 0;
 143                 }
 144                 else
 145                 {
 146                         tracebox(tracewalk_dest, ent.mins, ent.maxs, tracewalk_dest - '0 0 700', MOVE_NORMAL, ent);
 147                         if (!trace_startsolid && tracewalk_dest.z - trace_endpos.z > 0)
 148                         {
 149                                 tracewalk_dest_height = tracewalk_dest.z - trace_endpos.z;
 150                                 tracewalk_dest.z = trace_endpos.z;
 151                         }
 152                 }
 153         }
 154 }
 155
 156 // returns point of ent closer to org
 157 vector set_tracewalk_dest_2(entity ent, vector org)
 158 {
 159         vector closer_dest = '0 0 0';
 160         if ((ent.classname != "waypoint") || ent.wpisbox)
 161         {
 162                 vector wm1 = ent.origin + ent.mins;
 163                 vector wm2 = ent.origin + ent.maxs;
 164                 closer_dest.x = bound(wm1.x, org.x, wm2.x);
 165                 closer_dest.y = bound(wm1.y, org.y, wm2.y);
 166                 closer_dest.z = bound(wm1.z, org.z, wm2.z);
 167                 // set destination point to x and y coords of ent that are closer to org
 168                 // z coord is set to ent's min height
 169                 tracewalk_dest.x = closer_dest.x;
 170                 tracewalk_dest.y = closer_dest.y;
 171                 tracewalk_dest.z = wm1.z;
 172                 tracewalk_dest_height = wm2.z - wm1.z; // destination height
 173         }
 174         else
 175         {
 176                 closer_dest = ent.origin;
 177                 tracewalk_dest = closer_dest;
 178                 tracewalk_dest_height = 0;
 179         }
 180         return closer_dest;
 181 }
 182
 183 bool navigation_check_submerged_state(entity ent, vector pos)
 184 {
 185         bool submerged;
 186         if(IS_PLAYER(ent))
 187                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
 188         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
 189                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
 190         else
 191         {
 192                 submerged = SUBMERGED(pos);
 193                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
 194                 //  is actually submerged because often they are inside some solid.
 195                 //  That's why submerged state is saved now that we know current pos is
 196                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
 197                 if(!ent.navigation_dynamicgoal)
 198                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
 199         }
 200         return submerged;
 201 }
 202
 203 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
 204 {
 205         IL_EACH(g_ladders, it.classname == "func_ladder",
 206         {
 207                 if(it.bot_pickup)
 208                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
 209                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
 210                 {
 211                         vector top = org;
 212                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
 213                         tracebox(org, m1, m2, top, movemode, e);
 214                         if(trace_fraction == 1)
 215                                 return true;
 216                 }
 217         });
 218         return false;
 219 }
 220
 221 vector resurface_limited(vector org, float lim, vector m1)
 222 {
 223         if (WETFEET(org + eZ * (lim - org.z)))
 224                 org.z = lim;
 225         else
 226         {
 227                 float RES_min_h = org.z;
 228                 float RES_max_h = lim;
 229                 do {
 230                         org.z = 0.5 * (RES_min_h + RES_max_h);
 231                         if(WETFEET(org))
 232                                 RES_min_h = org.z;
 233                         else
 234                                 RES_max_h = org.z;
 235                 } while (RES_max_h - RES_min_h >= 1);
 236                 org.z = RES_min_h;
 237         }
 238         return org;
 239 }
 240 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
 241
 242 #define NAV_WALK 0
 243 #define NAV_SWIM_ONWATER 1
 244 #define NAV_SWIM_UNDERWATER 2
 245
 246 // rough simulation of walking from one point to another to test if a path
 247 // can be traveled, used for waypoint linking and havocbot
 248 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 249 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 250 {
 251         if(autocvar_bot_debug_tracewalk)
 252         {
 253                 debugresetnodes();
 254                 debugnode(e, start);
 255         }
 256
 257         vector org = start;
 258         vector flatdir = end - start;
 259         flatdir.z = 0;
 260         float flatdist = vlen(flatdir);
 261         flatdir = normalize(flatdir);
 262         float stepdist = 32;
 263         bool ignorehazards = false;
 264         int nav_action;
 265
 266         // Analyze starting point
 267         if (IN_LAVA(start))
 268                 ignorehazards = true;
 269
 270         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 271         if (trace_startsolid)
 272         {
 273                 // Bad start
 274                 if(autocvar_bot_debug_tracewalk)
 275                         debugnodestatus(start, DEBUG_NODE_FAIL);
 276
 277                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 278                 return false;
 279         }
 280
 281         vector end2 = end;
 282         if(end_height)
 283                 end2.z += end_height;
 284
 285         vector fixed_end = end;
 286         vector move;
 287
 288         if (flatdist > 0 && WETFEET(org))
 289         {
 290                 if (SUBMERGED(org))
 291                         nav_action = NAV_SWIM_UNDERWATER;
 292                 else
 293                 {
 294                         // tracebox down by player's height
 295                         // useful to know if water level is so low that bot can still walk
 296                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 297                         if (SUBMERGED(trace_endpos))
 298                         {
 299                                 org = trace_endpos;
 300                                 nav_action = NAV_SWIM_UNDERWATER;
 301                         }
 302                         else
 303                                 nav_action = NAV_WALK;
 304                 }
 305         }
 306         else
 307                 nav_action =  NAV_WALK;
 308
 309         // Movement loop
 310         while (true)
 311         {
 312                 if (flatdist <= 0)
 313                 {
 314                         bool success = true;
 315                         if (org.z > end2.z + 1)
 316                         {
 317                                 tracebox(org, m1, m2, end2, movemode, e);
 318                                 org = trace_endpos;
 319                                 if (org.z > end2.z + 1)
 320                                         success = false;
 321                         }
 322                         else if (org.z < end.z - 1)
 323                         {
 324                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 325                                 if (SUBMERGED(trace_endpos))
 326                                 {
 327                                         vector v = trace_endpos;
 328                                         tracebox(v, m1, m2, end, movemode, e);
 329                                         if(trace_endpos.z >= end.z - 1)
 330                                         {
 331                                                 RESURFACE_LIMITED(v, trace_endpos.z);
 332                                                 trace_endpos = v;
 333                                         }
 334                                 }
 335                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 336                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 337                                 org = trace_endpos;
 338                                 if (org.z < end.z - 1)
 339                                         success = false;
 340                         }
 341
 342                         if (success)
 343                         {
 344                                 // Succeeded
 345                                 if(autocvar_bot_debug_tracewalk)
 346                                 {
 347                                         debugnode(e, org);
 348                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 349                                 }
 350
 351                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 352                                 return true;
 353                         }
 354                 }
 355
 356                 if(autocvar_bot_debug_tracewalk)
 357                         debugnode(e, org);
 358
 359                 if (flatdist <= 0)
 360                         break;
 361
 362                 if (stepdist > flatdist)
 363                         stepdist = flatdist;
 364                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 365                 {
 366                         // can't use movement direction here to calculate move because of
 367                         // precision errors especially when direction has a high enough z value
 368                         //water_dir = normalize(water_end - org);
 369                         //move = org + water_dir * stepdist;
 370                         fixed_end.z = bound(end.z, org.z, end2.z);
 371                         if (stepdist == flatdist) {
 372                                 move = fixed_end;
 373                                 flatdist = 0;
 374                         } else {
 375                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 376                                 flatdist = vlen(vec2(fixed_end - move));
 377                         }
 378                 }
 379                 else // horiz. direction
 380                 {
 381                         flatdist -= stepdist;
 382                         move = org + flatdir * stepdist;
 383                 }
 384
 385                 if(nav_action == NAV_SWIM_ONWATER)
 386                 {
 387                         tracebox(org, m1, m2, move, movemode, e); // swim
 388
 389                         // hit something
 390                         if (trace_fraction < 1)
 391                         {
 392                                 // stepswim
 393                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 394
 395                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 396                                 {
 397                                         org = trace_endpos;
 398                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 399                                         {
 400                                                 if(autocvar_bot_debug_tracewalk)
 401                                                 {
 402                                                         debugnode(e, org);
 403                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 404                                                 }
 405
 406                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 407                                                 return true;
 408                                         }
 409
 410                                         if(autocvar_bot_debug_tracewalk)
 411                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 412
 413                                         return false;
 414                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 415                                 }
 416
 417                                 //succesful stepswim
 418
 419                                 if (flatdist <= 0)
 420                                 {
 421                                         org = trace_endpos;
 422                                         continue;
 423                                 }
 424
 425                                 if (org.z <= move.z) // going horiz.
 426                                 {
 427                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 428                                         org = trace_endpos;
 429                                         nav_action = NAV_WALK;
 430                                         continue;
 431                                 }
 432                         }
 433
 434                         if (org.z <= move.z) // going horiz.
 435                         {
 436                                 org = trace_endpos;
 437                                 nav_action = NAV_SWIM_ONWATER;
 438                         }
 439                         else // going down
 440                         {
 441                                 org = trace_endpos;
 442                                 if (SUBMERGED(org))
 443                                         nav_action = NAV_SWIM_UNDERWATER;
 444                                 else
 445                                         nav_action = NAV_SWIM_ONWATER;
 446                         }
 447                 }
 448                 else if(nav_action == NAV_SWIM_UNDERWATER)
 449                 {
 450                         if (move.z >= org.z) // swimming upwards or horiz.
 451                         {
 452                                 tracebox(org, m1, m2, move, movemode, e); // swim
 453
 454                                 bool stepswum = false;
 455
 456                                 // hit something
 457                                 if (trace_fraction < 1)
 458                                 {
 459                                         // stepswim
 460                                         vector stepswim_move = move + stepheightvec;
 461                                         if (flatdist > 0 && stepswim_move.z > end2.z + stepheightvec.z) // don't allow stepswim to go higher than destination
 462                                                 stepswim_move.z = end2.z;
 463
 464                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 465
 466                                         // hit something
 467                                         if (trace_startsolid)
 468                                         {
 469                                                 if(autocvar_bot_debug_tracewalk)
 470                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 471
 472                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 473                                                 return false;
 474                                         }
 475
 476                                         if (trace_fraction < 1)
 477                                         {
 478                                                 float org_z_prev = org.z;
 479                                                 RESURFACE_LIMITED(org, end2.z);
 480                                                 if(org.z == org_z_prev)
 481                                                 {
 482                                                         if(autocvar_bot_debug_tracewalk)
 483                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 484
 485                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 486                                                         return false;
 487                                                 }
 488                                                 if(SUBMERGED(org))
 489                                                         nav_action = NAV_SWIM_UNDERWATER;
 490                                                 else
 491                                                         nav_action = NAV_SWIM_ONWATER;
 492
 493                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 494                                                 // but we can't do it properly right now... apply this workaround instead
 495                                                 if (flatdist <= 0)
 496                                                         flatdist = 1;
 497
 498                                                 continue;
 499                                         }
 500
 501                                         //succesful stepswim
 502
 503                                         if (flatdist <= 0)
 504                                         {
 505                                                 org = trace_endpos;
 506                                                 continue;
 507                                         }
 508
 509                                         stepswum = true;
 510                                 }
 511
 512                                 if (!WETFEET(trace_endpos))
 513                                 {
 514                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 515                                         // if stepswum we'll land on the obstacle, avoid the SUBMERGED check
 516                                         if (!stepswum && SUBMERGED(trace_endpos))
 517                                         {
 518                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 519                                                 org = trace_endpos;
 520                                                 nav_action = NAV_SWIM_ONWATER;
 521                                                 continue;
 522                                         }
 523
 524                                         // not submerged
 525                                         org = trace_endpos;
 526                                         nav_action = NAV_WALK;
 527                                         continue;
 528                                 }
 529
 530                                 // wetfeet
 531                                 org = trace_endpos;
 532                                 nav_action = NAV_SWIM_UNDERWATER;
 533                                 continue;
 534                         }
 535                         else //if (move.z < org.z) // swimming downwards
 536                         {
 537                                 tracebox(org, m1, m2, move, movemode, e); // swim
 538
 539                                 // hit something
 540                                 if (trace_fraction < 1)
 541                                 {
 542                                         // stepswim
 543                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 544
 545                                         // hit something
 546                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 547                                         {
 548                                                 if(autocvar_bot_debug_tracewalk)
 549                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 550
 551                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 552                                                 return false;
 553                                         }
 554
 555                                         //succesful stepswim
 556
 557                                         if (flatdist <= 0)
 558                                         {
 559                                                 org = trace_endpos;
 560                                                 continue;
 561                                         }
 562
 563                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 564                                         {
 565                                                 // stepswim caused upwards direction
 566                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 567                                                 if (!SUBMERGED(trace_endpos))
 568                                                 {
 569                                                         org = trace_endpos;
 570                                                         nav_action = NAV_WALK;
 571                                                         continue;
 572                                                 }
 573                                         }
 574                                 }
 575
 576                                 org = trace_endpos;
 577                                 nav_action = NAV_SWIM_UNDERWATER;
 578                                 continue;
 579                         }
 580                 }
 581                 else if(nav_action == NAV_WALK)
 582                 {
 583                         // walk
 584                         tracebox(org, m1, m2, move, movemode, e);
 585
 586                         if(autocvar_bot_debug_tracewalk)
 587                                 debugnode(e, trace_endpos);
 588
 589                         // hit something
 590                         if (trace_fraction < 1)
 591                         {
 592                                 // check if we can walk over this obstacle, possibly by jumpstepping
 593                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 594                                 if (trace_fraction < 1 || trace_startsolid)
 595                                 {
 596                                         if (trace_startsolid) // hit ceiling above org
 597                                         {
 598                                                 // reduce stepwalk height
 599                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 600                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 601                                         }
 602                                         else //if (trace_fraction < 1)
 603                                         {
 604                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 605                                                 if (trace_startsolid) // hit ceiling above org
 606                                                 {
 607                                                         // reduce jumpstepwalk height
 608                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 609                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 610                                                 }
 611                                         }
 612
 613                                         if (trace_fraction < 1)
 614                                         {
 615                                                 vector v = trace_endpos;
 616                                                 v.z = org.z + jumpheight_vec.z;
 617                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 618                                                 {
 619                                                         if(autocvar_bot_debug_tracewalk)
 620                                                         {
 621                                                                 debugnode(e, v);
 622                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 623                                                         }
 624
 625                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 626                                                         return true;
 627                                                 }
 628
 629                                                 if(autocvar_bot_debug_tracewalk)
 630                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 631
 632                                                 traceline( org, move, movemode, e);
 633
 634                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 635                                                 {
 636                                                         vector nextmove;
 637                                                         move = trace_endpos;
 638                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 639                                                         {
 640                                                                 nextmove = move + (flatdir * stepdist);
 641                                                                 traceline( move, nextmove, movemode, e);
 642                                                                 move = nextmove;
 643                                                         }
 644                                                         flatdist = vlen(vec2(end - move));
 645                                                 }
 646                                                 else
 647                                                 {
 648                                                         if(autocvar_bot_debug_tracewalk)
 649                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 650
 651                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 652                                                         //te_explosion(trace_endpos);
 653                                                         //print(ftos(e.dphitcontentsmask), "\n");
 654                                                         return false; // failed
 655                                                 }
 656                                         }
 657                                         else
 658                                                 move = trace_endpos;
 659                                 }
 660                                 else
 661                                         move = trace_endpos;
 662                         }
 663                         else
 664                                 move = trace_endpos;
 665
 666                         // trace down from stepheight as far as possible and move there,
 667                         // if this starts in solid we try again without the stepup, and
 668                         // if that also fails we assume it is a wall
 669                         // (this is the same logic as the Quake walkmove function used)
 670                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 671
 672                         org = trace_endpos;
 673
 674                         if (!ignorehazards)
 675                         {
 676                                 if (IN_LAVA(org))
 677                                 {
 678                                         if(autocvar_bot_debug_tracewalk)
 679                                         {
 680                                                 debugnode(e, trace_endpos);
 681                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 682                                         }
 683
 684                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 685                                         return false;
 686                                 }
 687                         }
 688
 689                         if (flatdist <= 0)
 690                         {
 691                                 if(move.z >= end2.z && org.z < end2.z)
 692                                         org.z = end2.z;
 693                                 continue;
 694                         }
 695
 696                         if(org.z > move.z - 1 || !SUBMERGED(org))
 697                         {
 698                                 nav_action = NAV_WALK;
 699                                 continue;
 700                         }
 701
 702                         // ended up submerged while walking
 703                         if(autocvar_bot_debug_tracewalk)
 704                                 debugnode(e, org);
 705
 706                         RESURFACE_LIMITED(org, move.z);
 707                         nav_action = NAV_SWIM_ONWATER;
 708                         continue;
 709                 }
 710         }
 711
 712         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 713
 714         // moved but didn't arrive at the intended destination
 715         if(autocvar_bot_debug_tracewalk)
 716                 debugnodestatus(org, DEBUG_NODE_FAIL);
 717
 718         return false;
 719 }
 720
 721 /////////////////////////////////////////////////////////////////////////////
 722 // goal stack
 723 /////////////////////////////////////////////////////////////////////////////
 724
 725 // completely empty the goal stack, used when deciding where to go
 726 void navigation_clearroute(entity this)
 727 {
 728         this.goalcurrent_prev = this.goalcurrent;
 729         this.goalcurrent_distance_2d = FLOAT_MAX;
 730         this.goalcurrent_distance_z = FLOAT_MAX;
 731         this.goalcurrent_distance_time = 0;
 732         this.goalentity_lock_timeout = 0;
 733         this.goalentity_shouldbefrozen = false;
 734         this.goalentity = NULL;
 735         this.goalcurrent = NULL;
 736         this.goalstack01 = NULL;
 737         this.goalstack02 = NULL;
 738         this.goalstack03 = NULL;
 739         this.goalstack04 = NULL;
 740         this.goalstack05 = NULL;
 741         this.goalstack06 = NULL;
 742         this.goalstack07 = NULL;
 743         this.goalstack08 = NULL;
 744         this.goalstack09 = NULL;
 745         this.goalstack10 = NULL;
 746         this.goalstack11 = NULL;
 747         this.goalstack12 = NULL;
 748         this.goalstack13 = NULL;
 749         this.goalstack14 = NULL;
 750         this.goalstack15 = NULL;
 751         this.goalstack16 = NULL;
 752         this.goalstack17 = NULL;
 753         this.goalstack18 = NULL;
 754         this.goalstack19 = NULL;
 755         this.goalstack20 = NULL;
 756         this.goalstack21 = NULL;
 757         this.goalstack22 = NULL;
 758         this.goalstack23 = NULL;
 759         this.goalstack24 = NULL;
 760         this.goalstack25 = NULL;
 761         this.goalstack26 = NULL;
 762         this.goalstack27 = NULL;
 763         this.goalstack28 = NULL;
 764         this.goalstack29 = NULL;
 765         this.goalstack30 = NULL;
 766         this.goalstack31 = NULL;
 767 }
 768
 769 // add a new goal at the beginning of the stack
 770 // (in other words: add a new prerequisite before going to the later goals)
 771 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 772 // next-closest WP on the shortest path to the WP
 773 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 774 // steps to the goal, and then recalculate the path.
 775 void navigation_pushroute(entity this, entity e)
 776 {
 777         this.goalcurrent_prev = this.goalcurrent;
 778         this.goalcurrent_distance_2d = FLOAT_MAX;
 779         this.goalcurrent_distance_z = FLOAT_MAX;
 780         this.goalcurrent_distance_time = 0;
 781         //print("bot ", etos(this), " push ", etos(e), "\n");
 782         if(this.goalstack31 == this.goalentity)
 783                 this.goalentity = NULL;
 784         this.goalstack31 = this.goalstack30;
 785         this.goalstack30 = this.goalstack29;
 786         this.goalstack29 = this.goalstack28;
 787         this.goalstack28 = this.goalstack27;
 788         this.goalstack27 = this.goalstack26;
 789         this.goalstack26 = this.goalstack25;
 790         this.goalstack25 = this.goalstack24;
 791         this.goalstack24 = this.goalstack23;
 792         this.goalstack23 = this.goalstack22;
 793         this.goalstack22 = this.goalstack21;
 794         this.goalstack21 = this.goalstack20;
 795         this.goalstack20 = this.goalstack19;
 796         this.goalstack19 = this.goalstack18;
 797         this.goalstack18 = this.goalstack17;
 798         this.goalstack17 = this.goalstack16;
 799         this.goalstack16 = this.goalstack15;
 800         this.goalstack15 = this.goalstack14;
 801         this.goalstack14 = this.goalstack13;
 802         this.goalstack13 = this.goalstack12;
 803         this.goalstack12 = this.goalstack11;
 804         this.goalstack11 = this.goalstack10;
 805         this.goalstack10 = this.goalstack09;
 806         this.goalstack09 = this.goalstack08;
 807         this.goalstack08 = this.goalstack07;
 808         this.goalstack07 = this.goalstack06;
 809         this.goalstack06 = this.goalstack05;
 810         this.goalstack05 = this.goalstack04;
 811         this.goalstack04 = this.goalstack03;
 812         this.goalstack03 = this.goalstack02;
 813         this.goalstack02 = this.goalstack01;
 814         this.goalstack01 = this.goalcurrent;
 815         this.goalcurrent = e;
 816 }
 817
 818 // remove first goal from stack
 819 // (in other words: remove a prerequisite for reaching the later goals)
 820 // (used when a spawnfunc_waypoint is reached)
 821 void navigation_poproute(entity this)
 822 {
 823         this.goalcurrent_prev = this.goalcurrent;
 824         this.goalcurrent_distance_2d = FLOAT_MAX;
 825         this.goalcurrent_distance_z = FLOAT_MAX;
 826         this.goalcurrent_distance_time = 0;
 827         //print("bot ", etos(this), " pop\n");
 828         if(this.goalcurrent == this.goalentity)
 829         {
 830                 this.goalentity = NULL;
 831                 this.goalentity_lock_timeout = 0;
 832         }
 833         this.goalcurrent = this.goalstack01;
 834         this.goalstack01 = this.goalstack02;
 835         this.goalstack02 = this.goalstack03;
 836         this.goalstack03 = this.goalstack04;
 837         this.goalstack04 = this.goalstack05;
 838         this.goalstack05 = this.goalstack06;
 839         this.goalstack06 = this.goalstack07;
 840         this.goalstack07 = this.goalstack08;
 841         this.goalstack08 = this.goalstack09;
 842         this.goalstack09 = this.goalstack10;
 843         this.goalstack10 = this.goalstack11;
 844         this.goalstack11 = this.goalstack12;
 845         this.goalstack12 = this.goalstack13;
 846         this.goalstack13 = this.goalstack14;
 847         this.goalstack14 = this.goalstack15;
 848         this.goalstack15 = this.goalstack16;
 849         this.goalstack16 = this.goalstack17;
 850         this.goalstack17 = this.goalstack18;
 851         this.goalstack18 = this.goalstack19;
 852         this.goalstack19 = this.goalstack20;
 853         this.goalstack20 = this.goalstack21;
 854         this.goalstack21 = this.goalstack22;
 855         this.goalstack22 = this.goalstack23;
 856         this.goalstack23 = this.goalstack24;
 857         this.goalstack24 = this.goalstack25;
 858         this.goalstack25 = this.goalstack26;
 859         this.goalstack26 = this.goalstack27;
 860         this.goalstack27 = this.goalstack28;
 861         this.goalstack28 = this.goalstack29;
 862         this.goalstack29 = this.goalstack30;
 863         this.goalstack30 = this.goalstack31;
 864         this.goalstack31 = NULL;
 865 }
 866
 867 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 868 // waypoint destination coordinates instead of v (only useful for box waypoints)
 869 // for normal waypoints v2 == v and v2_height == 0
 870 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, vector o2, float o2_height, float walkfromwp, float bestdist)
 871 {
 872         if (vdist(v - org, <, bestdist))
 873         {
 874                 traceline(v, org, true, ent);
 875                 if (trace_fraction == 1)
 876                 {
 877                         if (walkfromwp)
 878                         {
 879                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 880                                         return true;
 881                         }
 882                         else
 883                         {
 884                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, o2, o2_height, bot_navigation_movemode))
 885                                         return true;
 886                         }
 887                 }
 888         }
 889         return false;
 890 }
 891
 892 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 893 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 894 {
 895         if(ent.tag_entity)
 896                 ent = ent.tag_entity;
 897
 898         vector pm1 = ent.origin + ent.mins;
 899         vector pm2 = ent.origin + ent.maxs;
 900
 901         // do two scans, because box test is cheaper
 902         IL_EACH(g_waypoints, it != ent && it != except,
 903         {
 904                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 905                 {
 906                         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 907                         {
 908                                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 909                                 navigation_item_addlink(it, ent);
 910                         }
 911                         return it;
 912                 }
 913         });
 914
 915         vector org = ent.origin;
 916         if (navigation_testtracewalk)
 917                 te_plasmaburn(org);
 918
 919         entity best = NULL;
 920         vector v = '0 0 0';
 921
 922         if(ent.size && !IS_PLAYER(ent))
 923         {
 924                 org += 0.5 * (ent.mins + ent.maxs);
 925                 org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 926         }
 927
 928         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 929         {
 930                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 931                 IL_EACH(g_waypoints, it != ent,
 932                 {
 933                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 934                                 continue;
 935
 936                         set_tracewalk_dest(ent, it.origin, false);
 937                         if (vdist(tracewalk_dest - it.origin, <, 1050)
 938                                 && tracewalk(ent, it.origin, PL_MIN_CONST, PL_MAX_CONST,
 939                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 940                         {
 941                                 navigation_item_addlink(it, ent);
 942                         }
 943                 });
 944         }
 945
 946         // box check failed, try walk
 947         IL_EACH(g_waypoints, it != ent,
 948         {
 949                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 950                         continue;
 951                 v = it.origin;
 952
 953                 if (walkfromwp)
 954                 {
 955                         set_tracewalk_dest(ent, v, true);
 956                         if (trace_ent == ent)
 957                         {
 958                                 bestdist = 0;
 959                                 best = it;
 960                                 break;
 961                         }
 962                 }
 963                 else
 964                         set_tracewalk_dest(it, org, false);
 965
 966                 if (navigation_waypoint_will_link(v, org, ent,
 967                         tracewalk_dest, tracewalk_dest_height,
 968                         tracewalk_dest, tracewalk_dest_height, walkfromwp, bestdist))
 969                 {
 970                         if (walkfromwp)
 971                                 bestdist = vlen(tracewalk_dest - v);
 972                         else
 973                                 bestdist = vlen(v - org);
 974                         best = it;
 975                 }
 976         });
 977         if(!best && !ent.navigation_dynamicgoal)
 978         {
 979                 int solid_save = ent.solid;
 980                 ent.solid = SOLID_BSP;
 981                 IL_EACH(g_jumppads, true,
 982                 {
 983                         if(trigger_push_test(it, ent))
 984                         {
 985                                 best = it.nearestwaypoint;
 986                                 break;
 987                         }
 988                 });
 989                 ent.solid = solid_save;
 990         }
 991         return best;
 992 }
 993 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 994 {
 995         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 996         if (autocvar_g_waypointeditor_auto)
 997         {
 998                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 999                 if (wp && !wp2)
1000                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
1001         }
1002         return wp;
1003 }
1004
1005 // finds the waypoints near the bot initiating a navigation query
1006 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
1007 {
1008         //navigation_testtracewalk = true;
1009         int c = 0;
1010         IL_EACH(g_waypoints, !it.wpconsidered,
1011         {
1012                 set_tracewalk_dest(it, this.origin, false);
1013
1014                 vector diff = tracewalk_dest - this.origin;
1015                 diff.z = max(0, diff.z);
1016                 if(vdist(diff, <, maxdist))
1017                 {
1018                         it.wpconsidered = true;
1019                         if (tracewalk(this, this.origin, this.mins, this.maxs,
1020                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1021                         {
1022                                 it.wpnearestpoint = tracewalk_dest;
1023                                 it.wpcost = waypoint_gettravelcost(this.origin, tracewalk_dest, this, it) + it.dmg;
1024                                 it.wpfire = 1;
1025                                 it.enemy = NULL;
1026                                 c = c + 1;
1027                         }
1028                 }
1029         });
1030         //navigation_testtracewalk = false;
1031         return c;
1032 }
1033
1034 // updates a path link if a spawnfunc_waypoint link is better than the current one
1035 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
1036 {
1037         vector m1, m2;
1038         vector v;
1039         if (wp.wpisbox)
1040         {
1041                 m1 = wp.origin + wp.mins;
1042                 m2 = wp.origin + wp.maxs;
1043                 v.x = bound(m1_x, p.x, m2_x);
1044                 v.y = bound(m1_y, p.y, m2_y);
1045                 v.z = bound(m1_z, p.z, m2_z);
1046         }
1047         else
1048                 v = wp.origin;
1049         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1050                 cost += w.wp00mincost; // assuming teleport has exactly one destination
1051         else
1052                 cost += waypoint_gettravelcost(p, v, w, wp);
1053         if (wp.wpcost > cost)
1054         {
1055                 wp.wpcost = cost;
1056                 wp.enemy = w;
1057                 wp.wpfire = 1;
1058                 wp.wpnearestpoint = v;
1059         }
1060 }
1061
1062 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
1063 void navigation_markroutes(entity this, entity fixed_source_waypoint)
1064 {
1065         float cost, cost2;
1066         vector p;
1067
1068         IL_EACH(g_waypoints, true,
1069         {
1070                 it.wpconsidered = false;
1071                 it.wpnearestpoint = '0 0 0';
1072                 it.wpcost = 10000000;
1073                 it.wpfire = 0;
1074                 it.enemy = NULL;
1075         });
1076
1077         if(fixed_source_waypoint)
1078         {
1079                 fixed_source_waypoint.wpconsidered = true;
1080                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1081                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
1082                 fixed_source_waypoint.wpfire = 1;
1083                 fixed_source_waypoint.enemy = NULL;
1084         }
1085         else
1086         {
1087                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
1088                 // as this search is expensive we will use lower values if the bot is on the air
1089                 float increment, maxdistance;
1090                 if(IS_ONGROUND(this))
1091                 {
1092                         increment = 750;
1093                         maxdistance = 50000;
1094                 }
1095                 else
1096                 {
1097                         increment = 500;
1098                         maxdistance = 1500;
1099                 }
1100
1101                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
1102         }
1103
1104         bool searching = true;
1105         while (searching)
1106         {
1107                 searching = false;
1108                 IL_EACH(g_waypoints, it.wpfire,
1109                 {
1110                         searching = true;
1111                         it.wpfire = 0;
1112                         cost = it.wpcost;
1113                         p = it.wpnearestpoint;
1114                         entity wp;
1115                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1116                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1117                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1118                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1119                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1120                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1121                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1122                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1123                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1124                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1125                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1126                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1127                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1128                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1129                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1130                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1131                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1132                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1133                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1134                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1135                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1136                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1137                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1138                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1139                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1140                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1141                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1142                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1143                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1144                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1145                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1146                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1147                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1148                 });
1149         }
1150 }
1151
1152 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
1153 void navigation_markroutes_inverted(entity fixed_source_waypoint)
1154 {
1155         float cost, cost2;
1156         vector p;
1157         IL_EACH(g_waypoints, true,
1158         {
1159                 it.wpconsidered = false;
1160                 it.wpnearestpoint = '0 0 0';
1161                 it.wpcost = 10000000;
1162                 it.wpfire = 0;
1163                 it.enemy = NULL;
1164         });
1165
1166         if(fixed_source_waypoint)
1167         {
1168                 fixed_source_waypoint.wpconsidered = true;
1169                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1170                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
1171                 fixed_source_waypoint.wpfire = 1;
1172                 fixed_source_waypoint.enemy = NULL;
1173         }
1174         else
1175         {
1176                 error("need to start with a waypoint\n");
1177         }
1178
1179         bool searching = true;
1180         while (searching)
1181         {
1182                 searching = false;
1183                 IL_EACH(g_waypoints, it.wpfire,
1184                 {
1185                         searching = true;
1186                         it.wpfire = 0;
1187                         cost = it.wpcost; // cost to walk from it to home
1188                         p = it.wpnearestpoint;
1189                         entity wp = it;
1190                         IL_EACH(g_waypoints, it != wp,
1191                         {
1192                                 if(!waypoint_islinked(it, wp))
1193                                         continue;
1194                                 cost2 = cost + it.dmg;
1195                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
1196                         });
1197                 });
1198         }
1199 }
1200
1201 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1202 void navigation_routerating(entity this, entity e, float f, float rangebias)
1203 {
1204         if (!e)
1205                 return;
1206
1207         if(e.blacklisted)
1208                 return;
1209
1210         rangebias = waypoint_getlinearcost(rangebias);
1211         f = waypoint_getlinearcost(f);
1212
1213         if (IS_PLAYER(e))
1214         {
1215                 bool rate_wps = false;
1216                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1217                         rate_wps = true;
1218
1219                 if(!IS_ONGROUND(e))
1220                 {
1221                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1222                         int t = pointcontents(trace_endpos + '0 0 1');
1223                         if(t != CONTENT_SOLID )
1224                         {
1225                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1226                                         rate_wps = true;
1227                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1228                                         return;
1229                         }
1230                 }
1231
1232                 if(rate_wps)
1233                 {
1234                         entity theEnemy = e;
1235                         entity best_wp = NULL;
1236                         float best_dist = 10000;
1237                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1238                                 && vdist(it.origin - this.origin, >, 100)
1239                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1240                         {
1241                                 float dist = vlen(it.origin - theEnemy.origin);
1242                                 if (dist < best_dist)
1243                                 {
1244                                         best_wp = it;
1245                                         best_dist = dist;
1246                                 }
1247                         });
1248                         if (!best_wp)
1249                                 return;
1250                         e = best_wp;
1251                 }
1252         }
1253
1254         vector goal_org = (e.absmin + e.absmax) * 0.5;
1255
1256         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1257
1258         // Evaluate path using jetpack
1259         if(this.items & IT_JETPACK)
1260         if(autocvar_bot_ai_navigation_jetpack)
1261         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1262         {
1263                 vector pointa, pointb;
1264
1265                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1266
1267                 // Point A
1268                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1269                 pointa = trace_endpos - '0 0 1';
1270
1271                 // Point B
1272                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1273                 pointb = trace_endpos - '0 0 1';
1274
1275                 // Can I see these two points from the sky?
1276                 traceline(pointa, pointb, MOVE_NORMAL, this);
1277
1278                 if(trace_fraction==1)
1279                 {
1280                         LOG_DEBUG("jetpack ai: can bridge these two points");
1281
1282                         // Lower the altitude of these points as much as possible
1283                         float zdistance, xydistance, cost, t, fuel;
1284                         vector down, npa, npb;
1285
1286                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1287
1288                         do{
1289                                 npa = pointa + down;
1290                                 npb = pointb + down;
1291
1292                                 if(npa.z<=this.absmax.z)
1293                                         break;
1294
1295                                 if(npb.z<=e.absmax.z)
1296                                         break;
1297
1298                                 traceline(npa, npb, MOVE_NORMAL, this);
1299                                 if(trace_fraction==1)
1300                                 {
1301                                         pointa = npa;
1302                                         pointb = npb;
1303                                 }
1304                         }
1305                         while(trace_fraction == 1);
1306
1307
1308                         // Rough estimation of fuel consumption
1309                         // (ignores acceleration and current xyz velocity)
1310                         xydistance = vlen(pointa - pointb);
1311                         zdistance = fabs(pointa.z - this.origin.z);
1312
1313                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1314                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1315                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1316
1317                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1318
1319                         // enough fuel ?
1320                         if(this.ammo_fuel>fuel || (this.items & IT_UNLIMITED_WEAPON_AMMO))
1321                         {
1322                                 // Estimate cost
1323                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1324                                 //  - between air and ground speeds)
1325
1326                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1327                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1328                                 cost *= 1.5;
1329
1330                                 // Compare against other goals
1331                                 f = f * rangebias / (rangebias + cost);
1332
1333                                 if (navigation_bestrating < f)
1334                                 {
1335                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1336                                         navigation_bestrating = f;
1337                                         navigation_bestgoal = e;
1338                                         this.navigation_jetpack_goal = e;
1339                                         this.navigation_jetpack_point = pointb;
1340                                 }
1341                                 return;
1342                         }
1343                 }
1344         }
1345
1346         entity nwp;
1347         //te_wizspike(e.origin);
1348         //bprint(etos(e));
1349         //bprint("\n");
1350         // update the cached spawnfunc_waypoint link on a dynamic item entity
1351         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1352         {
1353                 nwp = e;
1354         }
1355         else
1356         {
1357                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1358                         e.nearestwaypoint = NULL;
1359
1360                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1361                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1362                 {
1363                         if(IS_BOT_CLIENT(e) && e.goalcurrent && e.goalcurrent.classname == "waypoint")
1364                                 e.nearestwaypoint = nwp = e.goalcurrent;
1365                         else
1366                                 e.nearestwaypoint = nwp = navigation_findnearestwaypoint(e, true);
1367                         if(!nwp)
1368                         {
1369                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1370
1371                                 if(!e.navigation_dynamicgoal)
1372                                         e.blacklisted = true;
1373
1374                                 if(e.blacklisted)
1375                                 {
1376                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1377                                         return;
1378                                 }
1379                         }
1380
1381                         if(e.navigation_dynamicgoal)
1382                                 e.nearestwaypointtimeout = time + 2;
1383                         else if(autocvar_g_waypointeditor)
1384                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1385                 }
1386                 nwp = e.nearestwaypoint;
1387         }
1388
1389         if (nwp && nwp.wpcost < 10000000)
1390         {
1391                 //te_wizspike(nwp.wpnearestpoint);
1392                 float nwptoitem_cost = 0;
1393                 if(nwp.wpflags & WAYPOINTFLAG_TELEPORT)
1394                         nwptoitem_cost = nwp.wp00mincost;
1395                 else
1396                         nwptoitem_cost = waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1397                 float cost = nwp.wpcost + nwptoitem_cost;
1398                 LOG_DEBUG("checking ^5", e.classname, "^7 with base rating ^xf04", ftos(f), "^7 and rangebias ^xf40", ftos(rangebias));
1399                 f = f * rangebias / (rangebias + cost);
1400                 LOG_DEBUG("         ^5", e.classname, "^7 with cost ^6", ftos(cost), "^7 and final rating ^2", ftos(f));
1401                 if (navigation_bestrating < f)
1402                 {
1403                         LOG_DEBUG(" ground path: ^3added goal ^5", e.classname);
1404                         navigation_bestrating = f;
1405                         navigation_bestgoal = e;
1406                 }
1407         }
1408 }
1409
1410 // adds an item to the the goal stack with the path to a given item
1411 bool navigation_routetogoal(entity this, entity e, vector startposition)
1412 {
1413         // if there is no goal, just exit
1414         if (!e)
1415                 return false;
1416
1417         entity teleport_goal = NULL;
1418
1419         this.goalentity = e;
1420
1421         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1422         {
1423                 // force teleport destination as route destination
1424                 teleport_goal = e;
1425                 navigation_pushroute(this, e.wp00);
1426                 this.goalentity = e.wp00;
1427         }
1428
1429         // put the entity on the goal stack
1430         //print("routetogoal ", etos(e), "\n");
1431         navigation_pushroute(this, e);
1432
1433         if(teleport_goal)
1434                 e = this.goalentity;
1435
1436         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1437         {
1438                 this.wp_goal_prev1 = this.wp_goal_prev0;
1439                 this.wp_goal_prev0 = e;
1440         }
1441
1442         if(g_jetpack)
1443         if(e==this.navigation_jetpack_goal)
1444                 return true;
1445
1446         // if it can reach the goal there is nothing more to do
1447         set_tracewalk_dest(e, startposition, true);
1448         if ((!IS_MOVABLE(this.goalcurrent) || vdist(tracewalk_dest - this.origin, <, MAX_CHASE_DISTANCE))
1449                 && (trace_ent == this || tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this),
1450                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
1451         {
1452                 return true;
1453         }
1454
1455         entity nearest_wp = NULL;
1456         // see if there are waypoints describing a path to the item
1457         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1458         {
1459                 e = e.nearestwaypoint;
1460                 nearest_wp = e;
1461         }
1462         else if(teleport_goal)
1463                 e = teleport_goal;
1464         else
1465                 e = e.enemy; // we already have added it, so...
1466
1467         if(e == NULL)
1468                 return false;
1469
1470         if(nearest_wp && nearest_wp.enemy)
1471         {
1472                 // often path can be optimized by not adding the nearest waypoint
1473                 if (this.goalentity.navigation_dynamicgoal || autocvar_g_waypointeditor)
1474                 {
1475                         if (nearest_wp.enemy.wpcost < autocvar_bot_ai_strategyinterval_movingtarget)
1476                         {
1477                                 if (vdist(vec2(this.goalentity.origin - nearest_wp.origin), <, 32))
1478                                         e = nearest_wp.enemy;
1479                                 else
1480                                 {
1481                                         set_tracewalk_dest(this.goalentity, nearest_wp.enemy.origin, true);
1482                                         if (trace_ent == this || (vdist(tracewalk_dest - nearest_wp.enemy.origin, <, 1050)
1483                                                 && vlen2(tracewalk_dest - nearest_wp.enemy.origin) < vlen2(nearest_wp.origin - nearest_wp.enemy.origin)
1484                                                 && tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1485                                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
1486                                         {
1487                                                 e = nearest_wp.enemy;
1488                                         }
1489                                 }
1490                         }
1491                 }
1492                 else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1493                         e = nearest_wp.enemy;
1494         }
1495
1496         for (;;)
1497         {
1498                 // add the spawnfunc_waypoint to the path
1499                 navigation_pushroute(this, e);
1500                 e = e.enemy;
1501
1502                 if(e==NULL)
1503                         break;
1504         }
1505
1506         return false;
1507 }
1508
1509 // shorten path by removing intermediate goals
1510 void navigation_shortenpath(entity this)
1511 {
1512         if (!this.goalstack01 || wasfreed(this.goalstack01))
1513                 return;
1514         if (this.bot_tracewalk_time > time)
1515                 return;
1516         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
1517
1518         bool cut_allowed = false;
1519         entity next = this.goalentity;
1520         // evaluate whether bot can discard current route and chase directly a player, trying to
1521         // keep waypoint route as long as possible, as it is safer and faster (bot can bunnyhop)
1522         if (IS_MOVABLE(next))
1523         {
1524                 set_tracewalk_dest(next, this.origin, true);
1525                 if (vdist(this.origin - tracewalk_dest, <, 200))
1526                         cut_allowed = true;
1527                 else if (vdist(tracewalk_dest - this.origin, <, MAX_CHASE_DISTANCE)
1528                         && vdist(tracewalk_dest - this.goalcurrent.origin, >, 200)
1529                         && vdist(this.origin - this.goalcurrent.origin, >, 100)
1530                         && checkpvs(this.origin + this.view_ofs, next))
1531                 {
1532                         if (vlen2(next.origin - this.origin) < vlen2(this.goalcurrent.origin - this.origin))
1533                                 cut_allowed = true;
1534                         else
1535                         {
1536                                 vector deviation = vectoangles(this.goalcurrent.origin - this.origin) - vectoangles(next.origin - this.origin);
1537                                 while (deviation.y < -180) deviation.y += 360;
1538                                 while (deviation.y > 180) deviation.y -= 360;
1539                                 if (fabs(deviation.y) > 25)
1540                                         cut_allowed = true;
1541                         }
1542                 }
1543                 if (cut_allowed)
1544                 {
1545                         if (trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
1546                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1547                         {
1548                                 LOG_DEBUG("path optimized for ", this.netname, ", route cleared");
1549                                 do
1550                                 {
1551                                         navigation_poproute(this);
1552                                 }
1553                                 while (this.goalcurrent != next);
1554                         }
1555                         return;
1556                 }
1557         }
1558
1559         next = this.goalstack01;
1560         // if for some reason the bot is closer to the next goal, pop the current one
1561         if (!IS_MOVABLE(next) // already checked in the previous case
1562                 && vlen2(this.goalcurrent.origin - next.origin) > vlen2(next.origin - this.origin)
1563                 && checkpvs(this.origin + this.view_ofs, next))
1564         {
1565                 set_tracewalk_dest(next, this.origin, true);
1566                 cut_allowed = true;
1567         }
1568
1569         if (cut_allowed)
1570         {
1571                 if (trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
1572                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1573                 {
1574                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1575                         navigation_poproute(this);
1576                 }
1577         }
1578 }
1579
1580 // removes any currently touching waypoints from the goal stack
1581 // (this is how bots detect if they reached a goal)
1582 int navigation_poptouchedgoals(entity this)
1583 {
1584         int removed_goals = 0;
1585
1586         if(!this.goalcurrent)
1587                 return removed_goals;
1588
1589         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1590         {
1591                 // make sure jumppad is really hit, don't rely on distance based checks
1592                 // as they may report a touch even if it didn't really happen
1593                 if(this.lastteleporttime > 0 && TELEPORT_USED(this, this.goalcurrent))
1594                 {
1595                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1596                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1597                         {
1598                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1599                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1600                         }
1601                         if(this.jumppadcount)
1602                         {
1603                                 // remove jumppad waypoint after a random delay to prevent bots getting
1604                                 // stuck on certain jumppads that require an extra initial horizontal speed
1605                                 float max_delay = 0.1;
1606                                 if (vdist(vec2(this.velocity), >, 2 * autocvar_sv_maxspeed))
1607                                         max_delay = 0.05;
1608                                 if (time - this.lastteleporttime < random() * max_delay)
1609                                         return removed_goals;
1610                         }
1611                         navigation_poproute(this);
1612                         this.lastteleporttime = 0;
1613                         ++removed_goals;
1614                 }
1615                 else
1616                         return removed_goals;
1617         }
1618         else if (this.lastteleporttime > 0)
1619         {
1620                 // sometimes bot is pushed so hard (by a jumppad or a shot) that ends up touching the next
1621                 // teleport / jumppad / warpzone present in its path skipping check of one or more goals
1622                 // if so immediately fix bot path by removing skipped goals
1623                 entity tele_ent = NULL;
1624                 if (this.goalstack01 && (this.goalstack01.wpflags & WAYPOINTFLAG_TELEPORT))
1625                         tele_ent = this.goalstack01;
1626                 else if (this.goalstack02 && (this.goalstack02.wpflags & WAYPOINTFLAG_TELEPORT))
1627                         tele_ent = this.goalstack02;
1628                 else if (this.goalstack03 && (this.goalstack03.wpflags & WAYPOINTFLAG_TELEPORT))
1629                         tele_ent = this.goalstack03;
1630                 if (tele_ent && TELEPORT_USED(this, tele_ent))
1631                 {
1632                         if (this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1633                         if (tele_ent.wpflags & WAYPOINTFLAG_PERSONAL && tele_ent.owner == this)
1634                         {
1635                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1636                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1637                         }
1638                         while (this.goalcurrent != tele_ent)
1639                         {
1640                                 navigation_poproute(this);
1641                                 ++removed_goals;
1642                         }
1643                         navigation_poproute(this);
1644                         this.lastteleporttime = 0;
1645                         ++removed_goals;
1646                         return removed_goals;
1647                 }
1648         }
1649
1650         // Loose goal touching check when running
1651         if(this.aistatus & AI_STATUS_RUNNING)
1652         if(this.goalcurrent.classname=="waypoint")
1653         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1654         {
1655                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1656                 {
1657                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1658                         if(trace_fraction==1)
1659                         {
1660                                 // Detect personal waypoints
1661                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1662                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1663                                 {
1664                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1665                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1666                                 }
1667
1668                                 navigation_poproute(this);
1669                                 ++removed_goals;
1670                                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1671                                         return removed_goals;
1672                         }
1673                 }
1674         }
1675
1676         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1677         {
1678                 vector gc_min = this.goalcurrent.absmin;
1679                 vector gc_max = this.goalcurrent.absmax;
1680                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1681                 {
1682                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1683                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1684                 }
1685                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1686                         break;
1687
1688                 // Detect personal waypoints
1689                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1690                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1691                 {
1692                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1693                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1694                 }
1695
1696                 navigation_poproute(this);
1697                 ++removed_goals;
1698                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1699                         return removed_goals;
1700         }
1701         return removed_goals;
1702 }
1703
1704 entity navigation_get_really_close_waypoint(entity this)
1705 {
1706         entity wp = this.goalcurrent;
1707         if(!wp)
1708                 wp = this.goalcurrent_prev;
1709         if(!wp)
1710                 return NULL;
1711         if(wp != this.goalcurrent_prev && vdist(wp.origin - this.origin, >, 50))
1712         {
1713                 wp = this.goalcurrent_prev;
1714                 if(!wp)
1715                         return NULL;
1716         }
1717         if(wp.classname != "waypoint")
1718         {
1719                 wp = wp.nearestwaypoint;
1720                 if(!wp)
1721                         return NULL;
1722         }
1723         if(vdist(wp.origin - this.origin, >, 50))
1724         {
1725                 wp = NULL;
1726                 IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1727                 {
1728                         if(vdist(it.origin - this.origin, <, 50))
1729                         {
1730                                 wp = it;
1731                                 break;
1732                         }
1733                 });
1734                 if(!wp)
1735                         return NULL;
1736         }
1737         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1738                 return NULL;
1739
1740         set_tracewalk_dest(wp, this.origin, false);
1741         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1742                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1743         {
1744                 return NULL;
1745         }
1746         return wp;
1747 }
1748
1749 // begin a goal selection session (queries spawnfunc_waypoint network)
1750 void navigation_goalrating_start(entity this)
1751 {
1752         if(this.aistatus & AI_STATUS_STUCK)
1753                 return;
1754
1755         this.navigation_jetpack_goal = NULL;
1756         navigation_bestrating = -1;
1757         entity wp = navigation_get_really_close_waypoint(this);
1758         navigation_clearroute(this);
1759         navigation_bestgoal = NULL;
1760         navigation_markroutes(this, wp);
1761 }
1762
1763 // ends a goal selection session (updates goal stack to the best goal)
1764 void navigation_goalrating_end(entity this)
1765 {
1766         if(this.aistatus & AI_STATUS_STUCK)
1767                 return;
1768
1769         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1770         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1771
1772         // If the bot got stuck then try to reach the farthest waypoint
1773         if (!this.goalentity && autocvar_bot_wander_enable)
1774         {
1775                 if (!(this.aistatus & AI_STATUS_STUCK))
1776                 {
1777                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1778                         this.aistatus |= AI_STATUS_STUCK;
1779                 }
1780         }
1781         this.goalentity_shouldbefrozen = boolean(STAT(FROZEN, this.goalentity));
1782 }
1783
1784 void botframe_updatedangerousobjects(float maxupdate)
1785 {
1786         vector m1, m2, v, o;
1787         float c, d, danger;
1788         c = 0;
1789         entity wp_cur;
1790         IL_EACH(g_waypoints, true,
1791         {
1792                 danger = 0;
1793                 m1 = it.absmin;
1794                 m2 = it.absmax;
1795                 wp_cur = it;
1796                 IL_EACH(g_bot_dodge, it.bot_dodge,
1797                 {
1798                         v = it.origin;
1799                         v.x = bound(m1_x, v.x, m2_x);
1800                         v.y = bound(m1_y, v.y, m2_y);
1801                         v.z = bound(m1_z, v.z, m2_z);
1802                         o = (it.absmin + it.absmax) * 0.5;
1803                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1804                         if (d > 0)
1805                         {
1806                                 traceline(o, v, true, NULL);
1807                                 if (trace_fraction == 1)
1808                                         danger = danger + d;
1809                         }
1810                 });
1811                 it.dmg = danger;
1812                 c = c + 1;
1813                 if (c >= maxupdate)
1814                         break;
1815         });
1816 }
1817
1818 void navigation_unstuck(entity this)
1819 {
1820         if (!autocvar_bot_wander_enable)
1821                 return;
1822
1823         bool has_user_waypoints = false;
1824         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_GENERATED),
1825         {
1826                 has_user_waypoints = true;
1827                 break;
1828         });
1829         if (!has_user_waypoints)
1830                 return;
1831
1832         float search_radius = 1000;
1833
1834         if (!bot_waypoint_queue_owner)
1835         {
1836                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1837                 bot_waypoint_queue_owner = this;
1838                 bot_waypoint_queue_bestgoal = NULL;
1839                 bot_waypoint_queue_bestgoalrating = 0;
1840         }
1841
1842         if(bot_waypoint_queue_owner!=this)
1843                 return;
1844
1845         if (bot_waypoint_queue_goal)
1846         {
1847                 // evaluate the next goal on the queue
1848                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1849                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1850                 set_tracewalk_dest(bot_waypoint_queue_goal, this.origin, false);
1851                 if (tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1852                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1853                 {
1854                         if( d > bot_waypoint_queue_bestgoalrating)
1855                         {
1856                                 bot_waypoint_queue_bestgoalrating = d;
1857                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1858                         }
1859                 }
1860                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1861
1862                 if (!bot_waypoint_queue_goal)
1863                 {
1864                         if (bot_waypoint_queue_bestgoal)
1865                         {
1866                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1867                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1868                                 navigation_goalrating_timeout_set(this);
1869                                 this.aistatus &= ~AI_STATUS_STUCK;
1870                         }
1871                         else
1872                         {
1873                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1874                         }
1875
1876                         bot_waypoint_queue_owner = NULL;
1877                 }
1878         }
1879         else
1880         {
1881                 if(bot_strategytoken!=this)
1882                         return;
1883
1884                 // build a new queue
1885                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1886
1887                 entity first = NULL;
1888
1889                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1890                 {
1891                         if(bot_waypoint_queue_goal)
1892                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1893                         else
1894                                 first = it;
1895
1896                         bot_waypoint_queue_goal = it;
1897                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1898                 });
1899
1900                 if (first)
1901                         bot_waypoint_queue_goal = first;
1902                 else
1903                 {
1904                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1905                         bot_waypoint_queue_owner = NULL;
1906                 }
1907         }
1908 }
1909
1910 // Support for debugging tracewalk visually
1911
1912 void debugresetnodes()
1913 {
1914         debuglastnode = '0 0 0';
1915 }
1916
1917 void debugnode(entity this, vector node)
1918 {
1919         if (!IS_PLAYER(this))
1920                 return;
1921
1922         if(debuglastnode=='0 0 0')
1923         {
1924                 debuglastnode = node;
1925                 return;
1926         }
1927
1928         te_lightning2(NULL, node, debuglastnode);
1929         debuglastnode = node;
1930 }
1931
1932 void debugnodestatus(vector position, float status)
1933 {
1934         vector c;
1935
1936         switch (status)
1937         {
1938                 case DEBUG_NODE_SUCCESS:
1939                         c = '0 15 0';
1940                         break;
1941                 case DEBUG_NODE_WARNING:
1942                         c = '15 15 0';
1943                         break;
1944                 case DEBUG_NODE_FAIL:
1945                         c = '15 0 0';
1946                         break;
1947                 default:
1948                         c = '15 15 15';
1949         }
1950
1951         te_customflash(position, 40,  2, c);
1952 }
1953
1954 // Support for debugging the goal stack visually
1955
1956 .float goalcounter;
1957 .vector lastposition;
1958
1959 // Debug the goal stack visually
1960 void debuggoalstack(entity this)
1961 {
1962         entity goal;
1963         vector org, go;
1964
1965         if(this.goalcounter==0)goal=this.goalcurrent;
1966         else if(this.goalcounter==1)goal=this.goalstack01;
1967         else if(this.goalcounter==2)goal=this.goalstack02;
1968         else if(this.goalcounter==3)goal=this.goalstack03;
1969         else if(this.goalcounter==4)goal=this.goalstack04;
1970         else if(this.goalcounter==5)goal=this.goalstack05;
1971         else if(this.goalcounter==6)goal=this.goalstack06;
1972         else if(this.goalcounter==7)goal=this.goalstack07;
1973         else if(this.goalcounter==8)goal=this.goalstack08;
1974         else if(this.goalcounter==9)goal=this.goalstack09;
1975         else if(this.goalcounter==10)goal=this.goalstack10;
1976         else if(this.goalcounter==11)goal=this.goalstack11;
1977         else if(this.goalcounter==12)goal=this.goalstack12;
1978         else if(this.goalcounter==13)goal=this.goalstack13;
1979         else if(this.goalcounter==14)goal=this.goalstack14;
1980         else if(this.goalcounter==15)goal=this.goalstack15;
1981         else if(this.goalcounter==16)goal=this.goalstack16;
1982         else if(this.goalcounter==17)goal=this.goalstack17;
1983         else if(this.goalcounter==18)goal=this.goalstack18;
1984         else if(this.goalcounter==19)goal=this.goalstack19;
1985         else if(this.goalcounter==20)goal=this.goalstack20;
1986         else if(this.goalcounter==21)goal=this.goalstack21;
1987         else if(this.goalcounter==22)goal=this.goalstack22;
1988         else if(this.goalcounter==23)goal=this.goalstack23;
1989         else if(this.goalcounter==24)goal=this.goalstack24;
1990         else if(this.goalcounter==25)goal=this.goalstack25;
1991         else if(this.goalcounter==26)goal=this.goalstack26;
1992         else if(this.goalcounter==27)goal=this.goalstack27;
1993         else if(this.goalcounter==28)goal=this.goalstack28;
1994         else if(this.goalcounter==29)goal=this.goalstack29;
1995         else if(this.goalcounter==30)goal=this.goalstack30;
1996         else if(this.goalcounter==31)goal=this.goalstack31;
1997         else goal=NULL;
1998
1999         if(goal==NULL)
2000         {
2001                 this.goalcounter = 0;
2002                 this.lastposition='0 0 0';
2003                 return;
2004         }
2005
2006         if(this.lastposition=='0 0 0')
2007                 org = this.origin;
2008         else
2009                 org = this.lastposition;
2010
2011
2012         go = ( goal.absmin + goal.absmax ) * 0.5;
2013         te_lightning2(NULL, org, go);
2014         this.lastposition = go;
2015
2016         this.goalcounter++;
2017 }