qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418             vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.think = SUB_Null;
 474         self.nextthink = 0;
 475         self.hook_time = 0;
 476         self.runes = 0;
 477         self.deadflag = DEAD_NO;
 478         self.angles = spot.angles;
 479         self.angles_z = 0;
 480         self.fixangle = TRUE;
 481         self.crouch = FALSE;
 482
 483         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 484         self.prevorigin = self.origin;
 485         self.items = 0;
 486         WEPSET_CLEAR_E(self);
 487         self.model = "";
 488         FixPlayermodel();
 489         setmodel(self, "null");
 490         self.drawonlytoclient = self;
 491
 492         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 493         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 494
 495         self.weapon = 0;
 496         self.weaponname = "";
 497         self.switchingweapon = 0;
 498         self.weaponmodel = "";
 499         self.weaponentity = world;
 500         self.exteriorweaponentity = world;
 501         self.killcount = -666;
 502         self.velocity = '0 0 0';
 503         self.avelocity = '0 0 0';
 504         self.punchangle = '0 0 0';
 505         self.punchvector = '0 0 0';
 506         self.oldvelocity = self.velocity;
 507         self.fire_endtime = -1;
 508
 509         if(g_arena)
 510         {
 511                 if(self.version_mismatch)
 512                 {
 513                         Spawnqueue_Unmark(self);
 514                         Spawnqueue_Remove(self);
 515                 }
 516                 else
 517                 {
 518                         Spawnqueue_Insert(self);
 519                 }
 520         }
 521         else if(g_lms)
 522         {
 523                 // Only if the player cannot play at all
 524                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 525                         self.frags = FRAGS_SPECTATOR;
 526                 else
 527                         self.frags = FRAGS_LMS_LOSER;
 528         }
 529         else if(g_ca)
 530         {
 531                 if(self.caplayer)
 532                         self.frags = FRAGS_LMS_LOSER;
 533                 else
 534                         self.frags = FRAGS_SPECTATOR;
 535         }
 536         else
 537                 self.frags = FRAGS_SPECTATOR;
 538 }
 539
 540 .float model_randomizer;
 541 void FixPlayermodel()
 542 {
 543         string defaultmodel;
 544         float defaultskin, chmdl, oldskin, n, i;
 545         vector m1, m2;
 546
 547         defaultmodel = "";
 548
 549         if(autocvar_sv_defaultcharacter == 1)
 550         {
 551                 defaultskin = 0;
 552
 553                 if(teamplay)
 554                 {
 555                         string s;
 556                         s = Team_ColorNameLowerCase(self.team);
 557                         if(s != "neutral")
 558                         {
 559                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 560                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 561                         }
 562                 }
 563
 564                 if(defaultmodel == "")
 565                 {
 566                         defaultmodel = autocvar_sv_defaultplayermodel;
 567                         defaultskin = autocvar_sv_defaultplayerskin;
 568                 }
 569
 570                 n = tokenize_console(defaultmodel);
 571                 if(n > 0)
 572                         defaultmodel = argv(floor(n * self.model_randomizer));
 573
 574                 i = strstrofs(defaultmodel, ":", 0);
 575                 if(i >= 0)
 576                 {
 577                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 578                         defaultmodel = substring(defaultmodel, 0, i);
 579                 }
 580         }
 581
 582         if(defaultmodel != "")
 583         {
 584                 if (defaultmodel != self.model)
 585                 {
 586                         m1 = self.mins;
 587                         m2 = self.maxs;
 588                         setplayermodel (self, defaultmodel);
 589                         setsize (self, m1, m2);
 590                         chmdl = TRUE;
 591                 }
 592
 593                 oldskin = self.skin;
 594                 self.skin = defaultskin;
 595         } else {
 596                 if (self.playermodel != self.model || self.playermodel == "")
 597                 {
 598                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 599                         m1 = self.mins;
 600                         m2 = self.maxs;
 601                         setplayermodel (self, self.playermodel);
 602                         setsize (self, m1, m2);
 603                         chmdl = TRUE;
 604                 }
 605
 606                 oldskin = self.skin;
 607                 self.skin = stof(self.playerskin);
 608         }
 609
 610         if(chmdl || oldskin != self.skin)
 611                 self.species = player_getspecies(); // model or skin has changed
 612
 613         if(!teamplay)
 614                 if(strlen(autocvar_sv_defaultplayercolors))
 615                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 616                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 617 }
 618
 619 void PlayerTouchExplode(entity p1, entity p2)
 620 {
 621         vector org;
 622         org = (p1.origin + p2.origin) * 0.5;
 623         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 624
 625         te_explosion(org);
 626
 627         entity e;
 628         e = spawn();
 629         setorigin(e, org);
 630         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 631         remove(e);
 632 }
 633
 634 /*
 635 =============
 636 PutClientInServer
 637
 638 Called when a client spawns in the server
 639 =============
 640 */
 641
 642 void PutClientInServer (void)
 643 {
 644         if(clienttype(self) == CLIENTTYPE_BOT)
 645         {
 646                 self.classname = "player";
 647                 if(g_ca)
 648                         self.caplayer = 1;
 649         }
 650         else if(clienttype(self) == CLIENTTYPE_REAL)
 651         {
 652                 msg_entity = self;
 653                 WriteByte(MSG_ONE, SVC_SETVIEW);
 654                 WriteEntity(MSG_ONE, self);
 655         }
 656
 657         // reset player keys
 658         self.itemkeys = 0;
 659
 660         // player is dead and becomes observer
 661         // FIXME fix LMS scoring for new system
 662         if(g_lms)
 663         {
 664                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 665                         self.classname = "observer";
 666         }
 667
 668         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 669                 self.classname = "observer";
 670
 671         if(gameover)
 672                 self.classname = "observer";
 673
 674         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 675                 entity spot, oldself;
 676                 float j;
 677
 678                 accuracy_resend(self);
 679
 680                 if(self.team < 0)
 681                         JoinBestTeam(self, FALSE, TRUE);
 682
 683                 race_PreSpawn();
 684
 685                 spot = SelectSpawnPoint (FALSE);
 686                 if(!spot)
 687                 {
 688                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 689                         return; // spawn failed
 690                 }
 691
 692                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 693
 694                 self.classname = "player";
 695                 self.wasplayer = TRUE;
 696                 self.iscreature = TRUE;
 697                 self.teleportable = TELEPORT_NORMAL;
 698                 self.damagedbycontents = TRUE;
 699                 self.movetype = MOVETYPE_WALK;
 700                 self.solid = SOLID_SLIDEBOX;
 701                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 702                 if(autocvar_g_playerclip_collisions)
 703                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 704                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 705                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 706                 self.frags = FRAGS_PLAYER;
 707                 if(INDEPENDENT_PLAYERS)
 708                         MAKE_INDEPENDENT_PLAYER(self);
 709                 self.flags = FL_CLIENT;
 710                 if(autocvar__notarget)
 711                         self.flags |= FL_NOTARGET;
 712                 self.takedamage = DAMAGE_AIM;
 713                 if(g_minstagib)
 714                         self.effects = EF_FULLBRIGHT;
 715                 else
 716                         self.effects = 0;
 717                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 718                 self.air_finished = time + 12;
 719                 self.dmg = 2;
 720                 if(autocvar_g_balance_nex_charge)
 721                 {
 722                         if(autocvar_g_balance_nex_secondary_chargepool)
 723                                 self.nex_chargepool_ammo = 1;
 724                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 725                 }
 726
 727                 if(inWarmupStage)
 728                 {
 729                         self.ammo_shells = warmup_start_ammo_shells;
 730                         self.ammo_nails = warmup_start_ammo_nails;
 731                         self.ammo_rockets = warmup_start_ammo_rockets;
 732                         self.ammo_cells = warmup_start_ammo_cells;
 733                         self.ammo_fuel = warmup_start_ammo_fuel;
 734                         self.health = warmup_start_health;
 735                         self.armorvalue = warmup_start_armorvalue;
 736                         WEPSET_COPY_EA(self, warmup_start_weapons);
 737                 }
 738                 else
 739                 {
 740                         self.ammo_shells = start_ammo_shells;
 741                         self.ammo_nails = start_ammo_nails;
 742                         self.ammo_rockets = start_ammo_rockets;
 743                         self.ammo_cells = start_ammo_cells;
 744                         self.ammo_fuel = start_ammo_fuel;
 745                         self.health = start_health;
 746                         self.armorvalue = start_armorvalue;
 747                         WEPSET_COPY_EA(self, start_weapons);
 748                 }
 749
 750                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 751                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 752                 else
 753                         self.superweapons_finished = 0;
 754
 755                 if(g_weaponarena_random)
 756                 {
 757                         if(g_weaponarena_random_with_laser)
 758                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 759                         W_RandomWeapons(self, g_weaponarena_random);
 760                         if(g_weaponarena_random_with_laser)
 761                                 WEPSET_OR_EW(self, WEP_LASER);
 762                 }
 763
 764                 self.items = start_items;
 765
 766                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 767                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 768                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 769                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 770                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 771                 //extend the pause of rotting if client was reset at the beginning of the countdown
 772                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 773                         self.spawnshieldtime += game_starttime - time;
 774                         self.pauserotarmor_finished += game_starttime - time;
 775                         self.pauserothealth_finished += game_starttime - time;
 776                         self.pauseregen_finished += game_starttime - time;
 777                 }
 778                 self.damageforcescale = 2;
 779                 self.death_time = 0;
 780                 self.respawn_time = 0;
 781                 self.scale = 0;
 782                 self.fade_time = 0;
 783                 self.pain_frame = 0;
 784                 self.pain_finished = 0;
 785                 self.strength_finished = 0;
 786                 self.invincible_finished = 0;
 787                 self.pushltime = 0;
 788                 // players have no think function
 789                 self.think = SUB_Null;
 790                 self.nextthink = 0;
 791                 self.hook_time = 0;
 792                 self.dmg_team = 0;
 793                 self.ballistics_density = autocvar_g_ballistics_density_player;
 794
 795                 self.metertime = 0;
 796
 797                 self.runes = 0;
 798
 799                 self.deadflag = DEAD_NO;
 800
 801                 self.angles = spot.angles;
 802
 803                 self.angles_z = 0; // never spawn tilted even if the spot says to
 804                 self.fixangle = TRUE; // turn this way immediately
 805                 self.velocity = '0 0 0';
 806                 self.avelocity = '0 0 0';
 807                 self.punchangle = '0 0 0';
 808                 self.punchvector = '0 0 0';
 809                 self.oldvelocity = self.velocity;
 810                 self.fire_endtime = -1;
 811
 812                 msg_entity = self;
 813                 WRITESPECTATABLE_MSG_ONE({
 814                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 815                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 816                 });
 817
 818                 self.model = "";
 819                 FixPlayermodel();
 820                 self.drawonlytoclient = world;
 821
 822                 self.crouch = FALSE;
 823                 self.view_ofs = PL_VIEW_OFS;
 824                 setsize (self, PL_MIN, PL_MAX);
 825                 self.spawnorigin = spot.origin;
 826                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 827                 // don't reset back to last position, even if new position is stuck in solid
 828                 self.oldorigin = self.origin;
 829                 self.prevorigin = self.origin;
 830                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 831                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 832         self.hud = HUD_NORMAL;
 833
 834                 if(g_arena)
 835                 {
 836                         Spawnqueue_Remove(self);
 837                         Spawnqueue_Mark(self);
 838                 }
 839                 else if(g_ca)
 840                         self.caplayer = 1;
 841
 842                 self.event_damage = PlayerDamage;
 843
 844                 self.bot_attack = TRUE;
 845
 846                 self.statdraintime = time + 5;
 847                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 848
 849                 if(self.killcount == -666) {
 850                         PlayerScore_Clear(self);
 851                         self.killcount = 0;
 852                 }
 853
 854                 CL_SpawnWeaponentity();
 855                 self.alpha = default_player_alpha;
 856                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 857                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 858
 859                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 860                 self.lms_traveled_distance = 0;
 861                 self.speedrunning = FALSE;
 862
 863                 race_PostSpawn(spot);
 864
 865                 //stuffcmd(self, "chase_active 0");
 866                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 867
 868                 if(g_assault) {
 869                         if(self.team == assault_attacker_team)
 870                                 centerprint(self, "You are attacking!");
 871                         else
 872                                 centerprint(self, "You are defending!");
 873                 }
 874
 875                 target_voicescript_clear(self);
 876
 877                 // reset fields the weapons may use
 878                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 879                 {
 880                         weapon_action(j, WR_RESETPLAYER);
 881
 882                         // all weapons must be fully loaded when we spawn
 883                         entity e;
 884                         e = get_weaponinfo(j);
 885                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 886                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 887                 }
 888
 889                 oldself = self;
 890                 self = spot;
 891                         activator = oldself;
 892                                 string s;
 893                                 s = self.target;
 894                                 self.target = string_null;
 895                                 SUB_UseTargets();
 896                                 self.target = s;
 897                         activator = world;
 898                 self = oldself;
 899
 900                 spawn_spot = spot;
 901                 MUTATOR_CALLHOOK(PlayerSpawn);
 902
 903                 if(autocvar_spawn_debug)
 904                 {
 905                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 906                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 907                 }
 908
 909                 self.switchweapon = w_getbestweapon(self);
 910                 self.cnt = -1; // W_LastWeapon will not complain
 911                 self.weapon = 0;
 912                 self.weaponname = "";
 913                 self.switchingweapon = 0;
 914
 915                 if(!self.alivetime)
 916                         self.alivetime = time;
 917
 918                 antilag_clear(self);
 919
 920                 if (autocvar_g_spawnsound)
 921                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 922         } else if(self.classname == "observer") {
 923                 PutObserverInServer ();
 924         }
 925 }
 926
 927 .float ebouncefactor, ebouncestop; // electro's values
 928 // TODO do we need all these fields, or should we stop autodetecting runtime
 929 // changes and just have a console command to update this?
 930 float ClientInit_SendEntity(entity to, float sf)
 931 {
 932         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 933         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 946         if(sv_foginterval && world.fog != "")
 947                 WriteString(MSG_ENTITY, world.fog);
 948         else
 949                 WriteString(MSG_ENTITY, "");
 950         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 951         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 952         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 953         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 954         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 955         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 958         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 961         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 963         return TRUE;
 964 }
 965
 966 void ClientInit_CheckUpdate()
 967 {
 968         self.nextthink = time;
 969         if(self.count != autocvar_g_balance_armor_blockpercent)
 970         {
 971                 self.count = autocvar_g_balance_armor_blockpercent;
 972                 self.SendFlags |= 1;
 973         }
 974         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 975         {
 976                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 977                 self.SendFlags |= 1;
 978         }
 979         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 980         {
 981                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 982                 self.SendFlags |= 1;
 983         }
 984         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 985         {
 986                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 987                 self.SendFlags |= 1;
 988         }
 989         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 990         {
 991                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 992                 self.SendFlags |= 1;
 993         }
 994         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 995         {
 996                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 997                 self.SendFlags |= 1;
 998         }
 999 }
