qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14
  15 #include <lib/warpzone/common.qh>
  16 #include <lib/warpzone/util_server.qh>
  17
  18 .entity spawnpointmodel;
  19 void waypoint_unreachable(entity pl)
  20 {
  21         IL_EACH(g_waypoints, true,
  22         {
  23                 it.colormod = '0.5 0.5 0.5';
  24                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  25         });
  26         entity e2 = navigation_findnearestwaypoint(pl, false);
  27         navigation_markroutes(pl, e2);
  28
  29         int j = 0;
  30         int m = 0;
  31         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  32         {
  33                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  34                 it.colormod_z = 8;
  35                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  36                 j++;
  37                 m++;
  38         });
  39         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  40         navigation_markroutes_inverted(e2);
  41
  42         j = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_x = 8;
  47                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  48                         m++;
  49                 it.effects |= EF_NODEPTHTEST | EF_RED;
  50                 j++;
  51         });
  52         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  53         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  54
  55         j = 0;
  56         IL_EACH(g_spawnpoints, true,
  57         {
  58                 if (navigation_findnearestwaypoint(it, false))
  59                 {
  60                         if(it.spawnpointmodel)
  61                         {
  62                                 delete(it.spawnpointmodel);
  63                                 it.spawnpointmodel = NULL;
  64                         }
  65                 }
  66                 else
  67                 {
  68                         if(!it.spawnpointmodel)
  69                         {
  70                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  71                                 entity e = new(spawnpointmodel);
  72                                 vector org = trace_endpos + eZ;
  73                                 setorigin(e, org);
  74                                 e.solid = SOLID_TRIGGER;
  75                                 it.spawnpointmodel = e;
  76                         }
  77                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  78                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  79                         _setmodel(it.spawnpointmodel, pl.model);
  80                         it.spawnpointmodel.frame = pl.frame;
  81                         it.spawnpointmodel.skin = pl.skin;
  82                         it.spawnpointmodel.colormap = pl.colormap;
  83                         it.spawnpointmodel.colormod = pl.colormod;
  84                         it.spawnpointmodel.glowmod = pl.glowmod;
  85                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  86                         j++;
  87                 }
  88         });
  89         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  90
  91         j = 0;
  92         IL_EACH(g_items, true,
  93         {
  94                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  95                 it.colormod = '0.5 0.5 0.5';
  96         });
  97         IL_EACH(g_items, true,
  98         {
  99                 if (navigation_findnearestwaypoint(it, false))
 100                         continue;
 101                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 102                 it.effects |= EF_NODEPTHTEST | EF_RED;
 103                 it.colormod_x = 8;
 104                 j++;
 105         });
 106         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 107
 108         j = 0;
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, true))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 115                 it.colormod_z = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 119 }
 120
 121 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 122 {
 123         vector new_org = org;
 124         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 125         {
 126                 vector map_center = havocbot_middlepoint;
 127                 if (autocvar_g_waypointeditor_symmetrical == -1)
 128                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 129
 130                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 131         }
 132         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 133         {
 134                 float m = havocbot_symmetryaxis_equation.x;
 135                 float q = havocbot_symmetryaxis_equation.y;
 136                 if (autocvar_g_waypointeditor_symmetrical == -2)
 137                 {
 138                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 139                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 140                 }
 141
 142                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 143                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 144         }
 145         new_org.z = org.z;
 146         return new_org;
 147 }
 148
 149 void waypoint_setupmodel(entity wp)
 150 {
 151         if (autocvar_g_waypointeditor)
 152         {
 153                 // TODO: add some sort of visible box in edit mode for box waypoints
 154                 vector m1 = wp.mins;
 155                 vector m2 = wp.maxs;
 156                 setmodel(wp, MDL_WAYPOINT);
 157                 setsize(wp, m1, m2);
 158                 wp.effects = EF_LOWPRECISION;
 159                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 160                         wp.colormod = '1 0 0';
 161                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 162                         wp.colormod = '1 1 0';
 163                 else
 164                         wp.colormod = '1 1 1';
 165         }
 166         else
 167                 wp.model = "";
 168 }
 169
 170 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 171 // them back to it as well
 172 // (suitable for spawnfunc_waypoint editor)
 173 entity waypoint_spawn(vector m1, vector m2, float f)
 174 {
 175         if(!(f & WAYPOINTFLAG_PERSONAL))
 176         {
 177                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 178                 {
 179                         return it;
 180                 });
 181         }
 182
 183         entity w = new(waypoint);
 184         IL_PUSH(g_waypoints, w);
 185         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 186         w.wpflags = f;
 187         w.solid = SOLID_TRIGGER;
 188         setorigin(w, (m1 + m2) * 0.5);
 189         setsize(w, m1 - w.origin, m2 - w.origin);
 190         if (w.size)
 191                 w.wpisbox = true;
 192
 193         if(!w.wpisbox)
 194         {
 195                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 196                 if(!move_out_of_solid(w))
 197                 {
 198                         if(!(f & WAYPOINTFLAG_GENERATED))
 199                         {
 200                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 201                                 delete(w);
 202                                 return NULL;
 203                         }
 204                         else
 205                         {
 206                                 if(autocvar_developer)
 207                                 {
 208                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 209                                         backtrace("Waypoint stuck");
 210                                 }
 211                         }
 212                 }
 213                 setsize(w, '0 0 0', '0 0 0');
 214         }
 215
 216         waypoint_clearlinks(w);
 217         //waypoint_schedulerelink(w);
 218
 219         waypoint_setupmodel(w);
 220
 221         return w;
 222 }
 223
 224 void waypoint_spawn_fromeditor(entity pl)
 225 {
 226         entity e;
 227         vector org = pl.origin;
 228         int ctf_flags = havocbot_symmetryaxis_equation.z;
 229         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 230                    || (autocvar_g_waypointeditor_symmetrical < 0));
 231         int order = ctf_flags;
 232         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 233         {
 234                 order = autocvar_g_waypointeditor_symmetrical_order;
 235                 ctf_flags = order;
 236         }
 237
 238         LABEL(add_wp);
 239         e = waypoint_spawn(org, org, 0);
 240         waypoint_schedulerelink(e);
 241         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 242         if(sym)
 243         {
 244                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 245                 if (vdist(org - pl.origin, >, 32))
 246                 {
 247                         if(order > 2)
 248                                 order--;
 249                         else
 250                                 sym = false;
 251                         goto add_wp;
 252                 }
 253         }
 254 }
 255
 256 void waypoint_remove(entity wp)
 257 {
 258         // tell all waypoints linked to wp that they need to relink
 259         IL_EACH(g_waypoints, it != wp,
 260         {
 261                 if (waypoint_islinked(it, wp))
 262                         waypoint_removelink(it, wp);
 263         });
 264         delete(wp);
 265 }
 266
 267 void waypoint_remove_fromeditor(entity pl)
 268 {
 269         entity e = navigation_findnearestwaypoint(pl, false);
 270
 271         int ctf_flags = havocbot_symmetryaxis_equation.z;
 272         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 273                    || (autocvar_g_waypointeditor_symmetrical < 0));
 274         int order = ctf_flags;
 275         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 276         {
 277                 order = autocvar_g_waypointeditor_symmetrical_order;
 278                 ctf_flags = order;
 279         }
 280
 281         LABEL(remove_wp);
 282         if (!e) return;
 283         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 284
 285         if (e.wphardwired)
 286         {
 287                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 288                 return;
 289         }
 290
 291         entity wp_sym = NULL;
 292         if (sym)
 293         {
 294                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 295                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 296                         if(vdist(org - it.origin, <, 3))
 297                         {
 298                                 wp_sym = it;
 299                                 break;
 300                         }
 301                 });
 302         }
 303
 304         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 305         waypoint_remove(e);
 306
 307         if (sym && wp_sym)
 308         {
 309                 e = wp_sym;
 310                 if(order > 2)
 311                         order--;
 312                 else
 313                         sym = false;
 314                 goto remove_wp;
 315         }
 316 }
 317
 318 void waypoint_removelink(entity from, entity to)
 319 {
 320         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 321                 return;
 322
 323         bool found = false;
 324         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 325         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 326         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 327         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 328         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 329         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 330         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 331         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 332         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 333         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 334         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 335         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 336         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 337         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 338         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 339         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 340         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 341         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 342         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 343         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 344         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 345         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 346         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 347         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 348         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 349         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 350         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 351         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 352         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 353         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 354         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 355         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 356 }
 357
 358 bool waypoint_islinked(entity from, entity to)
 359 {
 360         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 361         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 362         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 363         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 364         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 365         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 366         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 367         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 368         return false;
 369 }
 370
 371 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 372 void waypoint_addlink(entity from, entity to)
 373 {
 374         float c;
 375
 376         if (from == to)
 377                 return;
 378         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 379                 return;
 380
 381         if (waypoint_islinked(from, to))
 382                 return;
 383
 384         vector v1 = from.origin;
 385         vector v2 = to.origin;
 386         if (to.wpisbox || from.wpisbox)
 387         {
 388                 // if either is a box we have to find the nearest points on them to
 389                 // calculate the distance properly
 390                 vector m1, m2;
 391                 m1 = to.absmin;
 392                 m2 = to.absmax;
 393                 v1_x = bound(m1_x, v1_x, m2_x);
 394                 v1_y = bound(m1_y, v1_y, m2_y);
 395                 v1_z = bound(m1_z, v1_z, m2_z);
 396                 m1 = from.absmin;
 397                 m2 = from.absmax;
 398                 v2_x = bound(m1_x, v2_x, m2_x);
 399                 v2_y = bound(m1_y, v2_y, m2_y);
 400                 v2_z = bound(m1_z, v2_z, m2_z);
 401         }
 402         c = vlen(v2 - v1) / autocvar_sv_maxspeed;
 403
 404         float height = v1.z - v2.z;
 405         if(height > 0 && autocvar_sv_gravity > 0)
 406         {
 407                 float height_cost = sqrt(height / autocvar_sv_gravity);
 408                 float xydist = vlen((v2 - eZ * v2.z) - (v1 - eZ * v1.z));
 409                 float xydist_cost = xydist / autocvar_sv_maxspeed;
 410                 if(max(height_cost, xydist_cost) < c)
 411                         c = max(height_cost, xydist_cost);
 412         }
 413
 414         if (from.wp31mincost < c) return;
 415         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 416         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 417         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 418         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 419         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 420         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 421         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 422         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 423         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 424         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 425         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 426         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 427         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 428         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 429         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 430         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 431         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 432         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 433         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 434         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 435         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 436         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 437         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 438         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 439         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 440         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 441         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 442         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 443         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 444         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 445         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 446         from.wp00 = to;from.wp00mincost = c;return;
 447 }
 448
 449 // relink this spawnfunc_waypoint
 450 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 451 // (SLOW!)
 452 void waypoint_think(entity this)
 453 {
 454         vector sv, sm1, sm2, ev, em1, em2, dv;
 455
 456         bot_calculate_stepheightvec();
 457
 458         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 459
 460         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 461         sm1 = this.origin + this.mins;
 462         sm2 = this.origin + this.maxs;
 463         IL_EACH(g_waypoints, this != it,
 464         {
 465                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 466                 {
 467                         waypoint_addlink(this, it);
 468                         waypoint_addlink(it, this);
 469                 }
 470                 else
 471                 {
 472                         ++relink_total;
 473                         if(!checkpvs(this.origin, it))
 474                         {
 475                                 ++relink_pvsculled;
 476                                 continue;
 477                         }
 478                         sv = it.origin;
 479                         sv.x = bound(sm1_x, sv.x, sm2_x);
 480                         sv.y = bound(sm1_y, sv.y, sm2_y);
 481                         sv.z = bound(sm1_z, sv.z, sm2_z);
 482                         ev = this.origin;
 483                         em1 = it.origin + it.mins;
 484                         em2 = it.origin + it.maxs;
 485                         ev.x = bound(em1_x, ev.x, em2_x);
 486                         ev.y = bound(em1_y, ev.y, em2_y);
 487                         ev.z = bound(em1_z, ev.z, em2_z);
 488                         dv = ev - sv;
 489                         dv.z = 0;
 490                         if(vdist(dv, >=, 1050)) // max search distance in XY
 491                         {
 492                                 ++relink_lengthculled;
 493                                 continue;
 494                         }
 495                         navigation_testtracewalk = 0;
 496                         if (!this.wpisbox)
 497                         {
 498                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 499                                 if (!trace_startsolid)
 500                                 {
 501                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 502                                         sv = trace_endpos + '0 0 1';
 503                                 }
 504                         }
 505                         if (!it.wpisbox)
 506                         {
 507                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 508                                 if (!trace_startsolid)
 509                                 {
 510                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 511                                         ev = trace_endpos + '0 0 1';
 512                                 }
 513                         }
 514                         //traceline(this.origin, it.origin, false, NULL);
 515                         //if (trace_fraction == 1)
 516                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 517                                 waypoint_addlink(this, it);
 518                         else
 519                                 relink_walkculled += 0.5;
 520                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 521                                 waypoint_addlink(it, this);
 522                         else
 523                                 relink_walkculled += 0.5;
 524                 }
 525         });
 526         navigation_testtracewalk = 0;
 527         this.wplinked = true;
 528 }
 529
 530 void waypoint_clearlinks(entity wp)
 531 {
 532         // clear links to other waypoints
 533         float f = 10000000;
 534         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 535         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 536         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 537         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 538
 539         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 540         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 541         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 542         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 543
 544         wp.wplinked = false;
 545 }
 546
 547 // tell a spawnfunc_waypoint to relink
 548 void waypoint_schedulerelink(entity wp)
 549 {
 550         if (wp == NULL)
 551                 return;
 552
 553         waypoint_setupmodel(wp);
 554         wp.wpisbox = vdist(wp.size, >, 0);
 555         wp.enemy = NULL;
 556         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 557                 wp.owner = NULL;
 558         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 559                 waypoint_clearlinks(wp);
 560         // schedule an actual relink on next frame
 561         setthink(wp, waypoint_think);
 562         wp.nextthink = time;
 563         wp.effects = EF_LOWPRECISION;
 564 }
 565
 566 // spawnfunc_waypoint map entity
 567 spawnfunc(waypoint)
 568 {
 569         IL_PUSH(g_waypoints, this);
 570
 571         setorigin(this, this.origin);
 572         // schedule a relink after other waypoints have had a chance to spawn
 573         waypoint_clearlinks(this);
 574         //waypoint_schedulerelink(this);
 575 }
 576
 577 // tell all waypoints to relink
 578 // actually this is useful only to update relink_* stats
 579 void waypoint_schedulerelinkall()
 580 {
 581         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 582         IL_EACH(g_waypoints, true,
 583         {
 584                 waypoint_schedulerelink(it);
 585         });
 586         waypoint_load_links_hardwired();
 587 }
 588
 589 // Load waypoint links from file
 590 bool waypoint_load_links()
 591 {
 592         string filename, s;
 593         float file, tokens, c = 0, found;
 594         entity wp_from = NULL, wp_to;
 595         vector wp_to_pos, wp_from_pos;
 596         filename = strcat("maps/", mapname);
 597         filename = strcat(filename, ".waypoints.cache");
 598         file = fopen(filename, FILE_READ);
 599
 600         if (file < 0)
 601         {
 602                 LOG_TRACE("waypoint links load from ");
 603                 LOG_TRACE(filename);
 604                 LOG_TRACE(" failed");
 605                 return false;
 606         }
 607
 608         while ((s = fgets(file)))
 609         {
 610                 tokens = tokenizebyseparator(s, "*");
 611
 612                 if (tokens!=2)
 613                 {
 614                         // bad file format
 615                         fclose(file);
 616                         return false;
 617                 }
 618
 619                 wp_from_pos     = stov(argv(0));
 620                 wp_to_pos       = stov(argv(1));
 621
 622                 // Search "from" waypoint
 623                 if(!wp_from || wp_from.origin!=wp_from_pos)
 624                 {
 625                         wp_from = findradius(wp_from_pos, 1);
 626                         found = false;
 627                         while(wp_from)
 628                         {
 629                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 630                                 if(wp_from.classname == "waypoint")
 631                                 {
 632                                         found = true;
 633                                         break;
 634                                 }
 635                                 wp_from = wp_from.chain;
 636                         }
 637
 638                         if(!found)
 639                         {
 640                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 641                                 continue;
 642                         }
 643
 644                 }
 645
 646                 // Search "to" waypoint
 647                 wp_to = findradius(wp_to_pos, 1);
 648                 found = false;
 649                 while(wp_to)
 650                 {
 651                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 652                         if(wp_to.classname == "waypoint")
 653                         {
 654                                 found = true;
 655                                 break;
 656                         }
 657                         wp_to = wp_to.chain;
 658                 }
 659
 660                 if(!found)
 661                 {
 662                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 663                         continue;
 664                 }
 665
 666                 ++c;
 667                 waypoint_addlink(wp_from, wp_to);
 668         }
 669
 670         fclose(file);
 671
 672         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 673
 674         botframe_cachedwaypointlinks = true;
 675         return true;
 676 }
 677
 678 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 679 {
 680         string filename, s;
 681         float file, tokens, c = 0, found;
 682         entity wp_from = NULL, wp_to;
 683         vector wp_to_pos, wp_from_pos;
 684         filename = strcat("maps/", mapname);
 685         filename = strcat(filename, ".waypoints.hardwired");
 686         file = fopen(filename, FILE_READ);
 687
 688         botframe_loadedforcedlinks = true;
 689
 690         if (file < 0)
 691         {
 692                 if(!removal_mode)
 693                         LOG_TRACE("waypoint links load from ", filename, " failed");
 694                 return;
 695         }
 696
 697         while ((s = fgets(file)))
 698         {
 699                 if(substring(s, 0, 2)=="//")
 700                         continue;
 701
 702                 if(substring(s, 0, 1)=="#")
 703                         continue;
 704
 705                 tokens = tokenizebyseparator(s, "*");
 706
 707                 if (tokens!=2)
 708                         continue;
 709
 710                 wp_from_pos     = stov(argv(0));
 711                 wp_to_pos       = stov(argv(1));
 712
 713                 // Search "from" waypoint
 714                 if(!wp_from || wp_from.origin!=wp_from_pos)
 715                 {
 716                         wp_from = findradius(wp_from_pos, 5);
 717                         found = false;
 718                         while(wp_from)
 719                         {
 720                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 721                                 if(wp_from.classname == "waypoint")
 722                                 {
 723                                         found = true;
 724                                         break;
 725                                 }
 726                                 wp_from = wp_from.chain;
 727                         }
 728
 729                         if(!found)
 730                         {
 731                                 if(!removal_mode)
 732                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 733                                 continue;
 734                         }
 735                 }
 736
 737                 // Search "to" waypoint
 738                 wp_to = findradius(wp_to_pos, 5);
 739                 found = false;
 740                 while(wp_to)
 741                 {
 742                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 743                         if(wp_to.classname == "waypoint")
 744                         {
 745                                 found = true;
 746                                 break;
 747                         }
 748                         wp_to = wp_to.chain;
 749                 }
 750
 751                 if(!found)
 752                 {
 753                         if(!removal_mode)
 754                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 755                         continue;
 756                 }
 757
 758                 ++c;
 759                 if(removal_mode)
 760                 {
 761                         waypoint_removelink(wp_from, wp_to);
 762                         continue;
 763                 }
 764
 765                 waypoint_addlink(wp_from, wp_to);
 766                 wp_from.wphardwired = true;
 767                 wp_to.wphardwired = true;
 768         }
 769
 770         fclose(file);
 771
 772         if(!removal_mode)
 773                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 774 }
 775
 776 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 777 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 778
 779 entity waypoint_get_link(entity w, float i)
 780 {
 781         switch(i)
 782         {
 783                 case  0:return w.wp00;
 784                 case  1:return w.wp01;
 785                 case  2:return w.wp02;
 786                 case  3:return w.wp03;
 787                 case  4:return w.wp04;
 788                 case  5:return w.wp05;
 789                 case  6:return w.wp06;
 790                 case  7:return w.wp07;
 791                 case  8:return w.wp08;
 792                 case  9:return w.wp09;
 793                 case 10:return w.wp10;
 794                 case 11:return w.wp11;
 795                 case 12:return w.wp12;
 796                 case 13:return w.wp13;
 797                 case 14:return w.wp14;
 798                 case 15:return w.wp15;
 799                 case 16:return w.wp16;
 800                 case 17:return w.wp17;
 801                 case 18:return w.wp18;
 802                 case 19:return w.wp19;
 803                 case 20:return w.wp20;
 804                 case 21:return w.wp21;
 805                 case 22:return w.wp22;
 806                 case 23:return w.wp23;
 807                 case 24:return w.wp24;
 808                 case 25:return w.wp25;
 809                 case 26:return w.wp26;
 810                 case 27:return w.wp27;
 811                 case 28:return w.wp28;
 812                 case 29:return w.wp29;
 813                 case 30:return w.wp30;
 814                 case 31:return w.wp31;
 815                 default:return NULL;
 816         }
 817 }
 818
 819 // Save all waypoint links to a file
 820 void waypoint_save_links()
 821 {
 822         // temporarily remove hardwired links so they don't get saved among normal links
 823         waypoint_remove_links_hardwired();
 824
 825         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 826         int file = fopen(filename, FILE_WRITE);
 827         if (file < 0)
 828         {
 829                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 830                 return;
 831         }
 832
 833         int c = 0;
 834         IL_EACH(g_waypoints, true,
 835         {
 836                 for(int j = 0; j < 32; ++j)
 837                 {
 838                         entity link = waypoint_get_link(it, j);
 839                         if(link)
 840                         {
 841                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 842                                 fputs(file, s);
 843                                 ++c;
 844                         }
 845                 }
 846         });
 847         fclose(file);
 848         botframe_cachedwaypointlinks = true;
 849
 850         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 851
 852         waypoint_load_links_hardwired();
 853 }
 854
 855 // save waypoints to gamedir/data/maps/mapname.waypoints
 856 void waypoint_saveall()
 857 {
 858         string filename = sprintf("maps/%s.waypoints", mapname);
 859         int file = fopen(filename, FILE_WRITE);
 860         if (file < 0)
 861         {
 862                 waypoint_save_links(); // save anyway?
 863                 botframe_loadedforcedlinks = false;
 864
 865                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 866                 return;
 867         }
 868
 869         int c = 0;
 870         IL_EACH(g_waypoints, true,
 871         {
 872                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 873                         continue;
 874
 875                 string s;
 876                 s = strcat(vtos(it.origin + it.mins), "\n");
 877                 s = strcat(s, vtos(it.origin + it.maxs));
 878                 s = strcat(s, "\n");
 879                 s = strcat(s, ftos(it.wpflags));
 880                 s = strcat(s, "\n");
 881                 fputs(file, s);
 882                 c++;
 883         });
 884         fclose(file);
 885         waypoint_save_links();
 886         botframe_loadedforcedlinks = false;
 887
 888         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 889 }
 890
 891 // load waypoints from file
 892 float waypoint_loadall()
 893 {
 894         string filename, s;
 895         float file, cwp, cwb, fl;
 896         vector m1, m2;
 897         cwp = 0;
 898         cwb = 0;
 899         filename = strcat("maps/", mapname);
 900         filename = strcat(filename, ".waypoints");
 901         file = fopen(filename, FILE_READ);
 902         if (file >= 0)
 903         {
 904                 while ((s = fgets(file)))
 905                 {
 906                         m1 = stov(s);
 907                         s = fgets(file);
 908                         if (!s)
 909                                 break;
 910                         m2 = stov(s);
 911                         s = fgets(file);
 912                         if (!s)
 913                                 break;
 914                         fl = stof(s);
 915                         waypoint_spawn(m1, m2, fl);
 916                         if (m1 == m2)
 917                                 cwp = cwp + 1;
 918                         else
 919                                 cwb = cwb + 1;
 920                 }
 921                 fclose(file);
 922                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 923         }
 924         else
 925         {
 926                 LOG_TRACE("waypoint load from ", filename, " failed");
 927         }
 928         return cwp + cwb;
 929 }
 930
 931 vector waypoint_fixorigin(vector position)
 932 {
 933         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 934         if(trace_fraction < 1)
 935                 position = trace_endpos;
 936         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 937         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 938         return position;
 939 }
 940
 941 void waypoint_spawnforitem_force(entity e, vector org)
 942 {
 943         // Fix the waypoint altitude if necessary
 944         org = waypoint_fixorigin(org);
 945
 946         // don't spawn an item spawnfunc_waypoint if it already exists
 947         IL_EACH(g_waypoints, true,
 948         {
 949                 if(it.wpisbox)
 950                 {
 951                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 952                         {
 953                                 e.nearestwaypoint = it;
 954                                 return;
 955                         }
 956                 }
 957                 else
 958                 {
 959                         if(vdist(it.origin - org, <, 16))
 960                         {
 961                                 e.nearestwaypoint = it;
 962                                 return;
 963                         }
 964                 }
 965         });
 966
 967         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 968 }
 969
 970 void waypoint_spawnforitem(entity e)
 971 {
 972         if(!bot_waypoints_for_items)
 973                 return;
 974
 975         waypoint_spawnforitem_force(e, e.origin);
 976 }
 977
 978 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 979 {
 980         entity w;
 981         entity dw;
 982         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
 983         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 984         // one way link to the destination
 985         w.wp00 = dw;
 986         w.wp00mincost = timetaken; // this is just for jump pads
 987         // the teleporter's nearest spawnfunc_waypoint is this one
 988         // (teleporters are not goals, so this is probably useless)
 989         e.nearestwaypoint = w;
 990         e.nearestwaypointtimeout = -1;
 991 }
 992
 993 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 994 {
 995         org = waypoint_fixorigin(org);
 996         destination = waypoint_fixorigin(destination);
 997         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
 998 }
 999
