qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(IS_REAL_CLIENT(self))
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (g_arena && arena_roundbased)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(IS_REAL_CLIENT(self))
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         if((g_race && g_race_qualifying) || g_cts)
 389         {
 390                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 391                         self.frags = FRAGS_LMS_LOSER;
 392                 else
 393                         self.frags = FRAGS_SPECTATOR;
 394         }
 395         else
 396                 self.frags = FRAGS_SPECTATOR;
 397
 398         MUTATOR_CALLHOOK(MakePlayerObserver);
 399
 400         Portal_ClearAll(self);
 401
 402         Unfreeze(self);
 403
 404         if(self.alivetime)
 405         {
 406                 if(!inWarmupStage)
 407                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 408                 self.alivetime = 0;
 409         }
 410
 411         if(self.vehicle)
 412                 vehicles_exit(VHEF_RELESE);
 413
 414         WaypointSprite_PlayerDead();
 415
 416         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 417                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 418
 419         if(self.killcount != -666)
 420         {
 421                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 422
 423                 if(self.just_joined == FALSE) {
 424                         LogTeamchange(self.playerid, -1, 4);
 425                 } else
 426                         self.just_joined = FALSE;
 427         }
 428
 429         PlayerScore_Clear(self); // clear scores when needed
 430
 431         accuracy_resend(self);
 432
 433         self.spectatortime = time;
 434
 435         self.classname = "observer";
 436         self.iscreature = FALSE;
 437         self.teleportable = TELEPORT_SIMPLE;
 438         self.damagedbycontents = FALSE;
 439         self.health = -666;
 440         self.takedamage = DAMAGE_NO;
 441         self.solid = SOLID_NOT;
 442         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 443         self.flags = FL_CLIENT | FL_NOTARGET;
 444         self.armorvalue = 666;
 445         self.effects = 0;
 446         self.armorvalue = autocvar_g_balance_armor_start;
 447         self.pauserotarmor_finished = 0;
 448         self.pauserothealth_finished = 0;
 449         self.pauseregen_finished = 0;
 450         self.damageforcescale = 0;
 451         self.death_time = 0;
 452         self.respawn_flags = 0;
 453         self.respawn_time = 0;
 454         self.stat_respawn_time = 0;
 455         self.alpha = 0;
 456         self.scale = 0;
 457         self.fade_time = 0;
 458         self.pain_frame = 0;
 459         self.pain_finished = 0;
 460         self.strength_finished = 0;
 461         self.invincible_finished = 0;
 462         self.superweapons_finished = 0;
 463         self.pushltime = 0;
 464         self.istypefrag = 0;
 465         self.think = func_null;
 466         self.nextthink = 0;
 467         self.hook_time = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 475         self.prevorigin = self.origin;
 476         self.items = 0;
 477         WEPSET_CLEAR_E(self);
 478         self.model = "";
 479         FixPlayermodel();
 480         setmodel(self, "null");
 481         self.drawonlytoclient = self;
 482
 483         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 484         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 485
 486         self.weapon = 0;
 487         self.weaponname = "";
 488         self.switchingweapon = 0;
 489         self.weaponmodel = "";
 490         self.weaponentity = world;
 491         self.exteriorweaponentity = world;
 492         self.killcount = -666;
 493         self.velocity = '0 0 0';
 494         self.avelocity = '0 0 0';
 495         self.punchangle = '0 0 0';
 496         self.punchvector = '0 0 0';
 497         self.oldvelocity = self.velocity;
 498         self.fire_endtime = -1;
 499 }
 500
 501 .float model_randomizer;
 502 void FixPlayermodel()
 503 {
 504         string defaultmodel;
 505         float defaultskin, chmdl, oldskin, n, i;
 506         vector m1, m2;
 507
 508         defaultmodel = "";
 509         defaultskin = 0;
 510         chmdl = FALSE;
 511
 512         if(autocvar_sv_defaultcharacter == 1)
 513         {
 514                 if(teamplay)
 515                 {
 516                         string s;
 517                         s = Team_ColorName_Lower(self.team);
 518                         if(s != "neutral")
 519                         {
 520                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 521                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 522                         }
 523                 }
 524
 525                 if(defaultmodel == "")
 526                 {
 527                         defaultmodel = autocvar_sv_defaultplayermodel;
 528                         defaultskin = autocvar_sv_defaultplayerskin;
 529                 }
 530
 531                 n = tokenize_console(defaultmodel);
 532                 if(n > 0)
 533                         defaultmodel = argv(floor(n * self.model_randomizer));
 534
 535                 i = strstrofs(defaultmodel, ":", 0);
 536                 if(i >= 0)
 537                 {
 538                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 539                         defaultmodel = substring(defaultmodel, 0, i);
 540                 }
 541         }
 542
 543         if(defaultmodel != "")
 544         {
 545                 if (defaultmodel != self.model)
 546                 {
 547                         m1 = self.mins;
 548                         m2 = self.maxs;
 549                         setplayermodel (self, defaultmodel);
 550                         setsize (self, m1, m2);
 551                         chmdl = TRUE;
 552                 }
 553
 554                 oldskin = self.skin;
 555                 self.skin = defaultskin;
 556         } else {
 557                 if (self.playermodel != self.model || self.playermodel == "")
 558                 {
 559                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 560                         m1 = self.mins;
 561                         m2 = self.maxs;
 562                         setplayermodel (self, self.playermodel);
 563                         setsize (self, m1, m2);
 564                         chmdl = TRUE;
 565                 }
 566
 567                 oldskin = self.skin;
 568                 self.skin = stof(self.playerskin);
 569         }
 570
 571         if(chmdl || oldskin != self.skin) // model or skin has changed
 572         {
 573                 self.species = player_getspecies(); // update species
 574                 UpdatePlayerSounds(); // update skin sounds
 575         }
 576
 577         if(!teamplay)
 578                 if(strlen(autocvar_sv_defaultplayercolors))
 579                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 580                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 581 }
 582
 583 /*
 584 =============
 585 PutClientInServer
 586
 587 Called when a client spawns in the server
 588 =============
 589 */
 590
 591 void PutClientInServer (void)
 592 {
 593         if(IS_BOT_CLIENT(self))
 594                 self.classname = "player";
 595         else if(IS_REAL_CLIENT(self))
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         // reset player keys
 603         self.itemkeys = 0;
 604
 605         MUTATOR_CALLHOOK(PutClientInServer);
 606
 607         if(gameover)
 608                 self.classname = "observer";
 609
 610         if(IS_PLAYER(self))
 611         {
 612                 entity spot, oldself;
 613                 float j;
 614
 615                 accuracy_resend(self);
 616
 617                 if(self.team < 0)
 618                         JoinBestTeam(self, FALSE, TRUE);
 619
 620                 race_PreSpawn();
 621
 622                 spot = SelectSpawnPoint (FALSE);
 623                 if(!spot)
 624                 {
 625                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 626                         return; // spawn failed
 627                 }
 628
 629                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 630
 631                 self.classname = "player";
 632                 self.wasplayer = TRUE;
 633                 self.iscreature = TRUE;
 634                 self.teleportable = TELEPORT_NORMAL;
 635                 self.damagedbycontents = TRUE;
 636                 self.movetype = MOVETYPE_WALK;
 637                 self.solid = SOLID_SLIDEBOX;
 638                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 639                 if(autocvar_g_playerclip_collisions)
 640                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 641                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 642                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 643                 self.frags = FRAGS_PLAYER;
 644                 if(INDEPENDENT_PLAYERS)
 645                         MAKE_INDEPENDENT_PLAYER(self);
 646                 self.flags = FL_CLIENT;
 647                 if(autocvar__notarget)
 648                         self.flags |= FL_NOTARGET;
 649                 self.takedamage = DAMAGE_AIM;
 650                 self.effects = 0;
 651                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 652                 self.air_finished = time + 12;
 653                 self.dmg = 2;
 654                 if(autocvar_g_balance_nex_charge)
 655                 {
 656                         if(autocvar_g_balance_nex_secondary_chargepool)
 657                                 self.nex_chargepool_ammo = 1;
 658                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 659                 }
 660
 661                 if(inWarmupStage)
 662                 {
 663                         self.ammo_shells = warmup_start_ammo_shells;
 664                         self.ammo_nails = warmup_start_ammo_nails;
 665                         self.ammo_rockets = warmup_start_ammo_rockets;
 666                         self.ammo_cells = warmup_start_ammo_cells;
 667                         self.ammo_fuel = warmup_start_ammo_fuel;
 668                         self.health = warmup_start_health;
 669                         self.armorvalue = warmup_start_armorvalue;
 670                         WEPSET_COPY_EA(self, warmup_start_weapons);
 671                 }
 672                 else
 673                 {
 674                         self.ammo_shells = start_ammo_shells;
 675                         self.ammo_nails = start_ammo_nails;
 676                         self.ammo_rockets = start_ammo_rockets;
 677                         self.ammo_cells = start_ammo_cells;
 678                         self.ammo_fuel = start_ammo_fuel;
 679                         self.health = start_health;
 680                         self.armorvalue = start_armorvalue;
 681                         WEPSET_COPY_EA(self, start_weapons);
 682                 }
 683
 684                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 685                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 686                 else
 687                         self.superweapons_finished = 0;
 688
 689                 if(g_weaponarena_random)
 690                 {
 691                         if(g_weaponarena_random_with_laser)
 692                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 693                         W_RandomWeapons(self, g_weaponarena_random);
 694                         if(g_weaponarena_random_with_laser)
 695                                 WEPSET_OR_EW(self, WEP_LASER);
 696                 }
 697
 698                 self.items = start_items;
 699
 700                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 701                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 702                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 703                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 704                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 705                 //extend the pause of rotting if client was reset at the beginning of the countdown
 706                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 707                         self.spawnshieldtime += game_starttime - time;
 708                         self.pauserotarmor_finished += game_starttime - time;
 709                         self.pauserothealth_finished += game_starttime - time;
 710                         self.pauseregen_finished += game_starttime - time;
 711                 }
 712                 self.damageforcescale = 2;
 713                 self.death_time = 0;
 714                 self.respawn_flags = 0;
 715                 self.respawn_time = 0;
 716                 self.stat_respawn_time = 0;
 717                 self.scale = 0;
 718                 self.fade_time = 0;
 719                 self.pain_frame = 0;
 720                 self.pain_finished = 0;
 721                 self.strength_finished = 0;
 722                 self.invincible_finished = 0;
 723                 self.pushltime = 0;
 724                 // players have no think function
 725                 self.think = func_null;
 726                 self.nextthink = 0;
 727                 self.hook_time = 0;
 728                 self.dmg_team = 0;
 729                 self.ballistics_density = autocvar_g_ballistics_density_player;
 730
 731                 self.metertime = 0;
 732
 733                 self.deadflag = DEAD_NO;
 734
 735                 self.angles = spot.angles;
 736
 737                 self.angles_z = 0; // never spawn tilted even if the spot says to
 738                 self.fixangle = TRUE; // turn this way immediately
 739                 self.velocity = '0 0 0';
 740                 self.avelocity = '0 0 0';
 741                 self.punchangle = '0 0 0';
 742                 self.punchvector = '0 0 0';
 743                 self.oldvelocity = self.velocity;
 744                 self.fire_endtime = -1;
 745
 746                 msg_entity = self;
 747                 WRITESPECTATABLE_MSG_ONE({
 748                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 749                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 750                 });
 751
 752                 self.model = "";
 753                 FixPlayermodel();
 754                 self.drawonlytoclient = world;
 755
 756                 self.crouch = FALSE;
 757                 self.view_ofs = PL_VIEW_OFS;
 758                 setsize (self, PL_MIN, PL_MAX);
 759                 self.spawnorigin = spot.origin;
 760                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 761                 // don't reset back to last position, even if new position is stuck in solid
 762                 self.oldorigin = self.origin;
 763                 self.prevorigin = self.origin;
 764                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 765                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 766         self.hud = HUD_NORMAL;
 767
 768                 self.event_damage = PlayerDamage;
 769
 770                 self.bot_attack = TRUE;
 771                 self.monster_attack = TRUE;
 772
 773                 self.statdraintime = time + 5;
 774                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 775
 776                 if(self.killcount == -666) {
 777                         PlayerScore_Clear(self);
 778                         self.killcount = 0;
 779                 }
 780
 781                 CL_SpawnWeaponentity();
 782                 self.alpha = default_player_alpha;
 783                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 784                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 785
 786                 self.speedrunning = FALSE;
 787
 788                 race_PostSpawn(spot);
 789
 790                 //stuffcmd(self, "chase_active 0");
 791                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 792
 793                 target_voicescript_clear(self);
 794
 795                 // reset fields the weapons may use
 796                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 797                 {
 798                         weapon_action(j, WR_RESETPLAYER);
 799
 800                         // all weapons must be fully loaded when we spawn
 801                         entity e;
 802                         e = get_weaponinfo(j);
 803                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 804                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 805                 }
 806
 807                 oldself = self;
 808                 self = spot;
 809                         activator = oldself;
 810                                 string s;
 811                                 s = self.target;
 812                                 self.target = string_null;
 813                                 SUB_UseTargets();
 814                                 self.target = s;
 815                         activator = world;
 816                 self = oldself;
 817
 818                 Unfreeze(self);
 819
 820                 spawn_spot = spot;
 821                 MUTATOR_CALLHOOK(PlayerSpawn);
 822
 823                 if(autocvar_spawn_debug)
 824                 {
 825                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 826                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 827                 }
 828
 829                 self.switchweapon = w_getbestweapon(self);
 830                 self.cnt = -1; // W_LastWeapon will not complain
 831                 self.weapon = 0;
 832                 self.weaponname = "";
 833                 self.switchingweapon = 0;
 834
 835                 if(!inWarmupStage)
 836                         if(!self.alivetime)
 837                                 self.alivetime = time;
 838
 839                 antilag_clear(self);
 840
 841                 if (autocvar_g_spawnsound)
 842                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 843         } else if(IS_OBSERVER(self)) {
 844                 PutObserverInServer ();
 845         }
 846 }
 847
 848 .float ebouncefactor, ebouncestop; // electro's values
 849 // TODO do we need all these fields, or should we stop autodetecting runtime
 850 // changes and just have a console command to update this?
 851 float ClientInit_SendEntity(entity to, float sf)
 852 {
 853         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 854         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 855         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 856         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 857         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 858         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 859         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 860         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 861         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 862         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 863         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 864         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 865         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 866         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 867         if(sv_foginterval && world.fog != "")
 868                 WriteString(MSG_ENTITY, world.fog);
 869         else
 870                 WriteString(MSG_ENTITY, "");
 871         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 872         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 873         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 874         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 875         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 876         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 877         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 878         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 879         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 880         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 881         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 882         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 883         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 884         return TRUE;
 885 }
 886
 887 void ClientInit_CheckUpdate()
 888 {
 889         self.nextthink = time;
 890         if(self.count != autocvar_g_balance_armor_blockpercent)
 891         {
 892                 self.count = autocvar_g_balance_armor_blockpercent;
 893                 self.SendFlags |= 1;
 894         }
 895         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 896         {
 897                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 898                 self.SendFlags |= 1;
 899         }
 900         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 901         {
 902                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 903                 self.SendFlags |= 1;
 904         }
 905         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 906         {
 907                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 908                 self.SendFlags |= 1;
 909         }
 910         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 911         {
 912                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 913                 self.SendFlags |= 1;
 914         }
 915         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 916         {
 917                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 918                 self.SendFlags |= 1;
 919         }
 920 }
 921
 922 void ClientInit_Spawn()
 923 {
 924         entity o;
 925         entity e;
 926         e = spawn();
 927         e.classname = "clientinit";
 928         e.think = ClientInit_CheckUpdate;
 929         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 930
 931         o = self;
 932         self = e;
 933         ClientInit_CheckUpdate();
 934         self = o;
 935 }
 936
 937 /*
 938 =============
 939 SetNewParms
 940 =============
 941 */
 942 void SetNewParms (void)
 943 {
 944         // initialize parms for a new player
 945         parm1 = -(86400 * 366);
 946 }
 947
 948 /*
 949 =============
 950 SetChangeParms
 951 =============
 952 */
 953 void SetChangeParms (void)
 954 {
 955         // save parms for level change
 956         parm1 = self.parm_idlesince - time;
 957 }
 958
 959 /*
 960 =============
 961 DecodeLevelParms
 962 =============
 963 */
 964 void DecodeLevelParms (void)
 965 {
 966         // load parms
 967         self.parm_idlesince = parm1;
 968         if(self.parm_idlesince == -(86400 * 366))
 969                 self.parm_idlesince = time;
 970
 971         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 972         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 973 }
 974
 975 /*
 976 =============
 977 ClientKill
 978
 979 Called when a client types 'kill' in the console
 980 =============
 981 */
 982
 983 .float clientkill_nexttime;
 984 void ClientKill_Now_TeamChange()
 985 {
 986         if(self.killindicator_teamchange == -1)
 987         {
 988                 JoinBestTeam( self, FALSE, TRUE );
 989         }
 990         else if(self.killindicator_teamchange == -2)
 991         {
 992                 if(blockSpectators)
 993                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 994                 PutObserverInServer();
 995         }
 996         else
 997                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 998         self.killindicator_teamchange = 0;
 999 }
