qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 } else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434
 435                 if(self.just_joined == FALSE) {
 436                         LogTeamchange(self.playerid, -1, 4);
 437                 } else
 438                         self.just_joined = FALSE;
 439         }
 440
 441         PlayerScore_Clear(self); // clear scores when needed
 442
 443         accuracy_resend(self);
 444
 445         self.spectatortime = time;
 446
 447         self.classname = "observer";
 448         self.iscreature = FALSE;
 449         self.teleportable = TELEPORT_SIMPLE;
 450         self.damagedbycontents = FALSE;
 451         self.health = -666;
 452         self.takedamage = DAMAGE_NO;
 453         self.solid = SOLID_NOT;
 454         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 455         self.flags = FL_CLIENT | FL_NOTARGET;
 456         self.armorvalue = 666;
 457         self.effects = 0;
 458         self.armorvalue = autocvar_g_balance_armor_start;
 459         self.pauserotarmor_finished = 0;
 460         self.pauserothealth_finished = 0;
 461         self.pauseregen_finished = 0;
 462         self.damageforcescale = 0;
 463         self.death_time = 0;
 464         self.respawn_time = 0;
 465         self.alpha = 0;
 466         self.scale = 0;
 467         self.fade_time = 0;
 468         self.pain_frame = 0;
 469         self.pain_finished = 0;
 470         self.strength_finished = 0;
 471         self.invincible_finished = 0;
 472         self.superweapons_finished = 0;
 473         self.pushltime = 0;
 474         self.istypefrag = 0;
 475         self.think = func_null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         self.frags = FRAGS_SPECTATOR;
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         self.frags = FRAGS_LMS_LOSER;
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_ca)
 526         {
 527                 if(self.caplayer)
 528                         self.frags = FRAGS_LMS_LOSER;
 529                 else
 530                         self.frags = FRAGS_SPECTATOR;
 531         }
 532         else if((g_race && g_race_qualifying) || g_cts)
 533         {
 534                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551         defaultskin = 0;
 552         chmdl = FALSE;
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorNameLowerCase(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin)
 614                 self.species = player_getspecies(); // model or skin has changed
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644
 645 void PutClientInServer (void)
 646 {
 647         if(clienttype(self) == CLIENTTYPE_BOT)
 648         {
 649                 self.classname = "player";
 650                 if(g_ca)
 651                         self.caplayer = 1;
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 664                 self.classname = "observer";
 665
 666         if(gameover)
 667                 self.classname = "observer";
 668
 669         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 670                 entity spot, oldself;
 671                 float j;
 672
 673                 accuracy_resend(self);
 674
 675                 if(self.team < 0)
 676                         JoinBestTeam(self, FALSE, TRUE);
 677
 678                 race_PreSpawn();
 679
 680                 spot = SelectSpawnPoint (FALSE);
 681                 if(!spot)
 682                 {
 683                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 684                         return; // spawn failed
 685                 }
 686
 687                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 688
 689                 self.classname = "player";
 690                 self.wasplayer = TRUE;
 691                 self.iscreature = TRUE;
 692                 self.teleportable = TELEPORT_NORMAL;
 693                 self.damagedbycontents = TRUE;
 694                 self.movetype = MOVETYPE_WALK;
 695                 self.solid = SOLID_SLIDEBOX;
 696                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 697                 if(autocvar_g_playerclip_collisions)
 698                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 699                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 700                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 701                 self.frags = FRAGS_PLAYER;
 702                 if(INDEPENDENT_PLAYERS)
 703                         MAKE_INDEPENDENT_PLAYER(self);
 704                 self.flags = FL_CLIENT;
 705                 if(autocvar__notarget)
 706                         self.flags |= FL_NOTARGET;
 707                 self.takedamage = DAMAGE_AIM;
 708                 if(g_minstagib)
 709                         self.effects = EF_FULLBRIGHT;
 710                 else
 711                         self.effects = 0;
 712                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 713                 self.air_finished = time + 12;
 714                 self.dmg = 2;
 715                 if(autocvar_g_balance_nex_charge)
 716                 {
 717                         if(autocvar_g_balance_nex_secondary_chargepool)
 718                                 self.nex_chargepool_ammo = 1;
 719                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 720                 }
 721
 722                 if(inWarmupStage)
 723                 {
 724                         self.ammo_shells = warmup_start_ammo_shells;
 725                         self.ammo_nails = warmup_start_ammo_nails;
 726                         self.ammo_rockets = warmup_start_ammo_rockets;
 727                         self.ammo_cells = warmup_start_ammo_cells;
 728                         self.ammo_fuel = warmup_start_ammo_fuel;
 729                         self.health = warmup_start_health;
 730                         self.armorvalue = warmup_start_armorvalue;
 731                         WEPSET_COPY_EA(self, warmup_start_weapons);
 732                 }
 733                 else
 734                 {
 735                         self.ammo_shells = start_ammo_shells;
 736                         self.ammo_nails = start_ammo_nails;
 737                         self.ammo_rockets = start_ammo_rockets;
 738                         self.ammo_cells = start_ammo_cells;
 739                         self.ammo_fuel = start_ammo_fuel;
 740                         self.health = start_health;
 741                         self.armorvalue = start_armorvalue;
 742                         WEPSET_COPY_EA(self, start_weapons);
 743                 }
 744
 745                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 746                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 747                 else
 748                         self.superweapons_finished = 0;
 749
 750                 if(g_weaponarena_random)
 751                 {
 752                         if(g_weaponarena_random_with_laser)
 753                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 754                         W_RandomWeapons(self, g_weaponarena_random);
 755                         if(g_weaponarena_random_with_laser)
 756                                 WEPSET_OR_EW(self, WEP_LASER);
 757                 }
 758
 759                 self.items = start_items;
 760
 761                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 762                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 763                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 764                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 765                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 766                 //extend the pause of rotting if client was reset at the beginning of the countdown
 767                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 768                         self.spawnshieldtime += game_starttime - time;
 769                         self.pauserotarmor_finished += game_starttime - time;
 770                         self.pauserothealth_finished += game_starttime - time;
 771                         self.pauseregen_finished += game_starttime - time;
 772                 }
 773                 self.damageforcescale = 2;
 774                 self.death_time = 0;
 775                 self.respawn_time = 0;
 776                 self.scale = 0;
 777                 self.fade_time = 0;
 778                 self.pain_frame = 0;
 779                 self.pain_finished = 0;
 780                 self.strength_finished = 0;
 781                 self.invincible_finished = 0;
 782                 self.pushltime = 0;
 783                 // players have no think function
 784                 self.think = func_null;
 785                 self.nextthink = 0;
 786                 self.hook_time = 0;
 787                 self.dmg_team = 0;
 788                 self.ballistics_density = autocvar_g_ballistics_density_player;
 789
 790                 self.metertime = 0;
 791
 792                 self.runes = 0;
 793
 794                 self.deadflag = DEAD_NO;
 795
 796                 self.angles = spot.angles;
 797
 798                 self.angles_z = 0; // never spawn tilted even if the spot says to
 799                 self.fixangle = TRUE; // turn this way immediately
 800                 self.velocity = '0 0 0';
 801                 self.avelocity = '0 0 0';
 802                 self.punchangle = '0 0 0';
 803                 self.punchvector = '0 0 0';
 804                 self.oldvelocity = self.velocity;
 805                 self.fire_endtime = -1;
 806
 807                 msg_entity = self;
 808                 WRITESPECTATABLE_MSG_ONE({
 809                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 810                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 811                 });
 812
 813                 self.model = "";
 814                 FixPlayermodel();
 815                 self.drawonlytoclient = world;
 816
 817                 self.crouch = FALSE;
 818                 self.view_ofs = PL_VIEW_OFS;
 819                 setsize (self, PL_MIN, PL_MAX);
 820                 self.spawnorigin = spot.origin;
 821                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 822                 // don't reset back to last position, even if new position is stuck in solid
 823                 self.oldorigin = self.origin;
 824                 self.prevorigin = self.origin;
 825                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 826                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 827         self.hud = HUD_NORMAL;
 828
 829                 if(g_arena)
 830                 {
 831                         Spawnqueue_Remove(self);
 832                         Spawnqueue_Mark(self);
 833                 }
 834                 else if(g_ca)
 835                         self.caplayer = 1;
 836
 837                 self.event_damage = PlayerDamage;
 838
 839                 self.bot_attack = TRUE;
 840
 841                 self.statdraintime = time + 5;
 842                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 843
 844                 if(self.killcount == -666) {
 845                         PlayerScore_Clear(self);
 846                         self.killcount = 0;
 847                 }
 848
 849                 CL_SpawnWeaponentity();
 850                 self.alpha = default_player_alpha;
 851                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 852                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 853
 854                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 855                 self.lms_traveled_distance = 0;
 856                 self.speedrunning = FALSE;
 857
 858                 race_PostSpawn(spot);
 859
 860                 //stuffcmd(self, "chase_active 0");
 861                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 862
 863                 if(g_assault) {
 864                         if(self.team == assault_attacker_team)
 865                                 centerprint(self, "You are attacking!");
 866                         else
 867                                 centerprint(self, "You are defending!");
 868                 }
 869
 870                 target_voicescript_clear(self);
 871
 872                 // reset fields the weapons may use
 873                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 874                 {
 875                         weapon_action(j, WR_RESETPLAYER);
 876
 877                         // all weapons must be fully loaded when we spawn
 878                         entity e;
 879                         e = get_weaponinfo(j);
 880                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 881                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 882                 }
 883
 884                 oldself = self;
 885                 self = spot;
 886                         activator = oldself;
 887                                 string s;
 888                                 s = self.target;
 889                                 self.target = string_null;
 890                                 SUB_UseTargets();
 891                                 self.target = s;
 892                         activator = world;
 893                 self = oldself;
 894
 895                 spawn_spot = spot;
 896                 MUTATOR_CALLHOOK(PlayerSpawn);
 897
 898                 if(autocvar_spawn_debug)
 899                 {
 900                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 901                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 902                 }
 903
 904                 self.switchweapon = w_getbestweapon(self);
 905                 self.cnt = -1; // W_LastWeapon will not complain
 906                 self.weapon = 0;
 907                 self.weaponname = "";
 908                 self.switchingweapon = 0;
 909
 910                 if(!inWarmupStage)
 911                         if(!self.alivetime)
 912                                 self.alivetime = time;
 913
 914                 antilag_clear(self);
 915
 916                 if (autocvar_g_spawnsound)
 917                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 918         } else if(self.classname == "observer") {
 919                 PutObserverInServer ();
 920         }
 921 }
 922
 923 .float ebouncefactor, ebouncestop; // electro's values
 924 // TODO do we need all these fields, or should we stop autodetecting runtime
 925 // changes and just have a console command to update this?
 926 float ClientInit_SendEntity(entity to, float sf)
 927 {
 928         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 929         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 930         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 931         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 932         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 933         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 942         if(sv_foginterval && world.fog != "")
 943                 WriteString(MSG_ENTITY, world.fog);
 944         else
 945                 WriteString(MSG_ENTITY, "");
 946         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 947         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 948         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 949         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 950         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 951         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 952         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 953         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 954         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 955         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 957         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 959         return TRUE;
 960 }
 961
 962 void ClientInit_CheckUpdate()
 963 {
 964         self.nextthink = time;
 965         if(self.count != autocvar_g_balance_armor_blockpercent)
 966         {
 967                 self.count = autocvar_g_balance_armor_blockpercent;
 968                 self.SendFlags |= 1;
 969         }
 970         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 971         {
 972                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 973                 self.SendFlags |= 1;
 974         }
 975         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 976         {
 977                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 981         {
 982                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 986         {
 987                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 991         {
 992                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 993                 self.SendFlags |= 1;
 994         }
 995 }
 996
 997 void ClientInit_Spawn()
 998 {
 999         entity o;
1000         entity e;
1001         e = spawn();
1002         e.classname = "clientinit";
1003         e.think = ClientInit_CheckUpdate;
1004         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1005
1006         o = self;
1007         self = e;
1008         ClientInit_CheckUpdate();
1009         self = o;
1010 }
1011
1012 /*
1013 =============
1014 SetNewParms
1015 =============
1016 */
1017 void SetNewParms (void)
1018 {
1019         // initialize parms for a new player
1020         parm1 = -(86400 * 366);
1021 }
1022
1023 /*
1024 =============
1025 SetChangeParms
1026 =============
1027 */
1028 void SetChangeParms (void)
1029 {
1030         // save parms for level change
1031         parm1 = self.parm_idlesince - time;
1032 }
1033
1034 /*
1035 =============
1036 DecodeLevelParms
1037 =============
1038 */
1039 void DecodeLevelParms (void)
1040 {
1041         // load parms
1042         self.parm_idlesince = parm1;
1043         if(self.parm_idlesince == -(86400 * 366))
1044                 self.parm_idlesince = time;
1045
1046         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1047         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1048 }
1049
1050 /*
1051 =============
1052 ClientKill
1053
1054 Called when a client types 'kill' in the console
1055 =============
1056 */
1057
1058 .float clientkill_nexttime;
1059 void ClientKill_Now_TeamChange()
1060 {
1061         if(self.killindicator_teamchange == -1)
1062         {
1063                 JoinBestTeam( self, FALSE, TRUE );
1064         }
1065         else if(self.killindicator_teamchange == -2)
1066         {
1067                 if(g_ca)
1068                         self.caplayer = 0;
1069                 if(blockSpectators)
1070                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1071                 PutObserverInServer();
1072         }
1073         else
1074                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1075 }
1076
1077 void ClientKill_Now()
1078 {
1079         if(self.vehicle)
1080         {
1081             vehicles_exit(VHEF_RELESE);
1082             if(!self.killindicator_teamchange)
1083             {
1084             self.vehicle_health = -1;
1085             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1086             }
1087         }
1088
1089         if(self.killindicator && !wasfreed(self.killindicator))
1090                 remove(self.killindicator);
1091
1092         self.killindicator = world;
1093
1094         if(self.killindicator_teamchange)
1095                 ClientKill_Now_TeamChange();
1096
1097         // in any case:
1098         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1099
1100         // now I am sure the player IS dead
1101 }
1102 void KillIndicator_Think()
1103 {
1104         if (gameover)
1105         {
1106                 self.owner.killindicator = world;
1107                 remove(self);
1108                 return;
1109         }
1110
1111         if (self.owner.alpha < 0 && !self.owner.vehicle)
1112         {
1113                 self.owner.killindicator = world;
1114                 remove(self);
1115                 return;
1116         }
1117
1118         if(self.cnt <= 0)
1119         {
1120                 self = self.owner;
1121                 ClientKill_Now(); // no oldself needed
1122                 return;
1123         }
1124     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1125     {
1126         self.nextthink = time + 1;
1127         self.cnt -= 1;
1128     }
1129         else
1130         {
1131                 if(self.cnt <= 10)
1132                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1133                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1134                 {
1135                         if(self.cnt <= 10)
1136                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1137                 }
1138                 self.nextthink = time + 1;
1139                 self.cnt -= 1;
1140         }
1141 }
1142
1143 float clientkilltime;
1144 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1145 {
1146         float killtime;
1147         float starttime;
1148         entity e;
1149
1150         if (gameover)
1151                 return;
1152
1153         killtime = autocvar_g_balance_kill_delay;
1154
1155         if(g_race_qualifying || g_cts)
1156                 killtime = 0;
1157
1158     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1159     {
1160                 remove(self.killindicator);
1161                 self.killindicator = world;
1162
1163         ClientKill_Now(); // allow instant kill in this case
1164         return;
1165     }
1166
1167         self.killindicator_teamchange = targetteam;
1168
1169     if(!self.killindicator)
1170         {
1171                 if(self.deadflag == DEAD_NO)
1172                 {
1173                         killtime = max(killtime, self.clientkill_nexttime - time);
1174                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1175                 }
1176
1177                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1178                 {
1179                         ClientKill_Now();
1180                 }
1181                 else
1182                 {
1183                         starttime = max(time, clientkilltime);
1184
1185                         self.killindicator = spawn();
1186                         self.killindicator.owner = self;
1187                         self.killindicator.scale = 0.5;
1188                         setattachment(self.killindicator, self, "");
1189                         setorigin(self.killindicator, '0 0 52');
1190                         self.killindicator.think = KillIndicator_Think;
1191                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1192                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1193                         self.killindicator.cnt = ceil(killtime);
1194                         self.killindicator.count = bound(0, ceil(killtime), 10);
1195                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1196
1197                         for(e = world; (e = find(e, classname, "body")) != world; )
1198                         {
1199                                 if(e.enemy != self)
1200                                         continue;
1201                                 e.killindicator = spawn();
1202                                 e.killindicator.owner = e;
1203                                 e.killindicator.scale = 0.5;
1204                                 setattachment(e.killindicator, e, "");
1205                                 setorigin(e.killindicator, '0 0 52');
1206                                 e.killindicator.think = KillIndicator_Think;
1207                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1208                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1209                                 e.killindicator.cnt = ceil(killtime);
1210                         }
1211                         self.lip = 0;
1212                 }
1213         }
1214         if(self.killindicator)
1215         {
1216                 if(targetteam == 0) // just die
1217                 {
1218                         self.killindicator.colormod = '0 0 0';
1219                         if(clienttype(self) == CLIENTTYPE_REAL)
1220                         if(self.killindicator.cnt > 0)
1221                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1222                 }
1223                 else if(targetteam == -1) // auto
1224                 {
1225                         self.killindicator.colormod = '0 1 0';
1226                         if(clienttype(self) == CLIENTTYPE_REAL)
1227                         if(self.killindicator.cnt > 0)
1228                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1229                 }
1230                 else if(targetteam == -2) // spectate
1231                 {
1232                         self.killindicator.colormod = '0.5 0.5 0.5';
1233                         if(clienttype(self) == CLIENTTYPE_REAL)
1234                         if(self.killindicator.cnt > 0)
1235                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1236                 }
1237                 else
1238                 {
1239                         self.killindicator.colormod = TeamColor(targetteam);
1240                         if(clienttype(self) == CLIENTTYPE_REAL)
1241                         if(self.killindicator.cnt > 0)
1242                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1243                 }
1244         }
1245
1246 }
1247
1248 void ClientKill (void)
1249 {
1250         if (gameover)
1251                 return;
1252
1253         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1254         {
1255                 // do nothing
1256         }
1257     else if(self.freezetag_frozen)
1258     {
1259         // do nothing
1260     }
1261         else
1262                 ClientKill_TeamChange(0);
1263 }
1264
1265 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1266 {
1267     e.killindicator = spawn();
1268     e.killindicator.owner = e;
1269     e.killindicator.think = KillIndicator_Think;
1270     e.killindicator.nextthink = time + (e.lip) * 0.05;
1271     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1272     e.killindicator.health = 1; // this is used to indicate that it should be silent
1273     e.lip = 0;
1274 }
1275
1276 void FixClientCvars(entity e)
1277 {
1278         // send prediction settings to the client
1279         stuffcmd(e, "\nin_bindmap 0 0\n");
1280         if(g_race || g_cts)
1281                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1282         if(autocvar_g_antilag == 3) // client side hitscan
1283                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1284         if(sv_gentle)
1285                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1286         /*
1287          * we no longer need to stuff this. Remove this comment block if you feel
1288          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1289         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1290         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1291         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1292         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1293         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1294         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1295         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1296         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1297         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1298         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1299         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1300         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1301         stuffcmd(e, "cl_movement_edgefriction 1\n");
1302          */
1303 }
1304
1305 float PlayerInIDList(entity p, string idlist)
1306 {
1307         float n, i;
1308         string s;
1309
1310         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1311         if not(p.crypto_idfp)
1312                 return 0;
1313
1314         // this function allows abbreviated player IDs too!
1315         n = tokenize_console(idlist);
1316         for(i = 0; i < n; ++i)
1317         {
1318                 s = argv(i);
1319                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1320                         return 1;
1321         }
1322
1323         return 0;
1324 }
1325
1326 /*
1327 =============
1328 ClientConnect
1329
1330 Called when a client connects to the server
1331 =============
1332 */
1333 string ColoredTeamName(float t);
1334 void DecodeLevelParms (void);
1335 //void dom_player_join_team(entity pl);
1336 void set_dom_state(entity e);
1337 void ClientConnect (void)
1338 {
1339         float t;
1340
1341         if(self.flags & FL_CLIENT)
1342         {
1343                 print("Warning: ClientConnect, but already connected!\n");
1344                 return;
1345         }
1346
1347         if(Ban_MaybeEnforceBanOnce(self))
1348                 return;
1349
1350         DecodeLevelParms();
1351
1352 #ifdef WATERMARK
1353         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1354 #endif
1355
1356         self.classname = "player_joining";
1357
1358         self.flags = FL_CLIENT;
1359         self.version_nagtime = time + 10 + random() * 10;
1360
1361         if(player_count<0)
1362         {
1363                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1364                 player_count = 0;
1365         }
1366
1367         PlayerScore_Attach(self);
1368         ClientData_Attach();
1369         accuracy_init(self);
1370
1371         bot_clientconnect();
1372
1373         playerdemo_init();
1374
1375         anticheat_init();
1376
1377         race_PreSpawnObserver();
1378
1379         // identify the right forced team
1380         if(autocvar_g_campaign)
1381         {
1382                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1383                 {
1384                         switch(autocvar_g_campaign_forceteam)
1385                         {
1386                                 case 1: self.team_forced = COLOR_TEAM1; break;
1387                                 case 2: self.team_forced = COLOR_TEAM2; break;
1388                                 case 3: self.team_forced = COLOR_TEAM3; break;
1389                                 case 4: self.team_forced = COLOR_TEAM4; break;
1390                                 default: self.team_forced = 0;
1391                         }
1392                 }
1393         }
1394         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1395                 self.team_forced = COLOR_TEAM1;
1396         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1397                 self.team_forced = COLOR_TEAM2;
1398         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1399                 self.team_forced = COLOR_TEAM3;
1400         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1401                 self.team_forced = COLOR_TEAM4;
1402         else if(autocvar_g_forced_team_otherwise == "red")
1403                 self.team_forced = COLOR_TEAM1;
1404         else if(autocvar_g_forced_team_otherwise == "blue")
1405                 self.team_forced = COLOR_TEAM2;
1406         else if(autocvar_g_forced_team_otherwise == "yellow")
1407                 self.team_forced = COLOR_TEAM3;
1408         else if(autocvar_g_forced_team_otherwise == "pink")
1409                 self.team_forced = COLOR_TEAM4;
1410         else if(autocvar_g_forced_team_otherwise == "spectate")
1411                 self.team_forced = -1;
1412         else if(autocvar_g_forced_team_otherwise == "spectator")
1413                 self.team_forced = -1;
1414         else
1415                 self.team_forced = 0;
1416
1417         if(!teamplay)
1418                 if(self.team_forced > 0)
1419                         self.team_forced = 0;
1420
1421         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1422
1423         if(autocvar_g_campaign || self.team_forced < 0) {
1424                 self.classname = "observer";
1425         } else {
1426                 if(teamplay)
1427                 {
1428                         if(autocvar_g_balance_teams)
1429                         {
1430                                 self.classname = "player";
1431                                 campaign_bots_may_start = 1;
1432                         }
1433                         else
1434                         {
1435                                 self.classname = "observer"; // do it anyway
1436                         }
1437                 }
1438                 else
1439                 {
1440                         self.classname = "player";
1441                         campaign_bots_may_start = 1;
1442                 }
1443         }
1444
1445         self.playerid = (playerid_last = playerid_last + 1);
1446
1447         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1448
1449     if(clienttype(self) == CLIENTTYPE_BOT)
1450         PlayerStats_AddPlayer(self);
1451
1452         if(autocvar_sv_eventlog)
1453                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1454
1455         LogTeamchange(self.playerid, self.team, 1);
1456
1457         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1458
1459         self.netname_previous = strzone(self.netname);
1460
1461         bprint("^4", self.netname, "^4 connected");
1462
1463         if(self.classname != "observer" && (g_domination || g_ctf))
1464                 bprint(" and joined the ", ColoredTeamName(self.team));
1465
1466         bprint("\n");
1467
1468         stuffcmd(self, strcat(clientstuff, "\n"));
1469         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1470
1471         FixClientCvars(self);
1472
1473         // spawnfunc_waypoint sprites
1474         WaypointSprite_InitClient(self);
1475
1476         // Wazat's grappling hook
1477         SetGrappleHookBindings();
1478
1479         // get version info from player
1480         stuffcmd(self, "cmd clientversion $gameversion\n");
1481
1482         // get other cvars from player
1483         GetCvars(0);
1484
1485         // notify about available teams
1486         if(teamplay)
1487         {
1488                 CheckAllowedTeams(self);
1489                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1490                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1491         }
1492         else
1493                 stuffcmd(self, "set _teams_available 0\n");
1494
1495         if(g_arena || g_ca)
1496         {
1497                 self.classname = "observer";
1498                 if(g_arena)
1499                         Spawnqueue_Insert(self);
1500         }
1501
1502         attach_entcs();
1503
1504         bot_relinkplayerlist();
1505
1506         self.spectatortime = time;
1507         if(blockSpectators)
1508         {
1509                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1510         }
1511
1512         self.jointime = time;
1513         self.allowed_timeouts = autocvar_sv_timeout_number;
1514
1515         if(clienttype(self) == CLIENTTYPE_REAL)
1516         {
1517                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1518                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1519         }
1520
1521         if(!sv_foginterval && world.fog != "")
1522                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1523
1524         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1525         {
1526                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1527                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1528         }
1529         else
1530                 self.hitplotfh = -1;
1531
1532         if(g_race || g_cts) {
1533                 string rr;
1534                 if(g_cts)
1535                         rr = CTS_RECORD;
1536                 else
1537                         rr = RACE_RECORD;
1538
1539                 msg_entity = self;
1540                 race_send_recordtime(MSG_ONE);
1541                 race_send_speedaward(MSG_ONE);
1542
1543                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1544                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1545                 race_send_speedaward_alltimebest(MSG_ONE);
1546
1547                 float i;
1548                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1549                         race_SendRankings(i, 0, 0, MSG_ONE);
1550                 }
1551         }
1552         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1553                 send_CSQC_teamnagger();
1554
1555         CheatInitClient();
1556
1557         if(!autocvar_g_campaign)
1558                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1559
1560         CSQCMODEL_AUTOINIT();
1561
1562         self.model_randomizer = random();
1563
1564     if(clienttype(self) != CLIENTTYPE_REAL)
1565         return;
1566
1567     sv_notice_join();
1568
1569     MUTATOR_CALLHOOK(ClientConnect);
1570 }
1571 /*
1572 =============
1573 ClientDisconnect
1574
1575 Called when a client disconnects from the server
1576 =============
1577 */
1578 .entity chatbubbleentity;
1579 void ReadyCount();
1580 void ClientDisconnect (void)
1581 {
1582         if(self.vehicle)
1583             vehicles_exit(VHEF_RELESE);
1584
1585         if not(self.flags & FL_CLIENT)
1586         {
1587                 print("Warning: ClientDisconnect without ClientConnect\n");
1588                 return;
1589         }
1590
1591         PlayerStats_AddGlobalInfo(self);
1592
1593         CheatShutdownClient();
1594
1595         if(self.hitplotfh >= 0)
1596         {
1597                 fclose(self.hitplotfh);
1598                 self.hitplotfh = -1;
1599         }
1600
1601         anticheat_report();
1602         anticheat_shutdown();
1603
1604         playerdemo_shutdown();
1605
1606         bot_clientdisconnect();
1607
1608         if(self.entcs)
1609                 detach_entcs();
1610
1611         if(autocvar_sv_eventlog)
1612                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1613         bprint ("^4",self.netname);
1614         bprint ("^4 disconnected\n");
1615
1616         DropAllRunes(self);
1617         MUTATOR_CALLHOOK(ClientDisconnect);
1618
1619         Portal_ClearAll(self);
1620
1621         RemoveGrapplingHook(self);
1622
1623         // Here, everything has been done that requires this player to be a client.
1624
1625         self.flags &~= FL_CLIENT;
1626
1627         if (self.chatbubbleentity)
1628                 remove (self.chatbubbleentity);
1629
1630         if (self.killindicator)
1631                 remove (self.killindicator);
1632
1633         WaypointSprite_PlayerGone();
1634
1635         bot_relinkplayerlist();
1636
1637         if(g_arena)
1638         {
1639                 Spawnqueue_Unmark(self);
1640                 Spawnqueue_Remove(self);
1641         }
1642
1643         accuracy_free(self);
1644         ClientData_Detach();
1645         PlayerScore_Detach(self);
1646
1647         if(self.netname_previous)
1648                 strunzone(self.netname_previous);
1649         if(self.clientstatus)
1650                 strunzone(self.clientstatus);
1651         if(self.weaponorder_byimpulse)
1652                 strunzone(self.weaponorder_byimpulse);
1653
1654         ClearPlayerSounds();
1655
1656         if(self.personal)
1657                 remove(self.personal);
1658
1659         self.playerid = 0;
1660         ReadyCount();
1661
1662         // free cvars
1663         GetCvars(-1);
1664 }
1665
1666 .float BUTTON_CHAT;
1667 void ChatBubbleThink()
1668 {
1669         self.nextthink = time;
1670         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1671         {
1672                 if(self.owner) // but why can that ever be world?
1673                         self.owner.chatbubbleentity = world;
1674                 remove(self);
1675                 return;
1676         }
1677         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1678 #ifdef TETRIS
1679                 || self.owner.tetris_on
1680 #endif
1681         )
1682                 self.model = self.mdl;
1683         else
1684                 self.model = "";
1685 }
1686
1687 void UpdateChatBubble()
1688 {
1689         if (self.alpha < 0)
1690                 return;
1691         // spawn a chatbubble entity if needed
1692         if (!self.chatbubbleentity)
1693         {
1694                 self.chatbubbleentity = spawn();
1695                 self.chatbubbleentity.owner = self;
1696                 self.chatbubbleentity.exteriormodeltoclient = self;
1697                 self.chatbubbleentity.think = ChatBubbleThink;
1698                 self.chatbubbleentity.nextthink = time;
1699                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1700                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1701                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1702                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1703                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1704                 self.chatbubbleentity.model = "";
1705                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1706         }
1707 }
1708
1709
1710 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1711 // added to the model skins
1712 /*void UpdateColorModHack()
1713 {
1714         float c;
1715         c = self.clientcolors & 15;
1716         // LordHavoc: only bothering to support white, green, red, yellow, blue
1717              if (!teamplay) self.colormod = '0 0 0';
1718         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1719         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1720         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1721         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1722         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1723         else self.colormod = '1 1 1';
1724 }*/
1725
1726 void respawn(void)
1727 {
1728         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1729         {
1730                 self.solid = SOLID_NOT;
1731                 self.takedamage = DAMAGE_NO;
1732                 self.movetype = MOVETYPE_FLY;
1733                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1734                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1735                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1736                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1737                 if(autocvar_g_respawn_ghosts_maxtime)
1738                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1739         }
1740
1741         CopyBody(1);
1742
1743         self.effects |= EF_NODRAW; // prevent another CopyBody
1744         PutClientInServer();
1745 }
1746
1747 void play_countdown(float finished, string samp)
1748 {
1749         if(clienttype(self) == CLIENTTYPE_REAL)
1750                 if(floor(finished - time - frametime) != floor(finished - time))
1751                         if(finished - time < 6)
1752                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1753 }
1754
1755 void player_powerups (void)
1756 {
1757         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1758         olditems = self.items;
1759
1760         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1761                 self.modelflags |= MF_ROCKET;
1762         else
1763                 self.modelflags &~= MF_ROCKET;
1764
1765         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1766
1767         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1768                 return;
1769
1770         Fire_ApplyDamage(self);
1771         Fire_ApplyEffect(self);
1772
1773         if (g_minstagib)
1774         {
1775                 self.effects |= EF_FULLBRIGHT;
1776
1777                 if (self.items & IT_STRENGTH)
1778                 {
1779                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1780                         if (time > self.strength_finished)
1781                         {
1782                                 self.alpha = default_player_alpha;
1783                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1784                                 self.items &~= IT_STRENGTH;
1785                                 sprint(self, "^3Invisibility has worn off\n");
1786                         }
1787                 }
1788                 else
1789                 {
1790                         if (time < self.strength_finished)
1791                         {
1792                                 self.alpha = g_minstagib_invis_alpha;
1793                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1794                                 self.items |= IT_STRENGTH;
1795                                 sprint(self, "^3You are invisible\n");
1796                         }
1797                 }
1798
1799                 if (self.items & IT_INVINCIBLE)
1800                 {
1801                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1802                         if (time > self.invincible_finished)
1803                         {
1804                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1805                                 sprint(self, "^3Speed has worn off\n");
1806                         }
1807                 }
1808                 else
1809                 {
1810                         if (time < self.invincible_finished)
1811                         {
1812                                 self.items = self.items | IT_INVINCIBLE;
1813                                 sprint(self, "^3You are on speed\n");
1814                         }
1815                 }
1816         }
1817         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1818         {
1819                 if (self.items & IT_STRENGTH)
1820                 {
1821                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1822                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1823                         if (time > self.strength_finished)
1824                         {
1825                                 self.items = self.items - (self.items & IT_STRENGTH);
1826                                 sprint(self, "^3Strength has worn off\n");
1827                         }
1828                 }
1829                 else
1830                 {
1831                         if (time < self.strength_finished)
1832                         {
1833                                 self.items = self.items | IT_STRENGTH;
1834                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1835                         }
1836                 }
1837                 if (self.items & IT_INVINCIBLE)
1838                 {
1839                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1840                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1841                         if (time > self.invincible_finished)
1842                         {
1843                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1844                                 sprint(self, "^3Shield has worn off\n");
1845                         }
1846                 }
1847                 else
1848                 {
1849                         if (time < self.invincible_finished)
1850                         {
1851                                 self.items = self.items | IT_INVINCIBLE;
1852                                 sprint(self, "^3Shield surrounds you\n");
1853                         }
1854                 }
1855                 if (self.items & IT_SUPERWEAPON)
1856                 {
1857                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1858                         {
1859                                 self.superweapons_finished = 0;
1860                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1861                                 sprint(self, "^3Superweapons have been lost\n");
1862                         }
1863                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1864                         {
1865                                 // don't let them run out
1866                         }
1867                         else
1868                         {
1869                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1870                                 if (time > self.superweapons_finished)
1871                                 {
1872                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1873                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1874                                         sprint(self, "^3Superweapons have broken down\n");
1875                                 }
1876                         }
1877                 }
1878                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1879                 {
1880                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1881                         {
1882                                 self.items = self.items | IT_SUPERWEAPON;
1883                                 sprint(self, "^3You now have a superweapon\n");
1884                         }
1885                         else
1886                         {
1887                                 self.superweapons_finished = 0;
1888                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1889                         }
1890                 }
1891                 else
1892                 {
1893                         self.superweapons_finished = 0;
1894                 }
1895         }
1896
1897         if(autocvar_g_nodepthtestplayers)
1898                 self.effects = self.effects | EF_NODEPTHTEST;
1899
1900         if(autocvar_g_fullbrightplayers)
1901                 self.effects = self.effects | EF_FULLBRIGHT;
1902
1903         // midair gamemode: damage only while in the air
1904         // if in midair mode, being on ground grants temporary invulnerability
1905         // (this is so that multishot weapon don't clear the ground flag on the
1906         // first damage in the frame, leaving the player vulnerable to the
1907         // remaining hits in the same frame)
1908         if (self.flags & FL_ONGROUND)
1909         if (g_midair)
1910                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1911
1912         if (time >= game_starttime)
1913         if (time < self.spawnshieldtime)
1914                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1915
1916         MUTATOR_CALLHOOK(PlayerPowerups);
1917 }
1918
1919 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1920 {
1921         if(current > stable)
1922                 return current;
1923         else if(current > stable - 0.25) // when close enough, "snap"
1924                 return stable;
1925         else
1926                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1927 }
1928
1929 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1930 {
1931         if(current < stable)
1932                 return current;
1933         else if(current < stable + 0.25) // when close enough, "snap"
1934                 return stable;
1935         else
1936                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1937 }
1938
1939 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1940 {
1941         if(current > rotstable)
1942         {
1943                 if(rotframetime > 0)
1944                 {
1945                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1946                         current = max(rotstable, current - rotlinear * rotframetime);
1947                 }
1948         }
1949         else if(current < regenstable)
1950         {
1951                 if(regenframetime > 0)
1952                 {
1953                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1954                         current = min(regenstable, current + regenlinear * regenframetime);
1955                 }
1956         }
1957
1958         if(current > limit)
1959                 current = limit;
1960
1961         return current;
1962 }
1963
1964 void player_regen (void)
1965 {
1966         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1967         maxh = autocvar_g_balance_health_rotstable;
1968         maxa = autocvar_g_balance_armor_rotstable;
1969         maxf = autocvar_g_balance_fuel_rotstable;
1970         minh = autocvar_g_balance_health_regenstable;
1971         mina = autocvar_g_balance_armor_regenstable;
1972         minf = autocvar_g_balance_fuel_regenstable;
1973         limith = autocvar_g_balance_health_limit;
1974         limita = autocvar_g_balance_armor_limit;
1975         limitf = autocvar_g_balance_fuel_limit;
1976
1977         max_mod = regen_mod = rot_mod = limit_mod = 1;
1978
1979         if (self.runes & RUNE_REGEN)
1980         {
1981                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1982                 {
1983                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1984                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1985                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1986                 }
1987                 else
1988                 {
1989                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1990                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1991                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1992                 }
1993         }
1994         else if (self.runes & CURSE_VENOM)
1995         {
1996                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1997                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1998                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1999                 else
2000                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2001                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2002                 //if (!self.runes & RUNE_REGEN)
2003                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2004         }
2005         maxh = maxh * max_mod;
2006         //maxa = maxa * max_mod;
2007         //maxf = maxf * max_mod;
2008         minh = minh * max_mod;
2009         //mina = mina * max_mod;
2010         //minf = minf * max_mod;
2011         limith = limith * limit_mod;
2012         limita = limita * limit_mod;
2013         //limitf = limitf * limit_mod;
2014
2015         if(g_lms && g_ca)
2016                 rot_mod = 0;
2017
2018         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2019         {
2020                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2021                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2022
2023                 // if player rotted to death...  die!
2024                 if(self.health < 1)
2025                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2026         }
2027
2028         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2029                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2030 }
2031
2032 float zoomstate_set;
2033 void SetZoomState(float z)
2034 {
2035         if(z != self.zoomstate)
2036         {
2037                 self.zoomstate = z;
2038                 ClientData_Touch(self);
2039         }
2040         zoomstate_set = 1;
2041 }
2042
2043 void GetPressedKeys(void) {
2044         MUTATOR_CALLHOOK(GetPressedKeys);
2045         if (self.movement_x > 0) // get if movement keys are pressed
2046         {       // forward key pressed
2047                 self.pressedkeys |= KEY_FORWARD;
2048                 self.pressedkeys &~= KEY_BACKWARD;
2049         }
2050         else if (self.movement_x < 0)
2051         {       // backward key pressed
2052                 self.pressedkeys |= KEY_BACKWARD;
2053                 self.pressedkeys &~= KEY_FORWARD;
2054         }
2055         else
2056         {       // no x input
2057                 self.pressedkeys &~= KEY_FORWARD;
2058                 self.pressedkeys &~= KEY_BACKWARD;
2059         }
2060
2061         if (self.movement_y > 0)
2062         {       // right key pressed
2063                 self.pressedkeys |= KEY_RIGHT;
2064                 self.pressedkeys &~= KEY_LEFT;
2065         }
2066         else if (self.movement_y < 0)
2067         {       // left key pressed
2068                 self.pressedkeys |= KEY_LEFT;
2069                 self.pressedkeys &~= KEY_RIGHT;
2070         }
2071         else
2072         {       // no y input
2073                 self.pressedkeys &~= KEY_RIGHT;
2074                 self.pressedkeys &~= KEY_LEFT;
2075         }
2076
2077         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2078                 self.pressedkeys |= KEY_JUMP;
2079         else
2080                 self.pressedkeys &~= KEY_JUMP;
2081         if (self.BUTTON_CROUCH)
2082                 self.pressedkeys |= KEY_CROUCH;
2083         else
2084                 self.pressedkeys &~= KEY_CROUCH;
2085
2086         if (self.BUTTON_ATCK)
2087                 self.pressedkeys |= KEY_ATCK;
2088         else
2089                 self.pressedkeys &~= KEY_ATCK;
2090         if (self.BUTTON_ATCK2)
2091                 self.pressedkeys |= KEY_ATCK2;
2092         else
2093                 self.pressedkeys &~= KEY_ATCK2;
2094 }
2095
2096 /*
2097 ======================
2098 spectate mode routines
2099 ======================
2100 */
2101
2102 void SpectateCopy(entity spectatee) {
2103         other = spectatee;
2104         MUTATOR_CALLHOOK(SpectateCopy);
2105         self.armortype = spectatee.armortype;
2106         self.armorvalue = spectatee.armorvalue;
2107         self.ammo_cells = spectatee.ammo_cells;
2108         self.ammo_shells = spectatee.ammo_shells;
2109         self.ammo_nails = spectatee.ammo_nails;
2110         self.ammo_rockets = spectatee.ammo_rockets;
2111         self.ammo_fuel = spectatee.ammo_fuel;
2112         self.clip_load = spectatee.clip_load;
2113         self.clip_size = spectatee.clip_size;
2114         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2115         self.health = spectatee.health;
2116         self.impulse = 0;
2117         self.items = spectatee.items;
2118         self.last_pickup = spectatee.last_pickup;
2119         self.hit_time = spectatee.hit_time;
2120         self.metertime = spectatee.metertime;
2121         self.strength_finished = spectatee.strength_finished;
2122         self.invincible_finished = spectatee.invincible_finished;
2123         self.pressedkeys = spectatee.pressedkeys;
2124         WEPSET_COPY_EE(self, spectatee);
2125         self.switchweapon = spectatee.switchweapon;
2126         self.switchingweapon = spectatee.switchingweapon;
2127         self.weapon = spectatee.weapon;
2128         self.nex_charge = spectatee.nex_charge;
2129         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2130         self.hagar_load = spectatee.hagar_load;
2131         self.minelayer_mines = spectatee.minelayer_mines;
2132         self.punchangle = spectatee.punchangle;
2133         self.view_ofs = spectatee.view_ofs;
2134         self.velocity = spectatee.velocity;
2135         self.dmg_take = spectatee.dmg_take;
2136         self.dmg_save = spectatee.dmg_save;
2137         self.dmg_inflictor = spectatee.dmg_inflictor;
2138         self.v_angle = spectatee.v_angle;
2139         self.angles = spectatee.v_angle;
2140         self.stat_respawn_time = spectatee.stat_respawn_time;
2141         if(!self.BUTTON_USE)
2142                 self.fixangle = TRUE;
2143         setorigin(self, spectatee.origin);
2144         setsize(self, spectatee.mins, spectatee.maxs);
2145         SetZoomState(spectatee.zoomstate);
2146
2147     anticheat_spectatecopy(spectatee);
2148         self.hud = spectatee.hud;
2149         if(spectatee.vehicle)
2150     {
2151         self.fixangle = FALSE;
2152         //self.velocity = spectatee.vehicle.velocity;
2153         self.vehicle_health = spectatee.vehicle_health;
2154         self.vehicle_shield = spectatee.vehicle_shield;
2155         self.vehicle_energy = spectatee.vehicle_energy;
2156         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2157         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2158         self.vehicle_reload1 = spectatee.vehicle_reload1;
2159         self.vehicle_reload2 = spectatee.vehicle_reload2;
2160
2161         msg_entity = self;
2162
2163         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2164             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2165             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2166             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2167
2168         //WriteByte (MSG_ONE, SVC_SETVIEW);
2169         //    WriteEntity(MSG_ONE, self);
2170         //makevectors(spectatee.v_angle);
2171         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2172     }
2173 }
2174
2175 float SpectateUpdate() {
2176         if(!self.enemy)
2177             return 0;
2178
2179         if (self == self.enemy)
2180                 return 0;
2181
2182         if(self.enemy.classname != "player")
2183                 return 0;
2184
2185         SpectateCopy(self.enemy);
2186
2187         return 1;
2188 }
2189
2190
2191 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2192 entity CA_SpectateNext(entity start) {
2193         if (start.team == self.team) {
2194                 return start;
2195         }
2196
2197         other = start;
2198         // continue from current player
2199         while(other && other.team != self.team) {
2200                 other = find(other, classname, "player");
2201         }
2202
2203         if (!other) {
2204                 // restart from begining
2205                 other = find(other, classname, "player");
2206                 while(other && other.team != self.team) {
2207                         other = find(other, classname, "player");
2208                 }
2209         }
2210
2211         return other;
2212 }
2213
2214 float SpectateNext(entity _prefer) {
2215
2216         if(_prefer)
2217                 other = _prefer;
2218         else
2219                 other = find(self.enemy, classname, "player");
2220
2221         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2222                 // CA and ca players when spectating enemies is forbidden
2223                 other = CA_SpectateNext(other);
2224         } else {
2225                 // other modes and ca spectators or spectating enemies is allowed
2226                 if (!other)
2227                         other = find(other, classname, "player");
2228         }
2229
2230         if (other)
2231                 self.enemy = other;
2232
2233         if(self.enemy.classname == "player") {
2234             /*if(self.enemy.vehicle)
2235             {
2236
2237             msg_entity = self;
2238             WriteByte(MSG_ONE, SVC_SETVIEW);
2239             WriteEntity(MSG_ONE, self.enemy);
2240             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2241
2242             self.movetype = MOVETYPE_NONE;
2243             accuracy_resend(self);
2244             }
2245             else
2246             {*/
2247             msg_entity = self;
2248             WriteByte(MSG_ONE, SVC_SETVIEW);
2249             WriteEntity(MSG_ONE, self.enemy);
2250             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2251             self.movetype = MOVETYPE_NONE;
2252             accuracy_resend(self);
2253
2254             if(!SpectateUpdate())
2255                 PutObserverInServer();
2256         //}
2257         return 1;
2258         } else {
2259                 return 0;
2260         }
2261 }
2262
2263 /*
2264 =============
2265 ShowRespawnCountdown()
2266
2267 Update a respawn countdown display.
2268 =============
2269 */
2270 void ShowRespawnCountdown()
2271 {
2272         float number;
2273         if(self.deadflag == DEAD_NO) // just respawned?
2274                 return;
2275         else
2276         {
2277                 number = ceil(self.respawn_time - time);
2278                 if(number <= 0)
2279                         return;
2280                 if(number <= self.respawn_countdown)
2281                 {
2282                         self.respawn_countdown = number - 1;
2283                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2284                                 AnnounceTo(self, strcat(ftos(number), ""));
2285                 }
2286         }
2287 }
2288
2289 .float prevent_join_msgtime;
2290 void LeaveSpectatorMode()
2291 {
2292         if(nJoinAllowed(self)) {
2293                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2294                         self.classname = "player";
2295
2296                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2297                                 JoinBestTeam(self, FALSE, TRUE);
2298
2299                         if(autocvar_g_campaign)
2300                                 campaign_bots_may_start = 1;
2301
2302                         PutClientInServer();
2303
2304                         if(self.classname == "player")
2305                                 bprint ("^4", self.netname, "^4 is playing now\n");
2306
2307                         if(!autocvar_g_campaign)
2308                         if (time < self.jointime + autocvar_welcome_message_time)
2309                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2310
2311                         if (self.prevent_join_msgtime)
2312                         {
2313                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2314                                 self.prevent_join_msgtime = 0;
2315                         }
2316
2317                         return;
2318                 } else {
2319                         if (g_ca && self.caplayer) {
2320                         }       // do nothing
2321                         else
2322                                 stuffcmd(self,"menu_showteamselect\n");
2323                         return;
2324                 }
2325         }
2326         else {
2327                 //player may not join because of g_maxplayers is set
2328                 if (time - self.prevent_join_msgtime > 2)
2329                 {
2330                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2331                         self.prevent_join_msgtime = time;
2332                 }
2333         }
2334 }
2335
2336 /**
2337  * Determines whether the player is allowed to join. This depends on cvar
2338  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2339  * it checks whether the number of currently playing players exceeds g_maxplayers.
2340  * @return int number of free slots for players, 0 if none
2341  */
2342 float nJoinAllowed(entity ignore) {
2343         if(!ignore)
2344         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2345         // so report 0 free slots if restricted
2346         {
2347                 if(autocvar_g_forced_team_otherwise == "spectate")
2348                         return 0;
2349                 if(autocvar_g_forced_team_otherwise == "spectator")
2350                         return 0;
2351         }
2352
2353         if(self.team_forced < 0)
2354                 return 0; // forced spectators can never join
2355
2356         // TODO simplify this
2357         entity e;
2358         float totalClients = 0;
2359         FOR_EACH_CLIENT(e)
2360                 if(e != ignore)
2361                         totalClients += 1;
2362
2363         if (!autocvar_g_maxplayers)
2364                 return maxclients - totalClients;
2365
2366         float currentlyPlaying = 0;
2367         FOR_EACH_REALPLAYER(e)
2368                 currentlyPlaying += 1;
2369
2370         if(currentlyPlaying < autocvar_g_maxplayers)
2371                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2372
2373         return 0;
2374 }
2375
2376 /**
2377  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2378  * g_maxplayers_spectator_blocktime seconds
2379  */
2380 void checkSpectatorBlock() {
2381         if(self.classname == "spectator" || self.classname == "observer") {
2382                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2383                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2384                         dropclient(self);
2385                 }
2386         }
2387 }
2388
2389 .float motd_actived_time; // used for both motd and campaign_message
2390 void PrintWelcomeMessage()
2391 {
2392         if (self.motd_actived_time == 0) { // is there already a message showing?
2393                 if (autocvar_g_campaign) {
2394                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2395                                 self.motd_actived_time = time;
2396                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2397                         }
2398                 } else {
2399                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2400                                 self.motd_actived_time = time;
2401                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2402                         }
2403                 }
2404         } else { // showing MOTD or campaign message
2405                 if (autocvar_g_campaign) {
2406                         if (self.BUTTON_INFO)
2407                                 self.motd_actived_time = time;
2408                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2409                                 self.motd_actived_time = 0;
2410                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2411                         }
2412                 } else {
2413                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2414                                 if (self.BUTTON_INFO)
2415                                         self.motd_actived_time = time;
2416                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2417                                         self.motd_actived_time = 0;
2418                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2419                                 }
2420                         }
2421                 }
2422         }
2423 }
2424
2425 void ObserverThink()
2426 {
2427         float prefered_movetype;
2428         if (self.flags & FL_JUMPRELEASED) {
2429                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         self.flags |= FL_SPAWNING;
2432                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2433                         self.flags &~= FL_JUMPRELEASED;
2434                         if(SpectateNext(world) == 1) {
2435                                 self.classname = "spectator";
2436                         }
2437                 } else {
2438                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2439                         if (self.movetype != prefered_movetype)
2440                                 self.movetype = prefered_movetype;
2441                 }
2442         } else {
2443                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2444                         self.flags |= FL_JUMPRELEASED;
2445                         if(self.flags & FL_SPAWNING)
2446                         {
2447                                 self.flags &~= FL_SPAWNING;
2448                                 LeaveSpectatorMode();
2449                                 return;
2450                         }
2451                 }
2452         }
2453
2454         PrintWelcomeMessage();
2455 }
2456
2457 void SpectatorThink()
2458 {
2459         if (self.flags & FL_JUMPRELEASED) {
2460                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         self.flags |= FL_SPAWNING;
2463                 } else if(self.BUTTON_ATCK) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         if(SpectateNext(world) == 1) {
2466                                 self.classname = "spectator";
2467                         } else {
2468                                 self.classname = "observer";
2469                                 PutClientInServer();
2470                         }
2471                 } else if (self.BUTTON_ATCK2) {
2472                         self.flags &~= FL_JUMPRELEASED;
2473                         self.classname = "observer";
2474                         PutClientInServer();
2475                 } else {
2476                         if(!SpectateUpdate())
2477                                 PutObserverInServer();
2478                 }
2479         } else {
2480                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2481                         self.flags |= FL_JUMPRELEASED;
2482                         if(self.flags & FL_SPAWNING)
2483                         {
2484                                 self.flags &~= FL_SPAWNING;
2485                                 LeaveSpectatorMode();
2486                                 return;
2487                         }
2488                 }
2489                 if(!SpectateUpdate())
2490                         PutObserverInServer();
2491         }
2492
2493         PrintWelcomeMessage();
2494         self.flags |= FL_CLIENT | FL_NOTARGET;
2495 }
2496
2497 void PlayerUseKey()
2498 {
2499         if(self.classname != "player")
2500                 return;
2501
2502         if(self.vehicle)
2503         {
2504         vehicles_exit(VHEF_NORMAL);
2505         return;
2506         }
2507
2508         // a use key was pressed; call handlers
2509         MUTATOR_CALLHOOK(PlayerUseKey);
2510 }
2511
2512 .float touchexplode_time;
2513
2514 /*
2515 =============
2516 PlayerPreThink
2517
2518 Called every frame for each client before the physics are run
2519 =============
2520 */
2521 .float usekeypressed;
2522 void() nexball_setstatus;
2523 .float items_added;
2524 void PlayerPreThink (void)
2525 {
2526         WarpZone_PlayerPhysics_FixVAngle();
2527
2528         self.stat_game_starttime = game_starttime;
2529         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2530         self.stat_leadlimit = autocvar_leadlimit;
2531
2532         if(g_arena || (g_ca && !allowed_to_spawn))
2533                 self.stat_respawn_time = 0;
2534         else
2535                 self.stat_respawn_time = self.respawn_time;
2536
2537         if(frametime)
2538         {
2539                 // physics frames: update anticheat stuff
2540                 anticheat_prethink();
2541         }
2542
2543         if(blockSpectators && frametime)
2544                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2545                 checkSpectatorBlock();
2546
2547         zoomstate_set = 0;
2548
2549         if(self.netname_previous != self.netname)
2550         {
2551                 if(autocvar_sv_eventlog)
2552                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2553                 if(self.netname_previous)
2554                         strunzone(self.netname_previous);
2555                 self.netname_previous = strzone(self.netname);
2556         }
2557
2558         // version nagging
2559         if(self.version_nagtime)
2560                 if(self.cvar_g_xonoticversion)
2561                         if(time > self.version_nagtime)
2562                         {
2563                                 // don't notify git users
2564                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2565                                 {
2566                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2567                                         {
2568                                                 // notify release users if connecting to git
2569                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2570                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2571                                         }
2572                                         else
2573                                         {
2574                                                 float r;
2575                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2576                                                 if(r < 0)
2577                                                 {
2578                                                         // give users new version
2579                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2580                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2581                                                 }
2582                                                 else if(r > 0)
2583                                                 {
2584                                                         // notify users about old server version
2585                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2586                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2587                                                 }
2588                                         }
2589                                 }
2590                                 self.version_nagtime = 0;
2591                         }
2592
2593         // GOD MODE info
2594         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2595         {
2596                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2597                 self.max_armorvalue = 0;
2598         }
2599
2600 #ifdef TETRIS
2601         if (TetrisPreFrame())
2602                 return;
2603 #endif
2604
2605         MUTATOR_CALLHOOK(PlayerPreThink);
2606
2607         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2608         {
2609                 if(self.BUTTON_USE && !self.usekeypressed)
2610                         PlayerUseKey();
2611                 self.usekeypressed = self.BUTTON_USE;
2612         }
2613
2614         PrintWelcomeMessage();
2615
2616         if(self.classname == "player") {
2617 //              if(self.netname == "Wazat")
2618 //                      bprint(self.classname, "\n");
2619
2620                 CheckRules_Player();
2621
2622                 if (intermission_running)
2623                 {
2624                         IntermissionThink ();   // otherwise a button could be missed between
2625                         return;                                 // the think tics
2626                 }
2627
2628                 //don't allow the player to turn around while game is paused!
2629                 if(timeout_status == TIMEOUT_ACTIVE) {
2630                         // FIXME turn this into CSQC stuff
2631                         self.v_angle = self.lastV_angle;
2632                         self.angles = self.lastV_angle;
2633                         self.fixangle = TRUE;
2634                 }
2635
2636                 if(frametime)
2637                 {
2638 #ifndef NO_LEGACY_NETWORKING
2639                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2640 #endif
2641
2642                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2643                         {
2644                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2645                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2646                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2647
2648                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2649                                 {
2650                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2651                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2652                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2653                                 }
2654                         }
2655                         else
2656                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2657
2658                         player_powerups();
2659                 }
2660
2661                 if (g_minstagib)
2662                         minstagib_ammocheck();
2663
2664                 if (self.deadflag != DEAD_NO)
2665                 {
2666                         float button_pressed, force_respawn;
2667                         if(self.personal && g_race_qualifying)
2668                         {
2669                                 if(time > self.respawn_time)
2670                                 {
2671                                         self.respawn_time = time + 1; // only retry once a second
2672                                         respawn();
2673                                         self.impulse = 141;
2674                                 }
2675                         }
2676                         else
2677                         {
2678                                 if(frametime)
2679                                         player_anim();
2680                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2681                                 force_respawn = (g_ca || g_cts || autocvar_g_forced_respawn);
2682                                 if (self.deadflag == DEAD_DYING)
2683                                 {
2684                                         if(force_respawn)
2685                                                 self.deadflag = DEAD_RESPAWNING;
2686                                         else if(!button_pressed)
2687                                                 self.deadflag = DEAD_DEAD;
2688                                 }
2689                                 else if (self.deadflag == DEAD_DEAD)
2690                                 {
2691                                         if(button_pressed)
2692                                                 self.deadflag = DEAD_RESPAWNABLE;
2693                                 }
2694                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2695                                 {
2696                                         if(!button_pressed)
2697                                                 self.deadflag = DEAD_RESPAWNING;
2698                                 }
2699                                 else if (self.deadflag == DEAD_RESPAWNING)
2700                                 {
2701                                         if(time > self.respawn_time)
2702                                         {
2703                                                 self.respawn_time = time + 1; // only retry once a second
2704                                                 respawn();
2705                                         }
2706                                 }
2707                                 ShowRespawnCountdown();
2708                         }
2709
2710                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2711                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2712                                 self.stat_respawn_time *= -1;
2713
2714                         return;
2715                 }
2716                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2717                 // so (self.deadflag == DEAD_NO) is always true in the code below
2718
2719                 if(g_touchexplode)
2720                 if(time > self.touchexplode_time)
2721                 if(self.classname == "player")
2722                 if(self.deadflag == DEAD_NO)
2723                 if not(IS_INDEPENDENT_PLAYER(self))
2724                 FOR_EACH_PLAYER(other) if(self != other)
2725                 {
2726                         if(time > other.touchexplode_time)
2727                         if(other.deadflag == DEAD_NO)
2728                         if not(IS_INDEPENDENT_PLAYER(other))
2729                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2730                         {
2731                                 PlayerTouchExplode(self, other);
2732                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2733                         }
2734                 }
2735
2736                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2737                 {
2738                         vector dist;
2739
2740                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2741                         dist = self.prevorigin - self.origin;
2742                         dist_z = 0;
2743                         self.lms_traveled_distance += fabs(vlen(dist));
2744
2745                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2746                         {
2747                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2748                                 self.lms_traveled_distance = 0;
2749                         }
2750
2751                         if(time > self.lms_nextcheck)
2752                         {
2753                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2754                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2755                                 {
2756                                         centerprint(self, autocvar_g_lms_campcheck_message);
2757                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2758                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2759                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2760                                 }
2761                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2762                                 self.lms_traveled_distance = 0;
2763                         }
2764                 }
2765
2766                 self.prevorigin = self.origin;
2767
2768                 if (!self.vehicle)
2769                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2770                 {
2771                         if (!self.crouch)
2772                         {
2773                                 self.crouch = TRUE;
2774                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2775                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2776                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2777                         }
2778                 }
2779                 else
2780                 {
2781                         if (self.crouch)
2782                         {
2783                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2784                                 if (!trace_startsolid)
2785                                 {
2786                                         self.crouch = FALSE;
2787                                         self.view_ofs = PL_VIEW_OFS;
2788                                         setsize (self, PL_MIN, PL_MAX);
2789                                 }
2790                         }
2791                 }
2792
2793                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2794                 {
2795                         if(self.bloodloss_timer < time)
2796                         {
2797                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2798                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2799                         }
2800                 }
2801
2802                 FixPlayermodel();
2803
2804                 GrapplingHookFrame();
2805
2806                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2807                 //if(frametime)
2808                 {
2809                         self.items &~= self.items_added;
2810
2811                         W_WeaponFrame();
2812
2813                         self.items_added = 0;
2814                         if(self.items & IT_JETPACK)
2815                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2816                                         self.items_added |= IT_FUEL;
2817
2818                         self.items |= self.items_added;
2819                 }
2820
2821                 player_regen();
2822
2823                 // rot nex charge to the charge limit
2824                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2825                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2826
2827                 if(frametime)
2828                         player_anim();
2829
2830                 if(g_nexball)
2831                         nexball_setstatus();
2832
2833                 // secret status
2834                 secrets_setstatus();
2835
2836                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2837
2838                 //self.angles_y=self.v_angle_y + 90;   // temp
2839         } else if(gameover) {
2840                 if (intermission_running)
2841                         IntermissionThink ();   // otherwise a button could be missed between
2842                 return;
2843         } else if(self.classname == "observer") {
2844                 ObserverThink();
2845         } else if(self.classname == "spectator") {
2846                 SpectatorThink();
2847         }
2848
2849         if(!zoomstate_set)
2850                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2851
2852         float oldspectatee_status;
2853         oldspectatee_status = self.spectatee_status;
2854         if(self.classname == "spectator")
2855                 self.spectatee_status = num_for_edict(self.enemy);
2856         else if(self.classname == "observer")
2857                 self.spectatee_status = num_for_edict(self);
2858         else
2859                 self.spectatee_status = 0;
2860         if(self.spectatee_status != oldspectatee_status)
2861         {
2862                 ClientData_Touch(self);
2863                 if(g_race || g_cts)
2864                         race_InitSpectator();
2865         }
2866
2867         if(self.teamkill_soundtime)
2868         if(time > self.teamkill_soundtime)
2869         {
2870                 self.teamkill_soundtime = 0;
2871
2872                 entity oldpusher, oldself;
2873
2874                 oldself = self; self = self.teamkill_soundsource;
2875                 oldpusher = self.pusher; self.pusher = oldself;
2876
2877                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2878
2879                 self.pusher = oldpusher;
2880                 self = oldself;
2881         }
2882
2883         if(self.taunt_soundtime)
2884         if(time > self.taunt_soundtime)
2885         {
2886                 self.taunt_soundtime = 0;
2887                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2888         }
2889
2890         target_voicescript_next(self);
2891
2892         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2893         if(!self.weapon)
2894                 self.clip_load = self.clip_size = 0;
2895 }
2896
2897 float isInvisibleString(string s)
2898 {
2899         float i, n, c;
2900         s = strdecolorize(s);
2901         for((i = 0), (n = strlen(s)); i < n; ++i)
2902         {
2903                 c = str2chr(s, i);
2904                 switch(c)
2905                 {
2906                         case 0:
2907                         case 32: // space
2908                                 break;
2909                         case 192: // charmap space
2910                                 if (!autocvar_utf8_enable)
2911                                         break;
2912                                 return FALSE;
2913                         case 160: // space in unicode fonts
2914                         case 0xE000 + 192: // utf8 charmap space
2915                                 if (autocvar_utf8_enable)
2916                                         break;
2917                         default:
2918                                 return FALSE;
2919                 }
2920         }
2921         return TRUE;
2922 }
2923
2924 /*
2925 =============
2926 PlayerPostThink
2927
2928 Called every frame for each client after the physics are run
2929 =============
2930 */
2931 .float idlekick_lasttimeleft;
2932 .entity showheadshotbbox;
2933 void showheadshotbbox_think()
2934 {
2935         if(self.owner.showheadshotbbox != self)
2936         {
2937                 remove(self);
2938                 return;
2939         }
2940         self.nextthink = time;
2941         setorigin(self, self.owner.origin);
2942         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2943 }
2944 void PlayerPostThink (void)
2945 {
2946         // Savage: Check for nameless players
2947         if (isInvisibleString(self.netname)) {
2948                 self.netname = "Player";
2949                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2950         }
2951
2952         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2953         {
2954                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2955                 {
2956                         if(self.idlekick_lasttimeleft)
2957                         {
2958                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2959                                 self.idlekick_lasttimeleft = 0;
2960                         }
2961                 }
2962                 else
2963                 {
2964                         float timeleft;
2965                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2966                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2967                         {
2968                                 if(!self.idlekick_lasttimeleft)
2969                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2970                         }
2971                         if(timeleft <= 0)
2972                         {
2973                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2974                                 AnnounceTo(self, "terminated");
2975                                 dropclient(self);
2976                                 return;
2977                         }
2978                         else if(timeleft <= 10)
2979                         {
2980                                 if(timeleft != self.idlekick_lasttimeleft)
2981                                         AnnounceTo(self, ftos(timeleft));
2982                                 self.idlekick_lasttimeleft = timeleft;
2983                         }
2984                 }
2985         }
2986
2987 #ifdef TETRIS
2988         if(self.impulse == 100)
2989                 ImpulseCommands();
2990         if (!TetrisPostFrame())
2991         {
2992 #endif
2993
2994         CheatFrame();
2995
2996         //CheckPlayerJump();
2997
2998         if(self.classname == "player") {
2999                 CheckRules_Player();
3000                 UpdateChatBubble();
3001                 if (self.impulse)
3002                         ImpulseCommands();
3003                 if (intermission_running)
3004                         return;         // intermission or finale
3005                 GetPressedKeys();
3006         }
3007
3008 #ifdef TETRIS
3009         }
3010 #endif
3011
3012         /*
3013         float i;
3014         for(i = 0; i < 1000; ++i)
3015         {
3016                 vector end;
3017                 end = self.origin + '0 0 1024' + 512 * randomvec();
3018                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3019                 if(trace_fraction < 1)
3020                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3021                 {
3022                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3023                         break;
3024                 }
3025         }
3026         */
3027
3028         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3029
3030         if(self.waypointsprite_attachedforcarrier)
3031                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3032
3033         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3034         {
3035                 if(!self.showheadshotbbox)
3036                 {
3037                         self.showheadshotbbox = spawn();
3038                         self.showheadshotbbox.classname = "headshotbbox";
3039                         self.showheadshotbbox.owner = self;
3040                         self.showheadshotbbox.think = showheadshotbbox_think;
3041                         self.showheadshotbbox.nextthink = time;
3042                         self = self.showheadshotbbox;
3043                         self.think();
3044                         self = self.owner;
3045                 }
3046         }
3047         else
3048         {
3049                 if(self.showheadshotbbox)
3050                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3051                 remove(self.showheadshotbbox);
3052         }
3053
3054         playerdemo_write();
3055
3056         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3057         {
3058                 if not(self.stored_netname)
3059                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3060                 if(self.stored_netname != self.netname)
3061                 {
3062                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3063                         strunzone(self.stored_netname);
3064                         self.stored_netname = strzone(self.netname);
3065                 }
3066         }
3067
3068         /*
3069         if(g_race)
3070                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3071         */
3072
3073         CSQCMODEL_AUTOUPDATE();
3074 }