qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.respawn_schedule = 0;
 465         self.alpha = 0;
 466         self.scale = 0;
 467         self.fade_time = 0;
 468         self.pain_frame = 0;
 469         self.pain_finished = 0;
 470         self.strength_finished = 0;
 471         self.invincible_finished = 0;
 472         self.superweapons_finished = 0;
 473         self.pushltime = 0;
 474         self.istypefrag = 0;
 475         self.think = SUB_Null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         Spawnqueue_Unmark(self);
 516                         Spawnqueue_Remove(self);
 517                 }
 518                 else
 519                 {
 520                         Spawnqueue_Insert(self);
 521                 }
 522         }
 523         else if(g_lms)
 524         {
 525                 // Only if the player cannot play at all
 526                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 527                         self.frags = FRAGS_SPECTATOR;
 528                 else
 529                         self.frags = FRAGS_LMS_LOSER;
 530         }
 531         else if(g_ca)
 532         {
 533                 if(self.caplayer)
 534                         self.frags = FRAGS_LMS_LOSER;
 535                 else
 536                         self.frags = FRAGS_SPECTATOR;
 537         }
 538         else
 539                 self.frags = FRAGS_SPECTATOR;
 540 }
 541
 542 .float model_randomizer;
 543 void FixPlayermodel()
 544 {
 545         string defaultmodel;
 546         float defaultskin, chmdl, oldskin, n, i;
 547         vector m1, m2;
 548
 549         defaultmodel = "";
 550         defaultskin = 0;
 551         chmdl = FALSE;
 552
 553         if(autocvar_sv_defaultcharacter == 1)
 554         {
 555                 if(teamplay)
 556                 {
 557                         string s;
 558                         s = Team_ColorNameLowerCase(self.team);
 559                         if(s != "neutral")
 560                         {
 561                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 562                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 563                         }
 564                 }
 565
 566                 if(defaultmodel == "")
 567                 {
 568                         defaultmodel = autocvar_sv_defaultplayermodel;
 569                         defaultskin = autocvar_sv_defaultplayerskin;
 570                 }
 571
 572                 n = tokenize_console(defaultmodel);
 573                 if(n > 0)
 574                         defaultmodel = argv(floor(n * self.model_randomizer));
 575
 576                 i = strstrofs(defaultmodel, ":", 0);
 577                 if(i >= 0)
 578                 {
 579                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 580                         defaultmodel = substring(defaultmodel, 0, i);
 581                 }
 582         }
 583
 584         if(defaultmodel != "")
 585         {
 586                 if (defaultmodel != self.model)
 587                 {
 588                         m1 = self.mins;
 589                         m2 = self.maxs;
 590                         setplayermodel (self, defaultmodel);
 591                         setsize (self, m1, m2);
 592                         chmdl = TRUE;
 593                 }
 594
 595                 oldskin = self.skin;
 596                 self.skin = defaultskin;
 597         } else {
 598                 if (self.playermodel != self.model || self.playermodel == "")
 599                 {
 600                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 601                         m1 = self.mins;
 602                         m2 = self.maxs;
 603                         setplayermodel (self, self.playermodel);
 604                         setsize (self, m1, m2);
 605                         chmdl = TRUE;
 606                 }
 607
 608                 oldskin = self.skin;
 609                 self.skin = stof(self.playerskin);
 610         }
 611
 612         if(chmdl || oldskin != self.skin)
 613                 self.species = player_getspecies(); // model or skin has changed
 614
 615         if(!teamplay)
 616                 if(strlen(autocvar_sv_defaultplayercolors))
 617                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 618                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 619 }
 620
 621 void PlayerTouchExplode(entity p1, entity p2)
 622 {
 623         vector org;
 624         org = (p1.origin + p2.origin) * 0.5;
 625         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 626
 627         te_explosion(org);
 628
 629         entity e;
 630         e = spawn();
 631         setorigin(e, org);
 632         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 633         remove(e);
 634 }
 635
 636 /*
 637 =============
 638 PutClientInServer
 639
 640 Called when a client spawns in the server
 641 =============
 642 */
 643
 644 void PutClientInServer (void)
 645 {
 646         if(clienttype(self) == CLIENTTYPE_BOT)
 647         {
 648                 self.classname = "player";
 649                 if(g_ca)
 650                         self.caplayer = 1;
 651         }
 652         else if(clienttype(self) == CLIENTTYPE_REAL)
 653         {
 654                 msg_entity = self;
 655                 WriteByte(MSG_ONE, SVC_SETVIEW);
 656                 WriteEntity(MSG_ONE, self);
 657         }
 658
 659         // reset player keys
 660         self.itemkeys = 0;
 661
 662         // player is dead and becomes observer
 663         // FIXME fix LMS scoring for new system
 664         if(g_lms)
 665         {
 666                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 667                         self.classname = "observer";
 668         }
 669
 670         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 671                 self.classname = "observer";
 672
 673         if(gameover)
 674                 self.classname = "observer";
 675
 676         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 677                 entity spot, oldself;
 678                 float j;
 679
 680                 accuracy_resend(self);
 681
 682                 if(self.team < 0)
 683                         JoinBestTeam(self, FALSE, TRUE);
 684
 685                 race_PreSpawn();
 686
 687                 spot = SelectSpawnPoint (FALSE);
 688                 if(!spot)
 689                 {
 690                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 691                         return; // spawn failed
 692                 }
 693
 694                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 695
 696                 self.classname = "player";
 697                 self.wasplayer = TRUE;
 698                 self.iscreature = TRUE;
 699                 self.teleportable = TELEPORT_NORMAL;
 700                 self.damagedbycontents = TRUE;
 701                 self.movetype = MOVETYPE_WALK;
 702                 self.solid = SOLID_SLIDEBOX;
 703                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 704                 if(autocvar_g_playerclip_collisions)
 705                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 706                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 707                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 708                 self.frags = FRAGS_PLAYER;
 709                 if(INDEPENDENT_PLAYERS)
 710                         MAKE_INDEPENDENT_PLAYER(self);
 711                 self.flags = FL_CLIENT;
 712                 if(autocvar__notarget)
 713                         self.flags |= FL_NOTARGET;
 714                 self.takedamage = DAMAGE_AIM;
 715                 if(g_minstagib)
 716                         self.effects = EF_FULLBRIGHT;
 717                 else
 718                         self.effects = 0;
 719                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 720                 self.air_finished = time + 12;
 721                 self.dmg = 2;
 722                 if(autocvar_g_balance_nex_charge)
 723                 {
 724                         if(autocvar_g_balance_nex_secondary_chargepool)
 725                                 self.nex_chargepool_ammo = 1;
 726                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 727                 }
 728
 729                 if(inWarmupStage)
 730                 {
 731                         self.ammo_shells = warmup_start_ammo_shells;
 732                         self.ammo_nails = warmup_start_ammo_nails;
 733                         self.ammo_rockets = warmup_start_ammo_rockets;
 734                         self.ammo_cells = warmup_start_ammo_cells;
 735                         self.ammo_fuel = warmup_start_ammo_fuel;
 736                         self.health = warmup_start_health;
 737                         self.armorvalue = warmup_start_armorvalue;
 738                         WEPSET_COPY_EA(self, warmup_start_weapons);
 739                 }
 740                 else
 741                 {
 742                         self.ammo_shells = start_ammo_shells;
 743                         self.ammo_nails = start_ammo_nails;
 744                         self.ammo_rockets = start_ammo_rockets;
 745                         self.ammo_cells = start_ammo_cells;
 746                         self.ammo_fuel = start_ammo_fuel;
 747                         self.health = start_health;
 748                         self.armorvalue = start_armorvalue;
 749                         WEPSET_COPY_EA(self, start_weapons);
 750                 }
 751
 752                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 753                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 754                 else
 755                         self.superweapons_finished = 0;
 756
 757                 if(g_weaponarena_random)
 758                 {
 759                         if(g_weaponarena_random_with_laser)
 760                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 761                         W_RandomWeapons(self, g_weaponarena_random);
 762                         if(g_weaponarena_random_with_laser)
 763                                 WEPSET_OR_EW(self, WEP_LASER);
 764                 }
 765
 766                 self.items = start_items;
 767
 768                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 769                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 770                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 771                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 772                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 773                 //extend the pause of rotting if client was reset at the beginning of the countdown
 774                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 775                         self.spawnshieldtime += game_starttime - time;
 776                         self.pauserotarmor_finished += game_starttime - time;
 777                         self.pauserothealth_finished += game_starttime - time;
 778                         self.pauseregen_finished += game_starttime - time;
 779                 }
 780                 self.damageforcescale = 2;
 781                 self.death_time = 0;
 782                 self.respawn_time = 0;
 783                 self.respawn_schedule = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796                 self.ballistics_density = autocvar_g_ballistics_density_player;
 797
 798                 self.metertime = 0;
 799
 800                 self.runes = 0;
 801
 802                 self.deadflag = DEAD_NO;
 803
 804                 self.angles = spot.angles;
 805
 806                 self.angles_z = 0; // never spawn tilted even if the spot says to
 807                 self.fixangle = TRUE; // turn this way immediately
 808                 self.velocity = '0 0 0';
 809                 self.avelocity = '0 0 0';
 810                 self.punchangle = '0 0 0';
 811                 self.punchvector = '0 0 0';
 812                 self.oldvelocity = self.velocity;
 813                 self.fire_endtime = -1;
 814
 815                 msg_entity = self;
 816                 WRITESPECTATABLE_MSG_ONE({
 817                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 818                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 819                 });
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823                 self.drawonlytoclient = world;
 824
 825                 self.crouch = FALSE;
 826                 self.view_ofs = PL_VIEW_OFS;
 827                 setsize (self, PL_MIN, PL_MAX);
 828                 self.spawnorigin = spot.origin;
 829                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 830                 // don't reset back to last position, even if new position is stuck in solid
 831                 self.oldorigin = self.origin;
 832                 self.prevorigin = self.origin;
 833                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 834                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 835         self.hud = HUD_NORMAL;
 836
 837                 if(g_arena)
 838                 {
 839                         Spawnqueue_Remove(self);
 840                         Spawnqueue_Mark(self);
 841                 }
 842                 else if(g_ca)
 843                         self.caplayer = 1;
 844
 845                 self.event_damage = PlayerDamage;
 846
 847                 self.bot_attack = TRUE;
 848
 849                 self.statdraintime = time + 5;
 850                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 851
 852                 if(self.killcount == -666) {
 853                         PlayerScore_Clear(self);
 854                         self.killcount = 0;
 855                 }
 856
 857                 CL_SpawnWeaponentity();
 858                 self.alpha = default_player_alpha;
 859                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 860                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 861
 862                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 863                 self.lms_traveled_distance = 0;
 864                 self.speedrunning = FALSE;
 865
 866                 race_PostSpawn(spot);
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if(g_assault) {
 872                         if(self.team == assault_attacker_team)
 873                                 centerprint(self, "You are attacking!");
 874                         else
 875                                 centerprint(self, "You are defending!");
 876                 }
 877
 878                 target_voicescript_clear(self);
 879
 880                 // reset fields the weapons may use
 881                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 882                 {
 883                         weapon_action(j, WR_RESETPLAYER);
 884
 885                         // all weapons must be fully loaded when we spawn
 886                         entity e;
 887                         e = get_weaponinfo(j);
 888                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 889                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 890                 }
 891
 892                 oldself = self;
 893                 self = spot;
 894                         activator = oldself;
 895                                 string s;
 896                                 s = self.target;
 897                                 self.target = string_null;
 898                                 SUB_UseTargets();
 899                                 self.target = s;
 900                         activator = world;
 901                 self = oldself;
 902
 903                 spawn_spot = spot;
 904                 MUTATOR_CALLHOOK(PlayerSpawn);
 905
 906                 if(autocvar_spawn_debug)
 907                 {
 908                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 909                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 910                 }
 911
 912                 self.switchweapon = w_getbestweapon(self);
 913                 self.cnt = -1; // W_LastWeapon will not complain
 914                 self.weapon = 0;
 915                 self.weaponname = "";
 916                 self.switchingweapon = 0;
 917
 918                 if(!self.alivetime)
 919                         self.alivetime = time;
 920
 921                 antilag_clear(self);
 922
 923                 if (autocvar_g_spawnsound)
 924                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 925         } else if(self.classname == "observer") {
 926                 PutObserverInServer ();
 927         }
 928 }
 929
 930 .float ebouncefactor, ebouncestop; // electro's values
 931 // TODO do we need all these fields, or should we stop autodetecting runtime
 932 // changes and just have a console command to update this?
 933 float ClientInit_SendEntity(entity to, float sf)
 934 {
 935         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 936         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 949         if(sv_foginterval && world.fog != "")
 950                 WriteString(MSG_ENTITY, world.fog);
 951         else
 952                 WriteString(MSG_ENTITY, "");
 953         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 954         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 955         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 956         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 957         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 958         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 964         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 966         return TRUE;
 967 }
 968
 969 void ClientInit_CheckUpdate()
 970 {
 971         self.nextthink = time;
 972         if(self.count != autocvar_g_balance_armor_blockpercent)
 973         {
 974                 self.count = autocvar_g_balance_armor_blockpercent;
 975                 self.SendFlags |= 1;
 976         }
 977         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 978         {
 979                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 983         {
 984                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 988         {
 989                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 993         {
 994                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 998         {
 999                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1000                 self.SendFlags |= 1;
1001         }
1002 }
1003
1004 void ClientInit_Spawn()
1005 {
1006         entity o;
1007         entity e;
1008         e = spawn();
1009         e.classname = "clientinit";
1010         e.think = ClientInit_CheckUpdate;
1011         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1012
1013         o = self;
1014         self = e;
1015         ClientInit_CheckUpdate();
1016         self = o;
1017 }
1018
1019 /*
1020 =============
1021 SetNewParms
1022 =============
1023 */
1024 void SetNewParms (void)
1025 {
1026         // initialize parms for a new player
1027         parm1 = -(86400 * 366);
1028 }
1029
1030 /*
1031 =============
1032 SetChangeParms
1033 =============
1034 */
1035 void SetChangeParms (void)
1036 {
1037         // save parms for level change
1038         parm1 = self.parm_idlesince - time;
1039 }
1040
1041 /*
1042 =============
1043 DecodeLevelParms
1044 =============
1045 */
1046 void DecodeLevelParms (void)
1047 {
1048         // load parms
1049         self.parm_idlesince = parm1;
1050         if(self.parm_idlesince == -(86400 * 366))
1051                 self.parm_idlesince = time;
1052
1053         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1054         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1055 }
1056
1057 /*
1058 =============
1059 ClientKill
1060
1061 Called when a client types 'kill' in the console
1062 =============
1063 */
1064
1065 .float clientkill_nexttime;
1066 void ClientKill_Now_TeamChange()
1067 {
1068         if(self.killindicator_teamchange == -1)
1069         {
1070                 JoinBestTeam( self, FALSE, TRUE );
1071         }
1072         else if(self.killindicator_teamchange == -2)
1073         {
1074                 if(g_ca)
1075                         self.caplayer = 0;
1076                 if(blockSpectators)
1077                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1078                 PutObserverInServer();
1079         }
1080         else
1081                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1082 }
1083
1084 void ClientKill_Now()
1085 {
1086         if(self.vehicle)
1087         {
1088             vehicles_exit(VHEF_RELESE);
1089             if(!self.killindicator_teamchange)
1090             {
1091             self.vehicle_health = -1;
1092             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1093             }
1094         }
1095
1096         if(self.killindicator && !wasfreed(self.killindicator))
1097                 remove(self.killindicator);
1098
1099         self.killindicator = world;
1100
1101         if(self.killindicator_teamchange)
1102                 ClientKill_Now_TeamChange();
1103
1104         // in any case:
1105         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1106
1107         // now I am sure the player IS dead
1108 }
1109 void KillIndicator_Think()
1110 {
1111         if (gameover)
1112         {
1113                 self.owner.killindicator = world;
1114                 remove(self);
1115                 return;
1116         }
1117
1118         if (self.owner.alpha < 0 && !self.owner.vehicle)
1119         {
1120                 self.owner.killindicator = world;
1121                 remove(self);
1122                 return;
1123         }
1124
1125         if(self.cnt <= 0)
1126         {
1127                 self = self.owner;
1128                 ClientKill_Now(); // no oldself needed
1129                 return;
1130         }
1131     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1132     {
1133         self.nextthink = time + 1;
1134         self.cnt -= 1;
1135     }
1136         else
1137         {
1138                 if(self.cnt <= 10)
1139                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1140                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1141                 {
1142                         if(self.cnt <= 10)
1143                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1144                 }
1145                 self.nextthink = time + 1;
1146                 self.cnt -= 1;
1147         }
1148 }
1149
1150 float clientkilltime;
1151 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1152 {
1153         float killtime;
1154         float starttime;
1155         entity e;
1156
1157         if (gameover)
1158                 return;
1159
1160         killtime = autocvar_g_balance_kill_delay;
1161
1162         if(g_race_qualifying || g_cts)
1163                 killtime = 0;
1164
1165     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1166     {
1167                 remove(self.killindicator);
1168                 self.killindicator = world;
1169
1170         ClientKill_Now(); // allow instant kill in this case
1171         return;
1172     }
1173
1174         self.killindicator_teamchange = targetteam;
1175
1176     if(!self.killindicator)
1177         {
1178                 if(self.deadflag == DEAD_NO)
1179                 {
1180                         killtime = max(killtime, self.clientkill_nexttime - time);
1181                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1182                 }
1183
1184                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1185                 {
1186                         ClientKill_Now();
1187                 }
1188                 else
1189                 {
1190                         starttime = max(time, clientkilltime);
1191
1192                         self.killindicator = spawn();
1193                         self.killindicator.owner = self;
1194                         self.killindicator.scale = 0.5;
1195                         setattachment(self.killindicator, self, "");
1196                         setorigin(self.killindicator, '0 0 52');
1197                         self.killindicator.think = KillIndicator_Think;
1198                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1199                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1200                         self.killindicator.cnt = ceil(killtime);
1201                         self.killindicator.count = bound(0, ceil(killtime), 10);
1202                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1203
1204                         for(e = world; (e = find(e, classname, "body")) != world; )
1205                         {
1206                                 if(e.enemy != self)
1207                                         continue;
1208                                 e.killindicator = spawn();
1209                                 e.killindicator.owner = e;
1210                                 e.killindicator.scale = 0.5;
1211                                 setattachment(e.killindicator, e, "");
1212                                 setorigin(e.killindicator, '0 0 52');
1213                                 e.killindicator.think = KillIndicator_Think;
1214                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1215                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1216                                 e.killindicator.cnt = ceil(killtime);
1217                         }
1218                         self.lip = 0;
1219                 }
1220         }
1221         if(self.killindicator)
1222         {
1223                 if(targetteam == 0) // just die
1224                 {
1225                         self.killindicator.colormod = '0 0 0';
1226                         if(clienttype(self) == CLIENTTYPE_REAL)
1227                         if(self.killindicator.cnt > 0)
1228                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1229                 }
1230                 else if(targetteam == -1) // auto
1231                 {
1232                         self.killindicator.colormod = '0 1 0';
1233                         if(clienttype(self) == CLIENTTYPE_REAL)
1234                         if(self.killindicator.cnt > 0)
1235                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1236                 }
1237                 else if(targetteam == -2) // spectate
1238                 {
1239                         self.killindicator.colormod = '0.5 0.5 0.5';
1240                         if(clienttype(self) == CLIENTTYPE_REAL)
1241                         if(self.killindicator.cnt > 0)
1242                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1243                 }
1244                 else
1245                 {
1246                         self.killindicator.colormod = TeamColor(targetteam);
1247                         if(clienttype(self) == CLIENTTYPE_REAL)
1248                         if(self.killindicator.cnt > 0)
1249                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1250                 }
1251         }
1252
1253 }
1254
1255 void ClientKill (void)
1256 {
1257         if (gameover)
1258                 return;
1259
1260         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1261         {
1262                 // do nothing
1263         }
1264     else if(self.freezetag_frozen)
1265     {
1266         // do nothing
1267     }
1268         else
1269                 ClientKill_TeamChange(0);
1270 }
1271
1272 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1273 {
1274     e.killindicator = spawn();
1275     e.killindicator.owner = e;
1276     e.killindicator.think = KillIndicator_Think;
1277     e.killindicator.nextthink = time + (e.lip) * 0.05;
1278     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1279     e.killindicator.health = 1; // this is used to indicate that it should be silent
1280     e.lip = 0;
1281 }
1282
1283 void FixClientCvars(entity e)
1284 {
1285         // send prediction settings to the client
1286         stuffcmd(e, "\nin_bindmap 0 0\n");
1287         if(g_race || g_cts)
1288                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1289         if(autocvar_g_antilag == 3) // client side hitscan
1290                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1291         if(sv_gentle)
1292                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1293         /*
1294          * we no longer need to stuff this. Remove this comment block if you feel
1295          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1296         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1297         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1298         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1301         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1304         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1308         stuffcmd(e, "cl_movement_edgefriction 1\n");
1309          */
1310 }
1311
1312 float PlayerInIDList(entity p, string idlist)
1313 {
1314         float n, i;
1315         string s;
1316
1317         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1318         if not(p.crypto_idfp)
1319                 return 0;
1320
1321         // this function allows abbreviated player IDs too!
1322         n = tokenize_console(idlist);
1323         for(i = 0; i < n; ++i)
1324         {
1325                 s = argv(i);
1326                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1327                         return 1;
1328         }
1329
1330         return 0;
1331 }
1332
1333 /*
1334 =============
1335 ClientConnect
1336
1337 Called when a client connects to the server
1338 =============
1339 */
1340 string ColoredTeamName(float t);
1341 void DecodeLevelParms (void);
1342 //void dom_player_join_team(entity pl);
1343 void set_dom_state(entity e);
1344 void ClientConnect (void)
1345 {
1346         float t;
1347
1348         if(self.flags & FL_CLIENT)
1349         {
1350                 print("Warning: ClientConnect, but already connected!\n");
1351                 return;
1352         }
1353
1354         if(Ban_MaybeEnforceBanOnce(self))
1355                 return;
1356
1357         DecodeLevelParms();
1358
1359 #ifdef WATERMARK
1360         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1361 #endif
1362
1363         self.classname = "player_joining";
1364
1365         self.flags = FL_CLIENT;
1366         self.version_nagtime = time + 10 + random() * 10;
1367
1368         if(player_count<0)
1369         {
1370                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1371                 player_count = 0;
1372         }
1373
1374         PlayerScore_Attach(self);
1375         ClientData_Attach();
1376         accuracy_init(self);
1377
1378         bot_clientconnect();
1379
1380         playerdemo_init();
1381
1382         anticheat_init();
1383
1384         race_PreSpawnObserver();
1385
1386         //if(g_domination)
1387         //      dom_player_join_team(self);
1388
1389         // identify the right forced team
1390         if(autocvar_g_campaign)
1391         {
1392                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1393                 {
1394                         switch(autocvar_g_campaign_forceteam)
1395                         {
1396                                 case 1: self.team_forced = COLOR_TEAM1; break;
1397                                 case 2: self.team_forced = COLOR_TEAM2; break;
1398                                 case 3: self.team_forced = COLOR_TEAM3; break;
1399                                 case 4: self.team_forced = COLOR_TEAM4; break;
1400                                 default: self.team_forced = 0;
1401                         }
1402                 }
1403         }
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1405                 self.team_forced = COLOR_TEAM1;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1407                 self.team_forced = COLOR_TEAM2;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1409                 self.team_forced = COLOR_TEAM3;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1411                 self.team_forced = COLOR_TEAM4;
1412         else if(autocvar_g_forced_team_otherwise == "red")
1413                 self.team_forced = COLOR_TEAM1;
1414         else if(autocvar_g_forced_team_otherwise == "blue")
1415                 self.team_forced = COLOR_TEAM2;
1416         else if(autocvar_g_forced_team_otherwise == "yellow")
1417                 self.team_forced = COLOR_TEAM3;
1418         else if(autocvar_g_forced_team_otherwise == "pink")
1419                 self.team_forced = COLOR_TEAM4;
1420         else if(autocvar_g_forced_team_otherwise == "spectate")
1421                 self.team_forced = -1;
1422         else if(autocvar_g_forced_team_otherwise == "spectator")
1423                 self.team_forced = -1;
1424         else
1425                 self.team_forced = 0;
1426
1427         if(!teamplay)
1428                 if(self.team_forced > 0)
1429                         self.team_forced = 0;
1430
1431         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1432
1433         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1434                 self.classname = "observer";
1435         } else {
1436                 if(teamplay)
1437                 {
1438                         if(autocvar_g_balance_teams)
1439                         {
1440                                 self.classname = "player";
1441                                 campaign_bots_may_start = 1;
1442                         }
1443                         else
1444                         {
1445                                 self.classname = "observer"; // do it anyway
1446                         }
1447                 }
1448                 else
1449                 {
1450                         self.classname = "player";
1451                         campaign_bots_may_start = 1;
1452                 }
1453         }
1454
1455         self.playerid = (playerid_last = playerid_last + 1);
1456
1457         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1458
1459     if(clienttype(self) == CLIENTTYPE_BOT)
1460         PlayerStats_AddPlayer(self);
1461
1462         if(autocvar_sv_eventlog)
1463                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1464
1465         LogTeamchange(self.playerid, self.team, 1);
1466
1467         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1468
1469         self.netname_previous = strzone(self.netname);
1470
1471         bprint("^4", self.netname, "^4 connected");
1472
1473         if(self.classname != "observer" && (g_domination || g_ctf))
1474                 bprint(" and joined the ", ColoredTeamName(self.team));
1475
1476         bprint("\n");
1477
1478         stuffcmd(self, strcat(clientstuff, "\n"));
1479         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1480
1481         FixClientCvars(self);
1482
1483         // spawnfunc_waypoint sprites
1484         WaypointSprite_InitClient(self);
1485
1486         // Wazat's grappling hook
1487         SetGrappleHookBindings();
1488
1489         // get version info from player
1490         stuffcmd(self, "cmd clientversion $gameversion\n");
1491
1492         // get other cvars from player
1493         GetCvars(0);
1494
1495         // notify about available teams
1496         if(teamplay)
1497         {
1498                 CheckAllowedTeams(self);
1499                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1500                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1501         }
1502         else
1503                 stuffcmd(self, "set _teams_available 0\n");
1504
1505         if(g_arena || g_ca)
1506         {
1507                 self.classname = "observer";
1508                 if(g_arena)
1509                         Spawnqueue_Insert(self);
1510         }
1511
1512         attach_entcs();
1513
1514         bot_relinkplayerlist();
1515
1516         self.spectatortime = time;
1517         if(blockSpectators)
1518         {
1519                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1520         }
1521
1522         self.jointime = time;
1523         self.allowed_timeouts = autocvar_sv_timeout_number;
1524
1525         if(clienttype(self) == CLIENTTYPE_REAL)
1526         {
1527                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1528                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1529         }
1530
1531         if(g_lms)
1532         {
1533                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1534                 {
1535                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1536                         self.frags = FRAGS_SPECTATOR;
1537                 }
1538         }
1539
1540         if(!sv_foginterval && world.fog != "")
1541                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1542
1543         SoundEntity_Attach(self);
1544
1545         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1546         {
1547                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1548                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1549         }
1550         else
1551                 self.hitplotfh = -1;
1552
1553         if(g_race || g_cts) {
1554                 string rr;
1555                 if(g_cts)
1556                         rr = CTS_RECORD;
1557                 else
1558                         rr = RACE_RECORD;
1559
1560                 msg_entity = self;
1561                 race_send_recordtime(MSG_ONE);
1562                 race_send_speedaward(MSG_ONE);
1563
1564                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1565                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1566                 race_send_speedaward_alltimebest(MSG_ONE);
1567
1568                 float i;
1569                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1570                         race_SendRankings(i, 0, 0, MSG_ONE);
1571                 }
1572         }
1573         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1574                 send_CSQC_teamnagger();
1575
1576         if (g_domination)
1577                 set_dom_state(self);
1578
1579         CheatInitClient();
1580
1581         if(!autocvar_g_campaign)
1582                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1583
1584         CSQCMODEL_AUTOINIT();
1585
1586         self.model_randomizer = random();
1587
1588     if(clienttype(self) != CLIENTTYPE_REAL)
1589         return;
1590
1591     sv_notice_join();
1592
1593     MUTATOR_CALLHOOK(ClientConnect);
1594 }
1595 /*
1596 =============
1597 ClientDisconnect
1598
1599 Called when a client disconnects from the server
1600 =============
1601 */
1602 .entity chatbubbleentity;
1603 void ReadyCount();
1604 void ClientDisconnect (void)
1605 {
1606         if(self.vehicle)
1607             vehicles_exit(VHEF_RELESE);
1608
1609         if not(self.flags & FL_CLIENT)
1610         {
1611                 print("Warning: ClientDisconnect without ClientConnect\n");
1612                 return;
1613         }
1614
1615         PlayerStats_AddGlobalInfo(self);
1616
1617         CheatShutdownClient();
1618
1619         if(self.hitplotfh >= 0)
1620         {
1621                 fclose(self.hitplotfh);
1622                 self.hitplotfh = -1;
1623         }
1624
1625         anticheat_report();
1626         anticheat_shutdown();
1627
1628         playerdemo_shutdown();
1629
1630         bot_clientdisconnect();
1631
1632         if(self.entcs)
1633                 detach_entcs();
1634
1635         if(autocvar_sv_eventlog)
1636                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1637         bprint ("^4",self.netname);
1638         bprint ("^4 disconnected\n");
1639
1640         SoundEntity_Detach(self);
1641
1642         DropAllRunes(self);
1643         MUTATOR_CALLHOOK(ClientDisconnect);
1644
1645         Portal_ClearAll(self);
1646
1647         RemoveGrapplingHook(self);
1648
1649         // Here, everything has been done that requires this player to be a client.
1650
1651         self.flags &~= FL_CLIENT;
1652
1653         if (self.chatbubbleentity)
1654                 remove (self.chatbubbleentity);
1655
1656         if (self.killindicator)
1657                 remove (self.killindicator);
1658
1659         WaypointSprite_PlayerGone();
1660
1661         bot_relinkplayerlist();
1662
1663         if(g_arena)
1664         {
1665                 Spawnqueue_Unmark(self);
1666                 Spawnqueue_Remove(self);
1667         }
1668
1669         accuracy_free(self);
1670         ClientData_Detach();
1671         PlayerScore_Detach(self);
1672
1673         if(self.netname_previous)
1674                 strunzone(self.netname_previous);
1675         if(self.clientstatus)
1676                 strunzone(self.clientstatus);
1677         if(self.weaponorder_byimpulse)
1678                 strunzone(self.weaponorder_byimpulse);
1679
1680         ClearPlayerSounds();
1681
1682         if(self.personal)
1683                 remove(self.personal);
1684
1685         self.playerid = 0;
1686         ReadyCount();
1687
1688         // free cvars
1689         GetCvars(-1);
1690 }
1691
1692 .float BUTTON_CHAT;
1693 void ChatBubbleThink()
1694 {
1695         self.nextthink = time;
1696         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1697         {
1698                 if(self.owner) // but why can that ever be world?
1699                         self.owner.chatbubbleentity = world;
1700                 remove(self);
1701                 return;
1702         }
1703         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1704 #ifdef TETRIS
1705                 || self.owner.tetris_on
1706 #endif
1707         )
1708                 self.model = self.mdl;
1709         else
1710                 self.model = "";
1711 }
1712
1713 void UpdateChatBubble()
1714 {
1715         if (self.alpha < 0)
1716                 return;
1717         // spawn a chatbubble entity if needed
1718         if (!self.chatbubbleentity)
1719         {
1720                 self.chatbubbleentity = spawn();
1721                 self.chatbubbleentity.owner = self;
1722                 self.chatbubbleentity.exteriormodeltoclient = self;
1723                 self.chatbubbleentity.think = ChatBubbleThink;
1724                 self.chatbubbleentity.nextthink = time;
1725                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1726                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1727                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1728                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1729                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1730                 self.chatbubbleentity.model = "";
1731                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1732         }
1733 }
1734
1735
1736 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1737 // added to the model skins
1738 /*void UpdateColorModHack()
1739 {
1740         float c;
1741         c = self.clientcolors & 15;
1742         // LordHavoc: only bothering to support white, green, red, yellow, blue
1743              if (!teamplay) self.colormod = '0 0 0';
1744         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1745         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1746         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1747         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1748         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1749         else self.colormod = '1 1 1';
1750 }*/
1751
1752 void respawn(void)
1753 {
1754         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1755         {
1756                 self.solid = SOLID_NOT;
1757                 self.takedamage = DAMAGE_NO;
1758                 self.movetype = MOVETYPE_FLY;
1759                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1760                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1761                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1762                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1763                 if(autocvar_g_respawn_ghosts_maxtime)
1764                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1765         }
1766
1767         CopyBody(1);
1768
1769         self.effects |= EF_NODRAW; // prevent another CopyBody
1770         PutClientInServer();
1771 }
1772
1773 void play_countdown(float finished, string samp)
1774 {
1775         if(clienttype(self) == CLIENTTYPE_REAL)
1776                 if(floor(finished - time - frametime) != floor(finished - time))
1777                         if(finished - time < 6)
1778                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1779 }
1780
1781 void player_powerups (void)
1782 {
1783         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1784         olditems = self.items;
1785
1786         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1787         {
1788                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1789                 self.modelflags |= MF_ROCKET;
1790         }
1791         else
1792         {
1793                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1794                 self.modelflags &~= MF_ROCKET;
1795         }
1796
1797         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1798
1799         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1800                 return;
1801
1802         Fire_ApplyDamage(self);
1803         Fire_ApplyEffect(self);
1804
1805         if (g_minstagib)
1806         {
1807                 self.effects |= EF_FULLBRIGHT;
1808
1809                 if (self.items & IT_STRENGTH)
1810                 {
1811                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1812                         if (time > self.strength_finished)
1813                         {
1814                                 self.alpha = default_player_alpha;
1815                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1816                                 self.items &~= IT_STRENGTH;
1817                                 sprint(self, "^3Invisibility has worn off\n");
1818                         }
1819                 }
1820                 else
1821                 {
1822                         if (time < self.strength_finished)
1823                         {
1824                                 self.alpha = g_minstagib_invis_alpha;
1825                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1826                                 self.items |= IT_STRENGTH;
1827                                 sprint(self, "^3You are invisible\n");
1828                         }
1829                 }
1830
1831                 if (self.items & IT_INVINCIBLE)
1832                 {
1833                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1834                         if (time > self.invincible_finished)
1835                         {
1836                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1837                                 sprint(self, "^3Speed has worn off\n");
1838                         }
1839                 }
1840                 else
1841                 {
1842                         if (time < self.invincible_finished)
1843                         {
1844                                 self.items = self.items | IT_INVINCIBLE;
1845                                 sprint(self, "^3You are on speed\n");
1846                         }
1847                 }
1848         }
1849         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1850         {
1851                 if (self.items & IT_STRENGTH)
1852                 {
1853                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1854                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1855                         if (time > self.strength_finished)
1856                         {
1857                                 self.items = self.items - (self.items & IT_STRENGTH);
1858                                 sprint(self, "^3Strength has worn off\n");
1859                         }
1860                 }
1861                 else
1862                 {
1863                         if (time < self.strength_finished)
1864                         {
1865                                 self.items = self.items | IT_STRENGTH;
1866                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1867                         }
1868                 }
1869                 if (self.items & IT_INVINCIBLE)
1870                 {
1871                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1872                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1873                         if (time > self.invincible_finished)
1874                         {
1875                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1876                                 sprint(self, "^3Shield has worn off\n");
1877                         }
1878                 }
1879                 else
1880                 {
1881                         if (time < self.invincible_finished)
1882                         {
1883                                 self.items = self.items | IT_INVINCIBLE;
1884                                 sprint(self, "^3Shield surrounds you\n");
1885                         }
1886                 }
1887                 if (self.items & IT_SUPERWEAPON)
1888                 {
1889                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1890                         {
1891                                 self.superweapons_finished = 0;
1892                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1893                                 sprint(self, "^3Superweapons have been lost\n");
1894                         }
1895                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1896                         {
1897                                 // don't let them run out
1898                         }
1899                         else
1900                         {
1901                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1902                                 if (time > self.superweapons_finished)
1903                                 {
1904                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1905                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1906                                         sprint(self, "^3Superweapons have broken down\n");
1907                                 }
1908                         }
1909                 }
1910                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1911                 {
1912                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1913                         {
1914                                 self.items = self.items | IT_SUPERWEAPON;
1915                                 sprint(self, "^3You now have a superweapon\n");
1916                         }
1917                         else
1918                         {
1919                                 self.superweapons_finished = 0;
1920                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1921                         }
1922                 }
1923                 else
1924                 {
1925                         self.superweapons_finished = 0;
1926                 }
1927         }
1928
1929         if(autocvar_g_nodepthtestplayers)
1930                 self.effects = self.effects | EF_NODEPTHTEST;
1931
1932         if(autocvar_g_fullbrightplayers)
1933                 self.effects = self.effects | EF_FULLBRIGHT;
1934
1935         // midair gamemode: damage only while in the air
1936         // if in midair mode, being on ground grants temporary invulnerability
1937         // (this is so that multishot weapon don't clear the ground flag on the
1938         // first damage in the frame, leaving the player vulnerable to the
1939         // remaining hits in the same frame)
1940         if (self.flags & FL_ONGROUND)
1941         if (g_midair)
1942                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1943
1944         if (time >= game_starttime)
1945         if (time < self.spawnshieldtime)
1946                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1947
1948         MUTATOR_CALLHOOK(PlayerPowerups);
1949 }
1950
1951 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1952 {
1953         if(current > stable)
1954                 return current;
1955         else if(current > stable - 0.25) // when close enough, "snap"
1956                 return stable;
1957         else
1958                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1959 }
1960
1961 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1962 {
1963         if(current < stable)
1964                 return current;
1965         else if(current < stable + 0.25) // when close enough, "snap"
1966                 return stable;
1967         else
1968                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1969 }
1970
1971 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1972 {
1973         if(current > rotstable)
1974         {
1975                 if(rotframetime > 0)
1976                 {
1977                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1978                         current = max(rotstable, current - rotlinear * rotframetime);
1979                 }
1980         }
1981         else if(current < regenstable)
1982         {
1983                 if(regenframetime > 0)
1984                 {
1985                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1986                         current = min(regenstable, current + regenlinear * regenframetime);
1987                 }
1988         }
1989
1990         if(current > limit)
1991                 current = limit;
1992
1993         return current;
1994 }
1995
1996 void player_regen (void)
1997 {
1998         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1999         maxh = autocvar_g_balance_health_rotstable;
2000         maxa = autocvar_g_balance_armor_rotstable;
2001         maxf = autocvar_g_balance_fuel_rotstable;
2002         minh = autocvar_g_balance_health_regenstable;
2003         mina = autocvar_g_balance_armor_regenstable;
2004         minf = autocvar_g_balance_fuel_regenstable;
2005         limith = autocvar_g_balance_health_limit;
2006         limita = autocvar_g_balance_armor_limit;
2007         limitf = autocvar_g_balance_fuel_limit;
2008
2009         max_mod = regen_mod = rot_mod = limit_mod = 1;
2010
2011         if (self.runes & RUNE_REGEN)
2012         {
2013                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2014                 {
2015                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2016                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2017                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2018                 }
2019                 else
2020                 {
2021                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2022                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2023                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2024                 }
2025         }
2026         else if (self.runes & CURSE_VENOM)
2027         {
2028                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2029                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2030                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2031                 else
2032                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2033                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2034                 //if (!self.runes & RUNE_REGEN)
2035                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2036         }
2037         maxh = maxh * max_mod;
2038         //maxa = maxa * max_mod;
2039         //maxf = maxf * max_mod;
2040         minh = minh * max_mod;
2041         //mina = mina * max_mod;
2042         //minf = minf * max_mod;
2043         limith = limith * limit_mod;
2044         limita = limita * limit_mod;
2045         //limitf = limitf * limit_mod;
2046
2047         if(g_lms && g_ca)
2048                 rot_mod = 0;
2049
2050         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2051         {
2052                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2053                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2054
2055                 // if player rotted to death...  die!
2056                 if(self.health < 1)
2057                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2058         }
2059
2060         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2061                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2062 }
2063
2064 float zoomstate_set;
2065 void SetZoomState(float z)
2066 {
2067         if(z != self.zoomstate)
2068         {
2069                 self.zoomstate = z;
2070                 ClientData_Touch(self);
2071         }
2072         zoomstate_set = 1;
2073 }
2074
2075 void GetPressedKeys(void) {
2076         MUTATOR_CALLHOOK(GetPressedKeys);
2077         if (self.movement_x > 0) // get if movement keys are pressed
2078         {       // forward key pressed
2079                 self.pressedkeys |= KEY_FORWARD;
2080                 self.pressedkeys &~= KEY_BACKWARD;
2081         }
2082         else if (self.movement_x < 0)
2083         {       // backward key pressed
2084                 self.pressedkeys |= KEY_BACKWARD;
2085                 self.pressedkeys &~= KEY_FORWARD;
2086         }
2087         else
2088         {       // no x input
2089                 self.pressedkeys &~= KEY_FORWARD;
2090                 self.pressedkeys &~= KEY_BACKWARD;
2091         }
2092
2093         if (self.movement_y > 0)
2094         {       // right key pressed
2095                 self.pressedkeys |= KEY_RIGHT;
2096                 self.pressedkeys &~= KEY_LEFT;
2097         }
2098         else if (self.movement_y < 0)
2099         {       // left key pressed
2100                 self.pressedkeys |= KEY_LEFT;
2101                 self.pressedkeys &~= KEY_RIGHT;
2102         }
2103         else
2104         {       // no y input
2105                 self.pressedkeys &~= KEY_RIGHT;
2106                 self.pressedkeys &~= KEY_LEFT;
2107         }
2108
2109         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2110                 self.pressedkeys |= KEY_JUMP;
2111         else
2112                 self.pressedkeys &~= KEY_JUMP;
2113         if (self.BUTTON_CROUCH)
2114                 self.pressedkeys |= KEY_CROUCH;
2115         else
2116                 self.pressedkeys &~= KEY_CROUCH;
2117
2118         if (self.BUTTON_ATCK)
2119                 self.pressedkeys |= KEY_ATCK;
2120         else
2121                 self.pressedkeys &~= KEY_ATCK;
2122         if (self.BUTTON_ATCK2)
2123                 self.pressedkeys |= KEY_ATCK2;
2124         else
2125                 self.pressedkeys &~= KEY_ATCK2;
2126 }
2127
2128 /*
2129 ======================
2130 spectate mode routines
2131 ======================
2132 */
2133
2134 void SpectateCopy(entity spectatee) {
2135         other = spectatee;
2136         MUTATOR_CALLHOOK(SpectateCopy);
2137         self.armortype = spectatee.armortype;
2138         self.armorvalue = spectatee.armorvalue;
2139         self.ammo_cells = spectatee.ammo_cells;
2140         self.ammo_shells = spectatee.ammo_shells;
2141         self.ammo_nails = spectatee.ammo_nails;
2142         self.ammo_rockets = spectatee.ammo_rockets;
2143         self.ammo_fuel = spectatee.ammo_fuel;
2144         self.clip_load = spectatee.clip_load;
2145         self.clip_size = spectatee.clip_size;
2146         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2147         self.health = spectatee.health;
2148         self.impulse = 0;
2149         self.items = spectatee.items;
2150         self.last_pickup = spectatee.last_pickup;
2151         self.hit_time = spectatee.hit_time;
2152         self.metertime = spectatee.metertime;
2153         self.strength_finished = spectatee.strength_finished;
2154         self.invincible_finished = spectatee.invincible_finished;
2155         self.pressedkeys = spectatee.pressedkeys;
2156         WEPSET_COPY_EE(self, spectatee);
2157         self.switchweapon = spectatee.switchweapon;
2158         self.switchingweapon = spectatee.switchingweapon;
2159         self.weapon = spectatee.weapon;
2160         self.nex_charge = spectatee.nex_charge;
2161         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2162         self.hagar_load = spectatee.hagar_load;
2163         self.minelayer_mines = spectatee.minelayer_mines;
2164         self.punchangle = spectatee.punchangle;
2165         self.view_ofs = spectatee.view_ofs;
2166         self.velocity = spectatee.velocity;
2167         self.dmg_take = spectatee.dmg_take;
2168         self.dmg_save = spectatee.dmg_save;
2169         self.dmg_inflictor = spectatee.dmg_inflictor;
2170         self.v_angle = spectatee.v_angle;
2171         self.angles = spectatee.v_angle;
2172         if(!self.BUTTON_USE)
2173                 self.fixangle = TRUE;
2174         setorigin(self, spectatee.origin);
2175         setsize(self, spectatee.mins, spectatee.maxs);
2176         SetZoomState(spectatee.zoomstate);
2177
2178     anticheat_spectatecopy(spectatee);
2179         self.hud = spectatee.hud;
2180         if(spectatee.vehicle)
2181     {
2182         self.fixangle = FALSE;
2183         //self.velocity = spectatee.vehicle.velocity;
2184         self.vehicle_health = spectatee.vehicle_health;
2185         self.vehicle_shield = spectatee.vehicle_shield;
2186         self.vehicle_energy = spectatee.vehicle_energy;
2187         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2188         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2189         self.vehicle_reload1 = spectatee.vehicle_reload1;
2190         self.vehicle_reload2 = spectatee.vehicle_reload2;
2191
2192         msg_entity = self;
2193
2194         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2195             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2196             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2197             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2198
2199         //WriteByte (MSG_ONE, SVC_SETVIEW);
2200         //    WriteEntity(MSG_ONE, self);
2201         //makevectors(spectatee.v_angle);
2202         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2203     }
2204 }
2205
2206 float SpectateUpdate() {
2207         if(!self.enemy)
2208             return 0;
2209
2210         if (self == self.enemy)
2211                 return 0;
2212
2213         if(self.enemy.classname != "player")
2214                 return 0;
2215
2216         SpectateCopy(self.enemy);
2217
2218         return 1;
2219 }
2220
2221
2222 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2223 entity CA_SpectateNext(entity start) {
2224         if (start.team == self.team) {
2225                 return start;
2226         }
2227
2228         other = start;
2229         // continue from current player
2230         while(other && other.team != self.team) {
2231                 other = find(other, classname, "player");
2232         }
2233
2234         if (!other) {
2235                 // restart from begining
2236                 other = find(other, classname, "player");
2237                 while(other && other.team != self.team) {
2238                         other = find(other, classname, "player");
2239                 }
2240         }
2241
2242         return other;
2243 }
2244
2245 float SpectateNext(entity _prefer) {
2246
2247         if(_prefer)
2248                 other = _prefer;
2249         else
2250                 other = find(self.enemy, classname, "player");
2251
2252         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2253                 // CA and ca players when spectating enemies is forbidden
2254                 other = CA_SpectateNext(other);
2255         } else {
2256                 // other modes and ca spectators or spectating enemies is allowed
2257                 if (!other)
2258                         other = find(other, classname, "player");
2259         }
2260
2261         if (other)
2262                 self.enemy = other;
2263
2264         if(self.enemy.classname == "player") {
2265             /*if(self.enemy.vehicle)
2266             {
2267
2268             msg_entity = self;
2269             WriteByte(MSG_ONE, SVC_SETVIEW);
2270             WriteEntity(MSG_ONE, self.enemy);
2271             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2272
2273             self.movetype = MOVETYPE_NONE;
2274             accuracy_resend(self);
2275             }
2276             else
2277             {*/
2278             msg_entity = self;
2279             WriteByte(MSG_ONE, SVC_SETVIEW);
2280             WriteEntity(MSG_ONE, self.enemy);
2281             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2282             self.movetype = MOVETYPE_NONE;
2283             accuracy_resend(self);
2284
2285             if(!SpectateUpdate())
2286                 PutObserverInServer();
2287         //}
2288         return 1;
2289         } else {
2290                 return 0;
2291         }
2292 }
2293
2294 /*
2295 =============
2296 ShowRespawnCountdown()
2297
2298 Update a respawn countdown display.
2299 =============
2300 */
2301 void ShowRespawnCountdown()
2302 {
2303         float number;
2304         if(self.deadflag == DEAD_NO) // just respawned?
2305                 return;
2306         else
2307         {
2308                 number = ceil(self.respawn_time - time);
2309                 if(number <= 0)
2310                         return;
2311                 if(number <= self.respawn_countdown)
2312                 {
2313                         self.respawn_countdown = number - 1;
2314                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2315                                 AnnounceTo(self, strcat(ftos(number), ""));
2316                 }
2317         }
2318 }
2319
2320 .float prevent_join_msgtime;
2321 void LeaveSpectatorMode()
2322 {
2323         if(nJoinAllowed(self)) {
2324                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2325                         self.classname = "player";
2326
2327                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2328                                 JoinBestTeam(self, FALSE, TRUE);
2329
2330                         if(autocvar_g_campaign)
2331                                 campaign_bots_may_start = 1;
2332
2333                         PutClientInServer();
2334
2335                         if(self.classname == "player")
2336                                 bprint ("^4", self.netname, "^4 is playing now\n");
2337
2338                         if(!autocvar_g_campaign)
2339                         if (time < self.jointime + autocvar_welcome_message_time)
2340                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2341
2342                         if (self.prevent_join_msgtime)
2343                         {
2344                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2345                                 self.prevent_join_msgtime = 0;
2346                         }
2347
2348                         return;
2349                 } else {
2350                         if (g_ca && self.caplayer) {
2351                         }       // do nothing
2352                         else
2353                                 stuffcmd(self,"menu_showteamselect\n");
2354                         return;
2355                 }
2356         }
2357         else {
2358                 //player may not join because of g_maxplayers is set
2359                 if (time - self.prevent_join_msgtime > 2)
2360                 {
2361                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2362                         self.prevent_join_msgtime = time;
2363                 }
2364         }
2365 }
2366
2367 /**
2368  * Determines whether the player is allowed to join. This depends on cvar
2369  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2370  * it checks whether the number of currently playing players exceeds g_maxplayers.
2371  * @return int number of free slots for players, 0 if none
2372  */
2373 float nJoinAllowed(entity ignore) {
2374         if(!ignore)
2375         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2376         // so report 0 free slots if restricted
2377         {
2378                 if(autocvar_g_forced_team_otherwise == "spectate")
2379                         return 0;
2380                 if(autocvar_g_forced_team_otherwise == "spectator")
2381                         return 0;
2382         }
2383
2384         if(self.team_forced < 0)
2385                 return 0; // forced spectators can never join
2386
2387         // TODO simplify this
2388         entity e;
2389         float totalClients = 0;
2390         FOR_EACH_CLIENT(e)
2391                 if(e != ignore)
2392                         totalClients += 1;
2393
2394         if (!autocvar_g_maxplayers)
2395                 return maxclients - totalClients;
2396
2397         float currentlyPlaying = 0;
2398         FOR_EACH_REALPLAYER(e)
2399                 currentlyPlaying += 1;
2400
2401         if(currentlyPlaying < autocvar_g_maxplayers)
2402                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2403
2404         return 0;
2405 }
2406
2407 /**
2408  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2409  * g_maxplayers_spectator_blocktime seconds
2410  */
2411 void checkSpectatorBlock() {
2412         if(self.classname == "spectator" || self.classname == "observer") {
2413                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2414                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2415                         dropclient(self);
2416                 }
2417         }
2418 }
2419
2420 .float motd_actived_time; // used for both motd and campaign_message
2421 void PrintWelcomeMessage()
2422 {
2423         if (self.motd_actived_time == 0) { // is there already a message showing?
2424                 if (autocvar_g_campaign) {
2425                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2426                                 self.motd_actived_time = time;
2427                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2428                         }
2429                 } else {
2430                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2431                                 self.motd_actived_time = time;
2432                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2433                         }
2434                 }
2435         } else { // showing MOTD or campaign message
2436                 if (autocvar_g_campaign) {
2437                         if (self.BUTTON_INFO)
2438                                 self.motd_actived_time = time;
2439                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2440                                 self.motd_actived_time = 0;
2441                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2442                         }
2443                 } else {
2444                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2445                                 if (self.BUTTON_INFO)
2446                                         self.motd_actived_time = time;
2447                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2448                                         self.motd_actived_time = 0;
2449                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2450                                 }
2451                         }
2452                 }
2453         }
2454 }
2455
2456 void ObserverThink()
2457 {
2458         float prefered_movetype;
2459         if (self.flags & FL_JUMPRELEASED) {
2460                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         self.flags |= FL_SPAWNING;
2463                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         if(SpectateNext(world) == 1) {
2466                                 self.classname = "spectator";
2467                         }
2468                 } else {
2469                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2470                         if (self.movetype != prefered_movetype)
2471                                 self.movetype = prefered_movetype;
2472                 }
2473         } else {
2474                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2475                         self.flags |= FL_JUMPRELEASED;
2476                         if(self.flags & FL_SPAWNING)
2477                         {
2478                                 self.flags &~= FL_SPAWNING;
2479                                 LeaveSpectatorMode();
2480                                 return;
2481                         }
2482                 }
2483         }
2484
2485         PrintWelcomeMessage();
2486 }
2487
2488 void SpectatorThink()
2489 {
2490         if (self.flags & FL_JUMPRELEASED) {
2491                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2492                         self.flags &~= FL_JUMPRELEASED;
2493                         self.flags |= FL_SPAWNING;
2494                 } else if(self.BUTTON_ATCK) {
2495                         self.flags &~= FL_JUMPRELEASED;
2496                         if(SpectateNext(world) == 1) {
2497                                 self.classname = "spectator";
2498                         } else {
2499                                 self.classname = "observer";
2500                                 PutClientInServer();
2501                         }
2502                 } else if (self.BUTTON_ATCK2) {
2503                         self.flags &~= FL_JUMPRELEASED;
2504                         self.classname = "observer";
2505                         PutClientInServer();
2506                 } else {
2507                         if(!SpectateUpdate())
2508                                 PutObserverInServer();
2509                 }
2510         } else {
2511                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2512                         self.flags |= FL_JUMPRELEASED;
2513                         if(self.flags & FL_SPAWNING)
2514                         {
2515                                 self.flags &~= FL_SPAWNING;
2516                                 LeaveSpectatorMode();
2517                                 return;
2518                         }
2519                 }
2520                 if(!SpectateUpdate())
2521                         PutObserverInServer();
2522         }
2523
2524         PrintWelcomeMessage();
2525         self.flags |= FL_CLIENT | FL_NOTARGET;
2526 }
2527
2528 void PlayerUseKey()
2529 {
2530         if(self.classname != "player")
2531                 return;
2532
2533         if(self.vehicle)
2534         {
2535         vehicles_exit(VHEF_NORMAL);
2536         return;
2537         }
2538
2539         // a use key was pressed; call handlers
2540         MUTATOR_CALLHOOK(PlayerUseKey);
2541 }
2542
2543 .float touchexplode_time;
2544
2545 /*
2546 =============
2547 PlayerPreThink
2548
2549 Called every frame for each client before the physics are run
2550 =============
2551 */
2552 .float usekeypressed;
2553 void() nexball_setstatus;
2554 .float items_added;
2555 void PlayerPreThink (void)
2556 {
2557         WarpZone_PlayerPhysics_FixVAngle();
2558
2559         self.stat_game_starttime = game_starttime;
2560         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2561         self.stat_leadlimit = autocvar_leadlimit;
2562
2563         if(frametime)
2564         {
2565                 // physics frames: update anticheat stuff
2566                 anticheat_prethink();
2567         }
2568
2569         if(blockSpectators && frametime)
2570                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2571                 checkSpectatorBlock();
2572
2573         zoomstate_set = 0;
2574
2575         if(self.netname_previous != self.netname)
2576         {
2577                 if(autocvar_sv_eventlog)
2578                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2579                 if(self.netname_previous)
2580                         strunzone(self.netname_previous);
2581                 self.netname_previous = strzone(self.netname);
2582         }
2583
2584         // version nagging
2585         if(self.version_nagtime)
2586                 if(self.cvar_g_xonoticversion)
2587                         if(time > self.version_nagtime)
2588                         {
2589                                 // don't notify git users
2590                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2591                                 {
2592                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2593                                         {
2594                                                 // notify release users if connecting to git
2595                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2596                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2597                                         }
2598                                         else
2599                                         {
2600                                                 float r;
2601                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2602                                                 if(r < 0)
2603                                                 {
2604                                                         // give users new version
2605                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2606                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2607                                                 }
2608                                                 else if(r > 0)
2609                                                 {
2610                                                         // notify users about old server version
2611                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2612                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2613                                                 }
2614                                         }
2615                                 }
2616                                 self.version_nagtime = 0;
2617                         }
2618
2619         // GOD MODE info
2620         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2621         {
2622                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2623                 self.max_armorvalue = 0;
2624         }
2625
2626 #ifdef TETRIS
2627         if (TetrisPreFrame())
2628                 return;
2629 #endif
2630
2631         MUTATOR_CALLHOOK(PlayerPreThink);
2632
2633         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2634         {
2635                 if(self.BUTTON_USE && !self.usekeypressed)
2636                         PlayerUseKey();
2637                 self.usekeypressed = self.BUTTON_USE;
2638         }
2639
2640         PrintWelcomeMessage();
2641
2642         if(self.classname == "player") {
2643 //              if(self.netname == "Wazat")
2644 //                      bprint(self.classname, "\n");
2645
2646                 CheckRules_Player();
2647
2648                 if (intermission_running)
2649                 {
2650                         IntermissionThink ();   // otherwise a button could be missed between
2651                         return;                                 // the think tics
2652                 }
2653
2654                 //don't allow the player to turn around while game is paused!
2655                 if(timeout_status == TIMEOUT_ACTIVE) {
2656                         // FIXME turn this into CSQC stuff
2657                         self.v_angle = self.lastV_angle;
2658                         self.angles = self.lastV_angle;
2659                         self.fixangle = TRUE;
2660                 }
2661
2662                 if(frametime)
2663                 {
2664 #ifndef NO_LEGACY_NETWORKING
2665                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2666 #endif
2667
2668                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2669                         {
2670                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2671                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2672                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2673
2674                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2675                                 {
2676                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2677                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2678                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2679                                 }
2680                         }
2681                         else
2682                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2683
2684                         player_powerups();
2685                 }
2686
2687                 if (g_minstagib)
2688                         minstagib_ammocheck();
2689
2690                 if (self.deadflag != DEAD_NO)
2691                 {
2692                         float button_pressed, force_respawn;
2693                         if(self.personal && g_race_qualifying)
2694                         {
2695                                 if(time > self.respawn_time)
2696                                 {
2697                                         self.respawn_time = time + 1; // only retry once a second
2698                                         respawn();
2699                                         self.impulse = 141;
2700                                 }
2701                         }
2702                         else
2703                         {
2704                                 if(frametime)
2705                                         player_anim();
2706                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2707                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2708                                 if (self.deadflag == DEAD_DYING)
2709                                 {
2710                                         if(force_respawn)
2711                                                 self.deadflag = DEAD_RESPAWNING;
2712                                         else if(!button_pressed)
2713                                                 self.deadflag = DEAD_DEAD;
2714                                 }
2715                                 else if (self.deadflag == DEAD_DEAD)
2716                                 {
2717                                         if(button_pressed)
2718                                                 self.deadflag = DEAD_RESPAWNABLE;
2719                                 }
2720                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2721                                 {
2722                                         if(!button_pressed)
2723                                                 self.deadflag = DEAD_RESPAWNING;
2724                                 }
2725                                 else if (self.deadflag == DEAD_RESPAWNING)
2726                                 {
2727                                         if(time > self.respawn_time)
2728                                         {
2729                                                 self.respawn_time = time + 1; // only retry once a second
2730                                                 respawn();
2731                                         }
2732                                 }
2733                                 ShowRespawnCountdown();
2734                         }
2735
2736                         if(self.respawn_schedule != self.respawn_time)
2737                                 self.respawn_schedule = self.respawn_time;
2738                         if(self.deadflag == DEAD_RESPAWNING && self.respawn_schedule > 0)
2739                                 self.respawn_schedule *= -1; // invert to indicate we're awaiting respawn, the client translates this
2740
2741                         return;
2742                 }
2743                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2744                 // so (self.deadflag == DEAD_NO) is always true in the code below
2745
2746                 if(g_touchexplode)
2747                 if(time > self.touchexplode_time)
2748                 if(self.classname == "player")
2749                 if(self.deadflag == DEAD_NO)
2750                 if not(IS_INDEPENDENT_PLAYER(self))
2751                 FOR_EACH_PLAYER(other) if(self != other)
2752                 {
2753                         if(time > other.touchexplode_time)
2754                         if(other.deadflag == DEAD_NO)
2755                         if not(IS_INDEPENDENT_PLAYER(other))
2756                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2757                         {
2758                                 PlayerTouchExplode(self, other);
2759                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2760                         }
2761                 }
2762
2763                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2764                 {
2765                         vector dist;
2766
2767                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2768                         dist = self.prevorigin - self.origin;
2769                         dist_z = 0;
2770                         self.lms_traveled_distance += fabs(vlen(dist));
2771
2772                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2773                         {
2774                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2775                                 self.lms_traveled_distance = 0;
2776                         }
2777
2778                         if(time > self.lms_nextcheck)
2779                         {
2780                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2781                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2782                                 {
2783                                         centerprint(self, autocvar_g_lms_campcheck_message);
2784                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2785                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2786                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2787                                 }
2788                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2789                                 self.lms_traveled_distance = 0;
2790                         }
2791                 }
2792
2793                 self.prevorigin = self.origin;
2794
2795                 if (!self.vehicle)
2796                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2797                 {
2798                         if (!self.crouch)
2799                         {
2800                                 self.crouch = TRUE;
2801                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2802                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2803                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2804                         }
2805                 }
2806                 else
2807                 {
2808                         if (self.crouch)
2809                         {
2810                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2811                                 if (!trace_startsolid)
2812                                 {
2813                                         self.crouch = FALSE;
2814                                         self.view_ofs = PL_VIEW_OFS;
2815                                         setsize (self, PL_MIN, PL_MAX);
2816                                 }
2817                         }
2818                 }
2819
2820                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2821                 {
2822                         if(self.bloodloss_timer < time)
2823                         {
2824                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2825                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2826                         }
2827                 }
2828
2829                 FixPlayermodel();
2830
2831                 GrapplingHookFrame();
2832
2833                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2834                 //if(frametime)
2835                 {
2836                         self.items &~= self.items_added;
2837
2838                         W_WeaponFrame();
2839
2840                         self.items_added = 0;
2841                         if(self.items & IT_JETPACK)
2842                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2843                                         self.items_added |= IT_FUEL;
2844
2845                         self.items |= self.items_added;
2846                 }
2847
2848                 player_regen();
2849
2850                 // rot nex charge to the charge limit
2851                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2852                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2853
2854                 if(frametime)
2855                         player_anim();
2856
2857                 if(g_nexball)
2858                         nexball_setstatus();
2859
2860                 // secret status
2861                 secrets_setstatus();
2862
2863                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2864
2865                 //self.angles_y=self.v_angle_y + 90;   // temp
2866         } else if(gameover) {
2867                 if (intermission_running)
2868                         IntermissionThink ();   // otherwise a button could be missed between
2869                 return;
2870         } else if(self.classname == "observer") {
2871                 ObserverThink();
2872         } else if(self.classname == "spectator") {
2873                 SpectatorThink();
2874         }
2875
2876         if(!zoomstate_set)
2877                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2878
2879         float oldspectatee_status;
2880         oldspectatee_status = self.spectatee_status;
2881         if(self.classname == "spectator")
2882                 self.spectatee_status = num_for_edict(self.enemy);
2883         else if(self.classname == "observer")
2884                 self.spectatee_status = num_for_edict(self);
2885         else
2886                 self.spectatee_status = 0;
2887         if(self.spectatee_status != oldspectatee_status)
2888         {
2889                 ClientData_Touch(self);
2890                 if(g_race || g_cts)
2891                         race_InitSpectator();
2892         }
2893
2894         if(self.teamkill_soundtime)
2895         if(time > self.teamkill_soundtime)
2896         {
2897                 self.teamkill_soundtime = 0;
2898
2899                 entity oldpusher, oldself;
2900
2901                 oldself = self; self = self.teamkill_soundsource;
2902                 oldpusher = self.pusher; self.pusher = oldself;
2903
2904                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2905
2906                 self.pusher = oldpusher;
2907                 self = oldself;
2908         }
2909
2910         if(self.taunt_soundtime)
2911         if(time > self.taunt_soundtime)
2912         {
2913                 self.taunt_soundtime = 0;
2914                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2915         }
2916
2917         target_voicescript_next(self);
2918
2919         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2920         if(!self.weapon)
2921                 self.clip_load = self.clip_size = 0;
2922 }
2923
2924 float isInvisibleString(string s)
2925 {
2926         float i, n, c;
2927         s = strdecolorize(s);
2928         for((i = 0), (n = strlen(s)); i < n; ++i)
2929         {
2930                 c = str2chr(s, i);
2931                 switch(c)
2932                 {
2933                         case 0:
2934                         case 32: // space
2935                                 break;
2936                         case 192: // charmap space
2937                                 if (!autocvar_utf8_enable)
2938                                         break;
2939                                 return FALSE;
2940                         case 160: // space in unicode fonts
2941                         case 0xE000 + 192: // utf8 charmap space
2942                                 if (autocvar_utf8_enable)
2943                                         break;
2944                         default:
2945                                 return FALSE;
2946                 }
2947         }
2948         return TRUE;
2949 }
2950
2951 /*
2952 =============
2953 PlayerPostThink
2954
2955 Called every frame for each client after the physics are run
2956 =============
2957 */
2958 .float idlekick_lasttimeleft;
2959 .entity showheadshotbbox;
2960 void showheadshotbbox_think()
2961 {
2962         if(self.owner.showheadshotbbox != self)
2963         {
2964                 remove(self);
2965                 return;
2966         }
2967         self.nextthink = time;
2968         setorigin(self, self.owner.origin);
2969         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2970 }
2971 void PlayerPostThink (void)
2972 {
2973         // Savage: Check for nameless players
2974         if (isInvisibleString(self.netname)) {
2975                 self.netname = "Player";
2976                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2977         }
2978
2979         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2980         {
2981                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2982                 {
2983                         if(self.idlekick_lasttimeleft)
2984                         {
2985                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2986                                 self.idlekick_lasttimeleft = 0;
2987                         }
2988                 }
2989                 else
2990                 {
2991                         float timeleft;
2992                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2993                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2994                         {
2995                                 if(!self.idlekick_lasttimeleft)
2996                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2997                         }
2998                         if(timeleft <= 0)
2999                         {
3000                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3001                                 AnnounceTo(self, "terminated");
3002                                 dropclient(self);
3003                                 return;
3004                         }
3005                         else if(timeleft <= 10)
3006                         {
3007                                 if(timeleft != self.idlekick_lasttimeleft)
3008                                         AnnounceTo(self, ftos(timeleft));
3009                                 self.idlekick_lasttimeleft = timeleft;
3010                         }
3011                 }
3012         }
3013
3014 #ifdef TETRIS
3015         if(self.impulse == 100)
3016                 ImpulseCommands();
3017         if (!TetrisPostFrame())
3018         {
3019 #endif
3020
3021         CheatFrame();
3022
3023         //CheckPlayerJump();
3024
3025         if(self.classname == "player") {
3026                 CheckRules_Player();
3027                 UpdateChatBubble();
3028                 if (self.impulse)
3029                         ImpulseCommands();
3030                 if (intermission_running)
3031                         return;         // intermission or finale
3032                 GetPressedKeys();
3033         } else if (self.classname == "observer") {
3034                 //do nothing
3035         } else if (self.classname == "spectator") {
3036                 //do nothing
3037         }
3038
3039 #ifdef TETRIS
3040         }
3041 #endif
3042
3043         /*
3044         float i;
3045         for(i = 0; i < 1000; ++i)
3046         {
3047                 vector end;
3048                 end = self.origin + '0 0 1024' + 512 * randomvec();
3049                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3050                 if(trace_fraction < 1)
3051                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3052                 {
3053                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3054                         break;
3055                 }
3056         }
3057         */
3058
3059         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3060
3061         if(self.waypointsprite_attachedforcarrier)
3062                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3063
3064         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3065         {
3066                 if(!self.showheadshotbbox)
3067                 {
3068                         self.showheadshotbbox = spawn();
3069                         self.showheadshotbbox.classname = "headshotbbox";
3070                         self.showheadshotbbox.owner = self;
3071                         self.showheadshotbbox.think = showheadshotbbox_think;
3072                         self.showheadshotbbox.nextthink = time;
3073                         self = self.showheadshotbbox;
3074                         self.think();
3075                         self = self.owner;
3076                 }
3077         }
3078         else
3079         {
3080                 if(self.showheadshotbbox)
3081                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3082                 remove(self.showheadshotbbox);
3083         }
3084
3085         playerdemo_write();
3086
3087         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3088         {
3089                 if(!self.stored_netname)
3090                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3091                 if(self.stored_netname != self.netname)
3092                 {
3093                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3094                         strunzone(self.stored_netname);
3095                         self.stored_netname = strzone(self.netname);
3096                 }
3097         }
3098
3099         /*
3100         if(g_race)
3101                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3102         */
3103
3104         CSQCMODEL_AUTOUPDATE();
3105 }