qcsrc/server/bot/scripting.qc

   1 #include "scripting.qh"
   2
   3 #include "bot.qh"
   4
   5 .int state;
   6
   7 .float bot_cmdqueuebuf_allocated;
   8 .float bot_cmdqueuebuf;
   9 .float bot_cmdqueuebuf_start;
  10 .float bot_cmdqueuebuf_end;
  11
  12 void bot_clearqueue(entity bot)
  13 {
  14         if(!bot.bot_cmdqueuebuf_allocated)
  15                 return;
  16         buf_del(bot.bot_cmdqueuebuf);
  17         bot.bot_cmdqueuebuf_allocated = false;
  18         LOG_TRACE("bot ", bot.netname, " queue cleared\n");
  19 }
  20
  21 void bot_queuecommand(entity bot, string cmdstring)
  22 {
  23         if(!bot.bot_cmdqueuebuf_allocated)
  24         {
  25                 bot.bot_cmdqueuebuf = buf_create();
  26                 bot.bot_cmdqueuebuf_allocated = true;
  27                 bot.bot_cmdqueuebuf_start = 0;
  28                 bot.bot_cmdqueuebuf_end = 0;
  29         }
  30
  31         bufstr_set(bot.bot_cmdqueuebuf, bot.bot_cmdqueuebuf_end, cmdstring);
  32
  33         // if the command was a "sound" command, precache the sound NOW
  34         // this prevents lagging!
  35         {
  36                 float sp;
  37                 string parm;
  38                 string cmdstr;
  39
  40                 sp = strstrofs(cmdstring, " ", 0);
  41                 if(sp >= 0)
  42                 {
  43                         parm = substring(cmdstring, sp + 1, -1);
  44                         cmdstr = substring(cmdstring, 0, sp);
  45                         if(cmdstr == "sound")
  46                         {
  47                                 // find the LAST word
  48                                 for (;;)
  49                                 {
  50                                         sp = strstrofs(parm, " ", 0);
  51                                         if(sp < 0)
  52                                                 break;
  53                                         parm = substring(parm, sp + 1, -1);
  54                                 }
  55                                 precache_sound(parm);
  56                         }
  57                 }
  58         }
  59
  60         bot.bot_cmdqueuebuf_end += 1;
  61 }
  62
  63 void bot_dequeuecommand(entity bot, float idx)
  64 {
  65         if(!bot.bot_cmdqueuebuf_allocated)
  66                 error("dequeuecommand but no queue allocated");
  67         if(idx < bot.bot_cmdqueuebuf_start)
  68                 error("dequeueing a command in the past");
  69         if(idx >= bot.bot_cmdqueuebuf_end)
  70                 error("dequeueing a command in the future");
  71         bufstr_set(bot.bot_cmdqueuebuf, idx, "");
  72         if(idx == bot.bot_cmdqueuebuf_start)
  73                 bot.bot_cmdqueuebuf_start += 1;
  74         if(bot.bot_cmdqueuebuf_start >= bot.bot_cmdqueuebuf_end)
  75                 bot_clearqueue(bot);
  76 }
  77
  78 string bot_readcommand(entity bot, float idx)
  79 {
  80         if(!bot.bot_cmdqueuebuf_allocated)
  81                 error("readcommand but no queue allocated");
  82         if(idx < bot.bot_cmdqueuebuf_start)
  83                 error("reading a command in the past");
  84         if(idx >= bot.bot_cmdqueuebuf_end)
  85                 error("reading a command in the future");
  86         return bufstr_get(bot.bot_cmdqueuebuf, idx);
  87 }
  88
  89 float bot_havecommand(entity bot, float idx)
  90 {
  91         if(!bot.bot_cmdqueuebuf_allocated)
  92                 return 0;
  93         if(idx < bot.bot_cmdqueuebuf_start)
  94                 return 0;
  95         if(idx >= bot.bot_cmdqueuebuf_end)
  96                 return 0;
  97         return 1;
  98 }
  99
 100 const int MAX_BOT_PLACES = 4;
 101 .float bot_places_count;
 102 .entity bot_places[MAX_BOT_PLACES];
 103 .string bot_placenames[MAX_BOT_PLACES];
 104 entity bot_getplace(string placename)
 105 {SELFPARAM();
 106         entity e;
 107         if(substring(placename, 0, 1) == "@")
 108         {
 109                 int i, p;
 110                 placename = substring(placename, 1, -1);
 111                 string s, s2;
 112                 for(i = 0; i < self.bot_places_count; ++i)
 113                         if(self.(bot_placenames[i]) == placename)
 114                                 return self.(bot_places[i]);
 115                 // now: i == self.bot_places_count
 116                 s = s2 = cvar_string(placename);
 117                 p = strstrofs(s2, " ", 0);
 118                 if(p >= 0)
 119                 {
 120                         s = substring(s2, 0, p);
 121                         //print("places: ", placename, " -> ", cvar_string(placename), "\n");
 122                         cvar_set(placename, strcat(substring(s2, p+1, -1), " ", s));
 123                         //print("places: ", placename, " := ", cvar_string(placename), "\n");
 124                 }
 125                 e = find(world, targetname, s);
 126                 if(!e)
 127                         LOG_INFO("invalid place ", s, "\n");
 128                 if(i < MAX_BOT_PLACES)
 129                 {
 130                         self.(bot_placenames[i]) = strzone(placename);
 131                         self.(bot_places[i]) = e;
 132                         self.bot_places_count += 1;
 133                 }
 134                 return e;
 135         }
 136         else
 137         {
 138                 e = find(world, targetname, placename);
 139                 if(!e)
 140                         LOG_INFO("invalid place ", placename, "\n");
 141                 return e;
 142         }
 143 }
 144
 145
 146 // Initialize global commands list
 147 // NOTE: New commands should be initialized here
 148 void bot_commands_init()
 149 {
 150         bot_cmd_string[BOT_CMD_NULL] = "";
 151         bot_cmd_parm_type[BOT_CMD_NULL] = BOT_CMD_PARAMETER_NONE;
 152
 153         bot_cmd_string[BOT_CMD_PAUSE] = "pause";
 154         bot_cmd_parm_type[BOT_CMD_PAUSE] = BOT_CMD_PARAMETER_NONE;
 155
 156         bot_cmd_string[BOT_CMD_CONTINUE] = "continue";
 157         bot_cmd_parm_type[BOT_CMD_CONTINUE] = BOT_CMD_PARAMETER_NONE;
 158
 159         bot_cmd_string[BOT_CMD_WAIT] = "wait";
 160         bot_cmd_parm_type[BOT_CMD_WAIT] = BOT_CMD_PARAMETER_FLOAT;
 161
 162         bot_cmd_string[BOT_CMD_TURN] = "turn";
 163         bot_cmd_parm_type[BOT_CMD_TURN] = BOT_CMD_PARAMETER_FLOAT;
 164
 165         bot_cmd_string[BOT_CMD_MOVETO] = "moveto";
 166         bot_cmd_parm_type[BOT_CMD_MOVETO] = BOT_CMD_PARAMETER_VECTOR;
 167
 168         bot_cmd_string[BOT_CMD_MOVETOTARGET] = "movetotarget";
 169         bot_cmd_parm_type[BOT_CMD_MOVETOTARGET] = BOT_CMD_PARAMETER_STRING;
 170
 171         bot_cmd_string[BOT_CMD_RESETGOAL] = "resetgoal";
 172         bot_cmd_parm_type[BOT_CMD_RESETGOAL] = BOT_CMD_PARAMETER_NONE;
 173
 174         bot_cmd_string[BOT_CMD_CC] = "cc";
 175         bot_cmd_parm_type[BOT_CMD_CC] = BOT_CMD_PARAMETER_STRING;
 176
 177         bot_cmd_string[BOT_CMD_IF] = "if";
 178         bot_cmd_parm_type[BOT_CMD_IF] = BOT_CMD_PARAMETER_STRING;
 179
 180         bot_cmd_string[BOT_CMD_ELSE] = "else";
 181         bot_cmd_parm_type[BOT_CMD_ELSE] = BOT_CMD_PARAMETER_NONE;
 182
 183         bot_cmd_string[BOT_CMD_FI] = "fi";
 184         bot_cmd_parm_type[BOT_CMD_FI] = BOT_CMD_PARAMETER_NONE;
 185
 186         bot_cmd_string[BOT_CMD_RESETAIM] = "resetaim";
 187         bot_cmd_parm_type[BOT_CMD_RESETAIM] = BOT_CMD_PARAMETER_NONE;
 188
 189         bot_cmd_string[BOT_CMD_AIM] = "aim";
 190         bot_cmd_parm_type[BOT_CMD_AIM] = BOT_CMD_PARAMETER_STRING;
 191
 192         bot_cmd_string[BOT_CMD_AIMTARGET] = "aimtarget";
 193         bot_cmd_parm_type[BOT_CMD_AIMTARGET] = BOT_CMD_PARAMETER_STRING;
 194
 195         bot_cmd_string[BOT_CMD_PRESSKEY] = "presskey";
 196         bot_cmd_parm_type[BOT_CMD_PRESSKEY] = BOT_CMD_PARAMETER_STRING;
 197
 198         bot_cmd_string[BOT_CMD_RELEASEKEY] = "releasekey";
 199         bot_cmd_parm_type[BOT_CMD_RELEASEKEY] = BOT_CMD_PARAMETER_STRING;
 200
 201         bot_cmd_string[BOT_CMD_SELECTWEAPON] = "selectweapon";
 202         bot_cmd_parm_type[BOT_CMD_SELECTWEAPON] = BOT_CMD_PARAMETER_FLOAT;
 203
 204         bot_cmd_string[BOT_CMD_IMPULSE] = "impulse";
 205         bot_cmd_parm_type[BOT_CMD_IMPULSE] = BOT_CMD_PARAMETER_FLOAT;
 206
 207         bot_cmd_string[BOT_CMD_WAIT_UNTIL] = "wait_until";
 208         bot_cmd_parm_type[BOT_CMD_WAIT_UNTIL] = BOT_CMD_PARAMETER_FLOAT;
 209
 210         bot_cmd_string[BOT_CMD_BARRIER] = "barrier";
 211         bot_cmd_parm_type[BOT_CMD_BARRIER] = BOT_CMD_PARAMETER_NONE;
 212
 213         bot_cmd_string[BOT_CMD_CONSOLE] = "console";
 214         bot_cmd_parm_type[BOT_CMD_CONSOLE] = BOT_CMD_PARAMETER_STRING;
 215
 216         bot_cmd_string[BOT_CMD_SOUND] = "sound";
 217         bot_cmd_parm_type[BOT_CMD_SOUND] = BOT_CMD_PARAMETER_STRING;
 218
 219         bot_cmd_string[BOT_CMD_DEBUG_ASSERT_CANFIRE] = "debug_assert_canfire";
 220         bot_cmd_parm_type[BOT_CMD_DEBUG_ASSERT_CANFIRE] = BOT_CMD_PARAMETER_FLOAT;
 221
 222         bot_cmds_initialized = true;
 223 }
 224
 225 // Returns first bot with matching name
 226 entity find_bot_by_name(string name)
 227 {
 228         entity bot;
 229
 230         bot = findchainflags(flags, FL_CLIENT);
 231         while (bot)
 232         {
 233                 if(IS_BOT_CLIENT(bot))
 234                 if(bot.netname==name)
 235                         return bot;
 236
 237                 bot = bot.chain;
 238         }
 239
 240         return world;
 241 }
 242
 243 // Returns a bot by number on list
 244 entity find_bot_by_number(float number)
 245 {
 246         entity bot;
 247         float c = 0;
 248
 249         if(!number)
 250                 return world;
 251
 252         bot = findchainflags(flags, FL_CLIENT);
 253         while (bot)
 254         {
 255                 if(IS_BOT_CLIENT(bot))
 256                 {
 257                         if(++c==number)
 258                                 return bot;
 259                 }
 260                 bot = bot.chain;
 261         }
 262
 263         return world;
 264 }
 265
 266 float bot_decodecommand(string cmdstring)
 267 {
 268         float cmd_parm_type;
 269         float sp;
 270         string parm;
 271
 272         sp = strstrofs(cmdstring, " ", 0);
 273         if(sp < 0)
 274         {
 275                 parm = "";
 276         }
 277         else
 278         {
 279                 parm = substring(cmdstring, sp + 1, -1);
 280                 cmdstring = substring(cmdstring, 0, sp);
 281         }
 282
 283         if(!bot_cmds_initialized)
 284                 bot_commands_init();
 285
 286         int i;
 287         for(i=1;i<BOT_CMD_COUNTER;++i)
 288         {
 289                 if(bot_cmd_string[i]!=cmdstring)
 290                         continue;
 291
 292                 cmd_parm_type = bot_cmd_parm_type[i];
 293
 294                 if(cmd_parm_type!=BOT_CMD_PARAMETER_NONE&&parm=="")
 295                 {
 296                         LOG_INFO("ERROR: A parameter is required for this command\n");
 297                         return 0;
 298                 }
 299
 300                 // Load command into queue
 301                 bot_cmd.bot_cmd_type = i;
 302
 303                 // Attach parameter
 304                 switch(cmd_parm_type)
 305                 {
 306                         case BOT_CMD_PARAMETER_FLOAT:
 307                                 bot_cmd.bot_cmd_parm_float = stof(parm);
 308                                 break;
 309                         case BOT_CMD_PARAMETER_STRING:
 310                                 if(bot_cmd.bot_cmd_parm_string)
 311                                         strunzone(bot_cmd.bot_cmd_parm_string);
 312                                 bot_cmd.bot_cmd_parm_string = strzone(parm);
 313                                 break;
 314                         case BOT_CMD_PARAMETER_VECTOR:
 315                                 bot_cmd.bot_cmd_parm_vector = stov(parm);
 316                                 break;
 317                         default:
 318                                 break;
 319                 }
 320                 return 1;
 321         }
 322         LOG_INFO("ERROR: No such command '", cmdstring, "'\n");
 323         return 0;
 324 }
 325
 326 void bot_cmdhelp(string scmd)
 327 {
 328         int i, ntype;
 329         string stype;
 330
 331         if(!bot_cmds_initialized)
 332                 bot_commands_init();
 333
 334         for(i=1;i<BOT_CMD_COUNTER;++i)
 335         {
 336                 if(bot_cmd_string[i]!=scmd)
 337                         continue;
 338
 339                 ntype = bot_cmd_parm_type[i];
 340
 341                 switch(ntype)
 342                 {
 343                         case BOT_CMD_PARAMETER_FLOAT:
 344                                 stype = "float number";
 345                                 break;
 346                         case BOT_CMD_PARAMETER_STRING:
 347                                 stype = "string";
 348                                 break;
 349                         case BOT_CMD_PARAMETER_VECTOR:
 350                                 stype = "vector";
 351                                 break;
 352                         default:
 353                                 stype = "none";
 354                                 break;
 355                 }
 356
 357                 LOG_INFO(strcat("Command: ",bot_cmd_string[i],"\nParameter: <",stype,"> \n"));
 358
 359                 LOG_INFO("Description: ");
 360                 switch(i)
 361                 {
 362                         case BOT_CMD_PAUSE:
 363                                 LOG_INFO("Stops the bot completely. Any command other than 'continue' will be ignored.");
 364                                 break;
 365                         case BOT_CMD_CONTINUE:
 366                                 LOG_INFO("Disable paused status");
 367                                 break;
 368                         case BOT_CMD_WAIT:
 369                                 LOG_INFO("Pause command parsing and bot ai for N seconds. Pressed key will remain pressed");
 370                                 break;
 371                         case BOT_CMD_WAIT_UNTIL:
 372                                 LOG_INFO("Pause command parsing and bot ai until time is N from the last barrier. Pressed key will remain pressed");
 373                                 break;
 374                         case BOT_CMD_BARRIER:
 375                                 LOG_INFO("Waits till all bots that have a command queue reach this command. Pressed key will remain pressed");
 376                                 break;
 377                         case BOT_CMD_TURN:
 378                                 LOG_INFO("Look to the right or left N degrees. For turning to the left use positive numbers.");
 379                                 break;
 380                         case BOT_CMD_MOVETO:
 381                                 LOG_INFO("Walk to an specific coordinate on the map. Usage: moveto \"x y z\"");
 382                                 break;
 383                         case BOT_CMD_MOVETOTARGET:
 384                                 LOG_INFO("Walk to the specific target on the map");
 385                                 break;
 386                         case BOT_CMD_RESETGOAL:
 387                                 LOG_INFO("Resets the goal stack");
 388                                 break;
 389                         case BOT_CMD_CC:
 390                                 LOG_INFO("Execute client command. Examples: cc \"say something\"; cc god; cc \"name newnickname\"; cc kill;");
 391                                 break;
 392                         case BOT_CMD_IF:
 393                                 LOG_INFO("Perform simple conditional execution.\n");
 394                                 LOG_INFO("Syntax: \n");
 395                                 LOG_INFO("        sv_cmd .. if \"condition\"\n");
 396                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 397                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 398                                 LOG_INFO("        sv_cmd .. else\n");
 399                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 400                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 401                                 LOG_INFO("        sv_cmd .. fi\n");
 402                                 LOG_INFO("Conditions: a=b, a>b, a<b, a\t\t(spaces not allowed)\n");
 403                                 LOG_INFO("            Values in conditions can be numbers, cvars in the form cvar.cvar_string or special fields\n");
 404                                 LOG_INFO("Fields: health, speed, flagcarrier\n");
 405                                 LOG_INFO("Examples: if health>50; if health>cvar.g_balance_laser_primary_damage; if flagcarrier;");
 406                                 break;
 407                         case BOT_CMD_RESETAIM:
 408                                 LOG_INFO("Points the aim to the coordinates x,y 0,0");
 409                                 break;
 410                         case BOT_CMD_AIM:
 411                                 LOG_INFO("Move the aim x/y (horizontal/vertical) degrees relatives to the bot\n");
 412                                 LOG_INFO("There is a 3rd optional parameter telling in how many seconds the aim has to reach the new position\n");
 413                                 LOG_INFO("Examples: aim \"90 0\"        // Turn 90 degrees inmediately (positive numbers move to the left/up)\n");
 414                                 LOG_INFO("          aim \"0 90 2\"      // Will gradually look to the sky in the next two seconds");
 415                                 break;
 416                         case BOT_CMD_AIMTARGET:
 417                                 LOG_INFO("Points the aim to given target");
 418                                 break;
 419                         case BOT_CMD_PRESSKEY:
 420                                 LOG_INFO("Press one of the following keys: forward, backward, left, right, jump, crouch, attack1, attack2, use\n");
 421                                 LOG_INFO("Multiple keys can be pressed at time (with many presskey calls) and it will remain pressed until the command \"releasekey\" is called");
 422                                 LOG_INFO("Note: The script will not return the control to the bot ai until all keys are released");
 423                                 break;
 424                         case BOT_CMD_RELEASEKEY:
 425                                 LOG_INFO("Release previoulsy used keys. Use the parameter \"all\" to release all keys");
 426                                 break;
 427                         case BOT_CMD_SOUND:
 428                                 LOG_INFO("play sound file at bot location");
 429                                 break;
 430                         case BOT_CMD_DEBUG_ASSERT_CANFIRE:
 431                                 LOG_INFO("verify the state of the weapon entity");
 432                                 break;
 433                         default:
 434                                 LOG_INFO("This command has no description yet.");
 435                                 break;
 436                 }
 437                 LOG_INFO("\n");
 438         }
 439 }
 440
 441 void bot_list_commands()
 442 {
 443         int i;
 444         string ptype;
 445
 446         if(!bot_cmds_initialized)
 447                 bot_commands_init();
 448
 449         LOG_INFO("List of all available commands:\n");
 450         LOG_INFO("  Command - Parameter Type\n");
 451
 452         for(i=1;i<BOT_CMD_COUNTER;++i)
 453         {
 454                 switch(bot_cmd_parm_type[i])
 455                 {
 456                         case BOT_CMD_PARAMETER_FLOAT:
 457                                 ptype = "float number";
 458                                 break;
 459                         case BOT_CMD_PARAMETER_STRING:
 460                                 ptype = "string";
 461                                 break;
 462                         case BOT_CMD_PARAMETER_VECTOR:
 463                                 ptype = "vector";
 464                                 break;
 465                         default:
 466                                 ptype = "none";
 467                                 break;
 468                 }
 469                 LOG_INFO(strcat("  ",bot_cmd_string[i]," - <",ptype,"> \n"));
 470         }
 471 }
 472
 473 // Commands code
 474 .int bot_exec_status;
 475
 476 void SV_ParseClientCommand(string s);
 477 float bot_cmd_cc()
 478 {
 479         SV_ParseClientCommand(bot_cmd.bot_cmd_parm_string);
 480         return CMD_STATUS_FINISHED;
 481 }
 482
 483 float bot_cmd_impulse()
 484 {SELFPARAM();
 485         self.impulse = bot_cmd.bot_cmd_parm_float;
 486         return CMD_STATUS_FINISHED;
 487 }
 488
 489 float bot_cmd_continue()
 490 {SELFPARAM();
 491         self.bot_exec_status &= ~BOT_EXEC_STATUS_PAUSED;
 492         return CMD_STATUS_FINISHED;
 493 }
 494
 495 .float bot_cmd_wait_time;
 496 float bot_cmd_wait()
 497 {SELFPARAM();
 498         if(self.bot_exec_status & BOT_EXEC_STATUS_WAITING)
 499         {
 500                 if(time>=self.bot_cmd_wait_time)
 501                 {
 502                         self.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 503                         return CMD_STATUS_FINISHED;
 504                 }
 505                 else
 506                         return CMD_STATUS_EXECUTING;
 507         }
 508
 509         self.bot_cmd_wait_time = time + bot_cmd.bot_cmd_parm_float;
 510         self.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 511         return CMD_STATUS_EXECUTING;
 512 }
 513
 514 float bot_cmd_wait_until()
 515 {SELFPARAM();
 516         if(time < bot_cmd.bot_cmd_parm_float + bot_barriertime)
 517         {
 518                 self.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 519                 return CMD_STATUS_EXECUTING;
 520         }
 521         self.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 522         return CMD_STATUS_FINISHED;
 523 }
 524
 525 float bot_cmd_barrier()
 526 {SELFPARAM();
 527         // 0 = no barrier, 1 = waiting, 2 = waiting finished
 528
 529         if(self.bot_barrier == 0) // initialization
 530         {
 531                 self.bot_barrier = 1;
 532
 533                 //self.colormod = '4 4 0';
 534         }
 535
 536         if(self.bot_barrier == 1) // find other bots
 537         {
 538                 FOREACH_CLIENT(it.isbot, LAMBDA(
 539                         if(it.bot_cmdqueuebuf_allocated)
 540                         if(it.bot_barrier != 1)
 541                                 return CMD_STATUS_EXECUTING; // not all are at the barrier yet
 542                 ));
 543
 544                 // all bots hit the barrier!
 545
 546                 // acknowledge barrier
 547                 FOREACH_CLIENT(it.isbot, LAMBDA(it.bot_barrier = 2));
 548
 549                 bot_barriertime = time;
 550         }
 551
 552         // if we get here, the barrier is finished
 553         // so end it...
 554         self.bot_barrier = 0;
 555         //self.colormod = '0 0 0';
 556
 557         return CMD_STATUS_FINISHED;
 558 }
 559
 560 float bot_cmd_turn()
 561 {SELFPARAM();
 562         self.v_angle_y = self.v_angle.y + bot_cmd.bot_cmd_parm_float;
 563         self.v_angle_y = self.v_angle.y - floor(self.v_angle.y / 360) * 360;
 564         return CMD_STATUS_FINISHED;
 565 }
 566
 567 float bot_cmd_select_weapon()
 568 {SELFPARAM();
 569         float id = bot_cmd.bot_cmd_parm_float;
 570
 571         if(id < WEP_FIRST || id > WEP_LAST)
 572                 return CMD_STATUS_ERROR;
 573
 574         if(client_hasweapon(self, Weapons_from(id), true, false))
 575                 PS(self).m_switchweapon = Weapons_from(id);
 576         else
 577                 return CMD_STATUS_ERROR;
 578
 579         return CMD_STATUS_FINISHED;
 580 }
 581
 582 .int bot_cmd_condition_status;
 583
 584 const int CMD_CONDITION_NONE = 0;
 585 const int CMD_CONDITION_true = 1;
 586 const int CMD_CONDITION_false = 2;
 587 const int CMD_CONDITION_true_BLOCK = 4;
 588 const int CMD_CONDITION_false_BLOCK = 8;
 589
 590 float bot_cmd_eval(string expr)
 591 {SELFPARAM();
 592         // Search for numbers
 593         if(strstrofs("0123456789", substring(expr, 0, 1), 0) >= 0)
 594         {
 595                 return stof(expr);
 596         }
 597
 598         // Search for cvars
 599         if(substring(expr, 0, 5)=="cvar.")
 600         {
 601                 return cvar(substring(expr, 5, strlen(expr)));
 602         }
 603
 604         // Search for fields
 605         switch(expr)
 606         {
 607                 case "health":
 608                         return self.health;
 609                 case "speed":
 610                         return vlen(self.velocity);
 611                 case "flagcarrier":
 612                         return ((self.flagcarried!=world));
 613         }
 614
 615         LOG_INFO(strcat("ERROR: Unable to convert the expression '",expr,"' into a numeric value\n"));
 616         return 0;
 617 }
 618
 619 float bot_cmd_if()
 620 {SELFPARAM();
 621         string expr, val_a, val_b;
 622         float cmpofs;
 623
 624         if(self.bot_cmd_condition_status != CMD_CONDITION_NONE)
 625         {
 626                 // Only one "if" block is allowed at time
 627                 LOG_INFO("ERROR: Only one conditional block can be processed at time");
 628                 bot_clearqueue(self);
 629                 return CMD_STATUS_ERROR;
 630         }
 631
 632         self.bot_cmd_condition_status |= CMD_CONDITION_true_BLOCK;
 633
 634         // search for operators
 635         expr = bot_cmd.bot_cmd_parm_string;
 636
 637         cmpofs = strstrofs(expr,"=",0);
 638
 639         if(cmpofs>0)
 640         {
 641                 val_a = substring(expr,0,cmpofs);
 642                 val_b = substring(expr,cmpofs+1,strlen(expr));
 643
 644                 if(bot_cmd_eval(val_a)==bot_cmd_eval(val_b))
 645                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 646                 else
 647                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 648
 649                 return CMD_STATUS_FINISHED;
 650         }
 651
 652         cmpofs = strstrofs(expr,">",0);
 653
 654         if(cmpofs>0)
 655         {
 656                 val_a = substring(expr,0,cmpofs);
 657                 val_b = substring(expr,cmpofs+1,strlen(expr));
 658
 659                 if(bot_cmd_eval(val_a)>bot_cmd_eval(val_b))
 660                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 661                 else
 662                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 663
 664                 return CMD_STATUS_FINISHED;
 665         }
 666
 667         cmpofs = strstrofs(expr,"<",0);
 668
 669         if(cmpofs>0)
 670         {
 671                 val_a = substring(expr,0,cmpofs);
 672                 val_b = substring(expr,cmpofs+1,strlen(expr));
 673
 674                 if(bot_cmd_eval(val_a)<bot_cmd_eval(val_b))
 675                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 676                 else
 677                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 678
 679                 return CMD_STATUS_FINISHED;
 680         }
 681
 682         if(bot_cmd_eval(expr))
 683                 self.bot_cmd_condition_status |= CMD_CONDITION_true;
 684         else
 685                 self.bot_cmd_condition_status |= CMD_CONDITION_false;
 686
 687         return CMD_STATUS_FINISHED;
 688 }
 689
 690 float bot_cmd_else()
 691 {SELFPARAM();
 692         self.bot_cmd_condition_status &= ~CMD_CONDITION_true_BLOCK;
 693         self.bot_cmd_condition_status |= CMD_CONDITION_false_BLOCK;
 694         return CMD_STATUS_FINISHED;
 695 }
 696
 697 float bot_cmd_fi()
 698 {SELFPARAM();
 699         self.bot_cmd_condition_status = CMD_CONDITION_NONE;
 700         return CMD_STATUS_FINISHED;
 701 }
 702
 703 float bot_cmd_resetaim()
 704 {SELFPARAM();
 705         self.v_angle = '0 0 0';
 706         return CMD_STATUS_FINISHED;
 707 }
 708
 709 .float bot_cmd_aim_begintime;
 710 .float bot_cmd_aim_endtime;
 711 .vector bot_cmd_aim_begin;
 712 .vector bot_cmd_aim_end;
 713
 714 float bot_cmd_aim()
 715 {SELFPARAM();
 716         // Current direction
 717         if(self.bot_cmd_aim_endtime)
 718         {
 719                 float progress;
 720
 721                 progress = min(1 - (self.bot_cmd_aim_endtime - time) / (self.bot_cmd_aim_endtime - self.bot_cmd_aim_begintime),1);
 722                 self.v_angle = self.bot_cmd_aim_begin + ((self.bot_cmd_aim_end - self.bot_cmd_aim_begin) * progress);
 723
 724                 if(time>=self.bot_cmd_aim_endtime)
 725                 {
 726                         self.bot_cmd_aim_endtime = 0;
 727                         return CMD_STATUS_FINISHED;
 728                 }
 729                 else
 730                         return CMD_STATUS_EXECUTING;
 731         }
 732
 733         // New aiming direction
 734         string parms;
 735         float tokens, step;
 736
 737         parms = bot_cmd.bot_cmd_parm_string;
 738
 739         tokens = tokenizebyseparator(parms, " ");
 740
 741         if(tokens<2||tokens>3)
 742                 return CMD_STATUS_ERROR;
 743
 744         step = (tokens == 3) ? stof(argv(2)) : 0;
 745
 746         if(step == 0)
 747         {
 748                 self.v_angle_x -= stof(argv(1));
 749                 self.v_angle_y += stof(argv(0));
 750                 return CMD_STATUS_FINISHED;
 751         }
 752
 753         self.bot_cmd_aim_begin = self.v_angle;
 754
 755         self.bot_cmd_aim_end_x = self.v_angle.x - stof(argv(1));
 756         self.bot_cmd_aim_end_y = self.v_angle.y + stof(argv(0));
 757         self.bot_cmd_aim_end_z = 0;
 758
 759         self.bot_cmd_aim_begintime = time;
 760         self.bot_cmd_aim_endtime = time + step;
 761
 762         return CMD_STATUS_EXECUTING;
 763 }
 764
 765 float bot_cmd_aimtarget()
 766 {SELFPARAM();
 767         if(self.bot_cmd_aim_endtime)
 768         {
 769                 return bot_cmd_aim();
 770         }
 771
 772         entity e;
 773         string parms;
 774         vector v;
 775         float tokens, step;
 776
 777         parms = bot_cmd.bot_cmd_parm_string;
 778
 779         tokens = tokenizebyseparator(parms, " ");
 780
 781         e = bot_getplace(argv(0));
 782         if(!e)
 783                 return CMD_STATUS_ERROR;
 784
 785         v = e.origin + (e.mins + e.maxs) * 0.5;
 786
 787         if(tokens==1)
 788         {
 789                 self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 790                 self.v_angle_x = -self.v_angle.x;
 791                 return CMD_STATUS_FINISHED;
 792         }
 793
 794         if(tokens<1||tokens>2)
 795                 return CMD_STATUS_ERROR;
 796
 797         step = stof(argv(1));
 798
 799         self.bot_cmd_aim_begin = self.v_angle;
 800         self.bot_cmd_aim_end = vectoangles(v - (self.origin + self.view_ofs));
 801         self.bot_cmd_aim_end_x = -self.bot_cmd_aim_end.x;
 802
 803         self.bot_cmd_aim_begintime = time;
 804         self.bot_cmd_aim_endtime = time + step;
 805
 806         return CMD_STATUS_EXECUTING;
 807 }
 808
 809 .int bot_cmd_keys;
 810
 811 const int BOT_CMD_KEY_NONE              = 0;
 812 const int BOT_CMD_KEY_FORWARD   = BIT(0);
 813 const int BOT_CMD_KEY_BACKWARD  = BIT(1);
 814 const int BOT_CMD_KEY_RIGHT     = BIT(2);
 815 const int BOT_CMD_KEY_LEFT              = BIT(3);
 816 const int BOT_CMD_KEY_JUMP              = BIT(4);
 817 const int BOT_CMD_KEY_ATTACK1   = BIT(5);
 818 const int BOT_CMD_KEY_ATTACK2   = BIT(6);
 819 const int BOT_CMD_KEY_USE               = BIT(7);
 820 const int BOT_CMD_KEY_HOOK              = BIT(8);
 821 const int BOT_CMD_KEY_CROUCH    = BIT(9);
 822 const int BOT_CMD_KEY_CHAT              = BIT(10);
 823
 824 float bot_presskeys()
 825 {SELFPARAM();
 826         self.movement = '0 0 0';
 827         self.BUTTON_JUMP = false;
 828         self.BUTTON_CROUCH = false;
 829         self.BUTTON_ATCK = false;
 830         self.BUTTON_ATCK2 = false;
 831         self.BUTTON_USE = false;
 832         self.BUTTON_HOOK = false;
 833         self.BUTTON_CHAT = false;
 834
 835         if(self.bot_cmd_keys == BOT_CMD_KEY_NONE)
 836                 return false;
 837
 838         if(self.bot_cmd_keys & BOT_CMD_KEY_FORWARD)
 839                 self.movement_x = autocvar_sv_maxspeed;
 840         else if(self.bot_cmd_keys & BOT_CMD_KEY_BACKWARD)
 841                 self.movement_x = -autocvar_sv_maxspeed;
 842
 843         if(self.bot_cmd_keys & BOT_CMD_KEY_RIGHT)
 844                 self.movement_y = autocvar_sv_maxspeed;
 845         else if(self.bot_cmd_keys & BOT_CMD_KEY_LEFT)
 846                 self.movement_y = -autocvar_sv_maxspeed;
 847
 848         if(self.bot_cmd_keys & BOT_CMD_KEY_JUMP)
 849                 self.BUTTON_JUMP = true;
 850
 851         if(self.bot_cmd_keys & BOT_CMD_KEY_CROUCH)
 852                 self.BUTTON_CROUCH = true;
 853
 854         if(self.bot_cmd_keys & BOT_CMD_KEY_ATTACK1)
 855                 self.BUTTON_ATCK = true;
 856
 857         if(self.bot_cmd_keys & BOT_CMD_KEY_ATTACK2)
 858                 self.BUTTON_ATCK2 = true;
 859
 860         if(self.bot_cmd_keys & BOT_CMD_KEY_USE)
 861                 self.BUTTON_USE = true;
 862
 863         if(self.bot_cmd_keys & BOT_CMD_KEY_HOOK)
 864                 self.BUTTON_HOOK = true;
 865
 866         if(self.bot_cmd_keys & BOT_CMD_KEY_CHAT)
 867                 self.BUTTON_CHAT = true;
 868
 869         return true;
 870 }
 871
 872
 873 float bot_cmd_keypress_handler(string key, float enabled)
 874 {SELFPARAM();
 875         switch(key)
 876         {
 877                 case "all":
 878                         if(enabled)
 879                                 self.bot_cmd_keys = power2of(20) - 1; // >:)
 880                         else
 881                                 self.bot_cmd_keys = BOT_CMD_KEY_NONE;
 882                 case "forward":
 883                         if(enabled)
 884                         {
 885                                 self.bot_cmd_keys |= BOT_CMD_KEY_FORWARD;
 886                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 887                         }
 888                         else
 889                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 890                         break;
 891                 case "backward":
 892                         if(enabled)
 893                         {
 894                                 self.bot_cmd_keys |= BOT_CMD_KEY_BACKWARD;
 895                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 896                         }
 897                         else
 898                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 899                         break;
 900                 case "left":
 901                         if(enabled)
 902                         {
 903                                 self.bot_cmd_keys |= BOT_CMD_KEY_LEFT;
 904                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 905                         }
 906                         else
 907                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 908                         break;
 909                 case "right":
 910                         if(enabled)
 911                         {
 912                                 self.bot_cmd_keys |= BOT_CMD_KEY_RIGHT;
 913                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 914                         }
 915                         else
 916                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 917                         break;
 918                 case "jump":
 919                         if(enabled)
 920                                 self.bot_cmd_keys |= BOT_CMD_KEY_JUMP;
 921                         else
 922                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_JUMP;
 923                         break;
 924                 case "crouch":
 925                         if(enabled)
 926                                 self.bot_cmd_keys |= BOT_CMD_KEY_CROUCH;
 927                         else
 928                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_CROUCH;
 929                         break;
 930                 case "attack1":
 931                         if(enabled)
 932                                 self.bot_cmd_keys |= BOT_CMD_KEY_ATTACK1;
 933                         else
 934                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK1;
 935                         break;
 936                 case "attack2":
 937                         if(enabled)
 938                                 self.bot_cmd_keys |= BOT_CMD_KEY_ATTACK2;
 939                         else
 940                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK2;
 941                         break;
 942                 case "use":
 943                         if(enabled)
 944                                 self.bot_cmd_keys |= BOT_CMD_KEY_USE;
 945                         else
 946                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_USE;
 947                         break;
 948                 case "hook":
 949                         if(enabled)
 950                                 self.bot_cmd_keys |= BOT_CMD_KEY_HOOK;
 951                         else
 952                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_HOOK;
 953                         break;
 954                 case "chat":
 955                         if(enabled)
 956                                 self.bot_cmd_keys |= BOT_CMD_KEY_CHAT;
 957                         else
 958                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_CHAT;
 959                         break;
 960                 default:
 961                         break;
 962         }
 963
 964         return CMD_STATUS_FINISHED;
 965 }
 966
 967 float bot_cmd_presskey()
 968 {
 969         string key;
 970
 971         key = bot_cmd.bot_cmd_parm_string;
 972
 973         bot_cmd_keypress_handler(key,true);
 974
 975         return CMD_STATUS_FINISHED;
 976 }
 977
 978 float bot_cmd_releasekey()
 979 {
 980         string key;
 981
 982         key = bot_cmd.bot_cmd_parm_string;
 983
 984         return bot_cmd_keypress_handler(key,false);
 985 }
 986
 987 float bot_cmd_pause()
 988 {SELFPARAM();
 989         self.button1        = 0;
 990         self.button8        = 0;
 991         self.BUTTON_USE     = 0;
 992         self.BUTTON_ATCK    = 0;
 993         self.BUTTON_JUMP    = 0;
 994         self.BUTTON_HOOK    = 0;
 995         self.BUTTON_CHAT    = 0;
 996         self.BUTTON_ATCK2   = 0;
 997         self.BUTTON_CROUCH  = 0;
 998
 999         self.movement = '0 0 0';
1000         self.bot_cmd_keys = BOT_CMD_KEY_NONE;
1001
1002         self.bot_exec_status |= BOT_EXEC_STATUS_PAUSED;
1003         return CMD_STATUS_FINISHED;
1004 }
1005
1006 float bot_cmd_moveto()
1007 {SELFPARAM();
1008         return self.cmd_moveto(bot_cmd.bot_cmd_parm_vector);
1009 }
1010
1011 float bot_cmd_movetotarget()
1012 {SELFPARAM();
1013         entity e;
1014         e = bot_getplace(bot_cmd.bot_cmd_parm_string);
1015         if(!e)
1016                 return CMD_STATUS_ERROR;
1017         return self.cmd_moveto(e.origin + (e.mins + e.maxs) * 0.5);
1018 }
1019
1020 float bot_cmd_resetgoal()
1021 {SELFPARAM();
1022         return self.cmd_resetgoal();
1023 }
1024
1025
1026 float bot_cmd_sound()
1027 {SELFPARAM();
1028         string f;
1029         f = bot_cmd.bot_cmd_parm_string;
1030
1031         float n = tokenizebyseparator(f, " ");
1032
1033         string sample = f;
1034         float chan = CH_WEAPON_B;
1035         float vol = VOL_BASE;
1036         float atten = ATTEN_MIN;
1037
1038         if(n >= 1)
1039                 sample = argv(n - 1);
1040         if(n >= 2)
1041                 chan = stof(argv(0));
1042         if(n >= 3)
1043                 vol = stof(argv(1));
1044         if(n >= 4)
1045                 atten = stof(argv(2));
1046
1047         precache_sound(f);
1048         _sound(self, chan, sample, vol, atten);
1049
1050         return CMD_STATUS_FINISHED;
1051 }
1052
1053 .entity tuba_note;
1054 float bot_cmd_debug_assert_canfire()
1055 {SELFPARAM();
1056         float f = bot_cmd.bot_cmd_parm_float;
1057
1058         int slot = 0;
1059         .entity weaponentity = weaponentities[slot];
1060         if(self.(weaponentity).state != WS_READY)
1061         {
1062                 if(f)
1063                 {
1064                         self.colormod = '0 8 8';
1065                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, inhibited by weaponentity state\n");
1066                 }
1067         }
1068         else if(ATTACK_FINISHED(self, slot) > time)
1069         {
1070                 if(f)
1071                 {
1072                         self.colormod = '8 0 8';
1073                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, inhibited by ATTACK_FINISHED (", ftos(ATTACK_FINISHED(self, slot) - time), " seconds left)\n");
1074                 }
1075         }
1076         else if(self.tuba_note)
1077         {
1078                 if(f)
1079                 {
1080                         self.colormod = '8 0 0';
1081                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, bot still has an active tuba note\n");
1082                 }
1083         }
1084         else
1085         {
1086                 if(!f)
1087                 {
1088                         self.colormod = '8 8 0';
1089                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " thinks it has fired, but apparently did not; ATTACK_FINISHED says ", ftos(ATTACK_FINISHED(self, slot) - time), " seconds left\n");
1090                 }
1091         }
1092
1093         return CMD_STATUS_FINISHED;
1094 }
1095
1096 //
1097
1098 void bot_command_executed(float rm)
1099 {SELFPARAM();
1100         entity cmd;
1101
1102         cmd = bot_cmd;
1103
1104         if(rm)
1105                 bot_dequeuecommand(self, self.bot_cmd_execution_index);
1106
1107         self.bot_cmd_execution_index++;
1108 }
1109
1110 void bot_setcurrentcommand()
1111 {SELFPARAM();
1112         bot_cmd = world;
1113
1114         if(!self.bot_cmd_current)
1115         {
1116                 self.bot_cmd_current = new(bot_cmd);
1117                 self.bot_cmd_current.is_bot_cmd = true;
1118         }
1119
1120         bot_cmd = self.bot_cmd_current;
1121         if(bot_cmd.bot_cmd_index != self.bot_cmd_execution_index || self.bot_cmd_execution_index == 0)
1122         {
1123                 if(bot_havecommand(self, self.bot_cmd_execution_index))
1124                 {
1125                         string cmdstring;
1126                         cmdstring = bot_readcommand(self, self.bot_cmd_execution_index);
1127                         if(bot_decodecommand(cmdstring))
1128                         {
1129                                 bot_cmd.owner = self;
1130                                 bot_cmd.bot_cmd_index = self.bot_cmd_execution_index;
1131                         }
1132                         else
1133                         {
1134                                 // Invalid command, remove from queue
1135                                 bot_cmd = world;
1136                                 bot_dequeuecommand(self, self.bot_cmd_execution_index);
1137                                 self.bot_cmd_execution_index++;
1138                         }
1139                 }
1140                 else
1141                         bot_cmd = world;
1142         }
1143 }
1144
1145 void bot_resetqueues()
1146 {
1147         FOREACH_CLIENT(it.isbot, LAMBDA(
1148                 it.bot_cmd_execution_index = 0;
1149                 bot_clearqueue(it);
1150                 // also, cancel all barriers
1151                 it.bot_barrier = 0;
1152                 for(int i = 0; i < it.bot_places_count; ++i)
1153                 {
1154                         strunzone(it.(bot_placenames[i]));
1155                         it.(bot_placenames[i]) = string_null;
1156                 }
1157                 it.bot_places_count = 0;
1158         ));
1159
1160         bot_barriertime = time;
1161 }
1162
1163 // Here we map commands to functions and deal with complex interactions between commands and execution states
1164 // NOTE: Of course you need to include your commands here too :)
1165 float bot_execute_commands_once()
1166 {SELFPARAM();
1167         float status, ispressingkey;
1168
1169         // Find command
1170         bot_setcurrentcommand();
1171
1172         // if we have no bot command, better return
1173         // old logic kept pressing previously pressed keys, but that has problems
1174         // (namely, it means you cannot make a bot "normal" ever again)
1175         // to keep a bot walking for a while, use the "wait" bot command
1176         if(bot_cmd == world)
1177                 return false;
1178
1179         // Ignore all commands except continue when the bot is paused
1180         if(self.bot_exec_status & BOT_EXEC_STATUS_PAUSED)
1181         if(bot_cmd.bot_cmd_type!=BOT_CMD_CONTINUE)
1182         {
1183                 if(bot_cmd.bot_cmd_type!=BOT_CMD_NULL)
1184                 {
1185                         bot_command_executed(true);
1186                         LOG_INFO( "WARNING: Commands are ignored while the bot is paused. Use the command 'continue' instead.\n");
1187                 }
1188                 return 1;
1189         }
1190
1191         // Keep pressing keys raised by the "presskey" command
1192         ispressingkey = boolean(bot_presskeys());
1193
1194         // Handle conditions
1195         if (!(bot_cmd.bot_cmd_type==BOT_CMD_FI||bot_cmd.bot_cmd_type==BOT_CMD_ELSE))
1196         if(self.bot_cmd_condition_status & CMD_CONDITION_true && self.bot_cmd_condition_status & CMD_CONDITION_false_BLOCK)
1197         {
1198                 bot_command_executed(true);
1199                 return -1;
1200         }
1201         else if(self.bot_cmd_condition_status & CMD_CONDITION_false && self.bot_cmd_condition_status & CMD_CONDITION_true_BLOCK)
1202         {
1203                 bot_command_executed(true);
1204                 return -1;
1205         }
1206
1207         // Map commands to functions
1208         switch(bot_cmd.bot_cmd_type)
1209         {
1210                 case BOT_CMD_NULL:
1211                         return ispressingkey;
1212                         //break;
1213                 case BOT_CMD_PAUSE:
1214                         status = bot_cmd_pause();
1215                         break;
1216                 case BOT_CMD_CONTINUE:
1217                         status = bot_cmd_continue();
1218                         break;
1219                 case BOT_CMD_WAIT:
1220                         status = bot_cmd_wait();
1221                         break;
1222                 case BOT_CMD_WAIT_UNTIL:
1223                         status = bot_cmd_wait_until();
1224                         break;
1225                 case BOT_CMD_TURN:
1226                         status = bot_cmd_turn();
1227                         break;
1228                 case BOT_CMD_MOVETO:
1229                         status = bot_cmd_moveto();
1230                         break;
1231                 case BOT_CMD_MOVETOTARGET:
1232                         status = bot_cmd_movetotarget();
1233                         break;
1234                 case BOT_CMD_RESETGOAL:
1235                         status = bot_cmd_resetgoal();
1236                         break;
1237                 case BOT_CMD_CC:
1238                         status = bot_cmd_cc();
1239                         break;
1240                 case BOT_CMD_IF:
1241                         status = bot_cmd_if();
1242                         break;
1243                 case BOT_CMD_ELSE:
1244                         status = bot_cmd_else();
1245                         break;
1246                 case BOT_CMD_FI:
1247                         status = bot_cmd_fi();
1248                         break;
1249                 case BOT_CMD_RESETAIM:
1250                         status = bot_cmd_resetaim();
1251                         break;
1252                 case BOT_CMD_AIM:
1253                         status = bot_cmd_aim();
1254                         break;
1255                 case BOT_CMD_AIMTARGET:
1256                         status = bot_cmd_aimtarget();
1257                         break;
1258                 case BOT_CMD_PRESSKEY:
1259                         status = bot_cmd_presskey();
1260                         break;
1261                 case BOT_CMD_RELEASEKEY:
1262                         status = bot_cmd_releasekey();
1263                         break;
1264                 case BOT_CMD_SELECTWEAPON:
1265                         status = bot_cmd_select_weapon();
1266                         break;
1267                 case BOT_CMD_IMPULSE:
1268                         status = bot_cmd_impulse();
1269                         break;
1270                 case BOT_CMD_BARRIER:
1271                         status = bot_cmd_barrier();
1272                         break;
1273                 case BOT_CMD_CONSOLE:
1274                         localcmd(strcat(bot_cmd.bot_cmd_parm_string, "\n"));
1275                         status = CMD_STATUS_FINISHED;
1276                         break;
1277                 case BOT_CMD_SOUND:
1278                         status = bot_cmd_sound();
1279                         break;
1280                 case BOT_CMD_DEBUG_ASSERT_CANFIRE:
1281                         status = bot_cmd_debug_assert_canfire();
1282                         break;
1283                 default:
1284                         LOG_INFO(strcat("ERROR: Invalid command on queue with id '",ftos(bot_cmd.bot_cmd_type),"'\n"));
1285                         return 0;
1286         }
1287
1288         if (status==CMD_STATUS_ERROR)
1289                 LOG_INFO(strcat("ERROR: The command '",bot_cmd_string[bot_cmd.bot_cmd_type],"' returned an error status\n"));
1290
1291         // Move execution pointer
1292         if(status==CMD_STATUS_EXECUTING)
1293         {
1294                 return 1;
1295         }
1296         else
1297         {
1298                 if(autocvar_g_debug_bot_commands)
1299                 {
1300                         string parms;
1301
1302                         switch(bot_cmd_parm_type[bot_cmd.bot_cmd_type])
1303                         {
1304                                 case BOT_CMD_PARAMETER_FLOAT:
1305                                         parms = ftos(bot_cmd.bot_cmd_parm_float);
1306                                         break;
1307                                 case BOT_CMD_PARAMETER_STRING:
1308                                         parms = bot_cmd.bot_cmd_parm_string;
1309                                         break;
1310                                 case BOT_CMD_PARAMETER_VECTOR:
1311                                         parms = vtos(bot_cmd.bot_cmd_parm_vector);
1312                                         break;
1313                                 default:
1314                                         parms = "";
1315                                         break;
1316                         }
1317                         clientcommand(self,strcat("say ^7", bot_cmd_string[bot_cmd.bot_cmd_type]," ",parms,"\n"));
1318                 }
1319
1320                 bot_command_executed(true);
1321         }
1322
1323         if(status == CMD_STATUS_FINISHED)
1324                 return -1;
1325
1326         return CMD_STATUS_ERROR;
1327 }
1328
1329 // This function should be (the only) called directly from the bot ai loop
1330 float bot_execute_commands()
1331 {
1332         float f;
1333         do
1334         {
1335                 f = bot_execute_commands_once();
1336         }
1337         while(f < 0);
1338         return f;
1339 }