qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         Unfreeze(self);
 172
 173         if(self.alivetime)
 174         {
 175                 if(!warmup_stage)
 176                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 177                 self.alivetime = 0;
 178         }
 179
 180         if(self.vehicle)
 181                 vehicles_exit(VHEF_RELESE);
 182
 183         WaypointSprite_PlayerDead();
 184
 185         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 186                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 187
 188         if(self.killcount != -666)
 189         {
 190                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 191                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 192                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 193
 194                 if(self.just_joined == FALSE) {
 195                         LogTeamchange(self.playerid, -1, 4);
 196                 } else
 197                         self.just_joined = FALSE;
 198         }
 199
 200         PlayerScore_Clear(self); // clear scores when needed
 201
 202         accuracy_resend(self);
 203
 204         self.spectatortime = time;
 205
 206         self.classname = "observer";
 207         self.iscreature = FALSE;
 208         self.teleportable = TELEPORT_SIMPLE;
 209         self.damagedbycontents = FALSE;
 210         self.health = -666;
 211         self.takedamage = DAMAGE_NO;
 212         self.solid = SOLID_NOT;
 213         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 214         self.flags = FL_CLIENT | FL_NOTARGET;
 215         self.armorvalue = 666;
 216         self.effects = 0;
 217         self.armorvalue = autocvar_g_balance_armor_start;
 218         self.pauserotarmor_finished = 0;
 219         self.pauserothealth_finished = 0;
 220         self.pauseregen_finished = 0;
 221         self.damageforcescale = 0;
 222         self.death_time = 0;
 223         self.respawn_flags = 0;
 224         self.respawn_time = 0;
 225         self.stat_respawn_time = 0;
 226         self.alpha = 0;
 227         self.scale = 0;
 228         self.fade_time = 0;
 229         self.pain_frame = 0;
 230         self.pain_finished = 0;
 231         self.strength_finished = 0;
 232         self.invincible_finished = 0;
 233         self.superweapons_finished = 0;
 234         self.pushltime = 0;
 235         self.istypefrag = 0;
 236         self.think = func_null;
 237         self.nextthink = 0;
 238         self.hook_time = 0;
 239         self.deadflag = DEAD_NO;
 240         self.angles = spot.angles;
 241         self.angles_z = 0;
 242         self.fixangle = TRUE;
 243         self.crouch = FALSE;
 244         self.revival_time = 0;
 245
 246         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 247         self.prevorigin = self.origin;
 248         self.items = 0;
 249         self.weapons = '0 0 0';
 250         self.model = "";
 251         FixPlayermodel();
 252         setmodel(self, "null");
 253         self.drawonlytoclient = self;
 254
 255         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 256         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 257
 258         self.weapon = 0;
 259         self.weaponname = "";
 260         self.switchingweapon = 0;
 261         self.weaponmodel = "";
 262         self.weaponentity = world;
 263         self.exteriorweaponentity = world;
 264         self.killcount = -666;
 265         self.velocity = '0 0 0';
 266         self.avelocity = '0 0 0';
 267         self.punchangle = '0 0 0';
 268         self.punchvector = '0 0 0';
 269         self.oldvelocity = self.velocity;
 270         self.fire_endtime = -1;
 271 }
 272
 273 .float model_randomizer;
 274 void FixPlayermodel()
 275 {
 276         string defaultmodel;
 277         float defaultskin, chmdl, oldskin, n, i;
 278         vector m1, m2;
 279
 280         defaultmodel = "";
 281         defaultskin = 0;
 282         chmdl = FALSE;
 283
 284         if(autocvar_sv_defaultcharacter == 1)
 285         {
 286                 if(teamplay)
 287                 {
 288                         string s;
 289                         s = Team_ColorName_Lower(self.team);
 290                         if(s != "neutral")
 291                         {
 292                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 293                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 294                         }
 295                 }
 296
 297                 if(defaultmodel == "")
 298                 {
 299                         defaultmodel = autocvar_sv_defaultplayermodel;
 300                         defaultskin = autocvar_sv_defaultplayerskin;
 301                 }
 302
 303                 n = tokenize_console(defaultmodel);
 304                 if(n > 0)
 305                 {
 306                         defaultmodel = argv(floor(n * self.model_randomizer));
 307                         // However, do NOT randomize if the player-selected model is in the list.
 308                         for (i = 0; i < n; ++i)
 309                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 310                                         defaultmodel = argv(i);
 311                 }
 312
 313                 i = strstrofs(defaultmodel, ":", 0);
 314                 if(i >= 0)
 315                 {
 316                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 317                         defaultmodel = substring(defaultmodel, 0, i);
 318                 }
 319         }
 320
 321         if(defaultmodel != "")
 322         {
 323                 if (defaultmodel != self.model)
 324                 {
 325                         m1 = self.mins;
 326                         m2 = self.maxs;
 327                         setplayermodel (self, defaultmodel);
 328                         setsize (self, m1, m2);
 329                         chmdl = TRUE;
 330                 }
 331
 332                 oldskin = self.skin;
 333                 self.skin = defaultskin;
 334         } else {
 335                 if (self.playermodel != self.model || self.playermodel == "")
 336                 {
 337                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 338                         m1 = self.mins;
 339                         m2 = self.maxs;
 340                         setplayermodel (self, self.playermodel);
 341                         setsize (self, m1, m2);
 342                         chmdl = TRUE;
 343                 }
 344
 345                 oldskin = self.skin;
 346                 self.skin = stof(self.playerskin);
 347         }
 348
 349         if(chmdl || oldskin != self.skin) // model or skin has changed
 350         {
 351                 self.species = player_getspecies(); // update species
 352                 UpdatePlayerSounds(); // update skin sounds
 353         }
 354
 355         if(!teamplay)
 356                 if(strlen(autocvar_sv_defaultplayercolors))
 357                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 358                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 359 }
 360
 361 /*
 362 =============
 363 PutClientInServer
 364
 365 Called when a client spawns in the server
 366 =============
 367 */
 368 void PutClientInServer (void)
 369 {
 370         if(IS_BOT_CLIENT(self))
 371                 self.classname = "player";
 372         else if(IS_REAL_CLIENT(self))
 373         {
 374                 msg_entity = self;
 375                 WriteByte(MSG_ONE, SVC_SETVIEW);
 376                 WriteEntity(MSG_ONE, self);
 377         }
 378
 379         // reset player keys
 380         self.itemkeys = 0;
 381
 382         MUTATOR_CALLHOOK(PutClientInServer);
 383
 384         if(gameover)
 385                 self.classname = "observer";
 386
 387         if(IS_PLAYER(self))
 388         {
 389                 entity spot, oldself;
 390                 float j;
 391
 392                 accuracy_resend(self);
 393
 394                 if(self.team < 0)
 395                         JoinBestTeam(self, FALSE, TRUE);
 396
 397                 race_PreSpawn();
 398
 399                 spot = SelectSpawnPoint (FALSE);
 400                 if(!spot)
 401                 {
 402                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 403                         return; // spawn failed
 404                 }
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 if(self.vehicle)
 409                         vehicles_exit(VHEF_RELESE);
 410
 411                 self.classname = "player";
 412                 self.wasplayer = TRUE;
 413                 self.iscreature = TRUE;
 414                 self.teleportable = TELEPORT_NORMAL;
 415                 self.damagedbycontents = TRUE;
 416                 self.movetype = MOVETYPE_WALK;
 417                 self.solid = SOLID_SLIDEBOX;
 418                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 419                 if(autocvar_g_playerclip_collisions)
 420                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 421                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 422                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 423                 self.frags = FRAGS_PLAYER;
 424                 if(INDEPENDENT_PLAYERS)
 425                         MAKE_INDEPENDENT_PLAYER(self);
 426                 self.flags = FL_CLIENT;
 427                 if(autocvar__notarget)
 428                         self.flags |= FL_NOTARGET;
 429                 self.takedamage = DAMAGE_AIM;
 430                 self.effects = 0;
 431                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 432                 self.air_finished = time + 12;
 433                 self.dmg = 2;
 434                 if(autocvar_g_balance_nex_charge)
 435                 {
 436                         if(autocvar_g_balance_nex_secondary_chargepool)
 437                                 self.nex_chargepool_ammo = 1;
 438                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 439                 }
 440
 441                 if(warmup_stage)
 442                 {
 443                         self.ammo_shells = warmup_start_ammo_shells;
 444                         self.ammo_nails = warmup_start_ammo_nails;
 445                         self.ammo_rockets = warmup_start_ammo_rockets;
 446                         self.ammo_cells = warmup_start_ammo_cells;
 447                         self.ammo_fuel = warmup_start_ammo_fuel;
 448                         self.health = warmup_start_health;
 449                         self.armorvalue = warmup_start_armorvalue;
 450                         self.weapons = WARMUP_START_WEAPONS;
 451                 }
 452                 else
 453                 {
 454                         self.ammo_shells = start_ammo_shells;
 455                         self.ammo_nails = start_ammo_nails;
 456                         self.ammo_rockets = start_ammo_rockets;
 457                         self.ammo_cells = start_ammo_cells;
 458                         self.ammo_fuel = start_ammo_fuel;
 459                         self.health = start_health;
 460                         self.armorvalue = start_armorvalue;
 461                         self.weapons = start_weapons;
 462                 }
 463
 464                 if(self.weapons & WEPSET_SUPERWEAPONS)
 465                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 466                 else
 467                         self.superweapons_finished = 0;
 468
 469                 if(g_weaponarena_random)
 470                 {
 471                         if(g_weaponarena_random_with_laser)
 472                                 self.weapons &= ~WEPSET_LASER;
 473                         W_RandomWeapons(self, g_weaponarena_random);
 474                         if(g_weaponarena_random_with_laser)
 475                                 self.weapons |= WEPSET_LASER;
 476                 }
 477
 478                 self.items = start_items;
 479
 480                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 481                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 482                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 483                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 484                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 485                 //extend the pause of rotting if client was reset at the beginning of the countdown
 486                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 487                         self.spawnshieldtime += game_starttime - time;
 488                         self.pauserotarmor_finished += game_starttime - time;
 489                         self.pauserothealth_finished += game_starttime - time;
 490                         self.pauseregen_finished += game_starttime - time;
 491                 }
 492                 self.damageforcescale = 2;
 493                 self.death_time = 0;
 494                 self.respawn_flags = 0;
 495                 self.respawn_time = 0;
 496                 self.stat_respawn_time = 0;
 497                 self.scale = 0;
 498                 self.fade_time = 0;
 499                 self.pain_frame = 0;
 500                 self.pain_finished = 0;
 501                 self.strength_finished = 0;
 502                 self.invincible_finished = 0;
 503                 self.pushltime = 0;
 504                 // players have no think function
 505                 self.think = func_null;
 506                 self.nextthink = 0;
 507                 self.hook_time = 0;
 508                 self.dmg_team = 0;
 509                 self.ballistics_density = autocvar_g_ballistics_density_player;
 510
 511                 self.metertime = 0;
 512
 513                 self.deadflag = DEAD_NO;
 514
 515                 self.angles = spot.angles;
 516
 517                 self.angles_z = 0; // never spawn tilted even if the spot says to
 518                 self.fixangle = TRUE; // turn this way immediately
 519                 self.velocity = '0 0 0';
 520                 self.avelocity = '0 0 0';
 521                 self.punchangle = '0 0 0';
 522                 self.punchvector = '0 0 0';
 523                 self.oldvelocity = self.velocity;
 524                 self.fire_endtime = -1;
 525                 self.revival_time = 0;
 526
 527                 entity spawnevent = spawn();
 528                 spawnevent.owner = self;
 529                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = FALSE;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = TRUE;
 550                 self.monster_attack = TRUE;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.statdraintime = time + 5;
 555                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 556
 557                 if(self.killcount == -666) {
 558                         PlayerScore_Clear(self);
 559                         self.killcount = 0;
 560                 }
 561
 562                 CL_SpawnWeaponentity();
 563                 self.alpha = default_player_alpha;
 564                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 565                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 566
 567                 self.speedrunning = FALSE;
 568
 569                 race_PostSpawn(spot);
 570
 571                 //stuffcmd(self, "chase_active 0");
 572                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 573
 574                 target_voicescript_clear(self);
 575
 576                 // reset fields the weapons may use
 577                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 578                 {
 579                         weapon_action(j, WR_RESETPLAYER);
 580
 581                         // all weapons must be fully loaded when we spawn
 582                         entity e;
 583                         e = get_weaponinfo(j);
 584                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 585                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 586                 }
 587
 588                 oldself = self;
 589                 self = spot;
 590                         activator = oldself;
 591                                 string s;
 592                                 s = self.target;
 593                                 self.target = string_null;
 594                                 SUB_UseTargets();
 595                                 self.target = s;
 596                         activator = world;
 597                 self = oldself;
 598
 599                 Unfreeze(self);
 600
 601                 spawn_spot = spot;
 602                 MUTATOR_CALLHOOK(PlayerSpawn);
 603
 604                 if(autocvar_spawn_debug)
 605                 {
 606                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 607                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 608                 }
 609
 610                 self.switchweapon = w_getbestweapon(self);
 611                 self.cnt = -1; // W_LastWeapon will not complain
 612                 self.weapon = 0;
 613                 self.weaponname = "";
 614                 self.switchingweapon = 0;
 615
 616                 if(!warmup_stage)
 617                         if(!self.alivetime)
 618                                 self.alivetime = time;
 619
 620                 antilag_clear(self);
 621         }
 622         else if(IS_OBSERVER(self))
 623         {
 624                 PutObserverInServer ();
 625         }
 626 }
 627
 628 .float ebouncefactor, ebouncestop; // electro's values
 629 // TODO do we need all these fields, or should we stop autodetecting runtime
 630 // changes and just have a console command to update this?
 631 float ClientInit_SendEntity(entity to, float sf)
 632 {
 633         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 634         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 641         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 642         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 643         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 644         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 645         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 646         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 647         if(sv_foginterval && world.fog != "")
 648                 WriteString(MSG_ENTITY, world.fog);
 649         else
 650                 WriteString(MSG_ENTITY, "");
 651         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 652         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 653         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 654         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 655         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 656         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 657         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 658         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 659         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 660         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 661         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 662         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 663         return TRUE;
 664 }
 665
 666 void ClientInit_CheckUpdate()
 667 {
 668         self.nextthink = time;
 669         if(self.count != autocvar_g_balance_armor_blockpercent)
 670         {
 671                 self.count = autocvar_g_balance_armor_blockpercent;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 675         {
 676                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 680         {
 681                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 682                 self.SendFlags |= 1;
 683         }
 684         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 685         {
 686                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 687                 self.SendFlags |= 1;
 688         }
 689         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 690         {
 691                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 692                 self.SendFlags |= 1;
 693         }
 694 }
 695
 696 void ClientInit_Spawn()
 697 {
 698         entity o;
 699         entity e;
 700         e = spawn();
 701         e.classname = "clientinit";
 702         e.think = ClientInit_CheckUpdate;
 703         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 704
 705         o = self;
 706         self = e;
 707         ClientInit_CheckUpdate();
 708         self = o;
 709 }
 710
 711 /*
 712 =============
 713 SetNewParms
 714 =============
 715 */
 716 void SetNewParms (void)
 717 {
 718         // initialize parms for a new player
 719         parm1 = -(86400 * 366);
 720 }
 721
 722 /*
 723 =============
 724 SetChangeParms
 725 =============
 726 */
 727 void SetChangeParms (void)
 728 {
 729         // save parms for level change
 730         parm1 = self.parm_idlesince - time;
 731 }
 732
 733 /*
 734 =============
 735 DecodeLevelParms
 736 =============
 737 */
 738 void DecodeLevelParms (void)
 739 {
 740         // load parms
 741         self.parm_idlesince = parm1;
 742         if(self.parm_idlesince == -(86400 * 366))
 743                 self.parm_idlesince = time;
 744
 745         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 746         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 747 }
 748
 749 /*
 750 =============
 751 ClientKill
 752
 753 Called when a client types 'kill' in the console
 754 =============
 755 */
 756
 757 .float clientkill_nexttime;
 758 void ClientKill_Now_TeamChange()
 759 {
 760         if(self.killindicator_teamchange == -1)
 761         {
 762                 JoinBestTeam( self, FALSE, TRUE );
 763         }
 764         else if(self.killindicator_teamchange == -2)
 765         {
 766                 if(blockSpectators)
 767                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 768                 PutObserverInServer();
 769         }
 770         else
 771                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 772         self.killindicator_teamchange = 0;
 773 }
 774
 775 void ClientKill_Now()
 776 {
 777         if(self.vehicle)
 778         {
 779             vehicles_exit(VHEF_RELESE);
 780             if(!self.killindicator_teamchange)
 781             {
 782             self.vehicle_health = -1;
 783             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 784             }
 785         }
 786
 787         if(self.killindicator && !wasfreed(self.killindicator))
 788                 remove(self.killindicator);
 789
 790         self.killindicator = world;
 791
 792         if(self.killindicator_teamchange)
 793                 ClientKill_Now_TeamChange();
 794
 795         // in any case:
 796         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 797
 798         // now I am sure the player IS dead
 799 }
 800 void KillIndicator_Think()
 801 {
 802         if (gameover)
 803         {
 804                 self.owner.killindicator = world;
 805                 remove(self);
 806                 return;
 807         }
 808
 809         if (self.owner.alpha < 0 && !self.owner.vehicle)
 810         {
 811                 self.owner.killindicator = world;
 812                 remove(self);
 813                 return;
 814         }
 815
 816         if(self.cnt <= 0)
 817         {
 818                 self = self.owner;
 819                 ClientKill_Now(); // no oldself needed
 820                 return;
 821         }
 822     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 823     {
 824         self.nextthink = time + 1;
 825         self.cnt -= 1;
 826     }
 827         else
 828         {
 829                 if(self.cnt <= 10)
 830                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 831                 if(IS_REAL_CLIENT(self.owner))
 832                 {
 833                         if(self.cnt <= 10)
 834                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 835                 }
 836                 self.nextthink = time + 1;
 837                 self.cnt -= 1;
 838         }
 839 }
 840
 841 float clientkilltime;
 842 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 843 {
 844         float killtime;
 845         float starttime;
 846         entity e;
 847
 848         if (gameover)
 849                 return;
 850
 851         killtime = autocvar_g_balance_kill_delay;
 852
 853         if(g_race_qualifying || g_cts)
 854                 killtime = 0;
 855
 856     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 857     {
 858                 remove(self.killindicator);
 859                 self.killindicator = world;
 860
 861         ClientKill_Now(); // allow instant kill in this case
 862         return;
 863     }
 864
 865         self.killindicator_teamchange = targetteam;
 866
 867     if(!self.killindicator)
 868         {
 869                 if(self.deadflag == DEAD_NO)
 870                 {
 871                         killtime = max(killtime, self.clientkill_nexttime - time);
 872                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 873                 }
 874
 875                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 876                 {
 877                         ClientKill_Now();
 878                 }
 879                 else
 880                 {
 881                         starttime = max(time, clientkilltime);
 882
 883                         self.killindicator = spawn();
 884                         self.killindicator.owner = self;
 885                         self.killindicator.scale = 0.5;
 886                         setattachment(self.killindicator, self, "");
 887                         setorigin(self.killindicator, '0 0 52');
 888                         self.killindicator.think = KillIndicator_Think;
 889                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 890                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 891                         self.killindicator.cnt = ceil(killtime);
 892                         self.killindicator.count = bound(0, ceil(killtime), 10);
 893                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 894
 895                         for(e = world; (e = find(e, classname, "body")) != world; )
 896                         {
 897                                 if(e.enemy != self)
 898                                         continue;
 899                                 e.killindicator = spawn();
 900                                 e.killindicator.owner = e;
 901                                 e.killindicator.scale = 0.5;
 902                                 setattachment(e.killindicator, e, "");
 903                                 setorigin(e.killindicator, '0 0 52');
 904                                 e.killindicator.think = KillIndicator_Think;
 905                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 906                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 907                                 e.killindicator.cnt = ceil(killtime);
 908                         }
 909                         self.lip = 0;
 910                 }
 911         }
 912         if(self.killindicator)
 913         {
 914                 if(targetteam == 0) // just die
 915                 {
 916                         self.killindicator.colormod = '0 0 0';
 917                         if(IS_REAL_CLIENT(self))
 918                         if(self.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 920                 }
 921                 else if(targetteam == -1) // auto
 922                 {
 923                         self.killindicator.colormod = '0 1 0';
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 927                 }
 928                 else if(targetteam == -2) // spectate
 929                 {
 930                         self.killindicator.colormod = '0.5 0.5 0.5';
 931                         if(IS_REAL_CLIENT(self))
 932                         if(self.killindicator.cnt > 0)
 933                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 934                 }
 935                 else
 936                 {
 937                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 938                         if(IS_REAL_CLIENT(self))
 939                         if(self.killindicator.cnt > 0)
 940                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 941                 }
 942         }
 943
 944 }
 945
 946 void ClientKill (void)
 947 {
 948         if(gameover) return;
 949         if(self.player_blocked) return;
 950         if(self.frozen) return;
 951
 952         ClientKill_TeamChange(0);
 953 }
 954
 955 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 956 {
 957     e.killindicator = spawn();
 958     e.killindicator.owner = e;
 959     e.killindicator.think = KillIndicator_Think;
 960     e.killindicator.nextthink = time + (e.lip) * 0.05;
 961     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 962     e.killindicator.health = 1; // this is used to indicate that it should be silent
 963     e.lip = 0;
 964 }
 965
 966 void FixClientCvars(entity e)
 967 {
 968         // send prediction settings to the client
 969         stuffcmd(e, "\nin_bindmap 0 0\n");
 970         if(g_race || g_cts)
 971                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 972         if(autocvar_g_antilag == 3) // client side hitscan
 973                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 974         if(autocvar_sv_gentle)
 975                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 976         /*
 977          * we no longer need to stuff this. Remove this comment block if you feel
 978          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 979         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 980         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 981         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 982         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 983         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 984         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 985         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 986         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 987         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 988         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 989         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 990         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 991         stuffcmd(e, "cl_movement_edgefriction 1\n");
 992          */
 993 }
 994
 995 float PlayerInIDList(entity p, string idlist)
 996 {
 997         float n, i;
 998         string s;
 999
1000         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1001         if (!p.crypto_idfp)
1002                 return 0;
1003
1004         // this function allows abbreviated player IDs too!
1005         n = tokenize_console(idlist);
1006         for(i = 0; i < n; ++i)
1007         {
1008                 s = argv(i);
1009                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1010                         return 1;
1011         }
1012
1013         return 0;
1014 }
1015
1016 /*
1017 =============
1018 ClientConnect
1019
1020 Called when a client connects to the server
1021 =============
1022 */
1023 void DecodeLevelParms (void);
1024 //void dom_player_join_team(entity pl);
1025 void set_dom_state(entity e);
1026 void ClientConnect (void)
1027 {
1028         float t;
1029
1030         if(IS_CLIENT(self))
1031         {
1032                 print("Warning: ClientConnect, but already connected!\n");
1033                 return;
1034         }
1035
1036         if(Ban_MaybeEnforceBanOnce(self))
1037                 return;
1038
1039         DecodeLevelParms();
1040
1041 #ifdef WATERMARK
1042         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1043 #endif
1044
1045         self.classname = "player_joining";
1046
1047         self.flags = FL_CLIENT;
1048         self.version_nagtime = time + 10 + random() * 10;
1049
1050         if(player_count<0)
1051         {
1052                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1053                 player_count = 0;
1054         }
1055
1056         PlayerScore_Attach(self);
1057         ClientData_Attach();
1058         accuracy_init(self);
1059
1060         bot_clientconnect();
1061
1062         playerdemo_init();
1063
1064         anticheat_init();
1065
1066         race_PreSpawnObserver();
1067
1068         // identify the right forced team
1069         if(autocvar_g_campaign)
1070         {
1071                 if(IS_REAL_CLIENT(self)) // only players, not bots
1072                 {
1073                         switch(autocvar_g_campaign_forceteam)
1074                         {
1075                                 case 1: self.team_forced = NUM_TEAM_1; break;
1076                                 case 2: self.team_forced = NUM_TEAM_2; break;
1077                                 case 3: self.team_forced = NUM_TEAM_3; break;
1078                                 case 4: self.team_forced = NUM_TEAM_4; break;
1079                                 default: self.team_forced = 0;
1080                         }
1081                 }
1082         }
1083         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1084                 self.team_forced = NUM_TEAM_1;
1085         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1086                 self.team_forced = NUM_TEAM_2;
1087         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1088                 self.team_forced = NUM_TEAM_3;
1089         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1090                 self.team_forced = NUM_TEAM_4;
1091         else if(autocvar_g_forced_team_otherwise == "red")
1092                 self.team_forced = NUM_TEAM_1;
1093         else if(autocvar_g_forced_team_otherwise == "blue")
1094                 self.team_forced = NUM_TEAM_2;
1095         else if(autocvar_g_forced_team_otherwise == "yellow")
1096                 self.team_forced = NUM_TEAM_3;
1097         else if(autocvar_g_forced_team_otherwise == "pink")
1098                 self.team_forced = NUM_TEAM_4;
1099         else if(autocvar_g_forced_team_otherwise == "spectate")
1100                 self.team_forced = -1;
1101         else if(autocvar_g_forced_team_otherwise == "spectator")
1102                 self.team_forced = -1;
1103         else
1104                 self.team_forced = 0;
1105
1106         if(!teamplay)
1107                 if(self.team_forced > 0)
1108                         self.team_forced = 0;
1109
1110         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1111
1112         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1113                 self.classname = "observer";
1114         } else {
1115                 if(teamplay)
1116                 {
1117                         if(autocvar_g_balance_teams)
1118                         {
1119                                 self.classname = "player";
1120                                 campaign_bots_may_start = 1;
1121                         }
1122                         else
1123                         {
1124                                 self.classname = "observer"; // do it anyway
1125                         }
1126                 }
1127                 else
1128                 {
1129                         self.classname = "player";
1130                         campaign_bots_may_start = 1;
1131                 }
1132         }
1133
1134         self.playerid = (playerid_last = playerid_last + 1);
1135
1136         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1137
1138     if(IS_BOT_CLIENT(self))
1139         PlayerStats_AddPlayer(self);
1140
1141         if(autocvar_sv_eventlog)
1142                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1143
1144         LogTeamchange(self.playerid, self.team, 1);
1145
1146         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1147
1148         self.netname_previous = strzone(self.netname);
1149
1150         if(IS_PLAYER(self) && teamplay)
1151                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1152         else
1153                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1154
1155         stuffcmd(self, strcat(clientstuff, "\n"));
1156         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1157
1158         FixClientCvars(self);
1159
1160         // spawnfunc_waypoint sprites
1161         WaypointSprite_InitClient(self);
1162
1163         // Wazat's grappling hook
1164         SetGrappleHookBindings();
1165
1166         // get version info from player
1167         stuffcmd(self, "cmd clientversion $gameversion\n");
1168
1169         // get other cvars from player
1170         GetCvars(0);
1171
1172         // notify about available teams
1173         if(teamplay)
1174         {
1175                 CheckAllowedTeams(self);
1176                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1177                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1178         }
1179         else
1180                 stuffcmd(self, "set _teams_available 0\n");
1181
1182         attach_entcs();
1183
1184         bot_relinkplayerlist();
1185
1186         self.spectatortime = time;
1187         if(blockSpectators)
1188         {
1189                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1190         }
1191
1192         self.jointime = time;
1193         self.allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if(IS_REAL_CLIENT(self))
1196         {
1197                 if(!autocvar_g_campaign)
1198                 {
1199                         self.motd_actived_time = -1;
1200                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1201                 }
1202
1203                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1204                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1205         }
1206
1207         if(!sv_foginterval && world.fog != "")
1208                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1209
1210         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1211         {
1212                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1213                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1214         }
1215         else
1216                 self.hitplotfh = -1;
1217
1218         if(g_race || g_cts) {
1219                 string rr;
1220                 if(g_cts)
1221                         rr = CTS_RECORD;
1222                 else
1223                         rr = RACE_RECORD;
1224
1225                 msg_entity = self;
1226                 race_send_recordtime(MSG_ONE);
1227                 race_send_speedaward(MSG_ONE);
1228
1229                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1230                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1231                 race_send_speedaward_alltimebest(MSG_ONE);
1232
1233                 float i;
1234                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1235                         race_SendRankings(i, 0, 0, MSG_ONE);
1236                 }
1237         }
1238         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1239                 send_CSQC_teamnagger();
1240
1241         CheatInitClient();
1242
1243         CSQCMODEL_AUTOINIT();
1244
1245         self.model_randomizer = random();
1246
1247         if(IS_REAL_CLIENT(self))
1248                 sv_notice_join();
1249
1250         MUTATOR_CALLHOOK(ClientConnect);
1251 }
1252 /*
1253 =============
1254 ClientDisconnect
1255
1256 Called when a client disconnects from the server
1257 =============
1258 */
1259 .entity chatbubbleentity;
1260 void ReadyCount();
1261 void ClientDisconnect (void)
1262 {
1263         if(self.vehicle)
1264             vehicles_exit(VHEF_RELESE);
1265
1266         if (!IS_CLIENT(self))
1267         {
1268                 print("Warning: ClientDisconnect without ClientConnect\n");
1269                 return;
1270         }
1271
1272         PlayerStats_AddGlobalInfo(self);
1273
1274         CheatShutdownClient();
1275
1276         if(self.hitplotfh >= 0)
1277         {
1278                 fclose(self.hitplotfh);
1279                 self.hitplotfh = -1;
1280         }
1281
1282         anticheat_report();
1283         anticheat_shutdown();
1284
1285         playerdemo_shutdown();
1286
1287         bot_clientdisconnect();
1288
1289         if(self.entcs)
1290                 detach_entcs();
1291
1292         if(autocvar_sv_eventlog)
1293                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1294
1295         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1296
1297         MUTATOR_CALLHOOK(ClientDisconnect);
1298
1299         Portal_ClearAll(self);
1300
1301         Unfreeze(self);
1302
1303         RemoveGrapplingHook(self);
1304
1305         // Here, everything has been done that requires this player to be a client.
1306
1307         self.flags &= ~FL_CLIENT;
1308
1309         if (self.chatbubbleentity)
1310                 remove (self.chatbubbleentity);
1311
1312         if (self.killindicator)
1313                 remove (self.killindicator);
1314
1315         WaypointSprite_PlayerGone();
1316
1317         bot_relinkplayerlist();
1318
1319         accuracy_free(self);
1320         ClientData_Detach();
1321         PlayerScore_Detach(self);
1322
1323         if(self.netname_previous)
1324                 strunzone(self.netname_previous);
1325         if(self.clientstatus)
1326                 strunzone(self.clientstatus);
1327         if(self.weaponorder_byimpulse)
1328                 strunzone(self.weaponorder_byimpulse);
1329
1330         ClearPlayerSounds();
1331
1332         if(self.personal)
1333                 remove(self.personal);
1334
1335         self.playerid = 0;
1336         ReadyCount();
1337
1338         // free cvars
1339         GetCvars(-1);
1340 }
1341
1342 .float BUTTON_CHAT;
1343 void ChatBubbleThink()
1344 {
1345         self.nextthink = time;
1346         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1347         {
1348                 if(self.owner) // but why can that ever be world?
1349                         self.owner.chatbubbleentity = world;
1350                 remove(self);
1351                 return;
1352         }
1353         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1354 #ifdef TETRIS
1355                 || self.owner.tetris_on
1356 #endif
1357         )
1358                 self.model = self.mdl;
1359         else
1360                 self.model = "";
1361 }
1362
1363 void UpdateChatBubble()
1364 {
1365         if (self.alpha < 0)
1366                 return;
1367         // spawn a chatbubble entity if needed
1368         if (!self.chatbubbleentity)
1369         {
1370                 self.chatbubbleentity = spawn();
1371                 self.chatbubbleentity.owner = self;
1372                 self.chatbubbleentity.exteriormodeltoclient = self;
1373                 self.chatbubbleentity.think = ChatBubbleThink;
1374                 self.chatbubbleentity.nextthink = time;
1375                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1376                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1377                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1378                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1379                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1380                 self.chatbubbleentity.model = "";
1381                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1382         }
1383 }
1384
1385
1386 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1387 // added to the model skins
1388 /*void UpdateColorModHack()
1389 {
1390         float c;
1391         c = self.clientcolors & 15;
1392         // LordHavoc: only bothering to support white, green, red, yellow, blue
1393              if (!teamplay) self.colormod = '0 0 0';
1394         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1395         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1396         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1397         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1398         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1399         else self.colormod = '1 1 1';
1400 }*/
1401
1402 void respawn(void)
1403 {
1404         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1405         {
1406                 self.solid = SOLID_NOT;
1407                 self.takedamage = DAMAGE_NO;
1408                 self.movetype = MOVETYPE_FLY;
1409                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1410                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1411                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1412                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1413                 if(autocvar_g_respawn_ghosts_maxtime)
1414                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1415         }
1416
1417         CopyBody(1);
1418
1419         self.effects |= EF_NODRAW; // prevent another CopyBody
1420         PutClientInServer();
1421 }
1422
1423 void play_countdown(float finished, string samp)
1424 {
1425         if(IS_REAL_CLIENT(self))
1426                 if(floor(finished - time - frametime) != floor(finished - time))
1427                         if(finished - time < 6)
1428                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1429 }
1430
1431 void player_powerups (void)
1432 {
1433         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1434         olditems = self.items;
1435
1436         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1437                 self.modelflags |= MF_ROCKET;
1438         else
1439                 self.modelflags &= ~MF_ROCKET;
1440
1441         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1442
1443         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1444                 return;
1445
1446         Fire_ApplyDamage(self);
1447         Fire_ApplyEffect(self);
1448
1449         if (!g_minstagib)
1450         {
1451                 if (self.items & IT_STRENGTH)
1452                 {
1453                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1454                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1455                         if (time > self.strength_finished)
1456                         {
1457                                 self.items = self.items - (self.items & IT_STRENGTH);
1458                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1459                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1460                         }
1461                 }
1462                 else
1463                 {
1464                         if (time < self.strength_finished)
1465                         {
1466                                 self.items = self.items | IT_STRENGTH;
1467                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1468                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1469                         }
1470                 }
1471                 if (self.items & IT_INVINCIBLE)
1472                 {
1473                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1474                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1475                         if (time > self.invincible_finished)
1476                         {
1477                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1478                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1480                         }
1481                 }
1482                 else
1483                 {
1484                         if (time < self.invincible_finished)
1485                         {
1486                                 self.items = self.items | IT_INVINCIBLE;
1487                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1488                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1489                         }
1490                 }
1491                 if (self.items & IT_SUPERWEAPON)
1492                 {
1493                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1494                         {
1495                                 self.superweapons_finished = 0;
1496                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1497                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1498                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1499                         }
1500                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1501                         {
1502                                 // don't let them run out
1503                         }
1504                         else
1505                         {
1506                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1507                                 if (time > self.superweapons_finished)
1508                                 {
1509                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1510                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1511                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1512                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1513                                 }
1514                         }
1515                 }
1516                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1517                 {
1518                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1519                         {
1520                                 self.items = self.items | IT_SUPERWEAPON;
1521                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1522                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1523                         }
1524                         else
1525                         {
1526                                 self.superweapons_finished = 0;
1527                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1528                         }
1529                 }
1530                 else
1531                 {
1532                         self.superweapons_finished = 0;
1533                 }
1534         }
1535
1536         if(autocvar_g_nodepthtestplayers)
1537                 self.effects = self.effects | EF_NODEPTHTEST;
1538
1539         if(autocvar_g_fullbrightplayers)
1540                 self.effects = self.effects | EF_FULLBRIGHT;
1541
1542         if (time >= game_starttime)
1543         if (time < self.spawnshieldtime)
1544                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1545
1546         MUTATOR_CALLHOOK(PlayerPowerups);
1547 }
1548
1549 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1550 {
1551         if(current > stable)
1552                 return current;
1553         else if(current > stable - 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1557 }
1558
1559 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1560 {
1561         if(current < stable)
1562                 return current;
1563         else if(current < stable + 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1567 }
1568
1569 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1570 {
1571         if(current > rotstable)
1572         {
1573                 if(rotframetime > 0)
1574                 {
1575                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1576                         current = max(rotstable, current - rotlinear * rotframetime);
1577                 }
1578         }
1579         else if(current < regenstable)
1580         {
1581                 if(regenframetime > 0)
1582                 {
1583                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1584                         current = min(regenstable, current + regenlinear * regenframetime);
1585                 }
1586         }
1587
1588         if(current > limit)
1589                 current = limit;
1590
1591         return current;
1592 }
1593
1594 void player_regen (void)
1595 {
1596         if(!MUTATOR_CALLHOOK(PlayerRegen))
1597         if(!self.frozen)
1598         {
1599                 float minh, mina, maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1600                 maxh = autocvar_g_balance_health_rotstable;
1601                 maxa = autocvar_g_balance_armor_rotstable;
1602                 minh = autocvar_g_balance_health_regenstable;
1603                 mina = autocvar_g_balance_armor_regenstable;
1604                 limith = autocvar_g_balance_health_limit;
1605                 limita = autocvar_g_balance_armor_limit;
1606
1607                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1608
1609                 maxh = maxh * max_mod;
1610                 minh = minh * max_mod;
1611                 limith = limith * limit_mod;
1612                 limita = limita * limit_mod;
1613
1614                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1615                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1616         }
1617
1618         // if player rotted to death...  die!
1619         // check this outside above checks, as player may still be able to rot to death
1620         if(self.health < 1)
1621                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1622
1623         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1624         {
1625                 float minf, maxf, limitf;
1626
1627                 maxf = autocvar_g_balance_fuel_rotstable;
1628                 minf = autocvar_g_balance_fuel_regenstable;
1629                 limitf = autocvar_g_balance_fuel_limit;
1630
1631                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1632         }
1633 }
1634
1635 float zoomstate_set;
1636 void SetZoomState(float z)
1637 {
1638         if(z != self.zoomstate)
1639         {
1640                 self.zoomstate = z;
1641                 ClientData_Touch(self);
1642         }
1643         zoomstate_set = 1;
1644 }
1645
1646 void GetPressedKeys(void) {
1647         MUTATOR_CALLHOOK(GetPressedKeys);
1648         if (self.movement_x > 0) // get if movement keys are pressed
1649         {       // forward key pressed
1650                 self.pressedkeys |= KEY_FORWARD;
1651                 self.pressedkeys &= ~KEY_BACKWARD;
1652         }
1653         else if (self.movement_x < 0)
1654         {       // backward key pressed
1655                 self.pressedkeys |= KEY_BACKWARD;
1656                 self.pressedkeys &= ~KEY_FORWARD;
1657         }
1658         else
1659         {       // no x input
1660                 self.pressedkeys &= ~KEY_FORWARD;
1661                 self.pressedkeys &= ~KEY_BACKWARD;
1662         }
1663
1664         if (self.movement_y > 0)
1665         {       // right key pressed
1666                 self.pressedkeys |= KEY_RIGHT;
1667                 self.pressedkeys &= ~KEY_LEFT;
1668         }
1669         else if (self.movement_y < 0)
1670         {       // left key pressed
1671                 self.pressedkeys |= KEY_LEFT;
1672                 self.pressedkeys &= ~KEY_RIGHT;
1673         }
1674         else
1675         {       // no y input
1676                 self.pressedkeys &= ~KEY_RIGHT;
1677                 self.pressedkeys &= ~KEY_LEFT;
1678         }
1679
1680         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1681                 self.pressedkeys |= KEY_JUMP;
1682         else
1683                 self.pressedkeys &= ~KEY_JUMP;
1684         if (self.BUTTON_CROUCH)
1685                 self.pressedkeys |= KEY_CROUCH;
1686         else
1687                 self.pressedkeys &= ~KEY_CROUCH;
1688
1689         if (self.BUTTON_ATCK)
1690                 self.pressedkeys |= KEY_ATCK;
1691         else
1692                 self.pressedkeys &= ~KEY_ATCK;
1693         if (self.BUTTON_ATCK2)
1694                 self.pressedkeys |= KEY_ATCK2;
1695         else
1696                 self.pressedkeys &= ~KEY_ATCK2;
1697 }
1698
1699 /*
1700 ======================
1701 spectate mode routines
1702 ======================
1703 */
1704
1705 void SpectateCopy(entity spectatee) {
1706         other = spectatee;
1707         MUTATOR_CALLHOOK(SpectateCopy);
1708         self.armortype = spectatee.armortype;
1709         self.armorvalue = spectatee.armorvalue;
1710         self.ammo_cells = spectatee.ammo_cells;
1711         self.ammo_shells = spectatee.ammo_shells;
1712         self.ammo_nails = spectatee.ammo_nails;
1713         self.ammo_rockets = spectatee.ammo_rockets;
1714         self.ammo_fuel = spectatee.ammo_fuel;
1715         self.clip_load = spectatee.clip_load;
1716         self.clip_size = spectatee.clip_size;
1717         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1718         self.health = spectatee.health;
1719         self.impulse = 0;
1720         self.items = spectatee.items;
1721         self.last_pickup = spectatee.last_pickup;
1722         self.hit_time = spectatee.hit_time;
1723         self.metertime = spectatee.metertime;
1724         self.strength_finished = spectatee.strength_finished;
1725         self.invincible_finished = spectatee.invincible_finished;
1726         self.pressedkeys = spectatee.pressedkeys;
1727         self.weapons = spectatee.weapons;
1728         self.switchweapon = spectatee.switchweapon;
1729         self.switchingweapon = spectatee.switchingweapon;
1730         self.weapon = spectatee.weapon;
1731         self.nex_charge = spectatee.nex_charge;
1732         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1733         self.hagar_load = spectatee.hagar_load;
1734         self.minelayer_mines = spectatee.minelayer_mines;
1735         self.punchangle = spectatee.punchangle;
1736         self.view_ofs = spectatee.view_ofs;
1737         self.velocity = spectatee.velocity;
1738         self.dmg_take = spectatee.dmg_take;
1739         self.dmg_save = spectatee.dmg_save;
1740         self.dmg_inflictor = spectatee.dmg_inflictor;
1741         self.v_angle = spectatee.v_angle;
1742         self.angles = spectatee.v_angle;
1743         self.frozen = spectatee.frozen;
1744         self.revive_progress = spectatee.revive_progress;
1745         if(!self.BUTTON_USE)
1746                 self.fixangle = TRUE;
1747         setorigin(self, spectatee.origin);
1748         setsize(self, spectatee.mins, spectatee.maxs);
1749         SetZoomState(spectatee.zoomstate);
1750
1751     anticheat_spectatecopy(spectatee);
1752         self.hud = spectatee.hud;
1753         if(spectatee.vehicle)
1754     {
1755         self.fixangle = FALSE;
1756         //self.velocity = spectatee.vehicle.velocity;
1757         self.vehicle_health = spectatee.vehicle_health;
1758         self.vehicle_shield = spectatee.vehicle_shield;
1759         self.vehicle_energy = spectatee.vehicle_energy;
1760         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1761         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1762         self.vehicle_reload1 = spectatee.vehicle_reload1;
1763         self.vehicle_reload2 = spectatee.vehicle_reload2;
1764
1765         msg_entity = self;
1766
1767         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1768             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1771
1772         //WriteByte (MSG_ONE, SVC_SETVIEW);
1773         //    WriteEntity(MSG_ONE, self);
1774         //makevectors(spectatee.v_angle);
1775         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1776     }
1777 }
1778
1779 float SpectateUpdate() {
1780         if(!self.enemy)
1781             return 0;
1782
1783         if (self == self.enemy)
1784                 return 0;
1785
1786         if (!IS_PLAYER(self.enemy))
1787                 return 0;
1788
1789         SpectateCopy(self.enemy);
1790
1791         return 1;
1792 }
1793
1794
1795 float SpectateSet()
1796 {
1797         if(self.enemy.classname != "player")
1798                 return FALSE;
1799         /*if(self.enemy.vehicle)
1800         {
1801
1802                 msg_entity = self;
1803                 WriteByte(MSG_ONE, SVC_SETVIEW);
1804                 WriteEntity(MSG_ONE, self.enemy);
1805                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1806
1807                 self.movetype = MOVETYPE_NONE;
1808                 accuracy_resend(self);
1809         }
1810         else
1811         {*/
1812                 msg_entity = self;
1813                 WriteByte(MSG_ONE, SVC_SETVIEW);
1814                 WriteEntity(MSG_ONE, self.enemy);
1815                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1816                 self.movetype = MOVETYPE_NONE;
1817                 accuracy_resend(self);
1818
1819                 if(!SpectateUpdate())
1820                         PutObserverInServer();
1821         //}
1822         return TRUE;
1823 }
1824
1825 float Spectate(entity pl)
1826 {
1827         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1828         if(pl.team != self.team)
1829                 return 0;
1830
1831         self.enemy = pl;
1832         return SpectateSet();
1833 }
1834
1835 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1836 entity CA_SpectateNext(entity start) {
1837         if (start.team == self.team) {
1838                 return start;
1839         }
1840
1841         other = start;
1842         // continue from current player
1843         while(other && other.team != self.team) {
1844                 other = find(other, classname, "player");
1845         }
1846
1847         if (!other) {
1848                 // restart from begining
1849                 other = find(other, classname, "player");
1850                 while(other && other.team != self.team) {
1851                         other = find(other, classname, "player");
1852                 }
1853         }
1854
1855         return other;
1856 }
1857
1858 float SpectateNext()
1859 {
1860         other = find(self.enemy, classname, "player");
1861
1862         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1863                 // CA and ca players when spectating enemies is forbidden
1864                 other = CA_SpectateNext(other);
1865         } else {
1866                 // other modes and ca spectators or spectating enemies is allowed
1867                 if (!other)
1868                         other = find(other, classname, "player");
1869         }
1870
1871         if (other)
1872                 self.enemy = other;
1873
1874         return SpectateSet();
1875 }
1876
1877 float SpectatePrev()
1878 {
1879         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1880         other = findchain(classname, "player");
1881         if (!other) // no player
1882                 return FALSE;
1883
1884         entity first = other;
1885         // skip players until current spectated player
1886         if(self.enemy)
1887         while(other && other != self.enemy)
1888                 other = other.chain;
1889
1890         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1891         {
1892                 do { other = other.chain; }
1893                 while(other && other.team != self.team);
1894
1895                 if (!other)
1896                 {
1897                         other = first;
1898                         while(other.team != self.team)
1899                                 other = other.chain;
1900                         if(other == self.enemy)
1901                                 return TRUE;
1902                 }
1903         }
1904         else
1905         {
1906                 if(other.chain)
1907                         other = other.chain;
1908                 else
1909                         other = first;
1910         }
1911         self.enemy = other;
1912         return SpectateSet();
1913 }
1914
1915 /*
1916 =============
1917 ShowRespawnCountdown()
1918
1919 Update a respawn countdown display.
1920 =============
1921 */
1922 void ShowRespawnCountdown()
1923 {
1924         float number;
1925         if(self.deadflag == DEAD_NO) // just respawned?
1926                 return;
1927         else
1928         {
1929                 number = ceil(self.respawn_time - time);
1930                 if(number <= 0)
1931                         return;
1932                 if(number <= self.respawn_countdown)
1933                 {
1934                         self.respawn_countdown = number - 1;
1935                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1936                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1937                 }
1938         }
1939 }
1940
1941 void LeaveSpectatorMode()
1942 {
1943         if(self.caplayer)
1944                 return;
1945         if(nJoinAllowed(self))
1946         {
1947                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1948                 {
1949                         self.classname = "player";
1950                         nades_RemoveBonus(self);
1951
1952                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1953                                 { JoinBestTeam(self, FALSE, TRUE); }
1954
1955                         if(autocvar_g_campaign)
1956                                 { campaign_bots_may_start = 1; }
1957
1958                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1959
1960                         PutClientInServer();
1961
1962                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1963                 }
1964                 else
1965                         stuffcmd(self, "menu_showteamselect\n");
1966         }
1967         else
1968         {
1969                 // Player may not join because g_maxplayers is set
1970                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1971         }
1972 }
1973
1974 /**
1975  * Determines whether the player is allowed to join. This depends on cvar
1976  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1977  * it checks whether the number of currently playing players exceeds g_maxplayers.
1978  * @return int number of free slots for players, 0 if none
1979  */
1980 float nJoinAllowed(entity ignore) {
1981         if(!ignore)
1982         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1983         // so report 0 free slots if restricted
1984         {
1985                 if(autocvar_g_forced_team_otherwise == "spectate")
1986                         return 0;
1987                 if(autocvar_g_forced_team_otherwise == "spectator")
1988                         return 0;
1989         }
1990
1991         if(self.team_forced < 0)
1992                 return 0; // forced spectators can never join
1993
1994         // TODO simplify this
1995         entity e;
1996         float totalClients = 0;
1997         FOR_EACH_CLIENT(e)
1998                 if(e != ignore)
1999                         totalClients += 1;
2000
2001         if (!autocvar_g_maxplayers)
2002                 return maxclients - totalClients;
2003
2004         float currentlyPlaying = 0;
2005         FOR_EACH_REALCLIENT(e)
2006                 if(IS_PLAYER(e) || e.caplayer == 1)
2007                         currentlyPlaying += 1;
2008
2009         if(currentlyPlaying < autocvar_g_maxplayers)
2010                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2011
2012         return 0;
2013 }
2014
2015 /**
2016  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2017  * g_maxplayers_spectator_blocktime seconds
2018  */
2019 void checkSpectatorBlock() {
2020         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2021                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2022                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2023                         dropclient(self);
2024                 }
2025         }
2026 }
2027
2028 void PrintWelcomeMessage()
2029 {
2030         if(self.motd_actived_time == 0)
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2034                                 self.motd_actived_time = time;
2035                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2036                         }
2037                 } else {
2038                         if (self.BUTTON_INFO) {
2039                                 self.motd_actived_time = time;
2040                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2041                         }
2042                 }
2043         }
2044         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2045         {
2046                 if (autocvar_g_campaign) {
2047                         if (self.BUTTON_INFO)
2048                                 self.motd_actived_time = time;
2049                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2050                                 self.motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2052                         }
2053                 } else {
2054                         if (self.BUTTON_INFO)
2055                                 self.motd_actived_time = time;
2056                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2057                                 self.motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2059                         }
2060                 }
2061         }
2062         else //if(self.motd_actived_time < 0) // just connected, motd is active
2063         {
2064                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2065                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2066                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2067                 {
2068                         // instanctly hide MOTD
2069                         self.motd_actived_time = 0;
2070                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2071                 }
2072         }
2073 }
2074
2075 void ObserverThink()
2076 {
2077         float prefered_movetype;
2078         if (self.flags & FL_JUMPRELEASED) {
2079                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2080                         self.flags &= ~FL_JUMPRELEASED;
2081                         self.flags |= FL_SPAWNING;
2082                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         if(SpectateNext()) {
2085                                 self.classname = "spectator";
2086                         }
2087                 } else {
2088                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2089                         if (self.movetype != prefered_movetype)
2090                                 self.movetype = prefered_movetype;
2091                 }
2092         } else {
2093                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2094                         self.flags |= FL_JUMPRELEASED;
2095                         if(self.flags & FL_SPAWNING)
2096                         {
2097                                 self.flags &= ~FL_SPAWNING;
2098                                 LeaveSpectatorMode();
2099                                 return;
2100                         }
2101                 }
2102         }
2103 }
2104
2105 void SpectatorThink()
2106 {
2107         if (self.flags & FL_JUMPRELEASED) {
2108                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         self.flags |= FL_SPAWNING;
2111                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2112                         self.flags &= ~FL_JUMPRELEASED;
2113                         if(SpectateNext()) {
2114                                 self.classname = "spectator";
2115                         } else {
2116                                 self.classname = "observer";
2117                                 PutClientInServer();
2118                         }
2119                         self.impulse = 0;
2120                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2121                         self.flags &= ~FL_JUMPRELEASED;
2122                         if(SpectatePrev()) {
2123                                 self.classname = "spectator";
2124                         } else {
2125                                 self.classname = "observer";
2126                                 PutClientInServer();
2127                         }
2128                         self.impulse = 0;
2129                 } else if (self.BUTTON_ATCK2) {
2130                         self.flags &= ~FL_JUMPRELEASED;
2131                         self.classname = "observer";
2132                         PutClientInServer();
2133                 } else {
2134                         if(!SpectateUpdate())
2135                                 PutObserverInServer();
2136                 }
2137         } else {
2138                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2139                         self.flags |= FL_JUMPRELEASED;
2140                         if(self.flags & FL_SPAWNING)
2141                         {
2142                                 self.flags &= ~FL_SPAWNING;
2143                                 LeaveSpectatorMode();
2144                                 return;
2145                         }
2146                 }
2147                 if(!SpectateUpdate())
2148                         PutObserverInServer();
2149         }
2150
2151         self.flags |= FL_CLIENT | FL_NOTARGET;
2152 }
2153
2154 void PlayerUseKey()
2155 {
2156         if (!IS_PLAYER(self))
2157                 return;
2158
2159         if(self.vehicle)
2160         {
2161         vehicles_exit(VHEF_NORMAL);
2162         return;
2163         }
2164
2165         // a use key was pressed; call handlers
2166         MUTATOR_CALLHOOK(PlayerUseKey);
2167 }
2168
2169 /*
2170 =============
2171 PlayerPreThink
2172
2173 Called every frame for each client before the physics are run
2174 =============
2175 */
2176 .float usekeypressed;
2177 void() nexball_setstatus;
2178 .float items_added;
2179 void PlayerPreThink (void)
2180 {
2181         WarpZone_PlayerPhysics_FixVAngle();
2182
2183         self.stat_game_starttime = game_starttime;
2184         self.stat_round_starttime = round_starttime;
2185         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2186         self.stat_leadlimit = autocvar_leadlimit;
2187
2188         if(frametime)
2189         {
2190                 // physics frames: update anticheat stuff
2191                 anticheat_prethink();
2192         }
2193
2194         if(blockSpectators && frametime)
2195                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2196                 checkSpectatorBlock();
2197
2198         zoomstate_set = 0;
2199
2200         if(self.netname_previous != self.netname)
2201         {
2202                 if(autocvar_sv_eventlog)
2203                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2204                 if(self.netname_previous)
2205                         strunzone(self.netname_previous);
2206                 self.netname_previous = strzone(self.netname);
2207         }
2208
2209         // version nagging
2210         if(self.version_nagtime)
2211                 if(self.cvar_g_xonoticversion)
2212                         if(time > self.version_nagtime)
2213                         {
2214                                 // don't notify git users
2215                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2216                                 {
2217                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2218                                         {
2219                                                 // notify release users if connecting to git
2220                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2221                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2222                                         }
2223                                         else
2224                                         {
2225                                                 float r;
2226                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2227                                                 if(r < 0)
2228                                                 {
2229                                                         // give users new version
2230                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2231                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2232                                                 }
2233                                                 else if(r > 0)
2234                                                 {
2235                                                         // notify users about old server version
2236                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2237                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2238                                                 }
2239                                         }
2240                                 }
2241                                 self.version_nagtime = 0;
2242                         }
2243
2244         // GOD MODE info
2245         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2246         {
2247                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2248                 self.max_armorvalue = 0;
2249         }
2250
2251 #ifdef TETRIS
2252         if (TetrisPreFrame())
2253                 return;
2254 #endif
2255
2256         if(self.frozen == 2)
2257         {
2258                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2259                 self.health = max(1, self.revive_progress * start_health);
2260                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2261
2262                 if(self.revive_progress >= 1)
2263                         Unfreeze(self);
2264         }
2265         else if(self.frozen == 3)
2266         {
2267                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2268                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2269
2270                 if(self.health < 1)
2271                 {
2272                         if(self.vehicle)
2273                                 vehicles_exit(VHEF_RELESE);
2274                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2275                 }
2276                 else if ( self.revive_progress <= 0 )
2277                         Unfreeze(self);
2278         }
2279
2280         MUTATOR_CALLHOOK(PlayerPreThink);
2281
2282         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2283         {
2284                 if(self.BUTTON_USE && !self.usekeypressed)
2285                         PlayerUseKey();
2286                 self.usekeypressed = self.BUTTON_USE;
2287         }
2288
2289         if(IS_REAL_CLIENT(self))
2290                 PrintWelcomeMessage();
2291
2292         if(IS_PLAYER(self))
2293         {
2294
2295                 CheckRules_Player();
2296
2297                 if (intermission_running)
2298                 {
2299                         IntermissionThink ();   // otherwise a button could be missed between
2300                         return;                                 // the think tics
2301                 }
2302
2303                 //don't allow the player to turn around while game is paused!
2304                 if(timeout_status == TIMEOUT_ACTIVE) {
2305                         // FIXME turn this into CSQC stuff
2306                         self.v_angle = self.lastV_angle;
2307                         self.angles = self.lastV_angle;
2308                         self.fixangle = TRUE;
2309                 }
2310
2311                 if(frametime)
2312                 {
2313                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2314                         {
2315                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2316                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2317                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2318
2319                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2320                                 {
2321                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2322                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2323                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2324                                 }
2325                         }
2326                         else
2327                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2328
2329                         player_powerups();
2330                 }
2331
2332                 if (self.deadflag != DEAD_NO)
2333                 {
2334                         if(self.personal && g_race_qualifying)
2335                         {
2336                                 if(time > self.respawn_time)
2337                                 {
2338                                         self.respawn_time = time + 1; // only retry once a second
2339                                         self.stat_respawn_time = self.respawn_time;
2340                                         respawn();
2341                                         self.impulse = 141;
2342                                 }
2343                         }
2344                         else
2345                         {
2346                                 float button_pressed;
2347                                 if(frametime)
2348                                         player_anim();
2349                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2350
2351                                 if (self.deadflag == DEAD_DYING)
2352                                 {
2353                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2354                                                 self.deadflag = DEAD_RESPAWNING;
2355                                         else if(!button_pressed)
2356                                                 self.deadflag = DEAD_DEAD;
2357                                 }
2358                                 else if (self.deadflag == DEAD_DEAD)
2359                                 {
2360                                         if(button_pressed)
2361                                                 self.deadflag = DEAD_RESPAWNABLE;
2362                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2363                                                 self.deadflag = DEAD_RESPAWNING;
2364                                 }
2365                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2366                                 {
2367                                         if(!button_pressed)
2368                                                 self.deadflag = DEAD_RESPAWNING;
2369                                 }
2370                                 else if (self.deadflag == DEAD_RESPAWNING)
2371                                 {
2372                                         if(time > self.respawn_time)
2373                                         {
2374                                                 self.respawn_time = time + 1; // only retry once a second
2375                                                 self.respawn_time_max = self.respawn_time;
2376                                                 respawn();
2377                                         }
2378                                 }
2379
2380                                 ShowRespawnCountdown();
2381
2382                                 if(self.respawn_flags & RESPAWN_SILENT)
2383                                         self.stat_respawn_time = 0;
2384                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2385                                         self.stat_respawn_time = self.respawn_time_max;
2386                                 else
2387                                         self.stat_respawn_time = self.respawn_time;
2388                         }
2389
2390                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2391                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2392                                 self.stat_respawn_time *= -1;
2393
2394                         return;
2395                 }
2396
2397                 self.prevorigin = self.origin;
2398
2399                 float do_crouch = self.BUTTON_CROUCH;
2400                 if(self.hook.state)
2401                         do_crouch = 0;
2402                 if(self.vehicle)
2403                         do_crouch = 0;
2404                 if(self.frozen)
2405                         do_crouch = 0;
2406                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2407                         do_crouch = 0;
2408
2409                 if (do_crouch)
2410                 {
2411                         if (!self.crouch)
2412                         {
2413                                 self.crouch = TRUE;
2414                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2415                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2416                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2417                         }
2418                 }
2419                 else
2420                 {
2421                         if (self.crouch)
2422                         {
2423                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2424                                 if (!trace_startsolid)
2425                                 {
2426                                         self.crouch = FALSE;
2427                                         self.view_ofs = PL_VIEW_OFS;
2428                                         setsize (self, PL_MIN, PL_MAX);
2429                                 }
2430                         }
2431                 }
2432
2433                 FixPlayermodel();
2434
2435                 GrapplingHookFrame();
2436
2437                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2438                 //if(frametime)
2439                 {
2440                         self.items &= ~self.items_added;
2441
2442                         W_WeaponFrame();
2443
2444                         self.items_added = 0;
2445                         if(self.items & IT_JETPACK)
2446                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2447                                         self.items_added |= IT_FUEL;
2448
2449                         self.items |= self.items_added;
2450                 }
2451
2452                 player_regen();
2453
2454                 // rot nex charge to the charge limit
2455                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2456                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2457
2458                 if(frametime)
2459                         player_anim();
2460
2461                 // secret status
2462                 secrets_setstatus();
2463
2464                 // monsters status
2465                 monsters_setstatus();
2466
2467                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2468
2469                 //self.angles_y=self.v_angle_y + 90;   // temp
2470         } else if(gameover) {
2471                 if (intermission_running)
2472                         IntermissionThink ();   // otherwise a button could be missed between
2473                 return;
2474         } else if(IS_OBSERVER(self)) {
2475                 ObserverThink();
2476         } else if(IS_SPEC(self)) {
2477                 SpectatorThink();
2478         }
2479
2480         if(!zoomstate_set)
2481                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2482
2483         float oldspectatee_status;
2484         oldspectatee_status = self.spectatee_status;
2485         if(IS_SPEC(self))
2486                 self.spectatee_status = num_for_edict(self.enemy);
2487         else if(IS_OBSERVER(self))
2488                 self.spectatee_status = num_for_edict(self);
2489         else
2490                 self.spectatee_status = 0;
2491         if(self.spectatee_status != oldspectatee_status)
2492         {
2493                 ClientData_Touch(self);
2494                 if(g_race || g_cts)
2495                         race_InitSpectator();
2496         }
2497
2498         if(self.teamkill_soundtime)
2499         if(time > self.teamkill_soundtime)
2500         {
2501                 self.teamkill_soundtime = 0;
2502
2503                 entity oldpusher, oldself;
2504
2505                 oldself = self; self = self.teamkill_soundsource;
2506                 oldpusher = self.pusher; self.pusher = oldself;
2507
2508                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2509
2510                 self.pusher = oldpusher;
2511                 self = oldself;
2512         }
2513
2514         if(self.taunt_soundtime)
2515         if(time > self.taunt_soundtime)
2516         {
2517                 self.taunt_soundtime = 0;
2518                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2519         }
2520
2521         target_voicescript_next(self);
2522
2523         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2524         if(!self.weapon)
2525                 self.clip_load = self.clip_size = 0;
2526 }
2527
2528 float isInvisibleString(string s)
2529 {
2530         float i, n, c;
2531         s = strdecolorize(s);
2532         for((i = 0), (n = strlen(s)); i < n; ++i)
2533         {
2534                 c = str2chr(s, i);
2535                 switch(c)
2536                 {
2537                         case 0:
2538                         case 32: // space
2539                                 break;
2540                         case 192: // charmap space
2541                                 if (!autocvar_utf8_enable)
2542                                         break;
2543                                 return FALSE;
2544                         case 160: // space in unicode fonts
2545                         case 0xE000 + 192: // utf8 charmap space
2546                                 if (autocvar_utf8_enable)
2547                                         break;
2548                         default:
2549                                 return FALSE;
2550                 }
2551         }
2552         return TRUE;
2553 }
2554
2555 /*
2556 =============
2557 PlayerPostThink
2558
2559 Called every frame for each client after the physics are run
2560 =============
2561 */
2562 .float idlekick_lasttimeleft;
2563 void PlayerPostThink (void)
2564 {
2565         // Savage: Check for nameless players
2566         if (isInvisibleString(self.netname)) {
2567                 self.netname = "Player";
2568                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2569         }
2570
2571         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2572         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2573         {
2574                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2575                 {
2576                         if(self.idlekick_lasttimeleft)
2577                         {
2578                                 self.idlekick_lasttimeleft = 0;
2579                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2580                         }
2581                 }
2582                 else
2583                 {
2584                         float timeleft;
2585                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2586                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2587                         {
2588                                 if(!self.idlekick_lasttimeleft)
2589                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2590                         }
2591                         if(timeleft <= 0)
2592                         {
2593                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2594                                 dropclient(self);
2595                                 return;
2596                         }
2597                         else if(timeleft <= 10)
2598                         {
2599                                 if(timeleft != self.idlekick_lasttimeleft)
2600                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2601                                 self.idlekick_lasttimeleft = timeleft;
2602                         }
2603                 }
2604         }
2605
2606 #ifdef TETRIS
2607         if(self.impulse == 100)
2608                 ImpulseCommands();
2609         if (!TetrisPostFrame())
2610         {
2611 #endif
2612
2613         CheatFrame();
2614
2615         //CheckPlayerJump();
2616
2617         if(IS_PLAYER(self)) {
2618                 CheckRules_Player();
2619                 UpdateChatBubble();
2620                 if (self.impulse)
2621                         ImpulseCommands();
2622                 if (intermission_running)
2623                         return;         // intermission or finale
2624                 GetPressedKeys();
2625         }
2626
2627 #ifdef TETRIS
2628         }
2629 #endif
2630
2631         /*
2632         float i;
2633         for(i = 0; i < 1000; ++i)
2634         {
2635                 vector end;
2636                 end = self.origin + '0 0 1024' + 512 * randomvec();
2637                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2638                 if(trace_fraction < 1)
2639                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2640                 {
2641                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2642                         break;
2643                 }
2644         }
2645         */
2646
2647         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2648
2649         if(self.waypointsprite_attachedforcarrier)
2650                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2651
2652         playerdemo_write();
2653
2654         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2655         {
2656                 if (!self.stored_netname)
2657                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2658                 if(self.stored_netname != self.netname)
2659                 {
2660                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2661                         strunzone(self.stored_netname);
2662                         self.stored_netname = strzone(self.netname);
2663                 }
2664         }
2665
2666         /*
2667         if(g_race)
2668                 dprintf("%f %.6f\n", time, race_GetFractionalLapCount(self));
2669         */
2670
2671         CSQCMODEL_AUTOUPDATE();
2672 }