qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 // all weapons must be fully loaded the first time we pick them up, so set their load to maximum at respawn
 893                 self.shotgun_load = autocvar_g_balance_shotgun_reload_ammo;
 894                 self.sniperrifle_load = autocvar_g_balance_sniperrifle_reload_ammo;
 895                 self.uzi_load = autocvar_g_balance_uzi_reload_ammo;
 896                 self.grenadelauncher_load = autocvar_g_balance_grenadelauncher_reload_ammo;
 897                 self.minelayer_load = autocvar_g_balance_minelayer_reload_ammo;
 898                 self.electro_load = autocvar_g_balance_electro_reload_ammo;
 899                 self.crylink_load = autocvar_g_balance_crylink_reload_ammo;
 900                 self.hlac_load = autocvar_g_balance_hlac_reload_ammo;
 901                 self.fireball_load = autocvar_g_balance_fireball_reload_ammo;
 902                 self.seeker_load = autocvar_g_balance_fireball_reload_ammo;
 903                 self.minstanex_load = autocvar_g_balance_minstanex_reload_ammo;
 904                 self.nex_load = autocvar_g_balance_nex_reload_ammo;
 905
 906                 if(inWarmupStage)
 907                 {
 908                         self.ammo_shells = warmup_start_ammo_shells;
 909                         self.ammo_nails = warmup_start_ammo_nails;
 910                         self.ammo_rockets = warmup_start_ammo_rockets;
 911                         self.ammo_cells = warmup_start_ammo_cells;
 912                         self.ammo_fuel = warmup_start_ammo_fuel;
 913                         self.health = warmup_start_health;
 914                         self.armorvalue = warmup_start_armorvalue;
 915                         self.weapons = warmup_start_weapons;
 916                 }
 917                 else
 918                 {
 919                         self.ammo_shells = start_ammo_shells;
 920                         self.ammo_nails = start_ammo_nails;
 921                         self.ammo_rockets = start_ammo_rockets;
 922                         self.ammo_cells = start_ammo_cells;
 923                         self.ammo_fuel = start_ammo_fuel;
 924                         self.health = start_health;
 925                         self.armorvalue = start_armorvalue;
 926                         self.weapons = start_weapons;
 927                 }
 928
 929                 if(g_weaponarena_random)
 930                 {
 931                         if(g_weaponarena_random_with_laser)
 932                                 self.weapons &~= WEPBIT_LASER;
 933                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 934                         if(g_weaponarena_random_with_laser)
 935                                 self.weapons |= WEPBIT_LASER;
 936                 }
 937
 938                 self.items = start_items;
 939                 self.jump_interval = time;
 940
 941                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 942                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 943                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 944                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 945                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 946                 //extend the pause of rotting if client was reset at the beginning of the countdown
 947                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 948                         self.spawnshieldtime += game_starttime - time;
 949                         self.pauserotarmor_finished += game_starttime - time;
 950                         self.pauserothealth_finished += game_starttime - time;
 951                         self.pauseregen_finished += game_starttime - time;
 952                 }
 953                 self.damageforcescale = 2;
 954                 self.death_time = 0;
 955                 self.dead_frame = 0;
 956                 self.alpha = 0;
 957                 self.scale = 0;
 958                 self.fade_time = 0;
 959                 self.pain_frame = 0;
 960                 self.pain_finished = 0;
 961                 self.strength_finished = 0;
 962                 self.invincible_finished = 0;
 963                 self.pushltime = 0;
 964                 // players have no think function
 965                 self.think = SUB_Null;
 966                 self.nextthink = 0;
 967                 self.hook_time = 0;
 968                 self.dmg_team = 0;
 969                 self.ballistics_density = autocvar_g_ballistics_density_player;
 970
 971                 self.metertime = 0;
 972
 973                 self.runes = 0;
 974
 975                 self.deadflag = DEAD_NO;
 976
 977                 self.angles = spot.angles;
 978
 979                 self.angles_z = 0; // never spawn tilted even if the spot says to
 980                 self.fixangle = TRUE; // turn this way immediately
 981                 self.velocity = '0 0 0';
 982                 self.avelocity = '0 0 0';
 983                 self.punchangle = '0 0 0';
 984                 self.punchvector = '0 0 0';
 985                 self.oldvelocity = self.velocity;
 986                 self.fire_endtime = -1;
 987
 988                 msg_entity = self;
 989                 WRITESPECTATABLE_MSG_ONE({
 990                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 991                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 992                 });
 993
 994                 if(sv_loddistance1)
 995                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 996
 997                 self.model = "";
 998                 FixPlayermodel();
 999
