qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         float teamcheck;
 321         entity firstspot_new;
 322         entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.damagedbycontents = FALSE;
 666         self.health = -666;
 667         self.takedamage = DAMAGE_NO;
 668         self.solid = SOLID_NOT;
 669         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 670         self.flags = FL_CLIENT | FL_NOTARGET;
 671         self.armorvalue = 666;
 672         self.effects = 0;
 673         self.armorvalue = autocvar_g_balance_armor_start;
 674         self.pauserotarmor_finished = 0;
 675         self.pauserothealth_finished = 0;
 676         self.pauseregen_finished = 0;
 677         self.damageforcescale = 0;
 678         self.death_time = 0;
 679         self.dead_frame = 0;
 680         self.alpha = 0;
 681         self.scale = 0;
 682         self.fade_time = 0;
 683         self.pain_frame = 0;
 684         self.pain_finished = 0;
 685         self.strength_finished = 0;
 686         self.invincible_finished = 0;
 687         self.pushltime = 0;
 688         self.think = SUB_Null;
 689         self.nextthink = 0;
 690         self.hook_time = 0;
 691         self.runes = 0;
 692         self.deadflag = DEAD_NO;
 693         self.angles = spot.angles;
 694         self.angles_z = 0;
 695         self.fixangle = TRUE;
 696         self.crouch = FALSE;
 697
 698         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 699         setorigin (self, spot.origin);
 700         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 701         self.prevorigin = self.origin;
 702         self.items = 0;
 703         self.weapons = 0;
 704         self.model = "";
 705         FixPlayermodel();
 706         self.model = "";
 707         self.modelindex = 0;
 708         self.weapon = 0;
 709         self.weaponname = "";
 710         self.switchingweapon = 0;
 711         self.weaponmodel = "";
 712         self.weaponentity = world;
 713         self.exteriorweaponentity = world;
 714         self.killcount = -666;
 715         self.velocity = '0 0 0';
 716         self.avelocity = '0 0 0';
 717         self.punchangle = '0 0 0';
 718         self.punchvector = '0 0 0';
 719         self.oldvelocity = self.velocity;
 720         self.fire_endtime = -1;
 721
 722         if(sv_loddistance1)
 723                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 724
 725         if(g_arena)
 726         {
 727                 if(self.version_mismatch)
 728                 {
 729                         Spawnqueue_Unmark(self);
 730                         Spawnqueue_Remove(self);
 731                 }
 732                 else
 733                 {
 734                         Spawnqueue_Insert(self);
 735                 }
 736         }
 737         else if(g_lms)
 738         {
 739                 // Only if the player cannot play at all
 740                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 741                         self.frags = FRAGS_SPECTATOR;
 742                 else
 743                         self.frags = FRAGS_LMS_LOSER;
 744         }
 745         else if(g_ca)
 746         {
 747                 if(self.caplayer)
 748                         self.frags = FRAGS_LMS_LOSER;
 749                 else
 750                         self.frags = FRAGS_SPECTATOR;
 751         }
 752         else
 753                 self.frags = FRAGS_SPECTATOR;
 754 }
 755
 756 void FixPlayermodel()
 757 {
 758         string defaultmodel;
 759         float defaultskin, chmdl, oldskin;
 760         vector m1, m2;
 761
 762         defaultmodel = "";
 763
 764         if(autocvar_sv_defaultcharacter == 1) {
 765                 defaultskin = 0;
 766
 767                 if(teamplay)
 768                 {
 769                         string s;
 770                         s = Team_ColorNameLowerCase(self.team);
 771                         if(s != "neutral")
 772                         {
 773                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 774                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 775                         }
 776                 }
 777
 778                 if(defaultmodel == "")
 779                 {
 780                         defaultmodel = autocvar_sv_defaultplayermodel;
 781                         defaultskin = autocvar_sv_defaultplayerskin;
 782                 }
 783         }
 784
 785         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 786         {
 787                 if(self.model != "")
 788                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 789                 self.model = ""; // force the != checks to return true
 790         }
 791
 792         if(defaultmodel != "")
 793         {
 794                 if (defaultmodel != self.model)
 795                 {
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, defaultmodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = defaultskin;
 805         } else {
 806                 if (self.playermodel != self.model || self.playermodel == "")
 807                 {
 808                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 809                         m1 = self.mins;
 810                         m2 = self.maxs;
 811                         setmodel_lod (self, self.playermodel);
 812                         setsize (self, m1, m2);
 813                         chmdl = TRUE;
 814                 }
 815
 816                 oldskin = self.skinindex;
 817                 self.skinindex = stof(self.playerskin);
 818         }
 819
 820         if(chmdl || oldskin != self.skinindex)
 821                 self.species = player_getspecies(); // model or skin has changed
 822
 823         if(!teamplay)
 824                 if(strlen(autocvar_sv_defaultplayercolors))
 825                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 826                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 827 }
 828
 829 void PlayerTouchExplode(entity p1, entity p2)
 830 {
 831         vector org;
 832         org = (p1.origin + p2.origin) * 0.5;
 833         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 834
 835         te_explosion(org);
 836
 837         entity e;
 838         e = spawn();
 839         setorigin(e, org);
 840         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 841         remove(e);
 842 }
 843
 844 /*
 845 =============
 846 PutClientInServer
 847
 848 Called when a client spawns in the server
 849 =============
 850 */
 851 //void() ctf_playerchanged;
 852 void PutClientInServer (void)
 853 {
 854         if(clienttype(self) == CLIENTTYPE_BOT)
 855         {
 856                 self.classname = "player";
 857         }
 858         else if(clienttype(self) == CLIENTTYPE_REAL)
 859         {
 860                 msg_entity = self;
 861                 WriteByte(MSG_ONE, SVC_SETVIEW);
 862                 WriteEntity(MSG_ONE, self);
 863         }
 864
 865         // reset player keys
 866         self.itemkeys = 0;
 867
 868         // player is dead and becomes observer
 869         // FIXME fix LMS scoring for new system
 870         if(g_lms)
 871         {
 872                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 873                         self.classname = "observer";
 874         }
 875
 876         if(g_arena || (g_ca && !allowed_to_spawn))
 877         if(!self.spawned)
 878                 self.classname = "observer";
 879
 880         if(gameover)
 881                 self.classname = "observer";
 882
 883         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 884                 entity spot, oldself;
 885                 float j;
 886
 887                 accuracy_resend(self);
 888
 889                 if(self.team < 0)
 890                         JoinBestTeam(self, FALSE, TRUE);
 891
 892                 race_PreSpawn();
 893
 894                 spot = SelectSpawnPoint (FALSE);
 895                 if(!spot)
 896                 {
 897                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 898                         return; // spawn failed
 899                 }
 900
 901                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 902
 903                 self.classname = "player";
 904                 self.wasplayer = TRUE;
 905                 self.iscreature = TRUE;
 906                 self.damagedbycontents = TRUE;
 907                 self.movetype = MOVETYPE_WALK;
 908                 self.solid = SOLID_SLIDEBOX;
 909                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 910                 if(autocvar_g_playerclip_collisions)
 911                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 912                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 913                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 914                 self.frags = FRAGS_PLAYER;
 915                 if(INDEPENDENT_PLAYERS)
 916                         MAKE_INDEPENDENT_PLAYER(self);
 917                 self.flags = FL_CLIENT;
 918                 if(autocvar__notarget)
 919                         self.flags |= FL_NOTARGET;
 920                 self.takedamage = DAMAGE_AIM;
 921                 if(g_minstagib)
 922                         self.effects = EF_FULLBRIGHT;
 923                 else
 924                         self.effects = 0;
 925                 self.air_finished = time + 12;
 926                 self.dmg = 2;
 927                 if(autocvar_g_balance_nex_charge)
 928                 {
 929                         if(autocvar_g_balance_nex_secondary_chargepool)
 930                                 self.nex_chargepool_ammo = 1;
 931                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 932                 }
 933
 934                 if(inWarmupStage)
 935                 {
 936                         self.ammo_shells = warmup_start_ammo_shells;
 937                         self.ammo_nails = warmup_start_ammo_nails;
 938                         self.ammo_rockets = warmup_start_ammo_rockets;
 939                         self.ammo_cells = warmup_start_ammo_cells;
 940                         self.ammo_fuel = warmup_start_ammo_fuel;
 941                         self.health = warmup_start_health;
 942                         self.armorvalue = warmup_start_armorvalue;
 943                         self.weapons = warmup_start_weapons;
 944                 }
 945                 else
 946                 {
 947                         self.ammo_shells = start_ammo_shells;
 948                         self.ammo_nails = start_ammo_nails;
 949                         self.ammo_rockets = start_ammo_rockets;
 950                         self.ammo_cells = start_ammo_cells;
 951                         self.ammo_fuel = start_ammo_fuel;
 952                         self.health = start_health;
 953                         self.armorvalue = start_armorvalue;
 954                         self.weapons = start_weapons;
 955                 }
 956
 957                 if(g_weaponarena_random)
 958                 {
 959                         if(g_weaponarena_random_with_laser)
 960                                 self.weapons &~= WEPBIT_LASER;
 961                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 962                         if(g_weaponarena_random_with_laser)
 963                                 self.weapons |= WEPBIT_LASER;
 964                 }
 965
 966                 self.items = start_items;
 967                 self.jump_interval = time;
 968
 969                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 970                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 971                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 972                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 973                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 974                 //extend the pause of rotting if client was reset at the beginning of the countdown
 975                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 976                         self.spawnshieldtime += game_starttime - time;
 977                         self.pauserotarmor_finished += game_starttime - time;
 978                         self.pauserothealth_finished += game_starttime - time;
 979                         self.pauseregen_finished += game_starttime - time;
 980                 }
 981                 self.damageforcescale = 2;
 982                 self.death_time = 0;
 983                 self.dead_frame = 0;
 984                 self.alpha = 0;
 985                 self.scale = 0;
 986                 self.fade_time = 0;
 987                 self.pain_frame = 0;
 988                 self.pain_finished = 0;
 989                 self.strength_finished = 0;
 990                 self.invincible_finished = 0;
 991                 self.pushltime = 0;
 992                 // players have no think function
 993                 self.think = SUB_Null;
 994                 self.nextthink = 0;
 995                 self.hook_time = 0;
 996                 self.dmg_team = 0;
 997                 self.ballistics_density = autocvar_g_ballistics_density_player;
 998
 999                 self.metertime = 0;
1000
1001                 self.runes = 0;
1002
1003                 self.deadflag = DEAD_NO;
1004
1005                 self.angles = spot.angles;
1006
1007                 self.angles_z = 0; // never spawn tilted even if the spot says to
1008                 self.fixangle = TRUE; // turn this way immediately
1009                 self.velocity = '0 0 0';
1010                 self.avelocity = '0 0 0';
1011                 self.punchangle = '0 0 0';
1012                 self.punchvector = '0 0 0';
1013                 self.oldvelocity = self.velocity;
1014                 self.fire_endtime = -1;
1015
1016                 msg_entity = self;
1017                 WRITESPECTATABLE_MSG_ONE({
1018                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1019                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1020                 });
1021
1022                 if(sv_loddistance1)
1023                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1024
1025                 self.model = "";
1026                 FixPlayermodel();
1027
1028                 self.crouch = FALSE;
1029                 self.view_ofs = PL_VIEW_OFS;
1030                 setsize (self, PL_MIN, PL_MAX);
1031                 self.spawnorigin = spot.origin;
1032                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1033                 // don't reset back to last position, even if new position is stuck in solid
1034                 self.oldorigin = self.origin;
1035                 self.prevorigin = self.origin;
1036                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1037                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1038         self.hud = HUD_NORMAL;
1039
1040                 if(g_arena)
1041                 {
1042                         Spawnqueue_Remove(self);
1043                         Spawnqueue_Mark(self);
1044                 }
1045
1046                 else if(g_ca)
1047                         self.caplayer = 1;
1048
1049                 self.event_damage = PlayerDamage;
1050
1051                 self.bot_attack = TRUE;
1052
1053                 self.statdraintime = time + 5;
1054                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1055
1056                 if(self.killcount == -666) {
1057                         PlayerScore_Clear(self);
1058                         self.killcount = 0;
1059                 }
1060
1061                 CL_SpawnWeaponentity();
1062                 self.alpha = default_player_alpha;
1063                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1064                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1065
1066                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1067                 self.lms_traveled_distance = 0;
1068                 self.speedrunning = FALSE;
1069
1070                 race_PostSpawn(spot);
1071
1072                 if(autocvar_spawn_debug)
1073                 {
1074                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1075                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1076                 }
1077
1078                 //stuffcmd(self, "chase_active 0");
1079                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1080
1081                 if (autocvar_g_spawnsound)
1082                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1083
1084                 if(g_assault) {
1085                         if(self.team == assault_attacker_team)
1086                                 centerprint(self, "You are attacking!");
1087                         else
1088                                 centerprint(self, "You are defending!");
1089                 }
1090
1091                 target_voicescript_clear(self);
1092
1093                 // reset fields the weapons may use
1094                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1095                 {
1096                         weapon_action(j, WR_RESETPLAYER);
1097
1098                         // all weapons must be fully loaded when we spawn
1099                         entity e;
1100                         e = get_weaponinfo(j);
1101                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1102                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1103                 }
1104
1105                 oldself = self;
1106                 self = spot;
1107                         activator = oldself;
1108                                 string s;
1109                                 s = self.target;
1110                                 self.target = string_null;
1111                                 SUB_UseTargets();
1112                                 self.target = s;
1113                         activator = world;
1114                 self = oldself;
1115
1116                 MUTATOR_CALLHOOK(PlayerSpawn);
1117
1118                 self.switchweapon = w_getbestweapon(self);
1119                 self.cnt = -1; // W_LastWeapon will not complain
1120                 self.weapon = 0;
1121                 self.weaponname = "";
1122                 self.switchingweapon = 0;
1123
1124                 if(!self.alivetime)
1125                         self.alivetime = time;
1126         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1127                 PutObserverInServer ();
1128         }
1129
1130         //if(g_ctf)
1131         //      ctf_playerchanged();
1132 }
1133
1134 .float ebouncefactor, ebouncestop; // electro's values
1135 // TODO do we need all these fields, or should we stop autodetecting runtime
1136 // changes and just have a console command to update this?
1137 float ClientInit_SendEntity(entity to, float sf)
1138 {
1139         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1140         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1145         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1146         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1147         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1148         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1149         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1150         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1151         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1152         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1153         if(sv_foginterval && world.fog != "")
1154                 WriteString(MSG_ENTITY, world.fog);
1155         else
1156                 WriteString(MSG_ENTITY, "");
1157         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1158         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1159         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1160         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1161         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1162         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1163         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1164         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1165         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1166         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1167         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1168         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1169         return TRUE;
1170 }
1171
1172 void ClientInit_CheckUpdate()
1173 {
1174         self.nextthink = time;
1175         if(self.count != autocvar_g_balance_armor_blockpercent)
1176         {
1177                 self.count = autocvar_g_balance_armor_blockpercent;
1178                 self.SendFlags |= 1;
1179         }
1180         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1181         {
1182                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1183                 self.SendFlags |= 1;
1184         }
1185         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1186         {
1187                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1188                 self.SendFlags |= 1;
1189         }
1190         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1191         {
1192                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1193                 self.SendFlags |= 1;
1194         }
1195         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1196         {
1197                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1198                 self.SendFlags |= 1;
1199         }
1200         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1201         {
1202                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1203                 self.SendFlags |= 1;
1204         }
1205 }
1206
1207 void ClientInit_Spawn()
1208 {
1209         entity o;
1210         entity e;
1211         e = spawn();
1212         e.classname = "clientinit";
1213         e.think = ClientInit_CheckUpdate;
1214         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1215
1216         o = self;
1217         self = e;
1218         ClientInit_CheckUpdate();
1219         self = o;
1220 }
1221
1222 /*
1223 =============
1224 SetNewParms
1225 =============
1226 */
1227 void SetNewParms (void)
1228 {
1229         // initialize parms for a new player
1230         parm1 = -(86400 * 366);
1231 }
1232
1233 /*
1234 =============
1235 SetChangeParms
1236 =============
1237 */
1238 void SetChangeParms (void)
1239 {
1240         // save parms for level change
1241         parm1 = self.parm_idlesince - time;
1242 }
1243
1244 /*
1245 =============
1246 DecodeLevelParms
1247 =============
1248 */
1249 void DecodeLevelParms (void)
1250 {
1251         // load parms
1252         self.parm_idlesince = parm1;
1253         if(self.parm_idlesince == -(86400 * 366))
1254                 self.parm_idlesince = time;
1255
1256         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1257         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1258 }
1259
1260 /*
1261 =============
1262 ClientKill
1263
1264 Called when a client types 'kill' in the console
1265 =============
1266 */
1267
1268 .float clientkill_nexttime;
1269 void ClientKill_Now_TeamChange()
1270 {
1271         if(self.killindicator_teamchange == -1)
1272         {
1273                 self.team = -1;
1274                 JoinBestTeam( self, FALSE, FALSE );
1275         }
1276         else if(self.killindicator_teamchange == -2)
1277         {
1278                 if(g_ca)
1279                         self.caplayer = 0;
1280                 if(blockSpectators)
1281                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1282                 PutObserverInServer();
1283         }
1284         else
1285                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1286 }
1287
1288 void ClientKill_Now()
1289 {
1290         if(self.vehicle)
1291         {
1292             vehicles_exit(VHEF_RELESE);
1293             if(!self.killindicator_teamchange)
1294             {
1295             self.vehicle_health = -1;
1296             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1297             }
1298         }
1299
1300         if(self.killindicator && !wasfreed(self.killindicator))
1301                 remove(self.killindicator);
1302
1303         self.killindicator = world;
1304
1305         if(self.killindicator_teamchange)
1306                 ClientKill_Now_TeamChange();
1307
1308         // in any case:
1309         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1310
1311         // now I am sure the player IS dead
1312 }
1313 void KillIndicator_Think()
1314 {
1315         if (gameover)
1316         {
1317                 self.owner.killindicator = world;
1318                 remove(self);
1319                 return;
1320         }
1321
1322         if (!self.owner.modelindex)
1323         {
1324                 self.owner.killindicator = world;
1325                 remove(self);
1326                 return;
1327         }
1328
1329         if(self.cnt <= 0)
1330         {
1331                 self = self.owner;
1332                 ClientKill_Now(); // no oldself needed
1333                 return;
1334         }
1335     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1336     {
1337         self.nextthink = time + 1;
1338         self.cnt -= 1;
1339     }
1340         else
1341         {
1342                 if(self.cnt <= 10)
1343                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1344                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1345                 {
1346                         if(self.cnt <= 10)
1347                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1348                 }
1349                 self.nextthink = time + 1;
1350                 self.cnt -= 1;
1351         }
1352 }
1353
1354 float clientkilltime;
1355 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1356 {
1357         float killtime;
1358         float starttime;
1359         entity e;
1360
1361         if (gameover)
1362                 return;
1363
1364         killtime = autocvar_g_balance_kill_delay;
1365
1366         if(g_race_qualifying || g_cts)
1367                 killtime = 0;
1368
1369     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1370     {
1371                 remove(self.killindicator);
1372                 self.killindicator = world;
1373
1374         ClientKill_Now(); // allow instant kill in this case
1375         return;
1376     }
1377
1378         self.killindicator_teamchange = targetteam;
1379
1380     if(!self.killindicator)
1381         {
1382                 if(self.modelindex && self.deadflag == DEAD_NO)
1383                 {
1384                         killtime = max(killtime, self.clientkill_nexttime - time);
1385                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1386                 }
1387
1388                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1389                 {
1390                         ClientKill_Now();
1391                 }
1392                 else
1393                 {
1394                         starttime = max(time, clientkilltime);
1395
1396                         self.killindicator = spawn();
1397                         self.killindicator.owner = self;
1398                         self.killindicator.scale = 0.5;
1399                         setattachment(self.killindicator, self, "");
1400                         setorigin(self.killindicator, '0 0 52');
1401                         self.killindicator.think = KillIndicator_Think;
1402                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1403                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1404                         self.killindicator.cnt = ceil(killtime);
1405                         self.killindicator.count = bound(0, ceil(killtime), 10);
1406                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1407
1408                         for(e = world; (e = find(e, classname, "body")) != world; )
1409                         {
1410                                 if(e.enemy != self)
1411                                         continue;
1412                                 e.killindicator = spawn();
1413                                 e.killindicator.owner = e;
1414                                 e.killindicator.scale = 0.5;
1415                                 setattachment(e.killindicator, e, "");
1416                                 setorigin(e.killindicator, '0 0 52');
1417                                 e.killindicator.think = KillIndicator_Think;
1418                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1419                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1420                                 e.killindicator.cnt = ceil(killtime);
1421                         }
1422                         self.lip = 0;
1423                 }
1424         }
1425         if(self.killindicator)
1426         {
1427                 if(targetteam == 0) // just die
1428                 {
1429                         self.killindicator.colormod = '0 0 0';
1430                         if(clienttype(self) == CLIENTTYPE_REAL)
1431                         if(self.killindicator.cnt > 0)
1432                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1433                 }
1434                 else if(targetteam == -1) // auto
1435                 {
1436                         self.killindicator.colormod = '0 1 0';
1437                         if(clienttype(self) == CLIENTTYPE_REAL)
1438                         if(self.killindicator.cnt > 0)
1439                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1440                 }
1441                 else if(targetteam == -2) // spectate
1442                 {
1443                         self.killindicator.colormod = '0.5 0.5 0.5';
1444                         if(clienttype(self) == CLIENTTYPE_REAL)
1445                         if(self.killindicator.cnt > 0)
1446                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1447                 }
1448                 else
1449                 {
1450                         self.killindicator.colormod = TeamColor(targetteam);
1451                         if(clienttype(self) == CLIENTTYPE_REAL)
1452                         if(self.killindicator.cnt > 0)
1453                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1454                 }
1455         }
1456
1457 }
1458
1459 void ClientKill (void)
1460 {
1461         if (gameover)
1462                 return;
1463
1464         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1465         {
1466                 // do nothing
1467         }
1468     else if(self.freezetag_frozen)
1469     {
1470         // do nothing
1471     }
1472         else
1473                 ClientKill_TeamChange(0);
1474 }
1475
1476 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1477 {
1478     e.killindicator = spawn();
1479     e.killindicator.owner = e;
1480     e.killindicator.think = KillIndicator_Think;
1481     e.killindicator.nextthink = time + (e.lip) * 0.05;
1482     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1483     e.killindicator.health = 1; // this is used to indicate that it should be silent
1484     e.lip = 0;
1485 }
1486
1487 void FixClientCvars(entity e)
1488 {
1489         // send prediction settings to the client
1490         stuffcmd(e, "\nin_bindmap 0 0\n");
1491         if(g_race || g_cts)
1492                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1493         if(autocvar_g_antilag == 3) // client side hitscan
1494                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1495         if(sv_gentle)
1496                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1497         /*
1498          * we no longer need to stuff this. Remove this comment block if you feel
1499          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1500         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1501         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1502         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1503         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1504         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1505         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1506         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1507         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1508         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1509         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1510         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1511         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1512         stuffcmd(e, "cl_movement_edgefriction 1\n");
1513          */
1514 }
1515
1516 float PlayerInIDList(entity p, string idlist)
1517 {
1518         float n, i;
1519         string s;
1520
1521         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1522         if not(p.crypto_idfp)
1523                 return 0;
1524
1525         // this function allows abbreviated player IDs too!
1526         n = tokenize_console(idlist);
1527         for(i = 0; i < n; ++i)
1528         {
1529                 s = argv(i);
1530                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1531                         return 1;
1532         }
1533
1534         return 0;
1535 }
1536
1537 /*
1538 =============
1539 ClientConnect
1540
1541 Called when a client connects to the server
1542 =============
1543 */
1544 //void ctf_clientconnect();
1545 string ColoredTeamName(float t);
1546 void DecodeLevelParms (void);
1547 //void dom_player_join_team(entity pl);
1548 void set_dom_state(entity e);
1549 void ClientConnect (void)
1550 {
1551         float t;
1552
1553         if(self.flags & FL_CLIENT)
1554         {
1555                 print("Warning: ClientConnect, but already connected!\n");
1556                 return;
1557         }
1558
1559         if(Ban_MaybeEnforceBan(self))
1560                 return;
1561
1562         DecodeLevelParms();
1563
1564 #ifdef WATERMARK
1565         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1566 #endif
1567
1568         self.classname = "player_joining";
1569
1570         self.flags = FL_CLIENT;
1571         self.version_nagtime = time + 10 + random() * 10;
1572
1573         if(player_count<0)
1574         {
1575                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1576                 player_count = 0;
1577         }
1578
1579         PlayerScore_Attach(self);
1580         ClientData_Attach();
1581         accuracy_init(self);
1582
1583         bot_clientconnect();
1584
1585         playerdemo_init();
1586
1587         anticheat_init();
1588
1589         race_PreSpawnObserver();
1590
1591         //if(g_domination)
1592         //      dom_player_join_team(self);
1593
1594         // identify the right forced team
1595         if(autocvar_g_campaign)
1596         {
1597                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1598                 {
1599                         switch(autocvar_g_campaign_forceteam)
1600                         {
1601                                 case 1: self.team_forced = COLOR_TEAM1; break;
1602                                 case 2: self.team_forced = COLOR_TEAM2; break;
1603                                 case 3: self.team_forced = COLOR_TEAM3; break;
1604                                 case 4: self.team_forced = COLOR_TEAM4; break;
1605                                 default: self.team_forced = 0;
1606                         }
1607                 }
1608         }
1609         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1610                 self.team_forced = COLOR_TEAM1;
1611         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1612                 self.team_forced = COLOR_TEAM2;
1613         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1614                 self.team_forced = COLOR_TEAM3;
1615         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1616                 self.team_forced = COLOR_TEAM4;
1617         else if(autocvar_g_forced_team_otherwise == "red")
1618                 self.team_forced = COLOR_TEAM1;
1619         else if(autocvar_g_forced_team_otherwise == "blue")
1620                 self.team_forced = COLOR_TEAM2;
1621         else if(autocvar_g_forced_team_otherwise == "yellow")
1622                 self.team_forced = COLOR_TEAM3;
1623         else if(autocvar_g_forced_team_otherwise == "pink")
1624                 self.team_forced = COLOR_TEAM4;
1625         else if(autocvar_g_forced_team_otherwise == "spectate")
1626                 self.team_forced = -1;
1627         else if(autocvar_g_forced_team_otherwise == "spectator")
1628                 self.team_forced = -1;
1629         else
1630                 self.team_forced = 0;
1631
1632         if(!teamplay)
1633                 if(self.team_forced > 0)
1634                         self.team_forced = 0;
1635
1636         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1637
1638         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1639                 self.classname = "observer";
1640         } else {
1641                 if(teamplay)
1642                 {
1643                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1644                         {
1645                                 self.classname = "player";
1646                                 campaign_bots_may_start = 1;
1647                         }
1648                         else
1649                         {
1650                                 self.classname = "observer"; // do it anyway
1651                         }
1652                 }
1653                 else
1654                 {
1655                         self.classname = "player";
1656                         campaign_bots_may_start = 1;
1657                 }
1658         }
1659
1660         self.playerid = (playerid_last = playerid_last + 1);
1661
1662         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1663
1664     if(clienttype(self) == CLIENTTYPE_BOT)
1665         PlayerStats_AddPlayer(self);
1666
1667         if(autocvar_sv_eventlog)
1668                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1669
1670         LogTeamchange(self.playerid, self.team, 1);
1671
1672         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1673
1674         self.netname_previous = strzone(self.netname);
1675
1676         bprint("^4", self.netname, "^4 connected");
1677
1678         if(self.classname != "observer" && (g_domination || g_ctf))
1679                 bprint(" and joined the ", ColoredTeamName(self.team));
1680
1681         bprint("\n");
1682
1683         stuffcmd(self, strcat(clientstuff, "\n"));
1684         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1685
1686         FixClientCvars(self);
1687
1688         // spawnfunc_waypoint sprites
1689         WaypointSprite_InitClient(self);
1690
1691         // Wazat's grappling hook
1692         SetGrappleHookBindings();
1693
1694         // get autoswitch state from player when he toggles it
1695         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1696
1697         // get version info from player
1698         stuffcmd(self, "cmd clientversion $gameversion\n");
1699
1700         // get other cvars from player
1701         GetCvars(0);
1702
1703         // notify about available teams
1704         if(teamplay)
1705         {
1706                 CheckAllowedTeams(self);
1707                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1708                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1709         }
1710         else
1711                 stuffcmd(self, "set _teams_available 0\n");
1712
1713         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1714
1715         if(g_arena || g_ca)
1716         {
1717                 self.classname = "observer";
1718                 if(g_arena)
1719                         Spawnqueue_Insert(self);
1720         }
1721         /*else if(g_ctf)
1722         {
1723                 ctf_clientconnect();
1724         }*/
1725
1726         attach_entcs();
1727
1728         bot_relinkplayerlist();
1729
1730         self.spectatortime = time;
1731         if(blockSpectators)
1732         {
1733                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1734         }
1735
1736         self.jointime = time;
1737         self.allowedTimeouts = autocvar_sv_timeout_number;
1738
1739         if(clienttype(self) == CLIENTTYPE_REAL)
1740         {
1741                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1742                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1743         }
1744
1745         if(g_lms)
1746         {
1747                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1748                 {
1749                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1750                         self.frags = FRAGS_SPECTATOR;
1751                 }
1752         }
1753
1754         if(!sv_foginterval && world.fog != "")
1755                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1756
1757         SoundEntity_Attach(self);
1758
1759         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1760         {
1761                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1762                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1763         }
1764         else
1765                 self.hitplotfh = -1;
1766
1767         if(g_race || g_cts) {
1768                 string rr;
1769                 if(g_cts)
1770                         rr = CTS_RECORD;
1771                 else
1772                         rr = RACE_RECORD;
1773                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1774
1775                 msg_entity = self;
1776                 race_send_recordtime(MSG_ONE);
1777                 race_send_speedaward(MSG_ONE);
1778
1779                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1780                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1781                 race_send_speedaward_alltimebest(MSG_ONE);
1782
1783                 float i;
1784                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1785                         race_SendRankings(i, 0, 0, MSG_ONE);
1786                 }
1787         }
1788         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1789                 send_CSQC_teamnagger();
1790
1791         if (g_domination)
1792                 set_dom_state(self);
1793
1794         CheatInitClient();
1795
1796         if(!autocvar_g_campaign)
1797                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1798
1799         CSQCModel_LinkEntity();
1800 }
1801
1802 /*
1803 =============
1804 ClientDisconnect
1805
1806 Called when a client disconnects from the server
1807 =============
1808 */
1809 .entity chatbubbleentity;
1810 void ReadyCount();
1811 void ClientDisconnect (void)
1812 {
1813         if(self.vehicle)
1814             vehicles_exit(VHEF_RELESE);
1815
1816         if not(self.flags & FL_CLIENT)
1817         {
1818                 print("Warning: ClientDisconnect without ClientConnect\n");
1819                 return;
1820         }
1821
1822         PlayerStats_AddGlobalInfo(self);
1823
1824         CheatShutdownClient();
1825
1826         if(self.hitplotfh >= 0)
1827         {
1828                 fclose(self.hitplotfh);
1829                 self.hitplotfh = -1;
1830         }
1831
1832         anticheat_report();
1833         anticheat_shutdown();
1834
1835         playerdemo_shutdown();
1836
1837         bot_clientdisconnect();
1838
1839         if(self.entcs)
1840                 detach_entcs();
1841
1842         if(autocvar_sv_eventlog)
1843                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1844         bprint ("^4",self.netname);
1845         bprint ("^4 disconnected\n");
1846
1847         SoundEntity_Detach(self);
1848
1849         DropAllRunes(self);
1850         MUTATOR_CALLHOOK(ClientDisconnect);
1851
1852         Portal_ClearAll(self);
1853
1854         RemoveGrapplingHook(self);
1855         if(self.flagcarried)
1856                 DropFlag(self.flagcarried, world, world);
1857         if(self.ballcarried && g_nexball)
1858                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1859
1860         // Here, everything has been done that requires this player to be a client.
1861
1862         self.flags &~= FL_CLIENT;
1863
1864         if (self.chatbubbleentity)
1865                 remove (self.chatbubbleentity);
1866
1867         if (self.killindicator)
1868                 remove (self.killindicator);
1869
1870         WaypointSprite_PlayerGone();
1871
1872         bot_relinkplayerlist();
1873
1874         if(g_arena)
1875         {
1876                 Spawnqueue_Unmark(self);
1877                 Spawnqueue_Remove(self);
1878         }
1879
1880         accuracy_free(self);
1881         ClientData_Detach();
1882         PlayerScore_Detach(self);
1883
1884         if(self.netname_previous)
1885                 strunzone(self.netname_previous);
1886         if(self.clientstatus)
1887                 strunzone(self.clientstatus);
1888         if(self.weaponorder_byimpulse)
1889                 strunzone(self.weaponorder_byimpulse);
1890
1891         ClearPlayerSounds();
1892
1893         if(self.personal)
1894                 remove(self.personal);
1895
1896         self.playerid = 0;
1897         ReadyCount();
1898
1899         // free cvars
1900         GetCvars(-1);
1901 }
1902
1903 .float BUTTON_CHAT;
1904 void ChatBubbleThink()
1905 {
1906         self.nextthink = time;
1907         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1908         {
1909                 if(self.owner) // but why can that ever be world?
1910                         self.owner.chatbubbleentity = world;
1911                 remove(self);
1912                 return;
1913         }
1914         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1915 #ifdef TETRIS
1916                 || self.owner.tetris_on
1917 #endif
1918         )
1919                 self.model = self.mdl;
1920         else
1921                 self.model = "";
1922 }
1923
1924 void UpdateChatBubble()
1925 {
1926         if (!self.modelindex)
1927                 return;
1928         // spawn a chatbubble entity if needed
1929         if (!self.chatbubbleentity)
1930         {
1931                 self.chatbubbleentity = spawn();
1932                 self.chatbubbleentity.owner = self;
1933                 self.chatbubbleentity.exteriormodeltoclient = self;
1934                 self.chatbubbleentity.think = ChatBubbleThink;
1935                 self.chatbubbleentity.nextthink = time;
1936                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1937                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1938                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1939                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1940                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1941                 self.chatbubbleentity.model = "";
1942                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1943         }
1944 }
1945
1946
1947 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1948 // added to the model skins
1949 /*void UpdateColorModHack()
1950 {
1951         float c;
1952         c = self.clientcolors & 15;
1953         // LordHavoc: only bothering to support white, green, red, yellow, blue
1954              if (!teamplay) self.colormod = '0 0 0';
1955         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1956         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1957         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1958         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1959         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1960         else self.colormod = '1 1 1';
1961 }*/
1962
1963 .float oldcolormap;
1964 void respawn(void)
1965 {
1966         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1967         {
1968                 self.solid = SOLID_NOT;
1969                 self.takedamage = DAMAGE_NO;
1970                 self.movetype = MOVETYPE_FLY;
1971                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1972                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1973                 self.effects |= EF_ADDITIVE;
1974                 self.oldcolormap = self.colormap;
1975                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1976                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1977                 if(autocvar_g_respawn_ghosts_maxtime)
1978                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1979         }
1980
1981         CopyBody(1);
1982         self.effects |= EF_NODRAW; // prevent another CopyBody
1983         if(self.oldcolormap)
1984         {
1985                 self.colormap = self.oldcolormap;
1986                 self.oldcolormap = 0;
1987         }
1988         PutClientInServer();
1989 }
1990
1991 void play_countdown(float finished, string samp)
1992 {
1993         if(clienttype(self) == CLIENTTYPE_REAL)
1994                 if(floor(finished - time - frametime) != floor(finished - time))
1995                         if(finished - time < 6)
1996                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1997 }
1998
1999 void player_powerups (void)
2000 {
2001         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2002         olditems = self.items;
2003
2004         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2005         {
2006                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2007                 self.modelflags |= MF_ROCKET;
2008         }
2009         else
2010         {
2011                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2012                 self.modelflags &~= MF_ROCKET;
2013         }
2014
2015         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2016
2017         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2018                 return;
2019
2020         Fire_ApplyDamage(self);
2021         Fire_ApplyEffect(self);
2022
2023         if (g_minstagib)
2024         {
2025                 self.effects |= EF_FULLBRIGHT;
2026
2027                 if (self.items & IT_STRENGTH)
2028                 {
2029                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2030                         if (time > self.strength_finished)
2031                         {
2032                                 self.alpha = default_player_alpha;
2033                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2034                                 self.items &~= IT_STRENGTH;
2035                                 sprint(self, "^3Invisibility has worn off\n");
2036                         }
2037                 }
2038                 else
2039                 {
2040                         if (time < self.strength_finished)
2041                         {
2042                                 self.alpha = g_minstagib_invis_alpha;
2043                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2044                                 self.items |= IT_STRENGTH;
2045                                 sprint(self, "^3You are invisible\n");
2046                         }
2047                 }
2048
2049                 if (self.items & IT_INVINCIBLE)
2050                 {
2051                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2052                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2053                         {
2054                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2055                                 sprint(self, "^3Speed has worn off\n");
2056                         }
2057                 }
2058                 else
2059                 {
2060                         if (time < self.invincible_finished)
2061                         {
2062                                 self.items = self.items | IT_INVINCIBLE;
2063                                 sprint(self, "^3You are on speed\n");
2064                         }
2065                 }
2066         }
2067         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2068         {
2069                 if (self.items & IT_STRENGTH)
2070                 {
2071                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2072                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2073                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2074                         {
2075                                 self.items = self.items - (self.items & IT_STRENGTH);
2076                                 sprint(self, "^3Strength has worn off\n");
2077                         }
2078                 }
2079                 else
2080                 {
2081                         if (time < self.strength_finished)
2082                         {
2083                                 self.items = self.items | IT_STRENGTH;
2084                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2085                         }
2086                 }
2087                 if (self.items & IT_INVINCIBLE)
2088                 {
2089                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2090                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2091                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2092                         {
2093                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2094                                 sprint(self, "^3Shield has worn off\n");
2095                         }
2096                 }
2097                 else
2098                 {
2099                         if (time < self.invincible_finished)
2100                         {
2101                                 self.items = self.items | IT_INVINCIBLE;
2102                                 sprint(self, "^3Shield surrounds you\n");
2103                         }
2104                 }
2105
2106                 if(autocvar_g_nodepthtestplayers)
2107                         self.effects = self.effects | EF_NODEPTHTEST;
2108
2109                 if(autocvar_g_fullbrightplayers)
2110                         self.effects = self.effects | EF_FULLBRIGHT;
2111
2112                 // midair gamemode: damage only while in the air
2113                 // if in midair mode, being on ground grants temporary invulnerability
2114                 // (this is so that multishot weapon don't clear the ground flag on the
2115                 // first damage in the frame, leaving the player vulnerable to the
2116                 // remaining hits in the same frame)
2117                 if (self.flags & FL_ONGROUND)
2118                 if (g_midair)
2119                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2120
2121                 if (time >= game_starttime)
2122                 if (time < self.spawnshieldtime)
2123                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2124         }
2125
2126         MUTATOR_CALLHOOK(PlayerPowerups);
2127 }
2128
2129 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2130 {
2131         if(current > stable)
2132                 return current;
2133         else if(current > stable - 0.25) // when close enough, "snap"
2134                 return stable;
2135         else
2136                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2137 }
2138
2139 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2140 {
2141         if(current < stable)
2142                 return current;
2143         else if(current < stable + 0.25) // when close enough, "snap"
2144                 return stable;
2145         else
2146                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2147 }
2148
2149 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2150 {
2151         if(current > rotstable)
2152         {
2153                 if(rotframetime > 0)
2154                 {
2155                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2156                         current = max(rotstable, current - rotlinear * rotframetime);
2157                 }
2158         }
2159         else if(current < regenstable)
2160         {
2161                 if(regenframetime > 0)
2162                 {
2163                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2164                         current = min(regenstable, current + regenlinear * regenframetime);
2165                 }
2166         }
2167
2168         if(current > limit)
2169                 current = limit;
2170
2171         return current;
2172 }
2173
2174 void player_regen (void)
2175 {
2176         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2177         maxh = autocvar_g_balance_health_rotstable;
2178         maxa = autocvar_g_balance_armor_rotstable;
2179         maxf = autocvar_g_balance_fuel_rotstable;
2180         minh = autocvar_g_balance_health_regenstable;
2181         mina = autocvar_g_balance_armor_regenstable;
2182         minf = autocvar_g_balance_fuel_regenstable;
2183         limith = autocvar_g_balance_health_limit;
2184         limita = autocvar_g_balance_armor_limit;
2185         limitf = autocvar_g_balance_fuel_limit;
2186
2187         max_mod = regen_mod = rot_mod = limit_mod = 1;
2188
2189         if (self.runes & RUNE_REGEN)
2190         {
2191                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2192                 {
2193                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2194                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2195                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2196                 }
2197                 else
2198                 {
2199                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2200                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2201                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2202                 }
2203         }
2204         else if (self.runes & CURSE_VENOM)
2205         {
2206                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2207                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2208                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2209                 else
2210                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2211                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2212                 //if (!self.runes & RUNE_REGEN)
2213                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2214         }
2215         maxh = maxh * max_mod;
2216         //maxa = maxa * max_mod;
2217         //maxf = maxf * max_mod;
2218         minh = minh * max_mod;
2219         //mina = mina * max_mod;
2220         //minf = minf * max_mod;
2221         limith = limith * limit_mod;
2222         limita = limita * limit_mod;
2223         //limitf = limitf * limit_mod;
2224
2225         if(g_lms && g_ca)
2226                 rot_mod = 0;
2227
2228         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2229         {
2230                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2231                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2232
2233                 // if player rotted to death...  die!
2234                 if(self.health < 1)
2235                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2236         }
2237
2238         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2239                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2240 }
2241
2242 float zoomstate_set;
2243 void SetZoomState(float z)
2244 {
2245         if(z != self.zoomstate)
2246         {
2247                 self.zoomstate = z;
2248                 ClientData_Touch(self);
2249         }
2250         zoomstate_set = 1;
2251 }
2252
2253 void GetPressedKeys(void) {
2254         MUTATOR_CALLHOOK(GetPressedKeys);
2255         if (self.movement_x > 0) // get if movement keys are pressed
2256         {       // forward key pressed
2257                 self.pressedkeys |= KEY_FORWARD;
2258                 self.pressedkeys &~= KEY_BACKWARD;
2259         }
2260         else if (self.movement_x < 0)
2261         {       // backward key pressed
2262                 self.pressedkeys |= KEY_BACKWARD;
2263                 self.pressedkeys &~= KEY_FORWARD;
2264         }
2265         else
2266         {       // no x input
2267                 self.pressedkeys &~= KEY_FORWARD;
2268                 self.pressedkeys &~= KEY_BACKWARD;
2269         }
2270
2271         if (self.movement_y > 0)
2272         {       // right key pressed
2273                 self.pressedkeys |= KEY_RIGHT;
2274                 self.pressedkeys &~= KEY_LEFT;
2275         }
2276         else if (self.movement_y < 0)
2277         {       // left key pressed
2278                 self.pressedkeys |= KEY_LEFT;
2279                 self.pressedkeys &~= KEY_RIGHT;
2280         }
2281         else
2282         {       // no y input
2283                 self.pressedkeys &~= KEY_RIGHT;
2284                 self.pressedkeys &~= KEY_LEFT;
2285         }
2286
2287         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2288                 self.pressedkeys |= KEY_JUMP;
2289         else
2290                 self.pressedkeys &~= KEY_JUMP;
2291         if (self.BUTTON_CROUCH)
2292                 self.pressedkeys |= KEY_CROUCH;
2293         else
2294                 self.pressedkeys &~= KEY_CROUCH;
2295 }
2296
2297 /*
2298 ======================
2299 spectate mode routines
2300 ======================
2301 */
2302
2303 void SpectateCopy(entity spectatee) {
2304         other = spectatee;
2305         MUTATOR_CALLHOOK(SpectateCopy);
2306         self.armortype = spectatee.armortype;
2307         self.armorvalue = spectatee.armorvalue;
2308         self.ammo_cells = spectatee.ammo_cells;
2309         self.ammo_shells = spectatee.ammo_shells;
2310         self.ammo_nails = spectatee.ammo_nails;
2311         self.ammo_rockets = spectatee.ammo_rockets;
2312         self.ammo_fuel = spectatee.ammo_fuel;
2313         self.clip_load = spectatee.clip_load;
2314         self.clip_size = spectatee.clip_size;
2315         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2316         self.health = spectatee.health;
2317         self.impulse = 0;
2318         self.items = spectatee.items;
2319         self.last_pickup = spectatee.last_pickup;
2320         self.hit_time = spectatee.hit_time;
2321         self.metertime = spectatee.metertime;
2322         self.strength_finished = spectatee.strength_finished;
2323         self.invincible_finished = spectatee.invincible_finished;
2324         self.pressedkeys = spectatee.pressedkeys;
2325         self.weapons = spectatee.weapons;
2326         self.switchweapon = spectatee.switchweapon;
2327         self.switchingweapon = spectatee.switchingweapon;
2328         self.weapon = spectatee.weapon;
2329         self.nex_charge = spectatee.nex_charge;
2330         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2331         self.hagar_load = spectatee.hagar_load;
2332         self.minelayer_mines = spectatee.minelayer_mines;
2333         self.punchangle = spectatee.punchangle;
2334         self.view_ofs = spectatee.view_ofs;
2335         self.v_angle = spectatee.v_angle;
2336         self.velocity = spectatee.velocity;
2337         self.dmg_take = spectatee.dmg_take;
2338         self.dmg_save = spectatee.dmg_save;
2339         self.dmg_inflictor = spectatee.dmg_inflictor;
2340         self.angles = spectatee.v_angle;
2341         if(!self.BUTTON_USE)
2342                 self.fixangle = TRUE;
2343         setorigin(self, spectatee.origin);
2344         setsize(self, spectatee.mins, spectatee.maxs);
2345         SetZoomState(spectatee.zoomstate);
2346
2347         anticheat_spectatecopy(spectatee);
2348
2349         //self.vehicle = spectatee.vehicle;
2350
2351         self.hud = spectatee.hud;
2352         if(spectatee.vehicle)
2353     {
2354         setorigin(self, spectatee.origin);
2355         self.velocity = spectatee.vehicle.velocity;
2356         self.v_angle += spectatee.vehicle.angles;
2357         //self.v_angle_x *= -1;
2358         self.vehicle_health = spectatee.vehicle_health;
2359         self.vehicle_shield = spectatee.vehicle_shield;
2360         self.vehicle_energy = spectatee.vehicle_energy;
2361         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2362         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2363         self.vehicle_reload1 = spectatee.vehicle_reload1;
2364         self.vehicle_reload2 = spectatee.vehicle_reload2;
2365
2366         msg_entity = self;
2367         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2368         WriteEntity(MSG_ONE, spectatee);
2369         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2370     }
2371 }
2372
2373 float SpectateUpdate() {
2374         if(!self.enemy)
2375             return 0;
2376
2377         if (self == self.enemy)
2378                 return 0;
2379
2380         if(self.enemy.classname != "player")
2381                 return 0;
2382
2383         SpectateCopy(self.enemy);
2384
2385         return 1;
2386 }
2387
2388
2389 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2390 entity CA_SpectateNext(entity start) {
2391         if (start.team == self.team) {
2392                 return start;
2393         }
2394
2395         other = start;
2396         // continue from current player
2397         while(other && other.team != self.team) {
2398                 other = find(other, classname, "player");
2399         }
2400
2401         if (!other) {
2402                 // restart from begining
2403                 other = find(other, classname, "player");
2404                 while(other && other.team != self.team) {
2405                         other = find(other, classname, "player");
2406                 }
2407         }
2408
2409         return other;
2410 }
2411
2412 float SpectateNext() {
2413         other = find(self.enemy, classname, "player");
2414         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2415                 // CA and ca players when spectating enemies is forbidden
2416                 other = CA_SpectateNext(other);
2417         } else {
2418                 // other modes and ca spectators or spectating enemies is allowed
2419                 if (!other)
2420                         other = find(other, classname, "player");
2421         }
2422
2423         if (other)
2424                 self.enemy = other;
2425
2426         if(self.enemy.classname == "player") {
2427             if(self.enemy.vehicle)
2428             {
2429             msg_entity = self;
2430             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2431             WriteEntity(MSG_ONE, self.enemy);
2432             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2433             self.movetype = MOVETYPE_NONE;
2434             accuracy_resend(self);
2435             }
2436             else
2437             {
2438             msg_entity = self;
2439             WriteByte(MSG_ONE, SVC_SETVIEW);
2440             WriteEntity(MSG_ONE, self.enemy);
2441             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2442             self.movetype = MOVETYPE_NONE;
2443             accuracy_resend(self);
2444
2445             if(!SpectateUpdate())
2446                 PutObserverInServer();
2447         }
2448         return 1;
2449         } else {
2450                 return 0;
2451         }
2452 }
2453
2454 /*
2455 =============
2456 ShowRespawnCountdown()
2457
2458 Update a respawn countdown display.
2459 =============
2460 */
2461 void ShowRespawnCountdown()
2462 {
2463         float number;
2464         if(self.deadflag == DEAD_NO) // just respawned?
2465                 return;
2466         else
2467         {
2468                 number = ceil(self.death_time - time);
2469                 if(number <= 0)
2470                         return;
2471                 if(number <= self.respawn_countdown)
2472                 {
2473                         self.respawn_countdown = number - 1;
2474                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2475                                 AnnounceTo(self, strcat(ftos(number), ""));
2476                 }
2477         }
2478 }
2479
2480 .float prevent_join_msgtime;
2481 void LeaveSpectatorMode()
2482 {
2483         if(nJoinAllowed(1)) {
2484                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2485                         self.classname = "player";
2486
2487                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2488                                 JoinBestTeam(self, FALSE, TRUE);
2489
2490                         if(autocvar_g_campaign)
2491                                 campaign_bots_may_start = 1;
2492
2493                         PutClientInServer();
2494
2495                         if(self.classname == "player")
2496                                 bprint ("^4", self.netname, "^4 is playing now\n");
2497
2498                         if(!autocvar_g_campaign)
2499                         if (time < self.jointime + autocvar_welcome_message_time)
2500                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2501
2502                         if (self.prevent_join_msgtime)
2503                         {
2504                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2505                                 self.prevent_join_msgtime = 0;
2506                         }
2507
2508                         return;
2509                 } else {
2510                         if (g_ca && self.caplayer) {
2511                         }       // do nothing
2512                         else
2513                                 stuffcmd(self,"menu_showteamselect\n");
2514                         return;
2515                 }
2516         }
2517         else {
2518                 //player may not join because of g_maxplayers is set
2519                 if (time - self.prevent_join_msgtime > 2)
2520                 {
2521                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2522                         self.prevent_join_msgtime = time;
2523                 }
2524         }
2525 }
2526
2527 /**
2528  * Determines whether the player is allowed to join. This depends on cvar
2529  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2530  * it checks whether the number of currently playing players exceeds g_maxplayers.
2531  * @return int number of free slots for players, 0 if none
2532  */
2533 float nJoinAllowed(float includeMe) {
2534         if(self.team_forced < 0)
2535                 return FALSE; // forced spectators can never join
2536
2537         // TODO simplify this
2538         entity e;
2539
2540         float totalClients;
2541         FOR_EACH_CLIENT(e)
2542                 totalClients += 1;
2543
2544         if (!autocvar_g_maxplayers)
2545                 return maxclients - totalClients + includeMe;
2546
2547         float currentlyPlaying;
2548         FOR_EACH_REALPLAYER(e)
2549                 currentlyPlaying += 1;
2550
2551         if(currentlyPlaying < autocvar_g_maxplayers)
2552                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2553
2554         return 0;
2555 }
2556
2557 /**
2558  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2559  * g_maxplayers_spectator_blocktime seconds
2560  */
2561 void checkSpectatorBlock() {
2562         if(self.classname == "spectator" || self.classname == "observer") {
2563                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2564                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2565                         dropclient(self);
2566                 }
2567         }
2568 }
2569
2570 .float motd_actived_time; // used for both motd and campaign_message
2571 void PrintWelcomeMessage()
2572 {
2573         if (self.motd_actived_time == 0) { // is there already a message showing?
2574                 if (autocvar_g_campaign) {
2575                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2576                                 self.motd_actived_time = time;
2577                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2578                         }
2579                 } else {
2580                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2581                                 self.motd_actived_time = time;
2582                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2583                         }
2584                 }
2585         } else { // showing MOTD or campaign message
2586                 if (autocvar_g_campaign) {
2587                         if (self.BUTTON_INFO)
2588                                 self.motd_actived_time = time;
2589                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2590                                 self.motd_actived_time = 0;
2591                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2592                         }
2593                 } else {
2594                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2595                                 if (self.BUTTON_INFO)
2596                                         self.motd_actived_time = time;
2597                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2598                                         self.motd_actived_time = 0;
2599                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2600                                 }
2601                         }
2602                 }
2603         }
2604 }
2605
2606 void ObserverThink()
2607 {
2608         float prefered_movetype;
2609         if (self.flags & FL_JUMPRELEASED) {
2610                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2611                         self.flags &~= FL_JUMPRELEASED;
2612                         self.flags |= FL_SPAWNING;
2613                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2614                         self.flags &~= FL_JUMPRELEASED;
2615                         if(SpectateNext() == 1) {
2616                                 self.classname = "spectator";
2617                         }
2618                 } else {
2619                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2620                         if (self.movetype != prefered_movetype)
2621                                 self.movetype = prefered_movetype;
2622                 }
2623         } else {
2624                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2625                         self.flags |= FL_JUMPRELEASED;
2626                         if(self.flags & FL_SPAWNING)
2627                         {
2628                                 self.flags &~= FL_SPAWNING;
2629                                 LeaveSpectatorMode();
2630                                 return;
2631                         }
2632                 }
2633         }
2634
2635         PrintWelcomeMessage();
2636 }
2637
2638 void SpectatorThink()
2639 {
2640         if (self.flags & FL_JUMPRELEASED) {
2641                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2642                         self.flags &~= FL_JUMPRELEASED;
2643                         self.flags |= FL_SPAWNING;
2644                 } else if(self.BUTTON_ATCK) {
2645                         self.flags &~= FL_JUMPRELEASED;
2646                         if(SpectateNext() == 1) {
2647                                 self.classname = "spectator";
2648                         } else {
2649                                 self.classname = "observer";
2650                                 PutClientInServer();
2651                         }
2652                 } else if (self.BUTTON_ATCK2) {
2653                         self.flags &~= FL_JUMPRELEASED;
2654                         self.classname = "observer";
2655                         PutClientInServer();
2656                 } else {
2657                         if(!SpectateUpdate())
2658                                 PutObserverInServer();
2659                 }
2660         } else {
2661                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2662                         self.flags |= FL_JUMPRELEASED;
2663                         if(self.flags & FL_SPAWNING)
2664                         {
2665                                 self.flags &~= FL_SPAWNING;
2666                                 LeaveSpectatorMode();
2667                                 return;
2668                         }
2669                 }
2670                 if(!SpectateUpdate())
2671                         PutObserverInServer();
2672         }
2673
2674         PrintWelcomeMessage();
2675         self.flags |= FL_CLIENT | FL_NOTARGET;
2676 }
2677
2678 float ctf_usekey();
2679 void PlayerUseKey()
2680 {
2681         if(self.classname != "player")
2682                 return;
2683
2684         if(self.vehicle)
2685         {
2686         vehicles_exit(VHEF_NORMAL);
2687         return;
2688         }
2689
2690         // a use key was pressed; call handlers
2691         if(ctf_usekey())
2692                 return;
2693
2694         MUTATOR_CALLHOOK(PlayerUseKey);
2695 }
2696
2697 .float touchexplode_time;
2698
2699 /*
2700 =============
2701 PlayerPreThink
2702
2703 Called every frame for each client before the physics are run
2704 =============
2705 */
2706 .float usekeypressed;
2707 void() ctf_setstatus;
2708 void() nexball_setstatus;
2709 .float items_added;
2710 void PlayerPreThink (void)
2711 {
2712         WarpZone_PlayerPhysics_FixVAngle();
2713
2714         self.stat_game_starttime = game_starttime;
2715         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2716         self.stat_leadlimit = autocvar_leadlimit;
2717
2718         if(frametime)
2719         {
2720                 // physics frames: update anticheat stuff
2721                 anticheat_prethink();
2722         }
2723
2724         if(blockSpectators && frametime)
2725                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2726                 checkSpectatorBlock();
2727
2728         zoomstate_set = 0;
2729
2730         if(self.netname_previous != self.netname)
2731         {
2732                 if(autocvar_sv_eventlog)
2733                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2734                 if(self.netname_previous)
2735                         strunzone(self.netname_previous);
2736                 self.netname_previous = strzone(self.netname);
2737         }
2738
2739         // version nagging
2740         if(self.version_nagtime)
2741                 if(self.cvar_g_xonoticversion)
2742                         if(time > self.version_nagtime)
2743                         {
2744                                 // don't notify git users
2745                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2746                                 {
2747                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2748                                         {
2749                                                 // notify release users if connecting to git
2750                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2751                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2752                                         }
2753                                         else
2754                                         {
2755                                                 float r;
2756                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2757                                                 if(r < 0)
2758                                                 {
2759                                                         // give users new version
2760                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2761                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2762                                                 }
2763                                                 else if(r > 0)
2764                                                 {
2765                                                         // notify users about old server version
2766                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2767                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2768                                                 }
2769                                         }
2770                                 }
2771                                 self.version_nagtime = 0;
2772                         }
2773
2774         // GOD MODE info
2775         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2776         {
2777                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2778                 self.max_armorvalue = 0;
2779         }
2780
2781 #ifdef TETRIS
2782         if (TetrisPreFrame())
2783                 return;
2784 #endif
2785
2786         MUTATOR_CALLHOOK(PlayerPreThink);
2787
2788         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2789         {
2790                 if(self.BUTTON_USE && !self.usekeypressed)
2791                         PlayerUseKey();
2792                 self.usekeypressed = self.BUTTON_USE;
2793         }
2794
2795         PrintWelcomeMessage();
2796
2797         if(self.classname == "player") {
2798 //              if(self.netname == "Wazat")
2799 //                      bprint(self.classname, "\n");
2800
2801                 CheckRules_Player();
2802
2803                 if (intermission_running)
2804                 {
2805                         IntermissionThink ();   // otherwise a button could be missed between
2806                         return;                                 // the think tics
2807                 }
2808
2809                 //don't allow the player to turn around while game is paused!
2810                 if(timeoutStatus == 2) {
2811                         // FIXME turn this into CSQC stuff
2812                         self.v_angle = self.lastV_angle;
2813                         self.angles = self.lastV_angle;
2814                         self.fixangle = TRUE;
2815                 }
2816
2817                 if(frametime)
2818                 {
2819                         if(self.health <= 0 && autocvar_g_deathglow)
2820                         {
2821                                 if(self.glowmod_x > 0)
2822                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2823                                 else
2824                                         self.glowmod_x = -1;
2825                                 if(self.glowmod_y > 0)
2826                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2827                                 else
2828                                         self.glowmod_y = -1;
2829                                 if(self.glowmod_z > 0)
2830                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2831                                 else
2832                                         self.glowmod_z = -1;
2833                         }
2834                         else
2835                         {
2836                                 // set weapon and player glowmod
2837                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2838
2839                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2840                                 {
2841                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2842                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2843                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2844
2845                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2846                                         {
2847                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2848                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2849                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2850                                         }
2851                                 }
2852                                 else
2853                                         self.weaponentity_glowmod = self.glowmod;
2854                         }
2855                         player_powerups();
2856                 }
2857
2858                 if (g_minstagib)
2859                         minstagib_ammocheck();
2860
2861                 if (self.deadflag != DEAD_NO)
2862                 {
2863                         float button_pressed, force_respawn;
2864                         if(self.personal && g_race_qualifying)
2865                         {
2866                                 if(time > self.death_time)
2867                                 {
2868                                         self.death_time = time + 1; // only retry once a second
2869                                         respawn();
2870                                         self.impulse = 141;
2871                                 }
2872                         }
2873                         else
2874                         {
2875                                 if(frametime)
2876                                         player_anim();
2877                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2878                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2879                                 if (self.deadflag == DEAD_DYING)
2880                                 {
2881                                         if(force_respawn)
2882                                                 self.deadflag = DEAD_RESPAWNING;
2883                                         else if(!button_pressed)
2884                                                 self.deadflag = DEAD_DEAD;
2885                                 }
2886                                 else if (self.deadflag == DEAD_DEAD)
2887                                 {
2888                                         if(button_pressed)
2889                                                 self.deadflag = DEAD_RESPAWNABLE;
2890                                 }
2891                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2892                                 {
2893                                         if(!button_pressed)
2894                                                 self.deadflag = DEAD_RESPAWNING;
2895                                 }
2896                                 else if (self.deadflag == DEAD_RESPAWNING)
2897                                 {
2898                                         if(time > self.death_time)
2899                                         {
2900                                                 self.death_time = time + 1; // only retry once a second
2901                                                 respawn();
2902                                         }
2903                                 }
2904                                 ShowRespawnCountdown();
2905                         }
2906                         return;
2907                 }
2908                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2909                 // so (self.deadflag == DEAD_NO) is always true in the code below
2910
2911                 if(g_touchexplode)
2912                 if(time > self.touchexplode_time)
2913                 if(self.classname == "player")
2914                 if(self.deadflag == DEAD_NO)
2915                 if not(IS_INDEPENDENT_PLAYER(self))
2916                 FOR_EACH_PLAYER(other) if(self != other)
2917                 {
2918                         if(time > other.touchexplode_time)
2919                         if(other.deadflag == DEAD_NO)
2920                         if not(IS_INDEPENDENT_PLAYER(other))
2921                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2922                         {
2923                                 PlayerTouchExplode(self, other);
2924                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2925                         }
2926                 }
2927
2928                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2929                 {
2930                         vector dist;
2931
2932                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2933                         dist = self.prevorigin - self.origin;
2934                         dist_z = 0;
2935                         self.lms_traveled_distance += fabs(vlen(dist));
2936
2937                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2938                         {
2939                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2940                                 self.lms_traveled_distance = 0;
2941                         }
2942
2943                         if(time > self.lms_nextcheck)
2944                         {
2945                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2946                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2947                                 {
2948                                         centerprint(self, autocvar_g_lms_campcheck_message);
2949                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2950                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2951                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2952                                 }
2953                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2954                                 self.lms_traveled_distance = 0;
2955                         }
2956                 }
2957
2958                 self.prevorigin = self.origin;
2959
2960                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2961                 {
2962                         if (!self.crouch)
2963                         {
2964                                 self.crouch = TRUE;
2965                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2966                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2967                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2968                         }
2969                 }
2970                 else
2971                 {
2972                         if (self.crouch)
2973                         {
2974                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2975                                 if (!trace_startsolid)
2976                                 {
2977                                         self.crouch = FALSE;
2978                                         self.view_ofs = PL_VIEW_OFS;
2979                                         setsize (self, PL_MIN, PL_MAX);
2980                                 }
2981                         }
2982                 }
2983
2984                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2985                 {
2986                         if(self.bloodloss_timer < time)
2987                         {
2988                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2989                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2990                         }
2991                 }
2992
2993                 FixPlayermodel();
2994
2995                 GrapplingHookFrame();
2996
2997                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2998                 //if(frametime)
2999                 {
3000                         self.items &~= self.items_added;
3001
3002                         W_WeaponFrame();
3003
3004                         self.items_added = 0;
3005                         if(self.items & IT_JETPACK)
3006                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
3007                                         self.items_added |= IT_FUEL;
3008
3009                         self.items |= self.items_added;
3010                 }
3011
3012                 player_regen();
3013
3014                 // rot nex charge to the charge limit
3015                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3016                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3017
3018                 if(frametime)
3019                         player_anim();
3020
3021                 if(g_ctf)
3022                         ctf_setstatus();
3023
3024                 if(g_nexball)
3025                         nexball_setstatus();
3026
3027                 // secret status
3028                 secrets_setstatus();
3029
3030                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3031
3032                 //self.angles_y=self.v_angle_y + 90;   // temp
3033         } else if(gameover) {
3034                 if (intermission_running)
3035                         IntermissionThink ();   // otherwise a button could be missed between
3036                 return;
3037         } else if(self.classname == "observer") {
3038                 ObserverThink();
3039         } else if(self.classname == "spectator") {
3040                 SpectatorThink();
3041         }
3042
3043         if(!zoomstate_set)
3044                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3045
3046         float oldspectatee_status;
3047         oldspectatee_status = self.spectatee_status;
3048         if(self.classname == "spectator")
3049                 self.spectatee_status = num_for_edict(self.enemy);
3050         else if(self.classname == "observer")
3051                 self.spectatee_status = num_for_edict(self);
3052         else
3053                 self.spectatee_status = 0;
3054         if(self.spectatee_status != oldspectatee_status)
3055         {
3056                 ClientData_Touch(self);
3057                 if(g_race || g_cts)
3058                         race_InitSpectator();
3059         }
3060
3061         if(self.teamkill_soundtime)
3062         if(time > self.teamkill_soundtime)
3063         {
3064                 self.teamkill_soundtime = 0;
3065
3066                 entity oldpusher, oldself;
3067
3068                 oldself = self; self = self.teamkill_soundsource;
3069                 oldpusher = self.pusher; self.pusher = oldself;
3070
3071                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3072
3073                 self.pusher = oldpusher;
3074                 self = oldself;
3075         }
3076
3077         if(self.taunt_soundtime)
3078         if(time > self.taunt_soundtime)
3079         {
3080                 self.taunt_soundtime = 0;
3081                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3082         }
3083
3084         target_voicescript_next(self);
3085
3086         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3087         if(!self.weapon)
3088                 self.clip_load = self.clip_size = 0;
3089 }
3090
3091 float isInvisibleString(string s)
3092 {
3093         float i, n, c;
3094         s = strdecolorize(s);
3095         for((i = 0), (n = strlen(s)); i < n; ++i)
3096         {
3097                 c = str2chr(s, i);
3098                 switch(c)
3099                 {
3100                         case 0:
3101                         case 32: // space
3102                                 break;
3103                         case 192: // charmap space
3104                                 if (!autocvar_utf8_enable)
3105                                         break;
3106                                 return FALSE;
3107                         case 160: // space in unicode fonts
3108                         case 0xE000 + 192: // utf8 charmap space
3109                                 if (autocvar_utf8_enable)
3110                                         break;
3111                         default:
3112                                 return FALSE;
3113                 }
3114         }
3115         return TRUE;
3116 }
3117
3118 /*
3119 =============
3120 PlayerPostThink
3121
3122 Called every frame for each client after the physics are run
3123 =============
3124 */
3125 .float idlekick_lasttimeleft;
3126 .entity showheadshotbbox;
3127 void showheadshotbbox_think()
3128 {
3129         if(self.owner.showheadshotbbox != self)
3130         {
3131                 remove(self);
3132                 return;
3133         }
3134         self.nextthink = time;
3135         setorigin(self, self.owner.origin);
3136         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3137 }
3138 void PlayerPostThink (void)
3139 {
3140         // Savage: Check for nameless players
3141         if (isInvisibleString(self.netname)) {
3142                 self.netname = "Player";
3143                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3144         }
3145
3146         if(sv_maxidle && frametime)
3147         {
3148                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3149                 float timeleft;
3150                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3151                 {
3152                         if(self.idlekick_lasttimeleft)
3153                         {
3154                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3155                                 self.idlekick_lasttimeleft = 0;
3156                         }
3157                         return;
3158                 }
3159                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3160                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3161                 {
3162                         if(!self.idlekick_lasttimeleft)
3163                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3164                 }
3165                 if(timeleft <= 0)
3166                 {
3167                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3168                         AnnounceTo(self, "terminated");
3169                         dropclient(self);
3170                         return;
3171                 }
3172                 else if(timeleft <= 10)
3173                 {
3174                         if(timeleft != self.idlekick_lasttimeleft)
3175                                 AnnounceTo(self, ftos(timeleft));
3176                         self.idlekick_lasttimeleft = timeleft;
3177                 }
3178         }
3179
3180 #ifdef TETRIS
3181         if(self.impulse == 100)
3182                 ImpulseCommands();
3183         if (TetrisPostFrame())
3184                 return;
3185 #endif
3186
3187         CheatFrame();
3188
3189         //CheckPlayerJump();
3190
3191         if(self.classname == "player") {
3192                 CheckRules_Player();
3193                 UpdateChatBubble();
3194                 if (self.impulse)
3195                         ImpulseCommands();
3196                 if (intermission_running)
3197                         return;         // intermission or finale
3198                 GetPressedKeys();
3199         } else if (self.classname == "observer") {
3200                 //do nothing
3201         } else if (self.classname == "spectator") {
3202                 //do nothing
3203         }
3204
3205         /*
3206         float i;
3207         for(i = 0; i < 1000; ++i)
3208         {
3209                 vector end;
3210                 end = self.origin + '0 0 1024' + 512 * randomvec();
3211                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3212                 if(trace_fraction < 1)
3213                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3214                 {
3215                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3216                         break;
3217                 }
3218         }
3219         */
3220
3221         Arena_Warmup();
3222
3223         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3224
3225         if(self.waypointsprite_attachedforcarrier)
3226                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3227
3228         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3229         {
3230                 if(!self.showheadshotbbox)
3231                 {
3232                         self.showheadshotbbox = spawn();
3233                         self.showheadshotbbox.classname = "headshotbbox";
3234                         self.showheadshotbbox.owner = self;
3235                         self.showheadshotbbox.think = showheadshotbbox_think;
3236                         self.showheadshotbbox.nextthink = time;
3237                         self = self.showheadshotbbox;
3238                         self.think();
3239                         self = self.owner;
3240                 }
3241         }
3242         else
3243         {
3244                 if(self.showheadshotbbox)
3245                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3246                 remove(self.showheadshotbbox);
3247         }
3248
3249         playerdemo_write();
3250
3251         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3252         {
3253                 if(!self.stored_netname)
3254                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3255                 if(self.stored_netname != self.netname)
3256                 {
3257                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3258                         strunzone(self.stored_netname);
3259                         self.stored_netname = strzone(self.netname);
3260                 }
3261         }
3262
3263         /*
3264         if(g_race)
3265                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3266         */
3267
3268         CSQCModel_CheckUpdate();
3269 }