1000
1001 void ClientKill_Now()
1002 {
1003         if(self.vehicle)
1004         {
1005             vehicles_exit(VHEF_RELESE);
1006             if(!self.killindicator_teamchange)
1007             {
1008             self.vehicle_health = -1;
1009             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1010             }
1011         }
1012
1013         if(self.killindicator && !wasfreed(self.killindicator))
1014                 remove(self.killindicator);
1015
1016         self.killindicator = world;
1017
1018         if(self.killindicator_teamchange)
1019                 ClientKill_Now_TeamChange();
1020
1021         // in any case:
1022         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1023
1024         // now I am sure the player IS dead
1025 }
1026 void KillIndicator_Think()
1027 {
1028         if (gameover)
1029         {
1030                 self.owner.killindicator = world;
1031                 remove(self);
1032                 return;
1033         }
1034
1035         if (self.owner.alpha < 0 && !self.owner.vehicle)
1036         {
1037                 self.owner.killindicator = world;
1038                 remove(self);
1039                 return;
1040         }
1041
1042         if(self.cnt <= 0)
1043         {
1044                 self = self.owner;
1045                 ClientKill_Now(); // no oldself needed
1046                 return;
1047         }
1048     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1049     {
1050         self.nextthink = time + 1;
1051         self.cnt -= 1;
1052     }
1053         else
1054         {
1055                 if(self.cnt <= 10)
1056                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1057                 if(IS_REAL_CLIENT(self.owner))
1058                 {
1059                         if(self.cnt <= 10)
1060                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1061                 }
1062                 self.nextthink = time + 1;
1063                 self.cnt -= 1;
1064         }
1065 }
1066
1067 float clientkilltime;
1068 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1069 {
1070         float killtime;
1071         float starttime;
1072         entity e;
1073
1074         if (gameover)
1075                 return;
1076
1077         killtime = autocvar_g_balance_kill_delay;
1078
1079         if(g_race_qualifying || g_cts)
1080                 killtime = 0;
1081
1082     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1083     {
1084                 remove(self.killindicator);
1085                 self.killindicator = world;
1086
1087         ClientKill_Now(); // allow instant kill in this case
1088         return;
1089     }
1090
1091         self.killindicator_teamchange = targetteam;
1092
1093     if(!self.killindicator)
1094         {
1095                 if(self.deadflag == DEAD_NO)
1096                 {
1097                         killtime = max(killtime, self.clientkill_nexttime - time);
1098                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1099                 }
1100
1101                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
1102                 {
1103                         ClientKill_Now();
1104                 }
1105                 else
1106                 {
1107                         starttime = max(time, clientkilltime);
1108
1109                         self.killindicator = spawn();
1110                         self.killindicator.owner = self;
1111                         self.killindicator.scale = 0.5;
1112                         setattachment(self.killindicator, self, "");
1113                         setorigin(self.killindicator, '0 0 52');
1114                         self.killindicator.think = KillIndicator_Think;
1115                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1116                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1117                         self.killindicator.cnt = ceil(killtime);
1118                         self.killindicator.count = bound(0, ceil(killtime), 10);
1119                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1120
1121                         for(e = world; (e = find(e, classname, "body")) != world; )
1122                         {
1123                                 if(e.enemy != self)
1124                                         continue;
1125                                 e.killindicator = spawn();
1126                                 e.killindicator.owner = e;
1127                                 e.killindicator.scale = 0.5;
1128                                 setattachment(e.killindicator, e, "");
1129                                 setorigin(e.killindicator, '0 0 52');
1130                                 e.killindicator.think = KillIndicator_Think;
1131                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1132                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1133                                 e.killindicator.cnt = ceil(killtime);
1134                         }
1135                         self.lip = 0;
1136                 }
1137         }
1138         if(self.killindicator)
1139         {
1140                 if(targetteam == 0) // just die
1141                 {
1142                         self.killindicator.colormod = '0 0 0';
1143                         if(IS_REAL_CLIENT(self))
1144                         if(self.killindicator.cnt > 0)
1145                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1146                 }
1147                 else if(targetteam == -1) // auto
1148                 {
1149                         self.killindicator.colormod = '0 1 0';
1150                         if(IS_REAL_CLIENT(self))
1151                         if(self.killindicator.cnt > 0)
1152                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1153                 }
1154                 else if(targetteam == -2) // spectate
1155                 {
1156                         self.killindicator.colormod = '0.5 0.5 0.5';
1157                         if(IS_REAL_CLIENT(self))
1158                         if(self.killindicator.cnt > 0)
1159                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1160                 }
1161                 else
1162                 {
1163                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1164                         if(IS_REAL_CLIENT(self))
1165                         if(self.killindicator.cnt > 0)
1166                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1167                 }
1168         }
1169
1170 }
1171
1172 void ClientKill (void)
1173 {
1174         if(gameover) return;
1175         if(self.player_blocked) return;
1176         if(self.frozen) return;
1177
1178         ClientKill_TeamChange(0);
1179 }
1180
1181 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1182 {
1183     e.killindicator = spawn();
1184     e.killindicator.owner = e;
1185     e.killindicator.think = KillIndicator_Think;
1186     e.killindicator.nextthink = time + (e.lip) * 0.05;
1187     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1188     e.killindicator.health = 1; // this is used to indicate that it should be silent
1189     e.lip = 0;
1190 }
1191
1192 void FixClientCvars(entity e)
1193 {
1194         // send prediction settings to the client
1195         stuffcmd(e, "\nin_bindmap 0 0\n");
1196         if(g_race || g_cts)
1197                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1198         if(autocvar_g_antilag == 3) // client side hitscan
1199                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1200         if(autocvar_sv_gentle)
1201                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1202         /*
1203          * we no longer need to stuff this. Remove this comment block if you feel
1204          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1205         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1206         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1207         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1208         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1209         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1210         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1211         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1212         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1213         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1214         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1215         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1216         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1217         stuffcmd(e, "cl_movement_edgefriction 1\n");
1218          */
1219 }
1220
1221 float PlayerInIDList(entity p, string idlist)
1222 {
1223         float n, i;
1224         string s;
1225
1226         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1227         if not(p.crypto_idfp)
1228                 return 0;
1229
1230         // this function allows abbreviated player IDs too!
1231         n = tokenize_console(idlist);
1232         for(i = 0; i < n; ++i)
1233         {
1234                 s = argv(i);
1235                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1236                         return 1;
1237         }
1238
1239         return 0;
1240 }
1241
1242 /*
1243 =============
1244 ClientConnect
1245
1246 Called when a client connects to the server
1247 =============
1248 */
1249 void DecodeLevelParms (void);
1250 //void dom_player_join_team(entity pl);
1251 void set_dom_state(entity e);
1252 void ClientConnect (void)
1253 {
1254         float t;
1255
1256         if(IS_CLIENT(self))
1257         {
1258                 print("Warning: ClientConnect, but already connected!\n");
1259                 return;
1260         }
1261
1262         if(Ban_MaybeEnforceBanOnce(self))
1263                 return;
1264
1265         DecodeLevelParms();
1266
1267 #ifdef WATERMARK
1268         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1269 #endif
1270
1271         self.classname = "player_joining";
1272
1273         self.flags = FL_CLIENT;
1274         self.version_nagtime = time + 10 + random() * 10;
1275
1276         if(player_count<0)
1277         {
1278                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1279                 player_count = 0;
1280         }
1281
1282         PlayerScore_Attach(self);
1283         ClientData_Attach();
1284         accuracy_init(self);
1285
1286         bot_clientconnect();
1287
1288         playerdemo_init();
1289
1290         anticheat_init();
1291
1292         race_PreSpawnObserver();
1293
1294         // identify the right forced team
1295         if(autocvar_g_campaign)
1296         {
1297                 if(IS_REAL_CLIENT(self)) // only players, not bots
1298                 {
1299                         switch(autocvar_g_campaign_forceteam)
1300                         {
1301                                 case 1: self.team_forced = NUM_TEAM_1; break;
1302                                 case 2: self.team_forced = NUM_TEAM_2; break;
1303                                 case 3: self.team_forced = NUM_TEAM_3; break;
1304                                 case 4: self.team_forced = NUM_TEAM_4; break;
1305                                 default: self.team_forced = 0;
1306                         }
1307                 }
1308         }
1309         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1310                 self.team_forced = NUM_TEAM_1;
1311         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1312                 self.team_forced = NUM_TEAM_2;
1313         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1314                 self.team_forced = NUM_TEAM_3;
1315         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1316                 self.team_forced = NUM_TEAM_4;
1317         else if(autocvar_g_forced_team_otherwise == "red")
1318                 self.team_forced = NUM_TEAM_1;
1319         else if(autocvar_g_forced_team_otherwise == "blue")
1320                 self.team_forced = NUM_TEAM_2;
1321         else if(autocvar_g_forced_team_otherwise == "yellow")
1322                 self.team_forced = NUM_TEAM_3;
1323         else if(autocvar_g_forced_team_otherwise == "pink")
1324                 self.team_forced = NUM_TEAM_4;
1325         else if(autocvar_g_forced_team_otherwise == "spectate")
1326                 self.team_forced = -1;
1327         else if(autocvar_g_forced_team_otherwise == "spectator")
1328                 self.team_forced = -1;
1329         else
1330                 self.team_forced = 0;
1331
1332         if(!teamplay)
1333                 if(self.team_forced > 0)
1334                         self.team_forced = 0;
1335
1336         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1337
1338         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1339                 self.classname = "observer";
1340         } else {
1341                 if(teamplay)
1342                 {
1343                         if(autocvar_g_balance_teams)
1344                         {
1345                                 self.classname = "player";
1346                                 campaign_bots_may_start = 1;
1347                         }
1348                         else
1349                         {
1350                                 self.classname = "observer"; // do it anyway
1351                         }
1352                 }
1353                 else
1354                 {
1355                         self.classname = "player";
1356                         campaign_bots_may_start = 1;
1357                 }
1358         }
1359
1360         self.playerid = (playerid_last = playerid_last + 1);
1361
1362         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1363
1364     if(IS_BOT_CLIENT(self))
1365         PlayerStats_AddPlayer(self);
1366
1367         if(autocvar_sv_eventlog)
1368                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1369
1370         LogTeamchange(self.playerid, self.team, 1);
1371
1372         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1373
1374         self.netname_previous = strzone(self.netname);
1375
1376         if(IS_PLAYER(self) && teamplay)
1377                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1378         else
1379                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1380
1381         stuffcmd(self, strcat(clientstuff, "\n"));
1382         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1383
1384         FixClientCvars(self);
1385
1386         // spawnfunc_waypoint sprites
1387         WaypointSprite_InitClient(self);
1388
1389         // Wazat's grappling hook
1390         SetGrappleHookBindings();
1391
1392         // get version info from player
1393         stuffcmd(self, "cmd clientversion $gameversion\n");
1394
1395         // get other cvars from player
1396         GetCvars(0);
1397
1398         // notify about available teams
1399         if(teamplay)
1400         {
1401                 CheckAllowedTeams(self);
1402                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1403                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1404         }
1405         else
1406                 stuffcmd(self, "set _teams_available 0\n");
1407
1408         attach_entcs();
1409
1410         bot_relinkplayerlist();
1411
1412         self.spectatortime = time;
1413         if(blockSpectators)
1414         {
1415                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1416         }
1417
1418         self.jointime = time;
1419         self.allowed_timeouts = autocvar_sv_timeout_number;
1420
1421         if(IS_REAL_CLIENT(self))
1422         {
1423                 if(!autocvar_g_campaign)
1424                 {
1425                         self.motd_actived_time = -1;
1426                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1427                 }
1428
1429                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1430                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1431         }
1432
1433         if(!sv_foginterval && world.fog != "")
1434                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1435
1436         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1437         {
1438                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1439                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1440         }
1441         else
1442                 self.hitplotfh = -1;
1443
1444         if(g_race || g_cts) {
1445                 string rr;
1446                 if(g_cts)
1447                         rr = CTS_RECORD;
1448                 else
1449                         rr = RACE_RECORD;
1450
1451                 msg_entity = self;
1452                 race_send_recordtime(MSG_ONE);
1453                 race_send_speedaward(MSG_ONE);
1454
1455                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1456                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1457                 race_send_speedaward_alltimebest(MSG_ONE);
1458
1459                 float i;
1460                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1461                         race_SendRankings(i, 0, 0, MSG_ONE);
1462                 }
1463         }
1464         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1465                 send_CSQC_teamnagger();
1466
1467         CheatInitClient();
1468
1469         CSQCMODEL_AUTOINIT();
1470
1471         self.model_randomizer = random();
1472
1473         if(IS_REAL_CLIENT(self))
1474                 sv_notice_join();
1475
1476         MUTATOR_CALLHOOK(ClientConnect);
1477 }
1478 /*
1479 =============
1480 ClientDisconnect
1481
1482 Called when a client disconnects from the server
1483 =============
1484 */
1485 .entity chatbubbleentity;
1486 void ReadyCount();
1487 void ClientDisconnect (void)
1488 {
1489         if(self.vehicle)
1490             vehicles_exit(VHEF_RELESE);
1491
1492         if not(IS_CLIENT(self))
1493         {
1494                 print("Warning: ClientDisconnect without ClientConnect\n");
1495                 return;
1496         }
1497
1498         PlayerStats_AddGlobalInfo(self);
1499
1500         CheatShutdownClient();
1501
1502         if(self.hitplotfh >= 0)
1503         {
1504                 fclose(self.hitplotfh);
1505                 self.hitplotfh = -1;
1506         }
1507
1508         anticheat_report();
1509         anticheat_shutdown();
1510
1511         playerdemo_shutdown();
1512
1513         bot_clientdisconnect();
1514
1515         if(self.entcs)
1516                 detach_entcs();
1517
1518         if(autocvar_sv_eventlog)
1519                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1520
1521         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1522
1523         MUTATOR_CALLHOOK(ClientDisconnect);
1524
1525         Portal_ClearAll(self);
1526
1527         Unfreeze(self);
1528
1529         RemoveGrapplingHook(self);
1530
1531         // Here, everything has been done that requires this player to be a client.
1532
1533         self.flags &~= FL_CLIENT;
1534
1535         if (self.chatbubbleentity)
1536                 remove (self.chatbubbleentity);
1537
1538         if (self.killindicator)
1539                 remove (self.killindicator);
1540
1541         WaypointSprite_PlayerGone();
1542
1543         bot_relinkplayerlist();
1544
1545         accuracy_free(self);
1546         ClientData_Detach();
1547         PlayerScore_Detach(self);
1548
1549         if(self.netname_previous)
1550                 strunzone(self.netname_previous);
1551         if(self.clientstatus)
1552                 strunzone(self.clientstatus);
1553         if(self.weaponorder_byimpulse)
1554                 strunzone(self.weaponorder_byimpulse);
1555
1556         ClearPlayerSounds();
1557
1558         if(self.personal)
1559                 remove(self.personal);
1560
1561         self.playerid = 0;
1562         ReadyCount();
1563
1564         // free cvars
1565         GetCvars(-1);
1566 }
1567
1568 .float BUTTON_CHAT;
1569 void ChatBubbleThink()
1570 {
1571         self.nextthink = time;
1572         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1573         {
1574                 if(self.owner) // but why can that ever be world?
1575                         self.owner.chatbubbleentity = world;
1576                 remove(self);
1577                 return;
1578         }
1579         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1580 #ifdef TETRIS
1581                 || self.owner.tetris_on
1582 #endif
1583         )
1584                 self.model = self.mdl;
1585         else
1586                 self.model = "";
1587 }
1588
1589 void UpdateChatBubble()
1590 {
1591         if (self.alpha < 0)
1592                 return;
1593         // spawn a chatbubble entity if needed
1594         if (!self.chatbubbleentity)
1595         {
1596                 self.chatbubbleentity = spawn();
1597                 self.chatbubbleentity.owner = self;
1598                 self.chatbubbleentity.exteriormodeltoclient = self;
1599                 self.chatbubbleentity.think = ChatBubbleThink;
1600                 self.chatbubbleentity.nextthink = time;
1601                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1602                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1603                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1604                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1605                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1606                 self.chatbubbleentity.model = "";
1607                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1608         }
1609 }
1610
1611
1612 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1613 // added to the model skins
1614 /*void UpdateColorModHack()
1615 {
1616         float c;
1617         c = self.clientcolors & 15;
1618         // LordHavoc: only bothering to support white, green, red, yellow, blue
1619              if (!teamplay) self.colormod = '0 0 0';
1620         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1621         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1622         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1623         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1624         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1625         else self.colormod = '1 1 1';
1626 }*/
1627
1628 void respawn(void)
1629 {
1630         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1631         {
1632                 self.solid = SOLID_NOT;
1633                 self.takedamage = DAMAGE_NO;
1634                 self.movetype = MOVETYPE_FLY;
1635                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1636                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1637                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1638                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1639                 if(autocvar_g_respawn_ghosts_maxtime)
1640                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1641         }
1642
1643         CopyBody(1);
1644
1645         self.effects |= EF_NODRAW; // prevent another CopyBody
1646         PutClientInServer();
1647 }
1648
1649 void play_countdown(float finished, string samp)
1650 {
1651         if(IS_REAL_CLIENT(self))
1652                 if(floor(finished - time - frametime) != floor(finished - time))
1653                         if(finished - time < 6)
1654                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1655 }
1656
1657 void player_powerups (void)
1658 {
1659         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1660         olditems = self.items;
1661
1662         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1663                 self.modelflags |= MF_ROCKET;
1664         else
1665                 self.modelflags &~= MF_ROCKET;
1666
1667         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1668
1669         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1670                 return;
1671
1672         Fire_ApplyDamage(self);
1673         Fire_ApplyEffect(self);
1674
1675         if not(g_minstagib)
1676         {
1677                 if (self.items & IT_STRENGTH)
1678                 {
1679                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1680                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1681                         if (time > self.strength_finished)
1682                         {
1683                                 self.items = self.items - (self.items & IT_STRENGTH);
1684                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1685                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1686                         }
1687                 }
1688                 else
1689                 {
1690                         if (time < self.strength_finished)
1691                         {
1692                                 self.items = self.items | IT_STRENGTH;
1693                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1694                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1695                         }
1696                 }
1697                 if (self.items & IT_INVINCIBLE)
1698                 {
1699                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1700                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1701                         if (time > self.invincible_finished)
1702                         {
1703                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1704                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1705                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1706                         }
1707                 }
1708                 else
1709                 {
1710                         if (time < self.invincible_finished)
1711                         {
1712                                 self.items = self.items | IT_INVINCIBLE;
1713                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1714                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1715                         }
1716                 }
1717                 if (self.items & IT_SUPERWEAPON)
1718                 {
1719                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1720                         {
1721                                 self.superweapons_finished = 0;
1722                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1723                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1724                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1725                         }
1726                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1727                         {
1728                                 // don't let them run out
1729                         }
1730                         else
1731                         {
1732                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1733                                 if (time > self.superweapons_finished)
1734                                 {
1735                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1736                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1737                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1738                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1739                                 }
1740                         }
1741                 }
1742                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1743                 {
1744                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1745                         {
1746                                 self.items = self.items | IT_SUPERWEAPON;
1747                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1748                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1749                         }
1750                         else
1751                         {
1752                                 self.superweapons_finished = 0;
1753                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1754                         }
1755                 }
1756                 else
1757                 {
1758                         self.superweapons_finished = 0;
1759                 }
1760         }
1761
1762         if(autocvar_g_nodepthtestplayers)
1763                 self.effects = self.effects | EF_NODEPTHTEST;
1764
1765         if(autocvar_g_fullbrightplayers)
1766                 self.effects = self.effects | EF_FULLBRIGHT;
1767
1768         // midair gamemode: damage only while in the air
1769         // if in midair mode, being on ground grants temporary invulnerability
1770         // (this is so that multishot weapon don't clear the ground flag on the
1771         // first damage in the frame, leaving the player vulnerable to the
1772         // remaining hits in the same frame)
1773         if (self.flags & FL_ONGROUND)
1774         if (g_midair)
1775                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1776
1777         if (time >= game_starttime)
1778         if (time < self.spawnshieldtime)
1779                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1780
1781         MUTATOR_CALLHOOK(PlayerPowerups);
1782 }
1783
1784 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1785 {
1786         if(current > stable)
1787                 return current;
1788         else if(current > stable - 0.25) // when close enough, "snap"
1789                 return stable;
1790         else
1791                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1792 }
1793
1794 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1795 {
1796         if(current < stable)
1797                 return current;
1798         else if(current < stable + 0.25) // when close enough, "snap"
1799                 return stable;
1800         else
1801                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1802 }
1803
1804 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1805 {
1806         if(current > rotstable)
1807         {
1808                 if(rotframetime > 0)
1809                 {
1810                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1811                         current = max(rotstable, current - rotlinear * rotframetime);
1812                 }
1813         }
1814         else if(current < regenstable)
1815         {
1816                 if(regenframetime > 0)
1817                 {
1818                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1819                         current = min(regenstable, current + regenlinear * regenframetime);
1820                 }
1821         }
1822
1823         if(current > limit)
1824                 current = limit;
1825
1826         return current;
1827 }
1828
1829 void player_regen (void)
1830 {
1831         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1832         maxh = autocvar_g_balance_health_rotstable;
1833         maxa = autocvar_g_balance_armor_rotstable;
1834         maxf = autocvar_g_balance_fuel_rotstable;
1835         minh = autocvar_g_balance_health_regenstable;
1836         mina = autocvar_g_balance_armor_regenstable;
1837         minf = autocvar_g_balance_fuel_regenstable;
1838         limith = autocvar_g_balance_health_limit;
1839         limita = autocvar_g_balance_armor_limit;
1840         limitf = autocvar_g_balance_fuel_limit;
1841
1842         max_mod = regen_mod = rot_mod = limit_mod = 1;
1843
1844         maxh = maxh * max_mod;
1845         //maxa = maxa * max_mod;
1846         //maxf = maxf * max_mod;
1847         minh = minh * max_mod;
1848         //mina = mina * max_mod;
1849         //minf = minf * max_mod;
1850         limith = limith * limit_mod;
1851         limita = limita * limit_mod;
1852         //limitf = limitf * limit_mod;
1853
1854         if(g_ca)
1855                 rot_mod = 0;
1856
1857         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1858         {
1859                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1860                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1861
1862                 // if player rotted to death...  die!
1863                 if(self.health < 1)
1864                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1865         }
1866
1867         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1868                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1869 }
1870
1871 float zoomstate_set;
1872 void SetZoomState(float z)
1873 {
1874         if(z != self.zoomstate)
1875         {
1876                 self.zoomstate = z;
1877                 ClientData_Touch(self);
1878         }
1879         zoomstate_set = 1;
1880 }
1881
1882 void GetPressedKeys(void) {
1883         MUTATOR_CALLHOOK(GetPressedKeys);
1884         if (self.movement_x > 0) // get if movement keys are pressed
1885         {       // forward key pressed
1886                 self.pressedkeys |= KEY_FORWARD;
1887                 self.pressedkeys &~= KEY_BACKWARD;
1888         }
1889         else if (self.movement_x < 0)
1890         {       // backward key pressed
1891                 self.pressedkeys |= KEY_BACKWARD;
1892                 self.pressedkeys &~= KEY_FORWARD;
1893         }
1894         else
1895         {       // no x input
1896                 self.pressedkeys &~= KEY_FORWARD;
1897                 self.pressedkeys &~= KEY_BACKWARD;
1898         }
1899
1900         if (self.movement_y > 0)
1901         {       // right key pressed
1902                 self.pressedkeys |= KEY_RIGHT;
1903                 self.pressedkeys &~= KEY_LEFT;
1904         }
1905         else if (self.movement_y < 0)
1906         {       // left key pressed
1907                 self.pressedkeys |= KEY_LEFT;
1908                 self.pressedkeys &~= KEY_RIGHT;
1909         }
1910         else
1911         {       // no y input
1912                 self.pressedkeys &~= KEY_RIGHT;
1913                 self.pressedkeys &~= KEY_LEFT;
1914         }
1915
1916         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1917                 self.pressedkeys |= KEY_JUMP;
1918         else
1919                 self.pressedkeys &~= KEY_JUMP;
1920         if (self.BUTTON_CROUCH)
1921                 self.pressedkeys |= KEY_CROUCH;
1922         else
1923                 self.pressedkeys &~= KEY_CROUCH;
1924
1925         if (self.BUTTON_ATCK)
1926                 self.pressedkeys |= KEY_ATCK;
1927         else
1928                 self.pressedkeys &~= KEY_ATCK;
1929         if (self.BUTTON_ATCK2)
1930                 self.pressedkeys |= KEY_ATCK2;
1931         else
1932                 self.pressedkeys &~= KEY_ATCK2;
1933 }
1934
1935 /*
1936 ======================
1937 spectate mode routines
1938 ======================
1939 */
1940
1941 void SpectateCopy(entity spectatee) {
1942         other = spectatee;
1943         MUTATOR_CALLHOOK(SpectateCopy);
1944         self.armortype = spectatee.armortype;
1945         self.armorvalue = spectatee.armorvalue;
1946         self.ammo_cells = spectatee.ammo_cells;
1947         self.ammo_shells = spectatee.ammo_shells;
1948         self.ammo_nails = spectatee.ammo_nails;
1949         self.ammo_rockets = spectatee.ammo_rockets;
1950         self.ammo_fuel = spectatee.ammo_fuel;
1951         self.clip_load = spectatee.clip_load;
1952         self.clip_size = spectatee.clip_size;
1953         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1954         self.health = spectatee.health;
1955         self.impulse = 0;
1956         self.items = spectatee.items;
1957         self.last_pickup = spectatee.last_pickup;
1958         self.hit_time = spectatee.hit_time;
1959         self.metertime = spectatee.metertime;
1960         self.strength_finished = spectatee.strength_finished;
1961         self.invincible_finished = spectatee.invincible_finished;
1962         self.pressedkeys = spectatee.pressedkeys;
1963         WEPSET_COPY_EE(self, spectatee);
1964         self.switchweapon = spectatee.switchweapon;
1965         self.switchingweapon = spectatee.switchingweapon;
1966         self.weapon = spectatee.weapon;
1967         self.nex_charge = spectatee.nex_charge;
1968         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1969         self.hagar_load = spectatee.hagar_load;
1970         self.minelayer_mines = spectatee.minelayer_mines;
1971         self.punchangle = spectatee.punchangle;
1972         self.view_ofs = spectatee.view_ofs;
1973         self.velocity = spectatee.velocity;
1974         self.dmg_take = spectatee.dmg_take;
1975         self.dmg_save = spectatee.dmg_save;
1976         self.dmg_inflictor = spectatee.dmg_inflictor;
1977         self.v_angle = spectatee.v_angle;
1978         self.angles = spectatee.v_angle;
1979         if(!self.BUTTON_USE)
1980                 self.fixangle = TRUE;
1981         setorigin(self, spectatee.origin);
1982         setsize(self, spectatee.mins, spectatee.maxs);
1983         SetZoomState(spectatee.zoomstate);
1984
1985     anticheat_spectatecopy(spectatee);
1986         self.hud = spectatee.hud;
1987         if(spectatee.vehicle)
1988     {
1989         self.fixangle = FALSE;
1990         //self.velocity = spectatee.vehicle.velocity;
1991         self.vehicle_health = spectatee.vehicle_health;
1992         self.vehicle_shield = spectatee.vehicle_shield;
1993         self.vehicle_energy = spectatee.vehicle_energy;
1994         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1995         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1996         self.vehicle_reload1 = spectatee.vehicle_reload1;
1997         self.vehicle_reload2 = spectatee.vehicle_reload2;
1998
1999         msg_entity = self;
2000
2001         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2002             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2003             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2004             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2005
2006         //WriteByte (MSG_ONE, SVC_SETVIEW);
2007         //    WriteEntity(MSG_ONE, self);
2008         //makevectors(spectatee.v_angle);
2009         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2010     }
2011 }
2012
2013 float SpectateUpdate() {
2014         if(!self.enemy)
2015             return 0;
2016
2017         if (self == self.enemy)
2018                 return 0;
2019
2020         if not(IS_PLAYER(self.enemy))
2021                 return 0;
2022
2023         SpectateCopy(self.enemy);
2024
2025         return 1;
2026 }
2027
2028
2029 float SpectateSet()
2030 {
2031         if(self.enemy.classname != "player")
2032                 return FALSE;
2033         /*if(self.enemy.vehicle)
2034         {
2035
2036                 msg_entity = self;
2037                 WriteByte(MSG_ONE, SVC_SETVIEW);
2038                 WriteEntity(MSG_ONE, self.enemy);
2039                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2040
2041                 self.movetype = MOVETYPE_NONE;
2042                 accuracy_resend(self);
2043         }
2044         else
2045         {*/
2046                 msg_entity = self;
2047                 WriteByte(MSG_ONE, SVC_SETVIEW);
2048                 WriteEntity(MSG_ONE, self.enemy);
2049                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2050                 self.movetype = MOVETYPE_NONE;
2051                 accuracy_resend(self);
2052
2053                 if(!SpectateUpdate())
2054                         PutObserverInServer();
2055         //}
2056         return TRUE;
2057 }
2058
2059 float Spectate(entity pl)
2060 {
2061         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2062         if(pl.team != self.team)
2063                 return 0;
2064
2065         self.enemy = pl;
2066         return SpectateSet();
2067 }
2068
2069 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2070 entity CA_SpectateNext(entity start) {
2071         if (start.team == self.team) {
2072                 return start;
2073         }
2074
2075         other = start;
2076         // continue from current player
2077         while(other && other.team != self.team) {
2078                 other = find(other, classname, "player");
2079         }
2080
2081         if (!other) {
2082                 // restart from begining
2083                 other = find(other, classname, "player");
2084                 while(other && other.team != self.team) {
2085                         other = find(other, classname, "player");
2086                 }
2087         }
2088
2089         return other;
2090 }
2091
2092 float SpectateNext()
2093 {
2094         other = find(self.enemy, classname, "player");
2095
2096         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2097                 // CA and ca players when spectating enemies is forbidden
2098                 other = CA_SpectateNext(other);
2099         } else {
2100                 // other modes and ca spectators or spectating enemies is allowed
2101                 if (!other)
2102                         other = find(other, classname, "player");
2103         }
2104
2105         if (other)
2106                 self.enemy = other;
2107
2108         return SpectateSet();
2109 }
2110
2111 float SpectatePrev()
2112 {
2113         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2114         other = findchain(classname, "player");
2115         if not(other) // no player
2116                 return FALSE;
2117
2118         entity first = other;
2119         // skip players until current spectated player
2120         if(self.enemy)
2121         while(other && other != self.enemy)
2122                 other = other.chain;
2123
2124         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2125         {
2126                 do { other = other.chain; }
2127                 while(other && other.team != self.team);
2128
2129                 if not(other)
2130                 {
2131                         other = first;
2132                         while(other.team != self.team)
2133                                 other = other.chain;
2134                         if(other == self.enemy)
2135                                 return TRUE;
2136                 }
2137         }
2138         else
2139         {
2140                 if(other.chain)
2141                         other = other.chain;
2142                 else
2143                         other = first;
2144         }
2145         self.enemy = other;
2146         return SpectateSet();
2147 }
2148
2149 /*
2150 =============
2151 ShowRespawnCountdown()
2152
2153 Update a respawn countdown display.
2154 =============
2155 */
2156 void ShowRespawnCountdown()
2157 {
2158         float number;
2159         if(self.deadflag == DEAD_NO) // just respawned?
2160                 return;
2161         else
2162         {
2163                 number = ceil(self.respawn_time - time);
2164                 if(number <= 0)
2165                         return;
2166                 if(number <= self.respawn_countdown)
2167                 {
2168                         self.respawn_countdown = number - 1;
2169                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2170                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2171                 }
2172         }
2173 }
2174
2175 void LeaveSpectatorMode()
2176 {
2177         if(self.caplayer)
2178                 return;
2179         if(nJoinAllowed(self))
2180         {
2181                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2182                 {
2183                         self.classname = "player";
2184
2185                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2186                                 { JoinBestTeam(self, FALSE, TRUE); }
2187
2188                         if(autocvar_g_campaign)
2189                                 { campaign_bots_may_start = 1; }
2190
2191                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2192
2193                         PutClientInServer();
2194
2195                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2196                 }
2197                 else
2198                         stuffcmd(self, "menu_showteamselect\n");
2199         }
2200         else
2201         {
2202                 // Player may not join because g_maxplayers is set
2203                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2204         }
2205 }
2206
2207 /**
2208  * Determines whether the player is allowed to join. This depends on cvar
2209  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2210  * it checks whether the number of currently playing players exceeds g_maxplayers.
2211  * @return int number of free slots for players, 0 if none
2212  */
2213 float nJoinAllowed(entity ignore) {
2214         if(!ignore)
2215         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2216         // so report 0 free slots if restricted
2217         {
2218                 if(autocvar_g_forced_team_otherwise == "spectate")
2219                         return 0;
2220                 if(autocvar_g_forced_team_otherwise == "spectator")
2221                         return 0;
2222         }
2223
2224         if(self.team_forced < 0)
2225                 return 0; // forced spectators can never join
2226
2227         // TODO simplify this
2228         entity e;
2229         float totalClients = 0;
2230         FOR_EACH_CLIENT(e)
2231                 if(e != ignore)
2232                         totalClients += 1;
2233
2234         if (!autocvar_g_maxplayers)
2235                 return maxclients - totalClients;
2236
2237         float currentlyPlaying = 0;
2238         FOR_EACH_REALCLIENT(e)
2239                 if(IS_PLAYER(e) || e.caplayer == 1)
2240                         currentlyPlaying += 1;
2241
2242         if(currentlyPlaying < autocvar_g_maxplayers)
2243                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2244
2245         return 0;
2246 }
2247
2248 /**
2249  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2250  * g_maxplayers_spectator_blocktime seconds
2251  */
2252 void checkSpectatorBlock() {
2253         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2254                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2255                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2256                         dropclient(self);
2257                 }
2258         }
2259 }
2260
2261 void PrintWelcomeMessage()
2262 {
2263         if(self.motd_actived_time == 0)
2264         {
2265                 if (autocvar_g_campaign) {
2266                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2267                                 self.motd_actived_time = time;
2268                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2269                         }
2270                 } else {
2271                         if (self.BUTTON_INFO) {
2272                                 self.motd_actived_time = time;
2273                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2274                         }
2275                 }
2276         }
2277         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2278         {
2279                 if (autocvar_g_campaign) {
2280                         if (self.BUTTON_INFO)
2281                                 self.motd_actived_time = time;
2282                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2283                                 self.motd_actived_time = 0;
2284                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2285                         }
2286                 } else {
2287                         if (self.BUTTON_INFO)
2288                                 self.motd_actived_time = time;
2289                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2290                                 self.motd_actived_time = 0;
2291                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2292                         }
2293                 }
2294         }
2295         else //if(self.motd_actived_time < 0) // just connected, motd is active
2296         {
2297                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2298                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2299                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2300                 {
2301                         // instanctly hide MOTD
2302                         self.motd_actived_time = 0;
2303                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2304                 }
2305         }
2306 }
2307
2308 void ObserverThink()
2309 {
2310         float prefered_movetype;
2311         if (self.flags & FL_JUMPRELEASED) {
2312                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2313                         self.flags &~= FL_JUMPRELEASED;
2314                         self.flags |= FL_SPAWNING;
2315                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2316                         self.flags &~= FL_JUMPRELEASED;
2317                         if(SpectateNext()) {
2318                                 self.classname = "spectator";
2319                         }
2320                 } else {
2321                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2322                         if (self.movetype != prefered_movetype)
2323                                 self.movetype = prefered_movetype;
2324                 }
2325         } else {
2326                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2327                         self.flags |= FL_JUMPRELEASED;
2328                         if(self.flags & FL_SPAWNING)
2329                         {
2330                                 self.flags &~= FL_SPAWNING;
2331                                 LeaveSpectatorMode();
2332                                 return;
2333                         }
2334                 }
2335         }
2336 }
2337
2338 void SpectatorThink()
2339 {
2340         if (self.flags & FL_JUMPRELEASED) {
2341                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2342                         self.flags &~= FL_JUMPRELEASED;
2343                         self.flags |= FL_SPAWNING;
2344                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2345                         self.flags &~= FL_JUMPRELEASED;
2346                         if(SpectateNext()) {
2347                                 self.classname = "spectator";
2348                         } else {
2349                                 self.classname = "observer";
2350                                 PutClientInServer();
2351                         }
2352                         self.impulse = 0;
2353                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2354                         self.flags &~= FL_JUMPRELEASED;
2355                         if(SpectatePrev()) {
2356                                 self.classname = "spectator";
2357                         } else {
2358                                 self.classname = "observer";
2359                                 PutClientInServer();
2360                         }
2361                         self.impulse = 0;
2362                 } else if (self.BUTTON_ATCK2) {
2363                         self.flags &~= FL_JUMPRELEASED;
2364                         self.classname = "observer";
2365                         PutClientInServer();
2366                 } else {
2367                         if(!SpectateUpdate())
2368                                 PutObserverInServer();
2369                 }
2370         } else {
2371                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2372                         self.flags |= FL_JUMPRELEASED;
2373                         if(self.flags & FL_SPAWNING)
2374                         {
2375                                 self.flags &~= FL_SPAWNING;
2376                                 LeaveSpectatorMode();
2377                                 return;
2378                         }
2379                 }
2380                 if(!SpectateUpdate())
2381                         PutObserverInServer();
2382         }
2383
2384         self.flags |= FL_CLIENT | FL_NOTARGET;
2385 }
2386
2387 void PlayerUseKey()
2388 {
2389         if not(IS_PLAYER(self))
2390                 return;
2391
2392         if(self.vehicle)
2393         {
2394         vehicles_exit(VHEF_NORMAL);
2395         return;
2396         }
2397
2398         // a use key was pressed; call handlers
2399         MUTATOR_CALLHOOK(PlayerUseKey);
2400 }
2401
2402 /*
2403 =============
2404 PlayerPreThink
2405
2406 Called every frame for each client before the physics are run
2407 =============
2408 */
2409 .float usekeypressed;
2410 void() nexball_setstatus;
2411 .float items_added;
2412 void PlayerPreThink (void)
2413 {
2414         WarpZone_PlayerPhysics_FixVAngle();
2415
2416         self.stat_game_starttime = game_starttime;
2417         self.stat_round_starttime = round_starttime;
2418         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2419         self.stat_leadlimit = autocvar_leadlimit;
2420
2421         if(frametime)
2422         {
2423                 // physics frames: update anticheat stuff
2424                 anticheat_prethink();
2425         }
2426
2427         if(blockSpectators && frametime)
2428                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2429                 checkSpectatorBlock();
2430
2431         zoomstate_set = 0;
2432
2433         if(self.netname_previous != self.netname)
2434         {
2435                 if(autocvar_sv_eventlog)
2436                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2437                 if(self.netname_previous)
2438                         strunzone(self.netname_previous);
2439                 self.netname_previous = strzone(self.netname);
2440         }
2441
2442         // version nagging
2443         if(self.version_nagtime)
2444                 if(self.cvar_g_xonoticversion)
2445                         if(time > self.version_nagtime)
2446                         {
2447                                 // don't notify git users
2448                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2449                                 {
2450                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2451                                         {
2452                                                 // notify release users if connecting to git
2453                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2454                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2455                                         }
2456                                         else
2457                                         {
2458                                                 float r;
2459                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2460                                                 if(r < 0)
2461                                                 {
2462                                                         // give users new version
2463                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2464                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2465                                                 }
2466                                                 else if(r > 0)
2467                                                 {
2468                                                         // notify users about old server version
2469                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2470                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2471                                                 }
2472                                         }
2473                                 }
2474                                 self.version_nagtime = 0;
2475                         }
2476
2477         // GOD MODE info
2478         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2479         {
2480                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2481                 self.max_armorvalue = 0;
2482         }
2483
2484 #ifdef TETRIS
2485         if (TetrisPreFrame())
2486                 return;
2487 #endif
2488
2489         if(self.frozen == 2)
2490         {
2491                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2492                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2493
2494                 if(self.revive_progress >= 1)
2495                         Unfreeze(self);
2496         }
2497
2498         MUTATOR_CALLHOOK(PlayerPreThink);
2499
2500         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2501         {
2502                 if(self.BUTTON_USE && !self.usekeypressed)
2503                         PlayerUseKey();
2504                 self.usekeypressed = self.BUTTON_USE;
2505         }
2506
2507         if(IS_REAL_CLIENT(self))
2508                 PrintWelcomeMessage();
2509
2510         if(IS_PLAYER(self))
2511         {
2512
2513                 CheckRules_Player();
2514
2515                 if (intermission_running)
2516                 {
2517                         IntermissionThink ();   // otherwise a button could be missed between
2518                         return;                                 // the think tics
2519                 }
2520
2521                 //don't allow the player to turn around while game is paused!
2522                 if(timeout_status == TIMEOUT_ACTIVE) {
2523                         // FIXME turn this into CSQC stuff
2524                         self.v_angle = self.lastV_angle;
2525                         self.angles = self.lastV_angle;
2526                         self.fixangle = TRUE;
2527                 }
2528
2529                 if(frametime)
2530                 {
2531                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2532                         {
2533                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2534                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2535                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2536
2537                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2538                                 {
2539                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2540                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2541                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2542                                 }
2543                         }
2544                         else
2545                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2546
2547                         player_powerups();
2548                 }
2549
2550                 if (self.deadflag != DEAD_NO)
2551                 {
2552                         if(self.personal && g_race_qualifying)
2553                         {
2554                                 if(time > self.respawn_time)
2555                                 {
2556                                         self.respawn_time = time + 1; // only retry once a second
2557                                         self.stat_respawn_time = self.respawn_time;
2558                                         respawn();
2559                                         self.impulse = 141;
2560                                 }
2561                         }
2562                         else
2563                         {
2564                                 float button_pressed;
2565                                 if(frametime)
2566                                         player_anim();
2567                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2568
2569                                 if (self.deadflag == DEAD_DYING)
2570                                 {
2571                                         if(self.respawn_flags & RESPAWN_FORCE)
2572                                                 self.deadflag = DEAD_RESPAWNING;
2573                                         else if(!button_pressed)
2574                                                 self.deadflag = DEAD_DEAD;
2575                                 }
2576                                 else if (self.deadflag == DEAD_DEAD)
2577                                 {
2578                                         if(button_pressed)
2579                                                 self.deadflag = DEAD_RESPAWNABLE;
2580                                 }
2581                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2582                                 {
2583                                         if(!button_pressed)
2584                                                 self.deadflag = DEAD_RESPAWNING;
2585                                 }
2586                                 else if (self.deadflag == DEAD_RESPAWNING)
2587                                 {
2588                                         if(time > self.respawn_time)
2589                                         {
2590                                                 self.respawn_time = time + 1; // only retry once a second
2591                                                 respawn();
2592                                         }
2593                                 }
2594
2595                                 ShowRespawnCountdown();
2596
2597                                 if(self.respawn_flags & RESPAWN_SILENT)
2598                                         self.stat_respawn_time = 0;
2599                                 else
2600                                         self.stat_respawn_time = self.respawn_time;
2601                         }
2602
2603                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2604                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2605                                 self.stat_respawn_time *= -1;
2606
2607                         return;
2608                 }
2609
2610                 self.prevorigin = self.origin;
2611
2612                 float do_crouch = self.BUTTON_CROUCH;
2613                 if(self.hook.state)
2614                         do_crouch = 0;
2615                 if(self.health <= g_bloodloss)
2616                         do_crouch = 1;
2617                 if(self.vehicle)
2618                         do_crouch = 0;
2619                 if(self.frozen)
2620                         do_crouch = 0;
2621                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2622                         do_crouch = 0;
2623
2624                 if (do_crouch)
2625                 {
2626                         if (!self.crouch)
2627                         {
2628                                 self.crouch = TRUE;
2629                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2630                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2631                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2632                         }
2633                 }
2634                 else
2635                 {
2636                         if (self.crouch)
2637                         {
2638                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2639                                 if (!trace_startsolid)
2640                                 {
2641                                         self.crouch = FALSE;
2642                                         self.view_ofs = PL_VIEW_OFS;
2643                                         setsize (self, PL_MIN, PL_MAX);
2644                                 }
2645                         }
2646                 }
2647
2648                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2649                 {
2650                         if(self.bloodloss_timer < time)
2651                         {
2652                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2653                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2654                         }
2655                 }
2656
2657                 FixPlayermodel();
2658
2659                 GrapplingHookFrame();
2660
2661                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2662                 //if(frametime)
2663                 {
2664                         self.items &~= self.items_added;
2665
2666                         W_WeaponFrame();
2667
2668                         self.items_added = 0;
2669                         if(self.items & IT_JETPACK)
2670                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2671                                         self.items_added |= IT_FUEL;
2672
2673                         self.items |= self.items_added;
2674                 }
2675
2676                 player_regen();
2677
2678                 // rot nex charge to the charge limit
2679                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2680                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2681
2682                 if(frametime)
2683                         player_anim();
2684
2685                 if(g_nexball)
2686                         nexball_setstatus();
2687
2688                 // secret status
2689                 secrets_setstatus();
2690
2691                 // monsters status
2692                 monsters_setstatus();
2693
2694                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2695
2696                 //self.angles_y=self.v_angle_y + 90;   // temp
2697         } else if(gameover) {
2698                 if (intermission_running)
2699                         IntermissionThink ();   // otherwise a button could be missed between
2700                 return;
2701         } else if(IS_OBSERVER(self)) {
2702                 ObserverThink();
2703         } else if(IS_SPEC(self)) {
2704                 SpectatorThink();
2705         }
2706
2707         if(!zoomstate_set)
2708                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2709
2710         float oldspectatee_status;
2711         oldspectatee_status = self.spectatee_status;
2712         if(IS_SPEC(self))
2713                 self.spectatee_status = num_for_edict(self.enemy);
2714         else if(IS_OBSERVER(self))
2715                 self.spectatee_status = num_for_edict(self);
2716         else
2717                 self.spectatee_status = 0;
2718         if(self.spectatee_status != oldspectatee_status)
2719         {
2720                 ClientData_Touch(self);
2721                 if(g_race || g_cts)
2722                         race_InitSpectator();
2723         }
2724
2725         if(self.teamkill_soundtime)
2726         if(time > self.teamkill_soundtime)
2727         {
2728                 self.teamkill_soundtime = 0;
2729
2730                 entity oldpusher, oldself;
2731
2732                 oldself = self; self = self.teamkill_soundsource;
2733                 oldpusher = self.pusher; self.pusher = oldself;
2734
2735                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2736
2737                 self.pusher = oldpusher;
2738                 self = oldself;
2739         }
2740
2741         if(self.taunt_soundtime)
2742         if(time > self.taunt_soundtime)
2743         {
2744                 self.taunt_soundtime = 0;
2745                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2746         }
2747
2748         target_voicescript_next(self);
2749
2750         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2751         if(!self.weapon)
2752                 self.clip_load = self.clip_size = 0;
2753 }
2754
2755 float isInvisibleString(string s)
2756 {
2757         float i, n, c;
2758         s = strdecolorize(s);
2759         for((i = 0), (n = strlen(s)); i < n; ++i)
2760         {
2761                 c = str2chr(s, i);
2762                 switch(c)
2763                 {
2764                         case 0:
2765                         case 32: // space
2766                                 break;
2767                         case 192: // charmap space
2768                                 if (!autocvar_utf8_enable)
2769                                         break;
2770                                 return FALSE;
2771                         case 160: // space in unicode fonts
2772                         case 0xE000 + 192: // utf8 charmap space
2773                                 if (autocvar_utf8_enable)
2774                                         break;
2775                         default:
2776                                 return FALSE;
2777                 }
2778         }
2779         return TRUE;
2780 }
2781
2782 /*
2783 =============
2784 PlayerPostThink
2785
2786 Called every frame for each client after the physics are run
2787 =============
2788 */
2789 .float idlekick_lasttimeleft;
2790 void PlayerPostThink (void)
2791 {
2792         // Savage: Check for nameless players
2793         if (isInvisibleString(self.netname)) {
2794                 self.netname = "Player";
2795                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2796         }
2797
2798         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2799         {
2800                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2801                 {
2802                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2803                 }
2804                 else
2805                 {
2806                         float timeleft;
2807                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2808                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2809                         {
2810                                 if(!self.idlekick_lasttimeleft)
2811                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2812                         }
2813                         if(timeleft <= 0)
2814                         {
2815                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2816                                 dropclient(self);
2817                                 return;
2818                         }
2819                         else if(timeleft <= 10)
2820                         {
2821                                 if(timeleft != self.idlekick_lasttimeleft)
2822                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2823                                 self.idlekick_lasttimeleft = timeleft;
2824                         }
2825                 }
2826         }
2827
2828 #ifdef TETRIS
2829         if(self.impulse == 100)
2830                 ImpulseCommands();
2831         if (!TetrisPostFrame())
2832         {
2833 #endif
2834
2835         CheatFrame();
2836
2837         //CheckPlayerJump();
2838
2839         if(IS_PLAYER(self)) {
2840                 CheckRules_Player();
2841                 UpdateChatBubble();
2842                 if (self.impulse)
2843                         ImpulseCommands();
2844                 if (intermission_running)
2845                         return;         // intermission or finale
2846                 GetPressedKeys();
2847         }
2848
2849 #ifdef TETRIS
2850         }
2851 #endif
2852
2853         /*
2854         float i;
2855         for(i = 0; i < 1000; ++i)
2856         {
2857                 vector end;
2858                 end = self.origin + '0 0 1024' + 512 * randomvec();
2859                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2860                 if(trace_fraction < 1)
2861                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2862                 {
2863                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2864                         break;
2865                 }
2866         }
2867         */
2868
2869         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2870
2871         if(self.waypointsprite_attachedforcarrier)
2872                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2873
2874         playerdemo_write();
2875
2876         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2877         {
2878                 if not(self.stored_netname)
2879                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2880                 if(self.stored_netname != self.netname)
2881                 {
2882                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2883                         strunzone(self.stored_netname);
2884                         self.stored_netname = strzone(self.netname);
2885                 }
2886         }
2887
2888         /*
2889         if(g_race)
2890                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2891         */
2892
2893         CSQCMODEL_AUTOUPDATE();
2894 }