qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 871                 else
 872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 873                 self.frags = FRAGS_PLAYER;
 874                 if(independent_players)
 875                         MAKE_INDEPENDENT_PLAYER(self);
 876                 self.flags = FL_CLIENT;
 877                 self.takedamage = DAMAGE_AIM;
 878                 if(g_minstagib)
 879                         self.effects = EF_FULLBRIGHT;
 880                 else
 881                         self.effects = 0;
 882                 self.air_finished = time + 12;
 883                 self.dmg = 2;
 884
 885                 if(inWarmupStage)
 886                 {
 887                         self.ammo_shells = warmup_start_ammo_shells;
 888                         self.ammo_nails = warmup_start_ammo_nails;
 889                         self.ammo_rockets = warmup_start_ammo_rockets;
 890                         self.ammo_cells = warmup_start_ammo_cells;
 891                         self.ammo_fuel = warmup_start_ammo_fuel;
 892                         self.health = warmup_start_health;
 893                         self.armorvalue = warmup_start_armorvalue;
 894                         self.weapons = warmup_start_weapons;
 895                 }
 896                 else
 897                 {
 898                         self.ammo_shells = start_ammo_shells;
 899                         self.ammo_nails = start_ammo_nails;
 900                         self.ammo_rockets = start_ammo_rockets;
 901                         self.ammo_cells = start_ammo_cells;
 902                         self.ammo_fuel = start_ammo_fuel;
 903                         self.health = start_health;
 904                         self.armorvalue = start_armorvalue;
 905                         self.weapons = start_weapons;
 906                 }
 907
 908                 if(g_weaponarena_random)
 909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 910
 911                 self.items = start_items;
 912                 self.jump_interval = time;
 913
 914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 919                 //extend the pause of rotting if client was reset at the beginning of the countdown
 920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 921                         self.spawnshieldtime += game_starttime - time;
 922                         self.pauserotarmor_finished += game_starttime - time;
 923                         self.pauserothealth_finished += game_starttime - time;
 924                         self.pauseregen_finished += game_starttime - time;
 925                 }
 926                 self.damageforcescale = 2;
 927                 self.death_time = 0;
 928                 self.dead_frame = 0;
 929                 self.alpha = 0;
 930                 self.scale = 0;
 931                 self.fade_time = 0;
 932                 self.pain_frame = 0;
 933                 self.pain_finished = 0;
 934                 self.strength_finished = 0;
 935                 self.invincible_finished = 0;
 936                 self.pushltime = 0;
 937                 // players have no think function
 938                 self.think = SUB_Null;
 939                 self.nextthink = 0;
 940                 self.hook_time = 0;
 941                 self.dmg_team = 0;
 942                 self.ballistics_density = cvar("g_ballistics_density_player");
 943
 944                 self.metertime = 0;
 945
 946                 self.runes = 0;
 947
 948                 self.deadflag = DEAD_NO;
 949
 950                 self.angles = spot.angles;
 951
 952                 self.angles_z = 0; // never spawn tilted even if the spot says to
 953                 self.fixangle = TRUE; // turn this way immediately
 954                 self.velocity = '0 0 0';
 955                 self.avelocity = '0 0 0';
 956                 self.punchangle = '0 0 0';
 957                 self.punchvector = '0 0 0';
 958                 self.oldvelocity = self.velocity;
 959                 self.fire_endtime = -1;
 960
 961                 msg_entity = self;
 962                 WRITESPECTATABLE_MSG_ONE({
 963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 965                 });
 966
 967                 if(sv_loddistance1)
 968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 969
 970                 self.model = "";
 971                 FixPlayermodel();
 972
 973                 self.crouch = FALSE;
 974                 self.view_ofs = PL_VIEW_OFS;
 975                 setsize (self, PL_MIN, PL_MAX);
 976                 self.spawnorigin = spot.origin;
 977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 978                 // don't reset back to last position, even if new position is stuck in solid
 979                 self.oldorigin = self.origin;
 980                 self.prevorigin = self.origin;
 981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 982
 983                 if(g_arena)
 984                 {
 985                         Spawnqueue_Remove(self);
 986                         Spawnqueue_Mark(self);
 987                 }
 988
 989                 else if(g_ca)
 990                         self.caplayer = 1;
 991
 992                 self.event_damage = PlayerDamage;
 993
 994                 self.bot_attack = TRUE;
 995
 996                 self.statdraintime = time + 5;
 997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 998
 999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1067         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1068         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1069         if(sv_foginterval && world.fog != "")
