qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!warmup_stage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                 {
 301                         defaultmodel = argv(floor(n * self.model_randomizer));
 302                         // However, do NOT randomize if the player-selected model is in the list.
 303                         for (i = 0; i < n; ++i)
 304                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 305                                         defaultmodel = argv(i);
 306                 }
 307
 308                 i = strstrofs(defaultmodel, ":", 0);
 309                 if(i >= 0)
 310                 {
 311                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 312                         defaultmodel = substring(defaultmodel, 0, i);
 313                 }
 314         }
 315
 316         if(defaultmodel != "")
 317         {
 318                 if (defaultmodel != self.model)
 319                 {
 320                         m1 = self.mins;
 321                         m2 = self.maxs;
 322                         setplayermodel (self, defaultmodel);
 323                         setsize (self, m1, m2);
 324                         chmdl = TRUE;
 325                 }
 326
 327                 oldskin = self.skin;
 328                 self.skin = defaultskin;
 329         } else {
 330                 if (self.playermodel != self.model || self.playermodel == "")
 331                 {
 332                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 333                         m1 = self.mins;
 334                         m2 = self.maxs;
 335                         setplayermodel (self, self.playermodel);
 336                         setsize (self, m1, m2);
 337                         chmdl = TRUE;
 338                 }
 339
 340                 oldskin = self.skin;
 341                 self.skin = stof(self.playerskin);
 342         }
 343
 344         if(chmdl || oldskin != self.skin) // model or skin has changed
 345         {
 346                 self.species = player_getspecies(); // update species
 347                 UpdatePlayerSounds(); // update skin sounds
 348         }
 349
 350         if(!teamplay)
 351                 if(strlen(autocvar_sv_defaultplayercolors))
 352                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 353                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 354 }
 355
 356 /*
 357 =============
 358 PutClientInServer
 359
 360 Called when a client spawns in the server
 361 =============
 362 */
 363 void PutClientInServer (void)
 364 {
 365         if(IS_BOT_CLIENT(self))
 366                 self.classname = "player";
 367         else if(IS_REAL_CLIENT(self))
 368         {
 369                 msg_entity = self;
 370                 WriteByte(MSG_ONE, SVC_SETVIEW);
 371                 WriteEntity(MSG_ONE, self);
 372         }
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 race_PreSpawn();
 393
 394                 spot = SelectSpawnPoint (FALSE);
 395                 if(!spot)
 396                 {
 397                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 398                         return; // spawn failed
 399                 }
 400
 401                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 402
 403                 self.classname = "player";
 404                 self.wasplayer = TRUE;
 405                 self.iscreature = TRUE;
 406                 self.teleportable = TELEPORT_NORMAL;
 407                 self.damagedbycontents = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 411                 if(autocvar_g_playerclip_collisions)
 412                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 413                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 415                 self.frags = FRAGS_PLAYER;
 416                 if(INDEPENDENT_PLAYERS)
 417                         MAKE_INDEPENDENT_PLAYER(self);
 418                 self.flags = FL_CLIENT;
 419                 if(autocvar__notarget)
 420                         self.flags |= FL_NOTARGET;
 421                 self.takedamage = DAMAGE_AIM;
 422                 self.effects = 0;
 423                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 424                 self.air_finished = time + 12;
 425                 self.dmg = 2;
 426                 if(autocvar_g_balance_nex_charge)
 427                 {
 428                         if(autocvar_g_balance_nex_secondary_chargepool)
 429                                 self.nex_chargepool_ammo = 1;
 430                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 431                 }
 432
 433                 if(warmup_stage)
 434                 {
 435                         self.ammo_shells = warmup_start_ammo_shells;
 436                         self.ammo_nails = warmup_start_ammo_nails;
 437                         self.ammo_rockets = warmup_start_ammo_rockets;
 438                         self.ammo_cells = warmup_start_ammo_cells;
 439                         self.ammo_fuel = warmup_start_ammo_fuel;
 440                         self.health = warmup_start_health;
 441                         self.armorvalue = warmup_start_armorvalue;
 442
 443                         if(g_warmup_allguns == 2)
 444                                 self.weapons = warmup_start_weapons;
 445                         else if(g_warmup_allguns == 1)
 446                                 self.weapons = (warmup_start_weapons & (weaponsInMap | start_weapons));
 447                 }
 448                 else
 449                 {
 450                         self.ammo_shells = start_ammo_shells;
 451                         self.ammo_nails = start_ammo_nails;
 452                         self.ammo_rockets = start_ammo_rockets;
 453                         self.ammo_cells = start_ammo_cells;
 454                         self.ammo_fuel = start_ammo_fuel;
 455                         self.health = start_health;
 456                         self.armorvalue = start_armorvalue;
 457                         self.weapons = start_weapons;
 458                 }
 459
 460                 if(self.weapons & WEPSET_SUPERWEAPONS)
 461                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 462                 else
 463                         self.superweapons_finished = 0;
 464
 465                 if(g_weaponarena_random)
 466                 {
 467                         if(g_weaponarena_random_with_laser)
 468                                 self.weapons &= ~WEPSET_LASER;
 469                         W_RandomWeapons(self, g_weaponarena_random);
 470                         if(g_weaponarena_random_with_laser)
 471                                 self.weapons |= WEPSET_LASER;
 472                 }
 473
 474                 self.items = start_items;
 475
 476                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 477                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 478                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 479                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 480                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 481                 //extend the pause of rotting if client was reset at the beginning of the countdown
 482                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 483                         self.spawnshieldtime += game_starttime - time;
 484                         self.pauserotarmor_finished += game_starttime - time;
 485                         self.pauserothealth_finished += game_starttime - time;
 486                         self.pauseregen_finished += game_starttime - time;
 487                 }
 488                 self.damageforcescale = 2;
 489                 self.death_time = 0;
 490                 self.respawn_flags = 0;
 491                 self.respawn_time = 0;
 492                 self.stat_respawn_time = 0;
 493                 self.scale = 0;
 494                 self.fade_time = 0;
 495                 self.pain_frame = 0;
 496                 self.pain_finished = 0;
 497                 self.strength_finished = 0;
 498                 self.invincible_finished = 0;
 499                 self.pushltime = 0;
 500                 // players have no think function
 501                 self.think = func_null;
 502                 self.nextthink = 0;
 503                 self.hook_time = 0;
 504                 self.dmg_team = 0;
 505                 self.ballistics_density = autocvar_g_ballistics_density_player;
 506
 507                 self.metertime = 0;
 508
 509                 self.deadflag = DEAD_NO;
 510
 511                 self.angles = spot.angles;
 512
 513                 self.angles_z = 0; // never spawn tilted even if the spot says to
 514                 self.fixangle = TRUE; // turn this way immediately
 515                 self.velocity = '0 0 0';
 516                 self.avelocity = '0 0 0';
 517                 self.punchangle = '0 0 0';
 518                 self.punchvector = '0 0 0';
 519                 self.oldvelocity = self.velocity;
 520                 self.fire_endtime = -1;
 521
 522                 entity spawnevent = spawn();
 523                 spawnevent.owner = self;
 524                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 525
 526                 self.model = "";
 527                 FixPlayermodel();
 528                 self.drawonlytoclient = world;
 529
 530                 self.crouch = FALSE;
 531                 self.view_ofs = PL_VIEW_OFS;
 532                 setsize (self, PL_MIN, PL_MAX);
 533                 self.spawnorigin = spot.origin;
 534                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 535                 // don't reset back to last position, even if new position is stuck in solid
 536                 self.oldorigin = self.origin;
 537                 self.prevorigin = self.origin;
 538                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 539                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 540         self.hud = HUD_NORMAL;
 541
 542                 self.event_damage = PlayerDamage;
 543
 544                 self.bot_attack = TRUE;
 545
 546                 self.statdraintime = time + 5;
 547                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 548
 549                 if(self.killcount == -666) {
 550                         PlayerScore_Clear(self);
 551                         self.killcount = 0;
 552                 }
 553
 554                 CL_SpawnWeaponentity();
 555                 self.alpha = default_player_alpha;
 556                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 557                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 558
 559                 self.speedrunning = FALSE;
 560
 561                 race_PostSpawn(spot);
 562
 563                 //stuffcmd(self, "chase_active 0");
 564                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 565
 566                 target_voicescript_clear(self);
 567
 568                 // reset fields the weapons may use
 569                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 570                 {
 571                         weapon_action(j, WR_RESETPLAYER);
 572
 573                         // all weapons must be fully loaded when we spawn
 574                         entity e;
 575                         e = get_weaponinfo(j);
 576                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 577                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 578                 }
 579
 580                 oldself = self;
 581                 self = spot;
 582                         activator = oldself;
 583                                 string s;
 584                                 s = self.target;
 585                                 self.target = string_null;
 586                                 SUB_UseTargets();
 587                                 self.target = s;
 588                         activator = world;
 589                 self = oldself;
 590
 591                 spawn_spot = spot;
 592                 MUTATOR_CALLHOOK(PlayerSpawn);
 593
 594                 if(autocvar_spawn_debug)
 595                 {
 596                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 597                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 598                 }
 599
 600                 self.switchweapon = w_getbestweapon(self);
 601                 self.cnt = -1; // W_LastWeapon will not complain
 602                 self.weapon = 0;
 603                 self.weaponname = "";
 604                 self.switchingweapon = 0;
 605
 606                 if(!warmup_stage)
 607                         if(!self.alivetime)
 608                                 self.alivetime = time;
 609
 610                 antilag_clear(self);
 611         }
 612         else if(IS_OBSERVER(self))
 613         {
 614                 PutObserverInServer ();
 615         }
 616 }
 617
 618 .float ebouncefactor, ebouncestop; // electro's values
 619 // TODO do we need all these fields, or should we stop autodetecting runtime
 620 // changes and just have a console command to update this?
 621 float ClientInit_SendEntity(entity to, float sf)
 622 {
 623         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 624         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 637         if(sv_foginterval && world.fog != "")
 638                 WriteString(MSG_ENTITY, world.fog);
 639         else
 640                 WriteString(MSG_ENTITY, "");
 641         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 642         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 643         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 644         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 645         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 651         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 652         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 653         return TRUE;
 654 }
 655
 656 void ClientInit_CheckUpdate()
 657 {
 658         self.nextthink = time;
 659         if(self.count != autocvar_g_balance_armor_blockpercent)
 660         {
 661                 self.count = autocvar_g_balance_armor_blockpercent;
 662                 self.SendFlags |= 1;
 663         }
 664         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 665         {
 666                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 667                 self.SendFlags |= 1;
 668         }
 669         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 670         {
 671                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 675         {
 676                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 680         {
 681                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 682                 self.SendFlags |= 1;
 683         }
 684 }
 685
 686 void ClientInit_Spawn()
 687 {
 688         entity o;
 689         entity e;
 690         e = spawn();
 691         e.classname = "clientinit";
 692         e.think = ClientInit_CheckUpdate;
 693         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 694
 695         o = self;
 696         self = e;
 697         ClientInit_CheckUpdate();
 698         self = o;
 699 }
 700
 701 /*
 702 =============
 703 SetNewParms
 704 =============
 705 */
 706 void SetNewParms (void)
 707 {
 708         // initialize parms for a new player
 709         parm1 = -(86400 * 366);
 710 }
 711
 712 /*
 713 =============
 714 SetChangeParms
 715 =============
 716 */
 717 void SetChangeParms (void)
 718 {
 719         // save parms for level change
 720         parm1 = self.parm_idlesince - time;
 721 }
 722
 723 /*
 724 =============
 725 DecodeLevelParms
 726 =============
 727 */
 728 void DecodeLevelParms (void)
 729 {
 730         // load parms
 731         self.parm_idlesince = parm1;
 732         if(self.parm_idlesince == -(86400 * 366))
 733                 self.parm_idlesince = time;
 734
 735         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 736         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 737 }
 738
 739 /*
 740 =============
 741 ClientKill
 742
 743 Called when a client types 'kill' in the console
 744 =============
 745 */
 746
 747 .float clientkill_nexttime;
 748 void ClientKill_Now_TeamChange()
 749 {
 750         if(self.killindicator_teamchange == -1)
 751         {
 752                 JoinBestTeam( self, FALSE, TRUE );
 753         }
 754         else if(self.killindicator_teamchange == -2)
 755         {
 756                 if(blockSpectators)
 757                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 758                 PutObserverInServer();
 759         }
 760         else
 761                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 762         self.killindicator_teamchange = 0;
 763 }
 764
 765 void ClientKill_Now()
 766 {
 767         if(self.vehicle)
 768         {
 769             vehicles_exit(VHEF_RELESE);
 770             if(!self.killindicator_teamchange)
 771             {
 772             self.vehicle_health = -1;
 773             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 774             }
 775         }
 776
 777         if(self.killindicator && !wasfreed(self.killindicator))
 778                 remove(self.killindicator);
 779
 780         self.killindicator = world;
 781
 782         if(self.killindicator_teamchange)
 783                 ClientKill_Now_TeamChange();
 784
 785         // in any case:
 786         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 787
 788         // now I am sure the player IS dead
 789 }
 790 void KillIndicator_Think()
 791 {
 792         if (gameover)
 793         {
 794                 self.owner.killindicator = world;
 795                 remove(self);
 796                 return;
 797         }
 798
 799         if (self.owner.alpha < 0 && !self.owner.vehicle)
 800         {
 801                 self.owner.killindicator = world;
 802                 remove(self);
 803                 return;
 804         }
 805
 806         if(self.cnt <= 0)
 807         {
 808                 self = self.owner;
 809                 ClientKill_Now(); // no oldself needed
 810                 return;
 811         }
 812     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 813     {
 814         self.nextthink = time + 1;
 815         self.cnt -= 1;
 816     }
 817         else
 818         {
 819                 if(self.cnt <= 10)
 820                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 821                 if(IS_REAL_CLIENT(self.owner))
 822                 {
 823                         if(self.cnt <= 10)
 824                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 825                 }
 826                 self.nextthink = time + 1;
 827                 self.cnt -= 1;
 828         }
 829 }
 830
 831 float clientkilltime;
 832 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 833 {
 834         float killtime;
 835         float starttime;
 836         entity e;
 837
 838         if (gameover)
 839                 return;
 840
 841         killtime = autocvar_g_balance_kill_delay;
 842
 843         if(g_race_qualifying || g_cts)
 844                 killtime = 0;
 845
 846     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 847     {
 848                 remove(self.killindicator);
 849                 self.killindicator = world;
 850
 851         ClientKill_Now(); // allow instant kill in this case
 852         return;
 853     }
 854
 855         self.killindicator_teamchange = targetteam;
 856
 857     if(!self.killindicator)
 858         {
 859                 if(self.deadflag == DEAD_NO)
 860                 {
 861                         killtime = max(killtime, self.clientkill_nexttime - time);
 862                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 863                 }
 864
 865                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 866                 {
 867                         ClientKill_Now();
 868                 }
 869                 else
 870                 {
 871                         starttime = max(time, clientkilltime);
 872
 873                         self.killindicator = spawn();
 874                         self.killindicator.owner = self;
 875                         self.killindicator.scale = 0.5;
 876                         setattachment(self.killindicator, self, "");
 877                         setorigin(self.killindicator, '0 0 52');
 878                         self.killindicator.think = KillIndicator_Think;
 879                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 880                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 881                         self.killindicator.cnt = ceil(killtime);
 882                         self.killindicator.count = bound(0, ceil(killtime), 10);
 883                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 884
 885                         for(e = world; (e = find(e, classname, "body")) != world; )
 886                         {
 887                                 if(e.enemy != self)
 888                                         continue;
 889                                 e.killindicator = spawn();
 890                                 e.killindicator.owner = e;
 891                                 e.killindicator.scale = 0.5;
 892                                 setattachment(e.killindicator, e, "");
 893                                 setorigin(e.killindicator, '0 0 52');
 894                                 e.killindicator.think = KillIndicator_Think;
 895                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 896                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 897                                 e.killindicator.cnt = ceil(killtime);
 898                         }
 899                         self.lip = 0;
 900                 }
 901         }
 902         if(self.killindicator)
 903         {
 904                 if(targetteam == 0) // just die
 905                 {
 906                         self.killindicator.colormod = '0 0 0';
 907                         if(IS_REAL_CLIENT(self))
 908                         if(self.killindicator.cnt > 0)
 909                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 910                 }
 911                 else if(targetteam == -1) // auto
 912                 {
 913                         self.killindicator.colormod = '0 1 0';
 914                         if(IS_REAL_CLIENT(self))
 915                         if(self.killindicator.cnt > 0)
 916                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 917                 }
 918                 else if(targetteam == -2) // spectate
 919                 {
 920                         self.killindicator.colormod = '0.5 0.5 0.5';
 921                         if(IS_REAL_CLIENT(self))
 922                         if(self.killindicator.cnt > 0)
 923                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 924                 }
 925                 else
 926                 {
 927                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 928                         if(IS_REAL_CLIENT(self))
 929                         if(self.killindicator.cnt > 0)
 930                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 931                 }
 932         }
 933
 934 }
 935
 936 void ClientKill (void)
 937 {
 938         if(gameover) return;
 939         if(self.player_blocked) return;
 940         if(self.freezetag_frozen) return;
 941
 942         ClientKill_TeamChange(0);
 943 }
 944
 945 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 946 {
 947     e.killindicator = spawn();
 948     e.killindicator.owner = e;
 949     e.killindicator.think = KillIndicator_Think;
 950     e.killindicator.nextthink = time + (e.lip) * 0.05;
 951     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 952     e.killindicator.health = 1; // this is used to indicate that it should be silent
 953     e.lip = 0;
 954 }
 955
 956 void FixClientCvars(entity e)
 957 {
 958         // send prediction settings to the client
 959         stuffcmd(e, "\nin_bindmap 0 0\n");
 960         if(g_race || g_cts)
 961                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 962         if(autocvar_g_antilag == 3) // client side hitscan
 963                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 964         if(autocvar_sv_gentle)
 965                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 966         /*
 967          * we no longer need to stuff this. Remove this comment block if you feel
 968          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 969         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 970         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 971         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 972         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 973         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 976         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 978         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 979         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 981         stuffcmd(e, "cl_movement_edgefriction 1\n");
 982          */
 983 }
 984
 985 float PlayerInIDList(entity p, string idlist)
 986 {
 987         float n, i;
 988         string s;
 989
 990         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 991         if not(p.crypto_idfp)
 992                 return 0;
 993
 994         // this function allows abbreviated player IDs too!
 995         n = tokenize_console(idlist);
 996         for(i = 0; i < n; ++i)
 997         {
 998                 s = argv(i);
 999                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1000                         return 1;
1001         }
1002
1003         return 0;
1004 }
1005
1006 /*
1007 =============
1008 ClientConnect
1009
1010 Called when a client connects to the server
1011 =============
1012 */
1013 void DecodeLevelParms (void);
1014 //void dom_player_join_team(entity pl);
1015 void set_dom_state(entity e);
1016 void ClientConnect (void)
1017 {
1018         float t;
1019
1020         if(IS_CLIENT(self))
1021         {
1022                 print("Warning: ClientConnect, but already connected!\n");
1023                 return;
1024         }
1025
1026         if(Ban_MaybeEnforceBanOnce(self))
1027                 return;
1028
1029         DecodeLevelParms();
1030
1031 #ifdef WATERMARK
1032         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1033 #endif
1034
1035         self.classname = "player_joining";
1036
1037         self.flags = FL_CLIENT;
1038         self.version_nagtime = time + 10 + random() * 10;
1039
1040         if(player_count<0)
1041         {
1042                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1043                 player_count = 0;
1044         }
1045
1046         PlayerScore_Attach(self);
1047         ClientData_Attach();
1048         accuracy_init(self);
1049
1050         bot_clientconnect();
1051
1052         playerdemo_init();
1053
1054         anticheat_init();
1055
1056         race_PreSpawnObserver();
1057
1058         // identify the right forced team
1059         if(autocvar_g_campaign)
1060         {
1061                 if(IS_REAL_CLIENT(self)) // only players, not bots
1062                 {
1063                         switch(autocvar_g_campaign_forceteam)
1064                         {
1065                                 case 1: self.team_forced = NUM_TEAM_1; break;
1066                                 case 2: self.team_forced = NUM_TEAM_2; break;
1067                                 case 3: self.team_forced = NUM_TEAM_3; break;
1068                                 case 4: self.team_forced = NUM_TEAM_4; break;
1069                                 default: self.team_forced = 0;
1070                         }
1071                 }
1072         }
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1074                 self.team_forced = NUM_TEAM_1;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1076                 self.team_forced = NUM_TEAM_2;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1078                 self.team_forced = NUM_TEAM_3;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1080                 self.team_forced = NUM_TEAM_4;
1081         else if(autocvar_g_forced_team_otherwise == "red")
1082                 self.team_forced = NUM_TEAM_1;
1083         else if(autocvar_g_forced_team_otherwise == "blue")
1084                 self.team_forced = NUM_TEAM_2;
1085         else if(autocvar_g_forced_team_otherwise == "yellow")
1086                 self.team_forced = NUM_TEAM_3;
1087         else if(autocvar_g_forced_team_otherwise == "pink")
1088                 self.team_forced = NUM_TEAM_4;
1089         else if(autocvar_g_forced_team_otherwise == "spectate")
1090                 self.team_forced = -1;
1091         else if(autocvar_g_forced_team_otherwise == "spectator")
1092                 self.team_forced = -1;
1093         else
1094                 self.team_forced = 0;
1095
1096         if(!teamplay)
1097                 if(self.team_forced > 0)
1098                         self.team_forced = 0;
1099
1100         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1101
1102         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1103                 self.classname = "observer";
1104         } else {
1105                 if(teamplay)
1106                 {
1107                         if(autocvar_g_balance_teams)
1108                         {
1109                                 self.classname = "player";
1110                                 campaign_bots_may_start = 1;
1111                         }
1112                         else
1113                         {
1114                                 self.classname = "observer"; // do it anyway
1115                         }
1116                 }
1117                 else
1118                 {
1119                         self.classname = "player";
1120                         campaign_bots_may_start = 1;
1121                 }
1122         }
1123
1124         self.playerid = (playerid_last = playerid_last + 1);
1125
1126         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1127
1128     if(IS_BOT_CLIENT(self))
1129         PlayerStats_AddPlayer(self);
1130
1131         if(autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1133
1134         LogTeamchange(self.playerid, self.team, 1);
1135
1136         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1137
1138         self.netname_previous = strzone(self.netname);
1139
1140         if(IS_PLAYER(self) && teamplay)
1141                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1142         else
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1144
1145         stuffcmd(self, strcat(clientstuff, "\n"));
1146         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1147
1148         FixClientCvars(self);
1149
1150         // spawnfunc_waypoint sprites
1151         WaypointSprite_InitClient(self);
1152
1153         // Wazat's grappling hook
1154         SetGrappleHookBindings();
1155
1156         // get version info from player
1157         stuffcmd(self, "cmd clientversion $gameversion\n");
1158
1159         // get other cvars from player
1160         GetCvars(0);
1161
1162         // notify about available teams
1163         if(teamplay)
1164         {
1165                 CheckAllowedTeams(self);
1166                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1167                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1168         }
1169         else
1170                 stuffcmd(self, "set _teams_available 0\n");
1171
1172         attach_entcs();
1173
1174         bot_relinkplayerlist();
1175
1176         self.spectatortime = time;
1177         if(blockSpectators)
1178         {
1179                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1180         }
1181
1182         self.jointime = time;
1183         self.allowed_timeouts = autocvar_sv_timeout_number;
1184
1185         if(IS_REAL_CLIENT(self))
1186         {
1187                 if(!autocvar_g_campaign)
1188                 {
1189                         self.motd_actived_time = -1;
1190                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1191                 }
1192
1193                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1194                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1195         }
1196
1197         if(!sv_foginterval && world.fog != "")
1198                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1199
1200         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1201         {
1202                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1203                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1204         }
1205         else
1206                 self.hitplotfh = -1;
1207
1208         if(g_race || g_cts) {
1209                 string rr;
1210                 if(g_cts)
1211                         rr = CTS_RECORD;
1212                 else
1213                         rr = RACE_RECORD;
1214
1215                 msg_entity = self;
1216                 race_send_recordtime(MSG_ONE);
1217                 race_send_speedaward(MSG_ONE);
1218
1219                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1220                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1221                 race_send_speedaward_alltimebest(MSG_ONE);
1222
1223                 float i;
1224                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1225                         race_SendRankings(i, 0, 0, MSG_ONE);
1226                 }
1227         }
1228         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1229                 send_CSQC_teamnagger();
1230
1231         CheatInitClient();
1232
1233         CSQCMODEL_AUTOINIT();
1234
1235         self.model_randomizer = random();
1236
1237         if(IS_REAL_CLIENT(self))
1238                 sv_notice_join();
1239
1240         MUTATOR_CALLHOOK(ClientConnect);
1241 }
1242 /*
1243 =============
1244 ClientDisconnect
1245
1246 Called when a client disconnects from the server
1247 =============
1248 */
1249 .entity chatbubbleentity;
1250 void ReadyCount();
1251 void ClientDisconnect (void)
1252 {
1253         if(self.vehicle)
1254             vehicles_exit(VHEF_RELESE);
1255
1256         if not(IS_CLIENT(self))
1257         {
1258                 print("Warning: ClientDisconnect without ClientConnect\n");
1259                 return;
1260         }
1261
1262         PlayerStats_AddGlobalInfo(self);
1263
1264         CheatShutdownClient();
1265
1266         if(self.hitplotfh >= 0)
1267         {
1268                 fclose(self.hitplotfh);
1269                 self.hitplotfh = -1;
1270         }
1271
1272         anticheat_report();
1273         anticheat_shutdown();
1274
1275         playerdemo_shutdown();
1276
1277         bot_clientdisconnect();
1278
1279         if(self.entcs)
1280                 detach_entcs();
1281
1282         if(autocvar_sv_eventlog)
1283                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1284
1285         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1286
1287         MUTATOR_CALLHOOK(ClientDisconnect);
1288
1289         Portal_ClearAll(self);
1290
1291         RemoveGrapplingHook(self);
1292
1293         // Here, everything has been done that requires this player to be a client.
1294
1295         self.flags &= ~FL_CLIENT;
1296
1297         if (self.chatbubbleentity)
1298                 remove (self.chatbubbleentity);
1299
1300         if (self.killindicator)
1301                 remove (self.killindicator);
1302
1303         WaypointSprite_PlayerGone();
1304
1305         bot_relinkplayerlist();
1306
1307         accuracy_free(self);
1308         ClientData_Detach();
1309         PlayerScore_Detach(self);
1310
1311         if(self.netname_previous)
1312                 strunzone(self.netname_previous);
1313         if(self.clientstatus)
1314                 strunzone(self.clientstatus);
1315         if(self.weaponorder_byimpulse)
1316                 strunzone(self.weaponorder_byimpulse);
1317
1318         ClearPlayerSounds();
1319
1320         if(self.personal)
1321                 remove(self.personal);
1322
1323         self.playerid = 0;
1324         ReadyCount();
1325
1326         // free cvars
1327         GetCvars(-1);
1328 }
1329
1330 .float BUTTON_CHAT;
1331 void ChatBubbleThink()
1332 {
1333         self.nextthink = time;
1334         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1335         {
1336                 if(self.owner) // but why can that ever be world?
1337                         self.owner.chatbubbleentity = world;
1338                 remove(self);
1339                 return;
1340         }
1341         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1342 #ifdef TETRIS
1343                 || self.owner.tetris_on
1344 #endif
1345         )
1346                 self.model = self.mdl;
1347         else
1348                 self.model = "";
1349 }
1350
1351 void UpdateChatBubble()
1352 {
1353         if (self.alpha < 0)
1354                 return;
1355         // spawn a chatbubble entity if needed
1356         if (!self.chatbubbleentity)
1357         {
1358                 self.chatbubbleentity = spawn();
1359                 self.chatbubbleentity.owner = self;
1360                 self.chatbubbleentity.exteriormodeltoclient = self;
1361                 self.chatbubbleentity.think = ChatBubbleThink;
1362                 self.chatbubbleentity.nextthink = time;
1363                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1364                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1365                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1366                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1367                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1368                 self.chatbubbleentity.model = "";
1369                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1370         }
1371 }
1372
1373
1374 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1375 // added to the model skins
1376 /*void UpdateColorModHack()
1377 {
1378         float c;
1379         c = self.clientcolors & 15;
1380         // LordHavoc: only bothering to support white, green, red, yellow, blue
1381              if (!teamplay) self.colormod = '0 0 0';
1382         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1383         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1384         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1385         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1386         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1387         else self.colormod = '1 1 1';
1388 }*/
1389
1390 void respawn(void)
1391 {
1392         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1393         {
1394                 self.solid = SOLID_NOT;
1395                 self.takedamage = DAMAGE_NO;
1396                 self.movetype = MOVETYPE_FLY;
1397                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1398                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1399                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1400                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1401                 if(autocvar_g_respawn_ghosts_maxtime)
1402                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1403         }
1404
1405         CopyBody(1);
1406
1407         self.effects |= EF_NODRAW; // prevent another CopyBody
1408         PutClientInServer();
1409 }
1410
1411 void play_countdown(float finished, string samp)
1412 {
1413         if(IS_REAL_CLIENT(self))
1414                 if(floor(finished - time - frametime) != floor(finished - time))
1415                         if(finished - time < 6)
1416                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1417 }
1418
1419 void player_powerups (void)
1420 {
1421         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1422         olditems = self.items;
1423
1424         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1425                 self.modelflags |= MF_ROCKET;
1426         else
1427                 self.modelflags &= ~MF_ROCKET;
1428
1429         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1430
1431         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1432                 return;
1433
1434         Fire_ApplyDamage(self);
1435         Fire_ApplyEffect(self);
1436
1437         if not(g_minstagib)
1438         {
1439                 if (self.items & IT_STRENGTH)
1440                 {
1441                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1442                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1443                         if (time > self.strength_finished)
1444                         {
1445                                 self.items = self.items - (self.items & IT_STRENGTH);
1446                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1447                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (time < self.strength_finished)
1453                         {
1454                                 self.items = self.items | IT_STRENGTH;
1455                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1456                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1457                         }
1458                 }
1459                 if (self.items & IT_INVINCIBLE)
1460                 {
1461                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1462                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1463                         if (time > self.invincible_finished)
1464                         {
1465                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1466                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1468                         }
1469                 }
1470                 else
1471                 {
1472                         if (time < self.invincible_finished)
1473                         {
1474                                 self.items = self.items | IT_INVINCIBLE;
1475                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1476                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1477                         }
1478                 }
1479                 if (self.items & IT_SUPERWEAPON)
1480                 {
1481                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1482                         {
1483                                 self.superweapons_finished = 0;
1484                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1485                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1487                         }
1488                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1489                         {
1490                                 // don't let them run out
1491                         }
1492                         else
1493                         {
1494                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1495                                 if (time > self.superweapons_finished)
1496                                 {
1497                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1498                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1499                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1500                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1501                                 }
1502                         }
1503                 }
1504                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1505                 {
1506                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1507                         {
1508                                 self.items = self.items | IT_SUPERWEAPON;
1509                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1510                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1511                         }
1512                         else
1513                         {
1514                                 self.superweapons_finished = 0;
1515                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1516                         }
1517                 }
1518                 else
1519                 {
1520                         self.superweapons_finished = 0;
1521                 }
1522         }
1523
1524         if(autocvar_g_nodepthtestplayers)
1525                 self.effects = self.effects | EF_NODEPTHTEST;
1526
1527         if(autocvar_g_fullbrightplayers)
1528                 self.effects = self.effects | EF_FULLBRIGHT;
1529
1530         if (time >= game_starttime)
1531         if (time < self.spawnshieldtime)
1532                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1533
1534         MUTATOR_CALLHOOK(PlayerPowerups);
1535 }
1536
1537 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1538 {
1539         if(current > stable)
1540                 return current;
1541         else if(current > stable - 0.25) // when close enough, "snap"
1542                 return stable;
1543         else
1544                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1545 }
1546
1547 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1548 {
1549         if(current < stable)
1550                 return current;
1551         else if(current < stable + 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1555 }
1556
1557 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1558 {
1559         if(current > rotstable)
1560         {
1561                 if(rotframetime > 0)
1562                 {
1563                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1564                         current = max(rotstable, current - rotlinear * rotframetime);
1565                 }
1566         }
1567         else if(current < regenstable)
1568         {
1569                 if(regenframetime > 0)
1570                 {
1571                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1572                         current = min(regenstable, current + regenlinear * regenframetime);
1573                 }
1574         }
1575
1576         if(current > limit)
1577                 current = limit;
1578
1579         return current;
1580 }
1581
1582 void player_regen (void)
1583 {
1584         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1585         maxh = autocvar_g_balance_health_rotstable;
1586         maxa = autocvar_g_balance_armor_rotstable;
1587         maxf = autocvar_g_balance_fuel_rotstable;
1588         minh = autocvar_g_balance_health_regenstable;
1589         mina = autocvar_g_balance_armor_regenstable;
1590         minf = autocvar_g_balance_fuel_regenstable;
1591         limith = autocvar_g_balance_health_limit;
1592         limita = autocvar_g_balance_armor_limit;
1593         limitf = autocvar_g_balance_fuel_limit;
1594
1595         max_mod = regen_mod = rot_mod = limit_mod = 1;
1596
1597         maxh = maxh * max_mod;
1598         //maxa = maxa * max_mod;
1599         //maxf = maxf * max_mod;
1600         minh = minh * max_mod;
1601         //mina = mina * max_mod;
1602         //minf = minf * max_mod;
1603         limith = limith * limit_mod;
1604         limita = limita * limit_mod;
1605         //limitf = limitf * limit_mod;
1606
1607         if(g_ca)
1608                 rot_mod = 0;
1609
1610         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1611         {
1612                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1613                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1614
1615                 // if player rotted to death...  die!
1616                 if(self.health < 1)
1617                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1618         }
1619
1620         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1621                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1622 }
1623
1624 float zoomstate_set;
1625 void SetZoomState(float z)
1626 {
1627         if(z != self.zoomstate)
1628         {
1629                 self.zoomstate = z;
1630                 ClientData_Touch(self);
1631         }
1632         zoomstate_set = 1;
1633 }
1634
1635 void GetPressedKeys(void) {
1636         MUTATOR_CALLHOOK(GetPressedKeys);
1637         if (self.movement_x > 0) // get if movement keys are pressed
1638         {       // forward key pressed
1639                 self.pressedkeys |= KEY_FORWARD;
1640                 self.pressedkeys &= ~KEY_BACKWARD;
1641         }
1642         else if (self.movement_x < 0)
1643         {       // backward key pressed
1644                 self.pressedkeys |= KEY_BACKWARD;
1645                 self.pressedkeys &= ~KEY_FORWARD;
1646         }
1647         else
1648         {       // no x input
1649                 self.pressedkeys &= ~KEY_FORWARD;
1650                 self.pressedkeys &= ~KEY_BACKWARD;
1651         }
1652
1653         if (self.movement_y > 0)
1654         {       // right key pressed
1655                 self.pressedkeys |= KEY_RIGHT;
1656                 self.pressedkeys &= ~KEY_LEFT;
1657         }
1658         else if (self.movement_y < 0)
1659         {       // left key pressed
1660                 self.pressedkeys |= KEY_LEFT;
1661                 self.pressedkeys &= ~KEY_RIGHT;
1662         }
1663         else
1664         {       // no y input
1665                 self.pressedkeys &= ~KEY_RIGHT;
1666                 self.pressedkeys &= ~KEY_LEFT;
1667         }
1668
1669         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1670                 self.pressedkeys |= KEY_JUMP;
1671         else
1672                 self.pressedkeys &= ~KEY_JUMP;
1673         if (self.BUTTON_CROUCH)
1674                 self.pressedkeys |= KEY_CROUCH;
1675         else
1676                 self.pressedkeys &= ~KEY_CROUCH;
1677
1678         if (self.BUTTON_ATCK)
1679                 self.pressedkeys |= KEY_ATCK;
1680         else
1681                 self.pressedkeys &= ~KEY_ATCK;
1682         if (self.BUTTON_ATCK2)
1683                 self.pressedkeys |= KEY_ATCK2;
1684         else
1685                 self.pressedkeys &= ~KEY_ATCK2;
1686 }
1687
1688 /*
1689 ======================
1690 spectate mode routines
1691 ======================
1692 */
1693
1694 void SpectateCopy(entity spectatee) {
1695         other = spectatee;
1696         MUTATOR_CALLHOOK(SpectateCopy);
1697         self.armortype = spectatee.armortype;
1698         self.armorvalue = spectatee.armorvalue;
1699         self.ammo_cells = spectatee.ammo_cells;
1700         self.ammo_shells = spectatee.ammo_shells;
1701         self.ammo_nails = spectatee.ammo_nails;
1702         self.ammo_rockets = spectatee.ammo_rockets;
1703         self.ammo_fuel = spectatee.ammo_fuel;
1704         self.clip_load = spectatee.clip_load;
1705         self.clip_size = spectatee.clip_size;
1706         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1707         self.health = spectatee.health;
1708         self.impulse = 0;
1709         self.items = spectatee.items;
1710         self.last_pickup = spectatee.last_pickup;
1711         self.hit_time = spectatee.hit_time;
1712         self.metertime = spectatee.metertime;
1713         self.strength_finished = spectatee.strength_finished;
1714         self.invincible_finished = spectatee.invincible_finished;
1715         self.pressedkeys = spectatee.pressedkeys;
1716         self.weapons = spectatee.weapons;
1717         self.switchweapon = spectatee.switchweapon;
1718         self.switchingweapon = spectatee.switchingweapon;
1719         self.weapon = spectatee.weapon;
1720         self.nex_charge = spectatee.nex_charge;
1721         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1722         self.hagar_load = spectatee.hagar_load;
1723         self.minelayer_mines = spectatee.minelayer_mines;
1724         self.punchangle = spectatee.punchangle;
1725         self.view_ofs = spectatee.view_ofs;
1726         self.velocity = spectatee.velocity;
1727         self.dmg_take = spectatee.dmg_take;
1728         self.dmg_save = spectatee.dmg_save;
1729         self.dmg_inflictor = spectatee.dmg_inflictor;
1730         self.v_angle = spectatee.v_angle;
1731         self.angles = spectatee.v_angle;
1732         if(!self.BUTTON_USE)
1733                 self.fixangle = TRUE;
1734         setorigin(self, spectatee.origin);
1735         setsize(self, spectatee.mins, spectatee.maxs);
1736         SetZoomState(spectatee.zoomstate);
1737
1738     anticheat_spectatecopy(spectatee);
1739         self.hud = spectatee.hud;
1740         if(spectatee.vehicle)
1741     {
1742         self.fixangle = FALSE;
1743         //self.velocity = spectatee.vehicle.velocity;
1744         self.vehicle_health = spectatee.vehicle_health;
1745         self.vehicle_shield = spectatee.vehicle_shield;
1746         self.vehicle_energy = spectatee.vehicle_energy;
1747         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1748         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1749         self.vehicle_reload1 = spectatee.vehicle_reload1;
1750         self.vehicle_reload2 = spectatee.vehicle_reload2;
1751
1752         msg_entity = self;
1753
1754         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1755             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1756             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1757             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1758
1759         //WriteByte (MSG_ONE, SVC_SETVIEW);
1760         //    WriteEntity(MSG_ONE, self);
1761         //makevectors(spectatee.v_angle);
1762         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1763     }
1764 }
1765
1766 float SpectateUpdate() {
1767         if(!self.enemy)
1768             return 0;
1769
1770         if (self == self.enemy)
1771                 return 0;
1772
1773         if not(IS_PLAYER(self.enemy))
1774                 return 0;
1775
1776         SpectateCopy(self.enemy);
1777
1778         return 1;
1779 }
1780
1781
1782 float SpectateSet()
1783 {
1784         if(self.enemy.classname != "player")
1785                 return FALSE;
1786         /*if(self.enemy.vehicle)
1787         {
1788
1789                 msg_entity = self;
1790                 WriteByte(MSG_ONE, SVC_SETVIEW);
1791                 WriteEntity(MSG_ONE, self.enemy);
1792                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1793
1794                 self.movetype = MOVETYPE_NONE;
1795                 accuracy_resend(self);
1796         }
1797         else
1798         {*/
1799                 msg_entity = self;
1800                 WriteByte(MSG_ONE, SVC_SETVIEW);
1801                 WriteEntity(MSG_ONE, self.enemy);
1802                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1803                 self.movetype = MOVETYPE_NONE;
1804                 accuracy_resend(self);
1805
1806                 if(!SpectateUpdate())
1807                         PutObserverInServer();
1808         //}
1809         return TRUE;
1810 }
1811
1812 float Spectate(entity pl)
1813 {
1814         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1815         if(pl.team != self.team)
1816                 return 0;
1817
1818         self.enemy = pl;
1819         return SpectateSet();
1820 }
1821
1822 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1823 entity CA_SpectateNext(entity start) {
1824         if (start.team == self.team) {
1825                 return start;
1826         }
1827
1828         other = start;
1829         // continue from current player
1830         while(other && other.team != self.team) {
1831                 other = find(other, classname, "player");
1832         }
1833
1834         if (!other) {
1835                 // restart from begining
1836                 other = find(other, classname, "player");
1837                 while(other && other.team != self.team) {
1838                         other = find(other, classname, "player");
1839                 }
1840         }
1841
1842         return other;
1843 }
1844
1845 float SpectateNext()
1846 {
1847         other = find(self.enemy, classname, "player");
1848
1849         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1850                 // CA and ca players when spectating enemies is forbidden
1851                 other = CA_SpectateNext(other);
1852         } else {
1853                 // other modes and ca spectators or spectating enemies is allowed
1854                 if (!other)
1855                         other = find(other, classname, "player");
1856         }
1857
1858         if (other)
1859                 self.enemy = other;
1860
1861         return SpectateSet();
1862 }
1863
1864 float SpectatePrev()
1865 {
1866         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1867         other = findchain(classname, "player");
1868         if not(other) // no player
1869                 return FALSE;
1870
1871         entity first = other;
1872         // skip players until current spectated player
1873         if(self.enemy)
1874         while(other && other != self.enemy)
1875                 other = other.chain;
1876
1877         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1878         {
1879                 do { other = other.chain; }
1880                 while(other && other.team != self.team);
1881
1882                 if not(other)
1883                 {
1884                         other = first;
1885                         while(other.team != self.team)
1886                                 other = other.chain;
1887                         if(other == self.enemy)
1888                                 return TRUE;
1889                 }
1890         }
1891         else
1892         {
1893                 if(other.chain)
1894                         other = other.chain;
1895                 else
1896                         other = first;
1897         }
1898         self.enemy = other;
1899         return SpectateSet();
1900 }
1901
1902 /*
1903 =============
1904 ShowRespawnCountdown()
1905
1906 Update a respawn countdown display.
1907 =============
1908 */
1909 void ShowRespawnCountdown()
1910 {
1911         float number;
1912         if(self.deadflag == DEAD_NO) // just respawned?
1913                 return;
1914         else
1915         {
1916                 number = ceil(self.respawn_time - time);
1917                 if(number <= 0)
1918                         return;
1919                 if(number <= self.respawn_countdown)
1920                 {
1921                         self.respawn_countdown = number - 1;
1922                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1923                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1924                 }
1925         }
1926 }
1927
1928 void LeaveSpectatorMode()
1929 {
1930         if(self.caplayer)
1931                 return;
1932         if(nJoinAllowed(self))
1933         {
1934                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1935                 {
1936                         self.classname = "player";
1937
1938                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1939                                 { JoinBestTeam(self, FALSE, TRUE); }
1940
1941                         if(autocvar_g_campaign)
1942                                 { campaign_bots_may_start = 1; }
1943
1944                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1945
1946                         PutClientInServer();
1947
1948                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1949                 }
1950                 else
1951                         stuffcmd(self, "menu_showteamselect\n");
1952         }
1953         else
1954         {
1955                 // Player may not join because g_maxplayers is set
1956                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1957         }
1958 }
1959
1960 /**
1961  * Determines whether the player is allowed to join. This depends on cvar
1962  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1963  * it checks whether the number of currently playing players exceeds g_maxplayers.
1964  * @return int number of free slots for players, 0 if none
1965  */
1966 float nJoinAllowed(entity ignore) {
1967         if(!ignore)
1968         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1969         // so report 0 free slots if restricted
1970         {
1971                 if(autocvar_g_forced_team_otherwise == "spectate")
1972                         return 0;
1973                 if(autocvar_g_forced_team_otherwise == "spectator")
1974                         return 0;
1975         }
1976
1977         if(self.team_forced < 0)
1978                 return 0; // forced spectators can never join
1979
1980         // TODO simplify this
1981         entity e;
1982         float totalClients = 0;
1983         FOR_EACH_CLIENT(e)
1984                 if(e != ignore)
1985                         totalClients += 1;
1986
1987         if (!autocvar_g_maxplayers)
1988                 return maxclients - totalClients;
1989
1990         float currentlyPlaying = 0;
1991         FOR_EACH_REALCLIENT(e)
1992                 if(IS_PLAYER(e) || e.caplayer == 1)
1993                         currentlyPlaying += 1;
1994
1995         if(currentlyPlaying < autocvar_g_maxplayers)
1996                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1997
1998         return 0;
1999 }
2000
2001 /**
2002  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2003  * g_maxplayers_spectator_blocktime seconds
2004  */
2005 void checkSpectatorBlock() {
2006         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2007                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2008                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2009                         dropclient(self);
2010                 }
2011         }
2012 }
2013
2014 void PrintWelcomeMessage()
2015 {
2016         if(self.motd_actived_time == 0)
2017         {
2018                 if (autocvar_g_campaign) {
2019                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2020                                 self.motd_actived_time = time;
2021                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2022                         }
2023                 } else {
2024                         if (self.BUTTON_INFO) {
2025                                 self.motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2027                         }
2028                 }
2029         }
2030         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if (self.BUTTON_INFO)
2034                                 self.motd_actived_time = time;
2035                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2036                                 self.motd_actived_time = 0;
2037                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                         }
2039                 } else {
2040                         if (self.BUTTON_INFO)
2041                                 self.motd_actived_time = time;
2042                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2043                                 self.motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2045                         }
2046                 }
2047         }
2048         else //if(self.motd_actived_time < 0) // just connected, motd is active
2049         {
2050                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2051                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2052                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2053                 {
2054                         // instanctly hide MOTD
2055                         self.motd_actived_time = 0;
2056                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2057                 }
2058         }
2059 }
2060
2061 void ObserverThink()
2062 {
2063         float prefered_movetype;
2064         if (self.flags & FL_JUMPRELEASED) {
2065                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2066                         self.flags &= ~FL_JUMPRELEASED;
2067                         self.flags |= FL_SPAWNING;
2068                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2069                         self.flags &= ~FL_JUMPRELEASED;
2070                         if(SpectateNext()) {
2071                                 self.classname = "spectator";
2072                         }
2073                 } else {
2074                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2075                         if (self.movetype != prefered_movetype)
2076                                 self.movetype = prefered_movetype;
2077                 }
2078         } else {
2079                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2080                         self.flags |= FL_JUMPRELEASED;
2081                         if(self.flags & FL_SPAWNING)
2082                         {
2083                                 self.flags &= ~FL_SPAWNING;
2084                                 LeaveSpectatorMode();
2085                                 return;
2086                         }
2087                 }
2088         }
2089 }
2090
2091 void SpectatorThink()
2092 {
2093         if (self.flags & FL_JUMPRELEASED) {
2094                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         self.flags |= FL_SPAWNING;
2097                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectateNext()) {
2100                                 self.classname = "spectator";
2101                         } else {
2102                                 self.classname = "observer";
2103                                 PutClientInServer();
2104                         }
2105                         self.impulse = 0;
2106                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2107                         self.flags &= ~FL_JUMPRELEASED;
2108                         if(SpectatePrev()) {
2109                                 self.classname = "spectator";
2110                         } else {
2111                                 self.classname = "observer";
2112                                 PutClientInServer();
2113                         }
2114                         self.impulse = 0;
2115                 } else if (self.BUTTON_ATCK2) {
2116                         self.flags &= ~FL_JUMPRELEASED;
2117                         self.classname = "observer";
2118                         PutClientInServer();
2119                 } else {
2120                         if(!SpectateUpdate())
2121                                 PutObserverInServer();
2122                 }
2123         } else {
2124                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2125                         self.flags |= FL_JUMPRELEASED;
2126                         if(self.flags & FL_SPAWNING)
2127                         {
2128                                 self.flags &= ~FL_SPAWNING;
2129                                 LeaveSpectatorMode();
2130                                 return;
2131                         }
2132                 }
2133                 if(!SpectateUpdate())
2134                         PutObserverInServer();
2135         }
2136
2137         self.flags |= FL_CLIENT | FL_NOTARGET;
2138 }
2139
2140 void PlayerUseKey()
2141 {
2142         if not(IS_PLAYER(self))
2143                 return;
2144
2145         if(self.vehicle)
2146         {
2147         vehicles_exit(VHEF_NORMAL);
2148         return;
2149         }
2150
2151         // a use key was pressed; call handlers
2152         MUTATOR_CALLHOOK(PlayerUseKey);
2153 }
2154
2155 /*
2156 =============
2157 PlayerPreThink
2158
2159 Called every frame for each client before the physics are run
2160 =============
2161 */
2162 .float usekeypressed;
2163 void() nexball_setstatus;
2164 .float items_added;
2165 void PlayerPreThink (void)
2166 {
2167         WarpZone_PlayerPhysics_FixVAngle();
2168
2169         self.stat_game_starttime = game_starttime;
2170         self.stat_round_starttime = round_starttime;
2171         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2172         self.stat_leadlimit = autocvar_leadlimit;
2173
2174         if(frametime)
2175         {
2176                 // physics frames: update anticheat stuff
2177                 anticheat_prethink();
2178         }
2179
2180         if(blockSpectators && frametime)
2181                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2182                 checkSpectatorBlock();
2183
2184         zoomstate_set = 0;
2185
2186         if(self.netname_previous != self.netname)
2187         {
2188                 if(autocvar_sv_eventlog)
2189                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2190                 if(self.netname_previous)
2191                         strunzone(self.netname_previous);
2192                 self.netname_previous = strzone(self.netname);
2193         }
2194
2195         // version nagging
2196         if(self.version_nagtime)
2197                 if(self.cvar_g_xonoticversion)
2198                         if(time > self.version_nagtime)
2199                         {
2200                                 // don't notify git users
2201                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2202                                 {
2203                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2204                                         {
2205                                                 // notify release users if connecting to git
2206                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2207                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2208                                         }
2209                                         else
2210                                         {
2211                                                 float r;
2212                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2213                                                 if(r < 0)
2214                                                 {
2215                                                         // give users new version
2216                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2217                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2218                                                 }
2219                                                 else if(r > 0)
2220                                                 {
2221                                                         // notify users about old server version
2222                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2223                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2224                                                 }
2225                                         }
2226                                 }
2227                                 self.version_nagtime = 0;
2228                         }
2229
2230         // GOD MODE info
2231         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2232         {
2233                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2234                 self.max_armorvalue = 0;
2235         }
2236
2237 #ifdef TETRIS
2238         if (TetrisPreFrame())
2239                 return;
2240 #endif
2241
2242         MUTATOR_CALLHOOK(PlayerPreThink);
2243
2244         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2245         {
2246                 if(self.BUTTON_USE && !self.usekeypressed)
2247                         PlayerUseKey();
2248                 self.usekeypressed = self.BUTTON_USE;
2249         }
2250
2251         if(IS_REAL_CLIENT(self))
2252                 PrintWelcomeMessage();
2253
2254         if(IS_PLAYER(self))
2255         {
2256
2257                 CheckRules_Player();
2258
2259                 if (intermission_running)
2260                 {
2261                         IntermissionThink ();   // otherwise a button could be missed between
2262                         return;                                 // the think tics
2263                 }
2264
2265                 //don't allow the player to turn around while game is paused!
2266                 if(timeout_status == TIMEOUT_ACTIVE) {
2267                         // FIXME turn this into CSQC stuff
2268                         self.v_angle = self.lastV_angle;
2269                         self.angles = self.lastV_angle;
2270                         self.fixangle = TRUE;
2271                 }
2272
2273                 if(frametime)
2274                 {
2275                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2276                         {
2277                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2278                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2279                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2280
2281                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2282                                 {
2283                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2284                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2285                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2286                                 }
2287                         }
2288                         else
2289                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2290
2291                         player_powerups();
2292                 }
2293
2294                 if (self.deadflag != DEAD_NO)
2295                 {
2296                         if(self.personal && g_race_qualifying)
2297                         {
2298                                 if(time > self.respawn_time)
2299                                 {
2300                                         self.respawn_time = time + 1; // only retry once a second
2301                                         self.stat_respawn_time = self.respawn_time;
2302                                         respawn();
2303                                         self.impulse = 141;
2304                                 }
2305                         }
2306                         else
2307                         {
2308                                 float button_pressed;
2309                                 if(frametime)
2310                                         player_anim();
2311                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2312
2313                                 if (self.deadflag == DEAD_DYING)
2314                                 {
2315                                         if(self.respawn_flags & RESPAWN_FORCE)
2316                                                 self.deadflag = DEAD_RESPAWNING;
2317                                         else if(!button_pressed)
2318                                                 self.deadflag = DEAD_DEAD;
2319                                 }
2320                                 else if (self.deadflag == DEAD_DEAD)
2321                                 {
2322                                         if(button_pressed)
2323                                                 self.deadflag = DEAD_RESPAWNABLE;
2324                                 }
2325                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2326                                 {
2327                                         if(!button_pressed)
2328                                                 self.deadflag = DEAD_RESPAWNING;
2329                                 }
2330                                 else if (self.deadflag == DEAD_RESPAWNING)
2331                                 {
2332                                         if(time > self.respawn_time)
2333                                         {
2334                                                 self.respawn_time = time + 1; // only retry once a second
2335                                                 respawn();
2336                                         }
2337                                 }
2338
2339                                 ShowRespawnCountdown();
2340
2341                                 if(self.respawn_flags & RESPAWN_SILENT)
2342                                         self.stat_respawn_time = 0;
2343                                 else
2344                                         self.stat_respawn_time = self.respawn_time;
2345                         }
2346
2347                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2348                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2349                                 self.stat_respawn_time *= -1;
2350
2351                         return;
2352                 }
2353
2354                 self.prevorigin = self.origin;
2355
2356                 float do_crouch = self.BUTTON_CROUCH;
2357                 if(self.hook.state)
2358                         do_crouch = 0;
2359                 if(self.vehicle)
2360                         do_crouch = 0;
2361                 if(self.freezetag_frozen)
2362                         do_crouch = 0;
2363                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2364                         do_crouch = 0;
2365
2366                 if (do_crouch)
2367                 {
2368                         if (!self.crouch)
2369                         {
2370                                 self.crouch = TRUE;
2371                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2372                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2373                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2374                         }
2375                 }
2376                 else
2377                 {
2378                         if (self.crouch)
2379                         {
2380                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2381                                 if (!trace_startsolid)
2382                                 {
2383                                         self.crouch = FALSE;
2384                                         self.view_ofs = PL_VIEW_OFS;
2385                                         setsize (self, PL_MIN, PL_MAX);
2386                                 }
2387                         }
2388                 }
2389
2390                 FixPlayermodel();
2391
2392                 GrapplingHookFrame();
2393
2394                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2395                 //if(frametime)
2396                 {
2397                         self.items &= ~self.items_added;
2398
2399                         W_WeaponFrame();
2400
2401                         self.items_added = 0;
2402                         if(self.items & IT_JETPACK)
2403                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2404                                         self.items_added |= IT_FUEL;
2405
2406                         self.items |= self.items_added;
2407                 }
2408
2409                 player_regen();
2410
2411                 // rot nex charge to the charge limit
2412                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2413                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2414
2415                 if(frametime)
2416                         player_anim();
2417
2418                 // secret status
2419                 secrets_setstatus();
2420
2421                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2422
2423                 //self.angles_y=self.v_angle_y + 90;   // temp
2424         } else if(gameover) {
2425                 if (intermission_running)
2426                         IntermissionThink ();   // otherwise a button could be missed between
2427                 return;
2428         } else if(IS_OBSERVER(self)) {
2429                 ObserverThink();
2430         } else if(IS_SPEC(self)) {
2431                 SpectatorThink();
2432         }
2433
2434         if(!zoomstate_set)
2435                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2436
2437         float oldspectatee_status;
2438         oldspectatee_status = self.spectatee_status;
2439         if(IS_SPEC(self))
2440                 self.spectatee_status = num_for_edict(self.enemy);
2441         else if(IS_OBSERVER(self))
2442                 self.spectatee_status = num_for_edict(self);
2443         else
2444                 self.spectatee_status = 0;
2445         if(self.spectatee_status != oldspectatee_status)
2446         {
2447                 ClientData_Touch(self);
2448                 if(g_race || g_cts)
2449                         race_InitSpectator();
2450         }
2451
2452         if(self.teamkill_soundtime)
2453         if(time > self.teamkill_soundtime)
2454         {
2455                 self.teamkill_soundtime = 0;
2456
2457                 entity oldpusher, oldself;
2458
2459                 oldself = self; self = self.teamkill_soundsource;
2460                 oldpusher = self.pusher; self.pusher = oldself;
2461
2462                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2463
2464                 self.pusher = oldpusher;
2465                 self = oldself;
2466         }
2467
2468         if(self.taunt_soundtime)
2469         if(time > self.taunt_soundtime)
2470         {
2471                 self.taunt_soundtime = 0;
2472                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2473         }
2474
2475         target_voicescript_next(self);
2476
2477         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2478         if(!self.weapon)
2479                 self.clip_load = self.clip_size = 0;
2480 }
2481
2482 float isInvisibleString(string s)
2483 {
2484         float i, n, c;
2485         s = strdecolorize(s);
2486         for((i = 0), (n = strlen(s)); i < n; ++i)
2487         {
2488                 c = str2chr(s, i);
2489                 switch(c)
2490                 {
2491                         case 0:
2492                         case 32: // space
2493                                 break;
2494                         case 192: // charmap space
2495                                 if (!autocvar_utf8_enable)
2496                                         break;
2497                                 return FALSE;
2498                         case 160: // space in unicode fonts
2499                         case 0xE000 + 192: // utf8 charmap space
2500                                 if (autocvar_utf8_enable)
2501                                         break;
2502                         default:
2503                                 return FALSE;
2504                 }
2505         }
2506         return TRUE;
2507 }
2508
2509 /*
2510 =============
2511 PlayerPostThink
2512
2513 Called every frame for each client after the physics are run
2514 =============
2515 */
2516 .float idlekick_lasttimeleft;
2517 void PlayerPostThink (void)
2518 {
2519         // Savage: Check for nameless players
2520         if (isInvisibleString(self.netname)) {
2521                 self.netname = "Player";
2522                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2523         }
2524
2525         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2526         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2527         {
2528                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2529                 {
2530                         if(self.idlekick_lasttimeleft)
2531                         {
2532                                 self.idlekick_lasttimeleft = 0;
2533                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2534                         }
2535                 }
2536                 else
2537                 {
2538                         float timeleft;
2539                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2540                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2541                         {
2542                                 if(!self.idlekick_lasttimeleft)
2543                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2544                         }
2545                         if(timeleft <= 0)
2546                         {
2547                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2548                                 dropclient(self);
2549                                 return;
2550                         }
2551                         else if(timeleft <= 10)
2552                         {
2553                                 if(timeleft != self.idlekick_lasttimeleft)
2554                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2555                                 self.idlekick_lasttimeleft = timeleft;
2556                         }
2557                 }
2558         }
2559
2560 #ifdef TETRIS
2561         if(self.impulse == 100)
2562                 ImpulseCommands();
2563         if (!TetrisPostFrame())
2564         {
2565 #endif
2566
2567         CheatFrame();
2568
2569         //CheckPlayerJump();
2570
2571         if(IS_PLAYER(self)) {
2572                 CheckRules_Player();
2573                 UpdateChatBubble();
2574                 if (self.impulse)
2575                         ImpulseCommands();
2576                 if (intermission_running)
2577                         return;         // intermission or finale
2578                 GetPressedKeys();
2579         }
2580
2581 #ifdef TETRIS
2582         }
2583 #endif
2584
2585         /*
2586         float i;
2587         for(i = 0; i < 1000; ++i)
2588         {
2589                 vector end;
2590                 end = self.origin + '0 0 1024' + 512 * randomvec();
2591                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2592                 if(trace_fraction < 1)
2593                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2594                 {
2595                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2596                         break;
2597                 }
2598         }
2599         */
2600
2601         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2602
2603         if(self.waypointsprite_attachedforcarrier)
2604                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2605
2606         playerdemo_write();
2607
2608         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2609         {
2610                 if not(self.stored_netname)
2611                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2612                 if(self.stored_netname != self.netname)
2613                 {
2614                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2615                         strunzone(self.stored_netname);
2616                         self.stored_netname = strzone(self.netname);
2617                 }
2618         }
2619
2620         /*
2621         if(g_race)
2622                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2623         */
2624
2625         CSQCMODEL_AUTOUPDATE();
2626 }