qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (g_arena && arena_roundbased)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = SUB_Null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.runes = 0;
 478         self.deadflag = DEAD_NO;
 479         self.angles = spot.angles;
 480         self.angles_z = 0;
 481         self.fixangle = TRUE;
 482         self.crouch = FALSE;
 483
 484         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 485         self.prevorigin = self.origin;
 486         self.items = 0;
 487         WEPSET_CLEAR_E(self);
 488         self.model = "";
 489         FixPlayermodel();
 490         setmodel(self, "null");
 491         self.drawonlytoclient = self;
 492
 493         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 494         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 495
 496         self.weapon = 0;
 497         self.weaponname = "";
 498         self.switchingweapon = 0;
 499         self.weaponmodel = "";
 500         self.weaponentity = world;
 501         self.exteriorweaponentity = world;
 502         self.killcount = -666;
 503         self.velocity = '0 0 0';
 504         self.avelocity = '0 0 0';
 505         self.punchangle = '0 0 0';
 506         self.punchvector = '0 0 0';
 507         self.oldvelocity = self.velocity;
 508         self.fire_endtime = -1;
 509
 510         if(g_arena)
 511         {
 512                 if(self.version_mismatch)
 513                 {
 514                         Spawnqueue_Unmark(self);
 515                         Spawnqueue_Remove(self);
 516                 }
 517                 else
 518                 {
 519                         Spawnqueue_Insert(self);
 520                 }
 521         }
 522         else if(g_lms)
 523         {
 524                 // Only if the player cannot play at all
 525                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 526                         self.frags = FRAGS_SPECTATOR;
 527                 else
 528                         self.frags = FRAGS_LMS_LOSER;
 529         }
 530         else if(g_ca)
 531         {
 532                 if(self.caplayer)
 533                         self.frags = FRAGS_LMS_LOSER;
 534                 else
 535                         self.frags = FRAGS_SPECTATOR;
 536         }
 537         else
 538                 self.frags = FRAGS_SPECTATOR;
 539 }
 540
 541 .float model_randomizer;
 542 void FixPlayermodel()
 543 {
 544         string defaultmodel;
 545         float defaultskin, chmdl, oldskin, n, i;
 546         vector m1, m2;
 547
 548         defaultmodel = "";
 549         defaultskin = 0;
 550         chmdl = FALSE;
 551
 552         if(autocvar_sv_defaultcharacter == 1)
 553         {
 554                 if(teamplay)
 555                 {
 556                         string s;
 557                         s = Team_ColorNameLowerCase(self.team);
 558                         if(s != "neutral")
 559                         {
 560                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 561                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 562                         }
 563                 }
 564
 565                 if(defaultmodel == "")
 566                 {
 567                         defaultmodel = autocvar_sv_defaultplayermodel;
 568                         defaultskin = autocvar_sv_defaultplayerskin;
 569                 }
 570
 571                 n = tokenize_console(defaultmodel);
 572                 if(n > 0)
 573                         defaultmodel = argv(floor(n * self.model_randomizer));
 574
 575                 i = strstrofs(defaultmodel, ":", 0);
 576                 if(i >= 0)
 577                 {
 578                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 579                         defaultmodel = substring(defaultmodel, 0, i);
 580                 }
 581         }
 582
 583         if(defaultmodel != "")
 584         {
 585                 if (defaultmodel != self.model)
 586                 {
 587                         m1 = self.mins;
 588                         m2 = self.maxs;
 589                         setplayermodel (self, defaultmodel);
 590                         setsize (self, m1, m2);
 591                         chmdl = TRUE;
 592                 }
 593
 594                 oldskin = self.skin;
 595                 self.skin = defaultskin;
 596         } else {
 597                 if (self.playermodel != self.model || self.playermodel == "")
 598                 {
 599                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 600                         m1 = self.mins;
 601                         m2 = self.maxs;
 602                         setplayermodel (self, self.playermodel);
 603                         setsize (self, m1, m2);
 604                         chmdl = TRUE;
 605                 }
 606
 607                 oldskin = self.skin;
 608                 self.skin = stof(self.playerskin);
 609         }
 610
 611         if(chmdl || oldskin != self.skin)
 612                 self.species = player_getspecies(); // model or skin has changed
 613
 614         if(!teamplay)
 615                 if(strlen(autocvar_sv_defaultplayercolors))
 616                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 617                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 618 }
 619
 620 void PlayerTouchExplode(entity p1, entity p2)
 621 {
 622         vector org;
 623         org = (p1.origin + p2.origin) * 0.5;
 624         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 625
 626         te_explosion(org);
 627
 628         entity e;
 629         e = spawn();
 630         setorigin(e, org);
 631         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 632         remove(e);
 633 }
 634
 635 /*
 636 =============
 637 PutClientInServer
 638
 639 Called when a client spawns in the server
 640 =============
 641 */
 642
 643 void PutClientInServer (void)
 644 {
 645         if(clienttype(self) == CLIENTTYPE_BOT)
 646         {
 647                 self.classname = "player";
 648                 if(g_ca)
 649                         self.caplayer = 1;
 650         }
 651         else if(clienttype(self) == CLIENTTYPE_REAL)
 652         {
 653                 msg_entity = self;
 654                 WriteByte(MSG_ONE, SVC_SETVIEW);
 655                 WriteEntity(MSG_ONE, self);
 656         }
 657
 658         // reset player keys
 659         self.itemkeys = 0;
 660
 661         // player is dead and becomes observer
 662         // FIXME fix LMS scoring for new system
 663         if(g_lms)
 664         {
 665                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 666                         self.classname = "observer";
 667         }
 668
 669         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 670                 self.classname = "observer";
 671
 672         if(gameover)
 673                 self.classname = "observer";
 674
 675         if(self.classname == "player") {
 676                 entity spot, oldself;
 677                 float j;
 678
 679                 accuracy_resend(self);
 680
 681                 if(self.team < 0)
 682                         JoinBestTeam(self, FALSE, TRUE);
 683
 684                 race_PreSpawn();
 685
 686                 spot = SelectSpawnPoint (FALSE);
 687                 if(!spot)
 688                 {
 689                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 690                         return; // spawn failed
 691                 }
 692
 693                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 694
 695                 self.classname = "player";
 696                 self.wasplayer = TRUE;
 697                 self.iscreature = TRUE;
 698                 self.teleportable = TELEPORT_NORMAL;
 699                 self.damagedbycontents = TRUE;
 700                 self.movetype = MOVETYPE_WALK;
 701                 self.solid = SOLID_SLIDEBOX;
 702                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 703                 if(autocvar_g_playerclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 705                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 707                 self.frags = FRAGS_PLAYER;
 708                 if(INDEPENDENT_PLAYERS)
 709                         MAKE_INDEPENDENT_PLAYER(self);
 710                 self.flags = FL_CLIENT;
 711                 if(autocvar__notarget)
 712                         self.flags |= FL_NOTARGET;
 713                 self.takedamage = DAMAGE_AIM;
 714                 if(g_minstagib)
 715                         self.effects = EF_FULLBRIGHT;
 716                 else
 717                         self.effects = 0;
 718                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 719                 self.air_finished = time + 12;
 720                 self.dmg = 2;
 721                 if(autocvar_g_balance_nex_charge)
 722                 {
 723                         if(autocvar_g_balance_nex_secondary_chargepool)
 724                                 self.nex_chargepool_ammo = 1;
 725                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 726                 }
 727
 728                 if(inWarmupStage)
 729                 {
 730                         self.ammo_shells = warmup_start_ammo_shells;
 731                         self.ammo_nails = warmup_start_ammo_nails;
 732                         self.ammo_rockets = warmup_start_ammo_rockets;
 733                         self.ammo_cells = warmup_start_ammo_cells;
 734                         self.ammo_fuel = warmup_start_ammo_fuel;
 735                         self.health = warmup_start_health;
 736                         self.armorvalue = warmup_start_armorvalue;
 737                         WEPSET_COPY_EA(self, warmup_start_weapons);
 738                 }
 739                 else
 740                 {
 741                         self.ammo_shells = start_ammo_shells;
 742                         self.ammo_nails = start_ammo_nails;
 743                         self.ammo_rockets = start_ammo_rockets;
 744                         self.ammo_cells = start_ammo_cells;
 745                         self.ammo_fuel = start_ammo_fuel;
 746                         self.health = start_health;
 747                         self.armorvalue = start_armorvalue;
 748                         WEPSET_COPY_EA(self, start_weapons);
 749                 }
 750
 751                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 752                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 753                 else
 754                         self.superweapons_finished = 0;
 755
 756                 if(g_weaponarena_random)
 757                 {
 758                         if(g_weaponarena_random_with_laser)
 759                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 760                         W_RandomWeapons(self, g_weaponarena_random);
 761                         if(g_weaponarena_random_with_laser)
 762                                 WEPSET_OR_EW(self, WEP_LASER);
 763                 }
 764
 765                 self.items = start_items;
 766
 767                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 768                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 769                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 770                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 771                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 772                 //extend the pause of rotting if client was reset at the beginning of the countdown
 773                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 774                         self.spawnshieldtime += game_starttime - time;
 775                         self.pauserotarmor_finished += game_starttime - time;
 776                         self.pauserothealth_finished += game_starttime - time;
 777                         self.pauseregen_finished += game_starttime - time;
 778                 }
 779                 self.damageforcescale = 2;
 780                 self.death_time = 0;
 781                 self.respawn_time = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 // players have no think function
 790                 self.think = SUB_Null;
 791                 self.nextthink = 0;
 792                 self.hook_time = 0;
 793                 self.dmg_team = 0;
 794                 self.ballistics_density = autocvar_g_ballistics_density_player;
 795
 796                 self.metertime = 0;
 797
 798                 self.runes = 0;
 799
 800                 self.deadflag = DEAD_NO;
 801
 802                 self.angles = spot.angles;
 803
 804                 self.angles_z = 0; // never spawn tilted even if the spot says to
 805                 self.fixangle = TRUE; // turn this way immediately
 806                 self.velocity = '0 0 0';
 807                 self.avelocity = '0 0 0';
 808                 self.punchangle = '0 0 0';
 809                 self.punchvector = '0 0 0';
 810                 self.oldvelocity = self.velocity;
 811                 self.fire_endtime = -1;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821                 self.drawonlytoclient = world;
 822
 823                 self.crouch = FALSE;
 824                 self.view_ofs = PL_VIEW_OFS;
 825                 setsize (self, PL_MIN, PL_MAX);
 826                 self.spawnorigin = spot.origin;
 827                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 828                 // don't reset back to last position, even if new position is stuck in solid
 829                 self.oldorigin = self.origin;
 830                 self.prevorigin = self.origin;
 831                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 832                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 833         self.hud = HUD_NORMAL;
 834
 835                 if(g_arena)
 836                 {
 837                         Spawnqueue_Remove(self);
 838                         Spawnqueue_Mark(self);
 839                 }
 840
 841                 self.event_damage = PlayerDamage;
 842
 843                 self.bot_attack = TRUE;
 844
 845                 self.statdraintime = time + 5;
 846                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 847
 848                 if(self.killcount == -666) {
 849                         PlayerScore_Clear(self);
 850                         self.killcount = 0;
 851                 }
 852
 853                 CL_SpawnWeaponentity();
 854                 self.alpha = default_player_alpha;
 855                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 856                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 857
 858                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 859                 self.lms_traveled_distance = 0;
 860                 self.speedrunning = FALSE;
 861
 862                 race_PostSpawn(spot);
 863
 864                 //stuffcmd(self, "chase_active 0");
 865                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 866
 867                 if(g_assault) {
 868                         if(self.team == assault_attacker_team)
 869                                 centerprint(self, "You are attacking!");
 870                         else
 871                                 centerprint(self, "You are defending!");
 872                 }
 873
 874                 target_voicescript_clear(self);
 875
 876                 // reset fields the weapons may use
 877                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 878                 {
 879                         weapon_action(j, WR_RESETPLAYER);
 880
 881                         // all weapons must be fully loaded when we spawn
 882                         entity e;
 883                         e = get_weaponinfo(j);
 884                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 885                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 886                 }
 887
 888                 oldself = self;
 889                 self = spot;
 890                         activator = oldself;
 891                                 string s;
 892                                 s = self.target;
 893                                 self.target = string_null;
 894                                 SUB_UseTargets();
 895                                 self.target = s;
 896                         activator = world;
 897                 self = oldself;
 898
 899                 spawn_spot = spot;
 900                 MUTATOR_CALLHOOK(PlayerSpawn);
 901
 902                 if(autocvar_spawn_debug)
 903                 {
 904                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 905                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 906                 }
 907
 908                 self.switchweapon = w_getbestweapon(self);
 909                 self.cnt = -1; // W_LastWeapon will not complain
 910                 self.weapon = 0;
 911                 self.weaponname = "";
 912                 self.switchingweapon = 0;
 913
 914                 if(!self.alivetime)
 915                         self.alivetime = time;
 916
 917                 antilag_clear(self);
 918
 919                 if (autocvar_g_spawnsound)
 920                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 921         } else if(self.classname == "observer") {
 922                 PutObserverInServer ();
 923         }
 924 }
 925
 926 .float ebouncefactor, ebouncestop; // electro's values
 927 // TODO do we need all these fields, or should we stop autodetecting runtime
 928 // changes and just have a console command to update this?
 929 float ClientInit_SendEntity(entity to, float sf)
 930 {
 931         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 932         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 933         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 945         if(sv_foginterval && world.fog != "")
 946                 WriteString(MSG_ENTITY, world.fog);
 947         else
 948                 WriteString(MSG_ENTITY, "");
 949         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 950         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 951         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 952         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 953         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 954         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 955         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 957         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 960         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 962         return TRUE;
 963 }
 964
 965 void ClientInit_CheckUpdate()
 966 {
 967         self.nextthink = time;
 968         if(self.count != autocvar_g_balance_armor_blockpercent)
 969         {
 970                 self.count = autocvar_g_balance_armor_blockpercent;
 971                 self.SendFlags |= 1;
 972         }
 973         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 974         {
 975                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 976                 self.SendFlags |= 1;
 977         }
 978         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 979         {
 980                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 981                 self.SendFlags |= 1;
 982         }
 983         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 984         {
 985                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 986                 self.SendFlags |= 1;
 987         }
 988         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 989         {
 990                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 991                 self.SendFlags |= 1;
 992         }
 993         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 994         {
 995                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 996                 self.SendFlags |= 1;
 997         }
 998 }
 999
