qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         float teamcheck;
 321         entity firstspot_new;
 322         entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.damagedbycontents = FALSE;
 666         self.health = -666;
 667         self.takedamage = DAMAGE_NO;
 668         self.solid = SOLID_NOT;
 669         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 670         self.flags = FL_CLIENT | FL_NOTARGET;
 671         self.armorvalue = 666;
 672         self.effects = 0;
 673         self.armorvalue = autocvar_g_balance_armor_start;
 674         self.pauserotarmor_finished = 0;
 675         self.pauserothealth_finished = 0;
 676         self.pauseregen_finished = 0;
 677         self.damageforcescale = 0;
 678         self.death_time = 0;
 679         self.dead_frame = 0;
 680         self.alpha = 0;
 681         self.scale = 0;
 682         self.fade_time = 0;
 683         self.pain_frame = 0;
 684         self.pain_finished = 0;
 685         self.strength_finished = 0;
 686         self.invincible_finished = 0;
 687         self.pushltime = 0;
 688         self.think = SUB_Null;
 689         self.nextthink = 0;
 690         self.hook_time = 0;
 691         self.runes = 0;
 692         self.deadflag = DEAD_NO;
 693         self.angles = spot.angles;
 694         self.angles_z = 0;
 695         self.fixangle = TRUE;
 696         self.crouch = FALSE;
 697
 698         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 699         setorigin (self, spot.origin);
 700         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 701         self.prevorigin = self.origin;
 702         self.items = 0;
 703         self.weapons = 0;
 704         self.model = "";
 705         FixPlayermodel();
 706         self.model = "";
 707         self.modelindex = 0;
 708         self.weapon = 0;
 709         self.weaponname = "";
 710         self.switchingweapon = 0;
 711         self.weaponmodel = "";
 712         self.weaponentity = world;
 713         self.exteriorweaponentity = world;
 714         self.killcount = -666;
 715         self.velocity = '0 0 0';
 716         self.avelocity = '0 0 0';
 717         self.punchangle = '0 0 0';
 718         self.punchvector = '0 0 0';
 719         self.oldvelocity = self.velocity;
 720         self.fire_endtime = -1;
 721
 722         if(sv_loddistance1)
 723                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 724
 725         if(g_arena)
 726         {
 727                 if(self.version_mismatch)
 728                 {
 729                         Spawnqueue_Unmark(self);
 730                         Spawnqueue_Remove(self);
 731                 }
 732                 else
 733                 {
 734                         Spawnqueue_Insert(self);
 735                 }
 736         }
 737         else if(g_lms)
 738         {
 739                 // Only if the player cannot play at all
 740                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 741                         self.frags = FRAGS_SPECTATOR;
 742                 else
 743                         self.frags = FRAGS_LMS_LOSER;
 744         }
 745         else if(g_ca)
 746         {
 747                 if(self.caplayer)
 748                         self.frags = FRAGS_LMS_LOSER;
 749                 else
 750                         self.frags = FRAGS_SPECTATOR;
 751         }
 752         else
 753                 self.frags = FRAGS_SPECTATOR;
 754 }
 755
 756 void FixPlayermodel()
 757 {
 758         string defaultmodel;
 759         float defaultskin, chmdl, oldskin;
 760         vector m1, m2;
 761
 762         defaultmodel = "";
 763
 764         if(autocvar_sv_defaultcharacter == 1) {
 765                 defaultskin = 0;
 766
 767                 if(teamplay)
 768                 {
 769                         string s;
 770                         s = Team_ColorNameLowerCase(self.team);
 771                         if(s != "neutral")
 772                         {
 773                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 774                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 775                         }
 776                 }
 777
 778                 if(defaultmodel == "")
 779                 {
 780                         defaultmodel = autocvar_sv_defaultplayermodel;
 781                         defaultskin = autocvar_sv_defaultplayerskin;
 782                 }
 783         }
 784
 785         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 786         {
 787                 if(self.model != "")
 788                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 789                 self.model = ""; // force the != checks to return true
 790         }
 791
 792         if(defaultmodel != "")
 793         {
 794                 if (defaultmodel != self.model)
 795                 {
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, defaultmodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = defaultskin;
 805         } else {
 806                 if (self.playermodel != self.model || self.playermodel == "")
 807                 {
 808                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 809                         m1 = self.mins;
 810                         m2 = self.maxs;
 811                         setmodel_lod (self, self.playermodel);
 812                         setsize (self, m1, m2);
 813                         chmdl = TRUE;
 814                 }
 815
 816                 oldskin = self.skinindex;
 817                 self.skinindex = stof(self.playerskin);
 818         }
 819
 820         if(chmdl || oldskin != self.skinindex)
 821                 self.species = player_getspecies(); // model or skin has changed
 822
 823         if(!teamplay)
 824                 if(strlen(autocvar_sv_defaultplayercolors))
 825                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 826                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 827 }
 828
 829 void PlayerTouchExplode(entity p1, entity p2)
 830 {
 831         vector org;
 832         org = (p1.origin + p2.origin) * 0.5;
 833         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 834
 835         te_explosion(org);
 836
 837         entity e;
 838         e = spawn();
 839         setorigin(e, org);
 840         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 841         remove(e);
 842 }
 843
 844 /*
 845 =============
 846 PutClientInServer
 847
 848 Called when a client spawns in the server
 849 =============
 850 */
 851 //void() ctf_playerchanged;
 852 void PutClientInServer (void)
 853 {
 854         if(clienttype(self) == CLIENTTYPE_BOT)
 855         {
 856                 self.classname = "player";
 857         }
 858         else if(clienttype(self) == CLIENTTYPE_REAL)
 859         {
 860                 msg_entity = self;
 861                 WriteByte(MSG_ONE, SVC_SETVIEW);
 862                 WriteEntity(MSG_ONE, self);
 863         }
 864
 865         // reset player keys
 866         self.itemkeys = 0;
 867
 868         // player is dead and becomes observer
 869         // FIXME fix LMS scoring for new system
 870         if(g_lms)
 871         {
 872                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 873                         self.classname = "observer";
 874         }
 875
 876         if(g_arena || (g_ca && !allowed_to_spawn))
 877         if(!self.spawned)
 878                 self.classname = "observer";
 879
 880         if(gameover)
 881                 self.classname = "observer";
 882
 883         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 884                 entity spot, oldself;
 885                 float j;
 886
 887                 accuracy_resend(self);
 888
 889                 if(self.team < 0)
 890                         JoinBestTeam(self, FALSE, TRUE);
 891
 892                 race_PreSpawn();
 893
 894                 spot = SelectSpawnPoint (FALSE);
 895                 if(!spot)
 896                 {
 897                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 898                         return; // spawn failed
 899                 }
 900
 901                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 902
 903                 self.classname = "player";
 904                 self.wasplayer = TRUE;
 905                 self.iscreature = TRUE;
 906                 self.damagedbycontents = TRUE;
 907                 self.movetype = MOVETYPE_WALK;
 908                 self.solid = SOLID_SLIDEBOX;
 909                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 910                 if(autocvar_g_playerclip_collisions)
 911                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 912                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 913                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 914                 self.frags = FRAGS_PLAYER;
 915                 if(INDEPENDENT_PLAYERS)
 916                         MAKE_INDEPENDENT_PLAYER(self);
 917                 self.flags = FL_CLIENT;
 918                 if(autocvar__notarget)
 919                         self.flags |= FL_NOTARGET;
 920                 self.takedamage = DAMAGE_AIM;
 921                 if(g_minstagib)
 922                         self.effects = EF_FULLBRIGHT;
 923                 else
 924                         self.effects = 0;
 925                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 926                 self.air_finished = time + 12;
 927                 self.dmg = 2;
 928                 if(autocvar_g_balance_nex_charge)
 929                 {
 930                         if(autocvar_g_balance_nex_secondary_chargepool)
 931                                 self.nex_chargepool_ammo = 1;
 932                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 933                 }
 934
 935                 if(inWarmupStage)
 936                 {
 937                         self.ammo_shells = warmup_start_ammo_shells;
 938                         self.ammo_nails = warmup_start_ammo_nails;
 939                         self.ammo_rockets = warmup_start_ammo_rockets;
 940                         self.ammo_cells = warmup_start_ammo_cells;
 941                         self.ammo_fuel = warmup_start_ammo_fuel;
 942                         self.health = warmup_start_health;
 943                         self.armorvalue = warmup_start_armorvalue;
 944                         self.weapons = warmup_start_weapons;
 945                 }
 946                 else
 947                 {
 948                         self.ammo_shells = start_ammo_shells;
 949                         self.ammo_nails = start_ammo_nails;
 950                         self.ammo_rockets = start_ammo_rockets;
 951                         self.ammo_cells = start_ammo_cells;
 952                         self.ammo_fuel = start_ammo_fuel;
 953                         self.health = start_health;
 954                         self.armorvalue = start_armorvalue;
 955                         self.weapons = start_weapons;
 956                 }
 957
 958                 if(g_weaponarena_random)
 959                 {
 960                         if(g_weaponarena_random_with_laser)
 961                                 self.weapons &~= WEPBIT_LASER;
 962                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 963                         if(g_weaponarena_random_with_laser)
 964                                 self.weapons |= WEPBIT_LASER;
 965                 }
 966
 967                 self.items = start_items;
 968                 self.jump_interval = time;
 969
 970                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 971                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 972                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 973                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 974                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 975                 //extend the pause of rotting if client was reset at the beginning of the countdown
 976                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 977                         self.spawnshieldtime += game_starttime - time;
 978                         self.pauserotarmor_finished += game_starttime - time;
 979                         self.pauserothealth_finished += game_starttime - time;
 980                         self.pauseregen_finished += game_starttime - time;
 981                 }
 982                 self.damageforcescale = 2;
 983                 self.death_time = 0;
 984                 self.dead_frame = 0;
 985                 self.alpha = 0;
 986                 self.scale = 0;
 987                 self.fade_time = 0;
 988                 self.pain_frame = 0;
 989                 self.pain_finished = 0;
 990                 self.strength_finished = 0;
 991                 self.invincible_finished = 0;
 992                 self.pushltime = 0;
 993                 // players have no think function
 994                 self.think = SUB_Null;
 995                 self.nextthink = 0;
 996                 self.hook_time = 0;
 997                 self.dmg_team = 0;
 998                 self.ballistics_density = autocvar_g_ballistics_density_player;
 999
1000                 self.metertime = 0;
1001
1002                 self.runes = 0;
1003
1004                 self.deadflag = DEAD_NO;
1005
1006                 self.angles = spot.angles;
1007
1008                 self.angles_z = 0; // never spawn tilted even if the spot says to
1009                 self.fixangle = TRUE; // turn this way immediately
1010                 self.velocity = '0 0 0';
1011                 self.avelocity = '0 0 0';
1012                 self.punchangle = '0 0 0';
1013                 self.punchvector = '0 0 0';
1014                 self.oldvelocity = self.velocity;
1015                 self.fire_endtime = -1;
1016
1017                 msg_entity = self;
1018                 WRITESPECTATABLE_MSG_ONE({
1019                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1020                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1021                 });
1022
1023                 if(sv_loddistance1)
1024                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1025
1026                 self.model = "";
1027                 FixPlayermodel();
1028
1029                 self.crouch = FALSE;
1030                 self.view_ofs = PL_VIEW_OFS;
1031                 setsize (self, PL_MIN, PL_MAX);
1032                 self.spawnorigin = spot.origin;
1033                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1034                 // don't reset back to last position, even if new position is stuck in solid
1035                 self.oldorigin = self.origin;
1036                 self.prevorigin = self.origin;
1037                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1038                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1039         self.hud = HUD_NORMAL;
1040
1041                 if(g_arena)
1042                 {
1043                         Spawnqueue_Remove(self);
1044                         Spawnqueue_Mark(self);
1045                 }
1046
1047                 else if(g_ca)
1048                         self.caplayer = 1;
1049
1050                 self.event_damage = PlayerDamage;
1051
1052                 self.bot_attack = TRUE;
1053
1054                 self.statdraintime = time + 5;
1055                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1056
1057                 if(self.killcount == -666) {
1058                         PlayerScore_Clear(self);
1059                         self.killcount = 0;
1060                 }
1061
1062                 CL_SpawnWeaponentity();
1063                 self.alpha = default_player_alpha;
1064                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1065                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1066
1067                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1068                 self.lms_traveled_distance = 0;
1069                 self.speedrunning = FALSE;
1070
1071                 race_PostSpawn(spot);
1072
1073                 if(autocvar_spawn_debug)
1074                 {
1075                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1076                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1077                 }
1078
1079                 //stuffcmd(self, "chase_active 0");
1080                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1081
1082                 if (autocvar_g_spawnsound)
1083                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1084
1085                 if(g_assault) {
1086                         if(self.team == assault_attacker_team)
1087                                 centerprint(self, "You are attacking!");
1088                         else
1089                                 centerprint(self, "You are defending!");
1090                 }
1091
1092                 target_voicescript_clear(self);
1093
1094                 // reset fields the weapons may use
1095                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1096                 {
1097                         weapon_action(j, WR_RESETPLAYER);
1098
1099                         // all weapons must be fully loaded when we spawn
1100                         entity e;
1101                         e = get_weaponinfo(j);
1102                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1103                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1104                 }
1105
1106                 oldself = self;
1107                 self = spot;
1108                         activator = oldself;
1109                                 string s;
1110                                 s = self.target;
1111                                 self.target = string_null;
1112                                 SUB_UseTargets();
1113                                 self.target = s;
1114                         activator = world;
1115                 self = oldself;
1116
1117                 MUTATOR_CALLHOOK(PlayerSpawn);
1118
1119                 self.switchweapon = w_getbestweapon(self);
1120                 self.cnt = -1; // W_LastWeapon will not complain
1121                 self.weapon = 0;
1122                 self.weaponname = "";
1123                 self.switchingweapon = 0;
1124
1125                 if(!self.alivetime)
1126                         self.alivetime = time;
1127         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1128                 PutObserverInServer ();
1129         }
1130
1131         //if(g_ctf)
1132         //      ctf_playerchanged();
1133 }
1134
1135 .float ebouncefactor, ebouncestop; // electro's values
1136 // TODO do we need all these fields, or should we stop autodetecting runtime
1137 // changes and just have a console command to update this?
1138 float ClientInit_SendEntity(entity to, float sf)
1139 {
1140         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1141         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1145         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1146         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1147         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1148         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1149         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1150         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1151         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1152         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1153         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1154         if(sv_foginterval && world.fog != "")
1155                 WriteString(MSG_ENTITY, world.fog);
1156         else
1157                 WriteString(MSG_ENTITY, "");
1158         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1159         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1160         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1161         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1162         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1163         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1164         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1165         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1166         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1167         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1168         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1169         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1170         return TRUE;
1171 }
1172
1173 void ClientInit_CheckUpdate()
1174 {
1175         self.nextthink = time;
1176         if(self.count != autocvar_g_balance_armor_blockpercent)
1177         {
1178                 self.count = autocvar_g_balance_armor_blockpercent;
1179                 self.SendFlags |= 1;
1180         }
1181         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1182         {
1183                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1184                 self.SendFlags |= 1;
1185         }
1186         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1187         {
1188                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1189                 self.SendFlags |= 1;
1190         }
1191         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1192         {
1193                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1194                 self.SendFlags |= 1;
1195         }
1196         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1197         {
1198                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1199                 self.SendFlags |= 1;
1200         }
1201         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1202         {
1203                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1204                 self.SendFlags |= 1;
1205         }
1206 }
1207
1208 void ClientInit_Spawn()
1209 {
1210         entity o;
1211         entity e;
1212         e = spawn();
1213         e.classname = "clientinit";
1214         e.think = ClientInit_CheckUpdate;
1215         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1216
1217         o = self;
1218         self = e;
1219         ClientInit_CheckUpdate();
1220         self = o;
1221 }
1222
1223 /*
1224 =============
1225 SetNewParms
1226 =============
1227 */
1228 void SetNewParms (void)
1229 {
1230         // initialize parms for a new player
1231         parm1 = -(86400 * 366);
1232 }
1233
1234 /*
1235 =============
1236 SetChangeParms
1237 =============
1238 */
1239 void SetChangeParms (void)
1240 {
1241         // save parms for level change
1242         parm1 = self.parm_idlesince - time;
1243 }
1244
1245 /*
1246 =============
1247 DecodeLevelParms
1248 =============
1249 */
1250 void DecodeLevelParms (void)
1251 {
1252         // load parms
1253         self.parm_idlesince = parm1;
1254         if(self.parm_idlesince == -(86400 * 366))
1255                 self.parm_idlesince = time;
1256
1257         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1258         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1259 }
1260
1261 /*
1262 =============
1263 ClientKill
1264
1265 Called when a client types 'kill' in the console
1266 =============
1267 */
1268
1269 .float clientkill_nexttime;
1270 void ClientKill_Now_TeamChange()
1271 {
1272         if(self.killindicator_teamchange == -1)
1273         {
1274                 self.team = -1;
1275                 JoinBestTeam( self, FALSE, FALSE );
1276         }
1277         else if(self.killindicator_teamchange == -2)
1278         {
1279                 if(g_ca)
1280                         self.caplayer = 0;
1281                 if(blockSpectators)
1282                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1283                 PutObserverInServer();
1284         }
1285         else
1286                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1287 }
1288
1289 void ClientKill_Now()
1290 {
1291         if(self.vehicle)
1292         {
1293             vehicles_exit(VHEF_RELESE);
1294             if(!self.killindicator_teamchange)
1295             {
1296             self.vehicle_health = -1;
1297             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1298             }
1299         }
1300
1301         if(self.killindicator && !wasfreed(self.killindicator))
1302                 remove(self.killindicator);
1303
1304         self.killindicator = world;
1305
1306         if(self.killindicator_teamchange)
1307                 ClientKill_Now_TeamChange();
1308
1309         // in any case:
1310         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1311
1312         // now I am sure the player IS dead
1313 }
1314 void KillIndicator_Think()
1315 {
1316         if (gameover)
1317         {
1318                 self.owner.killindicator = world;
1319                 remove(self);
1320                 return;
1321         }
1322
1323         if (!self.owner.modelindex)
1324         {
1325                 self.owner.killindicator = world;
1326                 remove(self);
1327                 return;
1328         }
1329
1330         if(self.cnt <= 0)
1331         {
1332                 self = self.owner;
1333                 ClientKill_Now(); // no oldself needed
1334                 return;
1335         }
1336     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1337     {
1338         self.nextthink = time + 1;
1339         self.cnt -= 1;
1340     }
1341         else
1342         {
1343                 if(self.cnt <= 10)
1344                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1345                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1346                 {
1347                         if(self.cnt <= 10)
1348                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1349                 }
1350                 self.nextthink = time + 1;
1351                 self.cnt -= 1;
1352         }
1353 }
1354
1355 float clientkilltime;
1356 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1357 {
1358         float killtime;
1359         float starttime;
1360         entity e;
1361
1362         if (gameover)
1363                 return;
1364
1365         killtime = autocvar_g_balance_kill_delay;
1366
1367         if(g_race_qualifying || g_cts)
1368                 killtime = 0;
1369
1370     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1371     {
1372                 remove(self.killindicator);
1373                 self.killindicator = world;
1374
1375         ClientKill_Now(); // allow instant kill in this case
1376         return;
1377     }
1378
1379         self.killindicator_teamchange = targetteam;
1380
1381     if(!self.killindicator)
1382         {
1383                 if(self.modelindex && self.deadflag == DEAD_NO)
1384                 {
1385                         killtime = max(killtime, self.clientkill_nexttime - time);
1386                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1387                 }
1388
1389                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1390                 {
1391                         ClientKill_Now();
1392                 }
1393                 else
1394                 {
1395                         starttime = max(time, clientkilltime);
1396
1397                         self.killindicator = spawn();
1398                         self.killindicator.owner = self;
1399                         self.killindicator.scale = 0.5;
1400                         setattachment(self.killindicator, self, "");
1401                         setorigin(self.killindicator, '0 0 52');
1402                         self.killindicator.think = KillIndicator_Think;
1403                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1404                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1405                         self.killindicator.cnt = ceil(killtime);
1406                         self.killindicator.count = bound(0, ceil(killtime), 10);
1407                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1408
1409                         for(e = world; (e = find(e, classname, "body")) != world; )
1410                         {
1411                                 if(e.enemy != self)
1412                                         continue;
1413                                 e.killindicator = spawn();
1414                                 e.killindicator.owner = e;
1415                                 e.killindicator.scale = 0.5;
1416                                 setattachment(e.killindicator, e, "");
1417                                 setorigin(e.killindicator, '0 0 52');
1418                                 e.killindicator.think = KillIndicator_Think;
1419                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1420                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1421                                 e.killindicator.cnt = ceil(killtime);
1422                         }
1423                         self.lip = 0;
1424                 }
1425         }
1426         if(self.killindicator)
1427         {
1428                 if(targetteam == 0) // just die
1429                 {
1430                         self.killindicator.colormod = '0 0 0';
1431                         if(clienttype(self) == CLIENTTYPE_REAL)
1432                         if(self.killindicator.cnt > 0)
1433                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1434                 }
1435                 else if(targetteam == -1) // auto
1436                 {
1437                         self.killindicator.colormod = '0 1 0';
1438                         if(clienttype(self) == CLIENTTYPE_REAL)
1439                         if(self.killindicator.cnt > 0)
1440                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1441                 }
1442                 else if(targetteam == -2) // spectate
1443                 {
1444                         self.killindicator.colormod = '0.5 0.5 0.5';
1445                         if(clienttype(self) == CLIENTTYPE_REAL)
1446                         if(self.killindicator.cnt > 0)
1447                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1448                 }
1449                 else
1450                 {
1451                         self.killindicator.colormod = TeamColor(targetteam);
1452                         if(clienttype(self) == CLIENTTYPE_REAL)
1453                         if(self.killindicator.cnt > 0)
1454                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1455                 }
1456         }
1457
1458 }
1459
1460 void ClientKill (void)
1461 {
1462         if (gameover)
1463                 return;
1464
1465         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1466         {
1467                 // do nothing
1468         }
1469     else if(self.freezetag_frozen)
1470     {
1471         // do nothing
1472     }
1473         else
1474                 ClientKill_TeamChange(0);
1475 }
1476
1477 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1478 {
1479     e.killindicator = spawn();
1480     e.killindicator.owner = e;
1481     e.killindicator.think = KillIndicator_Think;
1482     e.killindicator.nextthink = time + (e.lip) * 0.05;
1483     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1484     e.killindicator.health = 1; // this is used to indicate that it should be silent
1485     e.lip = 0;
1486 }
1487
1488 void FixClientCvars(entity e)
1489 {
1490         // send prediction settings to the client
1491         stuffcmd(e, "\nin_bindmap 0 0\n");
1492         if(g_race || g_cts)
1493                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1494         if(autocvar_g_antilag == 3) // client side hitscan
1495                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1496         if(sv_gentle)
1497                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1498         /*
1499          * we no longer need to stuff this. Remove this comment block if you feel
1500          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1501         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1502         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1503         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1504         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1505         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1506         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1507         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1508         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1509         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1510         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1511         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1512         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1513         stuffcmd(e, "cl_movement_edgefriction 1\n");
1514          */
1515 }
1516
1517 float PlayerInIDList(entity p, string idlist)
1518 {
1519         float n, i;
1520         string s;
1521
1522         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1523         if not(p.crypto_idfp)
1524                 return 0;
1525
1526         // this function allows abbreviated player IDs too!
1527         n = tokenize_console(idlist);
1528         for(i = 0; i < n; ++i)
1529         {
1530                 s = argv(i);
1531                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1532                         return 1;
1533         }
1534
1535         return 0;
1536 }
1537
1538 #ifndef NO_LEGACY_NETWORKING
1539 .float iscsqcmodel;
1540 #endif
1541
1542 /*
1543 =============
1544 ClientConnect
1545
1546 Called when a client connects to the server
1547 =============
1548 */
1549 //void ctf_clientconnect();
1550 string ColoredTeamName(float t);
1551 void DecodeLevelParms (void);
1552 //void dom_player_join_team(entity pl);
1553 void set_dom_state(entity e);
1554 void ClientConnect (void)
1555 {
1556         float t;
1557
1558         if(self.flags & FL_CLIENT)
1559         {
1560                 print("Warning: ClientConnect, but already connected!\n");
1561                 return;
1562         }
1563
1564         if(Ban_MaybeEnforceBan(self))
1565                 return;
1566
1567         DecodeLevelParms();
1568
1569 #ifdef WATERMARK
1570         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1571 #endif
1572
1573         self.classname = "player_joining";
1574
1575         self.flags = FL_CLIENT;
1576         self.version_nagtime = time + 10 + random() * 10;
1577
1578         if(player_count<0)
1579         {
1580                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1581                 player_count = 0;
1582         }
1583
1584         PlayerScore_Attach(self);
1585         ClientData_Attach();
1586         accuracy_init(self);
1587
1588         bot_clientconnect();
1589
1590         playerdemo_init();
1591
1592         anticheat_init();
1593
1594         race_PreSpawnObserver();
1595
1596         //if(g_domination)
1597         //      dom_player_join_team(self);
1598
1599         // identify the right forced team
1600         if(autocvar_g_campaign)
1601         {
1602                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1603                 {
1604                         switch(autocvar_g_campaign_forceteam)
1605                         {
1606                                 case 1: self.team_forced = COLOR_TEAM1; break;
1607                                 case 2: self.team_forced = COLOR_TEAM2; break;
1608                                 case 3: self.team_forced = COLOR_TEAM3; break;
1609                                 case 4: self.team_forced = COLOR_TEAM4; break;
1610                                 default: self.team_forced = 0;
1611                         }
1612                 }
1613         }
1614         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1615                 self.team_forced = COLOR_TEAM1;
1616         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1617                 self.team_forced = COLOR_TEAM2;
1618         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1619                 self.team_forced = COLOR_TEAM3;
1620         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1621                 self.team_forced = COLOR_TEAM4;
1622         else if(autocvar_g_forced_team_otherwise == "red")
1623                 self.team_forced = COLOR_TEAM1;
1624         else if(autocvar_g_forced_team_otherwise == "blue")
1625                 self.team_forced = COLOR_TEAM2;
1626         else if(autocvar_g_forced_team_otherwise == "yellow")
1627                 self.team_forced = COLOR_TEAM3;
1628         else if(autocvar_g_forced_team_otherwise == "pink")
1629                 self.team_forced = COLOR_TEAM4;
1630         else if(autocvar_g_forced_team_otherwise == "spectate")
1631                 self.team_forced = -1;
1632         else if(autocvar_g_forced_team_otherwise == "spectator")
1633                 self.team_forced = -1;
1634         else
1635                 self.team_forced = 0;
1636
1637         if(!teamplay)
1638                 if(self.team_forced > 0)
1639                         self.team_forced = 0;
1640
1641         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1642
1643         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1644                 self.classname = "observer";
1645         } else {
1646                 if(teamplay)
1647                 {
1648                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1649                         {
1650                                 self.classname = "player";
1651                                 campaign_bots_may_start = 1;
1652                         }
1653                         else
1654                         {
1655                                 self.classname = "observer"; // do it anyway
1656                         }
1657                 }
1658                 else
1659                 {
1660                         self.classname = "player";
1661                         campaign_bots_may_start = 1;
1662                 }
1663         }
1664
1665         self.playerid = (playerid_last = playerid_last + 1);
1666
1667         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1668
1669     if(clienttype(self) == CLIENTTYPE_BOT)
1670         PlayerStats_AddPlayer(self);
1671
1672         if(autocvar_sv_eventlog)
1673                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1674
1675         LogTeamchange(self.playerid, self.team, 1);
1676
1677         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1678
1679         self.netname_previous = strzone(self.netname);
1680
1681         bprint("^4", self.netname, "^4 connected");
1682
1683         if(self.classname != "observer" && (g_domination || g_ctf))
1684                 bprint(" and joined the ", ColoredTeamName(self.team));
1685
1686         bprint("\n");
1687
1688         stuffcmd(self, strcat(clientstuff, "\n"));
1689         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1690
1691         FixClientCvars(self);
1692
1693         // spawnfunc_waypoint sprites
1694         WaypointSprite_InitClient(self);
1695
1696         // Wazat's grappling hook
1697         SetGrappleHookBindings();
1698
1699         // get autoswitch state from player when he toggles it
1700         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1701
1702         // get version info from player
1703         stuffcmd(self, "cmd clientversion $gameversion\n");
1704
1705         // get other cvars from player
1706         GetCvars(0);
1707
1708         // notify about available teams
1709         if(teamplay)
1710         {
1711                 CheckAllowedTeams(self);
1712                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1713                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1714         }
1715         else
1716                 stuffcmd(self, "set _teams_available 0\n");
1717
1718         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1719
1720         if(g_arena || g_ca)
1721         {
1722                 self.classname = "observer";
1723                 if(g_arena)
1724                         Spawnqueue_Insert(self);
1725         }
1726         /*else if(g_ctf)
1727         {
1728                 ctf_clientconnect();
1729         }*/
1730
1731         attach_entcs();
1732
1733         bot_relinkplayerlist();
1734
1735         self.spectatortime = time;
1736         if(blockSpectators)
1737         {
1738                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1739         }
1740
1741         self.jointime = time;
1742         self.allowedTimeouts = autocvar_sv_timeout_number;
1743
1744         if(clienttype(self) == CLIENTTYPE_REAL)
1745         {
1746                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1747                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1748         }
1749
1750         if(g_lms)
1751         {
1752                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1753                 {
1754                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1755                         self.frags = FRAGS_SPECTATOR;
1756                 }
1757         }
1758
1759         if(!sv_foginterval && world.fog != "")
1760                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1761
1762         SoundEntity_Attach(self);
1763
1764         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1765         {
1766                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1767                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1768         }
1769         else
1770                 self.hitplotfh = -1;
1771
1772         if(g_race || g_cts) {
1773                 string rr;
1774                 if(g_cts)
1775                         rr = CTS_RECORD;
1776                 else
1777                         rr = RACE_RECORD;
1778                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1779
1780                 msg_entity = self;
1781                 race_send_recordtime(MSG_ONE);
1782                 race_send_speedaward(MSG_ONE);
1783
1784                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1785                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1786                 race_send_speedaward_alltimebest(MSG_ONE);
1787
1788                 float i;
1789                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1790                         race_SendRankings(i, 0, 0, MSG_ONE);
1791                 }
1792         }
1793         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1794                 send_CSQC_teamnagger();
1795
1796         if (g_domination)
1797                 set_dom_state(self);
1798
1799         CheatInitClient();
1800
1801         if(!autocvar_g_campaign)
1802                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1803
1804 #ifndef NO_LEGACY_NETWORKING
1805         if(autocvar_sv_use_csqc_players)
1806         {
1807                 CSQCModel_LinkEntity();
1808                 self.iscsqcmodel = 1;
1809         }
1810 #else
1811         CSQCModel_LinkEntity();
1812 #endif
1813 }
1814
1815 /*
1816 =============
1817 ClientDisconnect
1818
1819 Called when a client disconnects from the server
1820 =============
1821 */
1822 .entity chatbubbleentity;
1823 void ReadyCount();
1824 void ClientDisconnect (void)
1825 {
1826         if(self.vehicle)
1827             vehicles_exit(VHEF_RELESE);
1828
1829         if not(self.flags & FL_CLIENT)
1830         {
1831                 print("Warning: ClientDisconnect without ClientConnect\n");
1832                 return;
1833         }
1834
1835         PlayerStats_AddGlobalInfo(self);
1836
1837         CheatShutdownClient();
1838
1839         if(self.hitplotfh >= 0)
1840         {
1841                 fclose(self.hitplotfh);
1842                 self.hitplotfh = -1;
1843         }
1844
1845         anticheat_report();
1846         anticheat_shutdown();
1847
1848         playerdemo_shutdown();
1849
1850         bot_clientdisconnect();
1851
1852         if(self.entcs)
1853                 detach_entcs();
1854
1855         if(autocvar_sv_eventlog)
1856                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1857         bprint ("^4",self.netname);
1858         bprint ("^4 disconnected\n");
1859
1860         SoundEntity_Detach(self);
1861
1862         DropAllRunes(self);
1863         MUTATOR_CALLHOOK(ClientDisconnect);
1864
1865         Portal_ClearAll(self);
1866
1867         RemoveGrapplingHook(self);
1868         if(self.flagcarried)
1869                 DropFlag(self.flagcarried, world, world);
1870         if(self.ballcarried && g_nexball)
1871                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1872
1873         // Here, everything has been done that requires this player to be a client.
1874
1875         self.flags &~= FL_CLIENT;
1876
1877         if (self.chatbubbleentity)
1878                 remove (self.chatbubbleentity);
1879
1880         if (self.killindicator)
1881                 remove (self.killindicator);
1882
1883         WaypointSprite_PlayerGone();
1884
1885         bot_relinkplayerlist();
1886
1887         if(g_arena)
1888         {
1889                 Spawnqueue_Unmark(self);
1890                 Spawnqueue_Remove(self);
1891         }
1892
1893         accuracy_free(self);
1894         ClientData_Detach();
1895         PlayerScore_Detach(self);
1896
1897         if(self.netname_previous)
1898                 strunzone(self.netname_previous);
1899         if(self.clientstatus)
1900                 strunzone(self.clientstatus);
1901         if(self.weaponorder_byimpulse)
1902                 strunzone(self.weaponorder_byimpulse);
1903
1904         ClearPlayerSounds();
1905
1906         if(self.personal)
1907                 remove(self.personal);
1908
1909         self.playerid = 0;
1910         ReadyCount();
1911
1912         // free cvars
1913         GetCvars(-1);
1914 }
1915
1916 .float BUTTON_CHAT;
1917 void ChatBubbleThink()
1918 {
1919         self.nextthink = time;
1920         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1921         {
1922                 if(self.owner) // but why can that ever be world?
1923                         self.owner.chatbubbleentity = world;
1924                 remove(self);
1925                 return;
1926         }
1927         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1928 #ifdef TETRIS
1929                 || self.owner.tetris_on
1930 #endif
1931         )
1932                 self.model = self.mdl;
1933         else
1934                 self.model = "";
1935 }
1936
1937 void UpdateChatBubble()
1938 {
1939         if (!self.modelindex)
1940                 return;
1941         // spawn a chatbubble entity if needed
1942         if (!self.chatbubbleentity)
1943         {
1944                 self.chatbubbleentity = spawn();
1945                 self.chatbubbleentity.owner = self;
1946                 self.chatbubbleentity.exteriormodeltoclient = self;
1947                 self.chatbubbleentity.think = ChatBubbleThink;
1948                 self.chatbubbleentity.nextthink = time;
1949                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1950                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1951                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1952                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1953                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1954                 self.chatbubbleentity.model = "";
1955                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1956         }
1957 }
1958
1959
1960 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1961 // added to the model skins
1962 /*void UpdateColorModHack()
1963 {
1964         float c;
1965         c = self.clientcolors & 15;
1966         // LordHavoc: only bothering to support white, green, red, yellow, blue
1967              if (!teamplay) self.colormod = '0 0 0';
1968         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1969         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1970         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1971         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1972         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1973         else self.colormod = '1 1 1';
1974 }*/
1975
1976 .float oldcolormap;
1977 void respawn(void)
1978 {
1979         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1980         {
1981                 self.solid = SOLID_NOT;
1982                 self.takedamage = DAMAGE_NO;
1983                 self.movetype = MOVETYPE_FLY;
1984                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1985                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1986                 self.effects |= EF_ADDITIVE;
1987                 self.oldcolormap = self.colormap;
1988                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1989                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1990                 if(autocvar_g_respawn_ghosts_maxtime)
1991                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1992         }
1993
1994         CopyBody(1);
1995         self.effects |= EF_NODRAW; // prevent another CopyBody
1996         if(self.oldcolormap)
1997         {
1998                 self.colormap = self.oldcolormap;
1999                 self.oldcolormap = 0;
2000         }
2001         PutClientInServer();
2002 }
2003
2004 void play_countdown(float finished, string samp)
2005 {
2006         if(clienttype(self) == CLIENTTYPE_REAL)
2007                 if(floor(finished - time - frametime) != floor(finished - time))
2008                         if(finished - time < 6)
2009                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
2010 }
2011
2012 void player_powerups (void)
2013 {
2014         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2015         olditems = self.items;
2016
2017         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2018         {
2019                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2020                 self.modelflags |= MF_ROCKET;
2021         }
2022         else
2023         {
2024                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2025                 self.modelflags &~= MF_ROCKET;
2026         }
2027
2028         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2029
2030         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2031                 return;
2032
2033         Fire_ApplyDamage(self);
2034         Fire_ApplyEffect(self);
2035
2036         if (g_minstagib)
2037         {
2038                 self.effects |= EF_FULLBRIGHT;
2039
2040                 if (self.items & IT_STRENGTH)
2041                 {
2042                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2043                         if (time > self.strength_finished)
2044                         {
2045                                 self.alpha = default_player_alpha;
2046                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2047                                 self.items &~= IT_STRENGTH;
2048                                 sprint(self, "^3Invisibility has worn off\n");
2049                         }
2050                 }
2051                 else
2052                 {
2053                         if (time < self.strength_finished)
2054                         {
2055                                 self.alpha = g_minstagib_invis_alpha;
2056                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2057                                 self.items |= IT_STRENGTH;
2058                                 sprint(self, "^3You are invisible\n");
2059                         }
2060                 }
2061
2062                 if (self.items & IT_INVINCIBLE)
2063                 {
2064                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2065                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2066                         {
2067                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2068                                 sprint(self, "^3Speed has worn off\n");
2069                         }
2070                 }
2071                 else
2072                 {
2073                         if (time < self.invincible_finished)
2074                         {
2075                                 self.items = self.items | IT_INVINCIBLE;
2076                                 sprint(self, "^3You are on speed\n");
2077                         }
2078                 }
2079         }
2080         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2081         {
2082                 if (self.items & IT_STRENGTH)
2083                 {
2084                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2085                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2086                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2087                         {
2088                                 self.items = self.items - (self.items & IT_STRENGTH);
2089                                 sprint(self, "^3Strength has worn off\n");
2090                         }
2091                 }
2092                 else
2093                 {
2094                         if (time < self.strength_finished)
2095                         {
2096                                 self.items = self.items | IT_STRENGTH;
2097                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2098                         }
2099                 }
2100                 if (self.items & IT_INVINCIBLE)
2101                 {
2102                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2103                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2104                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2105                         {
2106                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2107                                 sprint(self, "^3Shield has worn off\n");
2108                         }
2109                 }
2110                 else
2111                 {
2112                         if (time < self.invincible_finished)
2113                         {
2114                                 self.items = self.items | IT_INVINCIBLE;
2115                                 sprint(self, "^3Shield surrounds you\n");
2116                         }
2117                 }
2118
2119                 if(autocvar_g_nodepthtestplayers)
2120                         self.effects = self.effects | EF_NODEPTHTEST;
2121
2122                 if(autocvar_g_fullbrightplayers)
2123                         self.effects = self.effects | EF_FULLBRIGHT;
2124
2125                 // midair gamemode: damage only while in the air
2126                 // if in midair mode, being on ground grants temporary invulnerability
2127                 // (this is so that multishot weapon don't clear the ground flag on the
2128                 // first damage in the frame, leaving the player vulnerable to the
2129                 // remaining hits in the same frame)
2130                 if (self.flags & FL_ONGROUND)
2131                 if (g_midair)
2132                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2133
2134                 if (time >= game_starttime)
2135                 if (time < self.spawnshieldtime)
2136                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2137         }
2138
2139         MUTATOR_CALLHOOK(PlayerPowerups);
2140 }
2141
2142 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2143 {
2144         if(current > stable)
2145                 return current;
2146         else if(current > stable - 0.25) // when close enough, "snap"
2147                 return stable;
2148         else
2149                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2150 }
2151
2152 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2153 {
2154         if(current < stable)
2155                 return current;
2156         else if(current < stable + 0.25) // when close enough, "snap"
2157                 return stable;
2158         else
2159                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2160 }
2161
2162 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2163 {
2164         if(current > rotstable)
2165         {
2166                 if(rotframetime > 0)
2167                 {
2168                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2169                         current = max(rotstable, current - rotlinear * rotframetime);
2170                 }
2171         }
2172         else if(current < regenstable)
2173         {
2174                 if(regenframetime > 0)
2175                 {
2176                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2177                         current = min(regenstable, current + regenlinear * regenframetime);
2178                 }
2179         }
2180
2181         if(current > limit)
2182                 current = limit;
2183
2184         return current;
2185 }
2186
2187 void player_regen (void)
2188 {
2189         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2190         maxh = autocvar_g_balance_health_rotstable;
2191         maxa = autocvar_g_balance_armor_rotstable;
2192         maxf = autocvar_g_balance_fuel_rotstable;
2193         minh = autocvar_g_balance_health_regenstable;
2194         mina = autocvar_g_balance_armor_regenstable;
2195         minf = autocvar_g_balance_fuel_regenstable;
2196         limith = autocvar_g_balance_health_limit;
2197         limita = autocvar_g_balance_armor_limit;
2198         limitf = autocvar_g_balance_fuel_limit;
2199
2200         max_mod = regen_mod = rot_mod = limit_mod = 1;
2201
2202         if (self.runes & RUNE_REGEN)
2203         {
2204                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2205                 {
2206                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2207                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2208                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2209                 }
2210                 else
2211                 {
2212                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2213                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2214                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2215                 }
2216         }
2217         else if (self.runes & CURSE_VENOM)
2218         {
2219                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2220                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2221                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2222                 else
2223                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2224                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2225                 //if (!self.runes & RUNE_REGEN)
2226                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2227         }
2228         maxh = maxh * max_mod;
2229         //maxa = maxa * max_mod;
2230         //maxf = maxf * max_mod;
2231         minh = minh * max_mod;
2232         //mina = mina * max_mod;
2233         //minf = minf * max_mod;
2234         limith = limith * limit_mod;
2235         limita = limita * limit_mod;
2236         //limitf = limitf * limit_mod;
2237
2238         if(g_lms && g_ca)
2239                 rot_mod = 0;
2240
2241         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2242         {
2243                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2244                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2245
2246                 // if player rotted to death...  die!
2247                 if(self.health < 1)
2248                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2249         }
2250
2251         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2252                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2253 }
2254
2255 float zoomstate_set;
2256 void SetZoomState(float z)
2257 {
2258         if(z != self.zoomstate)
2259         {
2260                 self.zoomstate = z;
2261                 ClientData_Touch(self);
2262         }
2263         zoomstate_set = 1;
2264 }
2265
2266 void GetPressedKeys(void) {
2267         MUTATOR_CALLHOOK(GetPressedKeys);
2268         if (self.movement_x > 0) // get if movement keys are pressed
2269         {       // forward key pressed
2270                 self.pressedkeys |= KEY_FORWARD;
2271                 self.pressedkeys &~= KEY_BACKWARD;
2272         }
2273         else if (self.movement_x < 0)
2274         {       // backward key pressed
2275                 self.pressedkeys |= KEY_BACKWARD;
2276                 self.pressedkeys &~= KEY_FORWARD;
2277         }
2278         else
2279         {       // no x input
2280                 self.pressedkeys &~= KEY_FORWARD;
2281                 self.pressedkeys &~= KEY_BACKWARD;
2282         }
2283
2284         if (self.movement_y > 0)
2285         {       // right key pressed
2286                 self.pressedkeys |= KEY_RIGHT;
2287                 self.pressedkeys &~= KEY_LEFT;
2288         }
2289         else if (self.movement_y < 0)
2290         {       // left key pressed
2291                 self.pressedkeys |= KEY_LEFT;
2292                 self.pressedkeys &~= KEY_RIGHT;
2293         }
2294         else
2295         {       // no y input
2296                 self.pressedkeys &~= KEY_RIGHT;
2297                 self.pressedkeys &~= KEY_LEFT;
2298         }
2299
2300         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2301                 self.pressedkeys |= KEY_JUMP;
2302         else
2303                 self.pressedkeys &~= KEY_JUMP;
2304         if (self.BUTTON_CROUCH)
2305                 self.pressedkeys |= KEY_CROUCH;
2306         else
2307                 self.pressedkeys &~= KEY_CROUCH;
2308 }
2309
2310 /*
2311 ======================
2312 spectate mode routines
2313 ======================
2314 */
2315
2316 void SpectateCopy(entity spectatee) {
2317         other = spectatee;
2318         MUTATOR_CALLHOOK(SpectateCopy);
2319         self.armortype = spectatee.armortype;
2320         self.armorvalue = spectatee.armorvalue;
2321         self.ammo_cells = spectatee.ammo_cells;
2322         self.ammo_shells = spectatee.ammo_shells;
2323         self.ammo_nails = spectatee.ammo_nails;
2324         self.ammo_rockets = spectatee.ammo_rockets;
2325         self.ammo_fuel = spectatee.ammo_fuel;
2326         self.clip_load = spectatee.clip_load;
2327         self.clip_size = spectatee.clip_size;
2328         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2329         self.health = spectatee.health;
2330         self.impulse = 0;
2331         self.items = spectatee.items;
2332         self.last_pickup = spectatee.last_pickup;
2333         self.hit_time = spectatee.hit_time;
2334         self.metertime = spectatee.metertime;
2335         self.strength_finished = spectatee.strength_finished;
2336         self.invincible_finished = spectatee.invincible_finished;
2337         self.pressedkeys = spectatee.pressedkeys;
2338         self.weapons = spectatee.weapons;
2339         self.switchweapon = spectatee.switchweapon;
2340         self.switchingweapon = spectatee.switchingweapon;
2341         self.weapon = spectatee.weapon;
2342         self.nex_charge = spectatee.nex_charge;
2343         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2344         self.hagar_load = spectatee.hagar_load;
2345         self.minelayer_mines = spectatee.minelayer_mines;
2346         self.punchangle = spectatee.punchangle;
2347         self.view_ofs = spectatee.view_ofs;
2348         self.v_angle = spectatee.v_angle;
2349         self.velocity = spectatee.velocity;
2350         self.dmg_take = spectatee.dmg_take;
2351         self.dmg_save = spectatee.dmg_save;
2352         self.dmg_inflictor = spectatee.dmg_inflictor;
2353         self.angles = spectatee.v_angle;
2354         if(!self.BUTTON_USE)
2355                 self.fixangle = TRUE;
2356         setorigin(self, spectatee.origin);
2357         setsize(self, spectatee.mins, spectatee.maxs);
2358         SetZoomState(spectatee.zoomstate);
2359
2360         anticheat_spectatecopy(spectatee);
2361
2362         //self.vehicle = spectatee.vehicle;
2363
2364         self.hud = spectatee.hud;
2365         if(spectatee.vehicle)
2366     {
2367         setorigin(self, spectatee.origin);
2368         self.velocity = spectatee.vehicle.velocity;
2369         self.v_angle += spectatee.vehicle.angles;
2370         //self.v_angle_x *= -1;
2371         self.vehicle_health = spectatee.vehicle_health;
2372         self.vehicle_shield = spectatee.vehicle_shield;
2373         self.vehicle_energy = spectatee.vehicle_energy;
2374         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2375         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2376         self.vehicle_reload1 = spectatee.vehicle_reload1;
2377         self.vehicle_reload2 = spectatee.vehicle_reload2;
2378
2379         msg_entity = self;
2380         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2381         WriteEntity(MSG_ONE, spectatee);
2382         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2383     }
2384 }
2385
2386 float SpectateUpdate() {
2387         if(!self.enemy)
2388             return 0;
2389
2390         if (self == self.enemy)
2391                 return 0;
2392
2393         if(self.enemy.classname != "player")
2394                 return 0;
2395
2396         SpectateCopy(self.enemy);
2397
2398         return 1;
2399 }
2400
2401
2402 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2403 entity CA_SpectateNext(entity start) {
2404         if (start.team == self.team) {
2405                 return start;
2406         }
2407
2408         other = start;
2409         // continue from current player
2410         while(other && other.team != self.team) {
2411                 other = find(other, classname, "player");
2412         }
2413
2414         if (!other) {
2415                 // restart from begining
2416                 other = find(other, classname, "player");
2417                 while(other && other.team != self.team) {
2418                         other = find(other, classname, "player");
2419                 }
2420         }
2421
2422         return other;
2423 }
2424
2425 float SpectateNext() {
2426         other = find(self.enemy, classname, "player");
2427         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2428                 // CA and ca players when spectating enemies is forbidden
2429                 other = CA_SpectateNext(other);
2430         } else {
2431                 // other modes and ca spectators or spectating enemies is allowed
2432                 if (!other)
2433                         other = find(other, classname, "player");
2434         }
2435
2436         if (other)
2437                 self.enemy = other;
2438
2439         if(self.enemy.classname == "player") {
2440             if(self.enemy.vehicle)
2441             {
2442             msg_entity = self;
2443             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2444             WriteEntity(MSG_ONE, self.enemy);
2445             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2446             self.movetype = MOVETYPE_NONE;
2447             accuracy_resend(self);
2448             }
2449             else
2450             {
2451             msg_entity = self;
2452             WriteByte(MSG_ONE, SVC_SETVIEW);
2453             WriteEntity(MSG_ONE, self.enemy);
2454             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2455             self.movetype = MOVETYPE_NONE;
2456             accuracy_resend(self);
2457
2458             if(!SpectateUpdate())
2459                 PutObserverInServer();
2460         }
2461         return 1;
2462         } else {
2463                 return 0;
2464         }
2465 }
2466
2467 /*
2468 =============
2469 ShowRespawnCountdown()
2470
2471 Update a respawn countdown display.
2472 =============
2473 */
2474 void ShowRespawnCountdown()
2475 {
2476         float number;
2477         if(self.deadflag == DEAD_NO) // just respawned?
2478                 return;
2479         else
2480         {
2481                 number = ceil(self.death_time - time);
2482                 if(number <= 0)
2483                         return;
2484                 if(number <= self.respawn_countdown)
2485                 {
2486                         self.respawn_countdown = number - 1;
2487                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2488                                 AnnounceTo(self, strcat(ftos(number), ""));
2489                 }
2490         }
2491 }
2492
2493 .float prevent_join_msgtime;
2494 void LeaveSpectatorMode()
2495 {
2496         if(nJoinAllowed(1)) {
2497                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2498                         self.classname = "player";
2499
2500                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2501                                 JoinBestTeam(self, FALSE, TRUE);
2502
2503                         if(autocvar_g_campaign)
2504                                 campaign_bots_may_start = 1;
2505
2506                         PutClientInServer();
2507
2508                         if(self.classname == "player")
2509                                 bprint ("^4", self.netname, "^4 is playing now\n");
2510
2511                         if(!autocvar_g_campaign)
2512                         if (time < self.jointime + autocvar_welcome_message_time)
2513                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2514
2515                         if (self.prevent_join_msgtime)
2516                         {
2517                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2518                                 self.prevent_join_msgtime = 0;
2519                         }
2520
2521                         return;
2522                 } else {
2523                         if (g_ca && self.caplayer) {
2524                         }       // do nothing
2525                         else
2526                                 stuffcmd(self,"menu_showteamselect\n");
2527                         return;
2528                 }
2529         }
2530         else {
2531                 //player may not join because of g_maxplayers is set
2532                 if (time - self.prevent_join_msgtime > 2)
2533                 {
2534                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2535                         self.prevent_join_msgtime = time;
2536                 }
2537         }
2538 }
2539
2540 /**
2541  * Determines whether the player is allowed to join. This depends on cvar
2542  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2543  * it checks whether the number of currently playing players exceeds g_maxplayers.
2544  * @return int number of free slots for players, 0 if none
2545  */
2546 float nJoinAllowed(float includeMe) {
2547         if(self.team_forced < 0)
2548                 return FALSE; // forced spectators can never join
2549
2550         // TODO simplify this
2551         entity e;
2552
2553         float totalClients;
2554         FOR_EACH_CLIENT(e)
2555                 totalClients += 1;
2556
2557         if (!autocvar_g_maxplayers)
2558                 return maxclients - totalClients + includeMe;
2559
2560         float currentlyPlaying;
2561         FOR_EACH_REALPLAYER(e)
2562                 currentlyPlaying += 1;
2563
2564         if(currentlyPlaying < autocvar_g_maxplayers)
2565                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2566
2567         return 0;
2568 }
2569
2570 /**
2571  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2572  * g_maxplayers_spectator_blocktime seconds
2573  */
2574 void checkSpectatorBlock() {
2575         if(self.classname == "spectator" || self.classname == "observer") {
2576                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2577                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2578                         dropclient(self);
2579                 }
2580         }
2581 }
2582
2583 .float motd_actived_time; // used for both motd and campaign_message
2584 void PrintWelcomeMessage()
2585 {
2586         if (self.motd_actived_time == 0) { // is there already a message showing?
2587                 if (autocvar_g_campaign) {
2588                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2589                                 self.motd_actived_time = time;
2590                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2591                         }
2592                 } else {
2593                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2594                                 self.motd_actived_time = time;
2595                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2596                         }
2597                 }
2598         } else { // showing MOTD or campaign message
2599                 if (autocvar_g_campaign) {
2600                         if (self.BUTTON_INFO)
2601                                 self.motd_actived_time = time;
2602                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2603                                 self.motd_actived_time = 0;
2604                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2605                         }
2606                 } else {
2607                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2608                                 if (self.BUTTON_INFO)
2609                                         self.motd_actived_time = time;
2610                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2611                                         self.motd_actived_time = 0;
2612                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2613                                 }
2614                         }
2615                 }
2616         }
2617 }
2618
2619 void ObserverThink()
2620 {
2621         float prefered_movetype;
2622         if (self.flags & FL_JUMPRELEASED) {
2623                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2624                         self.flags &~= FL_JUMPRELEASED;
2625                         self.flags |= FL_SPAWNING;
2626                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2627                         self.flags &~= FL_JUMPRELEASED;
2628                         if(SpectateNext() == 1) {
2629                                 self.classname = "spectator";
2630                         }
2631                 } else {
2632                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2633                         if (self.movetype != prefered_movetype)
2634                                 self.movetype = prefered_movetype;
2635                 }
2636         } else {
2637                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2638                         self.flags |= FL_JUMPRELEASED;
2639                         if(self.flags & FL_SPAWNING)
2640                         {
2641                                 self.flags &~= FL_SPAWNING;
2642                                 LeaveSpectatorMode();
2643                                 return;
2644                         }
2645                 }
2646         }
2647
2648         PrintWelcomeMessage();
2649 }
2650
2651 void SpectatorThink()
2652 {
2653         if (self.flags & FL_JUMPRELEASED) {
2654                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2655                         self.flags &~= FL_JUMPRELEASED;
2656                         self.flags |= FL_SPAWNING;
2657                 } else if(self.BUTTON_ATCK) {
2658                         self.flags &~= FL_JUMPRELEASED;
2659                         if(SpectateNext() == 1) {
2660                                 self.classname = "spectator";
2661                         } else {
2662                                 self.classname = "observer";
2663                                 PutClientInServer();
2664                         }
2665                 } else if (self.BUTTON_ATCK2) {
2666                         self.flags &~= FL_JUMPRELEASED;
2667                         self.classname = "observer";
2668                         PutClientInServer();
2669                 } else {
2670                         if(!SpectateUpdate())
2671                                 PutObserverInServer();
2672                 }
2673         } else {
2674                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2675                         self.flags |= FL_JUMPRELEASED;
2676                         if(self.flags & FL_SPAWNING)
2677                         {
2678                                 self.flags &~= FL_SPAWNING;
2679                                 LeaveSpectatorMode();
2680                                 return;
2681                         }
2682                 }
2683                 if(!SpectateUpdate())
2684                         PutObserverInServer();
2685         }
2686
2687         PrintWelcomeMessage();
2688         self.flags |= FL_CLIENT | FL_NOTARGET;
2689 }
2690
2691 float ctf_usekey();
2692 void PlayerUseKey()
2693 {
2694         if(self.classname != "player")
2695                 return;
2696
2697         if(self.vehicle)
2698         {
2699         vehicles_exit(VHEF_NORMAL);
2700         return;
2701         }
2702
2703         // a use key was pressed; call handlers
2704         if(ctf_usekey())
2705                 return;
2706
2707         MUTATOR_CALLHOOK(PlayerUseKey);
2708 }
2709
2710 .float touchexplode_time;
2711
2712 /*
2713 =============
2714 PlayerPreThink
2715
2716 Called every frame for each client before the physics are run
2717 =============
2718 */
2719 .float usekeypressed;
2720 void() ctf_setstatus;
2721 void() nexball_setstatus;
2722 .float items_added;
2723 void PlayerPreThink (void)
2724 {
2725         WarpZone_PlayerPhysics_FixVAngle();
2726
2727         self.stat_game_starttime = game_starttime;
2728         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2729         self.stat_leadlimit = autocvar_leadlimit;
2730
2731         if(frametime)
2732         {
2733                 // physics frames: update anticheat stuff
2734                 anticheat_prethink();
2735         }
2736
2737         if(blockSpectators && frametime)
2738                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2739                 checkSpectatorBlock();
2740
2741         zoomstate_set = 0;
2742
2743         if(self.netname_previous != self.netname)
2744         {
2745                 if(autocvar_sv_eventlog)
2746                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2747                 if(self.netname_previous)
2748                         strunzone(self.netname_previous);
2749                 self.netname_previous = strzone(self.netname);
2750         }
2751
2752         // version nagging
2753         if(self.version_nagtime)
2754                 if(self.cvar_g_xonoticversion)
2755                         if(time > self.version_nagtime)
2756                         {
2757                                 // don't notify git users
2758                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2759                                 {
2760                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2761                                         {
2762                                                 // notify release users if connecting to git
2763                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2764                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2765                                         }
2766                                         else
2767                                         {
2768                                                 float r;
2769                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2770                                                 if(r < 0)
2771                                                 {
2772                                                         // give users new version
2773                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2774                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2775                                                 }
2776                                                 else if(r > 0)
2777                                                 {
2778                                                         // notify users about old server version
2779                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2780                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2781                                                 }
2782                                         }
2783                                 }
2784                                 self.version_nagtime = 0;
2785                         }
2786
2787         // GOD MODE info
2788         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2789         {
2790                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2791                 self.max_armorvalue = 0;
2792         }
2793
2794 #ifdef TETRIS
2795         if (TetrisPreFrame())
2796                 return;
2797 #endif
2798
2799         MUTATOR_CALLHOOK(PlayerPreThink);
2800
2801         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2802         {
2803                 if(self.BUTTON_USE && !self.usekeypressed)
2804                         PlayerUseKey();
2805                 self.usekeypressed = self.BUTTON_USE;
2806         }
2807
2808         PrintWelcomeMessage();
2809
2810         if(self.classname == "player") {
2811 //              if(self.netname == "Wazat")
2812 //                      bprint(self.classname, "\n");
2813
2814                 CheckRules_Player();
2815
2816                 if (intermission_running)
2817                 {
2818                         IntermissionThink ();   // otherwise a button could be missed between
2819                         return;                                 // the think tics
2820                 }
2821
2822                 //don't allow the player to turn around while game is paused!
2823                 if(timeoutStatus == 2) {
2824                         // FIXME turn this into CSQC stuff
2825                         self.v_angle = self.lastV_angle;
2826                         self.angles = self.lastV_angle;
2827                         self.fixangle = TRUE;
2828                 }
2829
2830                 if(frametime)
2831                 {
2832                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2833                         {
2834                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2835                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2836                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2837
2838                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2839                                 {
2840                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2841                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2842                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2843                                 }
2844                         }
2845                         else
2846                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2847
2848                         player_powerups();
2849                 }
2850
2851                 if (g_minstagib)
2852                         minstagib_ammocheck();
2853
2854                 if (self.deadflag != DEAD_NO)
2855                 {
2856                         float button_pressed, force_respawn;
2857                         if(self.personal && g_race_qualifying)
2858                         {
2859                                 if(time > self.death_time)
2860                                 {
2861                                         self.death_time = time + 1; // only retry once a second
2862                                         respawn();
2863                                         self.impulse = 141;
2864                                 }
2865                         }
2866                         else
2867                         {
2868                                 if(frametime)
2869                                         player_anim();
2870                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2871                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2872                                 if (self.deadflag == DEAD_DYING)
2873                                 {
2874                                         if(force_respawn)
2875                                                 self.deadflag = DEAD_RESPAWNING;
2876                                         else if(!button_pressed)
2877                                                 self.deadflag = DEAD_DEAD;
2878                                 }
2879                                 else if (self.deadflag == DEAD_DEAD)
2880                                 {
2881                                         if(button_pressed)
2882                                                 self.deadflag = DEAD_RESPAWNABLE;
2883                                 }
2884                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2885                                 {
2886                                         if(!button_pressed)
2887                                                 self.deadflag = DEAD_RESPAWNING;
2888                                 }
2889                                 else if (self.deadflag == DEAD_RESPAWNING)
2890                                 {
2891                                         if(time > self.death_time)
2892                                         {
2893                                                 self.death_time = time + 1; // only retry once a second
2894                                                 respawn();
2895                                         }
2896                                 }
2897                                 ShowRespawnCountdown();
2898                         }
2899                         return;
2900                 }
2901                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2902                 // so (self.deadflag == DEAD_NO) is always true in the code below
2903
2904                 if(g_touchexplode)
2905                 if(time > self.touchexplode_time)
2906                 if(self.classname == "player")
2907                 if(self.deadflag == DEAD_NO)
2908                 if not(IS_INDEPENDENT_PLAYER(self))
2909                 FOR_EACH_PLAYER(other) if(self != other)
2910                 {
2911                         if(time > other.touchexplode_time)
2912                         if(other.deadflag == DEAD_NO)
2913                         if not(IS_INDEPENDENT_PLAYER(other))
2914                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2915                         {
2916                                 PlayerTouchExplode(self, other);
2917                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2918                         }
2919                 }
2920
2921                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2922                 {
2923                         vector dist;
2924
2925                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2926                         dist = self.prevorigin - self.origin;
2927                         dist_z = 0;
2928                         self.lms_traveled_distance += fabs(vlen(dist));
2929
2930                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2931                         {
2932                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2933                                 self.lms_traveled_distance = 0;
2934                         }
2935
2936                         if(time > self.lms_nextcheck)
2937                         {
2938                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2939                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2940                                 {
2941                                         centerprint(self, autocvar_g_lms_campcheck_message);
2942                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2943                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2944                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2945                                 }
2946                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2947                                 self.lms_traveled_distance = 0;
2948                         }
2949                 }
2950
2951                 self.prevorigin = self.origin;
2952
2953                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2954                 {
2955                         if (!self.crouch)
2956                         {
2957                                 self.crouch = TRUE;
2958                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2959                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2960                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2961                         }
2962                 }
2963                 else
2964                 {
2965                         if (self.crouch)
2966                         {
2967                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2968                                 if (!trace_startsolid)
2969                                 {
2970                                         self.crouch = FALSE;
2971                                         self.view_ofs = PL_VIEW_OFS;
2972                                         setsize (self, PL_MIN, PL_MAX);
2973                                 }
2974                         }
2975                 }
2976
2977                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2978                 {
2979                         if(self.bloodloss_timer < time)
2980                         {
2981                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2982                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2983                         }
2984                 }
2985
2986                 FixPlayermodel();
2987
2988                 GrapplingHookFrame();
2989
2990                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2991                 //if(frametime)
2992                 {
2993                         self.items &~= self.items_added;
2994
2995                         W_WeaponFrame();
2996
2997                         self.items_added = 0;
2998                         if(self.items & IT_JETPACK)
2999                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
3000                                         self.items_added |= IT_FUEL;
3001
3002                         self.items |= self.items_added;
3003                 }
3004
3005                 player_regen();
3006
3007                 // rot nex charge to the charge limit
3008                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3009                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3010
3011                 if(frametime)
3012                         player_anim();
3013
3014                 if(g_ctf)
3015                         ctf_setstatus();
3016
3017                 if(g_nexball)
3018                         nexball_setstatus();
3019
3020                 // secret status
3021                 secrets_setstatus();
3022
3023                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3024
3025                 //self.angles_y=self.v_angle_y + 90;   // temp
3026         } else if(gameover) {
3027                 if (intermission_running)
3028                         IntermissionThink ();   // otherwise a button could be missed between
3029                 return;
3030         } else if(self.classname == "observer") {
3031                 ObserverThink();
3032         } else if(self.classname == "spectator") {
3033                 SpectatorThink();
3034         }
3035
3036         if(!zoomstate_set)
3037                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3038
3039         float oldspectatee_status;
3040         oldspectatee_status = self.spectatee_status;
3041         if(self.classname == "spectator")
3042                 self.spectatee_status = num_for_edict(self.enemy);
3043         else if(self.classname == "observer")
3044                 self.spectatee_status = num_for_edict(self);
3045         else
3046                 self.spectatee_status = 0;
3047         if(self.spectatee_status != oldspectatee_status)
3048         {
3049                 ClientData_Touch(self);
3050                 if(g_race || g_cts)
3051                         race_InitSpectator();
3052         }
3053
3054         if(self.teamkill_soundtime)
3055         if(time > self.teamkill_soundtime)
3056         {
3057                 self.teamkill_soundtime = 0;
3058
3059                 entity oldpusher, oldself;
3060
3061                 oldself = self; self = self.teamkill_soundsource;
3062                 oldpusher = self.pusher; self.pusher = oldself;
3063
3064                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3065
3066                 self.pusher = oldpusher;
3067                 self = oldself;
3068         }
3069
3070         if(self.taunt_soundtime)
3071         if(time > self.taunt_soundtime)
3072         {
3073                 self.taunt_soundtime = 0;
3074                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3075         }
3076
3077         target_voicescript_next(self);
3078
3079         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3080         if(!self.weapon)
3081                 self.clip_load = self.clip_size = 0;
3082 }
3083
3084 float isInvisibleString(string s)
3085 {
3086         float i, n, c;
3087         s = strdecolorize(s);
3088         for((i = 0), (n = strlen(s)); i < n; ++i)
3089         {
3090                 c = str2chr(s, i);
3091                 switch(c)
3092                 {
3093                         case 0:
3094                         case 32: // space
3095                                 break;
3096                         case 192: // charmap space
3097                                 if (!autocvar_utf8_enable)
3098                                         break;
3099                                 return FALSE;
3100                         case 160: // space in unicode fonts
3101                         case 0xE000 + 192: // utf8 charmap space
3102                                 if (autocvar_utf8_enable)
3103                                         break;
3104                         default:
3105                                 return FALSE;
3106                 }
3107         }
3108         return TRUE;
3109 }
3110
3111 /*
3112 =============
3113 PlayerPostThink
3114
3115 Called every frame for each client after the physics are run
3116 =============
3117 */
3118 .float idlekick_lasttimeleft;
3119 .entity showheadshotbbox;
3120 void showheadshotbbox_think()
3121 {
3122         if(self.owner.showheadshotbbox != self)
3123         {
3124                 remove(self);
3125                 return;
3126         }
3127         self.nextthink = time;
3128         setorigin(self, self.owner.origin);
3129         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3130 }
3131 void PlayerPostThink (void)
3132 {
3133         // Savage: Check for nameless players
3134         if (isInvisibleString(self.netname)) {
3135                 self.netname = "Player";
3136                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3137         }
3138
3139         if(sv_maxidle && frametime)
3140         {
3141                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3142                 float timeleft;
3143                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3144                 {
3145                         if(self.idlekick_lasttimeleft)
3146                         {
3147                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3148                                 self.idlekick_lasttimeleft = 0;
3149                         }
3150                         return;
3151                 }
3152                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3153                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3154                 {
3155                         if(!self.idlekick_lasttimeleft)
3156                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3157                 }
3158                 if(timeleft <= 0)
3159                 {
3160                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3161                         AnnounceTo(self, "terminated");
3162                         dropclient(self);
3163                         return;
3164                 }
3165                 else if(timeleft <= 10)
3166                 {
3167                         if(timeleft != self.idlekick_lasttimeleft)
3168                                 AnnounceTo(self, ftos(timeleft));
3169                         self.idlekick_lasttimeleft = timeleft;
3170                 }
3171         }
3172
3173 #ifdef TETRIS
3174         if(self.impulse == 100)
3175                 ImpulseCommands();
3176         if (TetrisPostFrame())
3177                 return;
3178 #endif
3179
3180         CheatFrame();
3181
3182         //CheckPlayerJump();
3183
3184         if(self.classname == "player") {
3185                 CheckRules_Player();
3186                 UpdateChatBubble();
3187                 if (self.impulse)
3188                         ImpulseCommands();
3189                 if (intermission_running)
3190                         return;         // intermission or finale
3191                 GetPressedKeys();
3192         } else if (self.classname == "observer") {
3193                 //do nothing
3194         } else if (self.classname == "spectator") {
3195                 //do nothing
3196         }
3197
3198         /*
3199         float i;
3200         for(i = 0; i < 1000; ++i)
3201         {
3202                 vector end;
3203                 end = self.origin + '0 0 1024' + 512 * randomvec();
3204                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3205                 if(trace_fraction < 1)
3206                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3207                 {
3208                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3209                         break;
3210                 }
3211         }
3212         */
3213
3214         Arena_Warmup();
3215
3216         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3217
3218         if(self.waypointsprite_attachedforcarrier)
3219                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3220
3221         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3222         {
3223                 if(!self.showheadshotbbox)
3224                 {
3225                         self.showheadshotbbox = spawn();
3226                         self.showheadshotbbox.classname = "headshotbbox";
3227                         self.showheadshotbbox.owner = self;
3228                         self.showheadshotbbox.think = showheadshotbbox_think;
3229                         self.showheadshotbbox.nextthink = time;
3230                         self = self.showheadshotbbox;
3231                         self.think();
3232                         self = self.owner;
3233                 }
3234         }
3235         else
3236         {
3237                 if(self.showheadshotbbox)
3238                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3239                 remove(self.showheadshotbbox);
3240         }
3241
3242         playerdemo_write();
3243
3244         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3245         {
3246                 if(!self.stored_netname)
3247                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3248                 if(self.stored_netname != self.netname)
3249                 {
3250                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3251                         strunzone(self.stored_netname);
3252                         self.stored_netname = strzone(self.netname);
3253                 }
3254         }
3255
3256         /*
3257         if(g_race)
3258                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3259         */
3260
3261 #ifndef NO_LEGACY_NETWORKING
3262         if(autocvar_sv_use_csqc_players && !self.iscsqcmodel)
3263         {
3264                 CSQCModel_LinkEntity();
3265                 self.iscsqcmodel = 1;
3266         }
3267
3268         if(!autocvar_sv_use_csqc_players && self.iscsqcmodel)
3269         {
3270                 CSQCModel_UnlinkEntity();
3271                 self.iscsqcmodel = 0;
3272         }
3273
3274         if(self.iscsqcmodel)
3275                 CSQCModel_CheckUpdate();
3276 #else
3277         CSQCModel_CheckUpdate();
3278 #endif
3279 }