qcsrc/server/bot/waypoints.qc

   1 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
   2 // them back to it as well
   3 // (suitable for spawnfunc_waypoint editor)
   4 entity waypoint_spawn(vector m1, vector m2, float f)
   5 {
   6         entity w;
   7         w = find(world, classname, "waypoint");
   8
   9         if (!(f & WAYPOINTFLAG_PERSONAL))
  10         while (w)
  11         {
  12                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  13                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  14                         return w;
  15                 w = find(w, classname, "waypoint");
  16         }
  17
  18         w = spawn();
  19         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  20         w.classname = "waypoint";
  21         w.wpflags = f;
  22         setorigin(w, (m1 + m2) * 0.5);
  23         setsize(w, m1 - w.origin, m2 - w.origin);
  24         if (vlen(w.size) > 0)
  25                 w.wpisbox = TRUE;
  26
  27         if(!w.wpisbox)
  28         {
  29                 setsize(w, PL_MIN - '1 1 0', PL_MAX + '1 1 0');
  30                 if(!move_out_of_solid(w))
  31                 {
  32                         if(!(f & WAYPOINTFLAG_GENERATED))
  33                         {
  34                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  35                                 remove(w);
  36                                 return world;
  37                         }
  38                         else
  39                         {
  40                                 if(autocvar_developer)
  41                                 {
  42                                         print("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  43                                         backtrace("Waypoint stuck");
  44                                 }
  45                         }
  46                 }
  47                 setsize(w, '0 0 0', '0 0 0');
  48         }
  49
  50         waypoint_clearlinks(w);
  51         //waypoint_schedulerelink(w);
  52
  53         if (autocvar_g_waypointeditor)
  54         {
  55                 m1 = w.mins;
  56                 m2 = w.maxs;
  57                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
  58                 setsize(w, m1, m2);
  59                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  60                         w.colormod = '1 0 0';
  61                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  62                         w.colormod = '1 1 0';
  63                 else
  64                         w.colormod = '1 1 1';
  65         }
  66         else
  67                 w.model = "";
  68
  69         return w;
  70 }
  71
  72 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  73 void waypoint_addlink(entity from, entity to)
  74 {
  75         float c;
  76
  77         if (from == to)
  78                 return;
  79         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  80                 return;
  81
  82         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  83         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  84         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  85         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  86         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  87         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
  88         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
  89         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
  90
  91         if (to.wpisbox || from.wpisbox)
  92         {
  93                 // if either is a box we have to find the nearest points on them to
  94                 // calculate the distance properly
  95                 vector v1, v2, m1, m2;
  96                 v1 = from.origin;
  97                 m1 = to.absmin;
  98                 m2 = to.absmax;
  99                 v1_x = bound(m1_x, v1_x, m2_x);
 100                 v1_y = bound(m1_y, v1_y, m2_y);
 101                 v1_z = bound(m1_z, v1_z, m2_z);
 102                 v2 = to.origin;
 103                 m1 = from.absmin;
 104                 m2 = from.absmax;
 105                 v2_x = bound(m1_x, v2_x, m2_x);
 106                 v2_y = bound(m1_y, v2_y, m2_y);
 107                 v2_z = bound(m1_z, v2_z, m2_z);
 108                 v2 = to.origin;
 109                 c = vlen(v2 - v1);
 110         }
 111         else
 112                 c = vlen(to.origin - from.origin);
 113
 114         if (from.wp31mincost < c) return;
 115         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 116         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 117         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 118         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 119         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 120         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 121         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 122         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 123         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 124         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 125         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 126         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 127         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 128         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 129         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 130         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 131         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 132         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 133         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 134         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 135         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 136         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 137         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 138         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 139         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 140         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 141         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 142         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 143         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 144         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 145         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 146         from.wp00 = to;from.wp00mincost = c;return;
 147 }
 148
 149 // relink this spawnfunc_waypoint
 150 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 151 // (SLOW!)
 152 void waypoint_think()
 153 {
 154         entity e;
 155         vector sv, sm1, sm2, ev, em1, em2, dv;
 156
 157         bot_calculate_stepheightvec();
 158
 159         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 160
 161         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 162         sm1 = self.origin + self.mins;
 163         sm2 = self.origin + self.maxs;
 164         for(e = world; (e = find(e, classname, "waypoint")); )
 165         {
 166                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 167                 {
 168                         waypoint_addlink(self, e);
 169                         waypoint_addlink(e, self);
 170                 }
 171                 else
 172                 {
 173                         ++relink_total;
 174                         if(!checkpvs(self.origin, e))
 175                         {
 176                                 ++relink_pvsculled;
 177                                 continue;
 178                         }
 179                         sv = e.origin;
 180                         sv_x = bound(sm1_x, sv_x, sm2_x);
 181                         sv_y = bound(sm1_y, sv_y, sm2_y);
 182                         sv_z = bound(sm1_z, sv_z, sm2_z);
 183                         ev = self.origin;
 184                         em1 = e.origin + e.mins;
 185                         em2 = e.origin + e.maxs;
 186                         ev_x = bound(em1_x, ev_x, em2_x);
 187                         ev_y = bound(em1_y, ev_y, em2_y);
 188                         ev_z = bound(em1_z, ev_z, em2_z);
 189                         dv = ev - sv;
 190                         dv_z = 0;
 191                         if (vlen(dv) >= 1050) // max search distance in XY
 192                         {
 193                                 ++relink_lengthculled;
 194                                 continue;
 195                         }
 196                         navigation_testtracewalk = 0;
 197                         if (!self.wpisbox)
 198                         {
 199                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 200                                 if (!trace_startsolid)
 201                                 {
 202                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 203                                         sv = trace_endpos + '0 0 1';
 204                                 }
 205                         }
 206                         if (!e.wpisbox)
 207                         {
 208                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 209                                 if (!trace_startsolid)
 210                                 {
 211                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 212                                         ev = trace_endpos + '0 0 1';
 213                                 }
 214                         }
 215                         //traceline(self.origin, e.origin, FALSE, world);
 216                         //if (trace_fraction == 1)
 217                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 218                                 waypoint_addlink(self, e);
 219                         else
 220                                 relink_walkculled += 0.5;
 221                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 222                                 waypoint_addlink(e, self);
 223                         else
 224                                 relink_walkculled += 0.5;
 225                 }
 226         }
 227         navigation_testtracewalk = 0;
 228         self.wplinked = TRUE;
 229 }
 230
 231 void waypoint_clearlinks(entity wp)
 232 {
 233         // clear links to other waypoints
 234         float f;
 235         f = 10000000;
 236         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 237         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 238         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 239         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 240
 241         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 242         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 243         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 244         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 245
 246         wp.wplinked = FALSE;
 247 }
 248
 249 // tell a spawnfunc_waypoint to relink
 250 void waypoint_schedulerelink(entity wp)
 251 {
 252         if (wp == world)
 253                 return;
 254         // TODO: add some sort of visible box in edit mode for box waypoints
 255         if (autocvar_g_waypointeditor)
 256         {
 257                 vector m1, m2;
 258                 m1 = wp.mins;
 259                 m2 = wp.maxs;
 260                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 261                 setsize(wp, m1, m2);
 262                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 263                         wp.colormod = '1 0 0';
 264                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 265                         wp.colormod = '1 1 0';
 266                 else
 267                         wp.colormod = '1 1 1';
 268         }
 269         else
 270                 wp.model = "";
 271         wp.wpisbox = vlen(wp.size) > 0;
 272         wp.enemy = world;
 273         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 274                 wp.owner = world;
 275         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 276                 waypoint_clearlinks(wp);
 277         // schedule an actual relink on next frame
 278         wp.think = waypoint_think;
 279         wp.nextthink = time;
 280         wp.effects = EF_LOWPRECISION;
 281 }
 282
 283 // spawnfunc_waypoint map entity
 284 void spawnfunc_waypoint()
 285 {
 286         setorigin(self, self.origin);
 287         // schedule a relink after other waypoints have had a chance to spawn
 288         waypoint_clearlinks(self);
 289         //waypoint_schedulerelink(self);
 290 }
 291
 292 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 293 void waypoint_remove(entity e)
 294 {
 295         // tell all linked waypoints that they need to relink
 296         waypoint_schedulerelink(e.wp00);
 297         waypoint_schedulerelink(e.wp01);
 298         waypoint_schedulerelink(e.wp02);
 299         waypoint_schedulerelink(e.wp03);
 300         waypoint_schedulerelink(e.wp04);
 301         waypoint_schedulerelink(e.wp05);
 302         waypoint_schedulerelink(e.wp06);
 303         waypoint_schedulerelink(e.wp07);
 304         waypoint_schedulerelink(e.wp08);
 305         waypoint_schedulerelink(e.wp09);
 306         waypoint_schedulerelink(e.wp10);
 307         waypoint_schedulerelink(e.wp11);
 308         waypoint_schedulerelink(e.wp12);
 309         waypoint_schedulerelink(e.wp13);
 310         waypoint_schedulerelink(e.wp14);
 311         waypoint_schedulerelink(e.wp15);
 312         waypoint_schedulerelink(e.wp16);
 313         waypoint_schedulerelink(e.wp17);
 314         waypoint_schedulerelink(e.wp18);
 315         waypoint_schedulerelink(e.wp19);
 316         waypoint_schedulerelink(e.wp20);
 317         waypoint_schedulerelink(e.wp21);
 318         waypoint_schedulerelink(e.wp22);
 319         waypoint_schedulerelink(e.wp23);
 320         waypoint_schedulerelink(e.wp24);
 321         waypoint_schedulerelink(e.wp25);
 322         waypoint_schedulerelink(e.wp26);
 323         waypoint_schedulerelink(e.wp27);
 324         waypoint_schedulerelink(e.wp28);
 325         waypoint_schedulerelink(e.wp29);
 326         waypoint_schedulerelink(e.wp30);
 327         waypoint_schedulerelink(e.wp31);
 328         // and now remove the spawnfunc_waypoint
 329         remove(e);
 330 }
 331
 332 // empties the map of waypoints
 333 void waypoint_removeall()
 334 {
 335         entity head, next;
 336         head = findchain(classname, "waypoint");
 337         while (head)
 338         {
 339                 next = head.chain;
 340                 remove(head);
 341                 head = next;
 342         }
 343 }
 344
 345 // tell all waypoints to relink
 346 // (is this useful at all?)
 347 void waypoint_schedulerelinkall()
 348 {
 349         entity head;
 350         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 351         head = findchain(classname, "waypoint");
 352         while (head)
 353         {
 354                 waypoint_schedulerelink(head);
 355                 head = head.chain;
 356         }
 357 }
 358
 359 // Load waypoint links from file
 360 float waypoint_load_links()
 361 {
 362         string filename, s;
 363         float file, tokens, c = 0, found;
 364         entity wp_from = world, wp_to;
 365         vector wp_to_pos, wp_from_pos;
 366         filename = strcat("maps/", mapname);
 367         filename = strcat(filename, ".waypoints.cache");
 368         file = fopen(filename, FILE_READ);
 369
 370         if (file < 0)
 371         {
 372                 dprint("waypoint links load from ");
 373                 dprint(filename);
 374                 dprint(" failed\n");
 375                 return FALSE;
 376         }
 377
 378         while ((s = fgets(file)))
 379         {
 380                 tokens = tokenizebyseparator(s, "*");
 381
 382                 if (tokens!=2)
 383                 {
 384                         // bad file format
 385                         fclose(file);
 386                         return FALSE;
 387                 }
 388
 389                 wp_from_pos     = stov(argv(0));
 390                 wp_to_pos       = stov(argv(1));
 391
 392                 // Search "from" waypoint
 393                 if(!wp_from || wp_from.origin!=wp_from_pos)
 394                 {
 395                         wp_from = findradius(wp_from_pos, 1);
 396                         found = FALSE;
 397                         while(wp_from)
 398                         {
 399                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 400                                 if(wp_from.classname == "waypoint")
 401                                 {
 402                                         found = TRUE;
 403                                         break;
 404                                 }
 405                                 wp_from = wp_from.chain;
 406                         }
 407
 408                         if(!found)
 409                         {
 410                                 dprint("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 411                                 continue;
 412                         }
 413
 414                 }
 415
 416                 // Search "to" waypoint
 417                 wp_to = findradius(wp_to_pos, 1);
 418                 found = FALSE;
 419                 while(wp_to)
 420                 {
 421                         if(vlen(wp_to.origin-wp_to_pos)<1)
 422                         if(wp_to.classname == "waypoint")
 423                         {
 424                                 found = TRUE;
 425                                 break;
 426                         }
 427                         wp_to = wp_to.chain;
 428                 }
 429
 430                 if(!found)
 431                 {
 432                         dprint("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 433                         continue;
 434                 }
 435
 436                 ++c;
 437                 waypoint_addlink(wp_from, wp_to);
 438         }
 439
 440         fclose(file);
 441
 442         dprint("loaded ");
 443         dprint(ftos(c));
 444         dprint(" waypoint links from maps/");
 445         dprint(mapname);
 446         dprint(".waypoints.cache\n");
 447
 448         botframe_cachedwaypointlinks = TRUE;
 449         return TRUE;
 450 }
 451
 452 void waypoint_load_links_hardwired()
 453 {
 454         string filename, s;
 455         float file, tokens, c = 0, found;
 456         entity wp_from = world, wp_to;
 457         vector wp_to_pos, wp_from_pos;
 458         filename = strcat("maps/", mapname);
 459         filename = strcat(filename, ".waypoints.hardwired");
 460         file = fopen(filename, FILE_READ);
 461
 462         botframe_loadedforcedlinks = TRUE;
 463
 464         if (file < 0)
 465         {
 466                 dprint("waypoint links load from ");
 467                 dprint(filename);
 468                 dprint(" failed\n");
 469                 return;
 470         }
 471
 472         while ((s = fgets(file)))
 473         {
 474                 if(substring(s, 0, 2)=="//")
 475                         continue;
 476
 477                 if(substring(s, 0, 1)=="#")
 478                         continue;
 479
 480                 tokens = tokenizebyseparator(s, "*");
 481
 482                 if (tokens!=2)
 483                         continue;
 484
 485                 wp_from_pos     = stov(argv(0));
 486                 wp_to_pos       = stov(argv(1));
 487
 488                 // Search "from" waypoint
 489                 if(!wp_from || wp_from.origin!=wp_from_pos)
 490                 {
 491                         wp_from = findradius(wp_from_pos, 5);
 492                         found = FALSE;
 493                         while(wp_from)
 494                         {
 495                                 if(vlen(wp_from.origin-wp_from_pos)<5)
 496                                 if(wp_from.classname == "waypoint")
 497                                 {
 498                                         found = TRUE;
 499                                         break;
 500                                 }
 501                                 wp_from = wp_from.chain;
 502                         }
 503
 504                         if(!found)
 505                         {
 506                                 print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 507                                 continue;
 508                         }
 509                 }
 510
 511                 // Search "to" waypoint
 512                 wp_to = findradius(wp_to_pos, 5);
 513                 found = FALSE;
 514                 while(wp_to)
 515                 {
 516                         if(vlen(wp_to.origin-wp_to_pos)<5)
 517                         if(wp_to.classname == "waypoint")
 518                         {
 519                                 found = TRUE;
 520                                 break;
 521                         }
 522                         wp_to = wp_to.chain;
 523                 }
 524
 525                 if(!found)
 526                 {
 527                         print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 528                         continue;
 529                 }
 530
 531                 ++c;
 532                 waypoint_addlink(wp_from, wp_to);
 533                 wp_from.wphardwired = TRUE;
 534                 wp_to.wphardwired = TRUE;
 535         }
 536
 537         fclose(file);
 538
 539         dprint("loaded ");
 540         dprint(ftos(c));
 541         dprint(" waypoint links from maps/");
 542         dprint(mapname);
 543         dprint(".waypoints.hardwired\n");
 544 }
 545
 546 // Save all waypoint links to a file
 547 void waypoint_save_links()
 548 {
 549         string filename, s;
 550         float file, c, i;
 551         entity w, link;
 552         filename = strcat("maps/", mapname);
 553         filename = strcat(filename, ".waypoints.cache");
 554         file = fopen(filename, FILE_WRITE);
 555         if (file < 0)
 556         {
 557                 print("waypoint links save to ");
 558                 print(filename);
 559                 print(" failed\n");
 560         }
 561         c = 0;
 562         w = findchain(classname, "waypoint");
 563         while (w)
 564         {
 565                 for(i=0;i<32;++i)
 566                 {
 567                         // :S
 568                         link = world;
 569                         switch(i)
 570                         {
 571                                 //      for i in $(seq -w 0 31); do echo "case $i:link = w.wp$i; break;"; done;
 572                                 case  0:link = w.wp00; break;
 573                                 case  1:link = w.wp01; break;
 574                                 case  2:link = w.wp02; break;
 575                                 case  3:link = w.wp03; break;
 576                                 case  4:link = w.wp04; break;
 577                                 case  5:link = w.wp05; break;
 578                                 case  6:link = w.wp06; break;
 579                                 case  7:link = w.wp07; break;
 580                                 case  8:link = w.wp08; break;
 581                                 case  9:link = w.wp09; break;
 582                                 case 10:link = w.wp10; break;
 583                                 case 11:link = w.wp11; break;
 584                                 case 12:link = w.wp12; break;
 585                                 case 13:link = w.wp13; break;
 586                                 case 14:link = w.wp14; break;
 587                                 case 15:link = w.wp15; break;
 588                                 case 16:link = w.wp16; break;
 589                                 case 17:link = w.wp17; break;
 590                                 case 18:link = w.wp18; break;
 591                                 case 19:link = w.wp19; break;
 592                                 case 20:link = w.wp20; break;
 593                                 case 21:link = w.wp21; break;
 594                                 case 22:link = w.wp22; break;
 595                                 case 23:link = w.wp23; break;
 596                                 case 24:link = w.wp24; break;
 597                                 case 25:link = w.wp25; break;
 598                                 case 26:link = w.wp26; break;
 599                                 case 27:link = w.wp27; break;
 600                                 case 28:link = w.wp28; break;
 601                                 case 29:link = w.wp29; break;
 602                                 case 30:link = w.wp30; break;
 603                                 case 31:link = w.wp31; break;
 604                         }
 605
 606                         if(link==world)
 607                                 continue;
 608
 609                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 610                         fputs(file, s);
 611                         ++c;
 612                 }
 613                 w = w.chain;
 614         }
 615         fclose(file);
 616         botframe_cachedwaypointlinks = TRUE;
 617
 618         print("saved ");
 619         print(ftos(c));
 620         print(" waypoints links to maps/");
 621         print(mapname);
 622         print(".waypoints.cache\n");
 623 }
 624
 625 // save waypoints to gamedir/data/maps/mapname.waypoints
 626 void waypoint_saveall()
 627 {
 628         string filename, s;
 629         float file, c;
 630         entity w;
 631         filename = strcat("maps/", mapname);
 632         filename = strcat(filename, ".waypoints");
 633         file = fopen(filename, FILE_WRITE);
 634         if (file >= 0)
 635         {
 636                 c = 0;
 637                 w = findchain(classname, "waypoint");
 638                 while (w)
 639                 {
 640                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 641                         {
 642                                 s = strcat(vtos(w.origin + w.mins), "\n");
 643                                 s = strcat(s, vtos(w.origin + w.maxs));
 644                                 s = strcat(s, "\n");
 645                                 s = strcat(s, ftos(w.wpflags));
 646                                 s = strcat(s, "\n");
 647                                 fputs(file, s);
 648                                 c = c + 1;
 649                         }
 650                         w = w.chain;
 651                 }
 652                 fclose(file);
 653                 bprint("saved ");
 654                 bprint(ftos(c));
 655                 bprint(" waypoints to maps/");
 656                 bprint(mapname);
 657                 bprint(".waypoints\n");
 658         }
 659         else
 660         {
 661                 bprint("waypoint save to ");
 662                 bprint(filename);
 663                 bprint(" failed\n");
 664         }
 665         waypoint_save_links();
 666         botframe_loadedforcedlinks = FALSE;
 667 }
 668
 669 // load waypoints from file
 670 float waypoint_loadall()
 671 {
 672         string filename, s;
 673         float file, cwp, cwb, fl;
 674         vector m1, m2;
 675         cwp = 0;
 676         cwb = 0;
 677         filename = strcat("maps/", mapname);
 678         filename = strcat(filename, ".waypoints");
 679         file = fopen(filename, FILE_READ);
 680         if (file >= 0)
 681         {
 682                 while ((s = fgets(file)))
 683                 {
 684                         m1 = stov(s);
 685                         s = fgets(file);
 686                         if (!s)
 687                                 break;
 688                         m2 = stov(s);
 689                         s = fgets(file);
 690                         if (!s)
 691                                 break;
 692                         fl = stof(s);
 693                         waypoint_spawn(m1, m2, fl);
 694                         if (m1 == m2)
 695                                 cwp = cwp + 1;
 696                         else
 697                                 cwb = cwb + 1;
 698                 }
 699                 fclose(file);
 700                 dprint("loaded ");
 701                 dprint(ftos(cwp));
 702                 dprint(" waypoints and ");
 703                 dprint(ftos(cwb));
 704                 dprint(" wayboxes from maps/");
 705                 dprint(mapname);
 706                 dprint(".waypoints\n");
 707         }
 708         else
 709         {
 710                 dprint("waypoint load from ");
 711                 dprint(filename);
 712                 dprint(" failed\n");
 713         }
 714         return cwp + cwb;
 715 }
 716
 717 vector waypoint_fixorigin(vector position)
 718 {
 719         tracebox(position + '0 0 1' * (1 - PL_MIN_z), PL_MIN, PL_MAX, position + '0 0 -512', MOVE_NOMONSTERS, world);
 720         if(trace_fraction < 1)
 721                 position = trace_endpos;
 722         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 723         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 724         return position;
 725 }
 726
 727 void waypoint_spawnforitem_force(entity e, vector org)
 728 {
 729         entity w;
 730
 731         // Fix the waypoint altitude if necessary
 732         org = waypoint_fixorigin(org);
 733
 734         // don't spawn an item spawnfunc_waypoint if it already exists
 735         w = findchain(classname, "waypoint");
 736         while (w)
 737         {
 738                 if (w.wpisbox)
 739                 {
 740                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 741                         {
 742                                 e.nearestwaypoint = w;
 743                                 return;
 744                         }
 745                 }
 746                 else
 747                 {
 748                         if (vlen(w.origin - org) < 16)
 749                         {
 750                                 e.nearestwaypoint = w;
 751                                 return;
 752                         }
 753                 }
 754                 w = w.chain;
 755         }
 756         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 757 }
 758
 759 void waypoint_spawnforitem(entity e)
 760 {
 761         if(!bot_waypoints_for_items)
 762                 return;
 763
 764         waypoint_spawnforitem_force(e, e.origin);
 765 }
 766
 767 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 768 {
 769         entity w;
 770         entity dw;
 771         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 772         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 773         // one way link to the destination
 774         w.wp00 = dw;
 775         w.wp00mincost = timetaken; // this is just for jump pads
 776         // the teleporter's nearest spawnfunc_waypoint is this one
 777         // (teleporters are not goals, so this is probably useless)
 778         e.nearestwaypoint = w;
 779         e.nearestwaypointtimeout = time + 1000000000;
 780 }
 781
 782 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 783 {
 784         org = waypoint_fixorigin(org);
 785         destination = waypoint_fixorigin(destination);
 786         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 787 }
 788
 789 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 790 {
 791         destination = waypoint_fixorigin(destination);
 792         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 793 }
 794
 795 entity waypoint_spawnpersonal(vector position)
 796 {
 797         entity w;
 798
 799         // drop the waypoint to a proper location:
 800         //   first move it up by a player height
 801         //   then move it down to hit the floor with player bbox size
 802         position = waypoint_fixorigin(position);
 803
 804         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 805         w.nearestwaypoint = world;
 806         w.nearestwaypointtimeout = 0;
 807         w.owner = self;
 808
 809         waypoint_schedulerelink(w);
 810
 811         return w;
 812 }
 813
 814 void botframe_showwaypointlinks()
 815 {
 816         entity player, head, w;
 817         if (time < botframe_waypointeditorlightningtime)
 818                 return;
 819         botframe_waypointeditorlightningtime = time + 0.5;
 820         player = find(world, classname, "player");
 821         while (player)
 822         {
 823                 if (!player.isbot)
 824                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
 825                 {
 826                         //navigation_testtracewalk = TRUE;
 827                         head = navigation_findnearestwaypoint(player, FALSE);
 828                 //      print("currently selected WP is ", etos(head), "\n");
 829                         //navigation_testtracewalk = FALSE;
 830                         if (head)
 831                         {
 832                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
 833                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 834                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 835                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 836                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 837                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 838                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 839                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 840                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 841                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 842                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 843                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 844                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 845                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 846                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 847                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 848                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 855                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 856                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 857                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 858                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 859                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 860                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 861                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 862                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 863                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 864                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 865                         }
 866                 }
 867                 player = find(player, classname, "player");
 868         }
 869 }
 870
 871 float botframe_autowaypoints_fixdown(vector v)
 872 {
 873         tracebox(v, PL_MIN, PL_MAX, v + '0 0 -64', MOVE_NOMONSTERS, world);
 874         if(trace_fraction >= 1)
 875                 return 0;
 876         return 1;
 877 }
 878
 879 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld)
 880 {
 881         entity w;
 882
 883         w = find(world, classname, "waypoint");
 884         while (w)
 885         {
 886                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 887                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 888                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 889                         return 0;
 890                 w = find(w, classname, "waypoint");
 891         }
 892
 893         waypoint_schedulerelink(p.fld = waypoint_spawn(v, v, 0));
 894         return 1;
 895 }
 896
 897 // return value:
 898 //    1 = WP created
 899 //    0 = no action needed
 900 //   -1 = temp fail, try from world too
 901 //   -2 = permanent fail, do not retry
 902 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 903 {
 904         // make it possible to go from p to wp, if we can
 905         // if wp is world, nearest is chosen
 906
 907         entity w;
 908         vector porg;
 909         float t, tmin, tmax;
 910         vector o;
 911         vector save;
 912
 913         if(!botframe_autowaypoints_fixdown(p.origin))
 914                 return -2;
 915         porg = trace_endpos;
 916
 917         if(wp)
 918         {
 919                 // if any WP w fulfills wp -> w -> porg, then switch from wp to w
 920
 921                 // if wp -> porg, then OK
 922                 float maxdist;
 923                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 924                 {
 925                         // we may find a better one
 926                         maxdist = vlen(wp.origin - porg);
 927                 }
 928                 else
 929                 {
 930                         // accept any "good"
 931                         maxdist = 2100;
 932                 }
 933
 934                 float bestdist;
 935                 bestdist = maxdist;
 936                 w = find(world, classname, "waypoint");
 937                 while (w)
 938                 {
 939                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 940                         {
 941                                 float d;
 942                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 943                                 if(d < bestdist)
 944                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 945                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 946                                                 {
 947                                                         bestdist = d;
 948                                                         p.fld = w;
 949                                                 }
 950                         }
 951                         w = find(w, classname, "waypoint");
 952                 }
 953                 if(bestdist < maxdist)
 954                 {
 955                         print("update chain to new nearest WP ", etos(p.fld), "\n");
 956                         return 0;
 957                 }
 958
 959                 if(bestdist < 2100)
 960                 {
 961                         // we know maxdist < 2100
 962                         // so wp -> porg is still valid
 963                         // all is good
 964                         p.fld = wp;
 965                         return 0;
 966                 }
 967
 968                 // otherwise, no existing WP can fix our issues
 969         }
 970         else
 971         {
 972                 save = p.origin;
 973                 setorigin(p, porg);
 974                 w = navigation_findnearestwaypoint(p, walkfromwp);
 975                 setorigin(p, save);
 976                 if(w)
 977                 {
 978                         p.fld = w;
 979                         return 0;
 980                 }
 981         }
 982
 983         tmin = 0;
 984         tmax = 1;
 985         for(;;)
 986         {
 987                 if(tmax - tmin < 0.001)
 988                 {
 989                         // did not get a good candidate
 990                         return -1;
 991                 }
 992
 993                 t = (tmin + tmax) * 0.5;
 994                 o = antilag_takebackorigin(p, time - t);
 995                 if(!botframe_autowaypoints_fixdown(o))
 996                         return -1;
 997                 o = trace_endpos;
 998
 999                 if(wp)
1000                 {
1001                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1002                         {
1003                                 // we cannot walk from wp.origin to o
1004                                 // get closer to tmax
1005                                 tmin = t;
1006                                 continue;
1007                         }
1008                 }
1009                 else
1010                 {
1011                         save = p.origin;
1012                         setorigin(p, o);
1013                         w = navigation_findnearestwaypoint(p, walkfromwp);
1014                         setorigin(p, save);
1015                         if(!w)
1016                         {
1017                                 // we cannot walk from any WP to o
1018                                 // get closer to tmax
1019                                 tmin = t;
1020                                 continue;
1021                         }
1022                 }
1023
1024                 // if we get here, o is valid regarding waypoints
1025                 // check if o is connected right to the player
1026                 // we break if it succeeds, as that means o is a good waypoint location
1027                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1028                         break;
1029
1030                 // o is no good, we need to get closer to the player
1031                 tmax = t;
1032         }
1033
1034         print("spawning a waypoint for connecting to ", etos(wp), "\n");
1035         botframe_autowaypoints_createwp(o, p, fld);
1036         return 1;
1037 }
1038
1039 // automatically create missing waypoints
1040 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1041 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1042 {
1043         float r;
1044         r = botframe_autowaypoints_fix_from(p, walkfromwp, p.fld, fld);
1045         if(r != -1)
1046                 return;
1047         r = botframe_autowaypoints_fix_from(p, walkfromwp, world, fld);
1048         if(r != -1)
1049                 return;
1050
1051         print("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1052         if(!botframe_autowaypoints_fixdown(p.origin))
1053                 return; // shouldn't happen, caught above
1054         botframe_autowaypoints_createwp(trace_endpos, p, fld);
1055 }
1056
1057 void botframe_autowaypoints()
1058 {
1059         entity p;
1060         FOR_EACH_REALPLAYER(p)
1061         {
1062                 if(p.deadflag)
1063                         continue;
1064                 // going back is broken, so only fix waypoints to walk TO the player
1065                 //botframe_autowaypoints_fix(p, FALSE, botframe_autowaypoints_lastwp0);
1066                 botframe_autowaypoints_fix(p, TRUE, botframe_autowaypoints_lastwp1);
1067                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1068         }
1069 }
1070