qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetryaxis_equation.x;
 145                 float q = havocbot_symmetryaxis_equation.y;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 183 // them back to it as well
 184 // (suitable for spawnfunc_waypoint editor)
 185 entity waypoint_spawn(vector m1, vector m2, float f)
 186 {
 187         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 188         {
 189                 vector em1 = m1 - '8 8 8';
 190                 vector em2 = m2 + '8 8 8';
 191                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 192                 {
 193                         return it;
 194                 });
 195         }
 196
 197         entity w = new(waypoint);
 198         IL_PUSH(g_waypoints, w);
 199         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 200         w.wpflags = f;
 201         w.solid = SOLID_TRIGGER;
 202         setorigin(w, (m1 + m2) * 0.5);
 203         setsize(w, m1 - w.origin, m2 - w.origin);
 204         if (w.size)
 205                 w.wpisbox = true;
 206
 207         if(!w.wpisbox)
 208         {
 209                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 210                 if(!move_out_of_solid(w))
 211                 {
 212                         if(!(f & WAYPOINTFLAG_GENERATED))
 213                         {
 214                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 215                                 delete(w);
 216                                 return NULL;
 217                         }
 218                         else
 219                         {
 220                                 if(autocvar_developer)
 221                                 {
 222                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 223                                         backtrace("Waypoint stuck");
 224                                 }
 225                         }
 226                 }
 227                 setsize(w, '0 0 0', '0 0 0');
 228         }
 229
 230         waypoint_clearlinks(w);
 231         //waypoint_schedulerelink(w);
 232
 233         waypoint_setupmodel(w);
 234
 235         return w;
 236 }
 237
 238 void waypoint_spawn_fromeditor(entity pl)
 239 {
 240         entity e;
 241         vector org = pl.origin;
 242         int ctf_flags = havocbot_symmetryaxis_equation.z;
 243         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 244                    || (autocvar_g_waypointeditor_symmetrical < 0));
 245         int order = ctf_flags;
 246         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 247         {
 248                 order = autocvar_g_waypointeditor_symmetrical_order;
 249                 ctf_flags = order;
 250         }
 251
 252         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 253         {
 254                 // snap waypoint to item's origin if close enough
 255                 IL_EACH(g_items, true,
 256                 {
 257                         vector item_org = (it.absmin + it.absmax) * 0.5;
 258                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 259                         if(vlen(item_org - org) < 30)
 260                         {
 261                                 org = item_org;
 262                                 break;
 263                         }
 264                 });
 265         }
 266
 267         LABEL(add_wp);
 268         e = waypoint_spawn(org, org, 0);
 269         if(!e)
 270         {
 271                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 272                 return;
 273         }
 274         waypoint_schedulerelink(e);
 275         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 276         if(sym)
 277         {
 278                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 279                 if (vdist(org - pl.origin, >, 32))
 280                 {
 281                         if(order > 2)
 282                                 order--;
 283                         else
 284                                 sym = false;
 285                         goto add_wp;
 286                 }
 287         }
 288 }
 289
 290 void waypoint_remove(entity wp)
 291 {
 292         // tell all waypoints linked to wp that they need to relink
 293         IL_EACH(g_waypoints, it != wp,
 294         {
 295                 if (waypoint_islinked(it, wp))
 296                         waypoint_removelink(it, wp);
 297         });
 298         delete(wp);
 299 }
 300
 301 void waypoint_remove_fromeditor(entity pl)
 302 {
 303         entity e = navigation_findnearestwaypoint(pl, false);
 304
 305         int ctf_flags = havocbot_symmetryaxis_equation.z;
 306         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 307                    || (autocvar_g_waypointeditor_symmetrical < 0));
 308         int order = ctf_flags;
 309         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 310         {
 311                 order = autocvar_g_waypointeditor_symmetrical_order;
 312                 ctf_flags = order;
 313         }
 314
 315         LABEL(remove_wp);
 316         if (!e) return;
 317         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 318
 319         if (e.wphardwired)
 320         {
 321                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 322                 return;
 323         }
 324
 325         entity wp_sym = NULL;
 326         if (sym)
 327         {
 328                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 329                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 330                         if(vdist(org - it.origin, <, 3))
 331                         {
 332                                 wp_sym = it;
 333                                 break;
 334                         }
 335                 });
 336         }
 337
 338         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 339         waypoint_remove(e);
 340
 341         if (sym && wp_sym)
 342         {
 343                 e = wp_sym;
 344                 if(order > 2)
 345                         order--;
 346                 else
 347                         sym = false;
 348                 goto remove_wp;
 349         }
 350 }
 351
 352 void waypoint_removelink(entity from, entity to)
 353 {
 354         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 355                 return;
 356
 357         bool found = false;
 358         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 359         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 360         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 361         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 362         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 363         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 364         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 365         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 366         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 367         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 368         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 369         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 370         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 371         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 372         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 373         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 374         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 375         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 376         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 377         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 378         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 379         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 380         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 381         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 382         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 383         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 384         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 385         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 386         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 387         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 388         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 389         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 390 }
 391
 392 bool waypoint_islinked(entity from, entity to)
 393 {
 394         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 395         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 396         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 397         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 398         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 399         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 400         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 401         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 402         return false;
 403 }
 404
 405 void waypoint_updatecost_foralllinks()
 406 {
 407         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 408         {
 409                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 410                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 411                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 412                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 413                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 414                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 415                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 416                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 417                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 418                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 419                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 420                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 421                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 422                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 423                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 424                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 425                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 426                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 427                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 428                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 429                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 430                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 431                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 432                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 433                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 434                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 435                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 436                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 437                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 438                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 439                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 440                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 441         });
 442 }
 443
 444 float waypoint_getlinearcost(float dist)
 445 {
 446         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 447                 return dist / (autocvar_sv_maxspeed * 1.25);
 448         return dist / autocvar_sv_maxspeed;
 449 }
 450 float waypoint_getlinearcost_underwater(float dist)
 451 {
 452         // NOTE: this value is hardcoded on the engine too, see SV_WaterMove
 453         return dist / (autocvar_sv_maxspeed * 0.7);
 454 }
 455
 456 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 457 {
 458         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 459         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 460
 461         if (submerged_from && submerged_to)
 462                 return waypoint_getlinearcost_underwater(vlen(to - from));
 463
 464         float c = waypoint_getlinearcost(vlen(to - from));
 465
 466         float height = from.z - to.z;
 467         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 468         {
 469                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 470                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 471                 if(height_cost > c)
 472                         c = height_cost;
 473         }
 474
 475         if (submerged_from || submerged_to)
 476                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 477         return c;
 478 }
 479
 480 float waypoint_getlinkcost(entity from, entity to)
 481 {
 482         vector v1 = from.origin;
 483         vector v2 = to.origin;
 484         if (from.wpisbox)
 485         {
 486                 vector m1 = from.absmin, m2 = from.absmax;
 487                 v1.x = bound(m1.x, v2.x, m2.x);
 488                 v1.y = bound(m1.y, v2.y, m2.y);
 489                 v1.z = bound(m1.z, v2.z, m2.z);
 490         }
 491         if (to.wpisbox)
 492         {
 493                 vector m1 = to.absmin, m2 = to.absmax;
 494                 v2.x = bound(m1.x, v1.x, m2.x);
 495                 v2.y = bound(m1.y, v1.y, m2.y);
 496                 v2.z = bound(m1.z, v1.z, m2.z);
 497         }
 498         return waypoint_gettravelcost(v1, v2, from, to);
 499 }
 500
 501 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 502 // if c == -1 automatically determine cost of the link
 503 void waypoint_addlink_customcost(entity from, entity to, float c)
 504 {
 505         if (from == to || waypoint_islinked(from, to))
 506                 return;
 507         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 508                 return;
 509
 510         if(c == -1)
 511                 c = waypoint_getlinkcost(from, to);
 512
 513         if (from.wp31mincost < c) return;
 514         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 515         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 516         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 517         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 518         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 519         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 520         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 521         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 522         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 523         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 524         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 525         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 526         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 527         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 528         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 529         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 530         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 531         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 532         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 533         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 534         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 535         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 536         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 537         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 538         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 539         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 540         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 541         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 542         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 543         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 544         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 545         from.wp00 = to;from.wp00mincost = c;return;
 546 }
 547
 548 void waypoint_addlink(entity from, entity to)
 549 {
 550         waypoint_addlink_customcost(from, to, -1);
 551 }
 552
 553 // relink this spawnfunc_waypoint
 554 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 555 // (SLOW!)
 556 void waypoint_think(entity this)
 557 {
 558         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 559         float sv2_height = 0, ev2_height = 0;
 560
 561         bot_calculate_stepheightvec();
 562
 563         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 564
 565         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 566         IL_EACH(g_waypoints, this != it,
 567         {
 568                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 569                 {
 570                         waypoint_addlink(this, it);
 571                         waypoint_addlink(it, this);
 572                 }
 573                 else
 574                 {
 575                         ++relink_total;
 576                         if(!checkpvs(this.origin, it))
 577                         {
 578                                 ++relink_pvsculled;
 579                                 continue;
 580                         }
 581
 582                         SET_TRACEWALK_DESTCOORDS_2(this, it.origin, sv, sv2, sv2_height);
 583                         SET_TRACEWALK_DESTCOORDS_2(it, this.origin, ev, ev2, ev2_height);
 584
 585                         dv = ev - sv;
 586                         dv.z = 0;
 587                         if(vdist(dv, >=, 1050)) // max search distance in XY
 588                         {
 589                                 ++relink_lengthculled;
 590                                 continue;
 591                         }
 592
 593                         navigation_testtracewalk = 0;
 594
 595                         //traceline(this.origin, it.origin, false, NULL);
 596                         //if (trace_fraction == 1)
 597                         if (this.wpisbox)
 598                                 relink_walkculled += 0.5;
 599                         else
 600                         {
 601                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 602                                         waypoint_addlink(this, it);
 603                                 else
 604                                         relink_walkculled += 0.5;
 605                         }
 606
 607                         if (it.wpisbox)
 608                                 relink_walkculled += 0.5;
 609                         else
 610                         {
 611                                 if (tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 612                                         waypoint_addlink(it, this);
 613                                 else
 614                                         relink_walkculled += 0.5;
 615                         }
 616                 }
 617         });
 618         navigation_testtracewalk = 0;
 619         this.wplinked = true;
 620 }
 621
 622 void waypoint_clearlinks(entity wp)
 623 {
 624         // clear links to other waypoints
 625         float f = 10000000;
 626         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 627         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 628         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 629         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 630
 631         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 632         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 633         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 634         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 635
 636         wp.wplinked = false;
 637 }
 638
 639 // tell a spawnfunc_waypoint to relink
 640 void waypoint_schedulerelink(entity wp)
 641 {
 642         if (wp == NULL)
 643                 return;
 644
 645         waypoint_setupmodel(wp);
 646         wp.wpisbox = vdist(wp.size, >, 0);
 647         wp.enemy = NULL;
 648         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 649                 wp.owner = NULL;
 650         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 651                 waypoint_clearlinks(wp);
 652         // schedule an actual relink on next frame
 653         setthink(wp, waypoint_think);
 654         wp.nextthink = time;
 655         wp.effects = EF_LOWPRECISION;
 656 }
 657
 658 // spawnfunc_waypoint map entity
 659 spawnfunc(waypoint)
 660 {
 661         IL_PUSH(g_waypoints, this);
 662
 663         setorigin(this, this.origin);
 664         // schedule a relink after other waypoints have had a chance to spawn
 665         waypoint_clearlinks(this);
 666         //waypoint_schedulerelink(this);
 667 }
 668
 669 // tell all waypoints to relink
 670 // actually this is useful only to update relink_* stats
 671 void waypoint_schedulerelinkall()
 672 {
 673         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 674         IL_EACH(g_waypoints, true,
 675         {
 676                 waypoint_schedulerelink(it);
 677         });
 678         waypoint_load_links_hardwired();
 679 }
 680
 681 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 682
 683 // Load waypoint links from file
 684 bool waypoint_load_links()
 685 {
 686         string s;
 687         float file, tokens, c = 0, found;
 688         entity wp_from = NULL, wp_to;
 689         vector wp_to_pos, wp_from_pos;
 690
 691         string gt_ext = GET_GAMETYPE_EXTENSION();
 692
 693         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 694         file = fopen(filename, FILE_READ);
 695
 696         if (gt_ext != "" && file < 0)
 697         {
 698                 // if race waypoint file doesn't exist load the default one
 699                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 700                 file = fopen(filename, FILE_READ);
 701         }
 702
 703         if (file < 0)
 704         {
 705                 LOG_TRACE("waypoint links load from ");
 706                 LOG_TRACE(filename);
 707                 LOG_TRACE(" failed");
 708                 return false;
 709         }
 710
 711         bool parse_comments = true;
 712         float ver = 0;
 713
 714         while ((s = fgets(file)))
 715         {
 716                 if(parse_comments)
 717                 {
 718                         if(substring(s, 0, 2) == "//")
 719                         {
 720                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 721                                         ver = stof(substring(s, 19, -1));
 722                                 continue;
 723                         }
 724                         else
 725                         {
 726                                 if(ver < WAYPOINT_VERSION)
 727                                 {
 728                                         LOG_TRACE("waypoint links for this map are outdated.");
 729                                         if (g_assault)
 730                                         {
 731                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 732                                         }
 733                                         else
 734                                         {
 735                                                 LOG_TRACE("automatically updating...");
 736                                                 return false;
 737                                         }
 738                                 }
 739                                 parse_comments = false;
 740                         }
 741                 }
 742
 743                 tokens = tokenizebyseparator(s, "*");
 744
 745                 if (tokens!=2)
 746                 {
 747                         // bad file format
 748                         fclose(file);
 749                         return false;
 750                 }
 751
 752                 wp_from_pos     = stov(argv(0));
 753                 wp_to_pos       = stov(argv(1));
 754
 755                 // Search "from" waypoint
 756                 if(!wp_from || wp_from.origin!=wp_from_pos)
 757                 {
 758                         wp_from = findradius(wp_from_pos, 1);
 759                         found = false;
 760                         while(wp_from)
 761                         {
 762                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 763                                 if(wp_from.classname == "waypoint")
 764                                 {
 765                                         found = true;
 766                                         break;
 767                                 }
 768                                 wp_from = wp_from.chain;
 769                         }
 770
 771                         if(!found)
 772                         {
 773                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 774                                 continue;
 775                         }
 776                 }
 777
 778                 // Search "to" waypoint
 779                 wp_to = findradius(wp_to_pos, 1);
 780                 found = false;
 781                 while(wp_to)
 782                 {
 783                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 784                         if(wp_to.classname == "waypoint")
 785                         {
 786                                 found = true;
 787                                 break;
 788                         }
 789                         wp_to = wp_to.chain;
 790                 }
 791
 792                 if(!found)
 793                 {
 794                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 795                         continue;
 796                 }
 797
 798                 ++c;
 799                 waypoint_addlink(wp_from, wp_to);
 800         }
 801
 802         fclose(file);
 803
 804         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 805
 806         botframe_cachedwaypointlinks = true;
 807         return true;
 808 }
 809
 810 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 811 {
 812         string s;
 813         float file, tokens, c = 0, found;
 814         entity wp_from = NULL, wp_to;
 815         vector wp_to_pos, wp_from_pos;
 816
 817         string gt_ext = GET_GAMETYPE_EXTENSION();
 818
 819         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 820         file = fopen(filename, FILE_READ);
 821
 822         if (gt_ext != "" && file < 0)
 823         {
 824                 // if race waypoint file doesn't exist load the default one
 825                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 826                 file = fopen(filename, FILE_READ);
 827         }
 828
 829         botframe_loadedforcedlinks = true;
 830
 831         if (file < 0)
 832         {
 833                 if(!removal_mode)
 834                         LOG_TRACE("waypoint links load from ", filename, " failed");
 835                 return;
 836         }
 837
 838         while ((s = fgets(file)))
 839         {
 840                 if(substring(s, 0, 2)=="//")
 841                         continue;
 842
 843                 if(substring(s, 0, 1)=="#")
 844                         continue;
 845
 846                 tokens = tokenizebyseparator(s, "*");
 847
 848                 if (tokens!=2)
 849                         continue;
 850
 851                 wp_from_pos     = stov(argv(0));
 852                 wp_to_pos       = stov(argv(1));
 853
 854                 // Search "from" waypoint
 855                 if(!wp_from || wp_from.origin!=wp_from_pos)
 856                 {
 857                         wp_from = findradius(wp_from_pos, 5);
 858                         found = false;
 859                         while(wp_from)
 860                         {
 861                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 862                                 if(wp_from.classname == "waypoint")
 863                                 {
 864                                         found = true;
 865                                         break;
 866                                 }
 867                                 wp_from = wp_from.chain;
 868                         }
 869
 870                         if(!found)
 871                         {
 872                                 if(!removal_mode)
 873                                         LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped");
 874                                 continue;
 875                         }
 876                 }
 877
 878                 // Search "to" waypoint
 879                 wp_to = findradius(wp_to_pos, 5);
 880                 found = false;
 881                 while(wp_to)
 882                 {
 883                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 884                         if(wp_to.classname == "waypoint")
 885                         {
 886                                 found = true;
 887                                 break;
 888                         }
 889                         wp_to = wp_to.chain;
 890                 }
 891
 892                 if(!found)
 893                 {
 894                         if(!removal_mode)
 895                                 LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped");
 896                         continue;
 897                 }
 898
 899                 ++c;
 900                 if(removal_mode)
 901                 {
 902                         waypoint_removelink(wp_from, wp_to);
 903                         continue;
 904                 }
 905
 906                 waypoint_addlink(wp_from, wp_to);
 907                 wp_from.wphardwired = true;
 908                 wp_to.wphardwired = true;
 909                 waypoint_setupmodel(wp_from);
 910                 waypoint_setupmodel(wp_to);
 911         }
 912
 913         fclose(file);
 914
 915         if(!removal_mode)
 916                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 917 }
 918
 919 entity waypoint_get_link(entity w, float i)
 920 {
 921         switch(i)
 922         {
 923                 case  0:return w.wp00;
 924                 case  1:return w.wp01;
 925                 case  2:return w.wp02;
 926                 case  3:return w.wp03;
 927                 case  4:return w.wp04;
 928                 case  5:return w.wp05;
 929                 case  6:return w.wp06;
 930                 case  7:return w.wp07;
 931                 case  8:return w.wp08;
 932                 case  9:return w.wp09;
 933                 case 10:return w.wp10;
 934                 case 11:return w.wp11;
 935                 case 12:return w.wp12;
 936                 case 13:return w.wp13;
 937                 case 14:return w.wp14;
 938                 case 15:return w.wp15;
 939                 case 16:return w.wp16;
 940                 case 17:return w.wp17;
 941                 case 18:return w.wp18;
 942                 case 19:return w.wp19;
 943                 case 20:return w.wp20;
 944                 case 21:return w.wp21;
 945                 case 22:return w.wp22;
 946                 case 23:return w.wp23;
 947                 case 24:return w.wp24;
 948                 case 25:return w.wp25;
 949                 case 26:return w.wp26;
 950                 case 27:return w.wp27;
 951                 case 28:return w.wp28;
 952                 case 29:return w.wp29;
 953                 case 30:return w.wp30;
 954                 case 31:return w.wp31;
 955                 default:return NULL;
 956         }
 957 }
 958
 959 // Save all waypoint links to a file
 960 void waypoint_save_links()
 961 {
 962         // temporarily remove hardwired links so they don't get saved among normal links
 963         waypoint_remove_links_hardwired();
 964
 965         string gt_ext = GET_GAMETYPE_EXTENSION();
 966
 967         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 968         int file = fopen(filename, FILE_WRITE);
 969         if (file < 0)
 970         {
 971                 LOG_INFOF("waypoint link save to %s failed", filename);
 972                 return;
 973         }
 974
 975         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
 976
 977         int c = 0;
 978         IL_EACH(g_waypoints, true,
 979         {
 980                 for(int j = 0; j < 32; ++j)
 981                 {
 982                         entity link = waypoint_get_link(it, j);
 983                         if(link)
 984                         {
 985                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 986                                 fputs(file, s);
 987                                 ++c;
 988                         }
 989                 }
 990         });
 991         fclose(file);
 992
 993         botframe_cachedwaypointlinks = true;
 994
 995         LOG_INFOF("saved %d waypoint links to %s", c, filename);
 996
 997         waypoint_load_links_hardwired();
 998 }
 999
1000 // save waypoints to gamedir/data/maps/mapname.waypoints
1001 void waypoint_saveall()
1002 {
1003         string gt_ext = GET_GAMETYPE_EXTENSION();
1004
1005         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1006         int file = fopen(filename, FILE_WRITE);
1007         if (file < 0)
1008         {
1009                 waypoint_save_links(); // save anyway?
1010                 botframe_loadedforcedlinks = false;
1011
1012                 LOG_INFOF("waypoint links: save to %s failed", filename);
1013                 return;
1014         }
1015
1016         // add 3 comments to not break compatibility with older Xonotic versions
1017         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1018         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1019         fputs(file, strcat("//", "\n"));
1020         fputs(file, strcat("//", "\n"));
1021
1022         int c = 0;
1023         IL_EACH(g_waypoints, true,
1024         {
1025                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1026                         continue;
1027
1028                 string s;
1029                 s = strcat(vtos(it.origin + it.mins), "\n");
1030                 s = strcat(s, vtos(it.origin + it.maxs));
1031                 s = strcat(s, "\n");
1032                 s = strcat(s, ftos(it.wpflags));
1033                 s = strcat(s, "\n");
1034                 fputs(file, s);
1035                 c++;
1036         });
1037         fclose(file);
1038         waypoint_save_links();
1039         botframe_loadedforcedlinks = false;
1040
1041         LOG_INFOF("saved %d waypoints to %s", c, filename);
1042 }
1043
1044 // load waypoints from file
1045 float waypoint_loadall()
1046 {
1047         string s;
1048         float file, cwp, cwb, fl;
1049         vector m1, m2;
1050         cwp = 0;
1051         cwb = 0;
1052
1053         string gt_ext = GET_GAMETYPE_EXTENSION();
1054
1055         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1056         file = fopen(filename, FILE_READ);
1057
1058         if (gt_ext != "" && file < 0)
1059         {
1060                 // if race waypoint file doesn't exist load the default one
1061                 filename = sprintf("maps/%s.waypoints", mapname);
1062                 file = fopen(filename, FILE_READ);
1063         }
1064
1065         if (file < 0)
1066         {
1067                 LOG_TRACE("waypoint load from ", filename, " failed");
1068                 return 0;
1069         }
1070
1071         bool parse_comments = true;
1072         float ver = 0;
1073
1074         while ((s = fgets(file)))
1075         {
1076                 if(parse_comments)
1077                 {
1078                         if(substring(s, 0, 2) == "//")
1079                         {
1080                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1081                                         ver = stof(substring(s, 19, -1));
1082                                 continue;
1083                         }
1084                         else
1085                         {
1086                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1087                                 {
1088                                         LOG_TRACE("waypoints for this map are outdated");
1089                                         LOG_TRACE("please update them in the editor");
1090                                 }
1091                                 parse_comments = false;
1092                         }
1093                 }
1094                 m1 = stov(s);
1095                 s = fgets(file);
1096                 if (!s)
1097                         break;
1098                 m2 = stov(s);
1099                 s = fgets(file);
1100                 if (!s)
1101                         break;
1102                 fl = stof(s);
1103                 waypoint_spawn(m1, m2, fl);
1104                 if (m1 == m2)
1105                         cwp = cwp + 1;
1106                 else
1107                         cwb = cwb + 1;
1108         }
1109         fclose(file);
1110         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1111
1112         return cwp + cwb;
1113 }
1114
1115 #define waypoint_fixorigin(position, tracetest_ent) \
1116         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1117
1118 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1119 {
1120         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1121         if(trace_startsolid)
1122                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1123         if(trace_startsolid)
1124                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1125         if(trace_fraction < 1)
1126                 position = trace_endpos;
1127         return position;
1128 }
1129
1130 void waypoint_spawnforitem_force(entity e, vector org)
1131 {
1132         // Fix the waypoint altitude if necessary
1133         org = waypoint_fixorigin(org, NULL);
1134
1135         // don't spawn an item spawnfunc_waypoint if it already exists
1136         IL_EACH(g_waypoints, true,
1137         {
1138                 if(it.wpisbox)
1139                 {
1140                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1141                         {
1142                                 e.nearestwaypoint = it;
1143                                 return;
1144                         }
1145                 }
1146                 else
1147                 {
1148                         if(vdist(it.origin - org, <, 16))
1149                         {
1150                                 e.nearestwaypoint = it;
1151                                 return;
1152                         }
1153                 }
1154         });
1155
1156         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1157 }
1158
1159 void waypoint_spawnforitem(entity e)
1160 {
1161         if(!bot_waypoints_for_items)
1162                 return;
1163
1164         waypoint_spawnforitem_force(e, e.origin);
1165 }
1166
1167 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1168 {
1169         entity w;
1170         entity dw;
1171         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1172         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1173         // one way link to the destination
1174         w.wp00 = dw;
1175         w.wp00mincost = timetaken; // this is just for jump pads
1176         // the teleporter's nearest spawnfunc_waypoint is this one
1177         // (teleporters are not goals, so this is probably useless)
1178         e.nearestwaypoint = w;
1179         e.nearestwaypointtimeout = -1;
1180 }
1181
1182 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1183 {
1184         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1185         // to the ground without leaving the warp plane
1186         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1187         // destination waypoint snapped to the ground (leaving warpzone), source
1188         // waypoint in the center of the warp plane
1189         if(down_dir.x != -1)
1190                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1191         if(down_dir.x == -1)
1192                 down_dir = '0 0 -1';
1193         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1194         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1195 }
1196
1197 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1198 {
1199         destination = waypoint_fixorigin(destination, tracetest_ent);
1200         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1201 }
1202
1203 entity waypoint_spawnpersonal(entity this, vector position)
1204 {
1205         entity w;
1206
1207         // drop the waypoint to a proper location:
1208         //   first move it up by a player height
1209         //   then move it down to hit the floor with player bbox size
1210         position = waypoint_fixorigin(position, this);
1211
1212         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1213         w.nearestwaypoint = NULL;
1214         w.nearestwaypointtimeout = 0;
1215         w.owner = this;
1216
1217         waypoint_schedulerelink(w);
1218
1219         return w;
1220 }
1221
1222 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1223 {
1224         if (!(wp1 && wp2))
1225                 return;
1226
1227         if (wp1.wphardwired && wp2.wphardwired)
1228                 te_beam(NULL, wp1.origin, wp2.origin);
1229         else if (display_type == 1)
1230                 te_lightning2(NULL, wp1.origin, wp2.origin);
1231 }
1232
1233 void waypoint_showlinks_to(entity wp, int display_type)
1234 {
1235         IL_EACH(g_waypoints, it != wp,
1236         {
1237                 if (waypoint_islinked(it, wp))
1238                         waypoint_showlink(it, wp, display_type);
1239         });
1240 }
1241
1242 void waypoint_showlinks_from(entity wp, int display_type)
1243 {
1244         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1245         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1246         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1247         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1248         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1249         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1250         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1251         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1252         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1253         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1254         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1255         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1256         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1257         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1258         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1259         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1260 }
1261
1262 void botframe_showwaypointlinks()
1263 {
1264         if (time < botframe_waypointeditorlightningtime)
1265                 return;
1266         botframe_waypointeditorlightningtime = time + 0.5;
1267         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1268         {
1269                 int display_type = 0;
1270                 entity head = navigation_findnearestwaypoint(it, false);
1271                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1272                         display_type = 1; // default
1273                 else if(head && (head.wphardwired))
1274                         display_type = 2; // only hardwired
1275
1276                 if (display_type)
1277                 {
1278                         //navigation_testtracewalk = true;
1279                         //print("currently selected WP is ", etos(head), "\n");
1280                         //navigation_testtracewalk = false;
1281                         if (head)
1282                         {
1283                                 te_lightning2(NULL, head.origin, it.origin);
1284                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1285                                         waypoint_showlinks_to(head, display_type);
1286                                 else
1287                                         waypoint_showlinks_from(head, display_type);
1288                         }
1289                 }
1290         });
1291 }
1292
1293 float botframe_autowaypoints_fixdown(vector v)
1294 {
1295         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1296         if(trace_fraction >= 1)
1297                 return 0;
1298         return 1;
1299 }
1300
1301 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1302 {
1303         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1304         {
1305                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1306                 return 0;
1307         });
1308
1309         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1310         return 1;
1311 }
1312
1313 // return value:
1314 //    1 = WP created
1315 //    0 = no action needed
1316 //   -1 = temp fail, try from world too
1317 //   -2 = permanent fail, do not retry
1318 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1319 {
1320         // make it possible to go from p to wp, if we can
1321         // if wp is NULL, nearest is chosen
1322
1323         entity w;
1324         vector porg;
1325         float t, tmin, tmax;
1326         vector o;
1327         vector save;
1328
1329         if(!botframe_autowaypoints_fixdown(p.origin))
1330                 return -2;
1331         porg = trace_endpos;
1332
1333         if(wp)
1334         {
1335                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1336
1337                 // if wp -> porg, then OK
1338                 float maxdist;
1339                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1340                 {
1341                         // we may find a better one
1342                         maxdist = vlen(wp.origin - porg);
1343                 }
1344                 else
1345                 {
1346                         // accept any "good"
1347                         maxdist = 2100;
1348                 }
1349
1350                 float bestdist = maxdist;
1351                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1352                 {
1353                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1354                         if(d < bestdist)
1355                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1356                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1357                         {
1358                                 bestdist = d;
1359                                 p.(fld) = it;
1360                         }
1361                 });
1362                 if(bestdist < maxdist)
1363                 {
1364                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1365                         return 0;
1366                 }
1367
1368                 if(bestdist < 2100)
1369                 {
1370                         // we know maxdist < 2100
1371                         // so wp -> porg is still valid
1372                         // all is good
1373                         p.(fld) = wp;
1374                         return 0;
1375                 }
1376
1377                 // otherwise, no existing WP can fix our issues
1378         }
1379         else
1380         {
1381                 save = p.origin;
1382                 setorigin(p, porg);
1383                 w = navigation_findnearestwaypoint(p, walkfromwp);
1384                 setorigin(p, save);
1385                 if(w)
1386                 {
1387                         p.(fld) = w;
1388                         return 0;
1389                 }
1390         }
1391
1392         tmin = 0;
1393         tmax = 1;
1394         for (;;)
1395         {
1396                 if(tmax - tmin < 0.001)
1397                 {
1398                         // did not get a good candidate
1399                         return -1;
1400                 }
1401
1402                 t = (tmin + tmax) * 0.5;
1403                 o = antilag_takebackorigin(p, CS(p), time - t);
1404                 if(!botframe_autowaypoints_fixdown(o))
1405                         return -2;
1406                 o = trace_endpos;
1407
1408                 if(wp)
1409                 {
1410                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1411                         {
1412                                 // we cannot walk from wp.origin to o
1413                                 // get closer to tmax
1414                                 tmin = t;
1415                                 continue;
1416                         }
1417                 }
1418                 else
1419                 {
1420                         save = p.origin;
1421                         setorigin(p, o);
1422                         w = navigation_findnearestwaypoint(p, walkfromwp);
1423                         setorigin(p, save);
1424                         if(!w)
1425                         {
1426                                 // we cannot walk from any WP to o
1427                                 // get closer to tmax
1428                                 tmin = t;
1429                                 continue;
1430                         }
1431                 }
1432
1433                 // if we get here, o is valid regarding waypoints
1434                 // check if o is connected right to the player
1435                 // we break if it succeeds, as that means o is a good waypoint location
1436                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1437                         break;
1438
1439                 // o is no good, we need to get closer to the player
1440                 tmax = t;
1441         }
1442
1443         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1444         botframe_autowaypoints_createwp(o, p, fld, 0);
1445         return 1;
1446 }
1447
1448 // automatically create missing waypoints
1449 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1450 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1451 {
1452         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1453         if(r != -1)
1454                 return;
1455         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1456         if(r != -1)
1457                 return;
1458
1459         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1460         if(!botframe_autowaypoints_fixdown(p.origin))
1461                 return; // shouldn't happen, caught above
1462         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1463 }
1464
1465 void botframe_deleteuselesswaypoints()
1466 {
1467         IL_EACH(g_items, it.bot_pickup,
1468         {
1469                 // NOTE: this protects waypoints if they're the ONLY nearest
1470                 // waypoint. That's the intention.
1471                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1472                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1473         });
1474         IL_EACH(g_waypoints, true,
1475         {
1476                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1477                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1478                 // WP is useful if:
1479                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1480                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1481                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1482                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1483                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1484                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1485                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1486                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1487                 // b) WP is closest WP for an item/spawnpoint/other entity
1488                 //    This has been done above by protecting these WPs.
1489         });
1490         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1491         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1492         {
1493                 for (int m = 0; m < 32; ++m)
1494                 {
1495                         entity w = waypoint_get_link(it, m);
1496                         if (!w)
1497                                 break;
1498                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1499                                 continue;
1500                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1501                                 continue;
1502                         for (int j = 0; j < 32; ++j)
1503                         {
1504                                 entity w2 = waypoint_get_link(w, j);
1505                                 if (!w2)
1506                                         break;
1507                                 if (it == w2)
1508                                         continue;
1509                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1510                                         continue;
1511                                 // If we got here, it != w2 exist with it -> w
1512                                 // and w -> w2. That means the waypoint is not
1513                                 // a dead end.
1514                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1515                                 for (int k = 0; k < 32; ++k)
1516                                 {
1517                                         if (waypoint_get_link(it, k) == w2)
1518                                                 continue;
1519                                         // IF WE GET HERE, w is proven useful
1520                                         // to get from it to w2!
1521                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1522                                         goto next;
1523                                 }
1524                         }
1525 LABEL(next)
1526                 }
1527         });
1528         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1529         //     they are needed to complete routes while autowaypointing.
1530
1531         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1532         {
1533                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1534                 te_explosion(it.origin);
1535                 waypoint_remove(it);
1536                 break;
1537         });
1538
1539         IL_EACH(g_waypoints, true,
1540         {
1541                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1542         });
1543 }
1544
1545 void botframe_autowaypoints()
1546 {
1547         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1548                 // going back is broken, so only fix waypoints to walk TO the player
1549                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1550                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1551                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1552         });
1553
1554         if (autocvar_g_waypointeditor_auto >= 2) {
1555                 botframe_deleteuselesswaypoints();
1556         }
1557 }
1558