1000 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1001 {
1002         destination = waypoint_fixorigin(destination);
1003         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1004 }
1005
1006 entity waypoint_spawnpersonal(entity this, vector position)
1007 {
1008         entity w;
1009
1010         // drop the waypoint to a proper location:
1011         //   first move it up by a player height
1012         //   then move it down to hit the floor with player bbox size
1013         position = waypoint_fixorigin(position);
1014
1015         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1016         w.nearestwaypoint = NULL;
1017         w.nearestwaypointtimeout = 0;
1018         w.owner = this;
1019
1020         waypoint_schedulerelink(w);
1021
1022         return w;
1023 }
1024
1025 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1026 {
1027         if (!(wp1 && wp2))
1028                 return;
1029
1030         if (wp1.wphardwired && wp2.wphardwired)
1031                 te_beam(NULL, wp1.origin, wp2.origin);
1032         else if (display_type == 1)
1033                 te_lightning2(NULL, wp1.origin, wp2.origin);
1034 }
1035
1036 void botframe_showwaypointlinks()
1037 {
1038         if (time < botframe_waypointeditorlightningtime)
1039                 return;
1040         botframe_waypointeditorlightningtime = time + 0.5;
1041         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1042         {
1043                 int display_type = 0;
1044                 entity head = navigation_findnearestwaypoint(it, false);
1045                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1046                         display_type = 1; // default
1047                 else if(head && (head.wphardwired))
1048                         display_type = 2; // only hardwired
1049
1050                 if (display_type)
1051                 {
1052                         //navigation_testtracewalk = true;
1053                         //print("currently selected WP is ", etos(head), "\n");
1054                         //navigation_testtracewalk = false;
1055                         if (head)
1056                         {
1057                                 te_lightning2(NULL, head.origin, it.origin);
1058                                 waypoint_showlink(head.wp00, head, display_type);
1059                                 waypoint_showlink(head.wp01, head, display_type);
1060                                 waypoint_showlink(head.wp02, head, display_type);
1061                                 waypoint_showlink(head.wp03, head, display_type);
1062                                 waypoint_showlink(head.wp04, head, display_type);
1063                                 waypoint_showlink(head.wp05, head, display_type);
1064                                 waypoint_showlink(head.wp06, head, display_type);
1065                                 waypoint_showlink(head.wp07, head, display_type);
1066                                 waypoint_showlink(head.wp08, head, display_type);
1067                                 waypoint_showlink(head.wp09, head, display_type);
1068                                 waypoint_showlink(head.wp10, head, display_type);
1069                                 waypoint_showlink(head.wp11, head, display_type);
1070                                 waypoint_showlink(head.wp12, head, display_type);
1071                                 waypoint_showlink(head.wp13, head, display_type);
1072                                 waypoint_showlink(head.wp14, head, display_type);
1073                                 waypoint_showlink(head.wp15, head, display_type);
1074                                 waypoint_showlink(head.wp16, head, display_type);
1075                                 waypoint_showlink(head.wp17, head, display_type);
1076                                 waypoint_showlink(head.wp18, head, display_type);
1077                                 waypoint_showlink(head.wp19, head, display_type);
1078                                 waypoint_showlink(head.wp20, head, display_type);
1079                                 waypoint_showlink(head.wp21, head, display_type);
1080                                 waypoint_showlink(head.wp22, head, display_type);
1081                                 waypoint_showlink(head.wp23, head, display_type);
1082                                 waypoint_showlink(head.wp24, head, display_type);
1083                                 waypoint_showlink(head.wp25, head, display_type);
1084                                 waypoint_showlink(head.wp26, head, display_type);
1085                                 waypoint_showlink(head.wp27, head, display_type);
1086                                 waypoint_showlink(head.wp28, head, display_type);
1087                                 waypoint_showlink(head.wp29, head, display_type);
1088                                 waypoint_showlink(head.wp30, head, display_type);
1089                                 waypoint_showlink(head.wp31, head, display_type);
1090                         }
1091                 }
1092         });
1093 }
1094
1095 float botframe_autowaypoints_fixdown(vector v)
1096 {
1097         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1098         if(trace_fraction >= 1)
1099                 return 0;
1100         return 1;
1101 }
1102
1103 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1104 {
1105         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1106         {
1107                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1108                 return 0;
1109         });
1110
1111         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1112         return 1;
1113 }
1114
1115 // return value:
1116 //    1 = WP created
1117 //    0 = no action needed
1118 //   -1 = temp fail, try from world too
1119 //   -2 = permanent fail, do not retry
1120 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1121 {
1122         // make it possible to go from p to wp, if we can
1123         // if wp is NULL, nearest is chosen
1124
1125         entity w;
1126         vector porg;
1127         float t, tmin, tmax;
1128         vector o;
1129         vector save;
1130
1131         if(!botframe_autowaypoints_fixdown(p.origin))
1132                 return -2;
1133         porg = trace_endpos;
1134
1135         if(wp)
1136         {
1137                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1138
1139                 // if wp -> porg, then OK
1140                 float maxdist;
1141                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1142                 {
1143                         // we may find a better one
1144                         maxdist = vlen(wp.origin - porg);
1145                 }
1146                 else
1147                 {
1148                         // accept any "good"
1149                         maxdist = 2100;
1150                 }
1151
1152                 float bestdist = maxdist;
1153                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1154                 {
1155                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1156                         if(d < bestdist)
1157                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1158                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1159                         {
1160                                 bestdist = d;
1161                                 p.(fld) = it;
1162                         }
1163                 });
1164                 if(bestdist < maxdist)
1165                 {
1166                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1167                         return 0;
1168                 }
1169
1170                 if(bestdist < 2100)
1171                 {
1172                         // we know maxdist < 2100
1173                         // so wp -> porg is still valid
1174                         // all is good
1175                         p.(fld) = wp;
1176                         return 0;
1177                 }
1178
1179                 // otherwise, no existing WP can fix our issues
1180         }
1181         else
1182         {
1183                 save = p.origin;
1184                 setorigin(p, porg);
1185                 w = navigation_findnearestwaypoint(p, walkfromwp);
1186                 setorigin(p, save);
1187                 if(w)
1188                 {
1189                         p.(fld) = w;
1190                         return 0;
1191                 }
1192         }
1193
1194         tmin = 0;
1195         tmax = 1;
1196         for (;;)
1197         {
1198                 if(tmax - tmin < 0.001)
1199                 {
1200                         // did not get a good candidate
1201                         return -1;
1202                 }
1203
1204                 t = (tmin + tmax) * 0.5;
1205                 o = antilag_takebackorigin(p, CS(p), time - t);
1206                 if(!botframe_autowaypoints_fixdown(o))
1207                         return -2;
1208                 o = trace_endpos;
1209
1210                 if(wp)
1211                 {
1212                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1213                         {
1214                                 // we cannot walk from wp.origin to o
1215                                 // get closer to tmax
1216                                 tmin = t;
1217                                 continue;
1218                         }
1219                 }
1220                 else
1221                 {
1222                         save = p.origin;
1223                         setorigin(p, o);
1224                         w = navigation_findnearestwaypoint(p, walkfromwp);
1225                         setorigin(p, save);
1226                         if(!w)
1227                         {
1228                                 // we cannot walk from any WP to o
1229                                 // get closer to tmax
1230                                 tmin = t;
1231                                 continue;
1232                         }
1233                 }
1234
1235                 // if we get here, o is valid regarding waypoints
1236                 // check if o is connected right to the player
1237                 // we break if it succeeds, as that means o is a good waypoint location
1238                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1239                         break;
1240
1241                 // o is no good, we need to get closer to the player
1242                 tmax = t;
1243         }
1244
1245         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1246         botframe_autowaypoints_createwp(o, p, fld, 0);
1247         return 1;
1248 }
1249
1250 // automatically create missing waypoints
1251 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1252 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1253 {
1254         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1255         if(r != -1)
1256                 return;
1257         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1258         if(r != -1)
1259                 return;
1260
1261         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1262         if(!botframe_autowaypoints_fixdown(p.origin))
1263                 return; // shouldn't happen, caught above
1264         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1265 }
1266
1267 void botframe_deleteuselesswaypoints()
1268 {
1269         IL_EACH(g_items, it.bot_pickup,
1270         {
1271                 // NOTE: this protects waypoints if they're the ONLY nearest
1272                 // waypoint. That's the intention.
1273                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1274                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1275         });
1276         IL_EACH(g_waypoints, true,
1277         {
1278                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1279                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1280                 // WP is useful if:
1281                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1282                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1283                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1284                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1285                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1286                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1287                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1288                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1289                 // b) WP is closest WP for an item/spawnpoint/other entity
1290                 //    This has been done above by protecting these WPs.
1291         });
1292         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1293         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1294         {
1295                 for (int m = 0; m < 32; ++m)
1296                 {
1297                         entity w = waypoint_get_link(it, m);
1298                         if (!w)
1299                                 break;
1300                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1301                                 continue;
1302                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1303                                 continue;
1304                         for (int j = 0; j < 32; ++j)
1305                         {
1306                                 entity w2 = waypoint_get_link(w, j);
1307                                 if (!w2)
1308                                         break;
1309                                 if (it == w2)
1310                                         continue;
1311                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1312                                         continue;
1313                                 // If we got here, it != w2 exist with it -> w
1314                                 // and w -> w2. That means the waypoint is not
1315                                 // a dead end.
1316                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1317                                 for (int k = 0; k < 32; ++k)
1318                                 {
1319                                         if (waypoint_get_link(it, k) == w2)
1320                                                 continue;
1321                                         // IF WE GET HERE, w is proven useful
1322                                         // to get from it to w2!
1323                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1324                                         goto next;
1325                                 }
1326                         }
1327 LABEL(next)
1328                 }
1329         });
1330         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1331         //     they are needed to complete routes while autowaypointing.
1332
1333         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1334         {
1335                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1336                 te_explosion(it.origin);
1337                 waypoint_remove(it);
1338                 break;
1339         });
1340
1341         IL_EACH(g_waypoints, true,
1342         {
1343                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1344         });
1345 }
1346
1347 void botframe_autowaypoints()
1348 {
1349         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1350                 // going back is broken, so only fix waypoints to walk TO the player
1351                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1352                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1353                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1354         ));
1355
1356         if (autocvar_g_waypointeditor_auto >= 2) {
1357                 botframe_deleteuselesswaypoints();
1358         }
1359 }
1360