1000
1001 void ClientInit_Spawn()
1002 {
1003         entity o;
1004         entity e;
1005         e = spawn();
1006         e.classname = "clientinit";
1007         e.think = ClientInit_CheckUpdate;
1008         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1009
1010         o = self;
1011         self = e;
1012         ClientInit_CheckUpdate();
1013         self = o;
1014 }
1015
1016 /*
1017 =============
1018 SetNewParms
1019 =============
1020 */
1021 void SetNewParms (void)
1022 {
1023         // initialize parms for a new player
1024         parm1 = -(86400 * 366);
1025 }
1026
1027 /*
1028 =============
1029 SetChangeParms
1030 =============
1031 */
1032 void SetChangeParms (void)
1033 {
1034         // save parms for level change
1035         parm1 = self.parm_idlesince - time;
1036 }
1037
1038 /*
1039 =============
1040 DecodeLevelParms
1041 =============
1042 */
1043 void DecodeLevelParms (void)
1044 {
1045         // load parms
1046         self.parm_idlesince = parm1;
1047         if(self.parm_idlesince == -(86400 * 366))
1048                 self.parm_idlesince = time;
1049
1050         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1051         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1052 }
1053
1054 /*
1055 =============
1056 ClientKill
1057
1058 Called when a client types 'kill' in the console
1059 =============
1060 */
1061
1062 .float clientkill_nexttime;
1063 void ClientKill_Now_TeamChange()
1064 {
1065         if(self.killindicator_teamchange == -1)
1066         {
1067                 self.team = -1;
1068                 JoinBestTeam( self, FALSE, FALSE );
1069         }
1070         else if(self.killindicator_teamchange == -2)
1071         {
1072                 if(g_ca)
1073                         self.caplayer = 0;
1074                 if(blockSpectators)
1075                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1076                 PutObserverInServer();
1077         }
1078         else
1079                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1080 }
1081
1082 void ClientKill_Now()
1083 {
1084         if(self.vehicle)
1085         {
1086             vehicles_exit(VHEF_RELESE);
1087             if(!self.killindicator_teamchange)
1088             {
1089             self.vehicle_health = -1;
1090             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1091             }
1092         }
1093
1094         if(self.killindicator && !wasfreed(self.killindicator))
1095                 remove(self.killindicator);
1096
1097         self.killindicator = world;
1098
1099         if(self.killindicator_teamchange)
1100                 ClientKill_Now_TeamChange();
1101
1102         // in any case:
1103         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1104
1105         // now I am sure the player IS dead
1106 }
1107 void KillIndicator_Think()
1108 {
1109         if (gameover)
1110         {
1111                 self.owner.killindicator = world;
1112                 remove(self);
1113                 return;
1114         }
1115
1116         if (self.owner.alpha < 0)
1117         {
1118                 self.owner.killindicator = world;
1119                 remove(self);
1120                 return;
1121         }
1122
1123         if(self.cnt <= 0)
1124         {
1125                 self = self.owner;
1126                 ClientKill_Now(); // no oldself needed
1127                 return;
1128         }
1129     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1130     {
1131         self.nextthink = time + 1;
1132         self.cnt -= 1;
1133     }
1134         else
1135         {
1136                 if(self.cnt <= 10)
1137                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1138                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1139                 {
1140                         if(self.cnt <= 10)
1141                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1142                 }
1143                 self.nextthink = time + 1;
1144                 self.cnt -= 1;
1145         }
1146 }
1147
1148 float clientkilltime;
1149 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1150 {
1151         float killtime;
1152         float starttime;
1153         entity e;
1154
1155         if (gameover)
1156                 return;
1157
1158         killtime = autocvar_g_balance_kill_delay;
1159
1160         if(g_race_qualifying || g_cts)
1161                 killtime = 0;
1162
1163     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1164     {
1165                 remove(self.killindicator);
1166                 self.killindicator = world;
1167
1168         ClientKill_Now(); // allow instant kill in this case
1169         return;
1170     }
1171
1172         self.killindicator_teamchange = targetteam;
1173
1174     if(!self.killindicator)
1175         {
1176                 if(self.deadflag == DEAD_NO)
1177                 {
1178                         killtime = max(killtime, self.clientkill_nexttime - time);
1179                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1180                 }
1181
1182                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1183                 {
1184                         ClientKill_Now();
1185                 }
1186                 else
1187                 {
1188                         starttime = max(time, clientkilltime);
1189
1190                         self.killindicator = spawn();
1191                         self.killindicator.owner = self;
1192                         self.killindicator.scale = 0.5;
1193                         setattachment(self.killindicator, self, "");
1194                         setorigin(self.killindicator, '0 0 52');
1195                         self.killindicator.think = KillIndicator_Think;
1196                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1197                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1198                         self.killindicator.cnt = ceil(killtime);
1199                         self.killindicator.count = bound(0, ceil(killtime), 10);
1200                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1201
1202                         for(e = world; (e = find(e, classname, "body")) != world; )
1203                         {
1204                                 if(e.enemy != self)
1205                                         continue;
1206                                 e.killindicator = spawn();
1207                                 e.killindicator.owner = e;
1208                                 e.killindicator.scale = 0.5;
1209                                 setattachment(e.killindicator, e, "");
1210                                 setorigin(e.killindicator, '0 0 52');
1211                                 e.killindicator.think = KillIndicator_Think;
1212                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1213                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1214                                 e.killindicator.cnt = ceil(killtime);
1215                         }
1216                         self.lip = 0;
1217                 }
1218         }
1219         if(self.killindicator)
1220         {
1221                 if(targetteam == 0) // just die
1222                 {
1223                         self.killindicator.colormod = '0 0 0';
1224                         if(clienttype(self) == CLIENTTYPE_REAL)
1225                         if(self.killindicator.cnt > 0)
1226                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1227                 }
1228                 else if(targetteam == -1) // auto
1229                 {
1230                         self.killindicator.colormod = '0 1 0';
1231                         if(clienttype(self) == CLIENTTYPE_REAL)
1232                         if(self.killindicator.cnt > 0)
1233                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1234                 }
1235                 else if(targetteam == -2) // spectate
1236                 {
1237                         self.killindicator.colormod = '0.5 0.5 0.5';
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1241                 }
1242                 else
1243                 {
1244                         self.killindicator.colormod = TeamColor(targetteam);
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1248                 }
1249         }
1250
1251 }
1252
1253 void ClientKill (void)
1254 {
1255         if (gameover)
1256                 return;
1257
1258         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1259         {
1260                 // do nothing
1261         }
1262     else if(self.freezetag_frozen)
1263     {
1264         // do nothing
1265     }
1266         else
1267                 ClientKill_TeamChange(0);
1268 }
1269
1270 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1271 {
1272     e.killindicator = spawn();
1273     e.killindicator.owner = e;
1274     e.killindicator.think = KillIndicator_Think;
1275     e.killindicator.nextthink = time + (e.lip) * 0.05;
1276     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1277     e.killindicator.health = 1; // this is used to indicate that it should be silent
1278     e.lip = 0;
1279 }
1280
1281 void FixClientCvars(entity e)
1282 {
1283         // send prediction settings to the client
1284         stuffcmd(e, "\nin_bindmap 0 0\n");
1285         if(g_race || g_cts)
1286                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1287         if(autocvar_g_antilag == 3) // client side hitscan
1288                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1289         if(sv_gentle)
1290                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1291         /*
1292          * we no longer need to stuff this. Remove this comment block if you feel
1293          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1294         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1295         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1296         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1297         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1298         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1303         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1306         stuffcmd(e, "cl_movement_edgefriction 1\n");
1307          */
1308 }
1309
1310 float PlayerInIDList(entity p, string idlist)
1311 {
1312         float n, i;
1313         string s;
1314
1315         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1316         if not(p.crypto_idfp)
1317                 return 0;
1318
1319         // this function allows abbreviated player IDs too!
1320         n = tokenize_console(idlist);
1321         for(i = 0; i < n; ++i)
1322         {
1323                 s = argv(i);
1324                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1325                         return 1;
1326         }
1327
1328         return 0;
1329 }
1330
1331 /*
1332 =============
1333 ClientConnect
1334
1335 Called when a client connects to the server
1336 =============
1337 */
1338 string ColoredTeamName(float t);
1339 void DecodeLevelParms (void);
1340 //void dom_player_join_team(entity pl);
1341 void set_dom_state(entity e);
1342 void ClientConnect (void)
1343 {
1344         float t;
1345
1346         if(self.flags & FL_CLIENT)
1347         {
1348                 print("Warning: ClientConnect, but already connected!\n");
1349                 return;
1350         }
1351
1352         if(Ban_MaybeEnforceBanOnce(self))
1353                 return;
1354
1355         DecodeLevelParms();
1356
1357 #ifdef WATERMARK
1358         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1359 #endif
1360
1361         self.classname = "player_joining";
1362
1363         self.flags = FL_CLIENT;
1364         self.version_nagtime = time + 10 + random() * 10;
1365
1366         if(player_count<0)
1367         {
1368                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1369                 player_count = 0;
1370         }
1371
1372         PlayerScore_Attach(self);
1373         ClientData_Attach();
1374         accuracy_init(self);
1375
1376         bot_clientconnect();
1377
1378         playerdemo_init();
1379
1380         anticheat_init();
1381
1382         race_PreSpawnObserver();
1383
1384         //if(g_domination)
1385         //      dom_player_join_team(self);
1386
1387         // identify the right forced team
1388         if(autocvar_g_campaign)
1389         {
1390                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1391                 {
1392                         switch(autocvar_g_campaign_forceteam)
1393                         {
1394                                 case 1: self.team_forced = COLOR_TEAM1; break;
1395                                 case 2: self.team_forced = COLOR_TEAM2; break;
1396                                 case 3: self.team_forced = COLOR_TEAM3; break;
1397                                 case 4: self.team_forced = COLOR_TEAM4; break;
1398                                 default: self.team_forced = 0;
1399                         }
1400                 }
1401         }
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1403                 self.team_forced = COLOR_TEAM1;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1405                 self.team_forced = COLOR_TEAM2;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1407                 self.team_forced = COLOR_TEAM3;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1409                 self.team_forced = COLOR_TEAM4;
1410         else if(autocvar_g_forced_team_otherwise == "red")
1411                 self.team_forced = COLOR_TEAM1;
1412         else if(autocvar_g_forced_team_otherwise == "blue")
1413                 self.team_forced = COLOR_TEAM2;
1414         else if(autocvar_g_forced_team_otherwise == "yellow")
1415                 self.team_forced = COLOR_TEAM3;
1416         else if(autocvar_g_forced_team_otherwise == "pink")
1417                 self.team_forced = COLOR_TEAM4;
1418         else if(autocvar_g_forced_team_otherwise == "spectate")
1419                 self.team_forced = -1;
1420         else if(autocvar_g_forced_team_otherwise == "spectator")
1421                 self.team_forced = -1;
1422         else
1423                 self.team_forced = 0;
1424
1425         if(!teamplay)
1426                 if(self.team_forced > 0)
1427                         self.team_forced = 0;
1428
1429         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1430
1431         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1432                 self.classname = "observer";
1433         } else {
1434                 if(teamplay)
1435                 {
1436                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1437                         {
1438                                 self.classname = "player";
1439                                 campaign_bots_may_start = 1;
1440                         }
1441                         else
1442                         {
1443                                 self.classname = "observer"; // do it anyway
1444                         }
1445                 }
1446                 else
1447                 {
1448                         self.classname = "player";
1449                         campaign_bots_may_start = 1;
1450                 }
1451         }
1452
1453         self.playerid = (playerid_last = playerid_last + 1);
1454
1455         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1456
1457     if(clienttype(self) == CLIENTTYPE_BOT)
1458         PlayerStats_AddPlayer(self);
1459
1460         if(autocvar_sv_eventlog)
1461                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1462
1463         LogTeamchange(self.playerid, self.team, 1);
1464
1465         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1466
1467         self.netname_previous = strzone(self.netname);
1468
1469         bprint("^4", self.netname, "^4 connected");
1470
1471         if(self.classname != "observer" && (g_domination || g_ctf))
1472                 bprint(" and joined the ", ColoredTeamName(self.team));
1473
1474         bprint("\n");
1475
1476         stuffcmd(self, strcat(clientstuff, "\n"));
1477         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1478
1479         FixClientCvars(self);
1480
1481         // spawnfunc_waypoint sprites
1482         WaypointSprite_InitClient(self);
1483
1484         // Wazat's grappling hook
1485         SetGrappleHookBindings();
1486
1487         // get version info from player
1488         stuffcmd(self, "cmd clientversion $gameversion\n");
1489
1490         // get other cvars from player
1491         GetCvars(0);
1492
1493         // notify about available teams
1494         if(teamplay)
1495         {
1496                 CheckAllowedTeams(self);
1497                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1498                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1499         }
1500         else
1501                 stuffcmd(self, "set _teams_available 0\n");
1502
1503         if(g_arena || g_ca)
1504         {
1505                 self.classname = "observer";
1506                 if(g_arena)
1507                         Spawnqueue_Insert(self);
1508         }
1509
1510         attach_entcs();
1511
1512         bot_relinkplayerlist();
1513
1514         self.spectatortime = time;
1515         if(blockSpectators)
1516         {
1517                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1518         }
1519
1520         self.jointime = time;
1521         self.allowed_timeouts = autocvar_sv_timeout_number;
1522
1523         if(clienttype(self) == CLIENTTYPE_REAL)
1524         {
1525                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1526                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1527         }
1528
1529         if(g_lms)
1530         {
1531                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1532                 {
1533                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1534                         self.frags = FRAGS_SPECTATOR;
1535                 }
1536         }
1537
1538         if(!sv_foginterval && world.fog != "")
1539                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1540
1541         SoundEntity_Attach(self);
1542
1543         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1544         {
1545                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1546                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1547         }
1548         else
1549                 self.hitplotfh = -1;
1550
1551         if(g_race || g_cts) {
1552                 string rr;
1553                 if(g_cts)
1554                         rr = CTS_RECORD;
1555                 else
1556                         rr = RACE_RECORD;
1557                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1558
1559                 msg_entity = self;
1560                 race_send_recordtime(MSG_ONE);
1561                 race_send_speedaward(MSG_ONE);
1562
1563                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1564                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1565                 race_send_speedaward_alltimebest(MSG_ONE);
1566
1567                 float i;
1568                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1569                         race_SendRankings(i, 0, 0, MSG_ONE);
1570                 }
1571         }
1572         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1573                 send_CSQC_teamnagger();
1574
1575         if (g_domination)
1576                 set_dom_state(self);
1577
1578         CheatInitClient();
1579
1580         if(!autocvar_g_campaign)
1581                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1582
1583         CSQCMODEL_AUTOINIT();
1584
1585         self.model_randomizer = random();
1586
1587     if(clienttype(self) != CLIENTTYPE_REAL)
1588         return;
1589
1590     sv_notice_join();
1591 }
1592 /*
1593 =============
1594 ClientDisconnect
1595
1596 Called when a client disconnects from the server
1597 =============
1598 */
1599 .entity chatbubbleentity;
1600 void ReadyCount();
1601 void ClientDisconnect (void)
1602 {
1603         if(self.vehicle)
1604             vehicles_exit(VHEF_RELESE);
1605
1606         if not(self.flags & FL_CLIENT)
1607         {
1608                 print("Warning: ClientDisconnect without ClientConnect\n");
1609                 return;
1610         }
1611
1612         PlayerStats_AddGlobalInfo(self);
1613
1614         CheatShutdownClient();
1615
1616         if(self.hitplotfh >= 0)
1617         {
1618                 fclose(self.hitplotfh);
1619                 self.hitplotfh = -1;
1620         }
1621
1622         anticheat_report();
1623         anticheat_shutdown();
1624
1625         playerdemo_shutdown();
1626
1627         bot_clientdisconnect();
1628
1629         if(self.entcs)
1630                 detach_entcs();
1631
1632         if(autocvar_sv_eventlog)
1633                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1634         bprint ("^4",self.netname);
1635         bprint ("^4 disconnected\n");
1636
1637         SoundEntity_Detach(self);
1638
1639         DropAllRunes(self);
1640         MUTATOR_CALLHOOK(ClientDisconnect);
1641
1642         Portal_ClearAll(self);
1643
1644         RemoveGrapplingHook(self);
1645
1646         // Here, everything has been done that requires this player to be a client.
1647
1648         self.flags &~= FL_CLIENT;
1649
1650         if (self.chatbubbleentity)
1651                 remove (self.chatbubbleentity);
1652
1653         if (self.killindicator)
1654                 remove (self.killindicator);
1655
1656         WaypointSprite_PlayerGone();
1657
1658         bot_relinkplayerlist();
1659
1660         if(g_arena)
1661         {
1662                 Spawnqueue_Unmark(self);
1663                 Spawnqueue_Remove(self);
1664         }
1665
1666         accuracy_free(self);
1667         ClientData_Detach();
1668         PlayerScore_Detach(self);
1669
1670         if(self.netname_previous)
1671                 strunzone(self.netname_previous);
1672         if(self.clientstatus)
1673                 strunzone(self.clientstatus);
1674         if(self.weaponorder_byimpulse)
1675                 strunzone(self.weaponorder_byimpulse);
1676
1677         ClearPlayerSounds();
1678
1679         if(self.personal)
1680                 remove(self.personal);
1681
1682         self.playerid = 0;
1683         ReadyCount();
1684
1685         // free cvars
1686         GetCvars(-1);
1687 }
1688
1689 .float BUTTON_CHAT;
1690 void ChatBubbleThink()
1691 {
1692         self.nextthink = time;
1693         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1694         {
1695                 if(self.owner) // but why can that ever be world?
1696                         self.owner.chatbubbleentity = world;
1697                 remove(self);
1698                 return;
1699         }
1700         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1701 #ifdef TETRIS
1702                 || self.owner.tetris_on
1703 #endif
1704         )
1705                 self.model = self.mdl;
1706         else
1707                 self.model = "";
1708 }
1709
1710 void UpdateChatBubble()
1711 {
1712         if (self.alpha < 0)
1713                 return;
1714         // spawn a chatbubble entity if needed
1715         if (!self.chatbubbleentity)
1716         {
1717                 self.chatbubbleentity = spawn();
1718                 self.chatbubbleentity.owner = self;
1719                 self.chatbubbleentity.exteriormodeltoclient = self;
1720                 self.chatbubbleentity.think = ChatBubbleThink;
1721                 self.chatbubbleentity.nextthink = time;
1722                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1723                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1724                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1725                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1726                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1727                 self.chatbubbleentity.model = "";
1728                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1729         }
1730 }
1731
1732
1733 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1734 // added to the model skins
1735 /*void UpdateColorModHack()
1736 {
1737         float c;
1738         c = self.clientcolors & 15;
1739         // LordHavoc: only bothering to support white, green, red, yellow, blue
1740              if (!teamplay) self.colormod = '0 0 0';
1741         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1742         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1743         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1744         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1745         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1746         else self.colormod = '1 1 1';
1747 }*/
1748
1749 void respawn(void)
1750 {
1751         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1752         {
1753                 self.solid = SOLID_NOT;
1754                 self.takedamage = DAMAGE_NO;
1755                 self.movetype = MOVETYPE_FLY;
1756                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1757                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1758                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1759                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1760                 if(autocvar_g_respawn_ghosts_maxtime)
1761                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1762         }
1763
1764         CopyBody(1);
1765
1766         self.effects |= EF_NODRAW; // prevent another CopyBody
1767         PutClientInServer();
1768 }
1769
1770 void play_countdown(float finished, string samp)
1771 {
1772         if(clienttype(self) == CLIENTTYPE_REAL)
1773                 if(floor(finished - time - frametime) != floor(finished - time))
1774                         if(finished - time < 6)
1775                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1776 }
1777
1778 void player_powerups (void)
1779 {
1780         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1781         olditems = self.items;
1782
1783         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1784         {
1785                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1786                 self.modelflags |= MF_ROCKET;
1787         }
1788         else
1789         {
1790                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1791                 self.modelflags &~= MF_ROCKET;
1792         }
1793
1794         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1795
1796         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1797                 return;
1798
1799         Fire_ApplyDamage(self);
1800         Fire_ApplyEffect(self);
1801
1802         if (g_minstagib)
1803         {
1804                 self.effects |= EF_FULLBRIGHT;
1805
1806                 if (self.items & IT_STRENGTH)
1807                 {
1808                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1809                         if (time > self.strength_finished)
1810                         {
1811                                 self.alpha = default_player_alpha;
1812                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1813                                 self.items &~= IT_STRENGTH;
1814                                 sprint(self, "^3Invisibility has worn off\n");
1815                         }
1816                 }
1817                 else
1818                 {
1819                         if (time < self.strength_finished)
1820                         {
1821                                 self.alpha = g_minstagib_invis_alpha;
1822                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1823                                 self.items |= IT_STRENGTH;
1824                                 sprint(self, "^3You are invisible\n");
1825                         }
1826                 }
1827
1828                 if (self.items & IT_INVINCIBLE)
1829                 {
1830                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1831                         if (time > self.invincible_finished)
1832                         {
1833                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1834                                 sprint(self, "^3Speed has worn off\n");
1835                         }
1836                 }
1837                 else
1838                 {
1839                         if (time < self.invincible_finished)
1840                         {
1841                                 self.items = self.items | IT_INVINCIBLE;
1842                                 sprint(self, "^3You are on speed\n");
1843                         }
1844                 }
1845         }
1846         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1847         {
1848                 if (self.items & IT_STRENGTH)
1849                 {
1850                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1851                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1852                         if (time > self.strength_finished)
1853                         {
1854                                 self.items = self.items - (self.items & IT_STRENGTH);
1855                                 sprint(self, "^3Strength has worn off\n");
1856                         }
1857                 }
1858                 else
1859                 {
1860                         if (time < self.strength_finished)
1861                         {
1862                                 self.items = self.items | IT_STRENGTH;
1863                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1864                         }
1865                 }
1866                 if (self.items & IT_INVINCIBLE)
1867                 {
1868                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1869                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1870                         if (time > self.invincible_finished)
1871                         {
1872                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1873                                 sprint(self, "^3Shield has worn off\n");
1874                         }
1875                 }
1876                 else
1877                 {
1878                         if (time < self.invincible_finished)
1879                         {
1880                                 self.items = self.items | IT_INVINCIBLE;
1881                                 sprint(self, "^3Shield surrounds you\n");
1882                         }
1883                 }
1884                 if (self.items & IT_SUPERWEAPON)
1885                 {
1886                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1887                         {
1888                                 self.superweapons_finished = 0;
1889                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1890                                 sprint(self, "^3Superweapons have been lost\n");
1891                         }
1892                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1893                         {
1894                                 // don't let them run out
1895                         }
1896                         else
1897                         {
1898                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1899                                 if (time > self.superweapons_finished)
1900                                 {
1901                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1902                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1903                                         sprint(self, "^3Superweapons have broken down\n");
1904                                 }
1905                         }
1906                 }
1907                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1908                 {
1909                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1910                         {
1911                                 self.items = self.items | IT_SUPERWEAPON;
1912                                 sprint(self, "^3You now have a superweapon\n");
1913                         }
1914                         else
1915                         {
1916                                 self.superweapons_finished = 0;
1917                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1918                         }
1919                 }
1920                 else
1921                 {
1922                         self.superweapons_finished = 0;
1923                 }
1924         }
1925
1926         if(autocvar_g_nodepthtestplayers)
1927                 self.effects = self.effects | EF_NODEPTHTEST;
1928
1929         if(autocvar_g_fullbrightplayers)
1930                 self.effects = self.effects | EF_FULLBRIGHT;
1931
1932         // midair gamemode: damage only while in the air
1933         // if in midair mode, being on ground grants temporary invulnerability
1934         // (this is so that multishot weapon don't clear the ground flag on the
1935         // first damage in the frame, leaving the player vulnerable to the
1936         // remaining hits in the same frame)
1937         if (self.flags & FL_ONGROUND)
1938         if (g_midair)
1939                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1940
1941         if (time >= game_starttime)
1942         if (time < self.spawnshieldtime)
1943                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1944
1945         MUTATOR_CALLHOOK(PlayerPowerups);
1946 }
1947
1948 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1949 {
1950         if(current > stable)
1951                 return current;
1952         else if(current > stable - 0.25) // when close enough, "snap"
1953                 return stable;
1954         else
1955                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1956 }
1957
1958 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1959 {
1960         if(current < stable)
1961                 return current;
1962         else if(current < stable + 0.25) // when close enough, "snap"
1963                 return stable;
1964         else
1965                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1966 }
1967
1968 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1969 {
1970         if(current > rotstable)
1971         {
1972                 if(rotframetime > 0)
1973                 {
1974                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1975                         current = max(rotstable, current - rotlinear * rotframetime);
1976                 }
1977         }
1978         else if(current < regenstable)
1979         {
1980                 if(regenframetime > 0)
1981                 {
1982                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1983                         current = min(regenstable, current + regenlinear * regenframetime);
1984                 }
1985         }
1986
1987         if(current > limit)
1988                 current = limit;
1989
1990         return current;
1991 }
1992
1993 void player_regen (void)
1994 {
1995         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1996         maxh = autocvar_g_balance_health_rotstable;
1997         maxa = autocvar_g_balance_armor_rotstable;
1998         maxf = autocvar_g_balance_fuel_rotstable;
1999         minh = autocvar_g_balance_health_regenstable;
2000         mina = autocvar_g_balance_armor_regenstable;
2001         minf = autocvar_g_balance_fuel_regenstable;
2002         limith = autocvar_g_balance_health_limit;
2003         limita = autocvar_g_balance_armor_limit;
2004         limitf = autocvar_g_balance_fuel_limit;
2005
2006         max_mod = regen_mod = rot_mod = limit_mod = 1;
2007
2008         if (self.runes & RUNE_REGEN)
2009         {
2010                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2011                 {
2012                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2013                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2014                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2015                 }
2016                 else
2017                 {
2018                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2019                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2020                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2021                 }
2022         }
2023         else if (self.runes & CURSE_VENOM)
2024         {
2025                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2026                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2027                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2028                 else
2029                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2030                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2031                 //if (!self.runes & RUNE_REGEN)
2032                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2033         }
2034         maxh = maxh * max_mod;
2035         //maxa = maxa * max_mod;
2036         //maxf = maxf * max_mod;
2037         minh = minh * max_mod;
2038         //mina = mina * max_mod;
2039         //minf = minf * max_mod;
2040         limith = limith * limit_mod;
2041         limita = limita * limit_mod;
2042         //limitf = limitf * limit_mod;
2043
2044         if(g_lms && g_ca)
2045                 rot_mod = 0;
2046
2047         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2048         {
2049                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2050                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2051
2052                 // if player rotted to death...  die!
2053                 if(self.health < 1)
2054                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2055         }
2056
2057         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2058                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2059 }
2060
2061 float zoomstate_set;
2062 void SetZoomState(float z)
2063 {
2064         if(z != self.zoomstate)
2065         {
2066                 self.zoomstate = z;
2067                 ClientData_Touch(self);
2068         }
2069         zoomstate_set = 1;
2070 }
2071
2072 void GetPressedKeys(void) {
2073         MUTATOR_CALLHOOK(GetPressedKeys);
2074         if (self.movement_x > 0) // get if movement keys are pressed
2075         {       // forward key pressed
2076                 self.pressedkeys |= KEY_FORWARD;
2077                 self.pressedkeys &~= KEY_BACKWARD;
2078         }
2079         else if (self.movement_x < 0)
2080         {       // backward key pressed
2081                 self.pressedkeys |= KEY_BACKWARD;
2082                 self.pressedkeys &~= KEY_FORWARD;
2083         }
2084         else
2085         {       // no x input
2086                 self.pressedkeys &~= KEY_FORWARD;
2087                 self.pressedkeys &~= KEY_BACKWARD;
2088         }
2089
2090         if (self.movement_y > 0)
2091         {       // right key pressed
2092                 self.pressedkeys |= KEY_RIGHT;
2093                 self.pressedkeys &~= KEY_LEFT;
2094         }
2095         else if (self.movement_y < 0)
2096         {       // left key pressed
2097                 self.pressedkeys |= KEY_LEFT;
2098                 self.pressedkeys &~= KEY_RIGHT;
2099         }
2100         else
2101         {       // no y input
2102                 self.pressedkeys &~= KEY_RIGHT;
2103                 self.pressedkeys &~= KEY_LEFT;
2104         }
2105
2106         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2107                 self.pressedkeys |= KEY_JUMP;
2108         else
2109                 self.pressedkeys &~= KEY_JUMP;
2110         if (self.BUTTON_CROUCH)
2111                 self.pressedkeys |= KEY_CROUCH;
2112         else
2113                 self.pressedkeys &~= KEY_CROUCH;
2114 }
2115
2116 /*
2117 ======================
2118 spectate mode routines
2119 ======================
2120 */
2121
2122 void SpectateCopy(entity spectatee) {
2123         other = spectatee;
2124         MUTATOR_CALLHOOK(SpectateCopy);
2125         self.armortype = spectatee.armortype;
2126         self.armorvalue = spectatee.armorvalue;
2127         self.ammo_cells = spectatee.ammo_cells;
2128         self.ammo_shells = spectatee.ammo_shells;
2129         self.ammo_nails = spectatee.ammo_nails;
2130         self.ammo_rockets = spectatee.ammo_rockets;
2131         self.ammo_fuel = spectatee.ammo_fuel;
2132         self.clip_load = spectatee.clip_load;
2133         self.clip_size = spectatee.clip_size;
2134         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2135         self.health = spectatee.health;
2136         self.impulse = 0;
2137         self.items = spectatee.items;
2138         self.last_pickup = spectatee.last_pickup;
2139         self.hit_time = spectatee.hit_time;
2140         self.metertime = spectatee.metertime;
2141         self.strength_finished = spectatee.strength_finished;
2142         self.invincible_finished = spectatee.invincible_finished;
2143         self.pressedkeys = spectatee.pressedkeys;
2144         WEPSET_COPY_EE(self, spectatee);
2145         self.switchweapon = spectatee.switchweapon;
2146         self.switchingweapon = spectatee.switchingweapon;
2147         self.weapon = spectatee.weapon;
2148         self.nex_charge = spectatee.nex_charge;
2149         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2150         self.hagar_load = spectatee.hagar_load;
2151         self.minelayer_mines = spectatee.minelayer_mines;
2152         self.punchangle = spectatee.punchangle;
2153         self.view_ofs = spectatee.view_ofs;
2154         self.v_angle = spectatee.v_angle;
2155         self.velocity = spectatee.velocity;
2156         self.dmg_take = spectatee.dmg_take;
2157         self.dmg_save = spectatee.dmg_save;
2158         self.dmg_inflictor = spectatee.dmg_inflictor;
2159         self.angles = spectatee.v_angle;
2160         if(!self.BUTTON_USE)
2161                 self.fixangle = TRUE;
2162         setorigin(self, spectatee.origin);
2163         setsize(self, spectatee.mins, spectatee.maxs);
2164         SetZoomState(spectatee.zoomstate);
2165
2166         anticheat_spectatecopy(spectatee);
2167
2168         //self.vehicle = spectatee.vehicle;
2169
2170         self.hud = spectatee.hud;
2171         if(spectatee.vehicle)
2172     {
2173         setorigin(self, spectatee.origin);
2174         self.velocity = spectatee.vehicle.velocity;
2175         self.v_angle += spectatee.vehicle.angles;
2176         //self.v_angle_x *= -1;
2177         self.vehicle_health = spectatee.vehicle_health;
2178         self.vehicle_shield = spectatee.vehicle_shield;
2179         self.vehicle_energy = spectatee.vehicle_energy;
2180         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2181         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2182         self.vehicle_reload1 = spectatee.vehicle_reload1;
2183         self.vehicle_reload2 = spectatee.vehicle_reload2;
2184
2185         msg_entity = self;
2186         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2187         WriteEntity(MSG_ONE, spectatee);
2188         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2189     }
2190 }
2191
2192 float SpectateUpdate() {
2193         if(!self.enemy)
2194             return 0;
2195
2196         if (self == self.enemy)
2197                 return 0;
2198
2199         if(self.enemy.classname != "player")
2200                 return 0;
2201
2202         SpectateCopy(self.enemy);
2203
2204         return 1;
2205 }
2206
2207
2208 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2209 entity CA_SpectateNext(entity start) {
2210         if (start.team == self.team) {
2211                 return start;
2212         }
2213
2214         other = start;
2215         // continue from current player
2216         while(other && other.team != self.team) {
2217                 other = find(other, classname, "player");
2218         }
2219
2220         if (!other) {
2221                 // restart from begining
2222                 other = find(other, classname, "player");
2223                 while(other && other.team != self.team) {
2224                         other = find(other, classname, "player");
2225                 }
2226         }
2227
2228         return other;
2229 }
2230
2231 float SpectateNext() {
2232         other = find(self.enemy, classname, "player");
2233         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2234                 // CA and ca players when spectating enemies is forbidden
2235                 other = CA_SpectateNext(other);
2236         } else {
2237                 // other modes and ca spectators or spectating enemies is allowed
2238                 if (!other)
2239                         other = find(other, classname, "player");
2240         }
2241
2242         if (other)
2243                 self.enemy = other;
2244
2245         if(self.enemy.classname == "player") {
2246             if(self.enemy.vehicle)
2247             {
2248             msg_entity = self;
2249             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2250             WriteEntity(MSG_ONE, self.enemy);
2251             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2252             self.movetype = MOVETYPE_NONE;
2253             accuracy_resend(self);
2254             }
2255             else
2256             {
2257             msg_entity = self;
2258             WriteByte(MSG_ONE, SVC_SETVIEW);
2259             WriteEntity(MSG_ONE, self.enemy);
2260             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2261             self.movetype = MOVETYPE_NONE;
2262             accuracy_resend(self);
2263
2264             if(!SpectateUpdate())
2265                 PutObserverInServer();
2266         }
2267         return 1;
2268         } else {
2269                 return 0;
2270         }
2271 }
2272
2273 /*
2274 =============
2275 ShowRespawnCountdown()
2276
2277 Update a respawn countdown display.
2278 =============
2279 */
2280 void ShowRespawnCountdown()
2281 {
2282         float number;
2283         if(self.deadflag == DEAD_NO) // just respawned?
2284                 return;
2285         else
2286         {
2287                 number = ceil(self.respawn_time - time);
2288                 if(number <= 0)
2289                         return;
2290                 if(number <= self.respawn_countdown)
2291                 {
2292                         self.respawn_countdown = number - 1;
2293                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2294                                 AnnounceTo(self, strcat(ftos(number), ""));
2295                 }
2296         }
2297 }
2298
2299 .float prevent_join_msgtime;
2300 void LeaveSpectatorMode()
2301 {
2302         if(nJoinAllowed(self)) {
2303                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2304                         self.classname = "player";
2305
2306                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2307                                 JoinBestTeam(self, FALSE, TRUE);
2308
2309                         if(autocvar_g_campaign)
2310                                 campaign_bots_may_start = 1;
2311
2312                         PutClientInServer();
2313
2314                         if(self.classname == "player")
2315                                 bprint ("^4", self.netname, "^4 is playing now\n");
2316
2317                         if(!autocvar_g_campaign)
2318                         if (time < self.jointime + autocvar_welcome_message_time)
2319                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2320
2321                         if (self.prevent_join_msgtime)
2322                         {
2323                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2324                                 self.prevent_join_msgtime = 0;
2325                         }
2326
2327                         return;
2328                 } else {
2329                         if (g_ca && self.caplayer) {
2330                         }       // do nothing
2331                         else
2332                                 stuffcmd(self,"menu_showteamselect\n");
2333                         return;
2334                 }
2335         }
2336         else {
2337                 //player may not join because of g_maxplayers is set
2338                 if (time - self.prevent_join_msgtime > 2)
2339                 {
2340                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2341                         self.prevent_join_msgtime = time;
2342                 }
2343         }
2344 }
2345
2346 /**
2347  * Determines whether the player is allowed to join. This depends on cvar
2348  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2349  * it checks whether the number of currently playing players exceeds g_maxplayers.
2350  * @return int number of free slots for players, 0 if none
2351  */
2352 float nJoinAllowed(entity ignore) {
2353         if(!ignore)
2354         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2355         // so report 0 free slots if restricted
2356         {
2357                 if(autocvar_g_forced_team_otherwise == "spectate")
2358                         return 0;
2359                 if(autocvar_g_forced_team_otherwise == "spectator")
2360                         return 0;
2361         }
2362
2363         if(self.team_forced < 0)
2364                 return 0; // forced spectators can never join
2365
2366         // TODO simplify this
2367         entity e;
2368         float totalClients;
2369         FOR_EACH_CLIENT(e)
2370                 if(e != ignore)
2371                         totalClients += 1;
2372
2373         if (!autocvar_g_maxplayers)
2374                 return maxclients - totalClients;
2375
2376         float currentlyPlaying;
2377         FOR_EACH_REALPLAYER(e)
2378                 currentlyPlaying += 1;
2379
2380         if(currentlyPlaying < autocvar_g_maxplayers)
2381                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2382
2383         return 0;
2384 }
2385
2386 /**
2387  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2388  * g_maxplayers_spectator_blocktime seconds
2389  */
2390 void checkSpectatorBlock() {
2391         if(self.classname == "spectator" || self.classname == "observer") {
2392                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2393                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2394                         dropclient(self);
2395                 }
2396         }
2397 }
2398
2399 .float motd_actived_time; // used for both motd and campaign_message
2400 void PrintWelcomeMessage()
2401 {
2402         if (self.motd_actived_time == 0) { // is there already a message showing?
2403                 if (autocvar_g_campaign) {
2404                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2405                                 self.motd_actived_time = time;
2406                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2407                         }
2408                 } else {
2409                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2410                                 self.motd_actived_time = time;
2411                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2412                         }
2413                 }
2414         } else { // showing MOTD or campaign message
2415                 if (autocvar_g_campaign) {
2416                         if (self.BUTTON_INFO)
2417                                 self.motd_actived_time = time;
2418                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2419                                 self.motd_actived_time = 0;
2420                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2421                         }
2422                 } else {
2423                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2424                                 if (self.BUTTON_INFO)
2425                                         self.motd_actived_time = time;
2426                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2427                                         self.motd_actived_time = 0;
2428                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2429                                 }
2430                         }
2431                 }
2432         }
2433 }
2434
2435 void ObserverThink()
2436 {
2437         float prefered_movetype;
2438         if (self.flags & FL_JUMPRELEASED) {
2439                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2440                         self.flags &~= FL_JUMPRELEASED;
2441                         self.flags |= FL_SPAWNING;
2442                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2443                         self.flags &~= FL_JUMPRELEASED;
2444                         if(SpectateNext() == 1) {
2445                                 self.classname = "spectator";
2446                         }
2447                 } else {
2448                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2449                         if (self.movetype != prefered_movetype)
2450                                 self.movetype = prefered_movetype;
2451                 }
2452         } else {
2453                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2454                         self.flags |= FL_JUMPRELEASED;
2455                         if(self.flags & FL_SPAWNING)
2456                         {
2457                                 self.flags &~= FL_SPAWNING;
2458                                 LeaveSpectatorMode();
2459                                 return;
2460                         }
2461                 }
2462         }
2463
2464         PrintWelcomeMessage();
2465 }
2466
2467 void SpectatorThink()
2468 {
2469         if (self.flags & FL_JUMPRELEASED) {
2470                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2471                         self.flags &~= FL_JUMPRELEASED;
2472                         self.flags |= FL_SPAWNING;
2473                 } else if(self.BUTTON_ATCK) {
2474                         self.flags &~= FL_JUMPRELEASED;
2475                         if(SpectateNext() == 1) {
2476                                 self.classname = "spectator";
2477                         } else {
2478                                 self.classname = "observer";
2479                                 PutClientInServer();
2480                         }
2481                 } else if (self.BUTTON_ATCK2) {
2482                         self.flags &~= FL_JUMPRELEASED;
2483                         self.classname = "observer";
2484                         PutClientInServer();
2485                 } else {
2486                         if(!SpectateUpdate())
2487                                 PutObserverInServer();
2488                 }
2489         } else {
2490                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2491                         self.flags |= FL_JUMPRELEASED;
2492                         if(self.flags & FL_SPAWNING)
2493                         {
2494                                 self.flags &~= FL_SPAWNING;
2495                                 LeaveSpectatorMode();
2496                                 return;
2497                         }
2498                 }
2499                 if(!SpectateUpdate())
2500                         PutObserverInServer();
2501         }
2502
2503         PrintWelcomeMessage();
2504         self.flags |= FL_CLIENT | FL_NOTARGET;
2505 }
2506
2507 void PlayerUseKey()
2508 {
2509         if(self.classname != "player")
2510                 return;
2511
2512         if(self.vehicle)
2513         {
2514         vehicles_exit(VHEF_NORMAL);
2515         return;
2516         }
2517
2518         // a use key was pressed; call handlers
2519         MUTATOR_CALLHOOK(PlayerUseKey);
2520 }
2521
2522 .float touchexplode_time;
2523
2524 /*
2525 =============
2526 PlayerPreThink
2527
2528 Called every frame for each client before the physics are run
2529 =============
2530 */
2531 .float usekeypressed;
2532 void() nexball_setstatus;
2533 .float items_added;
2534 void PlayerPreThink (void)
2535 {
2536         WarpZone_PlayerPhysics_FixVAngle();
2537
2538         self.stat_game_starttime = game_starttime;
2539         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2540         self.stat_leadlimit = autocvar_leadlimit;
2541
2542         if(frametime)
2543         {
2544                 // physics frames: update anticheat stuff
2545                 anticheat_prethink();
2546         }
2547
2548         if(blockSpectators && frametime)
2549                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2550                 checkSpectatorBlock();
2551
2552         zoomstate_set = 0;
2553
2554         if(self.netname_previous != self.netname)
2555         {
2556                 if(autocvar_sv_eventlog)
2557                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2558                 if(self.netname_previous)
2559                         strunzone(self.netname_previous);
2560                 self.netname_previous = strzone(self.netname);
2561         }
2562
2563         // version nagging
2564         if(self.version_nagtime)
2565                 if(self.cvar_g_xonoticversion)
2566                         if(time > self.version_nagtime)
2567                         {
2568                                 // don't notify git users
2569                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2570                                 {
2571                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2572                                         {
2573                                                 // notify release users if connecting to git
2574                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2575                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2576                                         }
2577                                         else
2578                                         {
2579                                                 float r;
2580                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2581                                                 if(r < 0)
2582                                                 {
2583                                                         // give users new version
2584                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2585                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2586                                                 }
2587                                                 else if(r > 0)
2588                                                 {
2589                                                         // notify users about old server version
2590                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2591                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2592                                                 }
2593                                         }
2594                                 }
2595                                 self.version_nagtime = 0;
2596                         }
2597
2598         // GOD MODE info
2599         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2600         {
2601                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2602                 self.max_armorvalue = 0;
2603         }
2604
2605 #ifdef TETRIS
2606         if (TetrisPreFrame())
2607                 return;
2608 #endif
2609
2610         MUTATOR_CALLHOOK(PlayerPreThink);
2611
2612         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2613         {
2614                 if(self.BUTTON_USE && !self.usekeypressed)
2615                         PlayerUseKey();
2616                 self.usekeypressed = self.BUTTON_USE;
2617         }
2618
2619         PrintWelcomeMessage();
2620
2621         if(self.classname == "player") {
2622 //              if(self.netname == "Wazat")
2623 //                      bprint(self.classname, "\n");
2624
2625                 CheckRules_Player();
2626
2627                 if (intermission_running)
2628                 {
2629                         IntermissionThink ();   // otherwise a button could be missed between
2630                         return;                                 // the think tics
2631                 }
2632
2633                 //don't allow the player to turn around while game is paused!
2634                 if(timeout_status == TIMEOUT_ACTIVE) {
2635                         // FIXME turn this into CSQC stuff
2636                         self.v_angle = self.lastV_angle;
2637                         self.angles = self.lastV_angle;
2638                         self.fixangle = TRUE;
2639                 }
2640
2641                 if(frametime)
2642                 {
2643 #ifndef NO_LEGACY_NETWORKING
2644                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2645 #endif
2646
2647                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2648                         {
2649                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2650                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2651                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2652
2653                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2654                                 {
2655                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2656                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2657                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2658                                 }
2659                         }
2660                         else
2661                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2662
2663                         player_powerups();
2664                 }
2665
2666                 if (g_minstagib)
2667                         minstagib_ammocheck();
2668
2669                 if (self.deadflag != DEAD_NO)
2670                 {
2671                         float button_pressed, force_respawn;
2672                         if(self.personal && g_race_qualifying)
2673                         {
2674                                 if(time > self.respawn_time)
2675                                 {
2676                                         self.respawn_time = time + 1; // only retry once a second
2677                                         respawn();
2678                                         self.impulse = 141;
2679                                 }
2680                         }
2681                         else
2682                         {
2683                                 if(frametime)
2684                                         player_anim();
2685                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2686                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2687                                 if (self.deadflag == DEAD_DYING)
2688                                 {
2689                                         if(force_respawn)
2690                                                 self.deadflag = DEAD_RESPAWNING;
2691                                         else if(!button_pressed)
2692                                                 self.deadflag = DEAD_DEAD;
2693                                 }
2694                                 else if (self.deadflag == DEAD_DEAD)
2695                                 {
2696                                         if(button_pressed)
2697                                                 self.deadflag = DEAD_RESPAWNABLE;
2698                                 }
2699                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2700                                 {
2701                                         if(!button_pressed)
2702                                                 self.deadflag = DEAD_RESPAWNING;
2703                                 }
2704                                 else if (self.deadflag == DEAD_RESPAWNING)
2705                                 {
2706                                         if(time > self.respawn_time)
2707                                         {
2708                                                 self.respawn_time = time + 1; // only retry once a second
2709                                                 respawn();
2710                                         }
2711                                 }
2712                                 ShowRespawnCountdown();
2713                         }
2714                         return;
2715                 }
2716                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2717                 // so (self.deadflag == DEAD_NO) is always true in the code below
2718
2719                 if(g_touchexplode)
2720                 if(time > self.touchexplode_time)
2721                 if(self.classname == "player")
2722                 if(self.deadflag == DEAD_NO)
2723                 if not(IS_INDEPENDENT_PLAYER(self))
2724                 FOR_EACH_PLAYER(other) if(self != other)
2725                 {
2726                         if(time > other.touchexplode_time)
2727                         if(other.deadflag == DEAD_NO)
2728                         if not(IS_INDEPENDENT_PLAYER(other))
2729                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2730                         {
2731                                 PlayerTouchExplode(self, other);
2732                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2733                         }
2734                 }
2735
2736                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2737                 {
2738                         vector dist;
2739
2740                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2741                         dist = self.prevorigin - self.origin;
2742                         dist_z = 0;
2743                         self.lms_traveled_distance += fabs(vlen(dist));
2744
2745                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2746                         {
2747                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2748                                 self.lms_traveled_distance = 0;
2749                         }
2750
2751                         if(time > self.lms_nextcheck)
2752                         {
2753                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2754                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2755                                 {
2756                                         centerprint(self, autocvar_g_lms_campcheck_message);
2757                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2758                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2759                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2760                                 }
2761                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2762                                 self.lms_traveled_distance = 0;
2763                         }
2764                 }
2765
2766                 self.prevorigin = self.origin;
2767
2768                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2769                 {
2770                         if (!self.crouch)
2771                         {
2772                                 self.crouch = TRUE;
2773                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2774                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2775                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2776                         }
2777                 }
2778                 else
2779                 {
2780                         if (self.crouch)
2781                         {
2782                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2783                                 if (!trace_startsolid)
2784                                 {
2785                                         self.crouch = FALSE;
2786                                         self.view_ofs = PL_VIEW_OFS;
2787                                         setsize (self, PL_MIN, PL_MAX);
2788                                 }
2789                         }
2790                 }
2791
2792                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2793                 {
2794                         if(self.bloodloss_timer < time)
2795                         {
2796                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2797                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2798                         }
2799                 }
2800
2801                 FixPlayermodel();
2802
2803                 GrapplingHookFrame();
2804
2805                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2806                 //if(frametime)
2807                 {
2808                         self.items &~= self.items_added;
2809
2810                         W_WeaponFrame();
2811
2812                         self.items_added = 0;
2813                         if(self.items & IT_JETPACK)
2814                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2815                                         self.items_added |= IT_FUEL;
2816
2817                         self.items |= self.items_added;
2818                 }
2819
2820                 player_regen();
2821
2822                 // rot nex charge to the charge limit
2823                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2824                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2825
2826                 if(frametime)
2827                         player_anim();
2828
2829                 if(g_nexball)
2830                         nexball_setstatus();
2831
2832                 // secret status
2833                 secrets_setstatus();
2834
2835                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2836
2837                 //self.angles_y=self.v_angle_y + 90;   // temp
2838         } else if(gameover) {
2839                 if (intermission_running)
2840                         IntermissionThink ();   // otherwise a button could be missed between
2841                 return;
2842         } else if(self.classname == "observer") {
2843                 ObserverThink();
2844         } else if(self.classname == "spectator") {
2845                 SpectatorThink();
2846         }
2847
2848         if(!zoomstate_set)
2849                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2850
2851         float oldspectatee_status;
2852         oldspectatee_status = self.spectatee_status;
2853         if(self.classname == "spectator")
2854                 self.spectatee_status = num_for_edict(self.enemy);
2855         else if(self.classname == "observer")
2856                 self.spectatee_status = num_for_edict(self);
2857         else
2858                 self.spectatee_status = 0;
2859         if(self.spectatee_status != oldspectatee_status)
2860         {
2861                 ClientData_Touch(self);
2862                 if(g_race || g_cts)
2863                         race_InitSpectator();
2864         }
2865
2866         if(self.teamkill_soundtime)
2867         if(time > self.teamkill_soundtime)
2868         {
2869                 self.teamkill_soundtime = 0;
2870
2871                 entity oldpusher, oldself;
2872
2873                 oldself = self; self = self.teamkill_soundsource;
2874                 oldpusher = self.pusher; self.pusher = oldself;
2875
2876                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2877
2878                 self.pusher = oldpusher;
2879                 self = oldself;
2880         }
2881
2882         if(self.taunt_soundtime)
2883         if(time > self.taunt_soundtime)
2884         {
2885                 self.taunt_soundtime = 0;
2886                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2887         }
2888
2889         target_voicescript_next(self);
2890
2891         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2892         if(!self.weapon)
2893                 self.clip_load = self.clip_size = 0;
2894 }
2895
2896 float isInvisibleString(string s)
2897 {
2898         float i, n, c;
2899         s = strdecolorize(s);
2900         for((i = 0), (n = strlen(s)); i < n; ++i)
2901         {
2902                 c = str2chr(s, i);
2903                 switch(c)
2904                 {
2905                         case 0:
2906                         case 32: // space
2907                                 break;
2908                         case 192: // charmap space
2909                                 if (!autocvar_utf8_enable)
2910                                         break;
2911                                 return FALSE;
2912                         case 160: // space in unicode fonts
2913                         case 0xE000 + 192: // utf8 charmap space
2914                                 if (autocvar_utf8_enable)
2915                                         break;
2916                         default:
2917                                 return FALSE;
2918                 }
2919         }
2920         return TRUE;
2921 }
2922
2923 /*
2924 =============
2925 PlayerPostThink
2926
2927 Called every frame for each client after the physics are run
2928 =============
2929 */
2930 .float idlekick_lasttimeleft;
2931 .entity showheadshotbbox;
2932 void showheadshotbbox_think()
2933 {
2934         if(self.owner.showheadshotbbox != self)
2935         {
2936                 remove(self);
2937                 return;
2938         }
2939         self.nextthink = time;
2940         setorigin(self, self.owner.origin);
2941         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2942 }
2943 void PlayerPostThink (void)
2944 {
2945         // Savage: Check for nameless players
2946         if (isInvisibleString(self.netname)) {
2947                 self.netname = "Player";
2948                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2949         }
2950
2951         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2952         {
2953                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2954                 {
2955                         if(self.idlekick_lasttimeleft)
2956                         {
2957                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2958                                 self.idlekick_lasttimeleft = 0;
2959                         }
2960                 }
2961                 else
2962                 {
2963                         float timeleft;
2964                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2965                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2966                         {
2967                                 if(!self.idlekick_lasttimeleft)
2968                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2969                         }
2970                         if(timeleft <= 0)
2971                         {
2972                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2973                                 AnnounceTo(self, "terminated");
2974                                 dropclient(self);
2975                                 return;
2976                         }
2977                         else if(timeleft <= 10)
2978                         {
2979                                 if(timeleft != self.idlekick_lasttimeleft)
2980                                         AnnounceTo(self, ftos(timeleft));
2981                                 self.idlekick_lasttimeleft = timeleft;
2982                         }
2983                 }
2984         }
2985
2986 #ifdef TETRIS
2987         if(self.impulse == 100)
2988                 ImpulseCommands();
2989         if (!TetrisPostFrame())
2990         {
2991 #endif
2992
2993         CheatFrame();
2994
2995         //CheckPlayerJump();
2996
2997         if(self.classname == "player") {
2998                 CheckRules_Player();
2999                 UpdateChatBubble();
3000                 if (self.impulse)
3001                         ImpulseCommands();
3002                 if (intermission_running)
3003                         return;         // intermission or finale
3004                 GetPressedKeys();
3005         } else if (self.classname == "observer") {
3006                 //do nothing
3007         } else if (self.classname == "spectator") {
3008                 //do nothing
3009         }
3010
3011 #ifdef TETRIS
3012         }
3013 #endif
3014
3015         /*
3016         float i;
3017         for(i = 0; i < 1000; ++i)
3018         {
3019                 vector end;
3020                 end = self.origin + '0 0 1024' + 512 * randomvec();
3021                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3022                 if(trace_fraction < 1)
3023                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3024                 {
3025                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3026                         break;
3027                 }
3028         }
3029         */
3030
3031         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3032
3033         if(self.waypointsprite_attachedforcarrier)
3034                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3035
3036         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3037         {
3038                 if(!self.showheadshotbbox)
3039                 {
3040                         self.showheadshotbbox = spawn();
3041                         self.showheadshotbbox.classname = "headshotbbox";
3042                         self.showheadshotbbox.owner = self;
3043                         self.showheadshotbbox.think = showheadshotbbox_think;
3044                         self.showheadshotbbox.nextthink = time;
3045                         self = self.showheadshotbbox;
3046                         self.think();
3047                         self = self.owner;
3048                 }
3049         }
3050         else
3051         {
3052                 if(self.showheadshotbbox)
3053                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3054                 remove(self.showheadshotbbox);
3055         }
3056
3057         playerdemo_write();
3058
3059         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3060         {
3061                 if(!self.stored_netname)
3062                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3063                 if(self.stored_netname != self.netname)
3064                 {
3065                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3066                         strunzone(self.stored_netname);
3067                         self.stored_netname = strzone(self.netname);
3068                 }
3069         }
3070
3071         /*
3072         if(g_race)
3073                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3074         */
3075
3076         CSQCMODEL_AUTOUPDATE();
3077 }