1070                 WriteString(MSG_ENTITY, world.fog);
1071         else
1072                 WriteString(MSG_ENTITY, "");
1073         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1074         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1075         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1076         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1077         return TRUE;
1078 }
1079
1080 void ClientInit_CheckUpdate()
1081 {
1082         self.nextthink = time;
1083         if(self.count != cvar("g_balance_armor_blockpercent"))
1084         {
1085                 self.count = cvar("g_balance_armor_blockpercent");
1086                 self.SendFlags |= 1;
1087         }
1088         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1089         {
1090                 self.cnt = cvar("g_balance_weaponswitchdelay");
1091                 self.SendFlags |= 1;
1092         }
1093         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1094         {
1095                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1096                 self.SendFlags |= 1;
1097         }
1098         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1099         {
1100                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1101                 self.SendFlags |= 1;
1102         }
1103 }
1104
1105 void ClientInit_Spawn()
1106 {
1107         entity o;
1108         entity e;
1109         e = spawn();
1110         e.classname = "clientinit";
1111         e.think = ClientInit_CheckUpdate;
1112         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1113
1114         o = self;
1115         self = e;
1116         ClientInit_CheckUpdate();
1117         self = o;
1118 }
1119
1120 /*
1121 =============
1122 SetNewParms
1123 =============
1124 */
1125 void SetNewParms (void)
1126 {
1127         // initialize parms for a new player
1128         parm1 = -(86400 * 366);
1129 }
1130
1131 /*
1132 =============
1133 SetChangeParms
1134 =============
1135 */
1136 void SetChangeParms (void)
1137 {
1138         // save parms for level change
1139         parm1 = self.parm_idlesince - time;
1140 }
1141
1142 /*
1143 =============
1144 DecodeLevelParms
1145 =============
1146 */
1147 void DecodeLevelParms (void)
1148 {
1149         // load parms
1150         self.parm_idlesince = parm1;
1151         if(self.parm_idlesince == -(86400 * 366))
1152                 self.parm_idlesince = time;
1153
1154         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1155         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1156 }
1157
1158 /*
1159 =============
1160 ClientKill
1161
1162 Called when a client types 'kill' in the console
1163 =============
1164 */
1165
1166 void ClientKill_Now_TeamChange()
1167 {
1168         if(self.killindicator_teamchange == -1)
1169         {
1170                 self.team = -1;
1171                 JoinBestTeam( self, FALSE, FALSE );
1172         }
1173         else
1174                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1175 }
1176
1177 void ClientKill_Now()
1178 {
1179         if(self.killindicator_teamchange)
1180                 ClientKill_Now_TeamChange();
1181
1182         // in any case:
1183         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1184
1185         if(self.killindicator)
1186         {
1187                 dprint("Cleaned up after a leaked kill indicator.\n");
1188                 remove(self.killindicator);
1189                 self.killindicator = world;
1190         }
1191 }
1192 void KillIndicator_Think()
1193 {
1194         if (!self.owner.modelindex)
1195         {
1196                 self.owner.killindicator = world;
1197                 remove(self);
1198                 return;
1199         }
1200
1201         if(self.cnt <= 0)
1202         {
1203                 self = self.owner;
1204                 ClientKill_Now(); // no oldself needed
1205                 return;
1206         }
1207         else
1208         {
1209                 if(self.cnt <= 10)
1210                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1211                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1212                 {
1213                         if(self.cnt <= 10)
1214                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1215                         if(self.owner.killindicator_teamchange)
1216                         {
1217                                 if(self.owner.killindicator_teamchange == -1)
1218                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1219                                 else
1220                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1221                         }
1222                         else
1223                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1224                 }
1225                 self.nextthink = time + 1;
1226                 self.cnt -= 1;
1227         }
1228 }
1229
1230 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1231 {
1232         float killtime;
1233         entity e;
1234         killtime = cvar("g_balance_kill_delay");
1235
1236         if(g_race_qualifying)
1237                 killtime = 0;
1238
1239         self.killindicator_teamchange = targetteam;
1240
1241         if(!self.killindicator)
1242         {
1243                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1244                 {
1245                         ClientKill_Now();
1246                 }
1247                 else
1248                 {
1249                         self.killindicator = spawn();
1250                         self.killindicator.owner = self;
1251                         self.killindicator.scale = 0.5;
1252                         setattachment(self.killindicator, self, "");
1253                         setorigin(self.killindicator, '0 0 52');
1254                         self.killindicator.think = KillIndicator_Think;
1255                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1256                         self.killindicator.cnt = ceil(killtime);
1257                         self.killindicator.count = bound(0, ceil(killtime), 10);
1258                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1259
1260                         for(e = world; (e = find(e, classname, "body")) != world; )
1261                         {
1262                                 if(e.enemy != self)
1263                                         continue;
1264                                 e.killindicator = spawn();
1265                                 e.killindicator.owner = e;
1266                                 e.killindicator.scale = 0.5;
1267                                 setattachment(e.killindicator, e, "");
1268                                 setorigin(e.killindicator, '0 0 52');
1269                                 e.killindicator.think = KillIndicator_Think;
1270                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1271                                 e.killindicator.cnt = ceil(killtime);
1272                         }
1273                         self.lip = 0;
1274                 }
1275         }
1276         if(self.killindicator)
1277         {
1278                 if(targetteam)
1279                         self.killindicator.colormod = TeamColor(targetteam);
1280                 else
1281                         self.killindicator.colormod = '0 0 0';
1282         }
1283 }
1284
1285 void ClientKill (void)
1286 {
1287         ClientKill_TeamChange(0);
1288 }
1289
1290 void DoTeamChange(float destteam)
1291 {
1292         float t, c0;
1293         if(!teams_matter)
1294         {
1295                 if(destteam >= 0)
1296                         SetPlayerColors(self, destteam);
1297                 return;
1298         }
1299         if(self.classname == "player")
1300         if(destteam == -1)
1301         {
1302                 CheckAllowedTeams(self);
1303                 t = FindSmallestTeam(self, TRUE);
1304                 switch(self.team)
1305                 {
1306                         case COLOR_TEAM1: c0 = c1; break;
1307                         case COLOR_TEAM2: c0 = c2; break;
1308                         case COLOR_TEAM3: c0 = c3; break;
1309                         case COLOR_TEAM4: c0 = c4; break;
1310                         default:          c0 = 999;
1311                 }
1312                 switch(t)
1313                 {
1314                         case 1:
1315                                 if(c0 > c1)
1316                                         destteam = COLOR_TEAM1;
1317                                 break;
1318                         case 2:
1319                                 if(c0 > c2)
1320                                         destteam = COLOR_TEAM2;
1321                                 break;
1322                         case 3:
1323                                 if(c0 > c3)
1324                                         destteam = COLOR_TEAM3;
1325                                 break;
1326                         case 4:
1327                                 if(c0 > c4)
1328                                         destteam = COLOR_TEAM4;
1329                                 break;
1330                 }
1331                 if(destteam == -1)
1332                         return;
1333         }
1334         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1335                 return;
1336         ClientKill_TeamChange(destteam);
1337 }
1338
1339 void FixClientCvars(entity e)
1340 {
1341         // send prediction settings to the client
1342         stuffcmd(e, "\nin_bindmap 0 0\n");
1343         if(g_race || g_cts)
1344                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1345         if(cvar("g_antilag") == 3) // client side hitscan
1346                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1347                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1348         /*
1349          * we no longer need to stuff this. Remove this comment block if you feel
1350          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1351         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1352         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1353         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1354         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1355         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1356         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1357         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1358         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1359         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1360         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1361         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1362         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1363         stuffcmd(e, "cl_movement_edgefriction 1\n");
1364          */
1365 }
1366
1367 /*
1368 =============
1369 ClientConnect
1370
1371 Called when a client connects to the server
1372 =============
1373 */
1374 //void ctf_clientconnect();
1375 string ColoredTeamName(float t);
1376 void DecodeLevelParms (void);
1377 //void dom_player_join_team(entity pl);
1378 #ifdef UID
1379 .float uid_kicktime;
1380 .string uid;
1381 #endif
1382 void set_dom_state(entity e, float connecting);
1383 void ClientConnect (void)
1384 {
1385         float t;
1386
1387         if(self.flags & FL_CLIENT)
1388         {
1389                 print("Warning: ClientConnect, but already connected!\n");
1390                 return;
1391         }
1392
1393         if(Ban_MaybeEnforceBan(self))
1394                 return;
1395
1396         DecodeLevelParms();
1397
1398 #ifdef WATERMARK
1399         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1400 #endif
1401
1402         self.classname = "player_joining";
1403
1404         self.flags = FL_CLIENT;
1405         self.version_nagtime = time + 10 + random() * 10;
1406
1407         if(player_count<0)
1408         {
1409                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1410                 player_count = 0;
1411         }
1412
1413         PlayerScore_Attach(self);
1414         ClientData_Attach();
1415
1416         bot_clientconnect();
1417
1418         playerdemo_init();
1419
1420         anticheat_init();
1421
1422         race_PreSpawnObserver();
1423
1424         //if(g_domination)
1425         //      dom_player_join_team(self);
1426
1427         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1428
1429         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1430                 self.classname = "observer";
1431         } else {
1432                 if(teams_matter)
1433                 {
1434                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1435                         {
1436                                 self.classname = "player";
1437                                 campaign_bots_may_start = 1;
1438                         }
1439                         else
1440                         {
1441                                 self.classname = "observer"; // do it anyway
1442                         }
1443                 }
1444                 else
1445                 {
1446                         self.classname = "player";
1447                         campaign_bots_may_start = 1;
1448                 }
1449         }
1450
1451         self.playerid = (playerid_last = playerid_last + 1);
1452
1453         if(cvar("sv_eventlog"))
1454                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1455
1456         LogTeamchange(self.playerid, self.team, 1);
1457
1458         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1459
1460         self.netname_previous = strzone(self.netname);
1461
1462         bprint("^4", self.netname, "^4 connected");
1463
1464         if(self.classname != "observer" && (g_domination || g_ctf))
1465                 bprint(" and joined the ", ColoredTeamName(self.team));
1466
1467         bprint("\n");
1468
1469         self.welcomemessage_time = 0;
1470
1471         stuffcmd(self, strcat(clientstuff, "\n"));
1472         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1473         stuffcmd(self, "cl_particles_reloadeffects\n");
1474
1475         FixClientCvars(self);
1476
1477         // spawnfunc_waypoint sprites
1478         WaypointSprite_InitClient(self);
1479
1480         // Wazat's grappling hook
1481         SetGrappleHookBindings();
1482
1483         // get autoswitch state from player when he toggles it
1484         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1485
1486         // get version info from player
1487         stuffcmd(self, "cmd clientversion $gameversion\n");
1488
1489         // get other cvars from player
1490         GetCvars(0);
1491
1492         // set cvar for team scoreboard
1493         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1494
1495         // notify about available teams
1496         if(teams_matter)
1497         {
1498                 CheckAllowedTeams(self);
1499                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1500                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1501         }
1502         else
1503                 stuffcmd(self, "set _teams_available 0\n");
1504
1505         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1506
1507         if(g_arena || g_ca)
1508         {
1509                 self.classname = "observer";
1510                 if(g_arena)
1511                         Spawnqueue_Insert(self);
1512         }
1513         /*else if(g_ctf)
1514         {
1515                 ctf_clientconnect();
1516         }*/
1517
1518         if(teams_matter || radar_showennemies)
1519                 attach_entcs();
1520
1521         bot_relinkplayerlist();
1522
1523         self.spectatortime = time;
1524         if(blockSpectators)
1525         {
1526                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1527         }
1528
1529         self.jointime = time;
1530         self.allowedTimeouts = cvar("sv_timeout_number");
1531
1532         if(clienttype(self) == CLIENTTYPE_REAL)
1533         {
1534                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1535                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1536         }
1537
1538         if(g_lms)
1539         {
1540                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1541                 {
1542                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1543                         self.frags = FRAGS_SPECTATOR;
1544                 }
1545         }
1546
1547         if(!sv_foginterval && world.fog != "")
1548                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1549
1550         SoundEntity_Attach(self);
1551
1552         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1553         {
1554                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1555                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1556         }
1557         else
1558                 self.hitplotfh = -1;
1559
1560 #ifdef UID
1561         if(clienttype(self) == CLIENTTYPE_REAL)
1562         if not(self.uid)
1563                 self.uid_kicktime = time + 60;
1564 #endif
1565
1566         if(g_race || g_cts) {
1567                 string rr;
1568                 if(g_cts)
1569                         rr = CTS_RECORD;
1570                 else
1571                         rr = RACE_RECORD;
1572                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1573
1574                 race_send_recordtime(MSG_ONE);
1575                 race_send_speedaward(MSG_ONE);
1576
1577                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1578                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1579                 race_send_speedaward_alltimebest(MSG_ONE);
1580
1581                 float i;
1582                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1583                         race_SendRankings(i, 0, 0, MSG_ONE);
1584                 }
1585         }
1586         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1587                 send_CSQC_teamnagger();
1588
1589         if (g_domination)
1590                 set_dom_state(self, TRUE);
1591
1592         CheatInitClient();
1593 }
1594
1595 /*
1596 =============
1597 ClientDisconnect
1598
1599 Called when a client disconnects from the server
1600 =============
1601 */
1602 .entity chatbubbleentity;
1603 .entity teambubbleentity;
1604 void ReadyCount();
1605 void ClientDisconnect (void)
1606 {
1607         if not(self.flags & FL_CLIENT)
1608         {
1609                 print("Warning: ClientDisconnect without ClientConnect\n");
1610                 return;
1611         }
1612
1613         CheatShutdownClient();
1614
1615         if(self.hitplotfh >= 0)
1616         {
1617                 fclose(self.hitplotfh);
1618                 self.hitplotfh = -1;
1619         }
1620
1621         anticheat_report();
1622         anticheat_shutdown();
1623
1624         playerdemo_shutdown();
1625
1626         bot_clientdisconnect();
1627
1628         if(self.entcs)
1629                 detach_entcs();
1630
1631         if(cvar("sv_eventlog"))
1632                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1633         bprint ("^4",self.netname);
1634         bprint ("^4 disconnected\n");
1635
1636         SoundEntity_Detach(self);
1637
1638         DropAllRunes(self);
1639         MUTATOR_CALLHOOK(ClientDisconnect);
1640
1641         Portal_ClearAll(self);
1642
1643         if(self.flagcarried)
1644                 DropFlag(self.flagcarried, world, world);
1645         if(self.ballcarried)
1646                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1647
1648         // Here, everything has been done that requires this player to be a client.
1649
1650         self.flags &~= FL_CLIENT;
1651
1652         if (self.chatbubbleentity)
1653                 remove (self.chatbubbleentity);
1654
1655         if (self.teambubbleentity)
1656                 remove (self.teambubbleentity);
1657
1658         if (self.killindicator)
1659                 remove (self.killindicator);
1660
1661         WaypointSprite_PlayerGone();
1662
1663         bot_relinkplayerlist();
1664
1665         // remove laserdot
1666         if(self.weaponentity)
1667                 if(self.weaponentity.lasertarget)
1668                         remove(self.weaponentity.lasertarget);
1669
1670         if(g_arena)
1671         {
1672                 Spawnqueue_Unmark(self);
1673                 Spawnqueue_Remove(self);
1674         }
1675
1676         ClientData_Detach();
1677         PlayerScore_Detach(self);
1678
1679         if(self.netname_previous)
1680                 strunzone(self.netname_previous);
1681         if(self.clientstatus)
1682                 strunzone(self.clientstatus);
1683
1684         ClearPlayerSounds();
1685
1686         if(self.personal)
1687                 remove(self.personal);
1688
1689         self.playerid = 0;
1690         ReadyCount();
1691
1692         // free cvars
1693         GetCvars(-1);
1694 }
1695
1696 .float BUTTON_CHAT;
1697 void ChatBubbleThink()
1698 {
1699         self.nextthink = time;
1700         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1701         {
1702                 if(self.owner) // but why can that ever be world?
1703                         self.owner.chatbubbleentity = world;
1704                 remove(self);
1705                 return;
1706         }
1707         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1708 #ifdef TETRIS
1709                 || self.owner.tetris_on
1710 #endif
1711         )
1712                 self.model = self.mdl;
1713         else
1714                 self.model = "";
1715 };
1716
1717 void UpdateChatBubble()
1718 {
1719         if (!self.modelindex)
1720                 return;
1721         // spawn a chatbubble entity if needed
1722         if (!self.chatbubbleentity)
1723         {
1724                 self.chatbubbleentity = spawn();
1725                 self.chatbubbleentity.owner = self;
1726                 self.chatbubbleentity.exteriormodeltoclient = self;
1727                 self.chatbubbleentity.think = ChatBubbleThink;
1728                 self.chatbubbleentity.nextthink = time;
1729                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1730                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1731                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1732                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1733                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1734                 self.chatbubbleentity.model = "";
1735                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1736         }
1737 }
1738
1739
1740 void TeamBubbleThink()
1741 {
1742         self.nextthink = time;
1743         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1744         {
1745                 if(self.owner) // but why can that ever be world?
1746                         self.owner.teambubbleentity = world;
1747                 remove(self);
1748                 return;
1749         }
1750 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1751         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1752                 self.model = "";
1753         else
1754                 self.model = self.mdl;
1755
1756 };
1757
1758 float TeamBubble_customizeentityforclient()
1759 {
1760         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1761 }
1762
1763 void UpdateTeamBubble()
1764 {
1765         if (!self.modelindex || !teams_matter)
1766                 return;
1767         // spawn a teambubble entity if needed
1768         if (!self.teambubbleentity && teams_matter)
1769         {
1770                 self.teambubbleentity = spawn();
1771                 self.teambubbleentity.owner = self;
1772                 self.teambubbleentity.exteriormodeltoclient = self;
1773                 self.teambubbleentity.think = TeamBubbleThink;
1774                 self.teambubbleentity.nextthink = time;
1775                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1776 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1777                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1778                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1779                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1780                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1781                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1782                 self.teambubbleentity.effects = EF_LOWPRECISION;
1783         }
1784 }
1785
1786 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1787 // added to the model skins
1788 /*void UpdateColorModHack()
1789 {
1790         local float c;
1791         c = self.clientcolors & 15;
1792         // LordHavoc: only bothering to support white, green, red, yellow, blue
1793              if (!teams_matter) self.colormod = '0 0 0';
1794         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1795         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1796         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1797         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1798         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1799         else self.colormod = '1 1 1';
1800 };*/
1801
1802 .float oldcolormap;
1803 void respawn(void)
1804 {
1805         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1806         {
1807                 self.solid = SOLID_NOT;
1808                 self.takedamage = DAMAGE_NO;
1809                 self.movetype = MOVETYPE_FLY;
1810                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1811                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1812                 self.effects |= EF_ADDITIVE;
1813                 self.oldcolormap = self.colormap;
1814                 self.colormap = 512;
1815                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1816                 if(cvar("g_respawn_ghosts_maxtime"))
1817                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1818         }
1819
1820         CopyBody(1);
1821         self.effects |= EF_NODRAW; // prevent another CopyBody
1822         if(self.oldcolormap)
1823         {
1824                 self.colormap = self.oldcolormap;
1825                 self.oldcolormap = 0;
1826         }
1827         PutClientInServer();
1828 }
1829
1830 void play_countdown(float finished, string samp)
1831 {
1832         if(clienttype(self) == CLIENTTYPE_REAL)
1833                 if(floor(finished - time - frametime) != floor(finished - time))
1834                         if(finished - time < 6)
1835                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1836 }
1837
1838 /**
1839  * When sv_timeout is used this function returs strings like
1840  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1841  * Called by centerprint functions
1842  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1843  */
1844 string getTimeoutText(float addOneSecond) {
1845         if (!cvar("sv_timeout") || !timeoutStatus)
1846                 return "";
1847
1848         local string retStr;
1849         if (timeoutStatus == 1) {
1850                 if (addOneSecond == 1) {
1851                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1852                 }
1853                 else {
1854                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1855                 }
1856                 return retStr;
1857         }
1858         else if (timeoutStatus == 2) {
1859                 if (addOneSecond) {
1860                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1861                         //don't show messages like "Timeout ends in 0 seconds"...
1862                         if ((remainingTimeoutTime + 1) > 0)
1863                                 return retStr;
1864                         else
1865                                 return "";
1866                 }
1867                 else {
1868                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1869                         //don't show messages like "Timeout ends in 0 seconds"...
1870                         if (remainingTimeoutTime > 0)
1871                                 return retStr;
1872                         else
1873                                 return "";
1874                 }
1875         }
1876         else return "";
1877 }
1878
1879 void player_powerups (void)
1880 {
1881         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1882         {
1883                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1884                 self.modelflags |= MF_ROCKET;
1885         }
1886         else
1887         {
1888                 SoundEntity_StopSound(self, CHAN_PLAYER);
1889                 self.modelflags &~= MF_ROCKET;
1890         }
1891
1892         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1893
1894         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1895                 return;
1896
1897         Fire_ApplyDamage(self);
1898         Fire_ApplyEffect(self);
1899
1900         if (g_minstagib)
1901         {
1902                 self.effects |= EF_FULLBRIGHT;
1903
1904                 if (self.items & IT_STRENGTH)
1905                 {
1906                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1907                         if (time > self.strength_finished)
1908                         {
1909                                 self.alpha = default_player_alpha;
1910                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1911                                 self.items &~= IT_STRENGTH;
1912                                 sprint(self, "^3Invisibility has worn off\n");
1913                         }
1914                 }
1915                 else
1916                 {
1917                         if (time < self.strength_finished)
1918                         {
1919                                 self.alpha = g_minstagib_invis_alpha;
1920                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1921                                 self.items |= IT_STRENGTH;
1922                                 sprint(self, "^3You are invisible\n");
1923                         }
1924                 }
1925
1926                 if (self.items & IT_INVINCIBLE)
1927                 {
1928                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1929                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1930                         {
1931                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1932                                 sprint(self, "^3Speed has worn off\n");
1933                         }
1934                 }
1935                 else
1936                 {
1937                         if (time < self.invincible_finished)
1938                         {
1939                                 self.items = self.items | IT_INVINCIBLE;
1940                                 sprint(self, "^3You are on speed\n");
1941                         }
1942                 }
1943                 return;
1944         }
1945
1946         if (self.items & IT_STRENGTH)
1947         {
1948                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1949                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1950                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1951                 {
1952                         self.items = self.items - (self.items & IT_STRENGTH);
1953                         sprint(self, "^3Strength has worn off\n");
1954                 }
1955         }
1956         else
1957         {
1958                 if (time < self.strength_finished)
1959                 {
1960                         self.items = self.items | IT_STRENGTH;
1961                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1962                 }
1963         }
1964         if (self.items & IT_INVINCIBLE)
1965         {
1966                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1967                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1968                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1969                 {
1970                         self.items = self.items - (self.items & IT_INVINCIBLE);
1971                         sprint(self, "^3Shield has worn off\n");
1972                 }
1973         }
1974         else
1975         {
1976                 if (time < self.invincible_finished)
1977                 {
1978                         self.items = self.items | IT_INVINCIBLE;
1979                         sprint(self, "^3Shield surrounds you\n");
1980                 }
1981         }
1982
1983         if(cvar("g_nodepthtestplayers"))
1984                 self.effects = self.effects | EF_NODEPTHTEST;
1985
1986         if(cvar("g_fullbrightplayers"))
1987                 self.effects = self.effects | EF_FULLBRIGHT;
1988
1989         // midair gamemode: damage only while in the air
1990         // if in midair mode, being on ground grants temporary invulnerability
1991         // (this is so that multishot weapon don't clear the ground flag on the
1992         // first damage in the frame, leaving the player vulnerable to the
1993         // remaining hits in the same frame)
1994         if (self.flags & FL_ONGROUND)
1995         if (g_midair)
1996                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1997
1998         if (time >= game_starttime)
1999         if (time < self.spawnshieldtime)
2000                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2001 }
2002
2003 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2004 {
2005         if(current > stable)
2006                 return current;
2007         else if(current > stable - 0.25) // when close enough, "snap"
2008                 return stable;
2009         else
2010                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2011 }
2012
2013 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2014 {
2015         if(current < stable)
2016                 return current;
2017         else if(current < stable + 0.25) // when close enough, "snap"
2018                 return stable;
2019         else
2020                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2021 }
2022
2023 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2024 {
2025         if(current > rotstable)
2026         {
2027                 if(rotframetime > 0)
2028                 {
2029                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2030                         current = max(rotstable, current - rotlinear * rotframetime);
2031                 }
2032         }
2033         else if(current < regenstable)
2034         {
2035                 if(regenframetime > 0)
2036                 {
2037                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2038                         current = min(regenstable, current + regenlinear * regenframetime);
2039                 }
2040         }
2041
2042         if(current > limit)
2043                 current = limit;
2044
2045         return current;
2046 }
2047
2048 void player_regen (void)
2049 {
2050         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2051         maxh = cvar("g_balance_health_rotstable");
2052         maxa = cvar("g_balance_armor_rotstable");
2053         maxf = cvar("g_balance_fuel_rotstable");
2054         minh = cvar("g_balance_health_regenstable");
2055         mina = cvar("g_balance_armor_regenstable");
2056         minf = cvar("g_balance_fuel_regenstable");
2057         limith = cvar("g_balance_health_limit");
2058         limita = cvar("g_balance_armor_limit");
2059         limitf = cvar("g_balance_fuel_limit");
2060
2061         max_mod = regen_mod = rot_mod = limit_mod = 1;
2062
2063         if (self.runes & RUNE_REGEN)
2064         {
2065                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2066                 {
2067                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2068                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2069                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2070                 }
2071                 else
2072                 {
2073                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2074                         max_mod = cvar("g_balance_rune_regen_hpmod");
2075                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2076                 }
2077         }
2078         else if (self.runes & CURSE_VENOM)
2079         {
2080                 max_mod = cvar("g_balance_curse_venom_hpmod");
2081                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2082                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2083                 else
2084                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2085                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2086                 //if (!self.runes & RUNE_REGEN)
2087                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2088         }
2089         maxh = maxh * max_mod;
2090         //maxa = maxa * max_mod;
2091         //maxf = maxf * max_mod;
2092         minh = minh * max_mod;
2093         //mina = mina * max_mod;
2094         //minf = minf * max_mod;
2095         limith = limith * limit_mod;
2096         limita = limita * limit_mod;
2097         //limitf = limitf * limit_mod;
2098
2099         if(g_lms && g_ca)
2100                 rot_mod = 0;
2101
2102         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2103         {
2104                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2105                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2106
2107                 // if player rotted to death...  die!
2108                 if(self.health < 1)
2109                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2110         }
2111
2112         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2113                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2114 }
2115
2116 float zoomstate_set;
2117 void SetZoomState(float z)
2118 {
2119         if(z != self.zoomstate)
2120         {
2121                 self.zoomstate = z;
2122                 ClientData_Touch(self);
2123         }
2124         zoomstate_set = 1;
2125 }
2126
2127 void GetPressedKeys(void) {
2128         MUTATOR_CALLHOOK(GetPressedKeys);
2129         if (self.movement_x > 0) // get if movement keys are pressed
2130         {       // forward key pressed
2131                 self.pressedkeys |= KEY_FORWARD;
2132                 self.pressedkeys &~= KEY_BACKWARD;
2133         }
2134         else if (self.movement_x < 0)
2135         {       // backward key pressed
2136                 self.pressedkeys |= KEY_BACKWARD;
2137                 self.pressedkeys &~= KEY_FORWARD;
2138         }
2139         else
2140         {       // no x input
2141                 self.pressedkeys &~= KEY_FORWARD;
2142                 self.pressedkeys &~= KEY_BACKWARD;
2143         }
2144
2145         if (self.movement_y > 0)
2146         {       // right key pressed
2147                 self.pressedkeys |= KEY_RIGHT;
2148                 self.pressedkeys &~= KEY_LEFT;
2149         }
2150         else if (self.movement_y < 0)
2151         {       // left key pressed
2152                 self.pressedkeys |= KEY_LEFT;
2153                 self.pressedkeys &~= KEY_RIGHT;
2154         }
2155         else
2156         {       // no y input
2157                 self.pressedkeys &~= KEY_RIGHT;
2158                 self.pressedkeys &~= KEY_LEFT;
2159         }
2160
2161         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2162                 self.pressedkeys |= KEY_JUMP;
2163         else
2164                 self.pressedkeys &~= KEY_JUMP;
2165         if (self.BUTTON_CROUCH)
2166                 self.pressedkeys |= KEY_CROUCH;
2167         else
2168                 self.pressedkeys &~= KEY_CROUCH;
2169 }
2170
2171 void update_stats (float number, float hit, float fired) {
2172 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2173 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2174
2175         if(number) {
2176                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2177                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2178         } else {
2179                 self.stat_hit = hit * sv_accuracy_data_share;
2180                 self.stat_fired = fired * sv_accuracy_data_share;
2181         }
2182 }
2183
2184 /*
2185 ======================
2186 spectate mode routines
2187 ======================
2188 */
2189
2190 .float weapon_count;
2191 void SpectateCopy(entity spectatee) {
2192         if(spectatee.weapon_count < WEP_LAST) {
2193                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2194                 spectatee.weapon_count ++;
2195         } else
2196                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2197
2198         other = spectatee;
2199         MUTATOR_CALLHOOK(SpectateCopy);
2200         self.armortype = spectatee.armortype;
2201         self.armorvalue = spectatee.armorvalue;
2202         self.ammo_cells = spectatee.ammo_cells;
2203         self.ammo_shells = spectatee.ammo_shells;
2204         self.ammo_nails = spectatee.ammo_nails;
2205         self.ammo_rockets = spectatee.ammo_rockets;
2206         self.ammo_fuel = spectatee.ammo_fuel;
2207         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2208         self.health = spectatee.health;
2209         self.impulse = 0;
2210         self.items = spectatee.items;
2211         self.metertime = spectatee.metertime;
2212         self.strength_finished = spectatee.strength_finished;
2213         self.invincible_finished = spectatee.invincible_finished;
2214         self.pressedkeys = spectatee.pressedkeys;
2215         self.weapons = spectatee.weapons;
2216         self.switchweapon = spectatee.switchweapon;
2217         self.weapon = spectatee.weapon;
2218         self.punchangle = spectatee.punchangle;
2219         self.view_ofs = spectatee.view_ofs;
2220         self.v_angle = spectatee.v_angle;
2221         self.velocity = spectatee.velocity;
2222         self.dmg_take = spectatee.dmg_take;
2223         self.dmg_save = spectatee.dmg_save;
2224         self.dmg_inflictor = spectatee.dmg_inflictor;
2225         self.angles = spectatee.v_angle;
2226         self.fixangle = TRUE;
2227         setorigin(self, spectatee.origin);
2228         setsize(self, spectatee.mins, spectatee.maxs);
2229         SetZoomState(spectatee.zoomstate);
2230
2231         anticheat_spectatecopy(spectatee);
2232 }
2233
2234 float SpectateUpdate() {
2235         if(!self.enemy)
2236                 return 0;
2237
2238         if (self == self.enemy)
2239                 return 0;
2240
2241         if(self.enemy.classname != "player")
2242                 return 0;
2243
2244         SpectateCopy(self.enemy);
2245
2246         return 1;
2247 }
2248
2249 float SpectateNext() {
2250         other = find(self.enemy, classname, "player");
2251
2252         if (!other)
2253                 other = find(other, classname, "player");
2254
2255         if (other)
2256                 self.enemy = other;
2257
2258         if(self.enemy.classname == "player") {
2259                 msg_entity = self;
2260                 WriteByte(MSG_ONE, SVC_SETVIEW);
2261                 WriteEntity(MSG_ONE, self.enemy);
2262                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2263                 self.movetype = MOVETYPE_NONE;
2264
2265                 self.enemy.weapon_count = 0;
2266
2267                 if(!SpectateUpdate())
2268                         PutObserverInServer();
2269
2270                 return 1;
2271         } else {
2272                 return 0;
2273         }
2274 }
2275
2276 /*
2277 =============
2278 ShowRespawnCountdown()
2279
2280 Update a respawn countdown display.
2281 =============
2282 */
2283 void ShowRespawnCountdown()
2284 {
2285         float number;
2286         if(self.deadflag == DEAD_NO) // just respawned?
2287                 return;
2288         else
2289         {
2290                 number = ceil(self.death_time - time);
2291                 if(number <= 0)
2292                         return;
2293                 if(number <= self.respawn_countdown)
2294                 {
2295                         self.respawn_countdown = number - 1;
2296                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2297                                 AnnounceTo(self, strcat(ftos(number), ""));
2298                 }
2299         }
2300 }
2301
2302 void LeaveSpectatorMode()
2303 {
2304         if(isJoinAllowed()) {
2305                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2306                         self.classname = "player";
2307
2308                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2309                                 JoinBestTeam(self, FALSE, TRUE);
2310
2311                         if(cvar("g_campaign"))
2312                                 campaign_bots_may_start = 1;
2313
2314                         self.stat_count = WEP_LAST;
2315
2316                         PutClientInServer();
2317
2318                         if(self.classname == "player")
2319                                 bprint ("^4", self.netname, "^4 is playing now\n");
2320
2321                         if(!cvar("g_campaign"))
2322                                 centerprint(self,""); // clear MOTD
2323
2324                         return;
2325                 } else {
2326                         if (g_ca && self.caplayer) {
2327                         }       // do nothing
2328                         else
2329                                 stuffcmd(self,"menu_showteamselect\n");
2330                         return;
2331                 }
2332         }
2333         else {
2334                 //player may not join because of g_maxplayers is set
2335                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2336         }
2337 }
2338
2339 /**
2340  * Determines whether the player is allowed to join. This depends on cvar
2341  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2342  * it checks whether the number of currently playing players exceeds g_maxplayers.
2343  * @return bool TRUE if the player is allowed to join, false otherwise
2344  */
2345 float isJoinAllowed() {
2346         if (!cvar("g_maxplayers"))
2347                 return TRUE;
2348
2349         local entity e;
2350         local float currentlyPlaying;
2351         FOR_EACH_REALPLAYER(e) {
2352                 if(e.classname == "player")
2353                         currentlyPlaying += 1;
2354         }
2355         if(currentlyPlaying < cvar("g_maxplayers"))
2356                 return TRUE;
2357
2358         return FALSE;
2359 }
2360
2361 /**
2362  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2363  * g_maxplayers_spectator_blocktime seconds
2364  */
2365 void checkSpectatorBlock() {
2366         if(self.classname == "spectator" || self.classname == "observer") {
2367                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2368                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2369                         dropclient(self);
2370                 }
2371         }
2372 }
2373
2374 float vercmp_recursive(string v1, string v2)
2375 {
2376         float dot1, dot2;
2377         string s1, s2;
2378         float r;
2379
2380         dot1 = strstrofs(v1, ".", 0);
2381         dot2 = strstrofs(v2, ".", 0);
2382         if(dot1 == -1)
2383                 s1 = v1;
2384         else
2385                 s1 = substring(v1, 0, dot1);
2386         if(dot2 == -1)
2387                 s2 = v2;
2388         else
2389                 s2 = substring(v2, 0, dot2);
2390
2391         r = stof(s1) - stof(s2);
2392         if(r != 0)
2393                 return r;
2394
2395         r = strcasecmp(s1, s2);
2396         if(r != 0)
2397                 return r;
2398
2399         if(dot1 == -1)
2400                 if(dot2 == -1)
2401                         return 0;
2402                 else
2403                         return -1;
2404         else
2405                 if(dot2 == -1)
2406                         return 1;
2407                 else
2408                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2409 }
2410
2411 float vercmp(string v1, string v2)
2412 {
2413         if(strcasecmp(v1, v2) == 0) // early out check
2414                 return 0;
2415         return vercmp_recursive(v1, v2);
2416 }
2417
2418 void ObserverThink()
2419 {
2420         if (self.flags & FL_JUMPRELEASED) {
2421                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2422                         self.welcomemessage_time = 0;
2423                         self.flags &~= FL_JUMPRELEASED;
2424                         self.flags |= FL_SPAWNING;
2425                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2426                         self.welcomemessage_time = 0;
2427                         self.flags &~= FL_JUMPRELEASED;
2428                         if(SpectateNext() == 1) {
2429                                 self.classname = "spectator";
2430                         }
2431                 }
2432         } else {
2433                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2434                         self.flags |= FL_JUMPRELEASED;
2435                         if(self.flags & FL_SPAWNING)
2436                         {
2437                                 self.flags &~= FL_SPAWNING;
2438                                 LeaveSpectatorMode();
2439                                 return;
2440                         }
2441                 }
2442         }
2443         PrintWelcomeMessage(self);
2444 }
2445
2446 void SpectatorThink()
2447 {
2448         if (self.flags & FL_JUMPRELEASED) {
2449                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2450                         self.welcomemessage_time = 0;
2451                         self.flags &~= FL_JUMPRELEASED;
2452                         self.flags |= FL_SPAWNING;
2453                 } else if(self.BUTTON_ATCK) {
2454                         self.welcomemessage_time = 0;
2455                         self.flags &~= FL_JUMPRELEASED;
2456                         if(SpectateNext() == 1) {
2457                                 self.classname = "spectator";
2458                         } else {
2459                                 self.classname = "observer";
2460                                 self.stat_count = WEP_LAST;
2461                                 PutClientInServer();
2462                         }
2463                 } else if (self.BUTTON_ATCK2) {
2464                         self.welcomemessage_time = 0;
2465                         self.flags &~= FL_JUMPRELEASED;
2466                         self.classname = "observer";
2467                         self.stat_count = WEP_LAST;
2468                         PutClientInServer();
2469                 } else {
2470                         if(!SpectateUpdate())
2471                                 PutObserverInServer();
2472                 }
2473         } else {
2474                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2475                         self.flags |= FL_JUMPRELEASED;
2476                         if(self.flags & FL_SPAWNING)
2477                         {
2478                                 self.flags &~= FL_SPAWNING;
2479                                 LeaveSpectatorMode();
2480                                 return;
2481                         }
2482                 }
2483         }
2484
2485         PrintWelcomeMessage(self);
2486         self.flags |= FL_CLIENT | FL_NOTARGET;
2487 }
2488
2489 .float touchexplode_time;
2490
2491 /*
2492 =============
2493 PlayerPreThink
2494
2495 Called every frame for each client before the physics are run
2496 =============
2497 */
2498 void() ctf_setstatus;
2499 void() nexball_setstatus;
2500 .float items_added;
2501 void PlayerPreThink (void)
2502 {
2503         self.stat_game_starttime = game_starttime;
2504         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2505         self.stat_leadlimit = cvar("leadlimit");
2506
2507         if(frametime)
2508         {
2509                 // physics frames: update anticheat stuff
2510                 anticheat_prethink();
2511         }
2512
2513         if(blockSpectators && frametime)
2514                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2515                 checkSpectatorBlock();
2516
2517         zoomstate_set = 0;
2518
2519         if(self.netname_previous != self.netname)
2520         {
2521                 if(cvar("sv_eventlog"))
2522                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2523                 if(self.netname_previous)
2524                         strunzone(self.netname_previous);
2525                 self.netname_previous = strzone(self.netname);
2526         }
2527
2528         // version nagging
2529         if(self.version_nagtime)
2530                 if(self.cvar_g_xonoticversion)
2531                         if(time > self.version_nagtime)
2532                         {
2533                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2534                                 {
2535                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2536                                         {
2537                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2538                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2539                                         }
2540                                         else
2541                                         {
2542                                                 float r;
2543                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2544                                                 if(r < 0)
2545                                                 {
2546                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2547                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2548                                                 }
2549                                                 else if(r > 0)
2550                                                 {
2551                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2552                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2553                                                 }
2554                                         }
2555                                 }
2556                                 self.version_nagtime = 0;
2557                         }
2558
2559         // GOD MODE info
2560         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2561         {
2562                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2563                 self.max_armorvalue = 0;
2564         }
2565
2566 #ifdef TETRIS
2567         if (TetrisPreFrame())
2568                 return;
2569 #endif
2570
2571         MUTATOR_CALLHOOK(PlayerPreThink);
2572
2573         if(self.classname == "player") {
2574 //              if(self.netname == "Wazat")
2575 //                      bprint(self.classname, "\n");
2576
2577                 CheckRules_Player();
2578
2579                 PrintWelcomeMessage(self);
2580
2581                 if (intermission_running)
2582                 {
2583                         IntermissionThink ();   // otherwise a button could be missed between
2584                         return;                                 // the think tics
2585                 }
2586
2587                 if(self.teleport_time)
2588                 if(time > self.teleport_time)
2589                 {
2590                         self.teleport_time = 0;
2591                         self.effects = self.effects - (self.effects & EF_NODRAW);
2592                 }
2593
2594                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2595                         UpdateSelectedPlayer();
2596
2597                 //don't allow the player to turn around while game is paused!
2598                 if(timeoutStatus == 2) {
2599                         self.v_angle = self.lastV_angle;
2600                         self.angles = self.lastV_angle;
2601                         self.fixangle = TRUE;
2602                 }
2603
2604                 if(frametime)
2605                 {
2606                         if(self.health <= 0 && cvar("g_deathglow"))
2607                         {
2608                                 if(self.glowmod_x > 0)
2609                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2610                                 else
2611                                         self.glowmod_x = -1;
2612                                 if(self.glowmod_y > 0)
2613                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2614                                 else
2615                                         self.glowmod_y = -1;
2616                                 if(self.glowmod_z > 0)
2617                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2618                                 else
2619                                         self.glowmod_z = -1;
2620                         }
2621                         else
2622                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2623                         player_powerups();
2624                 }
2625
2626                 if (self.deadflag != DEAD_NO)
2627                 {
2628                         float button_pressed, force_respawn;
2629                         if(self.personal && g_race_qualifying)
2630                         {
2631                                 if(time > self.death_time)
2632                                 {
2633                                         self.death_time = time + 1; // only retry once a second
2634                                         respawn();
2635                                         self.impulse = 141;
2636                                 }
2637                         }
2638                         else
2639                         {
2640                                 if(frametime)
2641                                         player_anim();
2642                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2643                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2644                                 if (self.deadflag == DEAD_DYING)
2645                                 {
2646                                         if(force_respawn)
2647                                                 self.deadflag = DEAD_RESPAWNING;
2648                                         else if(!button_pressed)
2649                                                 self.deadflag = DEAD_DEAD;
2650                                 }
2651                                 else if (self.deadflag == DEAD_DEAD)
2652                                 {
2653                                         if(button_pressed)
2654                                                 self.deadflag = DEAD_RESPAWNABLE;
2655                                 }
2656                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2657                                 {
2658                                         if(!button_pressed)
2659                                                 self.deadflag = DEAD_RESPAWNING;
2660                                 }
2661                                 else if (self.deadflag == DEAD_RESPAWNING)
2662                                 {
2663                                         if(time > self.death_time)
2664                                         {
2665                                                 self.death_time = time + 1; // only retry once a second
2666                                                 respawn();
2667                                         }
2668                                 }
2669                                 ShowRespawnCountdown();
2670                         }
2671                         return;
2672                 }
2673
2674                 if(g_touchexplode)
2675                 if(time > self.touchexplode_time)
2676                 if(self.classname == "player")
2677                 if(self.deadflag == DEAD_NO)
2678                 if not(IS_INDEPENDENT_PLAYER(self))
2679                 FOR_EACH_PLAYER(other) if(self != other)
2680                 {
2681                         if(time > other.touchexplode_time)
2682                         if(other.deadflag == DEAD_NO)
2683                         if not(IS_INDEPENDENT_PLAYER(other))
2684                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2685                         {
2686                                 PlayerTouchExplode(self, other);
2687                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2688                         }
2689                 }
2690
2691                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2692                 {
2693                         vector dist;
2694
2695                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2696                         dist = self.prevorigin - self.origin;
2697                         dist_z = 0;
2698                         self.lms_traveled_distance += fabs(vlen(dist));
2699
2700                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2701                         {
2702                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2703                                 self.lms_traveled_distance = 0;
2704                         }
2705
2706                         if(time > self.lms_nextcheck)
2707                         {
2708                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2709                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2710                                 {
2711                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2712                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2713                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2714                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2715                                 }
2716                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2717                                 self.lms_traveled_distance = 0;
2718                         }
2719                 }
2720
2721                 self.prevorigin = self.origin;
2722
2723                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2724                 {
2725                         if (!self.crouch)
2726                         {
2727                                 self.crouch = TRUE;
2728                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2729                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2730                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2731                         }
2732                 }
2733                 else
2734                 {
2735                         if (self.crouch)
2736                         {
2737                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2738                                 if (!trace_startsolid)
2739                                 {
2740                                         self.crouch = FALSE;
2741                                         self.view_ofs = PL_VIEW_OFS;
2742                                         setsize (self, PL_MIN, PL_MAX);
2743                                 }
2744                         }
2745                 }
2746
2747                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2748                 {
2749                         if(self.bloodloss_timer < time)
2750                         {
2751                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2752                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2753                         }
2754                 }
2755
2756                 FixPlayermodel();
2757
2758                 GrapplingHookFrame();
2759
2760                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2761                 //if(frametime)
2762                 {
2763                         self.items &~= self.items_added;
2764
2765                         W_WeaponFrame();
2766
2767                         self.items_added = 0;
2768                         if(self.items & IT_JETPACK)
2769                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2770                                         self.items_added |= IT_FUEL;
2771
2772                         self.items |= self.items_added;
2773                 }
2774
2775                 player_regen();
2776                 if(frametime)
2777                         player_anim();
2778
2779                 if (g_minstagib)
2780                         minstagib_ammocheck();
2781
2782                 ctf_setstatus();
2783                 nexball_setstatus();
2784
2785                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2786
2787                 //self.angles_y=self.v_angle_y + 90;   // temp
2788         } else if(gameover) {
2789                 if (intermission_running)
2790                         IntermissionThink ();   // otherwise a button could be missed between
2791                 return;
2792         } else if(self.classname == "observer") {
2793                 ObserverThink();
2794         } else if(self.classname == "spectator") {
2795                 SpectatorThink();
2796         }
2797
2798         if(!zoomstate_set)
2799                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2800
2801         float oldspectatee_status;
2802         oldspectatee_status = self.spectatee_status;
2803         if(self.classname == "spectator")
2804                 self.spectatee_status = num_for_edict(self.enemy);
2805         else if(self.classname == "observer")
2806                 self.spectatee_status = num_for_edict(self);
2807         else
2808                 self.spectatee_status = 0;
2809         if(self.spectatee_status != oldspectatee_status)
2810         {
2811                 ClientData_Touch(self);
2812                 if(g_race || g_cts)
2813                         race_InitSpectator();
2814         }
2815
2816         if(self.teamkill_soundtime)
2817         if(time > self.teamkill_soundtime)
2818         {
2819                 self.teamkill_soundtime = 0;
2820
2821                 entity oldpusher, oldself;
2822
2823                 oldself = self; self = self.teamkill_soundsource;
2824                 oldpusher = self.pusher; self.pusher = oldself;
2825
2826                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2827
2828                 self.pusher = oldpusher;
2829                 self = oldself;
2830         }
2831
2832         if(self.taunt_soundtime)
2833         if(time > self.taunt_soundtime)
2834         {
2835                 self.taunt_soundtime = 0;
2836                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2837         }
2838
2839         target_voicescript_next(self);
2840 }
2841
2842 float isInvisibleString(string s)
2843 {
2844         float i, n, c;
2845         s = strdecolorize(s);
2846         for((i = 0), (n = strlen(s)); i < n; ++i)
2847         {
2848                 c = str2chr(s, i);
2849                 switch(c)
2850                 {
2851                         case 0:
2852                         case 32:
2853                         case 160:
2854                                 break;
2855                         default:
2856                                 return FALSE;
2857                 }
2858         }
2859         return TRUE;
2860 }
2861
2862 /*
2863 =============
2864 PlayerPostThink
2865
2866 Called every frame for each client after the physics are run
2867 =============
2868 */
2869 .float idlekick_lasttimeleft;
2870 .entity showheadshotbbox;
2871 void showheadshotbbox_think()
2872 {
2873         if(self.owner.showheadshotbbox != self)
2874         {
2875                 remove(self);
2876                 return;
2877         }
2878         self.nextthink = time;
2879         setorigin(self, self.owner.origin);
2880         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2881 }
2882 void PlayerPostThink (void)
2883 {
2884         // Savage: Check for nameless players
2885         if (isInvisibleString(self.netname)) {
2886                 self.netname = "Player";
2887                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2888         }
2889
2890         // send the clients accuracy stats to the client
2891         if(self.stat_count > 0)
2892         if(frametime)
2893         {
2894                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2895                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2896                 self.stat_count -= 1;
2897         }
2898
2899 #ifdef UID
2900         if(self.uid_kicktime)
2901         if(time > self.uid_kicktime)
2902         {
2903                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2904                 dropclient(self);
2905                 return;
2906         }
2907 #endif
2908
2909         if(sv_maxidle && frametime)
2910         {
2911                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2912                 float timeleft;
2913                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2914                 if(timeleft <= 0)
2915                 {
2916                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2917                         AnnounceTo(self, "terminated");
2918                         dropclient(self);
2919                         return;
2920                 }
2921                 else if(timeleft <= 10)
2922                 {
2923                         if(timeleft != self.idlekick_lasttimeleft)
2924                         {
2925                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2926                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2927                         }
2928                 }
2929                 else
2930                 {
2931                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2932                 }
2933                 self.idlekick_lasttimeleft = timeleft;
2934         }
2935
2936 #ifdef TETRIS
2937         if(self.impulse == 100)
2938                 ImpulseCommands();
2939         if (TetrisPostFrame())
2940                 return;
2941 #endif
2942
2943         CheatFrame();
2944
2945         if(self.classname == "player") {
2946                 CheckRules_Player();
2947                 UpdateChatBubble();
2948                 UpdateTeamBubble();
2949                 if (self.impulse)
2950                         ImpulseCommands();
2951                 if (intermission_running)
2952                         return;         // intermission or finale
2953                 GetPressedKeys();
2954         } else if (self.classname == "observer") {
2955                 //do nothing
2956         } else if (self.classname == "spectator") {
2957                 //do nothing
2958         }
2959
2960         /*
2961         float i;
2962         for(i = 0; i < 1000; ++i)
2963         {
2964                 vector end;
2965                 end = self.origin + '0 0 1024' + 512 * randomvec();
2966                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2967                 if(trace_fraction < 1)
2968                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2969                 {
2970                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2971                         break;
2972                 }
2973         }
2974         */
2975
2976         Arena_Warmup();
2977
2978         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2979
2980         if(self.waypointsprite_attachedforcarrier)
2981                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2982
2983         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2984         {
2985                 if(!self.showheadshotbbox)
2986                 {
2987                         self.showheadshotbbox = spawn();
2988                         self.showheadshotbbox.classname = "headshotbbox";
2989                         self.showheadshotbbox.owner = self;
2990                         self.showheadshotbbox.think = showheadshotbbox_think;
2991                         self.showheadshotbbox.nextthink = time;
2992                         self = self.showheadshotbbox;
2993                         self.think();
2994                         self = self.owner;
2995                 }
2996         }
2997         else
2998         {
2999                 if(self.showheadshotbbox)
3000                         remove(self.showheadshotbbox);
3001         }
3002
3003         playerdemo_write();
3004
3005         /*
3006         if(g_race)
3007                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3008         */
3009 }