1000 void ClientInit_Spawn()
1001 {
1002         entity o;
1003         entity e;
1004         e = spawn();
1005         e.classname = "clientinit";
1006         e.think = ClientInit_CheckUpdate;
1007         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1008
1009         o = self;
1010         self = e;
1011         ClientInit_CheckUpdate();
1012         self = o;
1013 }
1014
1015 /*
1016 =============
1017 SetNewParms
1018 =============
1019 */
1020 void SetNewParms (void)
1021 {
1022         // initialize parms for a new player
1023         parm1 = -(86400 * 366);
1024 }
1025
1026 /*
1027 =============
1028 SetChangeParms
1029 =============
1030 */
1031 void SetChangeParms (void)
1032 {
1033         // save parms for level change
1034         parm1 = self.parm_idlesince - time;
1035 }
1036
1037 /*
1038 =============
1039 DecodeLevelParms
1040 =============
1041 */
1042 void DecodeLevelParms (void)
1043 {
1044         // load parms
1045         self.parm_idlesince = parm1;
1046         if(self.parm_idlesince == -(86400 * 366))
1047                 self.parm_idlesince = time;
1048
1049         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1050         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1051 }
1052
1053 /*
1054 =============
1055 ClientKill
1056
1057 Called when a client types 'kill' in the console
1058 =============
1059 */
1060
1061 .float clientkill_nexttime;
1062 void ClientKill_Now_TeamChange()
1063 {
1064         if(self.killindicator_teamchange == -1)
1065         {
1066                 JoinBestTeam( self, FALSE, TRUE );
1067         }
1068         else if(self.killindicator_teamchange == -2)
1069         {
1070                 if(g_ca)
1071                         self.caplayer = 0;
1072                 if(blockSpectators)
1073                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1074                 PutObserverInServer();
1075         }
1076         else
1077                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1078 }
1079
1080 void ClientKill_Now()
1081 {
1082         if(self.vehicle)
1083         {
1084             vehicles_exit(VHEF_RELESE);
1085             if(!self.killindicator_teamchange)
1086             {
1087             self.vehicle_health = -1;
1088             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1089             }
1090         }
1091
1092         if(self.killindicator && !wasfreed(self.killindicator))
1093                 remove(self.killindicator);
1094
1095         self.killindicator = world;
1096
1097         if(self.killindicator_teamchange)
1098                 ClientKill_Now_TeamChange();
1099
1100         // in any case:
1101         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1102
1103         // now I am sure the player IS dead
1104 }
1105 void KillIndicator_Think()
1106 {
1107         if (gameover)
1108         {
1109                 self.owner.killindicator = world;
1110                 remove(self);
1111                 return;
1112         }
1113
1114         if (self.owner.alpha < 0 && !self.owner.vehicle)
1115         {
1116                 self.owner.killindicator = world;
1117                 remove(self);
1118                 return;
1119         }
1120
1121         if(self.cnt <= 0)
1122         {
1123                 self = self.owner;
1124                 ClientKill_Now(); // no oldself needed
1125                 return;
1126         }
1127     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1128     {
1129         self.nextthink = time + 1;
1130         self.cnt -= 1;
1131     }
1132         else
1133         {
1134                 if(self.cnt <= 10)
1135                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1136                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1137                 {
1138                         if(self.cnt <= 10)
1139                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1140                 }
1141                 self.nextthink = time + 1;
1142                 self.cnt -= 1;
1143         }
1144 }
1145
1146 float clientkilltime;
1147 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1148 {
1149         float killtime;
1150         float starttime;
1151         entity e;
1152
1153         if (gameover)
1154                 return;
1155
1156         killtime = autocvar_g_balance_kill_delay;
1157
1158         if(g_race_qualifying || g_cts)
1159                 killtime = 0;
1160
1161     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1162     {
1163                 remove(self.killindicator);
1164                 self.killindicator = world;
1165
1166         ClientKill_Now(); // allow instant kill in this case
1167         return;
1168     }
1169
1170         self.killindicator_teamchange = targetteam;
1171
1172     if(!self.killindicator)
1173         {
1174                 if(self.deadflag == DEAD_NO)
1175                 {
1176                         killtime = max(killtime, self.clientkill_nexttime - time);
1177                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1178                 }
1179
1180                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1181                 {
1182                         ClientKill_Now();
1183                 }
1184                 else
1185                 {
1186                         starttime = max(time, clientkilltime);
1187
1188                         self.killindicator = spawn();
1189                         self.killindicator.owner = self;
1190                         self.killindicator.scale = 0.5;
1191                         setattachment(self.killindicator, self, "");
1192                         setorigin(self.killindicator, '0 0 52');
1193                         self.killindicator.think = KillIndicator_Think;
1194                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1195                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1196                         self.killindicator.cnt = ceil(killtime);
1197                         self.killindicator.count = bound(0, ceil(killtime), 10);
1198                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1199
1200                         for(e = world; (e = find(e, classname, "body")) != world; )
1201                         {
1202                                 if(e.enemy != self)
1203                                         continue;
1204                                 e.killindicator = spawn();
1205                                 e.killindicator.owner = e;
1206                                 e.killindicator.scale = 0.5;
1207                                 setattachment(e.killindicator, e, "");
1208                                 setorigin(e.killindicator, '0 0 52');
1209                                 e.killindicator.think = KillIndicator_Think;
1210                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1211                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1212                                 e.killindicator.cnt = ceil(killtime);
1213                         }
1214                         self.lip = 0;
1215                 }
1216         }
1217         if(self.killindicator)
1218         {
1219                 if(targetteam == 0) // just die
1220                 {
1221                         self.killindicator.colormod = '0 0 0';
1222                         if(clienttype(self) == CLIENTTYPE_REAL)
1223                         if(self.killindicator.cnt > 0)
1224                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1225                 }
1226                 else if(targetteam == -1) // auto
1227                 {
1228                         self.killindicator.colormod = '0 1 0';
1229                         if(clienttype(self) == CLIENTTYPE_REAL)
1230                         if(self.killindicator.cnt > 0)
1231                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1232                 }
1233                 else if(targetteam == -2) // spectate
1234                 {
1235                         self.killindicator.colormod = '0.5 0.5 0.5';
1236                         if(clienttype(self) == CLIENTTYPE_REAL)
1237                         if(self.killindicator.cnt > 0)
1238                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1239                 }
1240                 else
1241                 {
1242                         self.killindicator.colormod = TeamColor(targetteam);
1243                         if(clienttype(self) == CLIENTTYPE_REAL)
1244                         if(self.killindicator.cnt > 0)
1245                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1246                 }
1247         }
1248
1249 }
1250
1251 void ClientKill (void)
1252 {
1253         if (gameover)
1254                 return;
1255
1256         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1257         {
1258                 // do nothing
1259         }
1260     else if(self.freezetag_frozen)
1261     {
1262         // do nothing
1263     }
1264         else
1265                 ClientKill_TeamChange(0);
1266 }
1267
1268 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1269 {
1270     e.killindicator = spawn();
1271     e.killindicator.owner = e;
1272     e.killindicator.think = KillIndicator_Think;
1273     e.killindicator.nextthink = time + (e.lip) * 0.05;
1274     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1275     e.killindicator.health = 1; // this is used to indicate that it should be silent
1276     e.lip = 0;
1277 }
1278
1279 void FixClientCvars(entity e)
1280 {
1281         // send prediction settings to the client
1282         stuffcmd(e, "\nin_bindmap 0 0\n");
1283         if(g_race || g_cts)
1284                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1285         if(autocvar_g_antilag == 3) // client side hitscan
1286                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1287         if(sv_gentle)
1288                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1289         /*
1290          * we no longer need to stuff this. Remove this comment block if you feel
1291          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1292         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1293         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1294         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1295         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1296         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1297         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1298         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1299         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1300         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1301         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1302         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1303         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1304         stuffcmd(e, "cl_movement_edgefriction 1\n");
1305          */
1306 }
1307
1308 float PlayerInIDList(entity p, string idlist)
1309 {
1310         float n, i;
1311         string s;
1312
1313         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1314         if not(p.crypto_idfp)
1315                 return 0;
1316
1317         // this function allows abbreviated player IDs too!
1318         n = tokenize_console(idlist);
1319         for(i = 0; i < n; ++i)
1320         {
1321                 s = argv(i);
1322                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1323                         return 1;
1324         }
1325
1326         return 0;
1327 }
1328
1329 /*
1330 =============
1331 ClientConnect
1332
1333 Called when a client connects to the server
1334 =============
1335 */
1336 string ColoredTeamName(float t);
1337 void DecodeLevelParms (void);
1338 //void dom_player_join_team(entity pl);
1339 void set_dom_state(entity e);
1340 void ClientConnect (void)
1341 {
1342         float t;
1343
1344         if(self.flags & FL_CLIENT)
1345         {
1346                 print("Warning: ClientConnect, but already connected!\n");
1347                 return;
1348         }
1349
1350         if(Ban_MaybeEnforceBanOnce(self))
1351                 return;
1352
1353         DecodeLevelParms();
1354
1355 #ifdef WATERMARK
1356         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1357 #endif
1358
1359         self.classname = "player_joining";
1360
1361         self.flags = FL_CLIENT;
1362         self.version_nagtime = time + 10 + random() * 10;
1363
1364         if(player_count<0)
1365         {
1366                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1367                 player_count = 0;
1368         }
1369
1370         PlayerScore_Attach(self);
1371         ClientData_Attach();
1372         accuracy_init(self);
1373
1374         bot_clientconnect();
1375
1376         playerdemo_init();
1377
1378         anticheat_init();
1379
1380         race_PreSpawnObserver();
1381
1382         //if(g_domination)
1383         //      dom_player_join_team(self);
1384
1385         // identify the right forced team
1386         if(autocvar_g_campaign)
1387         {
1388                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1389                 {
1390                         switch(autocvar_g_campaign_forceteam)
1391                         {
1392                                 case 1: self.team_forced = COLOR_TEAM1; break;
1393                                 case 2: self.team_forced = COLOR_TEAM2; break;
1394                                 case 3: self.team_forced = COLOR_TEAM3; break;
1395                                 case 4: self.team_forced = COLOR_TEAM4; break;
1396                                 default: self.team_forced = 0;
1397                         }
1398                 }
1399         }
1400         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1401                 self.team_forced = COLOR_TEAM1;
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1403                 self.team_forced = COLOR_TEAM2;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1405                 self.team_forced = COLOR_TEAM3;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1407                 self.team_forced = COLOR_TEAM4;
1408         else if(autocvar_g_forced_team_otherwise == "red")
1409                 self.team_forced = COLOR_TEAM1;
1410         else if(autocvar_g_forced_team_otherwise == "blue")
1411                 self.team_forced = COLOR_TEAM2;
1412         else if(autocvar_g_forced_team_otherwise == "yellow")
1413                 self.team_forced = COLOR_TEAM3;
1414         else if(autocvar_g_forced_team_otherwise == "pink")
1415                 self.team_forced = COLOR_TEAM4;
1416         else if(autocvar_g_forced_team_otherwise == "spectate")
1417                 self.team_forced = -1;
1418         else if(autocvar_g_forced_team_otherwise == "spectator")
1419                 self.team_forced = -1;
1420         else
1421                 self.team_forced = 0;
1422
1423         if(!teamplay)
1424                 if(self.team_forced > 0)
1425                         self.team_forced = 0;
1426
1427         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1428
1429         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1430                 self.classname = "observer";
1431         } else {
1432                 if(teamplay)
1433                 {
1434                         if(autocvar_g_balance_teams)
1435                         {
1436                                 self.classname = "player";
1437                                 campaign_bots_may_start = 1;
1438                         }
1439                         else
1440                         {
1441                                 self.classname = "observer"; // do it anyway
1442                         }
1443                 }
1444                 else
1445                 {
1446                         self.classname = "player";
1447                         campaign_bots_may_start = 1;
1448                 }
1449         }
1450
1451         self.playerid = (playerid_last = playerid_last + 1);
1452
1453         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1454
1455     if(clienttype(self) == CLIENTTYPE_BOT)
1456         PlayerStats_AddPlayer(self);
1457
1458         if(autocvar_sv_eventlog)
1459                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1460
1461         LogTeamchange(self.playerid, self.team, 1);
1462
1463         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1464
1465         self.netname_previous = strzone(self.netname);
1466
1467         bprint("^4", self.netname, "^4 connected");
1468
1469         if(self.classname != "observer" && (g_domination || g_ctf))
1470                 bprint(" and joined the ", ColoredTeamName(self.team));
1471
1472         bprint("\n");
1473
1474         stuffcmd(self, strcat(clientstuff, "\n"));
1475         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1476
1477         FixClientCvars(self);
1478
1479         // spawnfunc_waypoint sprites
1480         WaypointSprite_InitClient(self);
1481
1482         // Wazat's grappling hook
1483         SetGrappleHookBindings();
1484
1485         // get version info from player
1486         stuffcmd(self, "cmd clientversion $gameversion\n");
1487
1488         // get other cvars from player
1489         GetCvars(0);
1490
1491         // notify about available teams
1492         if(teamplay)
1493         {
1494                 CheckAllowedTeams(self);
1495                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1496                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1497         }
1498         else
1499                 stuffcmd(self, "set _teams_available 0\n");
1500
1501         if(g_arena || g_ca)
1502         {
1503                 self.classname = "observer";
1504                 if(g_arena)
1505                         Spawnqueue_Insert(self);
1506         }
1507
1508         attach_entcs();
1509
1510         bot_relinkplayerlist();
1511
1512         self.spectatortime = time;
1513         if(blockSpectators)
1514         {
1515                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1516         }
1517
1518         self.jointime = time;
1519         self.allowed_timeouts = autocvar_sv_timeout_number;
1520
1521         if(clienttype(self) == CLIENTTYPE_REAL)
1522         {
1523                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1524                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1525         }
1526
1527         if(g_lms)
1528         {
1529                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1530                 {
1531                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1532                         self.frags = FRAGS_SPECTATOR;
1533                 }
1534         }
1535
1536         if(!sv_foginterval && world.fog != "")
1537                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1538
1539         SoundEntity_Attach(self);
1540
1541         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1542         {
1543                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1544                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1545         }
1546         else
1547                 self.hitplotfh = -1;
1548
1549         if(g_race || g_cts) {
1550                 string rr;
1551                 if(g_cts)
1552                         rr = CTS_RECORD;
1553                 else
1554                         rr = RACE_RECORD;
1555
1556                 msg_entity = self;
1557                 race_send_recordtime(MSG_ONE);
1558                 race_send_speedaward(MSG_ONE);
1559
1560                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1561                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1562                 race_send_speedaward_alltimebest(MSG_ONE);
1563
1564                 float i;
1565                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1566                         race_SendRankings(i, 0, 0, MSG_ONE);
1567                 }
1568         }
1569         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1570                 send_CSQC_teamnagger();
1571
1572         if (g_domination)
1573                 set_dom_state(self);
1574
1575         CheatInitClient();
1576
1577         if(!autocvar_g_campaign)
1578                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1579
1580         CSQCMODEL_AUTOINIT();
1581
1582         self.model_randomizer = random();
1583
1584     if(clienttype(self) != CLIENTTYPE_REAL)
1585         return;
1586
1587     sv_notice_join();
1588
1589     MUTATOR_CALLHOOK(ClientConnect);
1590 }
1591 /*
1592 =============
1593 ClientDisconnect
1594
1595 Called when a client disconnects from the server
1596 =============
1597 */
1598 .entity chatbubbleentity;
1599 void ReadyCount();
1600 void ClientDisconnect (void)
1601 {
1602         if(self.vehicle)
1603             vehicles_exit(VHEF_RELESE);
1604
1605         if not(self.flags & FL_CLIENT)
1606         {
1607                 print("Warning: ClientDisconnect without ClientConnect\n");
1608                 return;
1609         }
1610
1611         PlayerStats_AddGlobalInfo(self);
1612
1613         CheatShutdownClient();
1614
1615         if(self.hitplotfh >= 0)
1616         {
1617                 fclose(self.hitplotfh);
1618                 self.hitplotfh = -1;
1619         }
1620
1621         anticheat_report();
1622         anticheat_shutdown();
1623
1624         playerdemo_shutdown();
1625
1626         bot_clientdisconnect();
1627
1628         if(self.entcs)
1629                 detach_entcs();
1630
1631         if(autocvar_sv_eventlog)
1632                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1633         bprint ("^4",self.netname);
1634         bprint ("^4 disconnected\n");
1635
1636         SoundEntity_Detach(self);
1637
1638         DropAllRunes(self);
1639         MUTATOR_CALLHOOK(ClientDisconnect);
1640
1641         Portal_ClearAll(self);
1642
1643         RemoveGrapplingHook(self);
1644
1645         // Here, everything has been done that requires this player to be a client.
1646
1647         self.flags &~= FL_CLIENT;
1648
1649         if (self.chatbubbleentity)
1650                 remove (self.chatbubbleentity);
1651
1652         if (self.killindicator)
1653                 remove (self.killindicator);
1654
1655         WaypointSprite_PlayerGone();
1656
1657         bot_relinkplayerlist();
1658
1659         if(g_arena)
1660         {
1661                 Spawnqueue_Unmark(self);
1662                 Spawnqueue_Remove(self);
1663         }
1664
1665         accuracy_free(self);
1666         ClientData_Detach();
1667         PlayerScore_Detach(self);
1668
1669         if(self.netname_previous)
1670                 strunzone(self.netname_previous);
1671         if(self.clientstatus)
1672                 strunzone(self.clientstatus);
1673         if(self.weaponorder_byimpulse)
1674                 strunzone(self.weaponorder_byimpulse);
1675
1676         ClearPlayerSounds();
1677
1678         if(self.personal)
1679                 remove(self.personal);
1680
1681         self.playerid = 0;
1682         ReadyCount();
1683
1684         // free cvars
1685         GetCvars(-1);
1686 }
1687
1688 .float BUTTON_CHAT;
1689 void ChatBubbleThink()
1690 {
1691         self.nextthink = time;
1692         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1693         {
1694                 if(self.owner) // but why can that ever be world?
1695                         self.owner.chatbubbleentity = world;
1696                 remove(self);
1697                 return;
1698         }
1699         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1700 #ifdef TETRIS
1701                 || self.owner.tetris_on
1702 #endif
1703         )
1704                 self.model = self.mdl;
1705         else
1706                 self.model = "";
1707 }
1708
1709 void UpdateChatBubble()
1710 {
1711         if (self.alpha < 0)
1712                 return;
1713         // spawn a chatbubble entity if needed
1714         if (!self.chatbubbleentity)
1715         {
1716                 self.chatbubbleentity = spawn();
1717                 self.chatbubbleentity.owner = self;
1718                 self.chatbubbleentity.exteriormodeltoclient = self;
1719                 self.chatbubbleentity.think = ChatBubbleThink;
1720                 self.chatbubbleentity.nextthink = time;
1721                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1722                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1723                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1724                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1725                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1726                 self.chatbubbleentity.model = "";
1727                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1728         }
1729 }
1730
1731
1732 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1733 // added to the model skins
1734 /*void UpdateColorModHack()
1735 {
1736         float c;
1737         c = self.clientcolors & 15;
1738         // LordHavoc: only bothering to support white, green, red, yellow, blue
1739              if (!teamplay) self.colormod = '0 0 0';
1740         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1741         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1742         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1743         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1744         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1745         else self.colormod = '1 1 1';
1746 }*/
1747
1748 void respawn(void)
1749 {
1750         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1751         {
1752                 self.solid = SOLID_NOT;
1753                 self.takedamage = DAMAGE_NO;
1754                 self.movetype = MOVETYPE_FLY;
1755                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1756                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1757                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1758                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1759                 if(autocvar_g_respawn_ghosts_maxtime)
1760                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1761         }
1762
1763         CopyBody(1);
1764
1765         self.effects |= EF_NODRAW; // prevent another CopyBody
1766         PutClientInServer();
1767 }
1768
1769 void play_countdown(float finished, string samp)
1770 {
1771         if(clienttype(self) == CLIENTTYPE_REAL)
1772                 if(floor(finished - time - frametime) != floor(finished - time))
1773                         if(finished - time < 6)
1774                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1775 }
1776
1777 void player_powerups (void)
1778 {
1779         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1780         olditems = self.items;
1781
1782         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1783         {
1784                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1785                 self.modelflags |= MF_ROCKET;
1786         }
1787         else
1788         {
1789                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1790                 self.modelflags &~= MF_ROCKET;
1791         }
1792
1793         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1794
1795         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1796                 return;
1797
1798         Fire_ApplyDamage(self);
1799         Fire_ApplyEffect(self);
1800
1801         if (g_minstagib)
1802         {
1803                 self.effects |= EF_FULLBRIGHT;
1804
1805                 if (self.items & IT_STRENGTH)
1806                 {
1807                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1808                         if (time > self.strength_finished)
1809                         {
1810                                 self.alpha = default_player_alpha;
1811                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1812                                 self.items &~= IT_STRENGTH;
1813                                 sprint(self, "^3Invisibility has worn off\n");
1814                         }
1815                 }
1816                 else
1817                 {
1818                         if (time < self.strength_finished)
1819                         {
1820                                 self.alpha = g_minstagib_invis_alpha;
1821                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1822                                 self.items |= IT_STRENGTH;
1823                                 sprint(self, "^3You are invisible\n");
1824                         }
1825                 }
1826
1827                 if (self.items & IT_INVINCIBLE)
1828                 {
1829                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1830                         if (time > self.invincible_finished)
1831                         {
1832                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1833                                 sprint(self, "^3Speed has worn off\n");
1834                         }
1835                 }
1836                 else
1837                 {
1838                         if (time < self.invincible_finished)
1839                         {
1840                                 self.items = self.items | IT_INVINCIBLE;
1841                                 sprint(self, "^3You are on speed\n");
1842                         }
1843                 }
1844         }
1845         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1846         {
1847                 if (self.items & IT_STRENGTH)
1848                 {
1849                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1850                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1851                         if (time > self.strength_finished)
1852                         {
1853                                 self.items = self.items - (self.items & IT_STRENGTH);
1854                                 sprint(self, "^3Strength has worn off\n");
1855                         }
1856                 }
1857                 else
1858                 {
1859                         if (time < self.strength_finished)
1860                         {
1861                                 self.items = self.items | IT_STRENGTH;
1862                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1863                         }
1864                 }
1865                 if (self.items & IT_INVINCIBLE)
1866                 {
1867                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1868                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1869                         if (time > self.invincible_finished)
1870                         {
1871                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1872                                 sprint(self, "^3Shield has worn off\n");
1873                         }
1874                 }
1875                 else
1876                 {
1877                         if (time < self.invincible_finished)
1878                         {
1879                                 self.items = self.items | IT_INVINCIBLE;
1880                                 sprint(self, "^3Shield surrounds you\n");
1881                         }
1882                 }
1883                 if (self.items & IT_SUPERWEAPON)
1884                 {
1885                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1886                         {
1887                                 self.superweapons_finished = 0;
1888                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1889                                 sprint(self, "^3Superweapons have been lost\n");
1890                         }
1891                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1892                         {
1893                                 // don't let them run out
1894                         }
1895                         else
1896                         {
1897                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1898                                 if (time > self.superweapons_finished)
1899                                 {
1900                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1901                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1902                                         sprint(self, "^3Superweapons have broken down\n");
1903                                 }
1904                         }
1905                 }
1906                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1907                 {
1908                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1909                         {
1910                                 self.items = self.items | IT_SUPERWEAPON;
1911                                 sprint(self, "^3You now have a superweapon\n");
1912                         }
1913                         else
1914                         {
1915                                 self.superweapons_finished = 0;
1916                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1917                         }
1918                 }
1919                 else
1920                 {
1921                         self.superweapons_finished = 0;
1922                 }
1923         }
1924
1925         if(autocvar_g_nodepthtestplayers)
1926                 self.effects = self.effects | EF_NODEPTHTEST;
1927
1928         if(autocvar_g_fullbrightplayers)
1929                 self.effects = self.effects | EF_FULLBRIGHT;
1930
1931         // midair gamemode: damage only while in the air
1932         // if in midair mode, being on ground grants temporary invulnerability
1933         // (this is so that multishot weapon don't clear the ground flag on the
1934         // first damage in the frame, leaving the player vulnerable to the
1935         // remaining hits in the same frame)
1936         if (self.flags & FL_ONGROUND)
1937         if (g_midair)
1938                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1939
1940         if (time >= game_starttime)
1941         if (time < self.spawnshieldtime)
1942                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1943
1944         MUTATOR_CALLHOOK(PlayerPowerups);
1945 }
1946
1947 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1948 {
1949         if(current > stable)
1950                 return current;
1951         else if(current > stable - 0.25) // when close enough, "snap"
1952                 return stable;
1953         else
1954                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1955 }
1956
1957 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1958 {
1959         if(current < stable)
1960                 return current;
1961         else if(current < stable + 0.25) // when close enough, "snap"
1962                 return stable;
1963         else
1964                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1965 }
1966
1967 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1968 {
1969         if(current > rotstable)
1970         {
1971                 if(rotframetime > 0)
1972                 {
1973                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1974                         current = max(rotstable, current - rotlinear * rotframetime);
1975                 }
1976         }
1977         else if(current < regenstable)
1978         {
1979                 if(regenframetime > 0)
1980                 {
1981                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1982                         current = min(regenstable, current + regenlinear * regenframetime);
1983                 }
1984         }
1985
1986         if(current > limit)
1987                 current = limit;
1988
1989         return current;
1990 }
1991
1992 void player_regen (void)
1993 {
1994         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1995         maxh = autocvar_g_balance_health_rotstable;
1996         maxa = autocvar_g_balance_armor_rotstable;
1997         maxf = autocvar_g_balance_fuel_rotstable;
1998         minh = autocvar_g_balance_health_regenstable;
1999         mina = autocvar_g_balance_armor_regenstable;
2000         minf = autocvar_g_balance_fuel_regenstable;
2001         limith = autocvar_g_balance_health_limit;
2002         limita = autocvar_g_balance_armor_limit;
2003         limitf = autocvar_g_balance_fuel_limit;
2004
2005         max_mod = regen_mod = rot_mod = limit_mod = 1;
2006
2007         if (self.runes & RUNE_REGEN)
2008         {
2009                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2010                 {
2011                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2012                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2013                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2014                 }
2015                 else
2016                 {
2017                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2018                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2019                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2020                 }
2021         }
2022         else if (self.runes & CURSE_VENOM)
2023         {
2024                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2025                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2026                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2027                 else
2028                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2029                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2030                 //if (!self.runes & RUNE_REGEN)
2031                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2032         }
2033         maxh = maxh * max_mod;
2034         //maxa = maxa * max_mod;
2035         //maxf = maxf * max_mod;
2036         minh = minh * max_mod;
2037         //mina = mina * max_mod;
2038         //minf = minf * max_mod;
2039         limith = limith * limit_mod;
2040         limita = limita * limit_mod;
2041         //limitf = limitf * limit_mod;
2042
2043         if(g_lms || g_ca)
2044                 rot_mod = 0;
2045
2046         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2047         {
2048                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2049                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2050
2051                 // if player rotted to death...  die!
2052                 if(self.health < 1)
2053                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2054         }
2055
2056         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2057                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2058 }
2059
2060 float zoomstate_set;
2061 void SetZoomState(float z)
2062 {
2063         if(z != self.zoomstate)
2064         {
2065                 self.zoomstate = z;
2066                 ClientData_Touch(self);
2067         }
2068         zoomstate_set = 1;
2069 }
2070
2071 void GetPressedKeys(void) {
2072         MUTATOR_CALLHOOK(GetPressedKeys);
2073         if (self.movement_x > 0) // get if movement keys are pressed
2074         {       // forward key pressed
2075                 self.pressedkeys |= KEY_FORWARD;
2076                 self.pressedkeys &~= KEY_BACKWARD;
2077         }
2078         else if (self.movement_x < 0)
2079         {       // backward key pressed
2080                 self.pressedkeys |= KEY_BACKWARD;
2081                 self.pressedkeys &~= KEY_FORWARD;
2082         }
2083         else
2084         {       // no x input
2085                 self.pressedkeys &~= KEY_FORWARD;
2086                 self.pressedkeys &~= KEY_BACKWARD;
2087         }
2088
2089         if (self.movement_y > 0)
2090         {       // right key pressed
2091                 self.pressedkeys |= KEY_RIGHT;
2092                 self.pressedkeys &~= KEY_LEFT;
2093         }
2094         else if (self.movement_y < 0)
2095         {       // left key pressed
2096                 self.pressedkeys |= KEY_LEFT;
2097                 self.pressedkeys &~= KEY_RIGHT;
2098         }
2099         else
2100         {       // no y input
2101                 self.pressedkeys &~= KEY_RIGHT;
2102                 self.pressedkeys &~= KEY_LEFT;
2103         }
2104
2105         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2106                 self.pressedkeys |= KEY_JUMP;
2107         else
2108                 self.pressedkeys &~= KEY_JUMP;
2109         if (self.BUTTON_CROUCH)
2110                 self.pressedkeys |= KEY_CROUCH;
2111         else
2112                 self.pressedkeys &~= KEY_CROUCH;
2113
2114         if (self.BUTTON_ATCK)
2115                 self.pressedkeys |= KEY_ATCK;
2116         else
2117                 self.pressedkeys &~= KEY_ATCK;
2118         if (self.BUTTON_ATCK2)
2119                 self.pressedkeys |= KEY_ATCK2;
2120         else
2121                 self.pressedkeys &~= KEY_ATCK2;
2122 }
2123
2124 /*
2125 ======================
2126 spectate mode routines
2127 ======================
2128 */
2129
2130 void SpectateCopy(entity spectatee) {
2131         other = spectatee;
2132         MUTATOR_CALLHOOK(SpectateCopy);
2133         self.armortype = spectatee.armortype;
2134         self.armorvalue = spectatee.armorvalue;
2135         self.ammo_cells = spectatee.ammo_cells;
2136         self.ammo_shells = spectatee.ammo_shells;
2137         self.ammo_nails = spectatee.ammo_nails;
2138         self.ammo_rockets = spectatee.ammo_rockets;
2139         self.ammo_fuel = spectatee.ammo_fuel;
2140         self.clip_load = spectatee.clip_load;
2141         self.clip_size = spectatee.clip_size;
2142         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2143         self.health = spectatee.health;
2144         self.impulse = 0;
2145         self.items = spectatee.items;
2146         self.last_pickup = spectatee.last_pickup;
2147         self.hit_time = spectatee.hit_time;
2148         self.metertime = spectatee.metertime;
2149         self.strength_finished = spectatee.strength_finished;
2150         self.invincible_finished = spectatee.invincible_finished;
2151         self.pressedkeys = spectatee.pressedkeys;
2152         WEPSET_COPY_EE(self, spectatee);
2153         self.switchweapon = spectatee.switchweapon;
2154         self.switchingweapon = spectatee.switchingweapon;
2155         self.weapon = spectatee.weapon;
2156         self.nex_charge = spectatee.nex_charge;
2157         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2158         self.hagar_load = spectatee.hagar_load;
2159         self.minelayer_mines = spectatee.minelayer_mines;
2160         self.punchangle = spectatee.punchangle;
2161         self.view_ofs = spectatee.view_ofs;
2162         self.velocity = spectatee.velocity;
2163         self.dmg_take = spectatee.dmg_take;
2164         self.dmg_save = spectatee.dmg_save;
2165         self.dmg_inflictor = spectatee.dmg_inflictor;
2166         self.v_angle = spectatee.v_angle;
2167         self.angles = spectatee.v_angle;
2168         self.stat_respawn_time = spectatee.stat_respawn_time;
2169         if(!self.BUTTON_USE)
2170                 self.fixangle = TRUE;
2171         setorigin(self, spectatee.origin);
2172         setsize(self, spectatee.mins, spectatee.maxs);
2173         SetZoomState(spectatee.zoomstate);
2174
2175     anticheat_spectatecopy(spectatee);
2176         self.hud = spectatee.hud;
2177         if(spectatee.vehicle)
2178     {
2179         self.fixangle = FALSE;
2180         //self.velocity = spectatee.vehicle.velocity;
2181         self.vehicle_health = spectatee.vehicle_health;
2182         self.vehicle_shield = spectatee.vehicle_shield;
2183         self.vehicle_energy = spectatee.vehicle_energy;
2184         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2185         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2186         self.vehicle_reload1 = spectatee.vehicle_reload1;
2187         self.vehicle_reload2 = spectatee.vehicle_reload2;
2188
2189         msg_entity = self;
2190
2191         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2192             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2193             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2194             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2195
2196         //WriteByte (MSG_ONE, SVC_SETVIEW);
2197         //    WriteEntity(MSG_ONE, self);
2198         //makevectors(spectatee.v_angle);
2199         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2200     }
2201 }
2202
2203 float SpectateUpdate() {
2204         if(!self.enemy)
2205             return 0;
2206
2207         if (self == self.enemy)
2208                 return 0;
2209
2210         if(self.enemy.classname != "player")
2211                 return 0;
2212
2213         SpectateCopy(self.enemy);
2214
2215         return 1;
2216 }
2217
2218
2219 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2220 entity CA_SpectateNext(entity start) {
2221         if (start.team == self.team) {
2222                 return start;
2223         }
2224
2225         other = start;
2226         // continue from current player
2227         while(other && other.team != self.team) {
2228                 other = find(other, classname, "player");
2229         }
2230
2231         if (!other) {
2232                 // restart from begining
2233                 other = find(other, classname, "player");
2234                 while(other && other.team != self.team) {
2235                         other = find(other, classname, "player");
2236                 }
2237         }
2238
2239         return other;
2240 }
2241
2242 float SpectateNext(entity _prefer) {
2243
2244         if(_prefer)
2245                 other = _prefer;
2246         else
2247                 other = find(self.enemy, classname, "player");
2248
2249         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2250                 // CA and ca players when spectating enemies is forbidden
2251                 other = CA_SpectateNext(other);
2252         } else {
2253                 // other modes and ca spectators or spectating enemies is allowed
2254                 if (!other)
2255                         other = find(other, classname, "player");
2256         }
2257
2258         if (other)
2259                 self.enemy = other;
2260
2261         if(self.enemy.classname == "player") {
2262             /*if(self.enemy.vehicle)
2263             {
2264
2265             msg_entity = self;
2266             WriteByte(MSG_ONE, SVC_SETVIEW);
2267             WriteEntity(MSG_ONE, self.enemy);
2268             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2269
2270             self.movetype = MOVETYPE_NONE;
2271             accuracy_resend(self);
2272             }
2273             else
2274             {*/
2275             msg_entity = self;
2276             WriteByte(MSG_ONE, SVC_SETVIEW);
2277             WriteEntity(MSG_ONE, self.enemy);
2278             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2279             self.movetype = MOVETYPE_NONE;
2280             accuracy_resend(self);
2281
2282             if(!SpectateUpdate())
2283                 PutObserverInServer();
2284         //}
2285         return 1;
2286         } else {
2287                 return 0;
2288         }
2289 }
2290
2291 /*
2292 =============
2293 ShowRespawnCountdown()
2294
2295 Update a respawn countdown display.
2296 =============
2297 */
2298 void ShowRespawnCountdown()
2299 {
2300         float number;
2301         if(self.deadflag == DEAD_NO) // just respawned?
2302                 return;
2303         else
2304         {
2305                 number = ceil(self.respawn_time - time);
2306                 if(number <= 0)
2307                         return;
2308                 if(number <= self.respawn_countdown)
2309                 {
2310                         self.respawn_countdown = number - 1;
2311                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2312                                 AnnounceTo(self, strcat(ftos(number), ""));
2313                 }
2314         }
2315 }
2316
2317 .float prevent_join_msgtime;
2318 void LeaveSpectatorMode()
2319 {
2320         if(nJoinAllowed(self)) {
2321                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2322                         self.classname = "player";
2323
2324                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2325                                 JoinBestTeam(self, FALSE, TRUE);
2326
2327                         if(autocvar_g_campaign)
2328                                 campaign_bots_may_start = 1;
2329
2330                         PutClientInServer();
2331
2332                         if(self.classname == "player")
2333                                 bprint ("^4", self.netname, "^4 is playing now\n");
2334
2335                         if(!autocvar_g_campaign)
2336                         if (time < self.jointime + autocvar_welcome_message_time)
2337                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2338
2339                         if (self.prevent_join_msgtime)
2340                         {
2341                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2342                                 self.prevent_join_msgtime = 0;
2343                         }
2344
2345                         return;
2346                 } else {
2347                         if (g_ca && self.caplayer) {
2348                         }       // do nothing
2349                         else
2350                                 stuffcmd(self,"menu_showteamselect\n");
2351                         return;
2352                 }
2353         }
2354         else {
2355                 //player may not join because of g_maxplayers is set
2356                 if (time - self.prevent_join_msgtime > 2)
2357                 {
2358                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2359                         self.prevent_join_msgtime = time;
2360                 }
2361         }
2362 }
2363
2364 /**
2365  * Determines whether the player is allowed to join. This depends on cvar
2366  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2367  * it checks whether the number of currently playing players exceeds g_maxplayers.
2368  * @return int number of free slots for players, 0 if none
2369  */
2370 float nJoinAllowed(entity ignore) {
2371         if(!ignore)
2372         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2373         // so report 0 free slots if restricted
2374         {
2375                 if(autocvar_g_forced_team_otherwise == "spectate")
2376                         return 0;
2377                 if(autocvar_g_forced_team_otherwise == "spectator")
2378                         return 0;
2379         }
2380
2381         if(self.team_forced < 0)
2382                 return 0; // forced spectators can never join
2383
2384         // TODO simplify this
2385         entity e;
2386         float totalClients = 0;
2387         FOR_EACH_CLIENT(e)
2388                 if(e != ignore)
2389                         totalClients += 1;
2390
2391         if (!autocvar_g_maxplayers)
2392                 return maxclients - totalClients;
2393
2394         float currentlyPlaying = 0;
2395         FOR_EACH_REALPLAYER(e)
2396                 currentlyPlaying += 1;
2397
2398         if(currentlyPlaying < autocvar_g_maxplayers)
2399                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2400
2401         return 0;
2402 }
2403
2404 /**
2405  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2406  * g_maxplayers_spectator_blocktime seconds
2407  */
2408 void checkSpectatorBlock() {
2409         if(self.classname == "spectator" || self.classname == "observer") {
2410                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2411                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2412                         dropclient(self);
2413                 }
2414         }
2415 }
2416
2417 .float motd_actived_time; // used for both motd and campaign_message
2418 void PrintWelcomeMessage()
2419 {
2420         if (self.motd_actived_time == 0) { // is there already a message showing?
2421                 if (autocvar_g_campaign) {
2422                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2423                                 self.motd_actived_time = time;
2424                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2425                         }
2426                 } else {
2427                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2428                                 self.motd_actived_time = time;
2429                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2430                         }
2431                 }
2432         } else { // showing MOTD or campaign message
2433                 if (autocvar_g_campaign) {
2434                         if (self.BUTTON_INFO)
2435                                 self.motd_actived_time = time;
2436                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2437                                 self.motd_actived_time = 0;
2438                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2439                         }
2440                 } else {
2441                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2442                                 if (self.BUTTON_INFO)
2443                                         self.motd_actived_time = time;
2444                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2445                                         self.motd_actived_time = 0;
2446                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2447                                 }
2448                         }
2449                 }
2450         }
2451 }
2452
2453 void ObserverThink()
2454 {
2455         float prefered_movetype;
2456         if (self.flags & FL_JUMPRELEASED) {
2457                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2458                         self.flags &~= FL_JUMPRELEASED;
2459                         self.flags |= FL_SPAWNING;
2460                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         if(SpectateNext(world) == 1) {
2463                                 self.classname = "spectator";
2464                         }
2465                 } else {
2466                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2467                         if (self.movetype != prefered_movetype)
2468                                 self.movetype = prefered_movetype;
2469                 }
2470         } else {
2471                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2472                         self.flags |= FL_JUMPRELEASED;
2473                         if(self.flags & FL_SPAWNING)
2474                         {
2475                                 self.flags &~= FL_SPAWNING;
2476                                 LeaveSpectatorMode();
2477                                 return;
2478                         }
2479                 }
2480         }
2481
2482         PrintWelcomeMessage();
2483 }
2484
2485 void SpectatorThink()
2486 {
2487         if (self.flags & FL_JUMPRELEASED) {
2488                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2489                         self.flags &~= FL_JUMPRELEASED;
2490                         self.flags |= FL_SPAWNING;
2491                 } else if(self.BUTTON_ATCK) {
2492                         self.flags &~= FL_JUMPRELEASED;
2493                         if(SpectateNext(world) == 1) {
2494                                 self.classname = "spectator";
2495                         } else {
2496                                 self.classname = "observer";
2497                                 PutClientInServer();
2498                         }
2499                 } else if (self.BUTTON_ATCK2) {
2500                         self.flags &~= FL_JUMPRELEASED;
2501                         self.classname = "observer";
2502                         PutClientInServer();
2503                 } else {
2504                         if(!SpectateUpdate())
2505                                 PutObserverInServer();
2506                 }
2507         } else {
2508                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2509                         self.flags |= FL_JUMPRELEASED;
2510                         if(self.flags & FL_SPAWNING)
2511                         {
2512                                 self.flags &~= FL_SPAWNING;
2513                                 LeaveSpectatorMode();
2514                                 return;
2515                         }
2516                 }
2517                 if(!SpectateUpdate())
2518                         PutObserverInServer();
2519         }
2520
2521         PrintWelcomeMessage();
2522         self.flags |= FL_CLIENT | FL_NOTARGET;
2523 }
2524
2525 void PlayerUseKey()
2526 {
2527         if(self.classname != "player")
2528                 return;
2529
2530         if(self.vehicle)
2531         {
2532         vehicles_exit(VHEF_NORMAL);
2533         return;
2534         }
2535
2536         // a use key was pressed; call handlers
2537         MUTATOR_CALLHOOK(PlayerUseKey);
2538 }
2539
2540 .float touchexplode_time;
2541
2542 /*
2543 =============
2544 PlayerPreThink
2545
2546 Called every frame for each client before the physics are run
2547 =============
2548 */
2549 .float usekeypressed;
2550 void() nexball_setstatus;
2551 .float items_added;
2552 void PlayerPreThink (void)
2553 {
2554         WarpZone_PlayerPhysics_FixVAngle();
2555
2556         self.stat_game_starttime = game_starttime;
2557         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2558         self.stat_leadlimit = autocvar_leadlimit;
2559
2560         if(g_arena)
2561                 self.stat_respawn_time = 0;
2562         else
2563                 self.stat_respawn_time = self.respawn_time;
2564
2565         if(frametime)
2566         {
2567                 // physics frames: update anticheat stuff
2568                 anticheat_prethink();
2569         }
2570
2571         if(blockSpectators && frametime)
2572                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2573                 checkSpectatorBlock();
2574
2575         zoomstate_set = 0;
2576
2577         if(self.netname_previous != self.netname)
2578         {
2579                 if(autocvar_sv_eventlog)
2580                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2581                 if(self.netname_previous)
2582                         strunzone(self.netname_previous);
2583                 self.netname_previous = strzone(self.netname);
2584         }
2585
2586         // version nagging
2587         if(self.version_nagtime)
2588                 if(self.cvar_g_xonoticversion)
2589                         if(time > self.version_nagtime)
2590                         {
2591                                 // don't notify git users
2592                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2593                                 {
2594                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2595                                         {
2596                                                 // notify release users if connecting to git
2597                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2598                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2599                                         }
2600                                         else
2601                                         {
2602                                                 float r;
2603                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2604                                                 if(r < 0)
2605                                                 {
2606                                                         // give users new version
2607                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2608                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2609                                                 }
2610                                                 else if(r > 0)
2611                                                 {
2612                                                         // notify users about old server version
2613                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2614                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2615                                                 }
2616                                         }
2617                                 }
2618                                 self.version_nagtime = 0;
2619                         }
2620
2621         // GOD MODE info
2622         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2623         {
2624                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2625                 self.max_armorvalue = 0;
2626         }
2627
2628 #ifdef TETRIS
2629         if (TetrisPreFrame())
2630                 return;
2631 #endif
2632
2633         MUTATOR_CALLHOOK(PlayerPreThink);
2634
2635         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2636         {
2637                 if(self.BUTTON_USE && !self.usekeypressed)
2638                         PlayerUseKey();
2639                 self.usekeypressed = self.BUTTON_USE;
2640         }
2641
2642         PrintWelcomeMessage();
2643
2644         if(self.classname == "player") {
2645 //              if(self.netname == "Wazat")
2646 //                      bprint(self.classname, "\n");
2647
2648                 CheckRules_Player();
2649
2650                 if (intermission_running)
2651                 {
2652                         IntermissionThink ();   // otherwise a button could be missed between
2653                         return;                                 // the think tics
2654                 }
2655
2656                 //don't allow the player to turn around while game is paused!
2657                 if(timeout_status == TIMEOUT_ACTIVE) {
2658                         // FIXME turn this into CSQC stuff
2659                         self.v_angle = self.lastV_angle;
2660                         self.angles = self.lastV_angle;
2661                         self.fixangle = TRUE;
2662                 }
2663
2664                 if(frametime)
2665                 {
2666 #ifndef NO_LEGACY_NETWORKING
2667                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2668 #endif
2669
2670                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2671                         {
2672                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2673                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2674                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2675
2676                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2677                                 {
2678                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2679                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2680                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2681                                 }
2682                         }
2683                         else
2684                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2685
2686                         player_powerups();
2687                 }
2688
2689                 if (g_minstagib)
2690                         minstagib_ammocheck();
2691
2692                 if (self.deadflag != DEAD_NO)
2693                 {
2694                         float button_pressed, force_respawn;
2695                         if(self.personal && g_race_qualifying)
2696                         {
2697                                 if(time > self.respawn_time)
2698                                 {
2699                                         self.respawn_time = time + 1; // only retry once a second
2700                                         respawn();
2701                                         self.impulse = 141;
2702                                 }
2703                         }
2704                         else
2705                         {
2706                                 if(frametime)
2707                                         player_anim();
2708                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2709                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2710                                 if (self.deadflag == DEAD_DYING)
2711                                 {
2712                                         if(force_respawn)
2713                                                 self.deadflag = DEAD_RESPAWNING;
2714                                         else if(!button_pressed)
2715                                                 self.deadflag = DEAD_DEAD;
2716                                 }
2717                                 else if (self.deadflag == DEAD_DEAD)
2718                                 {
2719                                         if(button_pressed)
2720                                                 self.deadflag = DEAD_RESPAWNABLE;
2721                                 }
2722                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2723                                 {
2724                                         if(!button_pressed)
2725                                                 self.deadflag = DEAD_RESPAWNING;
2726                                 }
2727                                 else if (self.deadflag == DEAD_RESPAWNING)
2728                                 {
2729                                         if(time > self.respawn_time)
2730                                         {
2731                                                 self.respawn_time = time + 1; // only retry once a second
2732                                                 respawn();
2733                                         }
2734                                 }
2735                                 ShowRespawnCountdown();
2736                         }
2737
2738                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2739                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2740                                 self.stat_respawn_time *= -1;
2741
2742                         return;
2743                 }
2744                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2745                 // so (self.deadflag == DEAD_NO) is always true in the code below
2746
2747                 if(g_touchexplode)
2748                 if(time > self.touchexplode_time)
2749                 if(self.classname == "player")
2750                 if(self.deadflag == DEAD_NO)
2751                 if not(IS_INDEPENDENT_PLAYER(self))
2752                 FOR_EACH_PLAYER(other) if(self != other)
2753                 {
2754                         if(time > other.touchexplode_time)
2755                         if(other.deadflag == DEAD_NO)
2756                         if not(IS_INDEPENDENT_PLAYER(other))
2757                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2758                         {
2759                                 PlayerTouchExplode(self, other);
2760                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2761                         }
2762                 }
2763
2764                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2765                 {
2766                         vector dist;
2767
2768                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2769                         dist = self.prevorigin - self.origin;
2770                         dist_z = 0;
2771                         self.lms_traveled_distance += fabs(vlen(dist));
2772
2773                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2774                         {
2775                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2776                                 self.lms_traveled_distance = 0;
2777                         }
2778
2779                         if(time > self.lms_nextcheck)
2780                         {
2781                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2782                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2783                                 {
2784                                         centerprint(self, autocvar_g_lms_campcheck_message);
2785                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2786                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2787                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2788                                 }
2789                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2790                                 self.lms_traveled_distance = 0;
2791                         }
2792                 }
2793
2794                 self.prevorigin = self.origin;
2795
2796                 if (!self.vehicle)
2797                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2798                 {
2799                         if (!self.crouch)
2800                         {
2801                                 self.crouch = TRUE;
2802                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2803                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2804                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2805                         }
2806                 }
2807                 else
2808                 {
2809                         if (self.crouch)
2810                         {
2811                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2812                                 if (!trace_startsolid)
2813                                 {
2814                                         self.crouch = FALSE;
2815                                         self.view_ofs = PL_VIEW_OFS;
2816                                         setsize (self, PL_MIN, PL_MAX);
2817                                 }
2818                         }
2819                 }
2820
2821                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2822                 {
2823                         if(self.bloodloss_timer < time)
2824                         {
2825                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2826                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2827                         }
2828                 }
2829
2830                 FixPlayermodel();
2831
2832                 GrapplingHookFrame();
2833
2834                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2835                 //if(frametime)
2836                 {
2837                         self.items &~= self.items_added;
2838
2839                         W_WeaponFrame();
2840
2841                         self.items_added = 0;
2842                         if(self.items & IT_JETPACK)
2843                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2844                                         self.items_added |= IT_FUEL;
2845
2846                         self.items |= self.items_added;
2847                 }
2848
2849                 player_regen();
2850
2851                 // rot nex charge to the charge limit
2852                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2853                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2854
2855                 if(frametime)
2856                         player_anim();
2857
2858                 if(g_nexball)
2859                         nexball_setstatus();
2860
2861                 // secret status
2862                 secrets_setstatus();
2863
2864                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2865
2866                 //self.angles_y=self.v_angle_y + 90;   // temp
2867         } else if(gameover) {
2868                 if (intermission_running)
2869                         IntermissionThink ();   // otherwise a button could be missed between
2870                 return;
2871         } else if(self.classname == "observer") {
2872                 ObserverThink();
2873         } else if(self.classname == "spectator") {
2874                 SpectatorThink();
2875         }
2876
2877         if(!zoomstate_set)
2878                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2879
2880         float oldspectatee_status;
2881         oldspectatee_status = self.spectatee_status;
2882         if(self.classname == "spectator")
2883                 self.spectatee_status = num_for_edict(self.enemy);
2884         else if(self.classname == "observer")
2885                 self.spectatee_status = num_for_edict(self);
2886         else
2887                 self.spectatee_status = 0;
2888         if(self.spectatee_status != oldspectatee_status)
2889         {
2890                 ClientData_Touch(self);
2891                 if(g_race || g_cts)
2892                         race_InitSpectator();
2893         }
2894
2895         if(self.teamkill_soundtime)
2896         if(time > self.teamkill_soundtime)
2897         {
2898                 self.teamkill_soundtime = 0;
2899
2900                 entity oldpusher, oldself;
2901
2902                 oldself = self; self = self.teamkill_soundsource;
2903                 oldpusher = self.pusher; self.pusher = oldself;
2904
2905                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2906
2907                 self.pusher = oldpusher;
2908                 self = oldself;
2909         }
2910
2911         if(self.taunt_soundtime)
2912         if(time > self.taunt_soundtime)
2913         {
2914                 self.taunt_soundtime = 0;
2915                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2916         }
2917
2918         target_voicescript_next(self);
2919
2920         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2921         if(!self.weapon)
2922                 self.clip_load = self.clip_size = 0;
2923 }
2924
2925 float isInvisibleString(string s)
2926 {
2927         float i, n, c;
2928         s = strdecolorize(s);
2929         for((i = 0), (n = strlen(s)); i < n; ++i)
2930         {
2931                 c = str2chr(s, i);
2932                 switch(c)
2933                 {
2934                         case 0:
2935                         case 32: // space
2936                                 break;
2937                         case 192: // charmap space
2938                                 if (!autocvar_utf8_enable)
2939                                         break;
2940                                 return FALSE;
2941                         case 160: // space in unicode fonts
2942                         case 0xE000 + 192: // utf8 charmap space
2943                                 if (autocvar_utf8_enable)
2944                                         break;
2945                         default:
2946                                 return FALSE;
2947                 }
2948         }
2949         return TRUE;
2950 }
2951
2952 /*
2953 =============
2954 PlayerPostThink
2955
2956 Called every frame for each client after the physics are run
2957 =============
2958 */
2959 .float idlekick_lasttimeleft;
2960 .entity showheadshotbbox;
2961 void showheadshotbbox_think()
2962 {
2963         if(self.owner.showheadshotbbox != self)
2964         {
2965                 remove(self);
2966                 return;
2967         }
2968         self.nextthink = time;
2969         setorigin(self, self.owner.origin);
2970         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2971 }
2972 void PlayerPostThink (void)
2973 {
2974         // Savage: Check for nameless players
2975         if (isInvisibleString(self.netname)) {
2976                 self.netname = "Player";
2977                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2978         }
2979
2980         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2981         {
2982                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2983                 {
2984                         if(self.idlekick_lasttimeleft)
2985                         {
2986                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2987                                 self.idlekick_lasttimeleft = 0;
2988                         }
2989                 }
2990                 else
2991                 {
2992                         float timeleft;
2993                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2994                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2995                         {
2996                                 if(!self.idlekick_lasttimeleft)
2997                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2998                         }
2999                         if(timeleft <= 0)
3000                         {
3001                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3002                                 AnnounceTo(self, "terminated");
3003                                 dropclient(self);
3004                                 return;
3005                         }
3006                         else if(timeleft <= 10)
3007                         {
3008                                 if(timeleft != self.idlekick_lasttimeleft)
3009                                         AnnounceTo(self, ftos(timeleft));
3010                                 self.idlekick_lasttimeleft = timeleft;
3011                         }
3012                 }
3013         }
3014
3015 #ifdef TETRIS
3016         if(self.impulse == 100)
3017                 ImpulseCommands();
3018         if (!TetrisPostFrame())
3019         {
3020 #endif
3021
3022         CheatFrame();
3023
3024         //CheckPlayerJump();
3025
3026         if(self.classname == "player") {
3027                 CheckRules_Player();
3028                 UpdateChatBubble();
3029                 if (self.impulse)
3030                         ImpulseCommands();
3031                 if (intermission_running)
3032                         return;         // intermission or finale
3033                 GetPressedKeys();
3034         } else if (self.classname == "observer") {
3035                 //do nothing
3036         } else if (self.classname == "spectator") {
3037                 //do nothing
3038         }
3039
3040 #ifdef TETRIS
3041         }
3042 #endif
3043
3044         /*
3045         float i;
3046         for(i = 0; i < 1000; ++i)
3047         {
3048                 vector end;
3049                 end = self.origin + '0 0 1024' + 512 * randomvec();
3050                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3051                 if(trace_fraction < 1)
3052                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3053                 {
3054                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3055                         break;
3056                 }
3057         }
3058         */
3059
3060         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3061
3062         if(self.waypointsprite_attachedforcarrier)
3063                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3064
3065         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3066         {
3067                 if(!self.showheadshotbbox)
3068                 {
3069                         self.showheadshotbbox = spawn();
3070                         self.showheadshotbbox.classname = "headshotbbox";
3071                         self.showheadshotbbox.owner = self;
3072                         self.showheadshotbbox.think = showheadshotbbox_think;
3073                         self.showheadshotbbox.nextthink = time;
3074                         self = self.showheadshotbbox;
3075                         self.think();
3076                         self = self.owner;
3077                 }
3078         }
3079         else
3080         {
3081                 if(self.showheadshotbbox)
3082                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3083                 remove(self.showheadshotbbox);
3084         }
3085
3086         playerdemo_write();
3087
3088         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3089         {
3090                 if(!self.stored_netname)
3091                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3092                 if(self.stored_netname != self.netname)
3093                 {
3094                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3095                         strunzone(self.stored_netname);
3096                         self.stored_netname = strzone(self.netname);
3097                 }
3098         }
3099
3100         /*
3101         if(g_race)
3102                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3103         */
3104
3105         CSQCMODEL_AUTOUPDATE();
3106 }