1000                 self.crouch = FALSE;
1001                 self.view_ofs = PL_VIEW_OFS;
1002                 setsize (self, PL_MIN, PL_MAX);
1003                 self.spawnorigin = spot.origin;
1004                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1005                 // don't reset back to last position, even if new position is stuck in solid
1006                 self.oldorigin = self.origin;
1007                 self.prevorigin = self.origin;
1008                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1009
1010                 if(g_arena)
1011                 {
1012                         Spawnqueue_Remove(self);
1013                         Spawnqueue_Mark(self);
1014                 }
1015
1016                 else if(g_ca)
1017                         self.caplayer = 1;
1018
1019                 self.event_damage = PlayerDamage;
1020
1021                 self.bot_attack = TRUE;
1022
1023                 self.statdraintime = time + 5;
1024                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1025
1026                 if(self.killcount == -666) {
1027                         PlayerScore_Clear(self);
1028                         self.killcount = 0;
1029                 }
1030
1031                 self.cnt = WEP_LASER;
1032
1033                 CL_SpawnWeaponentity();
1034                 self.alpha = default_player_alpha;
1035                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1036                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1037
1038                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1039                 self.lms_traveled_distance = 0;
1040                 self.speedrunning = FALSE;
1041
1042                 race_PostSpawn(spot);
1043
1044                 if(autocvar_spawn_debug)
1045                 {
1046                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1047                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1048                 }
1049
1050                 //stuffcmd(self, "chase_active 0");
1051                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1052
1053                 if (autocvar_g_spawnsound)
1054                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1055
1056                 if(g_assault) {
1057                         if(self.team == assault_attacker_team)
1058                                 centerprint(self, "You are attacking!");
1059                         else
1060                                 centerprint(self, "You are defending!");
1061                 }
1062
1063                 target_voicescript_clear(self);
1064
1065                 // reset fields the weapons may use
1066                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1067                         weapon_action(j, WR_RESETPLAYER);
1068
1069                 oldself = self;
1070                 self = spot;
1071                         activator = oldself;
1072                                 SUB_UseTargets();
1073                         activator = world;
1074                 self = oldself;
1075
1076                 MUTATOR_CALLHOOK(PlayerSpawn);
1077
1078                 self.switchweapon = w_getbestweapon(self);
1079                 self.cnt = self.switchweapon;
1080                 self.weapon = 0;
1081
1082                 if(!self.alivetime)
1083                         self.alivetime = time;
1084         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1085                 PutObserverInServer ();
1086         }
1087
1088         //if(g_ctf)
1089         //      ctf_playerchanged();
1090 }
1091
1092 .float ebouncefactor, ebouncestop; // electro's values
1093 // TODO do we need all these fields, or should we stop autodetecting runtime
1094 // changes and just have a console command to update this?
1095 float ClientInit_SendEntity(entity to, float sf)
1096 {
1097         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1098         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1111         if(sv_foginterval && world.fog != "")
1112                 WriteString(MSG_ENTITY, world.fog);
1113         else
1114                 WriteString(MSG_ENTITY, "");
1115         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1116         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1117         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1118         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1119         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1122         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1123         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1124         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1125         return TRUE;
1126 }
1127
1128 void ClientInit_CheckUpdate()
1129 {
1130         self.nextthink = time;
1131         if(self.count != autocvar_g_balance_armor_blockpercent)
1132         {
1133                 self.count = autocvar_g_balance_armor_blockpercent;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1137         {
1138                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1142         {
1143                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1147         {
1148                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1149                 self.SendFlags |= 1;
1150         }
1151         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1152         {
1153                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1154                 self.SendFlags |= 1;
1155         }
1156         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1157         {
1158                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1159                 self.SendFlags |= 1;
1160         }
1161 }
1162
1163 void ClientInit_Spawn()
1164 {
1165         entity o;
1166         entity e;
1167         e = spawn();
1168         e.classname = "clientinit";
1169         e.think = ClientInit_CheckUpdate;
1170         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1171
1172         o = self;
1173         self = e;
1174         ClientInit_CheckUpdate();
1175         self = o;
1176 }
1177
1178 /*
1179 =============
1180 SetNewParms
1181 =============
1182 */
1183 void SetNewParms (void)
1184 {
1185         // initialize parms for a new player
1186         parm1 = -(86400 * 366);
1187 }
1188
1189 /*
1190 =============
1191 SetChangeParms
1192 =============
1193 */
1194 void SetChangeParms (void)
1195 {
1196         // save parms for level change
1197         parm1 = self.parm_idlesince - time;
1198 }
1199
1200 /*
1201 =============
1202 DecodeLevelParms
1203 =============
1204 */
1205 void DecodeLevelParms (void)
1206 {
1207         // load parms
1208         self.parm_idlesince = parm1;
1209         if(self.parm_idlesince == -(86400 * 366))
1210                 self.parm_idlesince = time;
1211
1212         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1213         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1214 }
1215
1216 /*
1217 =============
1218 ClientKill
1219
1220 Called when a client types 'kill' in the console
1221 =============
1222 */
1223
1224 .float clientkill_nexttime;
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else if(self.killindicator_teamchange == -2)
1233         {
1234                 if(g_ca)
1235                         self.caplayer = 0;
1236                 if(blockSpectators)
1237                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1238                 PutObserverInServer();
1239         }
1240         else
1241                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1242 }
1243
1244 void ClientKill_Now()
1245 {
1246         remove(self.killindicator);
1247         self.killindicator = world;
1248
1249         if(self.killindicator_teamchange)
1250                 ClientKill_Now_TeamChange();
1251
1252         // in any case:
1253         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1254
1255         // now I am sure the player IS dead
1256 }
1257 void KillIndicator_Think()
1258 {
1259         if (!self.owner.modelindex)
1260         {
1261                 self.owner.killindicator = world;
1262                 remove(self);
1263                 return;
1264         }
1265
1266         if(self.cnt <= 0)
1267         {
1268                 self = self.owner;
1269                 ClientKill_Now(); // no oldself needed
1270                 return;
1271         }
1272     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1273     {
1274         self.nextthink = time + 1;
1275         self.cnt -= 1;
1276     }
1277         else
1278         {
1279                 if(self.cnt <= 10)
1280                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1281                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1282                 {
1283                         if(self.cnt <= 10)
1284                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1285                         if(self.owner.killindicator_teamchange)
1286                         {
1287                                 if(self.owner.killindicator_teamchange == -1)
1288                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1289                                 else if(self.owner.killindicator_teamchange == -2)
1290                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1291                                 else
1292                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1293                         }
1294                         else
1295                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1296                 }
1297                 self.nextthink = time + 1;
1298                 self.cnt -= 1;
1299         }
1300 }
1301
1302 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1303 {
1304         float killtime;
1305         entity e;
1306         killtime = autocvar_g_balance_kill_delay;
1307
1308         if(g_race_qualifying || g_cts)
1309                 killtime = 0;
1310
1311     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1312     {
1313                 remove(self.killindicator);
1314                 self.killindicator = world;
1315
1316         ClientKill_Now(); // allow instant kill in this case
1317         return;
1318     }
1319
1320         self.killindicator_teamchange = targetteam;
1321
1322     if(!self.killindicator)
1323         {
1324                 if(self.modelindex && self.deadflag == DEAD_NO)
1325                 {
1326                         killtime = max(killtime, self.clientkill_nexttime - time);
1327                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1328                 }
1329
1330                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1331                 {
1332                         ClientKill_Now();
1333                 }
1334                 else
1335                 {
1336                         self.killindicator = spawn();
1337                         self.killindicator.owner = self;
1338                         self.killindicator.scale = 0.5;
1339                         setattachment(self.killindicator, self, "");
1340                         setorigin(self.killindicator, '0 0 52');
1341                         self.killindicator.think = KillIndicator_Think;
1342                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1343                         self.killindicator.cnt = ceil(killtime);
1344                         self.killindicator.count = bound(0, ceil(killtime), 10);
1345                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1346
1347                         for(e = world; (e = find(e, classname, "body")) != world; )
1348                         {
1349                                 if(e.enemy != self)
1350                                         continue;
1351                                 e.killindicator = spawn();
1352                                 e.killindicator.owner = e;
1353                                 e.killindicator.scale = 0.5;
1354                                 setattachment(e.killindicator, e, "");
1355                                 setorigin(e.killindicator, '0 0 52');
1356                                 e.killindicator.think = KillIndicator_Think;
1357                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1358                                 e.killindicator.cnt = ceil(killtime);
1359                         }
1360                         self.lip = 0;
1361                 }
1362         }
1363         if(self.killindicator)
1364         {
1365                 if(targetteam == 0) // just die
1366                         self.killindicator.colormod = '0 0 0';
1367                 else if(targetteam == -1) // auto
1368                         self.killindicator.colormod = '0 1 0';
1369                 else if(targetteam == -2) // spectate
1370                         self.killindicator.colormod = '0.5 0.5 0.5';
1371                 else
1372                         self.killindicator.colormod = TeamColor(targetteam);
1373         }
1374 }
1375
1376 void ClientKill (void)
1377 {
1378         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1379         {
1380                 // do nothing
1381         }
1382     else if(self.freezetag_frozen)
1383     {
1384         // do nothing
1385     }
1386         else
1387                 ClientKill_TeamChange(0);
1388 }
1389
1390 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1391 {
1392     e.killindicator = spawn();
1393     e.killindicator.owner = e;
1394     e.killindicator.think = KillIndicator_Think;
1395     e.killindicator.nextthink = time + (e.lip) * 0.05;
1396     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1397     e.killindicator.health = 1; // this is used to indicate that it should be silent
1398     e.lip = 0;
1399 }
1400
1401 void DoTeamChange(float destteam)
1402 {
1403         float t, c0;
1404         if(!teams_matter)
1405         {
1406                 if(destteam >= 0)
1407                         SetPlayerColors(self, destteam);
1408                 return;
1409         }
1410         if(self.classname == "player")
1411         if(destteam == -1)
1412         {
1413                 CheckAllowedTeams(self);
1414                 t = FindSmallestTeam(self, TRUE);
1415                 switch(self.team)
1416                 {
1417                         case COLOR_TEAM1: c0 = c1; break;
1418                         case COLOR_TEAM2: c0 = c2; break;
1419                         case COLOR_TEAM3: c0 = c3; break;
1420                         case COLOR_TEAM4: c0 = c4; break;
1421                         default:          c0 = 999;
1422                 }
1423                 switch(t)
1424                 {
1425                         case 1:
1426                                 if(c0 > c1)
1427                                         destteam = COLOR_TEAM1;
1428                                 break;
1429                         case 2:
1430                                 if(c0 > c2)
1431                                         destteam = COLOR_TEAM2;
1432                                 break;
1433                         case 3:
1434                                 if(c0 > c3)
1435                                         destteam = COLOR_TEAM3;
1436                                 break;
1437                         case 4:
1438                                 if(c0 > c4)
1439                                         destteam = COLOR_TEAM4;
1440                                 break;
1441                 }
1442                 if(destteam == -1)
1443                         return;
1444         }
1445         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1446                 return;
1447         ClientKill_TeamChange(destteam);
1448 }
1449
1450 void FixClientCvars(entity e)
1451 {
1452         // send prediction settings to the client
1453         stuffcmd(e, "\nin_bindmap 0 0\n");
1454         if(g_race || g_cts)
1455                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1456         if(autocvar_g_antilag == 3) // client side hitscan
1457                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1458         if(sv_gentle)
1459                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1460         /*
1461          * we no longer need to stuff this. Remove this comment block if you feel
1462          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1463         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1464         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1465         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1466         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1467         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1468         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1469         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1470         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1471         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1472         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1473         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1474         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1475         stuffcmd(e, "cl_movement_edgefriction 1\n");
1476          */
1477 }
1478
1479 float PlayerInIDList(entity p, string idlist)
1480 {
1481         float n, i;
1482         string s;
1483
1484         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1485         if not(p.crypto_idfp)
1486                 return 0;
1487
1488         // this function allows abbreviated player IDs too!
1489         n = tokenize_console(idlist);
1490         for(i = 0; i < n; ++i)
1491         {
1492                 s = argv(i);
1493                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1494                         return 1;
1495         }
1496
1497         return 0;
1498 }
1499
1500 /*
1501 =============
1502 ClientConnect
1503
1504 Called when a client connects to the server
1505 =============
1506 */
1507 //void ctf_clientconnect();
1508 string ColoredTeamName(float t);
1509 void DecodeLevelParms (void);
1510 //void dom_player_join_team(entity pl);
1511 void ClientConnect (void)
1512 {
1513         float t;
1514
1515         if(self.flags & FL_CLIENT)
1516         {
1517                 print("Warning: ClientConnect, but already connected!\n");
1518                 return;
1519         }
1520
1521         if(Ban_MaybeEnforceBan(self))
1522                 return;
1523
1524         DecodeLevelParms();
1525
1526 #ifdef WATERMARK
1527         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1528 #endif
1529
1530         self.classname = "player_joining";
1531
1532         self.flags = FL_CLIENT;
1533         self.version_nagtime = time + 10 + random() * 10;
1534
1535         if(player_count<0)
1536         {
1537                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1538                 player_count = 0;
1539         }
1540
1541         PlayerScore_Attach(self);
1542         ClientData_Attach();
1543         accuracy_init(self);
1544
1545         bot_clientconnect();
1546
1547         playerdemo_init();
1548
1549         anticheat_init();
1550
1551         race_PreSpawnObserver();
1552
1553         //if(g_domination)
1554         //      dom_player_join_team(self);
1555
1556         // identify the right forced team
1557         if(autocvar_g_campaign)
1558         {
1559                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1560                 {
1561                         switch(autocvar_g_campaign_forceteam)
1562                         {
1563                                 case 1: self.team_forced = COLOR_TEAM1; break;
1564                                 case 2: self.team_forced = COLOR_TEAM2; break;
1565                                 case 3: self.team_forced = COLOR_TEAM3; break;
1566                                 case 4: self.team_forced = COLOR_TEAM4; break;
1567                                 default: self.team_forced = 0;
1568                         }
1569                 }
1570         }
1571         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1572                 self.team_forced = COLOR_TEAM1;
1573         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1574                 self.team_forced = COLOR_TEAM2;
1575         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1576                 self.team_forced = COLOR_TEAM3;
1577         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1578                 self.team_forced = COLOR_TEAM4;
1579         else if(autocvar_g_forced_team_otherwise == "red")
1580                 self.team_forced = COLOR_TEAM1;
1581         else if(autocvar_g_forced_team_otherwise == "blue")
1582                 self.team_forced = COLOR_TEAM2;
1583         else if(autocvar_g_forced_team_otherwise == "yellow")
1584                 self.team_forced = COLOR_TEAM3;
1585         else if(autocvar_g_forced_team_otherwise == "pink")
1586                 self.team_forced = COLOR_TEAM4;
1587         else if(autocvar_g_forced_team_otherwise == "spectate")
1588                 self.team_forced = -1;
1589         else if(autocvar_g_forced_team_otherwise == "spectator")
1590                 self.team_forced = -1;
1591         else
1592                 self.team_forced = 0;
1593
1594         if(!teams_matter)
1595                 if(self.team_forced > 0)
1596                         self.team_forced = 0;
1597
1598         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1599
1600         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1601                 self.classname = "observer";
1602         } else {
1603                 if(teams_matter)
1604                 {
1605                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1606                         {
1607                                 self.classname = "player";
1608                                 campaign_bots_may_start = 1;
1609                         }
1610                         else
1611                         {
1612                                 self.classname = "observer"; // do it anyway
1613                         }
1614                 }
1615                 else
1616                 {
1617                         self.classname = "player";
1618                         campaign_bots_may_start = 1;
1619                 }
1620         }
1621
1622         self.playerid = (playerid_last = playerid_last + 1);
1623
1624         if(autocvar_sv_eventlog)
1625                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1626
1627         LogTeamchange(self.playerid, self.team, 1);
1628
1629         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1630
1631         self.netname_previous = strzone(self.netname);
1632
1633         bprint("^4", self.netname, "^4 connected");
1634
1635         if(self.classname != "observer" && (g_domination || g_ctf))
1636                 bprint(" and joined the ", ColoredTeamName(self.team));
1637
1638         bprint("\n");
1639
1640         self.welcomemessage_time = 0;
1641
1642         stuffcmd(self, strcat(clientstuff, "\n"));
1643         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1644         stuffcmd(self, "cl_particles_reloadeffects\n");
1645
1646         FixClientCvars(self);
1647
1648         // spawnfunc_waypoint sprites
1649         WaypointSprite_InitClient(self);
1650
1651         // Wazat's grappling hook
1652         SetGrappleHookBindings();
1653
1654         // get autoswitch state from player when he toggles it
1655         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1656
1657         // get version info from player
1658         stuffcmd(self, "cmd clientversion $gameversion\n");
1659
1660         // get other cvars from player
1661         GetCvars(0);
1662
1663         // notify about available teams
1664         if(teams_matter)
1665         {
1666                 CheckAllowedTeams(self);
1667                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1668                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1669         }
1670         else
1671                 stuffcmd(self, "set _teams_available 0\n");
1672
1673         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1674
1675         if(g_arena || g_ca)
1676         {
1677                 self.classname = "observer";
1678                 if(g_arena)
1679                         Spawnqueue_Insert(self);
1680         }
1681         /*else if(g_ctf)
1682         {
1683                 ctf_clientconnect();
1684         }*/
1685
1686         if(teams_matter || radar_showennemies)
1687                 attach_entcs();
1688
1689         bot_relinkplayerlist();
1690
1691         self.spectatortime = time;
1692         if(blockSpectators)
1693         {
1694                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1695         }
1696
1697         self.jointime = time;
1698         self.allowedTimeouts = autocvar_sv_timeout_number;
1699
1700         if(clienttype(self) == CLIENTTYPE_REAL)
1701         {
1702                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1703                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1704         }
1705
1706         if(g_lms)
1707         {
1708                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1709                 {
1710                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1711                         self.frags = FRAGS_SPECTATOR;
1712                 }
1713         }
1714
1715         if(!sv_foginterval && world.fog != "")
1716                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1717
1718         SoundEntity_Attach(self);
1719
1720         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1721         {
1722                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1723                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1724         }
1725         else
1726                 self.hitplotfh = -1;
1727
1728         if(g_race || g_cts) {
1729                 string rr;
1730                 if(g_cts)
1731                         rr = CTS_RECORD;
1732                 else
1733                         rr = RACE_RECORD;
1734                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1735
1736                 msg_entity = self;
1737                 race_send_recordtime(MSG_ONE);
1738                 race_send_speedaward(MSG_ONE);
1739
1740                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1741                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1742                 race_send_speedaward_alltimebest(MSG_ONE);
1743
1744                 float i;
1745                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1746                         race_SendRankings(i, 0, 0, MSG_ONE);
1747                 }
1748         }
1749         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1750                 send_CSQC_teamnagger();
1751
1752         CheatInitClient();
1753
1754         PlayerStats_AddPlayer(self);
1755 }
1756
1757 /*
1758 =============
1759 ClientDisconnect
1760
1761 Called when a client disconnects from the server
1762 =============
1763 */
1764 .entity chatbubbleentity;
1765 .entity teambubbleentity;
1766 void ReadyCount();
1767 void ClientDisconnect (void)
1768 {
1769         if not(self.flags & FL_CLIENT)
1770         {
1771                 print("Warning: ClientDisconnect without ClientConnect\n");
1772                 return;
1773         }
1774
1775         PlayerStats_AddGlobalInfo(self);
1776
1777         CheatShutdownClient();
1778
1779         if(self.hitplotfh >= 0)
1780         {
1781                 fclose(self.hitplotfh);
1782                 self.hitplotfh = -1;
1783         }
1784
1785         anticheat_report();
1786         anticheat_shutdown();
1787
1788         playerdemo_shutdown();
1789
1790         bot_clientdisconnect();
1791
1792         if(self.entcs)
1793                 detach_entcs();
1794
1795         if(autocvar_sv_eventlog)
1796                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1797         bprint ("^4",self.netname);
1798         bprint ("^4 disconnected\n");
1799
1800         SoundEntity_Detach(self);
1801
1802         DropAllRunes(self);
1803         MUTATOR_CALLHOOK(ClientDisconnect);
1804
1805         Portal_ClearAll(self);
1806
1807         if(self.flagcarried)
1808                 DropFlag(self.flagcarried, world, world);
1809         if(self.ballcarried && g_nexball)
1810                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1811
1812         // Here, everything has been done that requires this player to be a client.
1813
1814         self.flags &~= FL_CLIENT;
1815
1816         if (self.chatbubbleentity)
1817                 remove (self.chatbubbleentity);
1818
1819         if (self.teambubbleentity)
1820                 remove (self.teambubbleentity);
1821
1822         if (self.killindicator)
1823                 remove (self.killindicator);
1824
1825         WaypointSprite_PlayerGone();
1826
1827         bot_relinkplayerlist();
1828
1829         if(g_arena)
1830         {
1831                 Spawnqueue_Unmark(self);
1832                 Spawnqueue_Remove(self);
1833         }
1834
1835         accuracy_free(self);
1836         ClientData_Detach();
1837         PlayerScore_Detach(self);
1838
1839         if(self.netname_previous)
1840                 strunzone(self.netname_previous);
1841         if(self.clientstatus)
1842                 strunzone(self.clientstatus);
1843         if(self.weaponorder_byimpulse)
1844                 strunzone(self.weaponorder_byimpulse);
1845
1846         ClearPlayerSounds();
1847
1848         if(self.personal)
1849                 remove(self.personal);
1850
1851         self.playerid = 0;
1852         ReadyCount();
1853
1854         // free cvars
1855         GetCvars(-1);
1856 }
1857
1858 .float BUTTON_CHAT;
1859 void ChatBubbleThink()
1860 {
1861         self.nextthink = time;
1862         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1863         {
1864                 if(self.owner) // but why can that ever be world?
1865                         self.owner.chatbubbleentity = world;
1866                 remove(self);
1867                 return;
1868         }
1869         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1870 #ifdef TETRIS
1871                 || self.owner.tetris_on
1872 #endif
1873         )
1874                 self.model = self.mdl;
1875         else
1876                 self.model = "";
1877 };
1878
1879 void UpdateChatBubble()
1880 {
1881         if (!self.modelindex)
1882                 return;
1883         // spawn a chatbubble entity if needed
1884         if (!self.chatbubbleentity)
1885         {
1886                 self.chatbubbleentity = spawn();
1887                 self.chatbubbleentity.owner = self;
1888                 self.chatbubbleentity.exteriormodeltoclient = self;
1889                 self.chatbubbleentity.think = ChatBubbleThink;
1890                 self.chatbubbleentity.nextthink = time;
1891                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1892                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1893                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1894                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1895                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1896                 self.chatbubbleentity.model = "";
1897                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1898         }
1899 }
1900
1901
1902 void TeamBubbleThink()
1903 {
1904         self.nextthink = time;
1905         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1906         {
1907                 if(self.owner) // but why can that ever be world?
1908                         self.owner.teambubbleentity = world;
1909                 remove(self);
1910                 return;
1911         }
1912 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1913         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1914                 self.model = "";
1915         else
1916                 self.model = self.mdl;
1917
1918 };
1919
1920 float TeamBubble_customizeentityforclient()
1921 {
1922         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1923 }
1924
1925 void UpdateTeamBubble()
1926 {
1927         if (!self.modelindex || !teams_matter)
1928                 return;
1929         // spawn a teambubble entity if needed
1930         if (!self.teambubbleentity && teams_matter)
1931         {
1932                 self.teambubbleentity = spawn();
1933                 self.teambubbleentity.owner = self;
1934                 self.teambubbleentity.exteriormodeltoclient = self;
1935                 self.teambubbleentity.think = TeamBubbleThink;
1936                 self.teambubbleentity.nextthink = time;
1937                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1938 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1939                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1940                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1941                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1942                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1943                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1944                 self.teambubbleentity.effects = EF_LOWPRECISION;
1945         }
1946 }
1947
1948 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1949 // added to the model skins
1950 /*void UpdateColorModHack()
1951 {
1952         local float c;
1953         c = self.clientcolors & 15;
1954         // LordHavoc: only bothering to support white, green, red, yellow, blue
1955              if (!teams_matter) self.colormod = '0 0 0';
1956         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1957         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1958         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1959         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1960         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1961         else self.colormod = '1 1 1';
1962 };*/
1963
1964 .float oldcolormap;
1965 void respawn(void)
1966 {
1967         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1968         {
1969                 self.solid = SOLID_NOT;
1970                 self.takedamage = DAMAGE_NO;
1971                 self.movetype = MOVETYPE_FLY;
1972                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1973                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1974                 self.effects |= EF_ADDITIVE;
1975                 self.oldcolormap = self.colormap;
1976                 self.colormap = 512;
1977                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1978                 if(autocvar_g_respawn_ghosts_maxtime)
1979                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1980         }
1981
1982         CopyBody(1);
1983         self.effects |= EF_NODRAW; // prevent another CopyBody
1984         if(self.oldcolormap)
1985         {
1986                 self.colormap = self.oldcolormap;
1987                 self.oldcolormap = 0;
1988         }
1989         PutClientInServer();
1990 }
1991
1992 void play_countdown(float finished, string samp)
1993 {
1994         if(clienttype(self) == CLIENTTYPE_REAL)
1995                 if(floor(finished - time - frametime) != floor(finished - time))
1996                         if(finished - time < 6)
1997                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1998 }
1999
2000 /**
2001  * When sv_timeout is used this function returs strings like
2002  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2003  * Called by centerprint functions
2004  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2005  */
2006 string getTimeoutText(float addOneSecond) {
2007         if (!autocvar_sv_timeout || !timeoutStatus)
2008                 return "";
2009
2010         local string retStr;
2011         if (timeoutStatus == 1) {
2012                 if (addOneSecond == 1) {
2013                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2014                 }
2015                 else {
2016                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2017                 }
2018                 return retStr;
2019         }
2020         else if (timeoutStatus == 2) {
2021                 if (addOneSecond) {
2022                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2023                         //don't show messages like "Timeout ends in 0 seconds"...
2024                         if ((remainingTimeoutTime + 1) > 0)
2025                                 return retStr;
2026                         else
2027                                 return "";
2028                 }
2029                 else {
2030                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2031                         //don't show messages like "Timeout ends in 0 seconds"...
2032                         if (remainingTimeoutTime > 0)
2033                                 return retStr;
2034                         else
2035                                 return "";
2036                 }
2037         }
2038         else return "";
2039 }
2040
2041 void player_powerups (void)
2042 {
2043         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2044         olditems = self.items;
2045
2046         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2047         {
2048                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2049                 self.modelflags |= MF_ROCKET;
2050         }
2051         else
2052         {
2053                 SoundEntity_StopSound(self, CHAN_PLAYER);
2054                 self.modelflags &~= MF_ROCKET;
2055         }
2056
2057         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2058
2059         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2060                 return;
2061
2062         Fire_ApplyDamage(self);
2063         Fire_ApplyEffect(self);
2064
2065         if (g_minstagib)
2066         {
2067                 self.effects |= EF_FULLBRIGHT;
2068
2069                 if (self.items & IT_STRENGTH)
2070                 {
2071                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2072                         if (time > self.strength_finished)
2073                         {
2074                                 self.alpha = default_player_alpha;
2075                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2076                                 self.items &~= IT_STRENGTH;
2077                                 sprint(self, "^3Invisibility has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.strength_finished)
2083                         {
2084                                 self.alpha = g_minstagib_invis_alpha;
2085                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2086                                 self.items |= IT_STRENGTH;
2087                                 sprint(self, "^3You are invisible\n");
2088                         }
2089                 }
2090
2091                 if (self.items & IT_INVINCIBLE)
2092                 {
2093                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2094                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2095                         {
2096                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2097                                 sprint(self, "^3Speed has worn off\n");
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (time < self.invincible_finished)
2103                         {
2104                                 self.items = self.items | IT_INVINCIBLE;
2105                                 sprint(self, "^3You are on speed\n");
2106                         }
2107                 }
2108         }
2109         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2110         {
2111                 if (self.items & IT_STRENGTH)
2112                 {
2113                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2114                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2115                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2116                         {
2117                                 self.items = self.items - (self.items & IT_STRENGTH);
2118                                 sprint(self, "^3Strength has worn off\n");
2119                         }
2120                 }
2121                 else
2122                 {
2123                         if (time < self.strength_finished)
2124                         {
2125                                 self.items = self.items | IT_STRENGTH;
2126                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2127                         }
2128                 }
2129                 if (self.items & IT_INVINCIBLE)
2130                 {
2131                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2132                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2133                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2134                         {
2135                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2136                                 sprint(self, "^3Shield has worn off\n");
2137                         }
2138                 }
2139                 else
2140                 {
2141                         if (time < self.invincible_finished)
2142                         {
2143                                 self.items = self.items | IT_INVINCIBLE;
2144                                 sprint(self, "^3Shield surrounds you\n");
2145                         }
2146                 }
2147
2148                 if(autocvar_g_nodepthtestplayers)
2149                         self.effects = self.effects | EF_NODEPTHTEST;
2150
2151                 if(autocvar_g_fullbrightplayers)
2152                         self.effects = self.effects | EF_FULLBRIGHT;
2153
2154                 // midair gamemode: damage only while in the air
2155                 // if in midair mode, being on ground grants temporary invulnerability
2156                 // (this is so that multishot weapon don't clear the ground flag on the
2157                 // first damage in the frame, leaving the player vulnerable to the
2158                 // remaining hits in the same frame)
2159                 if (self.flags & FL_ONGROUND)
2160                 if (g_midair)
2161                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2162
2163                 if (time >= game_starttime)
2164                 if (time < self.spawnshieldtime)
2165                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2166         }
2167
2168         MUTATOR_CALLHOOK(PlayerPowerups);
2169 }
2170
2171 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2172 {
2173         if(current > stable)
2174                 return current;
2175         else if(current > stable - 0.25) // when close enough, "snap"
2176                 return stable;
2177         else
2178                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2179 }
2180
2181 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2182 {
2183         if(current < stable)
2184                 return current;
2185         else if(current < stable + 0.25) // when close enough, "snap"
2186                 return stable;
2187         else
2188                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2189 }
2190
2191 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2192 {
2193         if(current > rotstable)
2194         {
2195                 if(rotframetime > 0)
2196                 {
2197                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2198                         current = max(rotstable, current - rotlinear * rotframetime);
2199                 }
2200         }
2201         else if(current < regenstable)
2202         {
2203                 if(regenframetime > 0)
2204                 {
2205                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2206                         current = min(regenstable, current + regenlinear * regenframetime);
2207                 }
2208         }
2209
2210         if(current > limit)
2211                 current = limit;
2212
2213         return current;
2214 }
2215
2216 void player_regen (void)
2217 {
2218         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2219         maxh = autocvar_g_balance_health_rotstable;
2220         maxa = autocvar_g_balance_armor_rotstable;
2221         maxf = autocvar_g_balance_fuel_rotstable;
2222         minh = autocvar_g_balance_health_regenstable;
2223         mina = autocvar_g_balance_armor_regenstable;
2224         minf = autocvar_g_balance_fuel_regenstable;
2225         limith = autocvar_g_balance_health_limit;
2226         limita = autocvar_g_balance_armor_limit;
2227         limitf = autocvar_g_balance_fuel_limit;
2228
2229         max_mod = regen_mod = rot_mod = limit_mod = 1;
2230
2231         if (self.runes & RUNE_REGEN)
2232         {
2233                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2234                 {
2235                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2236                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2237                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2238                 }
2239                 else
2240                 {
2241                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2242                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2243                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2244                 }
2245         }
2246         else if (self.runes & CURSE_VENOM)
2247         {
2248                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2249                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2250                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2251                 else
2252                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2253                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2254                 //if (!self.runes & RUNE_REGEN)
2255                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2256         }
2257         maxh = maxh * max_mod;
2258         //maxa = maxa * max_mod;
2259         //maxf = maxf * max_mod;
2260         minh = minh * max_mod;
2261         //mina = mina * max_mod;
2262         //minf = minf * max_mod;
2263         limith = limith * limit_mod;
2264         limita = limita * limit_mod;
2265         //limitf = limitf * limit_mod;
2266
2267         if(g_lms && g_ca)
2268                 rot_mod = 0;
2269
2270         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2271         {
2272                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2273                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2274
2275                 // if player rotted to death...  die!
2276                 if(self.health < 1)
2277                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2278         }
2279
2280         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2281                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2282 }
2283
2284 float zoomstate_set;
2285 void SetZoomState(float z)
2286 {
2287         if(z != self.zoomstate)
2288         {
2289                 self.zoomstate = z;
2290                 ClientData_Touch(self);
2291         }
2292         zoomstate_set = 1;
2293 }
2294
2295 void GetPressedKeys(void) {
2296         MUTATOR_CALLHOOK(GetPressedKeys);
2297         if (self.movement_x > 0) // get if movement keys are pressed
2298         {       // forward key pressed
2299                 self.pressedkeys |= KEY_FORWARD;
2300                 self.pressedkeys &~= KEY_BACKWARD;
2301         }
2302         else if (self.movement_x < 0)
2303         {       // backward key pressed
2304                 self.pressedkeys |= KEY_BACKWARD;
2305                 self.pressedkeys &~= KEY_FORWARD;
2306         }
2307         else
2308         {       // no x input
2309                 self.pressedkeys &~= KEY_FORWARD;
2310                 self.pressedkeys &~= KEY_BACKWARD;
2311         }
2312
2313         if (self.movement_y > 0)
2314         {       // right key pressed
2315                 self.pressedkeys |= KEY_RIGHT;
2316                 self.pressedkeys &~= KEY_LEFT;
2317         }
2318         else if (self.movement_y < 0)
2319         {       // left key pressed
2320                 self.pressedkeys |= KEY_LEFT;
2321                 self.pressedkeys &~= KEY_RIGHT;
2322         }
2323         else
2324         {       // no y input
2325                 self.pressedkeys &~= KEY_RIGHT;
2326                 self.pressedkeys &~= KEY_LEFT;
2327         }
2328
2329         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2330                 self.pressedkeys |= KEY_JUMP;
2331         else
2332                 self.pressedkeys &~= KEY_JUMP;
2333         if (self.BUTTON_CROUCH)
2334                 self.pressedkeys |= KEY_CROUCH;
2335         else
2336                 self.pressedkeys &~= KEY_CROUCH;
2337 }
2338
2339 /*
2340 ======================
2341 spectate mode routines
2342 ======================
2343 */
2344
2345 void SpectateCopy(entity spectatee) {
2346         other = spectatee;
2347         MUTATOR_CALLHOOK(SpectateCopy);
2348         self.armortype = spectatee.armortype;
2349         self.armorvalue = spectatee.armorvalue;
2350         self.ammo_cells = spectatee.ammo_cells;
2351         self.ammo_shells = spectatee.ammo_shells;
2352         self.ammo_nails = spectatee.ammo_nails;
2353         self.ammo_rockets = spectatee.ammo_rockets;
2354         self.ammo_fuel = spectatee.ammo_fuel;
2355         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2356         self.health = spectatee.health;
2357         self.impulse = 0;
2358         self.items = spectatee.items;
2359         self.last_pickup = spectatee.last_pickup;
2360         self.metertime = spectatee.metertime;
2361         self.strength_finished = spectatee.strength_finished;
2362         self.invincible_finished = spectatee.invincible_finished;
2363         self.pressedkeys = spectatee.pressedkeys;
2364         self.weapons = spectatee.weapons;
2365         self.switchweapon = spectatee.switchweapon;
2366         self.weapon = spectatee.weapon;
2367         self.punchangle = spectatee.punchangle;
2368         self.view_ofs = spectatee.view_ofs;
2369         self.v_angle = spectatee.v_angle;
2370         self.velocity = spectatee.velocity;
2371         self.dmg_take = spectatee.dmg_take;
2372         self.dmg_save = spectatee.dmg_save;
2373         self.dmg_inflictor = spectatee.dmg_inflictor;
2374         self.angles = spectatee.v_angle;
2375         self.fixangle = TRUE;
2376         setorigin(self, spectatee.origin);
2377         setsize(self, spectatee.mins, spectatee.maxs);
2378         SetZoomState(spectatee.zoomstate);
2379
2380         anticheat_spectatecopy(spectatee);
2381 }
2382
2383 float SpectateUpdate() {
2384         if(!self.enemy)
2385                 return 0;
2386
2387         if (self == self.enemy)
2388                 return 0;
2389
2390         if(self.enemy.classname != "player")
2391                 return 0;
2392
2393         SpectateCopy(self.enemy);
2394
2395         return 1;
2396 }
2397
2398 float SpectateNext() {
2399         other = find(self.enemy, classname, "player");
2400
2401         if (!other)
2402                 other = find(other, classname, "player");
2403
2404         if (other)
2405                 self.enemy = other;
2406
2407         if(self.enemy.classname == "player") {
2408                 msg_entity = self;
2409                 WriteByte(MSG_ONE, SVC_SETVIEW);
2410                 WriteEntity(MSG_ONE, self.enemy);
2411                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2412                 self.movetype = MOVETYPE_NONE;
2413                 accuracy_resend(self);
2414
2415                 if(!SpectateUpdate())
2416                         PutObserverInServer();
2417
2418                 return 1;
2419         } else {
2420                 return 0;
2421         }
2422 }
2423
2424 /*
2425 =============
2426 ShowRespawnCountdown()
2427
2428 Update a respawn countdown display.
2429 =============
2430 */
2431 void ShowRespawnCountdown()
2432 {
2433         float number;
2434         if(self.deadflag == DEAD_NO) // just respawned?
2435                 return;
2436         else
2437         {
2438                 number = ceil(self.death_time - time);
2439                 if(number <= 0)
2440                         return;
2441                 if(number <= self.respawn_countdown)
2442                 {
2443                         self.respawn_countdown = number - 1;
2444                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2445                                 AnnounceTo(self, strcat(ftos(number), ""));
2446                 }
2447         }
2448 }
2449
2450 void LeaveSpectatorMode()
2451 {
2452         if(isJoinAllowed()) {
2453                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2454                         self.classname = "player";
2455
2456                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2457                                 JoinBestTeam(self, FALSE, TRUE);
2458
2459                         if(autocvar_g_campaign)
2460                                 campaign_bots_may_start = 1;
2461
2462                         PutClientInServer();
2463
2464                         if(self.classname == "player")
2465                                 bprint ("^4", self.netname, "^4 is playing now\n");
2466
2467                         if(!autocvar_g_campaign)
2468                                 centerprint(self,""); // clear MOTD
2469
2470                         return;
2471                 } else {
2472                         if (g_ca && self.caplayer) {
2473                         }       // do nothing
2474                         else
2475                                 stuffcmd(self,"menu_showteamselect\n");
2476                         return;
2477                 }
2478         }
2479         else {
2480                 //player may not join because of g_maxplayers is set
2481                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2482         }
2483 }
2484
2485 /**
2486  * Determines whether the player is allowed to join. This depends on cvar
2487  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2488  * it checks whether the number of currently playing players exceeds g_maxplayers.
2489  * @return bool TRUE if the player is allowed to join, false otherwise
2490  */
2491 float isJoinAllowed() {
2492         if(self.team_forced < 0)
2493                 return FALSE; // forced spectators can never join
2494
2495         if (!autocvar_g_maxplayers)
2496                 return TRUE;
2497
2498         local entity e;
2499         local float currentlyPlaying;
2500         FOR_EACH_REALPLAYER(e) {
2501                 if(e.classname == "player")
2502                         currentlyPlaying += 1;
2503         }
2504         if(currentlyPlaying < autocvar_g_maxplayers)
2505                 return TRUE;
2506
2507         return FALSE;
2508 }
2509
2510 /**
2511  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2512  * g_maxplayers_spectator_blocktime seconds
2513  */
2514 void checkSpectatorBlock() {
2515         if(self.classname == "spectator" || self.classname == "observer") {
2516                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2517                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2518                         dropclient(self);
2519                 }
2520         }
2521 }
2522
2523 void ObserverThink()
2524 {
2525         if (self.flags & FL_JUMPRELEASED) {
2526                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2527                         self.welcomemessage_time = 0;
2528                         self.flags &~= FL_JUMPRELEASED;
2529                         self.flags |= FL_SPAWNING;
2530                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2531                         self.welcomemessage_time = 0;
2532                         self.flags &~= FL_JUMPRELEASED;
2533                         if(SpectateNext() == 1) {
2534                                 self.classname = "spectator";
2535                         }
2536                 }
2537         } else {
2538                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2539                         self.flags |= FL_JUMPRELEASED;
2540                         if(self.flags & FL_SPAWNING)
2541                         {
2542                                 self.flags &~= FL_SPAWNING;
2543                                 LeaveSpectatorMode();
2544                                 return;
2545                         }
2546                 }
2547         }
2548         PrintWelcomeMessage(self);
2549 }
2550
2551 void SpectatorThink()
2552 {
2553         if (self.flags & FL_JUMPRELEASED) {
2554                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2555                         self.welcomemessage_time = 0;
2556                         self.flags &~= FL_JUMPRELEASED;
2557                         self.flags |= FL_SPAWNING;
2558                 } else if(self.BUTTON_ATCK) {
2559                         self.welcomemessage_time = 0;
2560                         self.flags &~= FL_JUMPRELEASED;
2561                         if(SpectateNext() == 1) {
2562                                 self.classname = "spectator";
2563                         } else {
2564                                 self.classname = "observer";
2565                                 PutClientInServer();
2566                         }
2567                 } else if (self.BUTTON_ATCK2) {
2568                         self.welcomemessage_time = 0;
2569                         self.flags &~= FL_JUMPRELEASED;
2570                         self.classname = "observer";
2571                         PutClientInServer();
2572                 } else {
2573                         if(!SpectateUpdate())
2574                                 PutObserverInServer();
2575                 }
2576         } else {
2577                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2578                         self.flags |= FL_JUMPRELEASED;
2579                         if(self.flags & FL_SPAWNING)
2580                         {
2581                                 self.flags &~= FL_SPAWNING;
2582                                 LeaveSpectatorMode();
2583                                 return;
2584                         }
2585                 }
2586         }
2587
2588         PrintWelcomeMessage(self);
2589         self.flags |= FL_CLIENT | FL_NOTARGET;
2590 }
2591
2592 .float touchexplode_time;
2593
2594 /*
2595 =============
2596 PlayerPreThink
2597
2598 Called every frame for each client before the physics are run
2599 =============
2600 */
2601 void() ctf_setstatus;
2602 void() nexball_setstatus;
2603 .float items_added;
2604 void PlayerPreThink (void)
2605 {
2606         self.stat_game_starttime = game_starttime;
2607         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2608         self.stat_leadlimit = autocvar_leadlimit;
2609
2610         if(frametime)
2611         {
2612                 // physics frames: update anticheat stuff
2613                 anticheat_prethink();
2614         }
2615
2616         if(blockSpectators && frametime)
2617                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2618                 checkSpectatorBlock();
2619
2620         zoomstate_set = 0;
2621
2622         if(self.netname_previous != self.netname)
2623         {
2624                 if(autocvar_sv_eventlog)
2625                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2626                 if(self.netname_previous)
2627                         strunzone(self.netname_previous);
2628                 self.netname_previous = strzone(self.netname);
2629         }
2630
2631         // version nagging
2632         if(self.version_nagtime)
2633                 if(self.cvar_g_xonoticversion)
2634                         if(time > self.version_nagtime)
2635                         {
2636                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2637                                 {
2638                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2639                                         {
2640                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2641                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2642                                         }
2643                                         else
2644                                         {
2645                                                 float r;
2646                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2647                                                 if(r < 0)
2648                                                 {
2649                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2650                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2651                                                 }
2652                                                 else if(r > 0)
2653                                                 {
2654                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2655                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2656                                                 }
2657                                         }
2658                                 }
2659                                 self.version_nagtime = 0;
2660                         }
2661
2662         // GOD MODE info
2663         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2664         {
2665                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2666                 self.max_armorvalue = 0;
2667         }
2668
2669 #ifdef TETRIS
2670         if (TetrisPreFrame())
2671                 return;
2672 #endif
2673
2674         MUTATOR_CALLHOOK(PlayerPreThink);
2675
2676         if(self.classname == "player") {
2677 //              if(self.netname == "Wazat")
2678 //                      bprint(self.classname, "\n");
2679
2680                 CheckRules_Player();
2681
2682                 PrintWelcomeMessage(self);
2683
2684                 if (intermission_running)
2685                 {
2686                         IntermissionThink ();   // otherwise a button could be missed between
2687                         return;                                 // the think tics
2688                 }
2689
2690                 if(self.teleport_time)
2691                 if(time > self.teleport_time)
2692                 {
2693                         self.teleport_time = 0;
2694                         self.effects = self.effects - (self.effects & EF_NODRAW);
2695                 }
2696
2697                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2698                         UpdateSelectedPlayer();
2699
2700                 //don't allow the player to turn around while game is paused!
2701                 if(timeoutStatus == 2) {
2702                         self.v_angle = self.lastV_angle;
2703                         self.angles = self.lastV_angle;
2704                         self.fixangle = TRUE;
2705                 }
2706
2707                 if(frametime)
2708                 {
2709                         if(self.health <= 0 && autocvar_g_deathglow)
2710                         {
2711                                 if(self.glowmod_x > 0)
2712                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2713                                 else
2714                                         self.glowmod_x = -1;
2715                                 if(self.glowmod_y > 0)
2716                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2717                                 else
2718                                         self.glowmod_y = -1;
2719                                 if(self.glowmod_z > 0)
2720                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2721                                 else
2722                                         self.glowmod_z = -1;
2723                         }
2724                         else
2725                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2726                         player_powerups();
2727                 }
2728
2729                 if (self.deadflag != DEAD_NO)
2730                 {
2731                         float button_pressed, force_respawn;
2732                         if(self.personal && g_race_qualifying)
2733                         {
2734                                 if(time > self.death_time)
2735                                 {
2736                                         self.death_time = time + 1; // only retry once a second
2737                                         respawn();
2738                                         self.impulse = 141;
2739                                 }
2740                         }
2741                         else
2742                         {
2743                                 if(frametime)
2744                                         player_anim();
2745                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2746                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2747                                 if (self.deadflag == DEAD_DYING)
2748                                 {
2749                                         if(force_respawn)
2750                                                 self.deadflag = DEAD_RESPAWNING;
2751                                         else if(!button_pressed)
2752                                                 self.deadflag = DEAD_DEAD;
2753                                 }
2754                                 else if (self.deadflag == DEAD_DEAD)
2755                                 {
2756                                         if(button_pressed)
2757                                                 self.deadflag = DEAD_RESPAWNABLE;
2758                                 }
2759                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2760                                 {
2761                                         if(!button_pressed)
2762                                                 self.deadflag = DEAD_RESPAWNING;
2763                                 }
2764                                 else if (self.deadflag == DEAD_RESPAWNING)
2765                                 {
2766                                         if(time > self.death_time)
2767                                         {
2768                                                 self.death_time = time + 1; // only retry once a second
2769                                                 respawn();
2770                                         }
2771                                 }
2772                                 ShowRespawnCountdown();
2773                         }
2774                         return;
2775                 }
2776
2777                 if(g_touchexplode)
2778                 if(time > self.touchexplode_time)
2779                 if(self.classname == "player")
2780                 if(self.deadflag == DEAD_NO)
2781                 if not(IS_INDEPENDENT_PLAYER(self))
2782                 FOR_EACH_PLAYER(other) if(self != other)
2783                 {
2784                         if(time > other.touchexplode_time)
2785                         if(other.deadflag == DEAD_NO)
2786                         if not(IS_INDEPENDENT_PLAYER(other))
2787                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2788                         {
2789                                 PlayerTouchExplode(self, other);
2790                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2791                         }
2792                 }
2793
2794                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2795                 {
2796                         vector dist;
2797
2798                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2799                         dist = self.prevorigin - self.origin;
2800                         dist_z = 0;
2801                         self.lms_traveled_distance += fabs(vlen(dist));
2802
2803                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2804                         {
2805                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2806                                 self.lms_traveled_distance = 0;
2807                         }
2808
2809                         if(time > self.lms_nextcheck)
2810                         {
2811                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2812                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2813                                 {
2814                                         centerprint(self, autocvar_g_lms_campcheck_message);
2815                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2816                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2817                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2818                                 }
2819                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2820                                 self.lms_traveled_distance = 0;
2821                         }
2822                 }
2823
2824                 self.prevorigin = self.origin;
2825
2826                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2827                 {
2828                         if (!self.crouch)
2829                         {
2830                                 self.crouch = TRUE;
2831                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2832                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2833                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2834                         }
2835                 }
2836                 else
2837                 {
2838                         if (self.crouch)
2839                         {
2840                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2841                                 if (!trace_startsolid)
2842                                 {
2843                                         self.crouch = FALSE;
2844                                         self.view_ofs = PL_VIEW_OFS;
2845                                         setsize (self, PL_MIN, PL_MAX);
2846                                 }
2847                         }
2848                 }
2849
2850                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2851                 {
2852                         if(self.bloodloss_timer < time)
2853                         {
2854                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2855                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2856                         }
2857                 }
2858
2859                 FixPlayermodel();
2860
2861                 GrapplingHookFrame();
2862
2863                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2864                 //if(frametime)
2865                 {
2866                         self.items &~= self.items_added;
2867
2868                         W_WeaponFrame();
2869
2870                         self.items_added = 0;
2871                         if(self.items & IT_JETPACK)
2872                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2873                                         self.items_added |= IT_FUEL;
2874
2875                         self.items |= self.items_added;
2876                 }
2877
2878                 player_regen();
2879
2880                 // rot nex charge to the charge limit
2881                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2882                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2883
2884                 if(frametime)
2885                         player_anim();
2886
2887                 if (g_minstagib)
2888                         minstagib_ammocheck();
2889
2890                 if(g_ctf)
2891                         ctf_setstatus();
2892
2893                 if(g_nexball)
2894                         nexball_setstatus();
2895
2896                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2897
2898                 //self.angles_y=self.v_angle_y + 90;   // temp
2899         } else if(gameover) {
2900                 if (intermission_running)
2901                         IntermissionThink ();   // otherwise a button could be missed between
2902                 return;
2903         } else if(self.classname == "observer") {
2904                 ObserverThink();
2905         } else if(self.classname == "spectator") {
2906                 SpectatorThink();
2907         }
2908
2909         if(!zoomstate_set)
2910                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2911
2912         float oldspectatee_status;
2913         oldspectatee_status = self.spectatee_status;
2914         if(self.classname == "spectator")
2915                 self.spectatee_status = num_for_edict(self.enemy);
2916         else if(self.classname == "observer")
2917                 self.spectatee_status = num_for_edict(self);
2918         else
2919                 self.spectatee_status = 0;
2920         if(self.spectatee_status != oldspectatee_status)
2921         {
2922                 ClientData_Touch(self);
2923                 if(g_race || g_cts)
2924                         race_InitSpectator();
2925         }
2926
2927         if(self.teamkill_soundtime)
2928         if(time > self.teamkill_soundtime)
2929         {
2930                 self.teamkill_soundtime = 0;
2931
2932                 entity oldpusher, oldself;
2933
2934                 oldself = self; self = self.teamkill_soundsource;
2935                 oldpusher = self.pusher; self.pusher = oldself;
2936
2937                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2938
2939                 self.pusher = oldpusher;
2940                 self = oldself;
2941         }
2942
2943         if(self.taunt_soundtime)
2944         if(time > self.taunt_soundtime)
2945         {
2946                 self.taunt_soundtime = 0;
2947                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2948         }
2949
2950         target_voicescript_next(self);
2951 }
2952
2953 float isInvisibleString(string s)
2954 {
2955         float i, n, c;
2956         s = strdecolorize(s);
2957         for((i = 0), (n = strlen(s)); i < n; ++i)
2958         {
2959                 c = str2chr(s, i);
2960                 switch(c)
2961                 {
2962                         case 0:
2963                         case 32: // space
2964                                 break;
2965                         case 192: // charmap space
2966                                 if (!autocvar_utf8_enable)
2967                                         break;
2968                                 return FALSE;
2969                         case 160: // space in unicode fonts
2970                         case 0xE000 + 192: // utf8 charmap space
2971                                 if (autocvar_utf8_enable)
2972                                         break;
2973                         default:
2974                                 return FALSE;
2975                 }
2976         }
2977         return TRUE;
2978 }
2979
2980 /*
2981 =============
2982 PlayerPostThink
2983
2984 Called every frame for each client after the physics are run
2985 =============
2986 */
2987 .float idlekick_lasttimeleft;
2988 .entity showheadshotbbox;
2989 void showheadshotbbox_think()
2990 {
2991         if(self.owner.showheadshotbbox != self)
2992         {
2993                 remove(self);
2994                 return;
2995         }
2996         self.nextthink = time;
2997         setorigin(self, self.owner.origin);
2998         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2999 }
3000 void PlayerPostThink (void)
3001 {
3002         // Savage: Check for nameless players
3003         if (isInvisibleString(self.netname)) {
3004                 self.netname = "Player";
3005                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3006         }
3007
3008         if(sv_maxidle && frametime)
3009         {
3010                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3011                 float timeleft;
3012                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3013                 if(timeleft <= 0)
3014                 {
3015                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3016                         AnnounceTo(self, "terminated");
3017                         dropclient(self);
3018                         return;
3019                 }
3020                 else if(timeleft <= 10)
3021                 {
3022                         if(timeleft != self.idlekick_lasttimeleft)
3023                         {
3024                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3025                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3026                         }
3027                 }
3028                 else
3029                 {
3030                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3031                 }
3032                 self.idlekick_lasttimeleft = timeleft;
3033         }
3034
3035 #ifdef TETRIS
3036         if(self.impulse == 100)
3037                 ImpulseCommands();
3038         if (TetrisPostFrame())
3039                 return;
3040 #endif
3041
3042         CheatFrame();
3043
3044         if(self.classname == "player") {
3045                 CheckRules_Player();
3046                 UpdateChatBubble();
3047                 UpdateTeamBubble();
3048                 if (self.impulse)
3049                         ImpulseCommands();
3050                 if (intermission_running)
3051                         return;         // intermission or finale
3052                 GetPressedKeys();
3053         } else if (self.classname == "observer") {
3054                 //do nothing
3055         } else if (self.classname == "spectator") {
3056                 //do nothing
3057         }
3058
3059         /*
3060         float i;
3061         for(i = 0; i < 1000; ++i)
3062         {
3063                 vector end;
3064                 end = self.origin + '0 0 1024' + 512 * randomvec();
3065                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3066                 if(trace_fraction < 1)
3067                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3068                 {
3069                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3070                         break;
3071                 }
3072         }
3073         */
3074
3075         Arena_Warmup();
3076
3077         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3078
3079         if(self.waypointsprite_attachedforcarrier)
3080                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3081
3082         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3083         {
3084                 if(!self.showheadshotbbox)
3085                 {
3086                         self.showheadshotbbox = spawn();
3087                         self.showheadshotbbox.classname = "headshotbbox";
3088                         self.showheadshotbbox.owner = self;
3089                         self.showheadshotbbox.think = showheadshotbbox_think;
3090                         self.showheadshotbbox.nextthink = time;
3091                         self = self.showheadshotbbox;
3092                         self.think();
3093                         self = self.owner;
3094                 }
3095         }
3096         else
3097         {
3098                 if(self.showheadshotbbox)
3099                         remove(self.showheadshotbbox);
3100         }
3101
3102         playerdemo_write();
3103
3104         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3105         {
3106                 if(!self.stored_netname)
3107                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3108                 if(self.stored_netname != self.netname)
3109                 {
3110                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3111                         strunzone(self.stored_netname);
3112                         self.stored_netname = strzone(self.netname);
3113                 }
3114         }
3115
3116         /*
3117         if(g_race)
3118                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3119         */
3120 }