qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27
  28         entity e2 = navigation_findnearestwaypoint(pl, false);
  29         if(!e2)
  30         {
  31                 LOG_INFOF("Can't find any waypoint nearby\n");
  32                 return;
  33         }
  34
  35         navigation_markroutes(pl, e2);
  36
  37         int j = 0;
  38         int m = 0;
  39         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  40         {
  41                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  42                 it.colormod_z = 8;
  43                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  44                 j++;
  45                 m++;
  46         });
  47         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  48         navigation_markroutes_inverted(e2);
  49
  50         j = 0;
  51         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  52         {
  53                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  54                 it.colormod_x = 8;
  55                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  56                         m++;
  57                 it.effects |= EF_NODEPTHTEST | EF_RED;
  58                 j++;
  59         });
  60         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  61         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  62
  63         j = 0;
  64         IL_EACH(g_spawnpoints, true,
  65         {
  66                 if (navigation_findnearestwaypoint(it, false))
  67                 {
  68                         if(it.spawnpointmodel)
  69                         {
  70                                 delete(it.spawnpointmodel);
  71                                 it.spawnpointmodel = NULL;
  72                         }
  73                 }
  74                 else
  75                 {
  76                         if(!it.spawnpointmodel)
  77                         {
  78                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  79                                 entity e = new(spawnpointmodel);
  80                                 vector org = trace_endpos + eZ;
  81                                 setorigin(e, org);
  82                                 e.solid = SOLID_TRIGGER;
  83                                 it.spawnpointmodel = e;
  84                         }
  85                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  86                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  87                         _setmodel(it.spawnpointmodel, pl.model);
  88                         it.spawnpointmodel.frame = pl.frame;
  89                         it.spawnpointmodel.skin = pl.skin;
  90                         it.spawnpointmodel.colormap = pl.colormap;
  91                         it.spawnpointmodel.colormod = pl.colormod;
  92                         it.spawnpointmodel.glowmod = pl.glowmod;
  93                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  94                         j++;
  95                 }
  96         });
  97         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  98
  99         j = 0;
 100         IL_EACH(g_items, true,
 101         {
 102                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 103                 it.colormod = '0.5 0.5 0.5';
 104         });
 105         IL_EACH(g_items, true,
 106         {
 107                 if (navigation_findnearestwaypoint(it, false))
 108                         continue;
 109                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 110                 it.effects |= EF_NODEPTHTEST | EF_RED;
 111                 it.colormod_x = 8;
 112                 j++;
 113         });
 114         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 115
 116         j = 0;
 117         IL_EACH(g_items, true,
 118         {
 119                 if (navigation_findnearestwaypoint(it, true))
 120                         continue;
 121                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 122                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 123                 it.colormod_z = 8;
 124                 j++;
 125         });
 126         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 127 }
 128
 129 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 130 {
 131         vector new_org = org;
 132         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 133         {
 134                 vector map_center = havocbot_middlepoint;
 135                 if (autocvar_g_waypointeditor_symmetrical == -1)
 136                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 137
 138                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 139         }
 140         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 141         {
 142                 float m = havocbot_symmetryaxis_equation.x;
 143                 float q = havocbot_symmetryaxis_equation.y;
 144                 if (autocvar_g_waypointeditor_symmetrical == -2)
 145                 {
 146                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 147                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 148                 }
 149
 150                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 151                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 152         }
 153         new_org.z = org.z;
 154         return new_org;
 155 }
 156
 157 void waypoint_setupmodel(entity wp)
 158 {
 159         if (autocvar_g_waypointeditor)
 160         {
 161                 // TODO: add some sort of visible box in edit mode for box waypoints
 162                 vector m1 = wp.mins;
 163                 vector m2 = wp.maxs;
 164                 setmodel(wp, MDL_WAYPOINT);
 165                 setsize(wp, m1, m2);
 166                 wp.effects = EF_LOWPRECISION;
 167                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 168                         wp.colormod = '1 0 0';
 169                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 170                         wp.colormod = '1 1 0';
 171                 else if (wp.wphardwired)
 172                         wp.colormod = '0.5 0 1';
 173                 else
 174                         wp.colormod = '1 1 1';
 175         }
 176         else
 177                 wp.model = "";
 178 }
 179
 180 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 181 // them back to it as well
 182 // (suitable for spawnfunc_waypoint editor)
 183 entity waypoint_spawn(vector m1, vector m2, float f)
 184 {
 185         if(!(f & WAYPOINTFLAG_PERSONAL))
 186         {
 187                 vector em1 = m1, em2 = m2;
 188                 if (!(f & WAYPOINTFLAG_GENERATED) && m1 == m2)
 189                 {
 190                         em1 = m1 - '8 8 8';
 191                         em2 = m2 + '8 8 8';
 192                 }
 193                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 194                 {
 195                         return it;
 196                 });
 197         }
 198
 199         entity w = new(waypoint);
 200         IL_PUSH(g_waypoints, w);
 201         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 202         w.wpflags = f;
 203         w.solid = SOLID_TRIGGER;
 204         setorigin(w, (m1 + m2) * 0.5);
 205         setsize(w, m1 - w.origin, m2 - w.origin);
 206         if (w.size)
 207                 w.wpisbox = true;
 208
 209         if(!w.wpisbox)
 210         {
 211                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 212                 if(!move_out_of_solid(w))
 213                 {
 214                         if(!(f & WAYPOINTFLAG_GENERATED))
 215                         {
 216                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 217                                 delete(w);
 218                                 return NULL;
 219                         }
 220                         else
 221                         {
 222                                 if(autocvar_developer)
 223                                 {
 224                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 225                                         backtrace("Waypoint stuck");
 226                                 }
 227                         }
 228                 }
 229                 setsize(w, '0 0 0', '0 0 0');
 230         }
 231
 232         waypoint_clearlinks(w);
 233         //waypoint_schedulerelink(w);
 234
 235         waypoint_setupmodel(w);
 236
 237         return w;
 238 }
 239
 240 void waypoint_spawn_fromeditor(entity pl)
 241 {
 242         entity e;
 243         vector org = pl.origin;
 244         int ctf_flags = havocbot_symmetryaxis_equation.z;
 245         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 246                    || (autocvar_g_waypointeditor_symmetrical < 0));
 247         int order = ctf_flags;
 248         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 249         {
 250                 order = autocvar_g_waypointeditor_symmetrical_order;
 251                 ctf_flags = order;
 252         }
 253
 254         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 255         {
 256                 // snap waypoint to item's origin if close enough
 257                 IL_EACH(g_items, true,
 258                 {
 259                         vector item_org = (it.absmin + it.absmax) * 0.5;
 260                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 261                         if(vlen(item_org - org) < 30)
 262                         {
 263                                 org = item_org;
 264                                 break;
 265                         }
 266                 });
 267         }
 268
 269         LABEL(add_wp);
 270         e = waypoint_spawn(org, org, 0);
 271         waypoint_schedulerelink(e);
 272         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 273         if(sym)
 274         {
 275                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 276                 if (vdist(org - pl.origin, >, 32))
 277                 {
 278                         if(order > 2)
 279                                 order--;
 280                         else
 281                                 sym = false;
 282                         goto add_wp;
 283                 }
 284         }
 285 }
 286
 287 void waypoint_remove(entity wp)
 288 {
 289         // tell all waypoints linked to wp that they need to relink
 290         IL_EACH(g_waypoints, it != wp,
 291         {
 292                 if (waypoint_islinked(it, wp))
 293                         waypoint_removelink(it, wp);
 294         });
 295         delete(wp);
 296 }
 297
 298 void waypoint_remove_fromeditor(entity pl)
 299 {
 300         entity e = navigation_findnearestwaypoint(pl, false);
 301
 302         int ctf_flags = havocbot_symmetryaxis_equation.z;
 303         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 304                    || (autocvar_g_waypointeditor_symmetrical < 0));
 305         int order = ctf_flags;
 306         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 307         {
 308                 order = autocvar_g_waypointeditor_symmetrical_order;
 309                 ctf_flags = order;
 310         }
 311
 312         LABEL(remove_wp);
 313         if (!e) return;
 314         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 315
 316         if (e.wphardwired)
 317         {
 318                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 319                 return;
 320         }
 321
 322         entity wp_sym = NULL;
 323         if (sym)
 324         {
 325                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 326                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 327                         if(vdist(org - it.origin, <, 3))
 328                         {
 329                                 wp_sym = it;
 330                                 break;
 331                         }
 332                 });
 333         }
 334
 335         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 336         waypoint_remove(e);
 337
 338         if (sym && wp_sym)
 339         {
 340                 e = wp_sym;
 341                 if(order > 2)
 342                         order--;
 343                 else
 344                         sym = false;
 345                 goto remove_wp;
 346         }
 347 }
 348
 349 void waypoint_removelink(entity from, entity to)
 350 {
 351         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 352                 return;
 353
 354         bool found = false;
 355         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 356         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 357         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 358         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 359         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 360         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 361         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 362         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 363         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 364         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 365         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 366         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 367         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 368         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 369         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 370         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 371         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 372         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 373         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 374         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 375         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 376         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 377         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 378         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 379         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 380         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 381         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 382         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 383         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 384         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 385         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 386         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 387 }
 388
 389 bool waypoint_islinked(entity from, entity to)
 390 {
 391         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 392         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 393         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 394         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 395         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 396         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 397         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 398         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 399         return false;
 400 }
 401
 402 void waypoint_updatecost_foralllinks()
 403 {
 404         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 405         {
 406                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 407                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 408                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 409                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 410                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 411                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 412                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 413                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 414                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 415                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 416                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 417                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 418                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 419                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 420                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 421                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 422                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 423                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 424                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 425                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 426                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 427                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 428                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 429                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 430                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 431                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 432                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 433                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 434                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 435                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 436                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 437                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 438         });
 439 }
 440
 441 float waypoint_getlinearcost(float dist)
 442 {
 443         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 444                 return dist / (autocvar_sv_maxspeed * 1.25);
 445         return dist / autocvar_sv_maxspeed;
 446 }
 447
 448 float waypoint_gettravelcost(vector from, vector to)
 449 {
 450         float c = waypoint_getlinearcost(vlen(to - from));
 451
 452         float height = from.z - to.z;
 453         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 454         {
 455                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 456                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 457                 if(height_cost > c)
 458                         c = height_cost;
 459         }
 460         return c;
 461 }
 462
 463 float waypoint_getlinkcost(entity from, entity to)
 464 {
 465         vector v1 = from.origin;
 466         vector v2 = to.origin;
 467         if (from.wpisbox)
 468         {
 469                 vector m1 = to.absmin, m2 = to.absmax;
 470                 v1_x = bound(m1_x, v1_x, m2_x);
 471                 v1_y = bound(m1_y, v1_y, m2_y);
 472                 v1_z = bound(m1_z, v1_z, m2_z);
 473         }
 474         if (to.wpisbox)
 475         {
 476                 vector m1 = from.absmin, m2 = from.absmax;
 477                 v2_x = bound(m1_x, v2_x, m2_x);
 478                 v2_y = bound(m1_y, v2_y, m2_y);
 479                 v2_z = bound(m1_z, v2_z, m2_z);
 480         }
 481         return waypoint_gettravelcost(v1, v2);
 482 }
 483
 484 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 485 // if c == -1 automatically determine cost of the link
 486 void waypoint_addlink_customcost(entity from, entity to, float c)
 487 {
 488         if (from == to || waypoint_islinked(from, to))
 489                 return;
 490         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 491                 return;
 492
 493         if(c == -1)
 494                 c = waypoint_getlinkcost(from, to);
 495
 496         if (from.wp31mincost < c) return;
 497         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 498         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 499         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 500         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 501         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 502         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 503         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 504         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 505         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 506         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 507         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 508         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 509         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 510         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 511         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 512         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 513         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 514         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 515         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 516         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 517         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 518         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 519         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 520         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 521         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 522         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 523         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 524         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 525         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 526         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 527         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 528         from.wp00 = to;from.wp00mincost = c;return;
 529 }
 530
 531 void waypoint_addlink(entity from, entity to)
 532 {
 533         waypoint_addlink_customcost(from, to, -1);
 534 }
 535
 536 // relink this spawnfunc_waypoint
 537 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 538 // (SLOW!)
 539 void waypoint_think(entity this)
 540 {
 541         vector sv, sv2, ev, ev2, dv;
 542         float sv2_height, ev2_height;
 543
 544         bot_calculate_stepheightvec();
 545
 546         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 547
 548         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 549         IL_EACH(g_waypoints, this != it,
 550         {
 551                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 552                 {
 553                         waypoint_addlink(this, it);
 554                         waypoint_addlink(it, this);
 555                 }
 556                 else
 557                 {
 558                         ++relink_total;
 559                         if(!checkpvs(this.origin, it))
 560                         {
 561                                 ++relink_pvsculled;
 562                                 continue;
 563                         }
 564
 565                         SET_TRACEWALK_DESTCOORDS_2(this, it.origin, sv, sv2, sv2_height);
 566                         SET_TRACEWALK_DESTCOORDS_2(it, this.origin, ev, ev2, ev2_height);
 567
 568                         dv = ev - sv;
 569                         dv.z = 0;
 570                         if(vdist(dv, >=, 1050)) // max search distance in XY
 571                         {
 572                                 ++relink_lengthculled;
 573                                 continue;
 574                         }
 575
 576                         navigation_testtracewalk = 0;
 577
 578                         //traceline(this.origin, it.origin, false, NULL);
 579                         //if (trace_fraction == 1)
 580                         if (this.wpisbox)
 581                                 relink_walkculled += 0.5;
 582                         else
 583                         {
 584                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 585                                         waypoint_addlink(this, it);
 586                                 else
 587                                         relink_walkculled += 0.5;
 588                         }
 589
 590                         if (it.wpisbox)
 591                                 relink_walkculled += 0.5;
 592                         else
 593                         {
 594                                 if (tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 595                                         waypoint_addlink(it, this);
 596                                 else
 597                                         relink_walkculled += 0.5;
 598                         }
 599                 }
 600         });
 601         navigation_testtracewalk = 0;
 602         this.wplinked = true;
 603 }
 604
 605 void waypoint_clearlinks(entity wp)
 606 {
 607         // clear links to other waypoints
 608         float f = 10000000;
 609         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 610         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 611         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 612         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 613
 614         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 615         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 616         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 617         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 618
 619         wp.wplinked = false;
 620 }
 621
 622 // tell a spawnfunc_waypoint to relink
 623 void waypoint_schedulerelink(entity wp)
 624 {
 625         if (wp == NULL)
 626                 return;
 627
 628         waypoint_setupmodel(wp);
 629         wp.wpisbox = vdist(wp.size, >, 0);
 630         wp.enemy = NULL;
 631         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 632                 wp.owner = NULL;
 633         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 634                 waypoint_clearlinks(wp);
 635         // schedule an actual relink on next frame
 636         setthink(wp, waypoint_think);
 637         wp.nextthink = time;
 638         wp.effects = EF_LOWPRECISION;
 639 }
 640
 641 // spawnfunc_waypoint map entity
 642 spawnfunc(waypoint)
 643 {
 644         IL_PUSH(g_waypoints, this);
 645
 646         setorigin(this, this.origin);
 647         // schedule a relink after other waypoints have had a chance to spawn
 648         waypoint_clearlinks(this);
 649         //waypoint_schedulerelink(this);
 650 }
 651
 652 // tell all waypoints to relink
 653 // actually this is useful only to update relink_* stats
 654 void waypoint_schedulerelinkall()
 655 {
 656         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 657         IL_EACH(g_waypoints, true,
 658         {
 659                 waypoint_schedulerelink(it);
 660         });
 661         waypoint_load_links_hardwired();
 662 }
 663
 664 // Load waypoint links from file
 665 bool waypoint_load_links()
 666 {
 667         string filename, s;
 668         float file, tokens, c = 0, found;
 669         entity wp_from = NULL, wp_to;
 670         vector wp_to_pos, wp_from_pos;
 671         filename = strcat("maps/", mapname);
 672         filename = strcat(filename, ".waypoints.cache");
 673         file = fopen(filename, FILE_READ);
 674
 675         if (file < 0)
 676         {
 677                 LOG_TRACE("waypoint links load from ");
 678                 LOG_TRACE(filename);
 679                 LOG_TRACE(" failed");
 680                 return false;
 681         }
 682
 683         while ((s = fgets(file)))
 684         {
 685                 tokens = tokenizebyseparator(s, "*");
 686
 687                 if (tokens!=2)
 688                 {
 689                         // bad file format
 690                         fclose(file);
 691                         return false;
 692                 }
 693
 694                 wp_from_pos     = stov(argv(0));
 695                 wp_to_pos       = stov(argv(1));
 696
 697                 // Search "from" waypoint
 698                 if(!wp_from || wp_from.origin!=wp_from_pos)
 699                 {
 700                         wp_from = findradius(wp_from_pos, 1);
 701                         found = false;
 702                         while(wp_from)
 703                         {
 704                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 705                                 if(wp_from.classname == "waypoint")
 706                                 {
 707                                         found = true;
 708                                         break;
 709                                 }
 710                                 wp_from = wp_from.chain;
 711                         }
 712
 713                         if(!found)
 714                         {
 715                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 716                                 continue;
 717                         }
 718
 719                 }
 720
 721                 // Search "to" waypoint
 722                 wp_to = findradius(wp_to_pos, 1);
 723                 found = false;
 724                 while(wp_to)
 725                 {
 726                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 727                         if(wp_to.classname == "waypoint")
 728                         {
 729                                 found = true;
 730                                 break;
 731                         }
 732                         wp_to = wp_to.chain;
 733                 }
 734
 735                 if(!found)
 736                 {
 737                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 738                         continue;
 739                 }
 740
 741                 ++c;
 742                 waypoint_addlink(wp_from, wp_to);
 743         }
 744
 745         fclose(file);
 746
 747         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 748
 749         botframe_cachedwaypointlinks = true;
 750         return true;
 751 }
 752
 753 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 754 {
 755         string filename, s;
 756         float file, tokens, c = 0, found;
 757         entity wp_from = NULL, wp_to;
 758         vector wp_to_pos, wp_from_pos;
 759         filename = strcat("maps/", mapname);
 760         filename = strcat(filename, ".waypoints.hardwired");
 761         file = fopen(filename, FILE_READ);
 762
 763         botframe_loadedforcedlinks = true;
 764
 765         if (file < 0)
 766         {
 767                 if(!removal_mode)
 768                         LOG_TRACE("waypoint links load from ", filename, " failed");
 769                 return;
 770         }
 771
 772         while ((s = fgets(file)))
 773         {
 774                 if(substring(s, 0, 2)=="//")
 775                         continue;
 776
 777                 if(substring(s, 0, 1)=="#")
 778                         continue;
 779
 780                 tokens = tokenizebyseparator(s, "*");
 781
 782                 if (tokens!=2)
 783                         continue;
 784
 785                 wp_from_pos     = stov(argv(0));
 786                 wp_to_pos       = stov(argv(1));
 787
 788                 // Search "from" waypoint
 789                 if(!wp_from || wp_from.origin!=wp_from_pos)
 790                 {
 791                         wp_from = findradius(wp_from_pos, 5);
 792                         found = false;
 793                         while(wp_from)
 794                         {
 795                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 796                                 if(wp_from.classname == "waypoint")
 797                                 {
 798                                         found = true;
 799                                         break;
 800                                 }
 801                                 wp_from = wp_from.chain;
 802                         }
 803
 804                         if(!found)
 805                         {
 806                                 if(!removal_mode)
 807                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 808                                 continue;
 809                         }
 810                 }
 811
 812                 // Search "to" waypoint
 813                 wp_to = findradius(wp_to_pos, 5);
 814                 found = false;
 815                 while(wp_to)
 816                 {
 817                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 818                         if(wp_to.classname == "waypoint")
 819                         {
 820                                 found = true;
 821                                 break;
 822                         }
 823                         wp_to = wp_to.chain;
 824                 }
 825
 826                 if(!found)
 827                 {
 828                         if(!removal_mode)
 829                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 830                         continue;
 831                 }
 832
 833                 ++c;
 834                 if(removal_mode)
 835                 {
 836                         waypoint_removelink(wp_from, wp_to);
 837                         continue;
 838                 }
 839
 840                 waypoint_addlink(wp_from, wp_to);
 841                 wp_from.wphardwired = true;
 842                 wp_to.wphardwired = true;
 843         }
 844
 845         fclose(file);
 846
 847         if(!removal_mode)
 848                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 849 }
 850
 851 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 852 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 853
 854 entity waypoint_get_link(entity w, float i)
 855 {
 856         switch(i)
 857         {
 858                 case  0:return w.wp00;
 859                 case  1:return w.wp01;
 860                 case  2:return w.wp02;
 861                 case  3:return w.wp03;
 862                 case  4:return w.wp04;
 863                 case  5:return w.wp05;
 864                 case  6:return w.wp06;
 865                 case  7:return w.wp07;
 866                 case  8:return w.wp08;
 867                 case  9:return w.wp09;
 868                 case 10:return w.wp10;
 869                 case 11:return w.wp11;
 870                 case 12:return w.wp12;
 871                 case 13:return w.wp13;
 872                 case 14:return w.wp14;
 873                 case 15:return w.wp15;
 874                 case 16:return w.wp16;
 875                 case 17:return w.wp17;
 876                 case 18:return w.wp18;
 877                 case 19:return w.wp19;
 878                 case 20:return w.wp20;
 879                 case 21:return w.wp21;
 880                 case 22:return w.wp22;
 881                 case 23:return w.wp23;
 882                 case 24:return w.wp24;
 883                 case 25:return w.wp25;
 884                 case 26:return w.wp26;
 885                 case 27:return w.wp27;
 886                 case 28:return w.wp28;
 887                 case 29:return w.wp29;
 888                 case 30:return w.wp30;
 889                 case 31:return w.wp31;
 890                 default:return NULL;
 891         }
 892 }
 893
 894 // Save all waypoint links to a file
 895 void waypoint_save_links()
 896 {
 897         // temporarily remove hardwired links so they don't get saved among normal links
 898         waypoint_remove_links_hardwired();
 899
 900         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 901         int file = fopen(filename, FILE_WRITE);
 902         if (file < 0)
 903         {
 904                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 905                 return;
 906         }
 907
 908         int c = 0;
 909         IL_EACH(g_waypoints, true,
 910         {
 911                 for(int j = 0; j < 32; ++j)
 912                 {
 913                         entity link = waypoint_get_link(it, j);
 914                         if(link)
 915                         {
 916                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 917                                 fputs(file, s);
 918                                 ++c;
 919                         }
 920                 }
 921         });
 922         fclose(file);
 923         botframe_cachedwaypointlinks = true;
 924
 925         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 926
 927         waypoint_load_links_hardwired();
 928 }
 929
 930 // save waypoints to gamedir/data/maps/mapname.waypoints
 931 void waypoint_saveall()
 932 {
 933         string filename = sprintf("maps/%s.waypoints", mapname);
 934         int file = fopen(filename, FILE_WRITE);
 935         if (file < 0)
 936         {
 937                 waypoint_save_links(); // save anyway?
 938                 botframe_loadedforcedlinks = false;
 939
 940                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 941                 return;
 942         }
 943
 944         int c = 0;
 945         IL_EACH(g_waypoints, true,
 946         {
 947                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 948                         continue;
 949
 950                 string s;
 951                 s = strcat(vtos(it.origin + it.mins), "\n");
 952                 s = strcat(s, vtos(it.origin + it.maxs));
 953                 s = strcat(s, "\n");
 954                 s = strcat(s, ftos(it.wpflags));
 955                 s = strcat(s, "\n");
 956                 fputs(file, s);
 957                 c++;
 958         });
 959         fclose(file);
 960         waypoint_save_links();
 961         botframe_loadedforcedlinks = false;
 962
 963         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 964 }
 965
 966 // load waypoints from file
 967 float waypoint_loadall()
 968 {
 969         string filename, s;
 970         float file, cwp, cwb, fl;
 971         vector m1, m2;
 972         cwp = 0;
 973         cwb = 0;
 974         filename = strcat("maps/", mapname);
 975         filename = strcat(filename, ".waypoints");
 976         file = fopen(filename, FILE_READ);
 977         if (file >= 0)
 978         {
 979                 while ((s = fgets(file)))
 980                 {
 981                         m1 = stov(s);
 982                         s = fgets(file);
 983                         if (!s)
 984                                 break;
 985                         m2 = stov(s);
 986                         s = fgets(file);
 987                         if (!s)
 988                                 break;
 989                         fl = stof(s);
 990                         waypoint_spawn(m1, m2, fl);
 991                         if (m1 == m2)
 992                                 cwp = cwp + 1;
 993                         else
 994                                 cwb = cwb + 1;
 995                 }
 996                 fclose(file);
 997                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 998         }
 999         else
1000         {
1001                 LOG_TRACE("waypoint load from ", filename, " failed");
1002         }
1003         return cwp + cwb;
1004 }
1005
1006 vector waypoint_fixorigin(vector position)
1007 {
1008         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1009         if(trace_fraction < 1)
1010                 position = trace_endpos;
1011         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1012         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
1013         return position;
1014 }
1015
1016 void waypoint_spawnforitem_force(entity e, vector org)
1017 {
1018         // Fix the waypoint altitude if necessary
1019         org = waypoint_fixorigin(org);
1020
1021         // don't spawn an item spawnfunc_waypoint if it already exists
1022         IL_EACH(g_waypoints, true,
1023         {
1024                 if(it.wpisbox)
1025                 {
1026                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1027                         {
1028                                 e.nearestwaypoint = it;
1029                                 return;
1030                         }
1031                 }
1032                 else
1033                 {
1034                         if(vdist(it.origin - org, <, 16))
1035                         {
1036                                 e.nearestwaypoint = it;
1037                                 return;
1038                         }
1039                 }
1040         });
1041
1042         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1043 }
1044
1045 void waypoint_spawnforitem(entity e)
1046 {
1047         if(!bot_waypoints_for_items)
1048                 return;
1049
1050         waypoint_spawnforitem_force(e, e.origin);
1051 }
1052
1053 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1054 {
1055         entity w;
1056         entity dw;
1057         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1058         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1059         // one way link to the destination
1060         w.wp00 = dw;
1061         w.wp00mincost = timetaken; // this is just for jump pads
1062         // the teleporter's nearest spawnfunc_waypoint is this one
1063         // (teleporters are not goals, so this is probably useless)
1064         e.nearestwaypoint = w;
1065         e.nearestwaypointtimeout = -1;
1066 }
1067
1068 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1069 {
1070         org = waypoint_fixorigin(org);
1071         destination = waypoint_fixorigin(destination);
1072         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1073 }
1074
1075 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1076 {
1077         destination = waypoint_fixorigin(destination);
1078         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1079 }
1080
1081 entity waypoint_spawnpersonal(entity this, vector position)
1082 {
1083         entity w;
1084
1085         // drop the waypoint to a proper location:
1086         //   first move it up by a player height
1087         //   then move it down to hit the floor with player bbox size
1088         position = waypoint_fixorigin(position);
1089
1090         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1091         w.nearestwaypoint = NULL;
1092         w.nearestwaypointtimeout = 0;
1093         w.owner = this;
1094
1095         waypoint_schedulerelink(w);
1096
1097         return w;
1098 }
1099
1100 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1101 {
1102         if (!(wp1 && wp2))
1103                 return;
1104
1105         if (wp1.wphardwired && wp2.wphardwired)
1106                 te_beam(NULL, wp1.origin, wp2.origin);
1107         else if (display_type == 1)
1108                 te_lightning2(NULL, wp1.origin, wp2.origin);
1109 }
1110
1111 void waypoint_showlinks_to(entity wp, int display_type)
1112 {
1113         IL_EACH(g_waypoints, it != wp,
1114         {
1115                 if (waypoint_islinked(it, wp))
1116                         waypoint_showlink(it, wp, display_type);
1117         });
1118 }
1119
1120 void waypoint_showlinks_from(entity wp, int display_type)
1121 {
1122         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1123         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1124         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1125         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1126         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1127         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1128         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1129         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1130         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1131         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1132         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1133         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1134         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1135         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1136         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1137         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1138 }
1139
1140 void botframe_showwaypointlinks()
1141 {
1142         if (time < botframe_waypointeditorlightningtime)
1143                 return;
1144         botframe_waypointeditorlightningtime = time + 0.5;
1145         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1146         {
1147                 int display_type = 0;
1148                 entity head = navigation_findnearestwaypoint(it, false);
1149                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1150                         display_type = 1; // default
1151                 else if(head && (head.wphardwired))
1152                         display_type = 2; // only hardwired
1153
1154                 if (display_type)
1155                 {
1156                         //navigation_testtracewalk = true;
1157                         //print("currently selected WP is ", etos(head), "\n");
1158                         //navigation_testtracewalk = false;
1159                         if (head)
1160                         {
1161                                 te_lightning2(NULL, head.origin, it.origin);
1162                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1163                                         waypoint_showlinks_to(head, display_type);
1164                                 else
1165                                         waypoint_showlinks_from(head, display_type);
1166                         }
1167                 }
1168         });
1169 }
1170
1171 float botframe_autowaypoints_fixdown(vector v)
1172 {
1173         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1174         if(trace_fraction >= 1)
1175                 return 0;
1176         return 1;
1177 }
1178
1179 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1180 {
1181         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1182         {
1183                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1184                 return 0;
1185         });
1186
1187         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1188         return 1;
1189 }
1190
1191 // return value:
1192 //    1 = WP created
1193 //    0 = no action needed
1194 //   -1 = temp fail, try from world too
1195 //   -2 = permanent fail, do not retry
1196 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1197 {
1198         // make it possible to go from p to wp, if we can
1199         // if wp is NULL, nearest is chosen
1200
1201         entity w;
1202         vector porg;
1203         float t, tmin, tmax;
1204         vector o;
1205         vector save;
1206
1207         if(!botframe_autowaypoints_fixdown(p.origin))
1208                 return -2;
1209         porg = trace_endpos;
1210
1211         if(wp)
1212         {
1213                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1214
1215                 // if wp -> porg, then OK
1216                 float maxdist;
1217                 if(navigation_waypoint_will_link(wp.origin, porg, p, wp.origin, 0, walkfromwp, 1050))
1218                 {
1219                         // we may find a better one
1220                         maxdist = vlen(wp.origin - porg);
1221                 }
1222                 else
1223                 {
1224                         // accept any "good"
1225                         maxdist = 2100;
1226                 }
1227
1228                 float bestdist = maxdist;
1229                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1230                 {
1231                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1232                         if(d < bestdist)
1233                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, wp.origin, 0, walkfromwp, 1050))
1234                         if(navigation_waypoint_will_link(it.origin, porg, p, it.origin, 0, walkfromwp, 1050))
1235                         {
1236                                 bestdist = d;
1237                                 p.(fld) = it;
1238                         }
1239                 });
1240                 if(bestdist < maxdist)
1241                 {
1242                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1243                         return 0;
1244                 }
1245
1246                 if(bestdist < 2100)
1247                 {
1248                         // we know maxdist < 2100
1249                         // so wp -> porg is still valid
1250                         // all is good
1251                         p.(fld) = wp;
1252                         return 0;
1253                 }
1254
1255                 // otherwise, no existing WP can fix our issues
1256         }
1257         else
1258         {
1259                 save = p.origin;
1260                 setorigin(p, porg);
1261                 w = navigation_findnearestwaypoint(p, walkfromwp);
1262                 setorigin(p, save);
1263                 if(w)
1264                 {
1265                         p.(fld) = w;
1266                         return 0;
1267                 }
1268         }
1269
1270         tmin = 0;
1271         tmax = 1;
1272         for (;;)
1273         {
1274                 if(tmax - tmin < 0.001)
1275                 {
1276                         // did not get a good candidate
1277                         return -1;
1278                 }
1279
1280                 t = (tmin + tmax) * 0.5;
1281                 o = antilag_takebackorigin(p, CS(p), time - t);
1282                 if(!botframe_autowaypoints_fixdown(o))
1283                         return -2;
1284                 o = trace_endpos;
1285
1286                 if(wp)
1287                 {
1288                         if(!navigation_waypoint_will_link(wp.origin, o, p, wp.origin, 0, walkfromwp, 1050))
1289                         {
1290                                 // we cannot walk from wp.origin to o
1291                                 // get closer to tmax
1292                                 tmin = t;
1293                                 continue;
1294                         }
1295                 }
1296                 else
1297                 {
1298                         save = p.origin;
1299                         setorigin(p, o);
1300                         w = navigation_findnearestwaypoint(p, walkfromwp);
1301                         setorigin(p, save);
1302                         if(!w)
1303                         {
1304                                 // we cannot walk from any WP to o
1305                                 // get closer to tmax
1306                                 tmin = t;
1307                                 continue;
1308                         }
1309                 }
1310
1311                 // if we get here, o is valid regarding waypoints
1312                 // check if o is connected right to the player
1313                 // we break if it succeeds, as that means o is a good waypoint location
1314                 if(navigation_waypoint_will_link(o, porg, p, o, 0, walkfromwp, 1050))
1315                         break;
1316
1317                 // o is no good, we need to get closer to the player
1318                 tmax = t;
1319         }
1320
1321         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1322         botframe_autowaypoints_createwp(o, p, fld, 0);
1323         return 1;
1324 }
1325
1326 // automatically create missing waypoints
1327 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1328 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1329 {
1330         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1331         if(r != -1)
1332                 return;
1333         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1334         if(r != -1)
1335                 return;
1336
1337         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1338         if(!botframe_autowaypoints_fixdown(p.origin))
1339                 return; // shouldn't happen, caught above
1340         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1341 }
1342
1343 void botframe_deleteuselesswaypoints()
1344 {
1345         IL_EACH(g_items, it.bot_pickup,
1346         {
1347                 // NOTE: this protects waypoints if they're the ONLY nearest
1348                 // waypoint. That's the intention.
1349                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1350                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1351         });
1352         IL_EACH(g_waypoints, true,
1353         {
1354                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1355                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1356                 // WP is useful if:
1357                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1358                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1359                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1360                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1361                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1362                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1363                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1364                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1365                 // b) WP is closest WP for an item/spawnpoint/other entity
1366                 //    This has been done above by protecting these WPs.
1367         });
1368         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1369         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1370         {
1371                 for (int m = 0; m < 32; ++m)
1372                 {
1373                         entity w = waypoint_get_link(it, m);
1374                         if (!w)
1375                                 break;
1376                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1377                                 continue;
1378                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1379                                 continue;
1380                         for (int j = 0; j < 32; ++j)
1381                         {
1382                                 entity w2 = waypoint_get_link(w, j);
1383                                 if (!w2)
1384                                         break;
1385                                 if (it == w2)
1386                                         continue;
1387                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1388                                         continue;
1389                                 // If we got here, it != w2 exist with it -> w
1390                                 // and w -> w2. That means the waypoint is not
1391                                 // a dead end.
1392                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1393                                 for (int k = 0; k < 32; ++k)
1394                                 {
1395                                         if (waypoint_get_link(it, k) == w2)
1396                                                 continue;
1397                                         // IF WE GET HERE, w is proven useful
1398                                         // to get from it to w2!
1399                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1400                                         goto next;
1401                                 }
1402                         }
1403 LABEL(next)
1404                 }
1405         });
1406         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1407         //     they are needed to complete routes while autowaypointing.
1408
1409         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1410         {
1411                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1412                 te_explosion(it.origin);
1413                 waypoint_remove(it);
1414                 break;
1415         });
1416
1417         IL_EACH(g_waypoints, true,
1418         {
1419                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1420         });
1421 }
1422
1423 void botframe_autowaypoints()
1424 {
1425         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1426                 // going back is broken, so only fix waypoints to walk TO the player
1427                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1428                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1429                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1430         ));
1431
1432         if (autocvar_g_waypointeditor_auto >= 2) {
1433                 botframe_deleteuselesswaypoints();
1434         }
1435 }
1436