qcsrc/server/cl_physics.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../warpzonelib/mathlib.qh"
   7     #include "../warpzonelib/server.qh"
   8     #include "../common/constants.qh"
   9     #include "../common/util.qh"
  10     #include "../common/animdecide.qh"
  11     #include "../common/monsters/sv_monsters.qh"
  12     #include "../common/weapons/weapons.qh"
  13     #include "t_items.qh"
  14     #include "autocvars.qh"
  15     #include "defs.qh"
  16     #include "../common/notifications.qh"
  17     #include "mutators/mutators_include.qh"
  18     #include "../common/mapinfo.qh"
  19     #include "../csqcmodellib/sv_model.qh"
  20     #include "anticheat.qh"
  21     #include "cheats.qh"
  22     #include "g_hook.qh"
  23     #include "race.qh"
  24     #include "playerdemo.qh"
  25 #endif
  26
  27 .float race_penalty;
  28 .float restart_jump;
  29
  30 .float ladder_time;
  31 .entity ladder_entity;
  32 .float gravity;
  33 .float swamp_slowdown;
  34 .int lastflags;
  35 .float lastground;
  36 .float wasFlying;
  37 .float spectatorspeed;
  38
  39 // client side physics
  40 float Physics_Valid(string thecvar)
  41 {
  42         if(!autocvar_g_physics_clientselect) { return false; }
  43
  44         string l = strcat(" ", autocvar_g_physics_clientselect_options, " ");
  45
  46         if(strstrofs(l, strcat(" ", thecvar, " "), 0) >= 0)
  47                 return true;
  48
  49         return false;
  50 }
  51
  52 float Physics_ClientOption(entity pl, string option)
  53 {
  54         if(Physics_Valid(pl.cvar_cl_physics))
  55         {
  56                 string var = sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option);
  57                 if(cvar_type(var) & 1)
  58                         return cvar(var);
  59         }
  60         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  61         {
  62                 string var = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  63                 if(cvar_type(var) & 1)
  64                         return cvar(var);
  65         }
  66         return cvar(strcat("sv_", option));
  67 }
  68
  69 /*
  70 =============
  71 PlayerJump
  72
  73 When you press the jump key
  74 returns true if handled
  75 =============
  76 */
  77 float PlayerJump (void)
  78 {
  79         if(self.frozen)
  80                 return true; // no jumping in freezetag when frozen
  81
  82         if(self.player_blocked)
  83                 return true; // no jumping while blocked
  84
  85         bool doublejump = false;
  86         float mjumpheight = self.stat_sv_jumpvelocity;
  87
  88         player_multijump = doublejump;
  89         player_jumpheight = mjumpheight;
  90         if(MUTATOR_CALLHOOK(PlayerJump))
  91                 return true;
  92
  93         doublejump = player_multijump;
  94         mjumpheight = player_jumpheight;
  95
  96         if (autocvar_sv_doublejump)
  97         {
  98                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  99                 if (trace_fraction < 1 && trace_plane_normal.z > 0.7)
 100                 {
 101                         doublejump = true;
 102
 103                         // we MUST clip velocity here!
 104                         float f;
 105                         f = self.velocity * trace_plane_normal;
 106                         if(f < 0)
 107                                 self.velocity -= f * trace_plane_normal;
 108                 }
 109         }
 110
 111         if (self.waterlevel >= WATERLEVEL_SWIMMING)
 112         {
 113                 self.velocity_z = self.stat_sv_maxspeed * 0.7;
 114                 return true;
 115         }
 116
 117         if (!doublejump)
 118                 if (!(self.flags & FL_ONGROUND))
 119                         return !(self.flags & FL_JUMPRELEASED);
 120
 121         if(self.cvar_cl_movement_track_canjump)
 122                 if (!(self.flags & FL_JUMPRELEASED))
 123                         return true;
 124
 125         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 126         // velocity bounds.  Final velocity is bound between (jumpheight *
 127         // min + jumpheight) and (jumpheight * max + jumpheight);
 128
 129         if(autocvar_sv_jumpspeedcap_min != "")
 130         {
 131                 float minjumpspeed;
 132
 133                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
 134
 135                 if (self.velocity.z < minjumpspeed)
 136                         mjumpheight += minjumpspeed - self.velocity.z;
 137         }
 138
 139         if(autocvar_sv_jumpspeedcap_max != "")
 140         {
 141                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 142                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 143
 144                 if(!(trace_fraction < 1 && trace_plane_normal.z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 145                 {
 146                         float maxjumpspeed;
 147
 148                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 149
 150                         if (self.velocity.z > maxjumpspeed)
 151                                 mjumpheight -= self.velocity.z - maxjumpspeed;
 152                 }
 153         }
 154
 155         if(!(self.lastflags & FL_ONGROUND))
 156         {
 157                 if(autocvar_speedmeter)
 158                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 159                 if(self.lastground < time - 0.3)
 160                 {
 161                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 162                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 163                 }
 164                 if(self.jumppadcount > 1)
 165                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 166                 self.jumppadcount = 0;
 167         }
 168
 169         self.velocity_z = self.velocity.z + mjumpheight;
 170         self.oldvelocity_z = self.velocity.z;
 171
 172         self.flags &= ~FL_ONGROUND;
 173         self.flags &= ~FL_JUMPRELEASED;
 174
 175         animdecide_setaction(self, ANIMACTION_JUMP, true);
 176
 177         if(autocvar_g_jump_grunt)
 178                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 179
 180         self.restart_jump = -1; // restart jump anim next time
 181         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 182         return true;
 183 }
 184 void CheckWaterJump()
 185 {
 186         vector start, end;
 187
 188 // check for a jump-out-of-water
 189         makevectors (self.angles);
 190         start = self.origin;
 191         start.z = start.z + 8;
 192         v_forward.z = 0;
 193         normalize(v_forward);
 194         end = start + v_forward*24;
 195         traceline (start, end, true, self);
 196         if (trace_fraction < 1)
 197         {       // solid at waist
 198                 start.z = start.z + self.maxs.z - 8;
 199                 end = start + v_forward*24;
 200                 self.movedir = trace_plane_normal * -50;
 201                 traceline (start, end, true, self);
 202                 if (trace_fraction == 1)
 203                 {       // open at eye level
 204                         self.flags |= FL_WATERJUMP;
 205                         self.velocity_z = 225;
 206                         self.flags &= ~FL_JUMPRELEASED;
 207                         self.teleport_time = time + 2;  // safety net
 208                         return;
 209                 }
 210         }
 211 }
 212
 213 .float jetpack_stopped;
 214 // Hack: shouldn't need to know about this
 215 .float multijump_count;
 216 void CheckPlayerJump()
 217 {
 218         float was_flying = self.items & IT_USING_JETPACK;
 219
 220         if (self.cvar_cl_jetpack_jump < 2)
 221                 self.items &= ~IT_USING_JETPACK;
 222
 223         if (self.BUTTON_JUMP || self.BUTTON_JETPACK)
 224         {
 225                 float air_jump = !PlayerJump() || self.multijump_count > 0; // PlayerJump() has important side effects
 226                 float activate = self.cvar_cl_jetpack_jump && air_jump && self.BUTTON_JUMP || self.BUTTON_JETPACK;
 227                 float has_fuel = !autocvar_g_jetpack_fuel || self.ammo_fuel || self.items & IT_UNLIMITED_WEAPON_AMMO;
 228                 if (!(self.items & IT_JETPACK)) { }
 229                 else if (self.jetpack_stopped) { }
 230                 else if (!has_fuel)
 231                 {
 232                         if (was_flying) // TODO: ran out of fuel message
 233                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 234                         else if (activate)
 235                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 236                         self.jetpack_stopped = true;
 237                         self.items &= ~IT_USING_JETPACK;
 238                 }
 239                 else if (activate && !self.frozen)
 240                         self.items |= IT_USING_JETPACK;
 241         }
 242         else
 243         {
 244                 self.jetpack_stopped = false;
 245                 self.items &= ~IT_USING_JETPACK;
 246         }
 247         if (!self.BUTTON_JUMP)
 248                 self.flags |= FL_JUMPRELEASED;
 249
 250         if (self.waterlevel == WATERLEVEL_SWIMMING)
 251                 CheckWaterJump ();
 252 }
 253
 254 float racecar_angle(float forward, float down)
 255 {
 256         float ret, angle_mult;
 257
 258         if(forward < 0)
 259         {
 260                 forward = -forward;
 261                 down = -down;
 262         }
 263
 264         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 265
 266         angle_mult = forward / (800 + forward);
 267
 268         if(ret > 180)
 269                 return ret * angle_mult + 360 * (1 - angle_mult);
 270         else
 271                 return ret * angle_mult;
 272 }
 273
 274 void RaceCarPhysics()
 275 {
 276         // using this move type for "big rigs"
 277         // the engine does not push the entity!
 278
 279         float accel, steer, f, myspeed, steerfactor;
 280         vector angles_save, rigvel;
 281
 282         angles_save = self.angles;
 283         accel = bound(-1, self.movement.x / self.stat_sv_maxspeed, 1);
 284         steer = bound(-1, self.movement.y / self.stat_sv_maxspeed, 1);
 285
 286         if(g_bugrigs_reverse_speeding)
 287         {
 288                 if(accel < 0)
 289                 {
 290                         // back accel is DIGITAL
 291                         // to prevent speedhack
 292                         if(accel < -0.5)
 293                                 accel = -1;
 294                         else
 295                                 accel = 0;
 296                 }
 297         }
 298
 299         self.angles_x = 0;
 300         self.angles_z = 0;
 301         makevectors(self.angles); // new forward direction!
 302
 303         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 304         {
 305                 float upspeed, accelfactor;
 306
 307                 myspeed = self.velocity * v_forward;
 308                 upspeed = self.velocity * v_up;
 309
 310                 // responsiveness factor for steering and acceleration
 311                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 312                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 313
 314                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 315                         steerfactor = -myspeed * g_bugrigs_steer;
 316                 else
 317                         steerfactor = -myspeed * f * g_bugrigs_steer;
 318
 319                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 320                         accelfactor = g_bugrigs_accel;
 321                 else
 322                         accelfactor = f * g_bugrigs_accel;
 323                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 324
 325                 if(accel < 0)
 326                 {
 327                         if(myspeed > 0)
 328                         {
 329                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 330                         }
 331                         else
 332                         {
 333                                 if(!g_bugrigs_reverse_speeding)
 334                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 335                         }
 336                 }
 337                 else
 338                 {
 339                         if(myspeed >= 0)
 340                         {
 341                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 342                         }
 343                         else
 344                         {
 345                                 if(g_bugrigs_reverse_stopping)
 346                                         myspeed = 0;
 347                                 else
 348                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 349                         }
 350                 }
 351                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 352                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 353
 354                 self.angles_y += steer * frametime * steerfactor; // apply steering
 355                 makevectors(self.angles); // new forward direction!
 356
 357                 myspeed += accel * accelfactor * frametime;
 358
 359                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 360         }
 361         else
 362         {
 363                 myspeed = vlen(self.velocity);
 364
 365                 // responsiveness factor for steering and acceleration
 366                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 367                 steerfactor = -myspeed * f;
 368                 self.angles_y += steer * frametime * steerfactor; // apply steering
 369
 370                 rigvel = self.velocity;
 371                 makevectors(self.angles); // new forward direction!
 372         }
 373
 374         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 375         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 376         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 377         //MAXIMA: solve(total_acceleration(v) = 0, v);
 378
 379         if(g_bugrigs_planar_movement)
 380         {
 381                 vector rigvel_xy, neworigin, up;
 382                 float mt;
 383
 384                 rigvel.z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 385                 rigvel_xy = vec2(rigvel);
 386
 387                 if(g_bugrigs_planar_movement_car_jumping)
 388                         mt = MOVE_NORMAL;
 389                 else
 390                         mt = MOVE_NOMONSTERS;
 391
 392                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 393                 up = trace_endpos - self.origin;
 394
 395                 // BUG RIGS: align the move to the surface instead of doing collision testing
 396                 // can we move?
 397                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 398
 399                 // align to surface
 400                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel.z * frametime, mt, self);
 401
 402                 if(trace_fraction < 0.5)
 403                 {
 404                         trace_fraction = 1;
 405                         neworigin = self.origin;
 406                 }
 407                 else
 408                         neworigin = trace_endpos;
 409
 410                 if(trace_fraction < 1)
 411                 {
 412                         // now set angles_x so that the car points parallel to the surface
 413                         self.angles = vectoangles(
 414                                         '1 0 0' * v_forward.x * trace_plane_normal.z
 415                                         +
 416                                         '0 1 0' * v_forward.y * trace_plane_normal.z
 417                                         +
 418                                         '0 0 1' * -(v_forward.x * trace_plane_normal.x + v_forward.y * trace_plane_normal.y)
 419                                         );
 420                         self.flags |= FL_ONGROUND;
 421                 }
 422                 else
 423                 {
 424                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 425                         self.flags &= ~FL_ONGROUND;
 426                 }
 427
 428                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 429                 self.movetype = MOVETYPE_NOCLIP;
 430         }
 431         else
 432         {
 433                 rigvel.z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 434                 self.velocity = rigvel;
 435                 self.movetype = MOVETYPE_FLY;
 436         }
 437
 438         trace_fraction = 1;
 439         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 440         if(trace_fraction != 1)
 441         {
 442                 self.angles = vectoangles2(
 443                                 '1 0 0' * v_forward.x * trace_plane_normal.z
 444                                 +
 445                                 '0 1 0' * v_forward.y * trace_plane_normal.z
 446                                 +
 447                                 '0 0 1' * -(v_forward.x * trace_plane_normal.x + v_forward.y * trace_plane_normal.y),
 448                                 trace_plane_normal
 449                                 );
 450         }
 451         else
 452         {
 453                 vector vel_local;
 454
 455                 vel_local.x = v_forward * self.velocity;
 456                 vel_local.y = v_right * self.velocity;
 457                 vel_local.z = v_up * self.velocity;
 458
 459                 self.angles_x = racecar_angle(vel_local.x, vel_local.z);
 460                 self.angles_z = racecar_angle(-vel_local.y, vel_local.z);
 461         }
 462
 463         // smooth the angles
 464         vector vf1, vu1, smoothangles;
 465         makevectors(self.angles);
 466         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 467         if(f == 0)
 468                 f = 1;
 469         vf1 = v_forward * f;
 470         vu1 = v_up * f;
 471         makevectors(angles_save);
 472         vf1 = vf1 + v_forward * (1 - f);
 473         vu1 = vu1 + v_up * (1 - f);
 474         smoothangles = vectoangles2(vf1, vu1);
 475         self.angles_x = -smoothangles.x;
 476         self.angles_z =  smoothangles.z;
 477 }
 478
 479 float IsMoveInDirection(vector mv, float angle) // key mix factor
 480 {
 481         if(mv.x == 0 && mv.y == 0)
 482                 return 0; // avoid division by zero
 483         angle -= RAD2DEG * atan2(mv.y, mv.x);
 484         angle = remainder(angle, 360) / 45;
 485         if(angle >  1)
 486                 return 0;
 487         if(angle < -1)
 488                 return 0;
 489         return 1 - fabs(angle);
 490 }
 491
 492 float GeomLerp(float a, float lerp, float b)
 493 {
 494         if(a == 0)
 495         {
 496                 if(lerp < 1)
 497                         return 0;
 498                 else
 499                         return b;
 500         }
 501         if(b == 0)
 502         {
 503                 if(lerp > 0)
 504                         return 0;
 505                 else
 506                         return a;
 507         }
 508         return a * pow(fabs(b / a), lerp);
 509 }
 510
 511 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 512 {
 513         float zspeed, xyspeed, dot, k;
 514
 515 #if 0
 516         // this doesn't play well with analog input
 517         if(self.movement_x == 0 || self.movement.y != 0)
 518                 return; // can't control movement if not moving forward or backward
 519         k = 32;
 520 #else
 521         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 522         if(k <= 0)
 523                 return;
 524 #endif
 525
 526         k *= bound(0, wishspeed / self.stat_sv_maxairspeed, 1);
 527
 528         zspeed = self.velocity.z;
 529         self.velocity_z = 0;
 530         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 531
 532         dot = self.velocity * wishdir;
 533
 534         if(dot > 0) // we can't change direction while slowing down
 535         {
 536                 k *= pow(dot, self.stat_sv_aircontrol_power)*frametime;
 537                 xyspeed = max(0, xyspeed - self.stat_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 538                 k *= self.stat_sv_aircontrol;
 539                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 540         }
 541
 542         self.velocity = self.velocity * xyspeed;
 543         self.velocity_z = zspeed;
 544 }
 545
 546 float AdjustAirAccelQW(float accelqw, float factor)
 547 {
 548         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 549 }
 550
 551 // example config for alternate speed clamping:
 552 //   sv_airaccel_qw 0.8
 553 //   sv_airaccel_sideways_friction 0
 554 //   prvm_globalset server speedclamp_mode 1
 555 //     (or 2)
 556 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 557 {
 558         float vel_straight;
 559         float velZ;
 560         vector vel_perpend;
 561         float step;
 562
 563         vector vel_xy;
 564         float vel_xy_current;
 565         float vel_xy_backward, vel_xy_forward;
 566         float speedclamp;
 567
 568         if(stretchfactor > 0)
 569                 speedclamp = stretchfactor;
 570         else if(accelqw < 0)
 571                 speedclamp = 1; // full clamping, no stretch
 572         else
 573                 speedclamp = -1; // no clamping
 574
 575         if(accelqw < 0)
 576                 accelqw = -accelqw;
 577
 578         if(autocvar_sv_gameplayfix_q2airaccelerate)
 579                 wishspeed0 = wishspeed;
 580
 581         vel_straight = self.velocity * wishdir;
 582         velZ = self.velocity.z;
 583         vel_xy = vec2(self.velocity);
 584         vel_perpend = vel_xy - vel_straight * wishdir;
 585
 586         step = accel * frametime * wishspeed0;
 587
 588         vel_xy_current  = vlen(vel_xy);
 589         if(speedlimit)
 590                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 591         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 592         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 593         if(vel_xy_backward < 0)
 594                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 595
 596         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 597
 598         if(sidefric < 0 && (vel_perpend*vel_perpend))
 599                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 600         {
 601                 float f, fminimum;
 602                 f = max(0, 1 + frametime * wishspeed * sidefric);
 603                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 604                 // this cannot be > 1
 605                 if(fminimum <= 0)
 606                         vel_perpend = vel_perpend * max(0, f);
 607                 else
 608                 {
 609                         fminimum = sqrt(fminimum);
 610                         vel_perpend = vel_perpend * max(fminimum, f);
 611                 }
 612         }
 613         else
 614                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 615
 616         vel_xy = vel_straight * wishdir + vel_perpend;
 617
 618         if(speedclamp >= 0)
 619         {
 620                 float vel_xy_preclamp;
 621                 vel_xy_preclamp = vlen(vel_xy);
 622                 if(vel_xy_preclamp > 0) // prevent division by zero
 623                 {
 624                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 625                         if(vel_xy_current < vel_xy_preclamp)
 626                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
 627                 }
 628         }
 629
 630         self.velocity = vel_xy + velZ * '0 0 1';
 631 }
 632
 633 void PM_AirAccelerate(vector wishdir, float wishspeed)
 634 {
 635         vector curvel, wishvel, acceldir, curdir;
 636         float addspeed, accelspeed, curspeed, f;
 637         float dot;
 638
 639         if(wishspeed == 0)
 640                 return;
 641
 642         curvel = self.velocity;
 643         curvel.z = 0;
 644         curspeed = vlen(curvel);
 645
 646         if(wishspeed > curspeed * 1.01)
 647         {
 648                 wishspeed = min(wishspeed, curspeed + self.stat_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 649         }
 650         else
 651         {
 652                 f = max(0, (self.stat_sv_warsowbunny_topspeed - curspeed) / (self.stat_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 653                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + self.stat_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 654         }
 655         wishvel = wishdir * wishspeed;
 656         acceldir = wishvel - curvel;
 657         addspeed = vlen(acceldir);
 658         acceldir = normalize(acceldir);
 659
 660         accelspeed = min(addspeed, self.stat_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 661
 662         if(self.stat_sv_warsowbunny_backtosideratio < 1)
 663         {
 664                 curdir = normalize(curvel);
 665                 dot = acceldir * curdir;
 666                 if(dot < 0)
 667                         acceldir = acceldir - (1 - self.stat_sv_warsowbunny_backtosideratio) * dot * curdir;
 668         }
 669
 670         self.velocity += accelspeed * acceldir;
 671 }
 672
 673 .vector movement_old;
 674 .float buttons_old;
 675 .vector v_angle_old;
 676 .string lastclassname;
 677
 678 .float() PlayerPhysplug;
 679
 680 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 681 .float specialcommand_pos;
 682 void SpecialCommand()
 683 {
 684 #ifdef TETRIS
 685         TetrisImpulse();
 686 #else
 687         if(!CheatImpulse(99))
 688                 print("A hollow voice says \"Plugh\".\n");
 689 #endif
 690 }
 691
 692 float speedaward_speed;
 693 string speedaward_holder;
 694 string speedaward_uid;
 695 void race_send_speedaward(float msg)
 696 {
 697         // send the best speed of the round
 698         WriteByte(msg, SVC_TEMPENTITY);
 699         WriteByte(msg, TE_CSQC_RACE);
 700         WriteByte(msg, RACE_NET_SPEED_AWARD);
 701         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 702         WriteString(msg, speedaward_holder);
 703 }
 704
 705 float speedaward_alltimebest;
 706 string speedaward_alltimebest_holder;
 707 string speedaward_alltimebest_uid;
 708 void race_send_speedaward_alltimebest(float msg)
 709 {
 710         // send the best speed
 711         WriteByte(msg, SVC_TEMPENTITY);
 712         WriteByte(msg, TE_CSQC_RACE);
 713         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 714         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 715         WriteString(msg, speedaward_alltimebest_holder);
 716 }
 717
 718 string GetMapname(void);
 719 float speedaward_lastupdate;
 720 float speedaward_lastsent;
 721 void SV_PlayerPhysics()
 722 {
 723         vector wishvel, wishdir, v;
 724         float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 725         string temps;
 726         int buttons_prev;
 727         float not_allowed_to_move;
 728         string c;
 729
 730         WarpZone_PlayerPhysics_FixVAngle();
 731
 732         maxspd_mod = 1;
 733         if(self.ballcarried)
 734                 if(g_keepaway)
 735                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 736
 737         maxspd_mod *= autocvar_g_movement_highspeed;
 738
 739         // fix physics stats for g_movement_highspeed
 740         // TODO maybe rather use maxairspeed? needs testing
 741         self.stat_sv_airaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airaccel_qw"), maxspd_mod);
 742         if(Physics_ClientOption(self, "airstrafeaccel_qw"))
 743                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airstrafeaccel_qw"), maxspd_mod);
 744         else
 745                 self.stat_sv_airstrafeaccel_qw = 0;
 746         self.stat_sv_airspeedlimit_nonqw = Physics_ClientOption(self, "airspeedlimit_nonqw") * maxspd_mod;
 747         self.stat_sv_maxspeed = Physics_ClientOption(self, "maxspeed") * maxspd_mod; // also slow walking
 748
 749         // fix some new settings
 750         self.stat_sv_airaccel_qw_stretchfactor = Physics_ClientOption(self, "airaccel_qw_stretchfactor");
 751         self.stat_sv_maxairstrafespeed = Physics_ClientOption(self, "maxairstrafespeed");
 752         self.stat_sv_maxairspeed = Physics_ClientOption(self, "maxairspeed");
 753         self.stat_sv_airstrafeaccelerate = Physics_ClientOption(self, "airstrafeaccelerate");
 754         self.stat_sv_warsowbunny_turnaccel = Physics_ClientOption(self, "warsowbunny_turnaccel");
 755         self.stat_sv_airaccel_sideways_friction = Physics_ClientOption(self, "airaccel_sideways_friction");
 756         self.stat_sv_aircontrol = Physics_ClientOption(self, "aircontrol");
 757         self.stat_sv_aircontrol_power = Physics_ClientOption(self, "aircontrol_power");
 758         self.stat_sv_aircontrol_penalty = Physics_ClientOption(self, "aircontrol_penalty");
 759         self.stat_sv_warsowbunny_airforwardaccel = Physics_ClientOption(self, "warsowbunny_airforwardaccel");
 760         self.stat_sv_warsowbunny_topspeed = Physics_ClientOption(self, "warsowbunny_topspeed");
 761         self.stat_sv_warsowbunny_accel = Physics_ClientOption(self, "warsowbunny_accel");
 762         self.stat_sv_warsowbunny_backtosideratio = Physics_ClientOption(self, "warsowbunny_backtosideratio");
 763         self.stat_sv_friction = Physics_ClientOption(self, "friction");
 764         self.stat_sv_accelerate = Physics_ClientOption(self, "accelerate");
 765         self.stat_sv_stopspeed = Physics_ClientOption(self, "stopspeed");
 766         self.stat_sv_airaccelerate = Physics_ClientOption(self, "airaccelerate");
 767         self.stat_sv_airstopaccelerate = Physics_ClientOption(self, "airstopaccelerate");
 768         self.stat_sv_jumpvelocity = Physics_ClientOption(self, "jumpvelocity");
 769
 770     if(self.PlayerPhysplug)
 771         if(self.PlayerPhysplug())
 772             return;
 773
 774         self.race_movetime_frac += frametime;
 775         f = floor(self.race_movetime_frac);
 776         self.race_movetime_frac -= f;
 777         self.race_movetime_count += f;
 778         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 779
 780         anticheat_physics();
 781
 782         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement.x < 0) + 256 * (self.movement.x > 0) + 512 * (self.movement.y < 0) + 1024 * (self.movement.y > 0);
 783
 784         if(!buttons)
 785                 c = "x";
 786         else if(buttons == 1)
 787                 c = "1";
 788         else if(buttons == 2)
 789                 c = " ";
 790         else if(buttons == 128)
 791                 c = "s";
 792         else if(buttons == 256)
 793                 c = "w";
 794         else if(buttons == 512)
 795                 c = "a";
 796         else if(buttons == 1024)
 797                 c = "d";
 798         else
 799                 c = "?";
 800
 801         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 802         {
 803                 self.specialcommand_pos += 1;
 804                 if(self.specialcommand_pos >= strlen(specialcommand))
 805                 {
 806                         self.specialcommand_pos = 0;
 807                         SpecialCommand();
 808                         return;
 809                 }
 810         }
 811         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 812                 self.specialcommand_pos = 0;
 813
 814         if(sv_maxidle > 0)
 815         {
 816                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 817                         self.parm_idlesince = time;
 818         }
 819         buttons_prev = self.buttons_old;
 820         self.buttons_old = buttons;
 821         self.movement_old = self.movement;
 822         self.v_angle_old = self.v_angle;
 823
 824         if(time < self.nickspamtime)
 825         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 826         {
 827                 // slight annoyance for nick change scripts
 828                 self.movement = -1 * self.movement;
 829                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 830
 831                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 832                 {
 833                         self.angles_x = random() * 360;
 834                         self.angles_y = random() * 360;
 835                         // at least I'm not forcing retardedview by also assigning to angles_z
 836                         self.fixangle = true;
 837                 }
 838         }
 839
 840         if (self.punchangle != '0 0 0')
 841         {
 842                 f = vlen(self.punchangle) - 10 * frametime;
 843                 if (f > 0)
 844                         self.punchangle = normalize(self.punchangle) * f;
 845                 else
 846                         self.punchangle = '0 0 0';
 847         }
 848
 849         if (self.punchvector != '0 0 0')
 850         {
 851                 f = vlen(self.punchvector) - 30 * frametime;
 852                 if (f > 0)
 853                         self.punchvector = normalize(self.punchvector) * f;
 854                 else
 855                         self.punchvector = '0 0 0';
 856         }
 857
 858         if (IS_BOT_CLIENT(self))
 859         {
 860                 if(playerdemo_read())
 861                         return;
 862                 bot_think();
 863         }
 864
 865         if(IS_PLAYER(self))
 866         {
 867                 if(self.race_penalty)
 868                         if(time > self.race_penalty)
 869                                 self.race_penalty = 0;
 870
 871                 not_allowed_to_move = 0;
 872                 if(self.race_penalty)
 873                         not_allowed_to_move = 1;
 874                 if(time < game_starttime)
 875                         not_allowed_to_move = 1;
 876
 877                 if(not_allowed_to_move)
 878                 {
 879                         self.velocity = '0 0 0';
 880                         self.movetype = MOVETYPE_NONE;
 881                         self.disableclientprediction = 2;
 882                 }
 883                 else if(self.disableclientprediction == 2)
 884                 {
 885                         if(self.movetype == MOVETYPE_NONE)
 886                                 self.movetype = MOVETYPE_WALK;
 887                         self.disableclientprediction = 0;
 888                 }
 889         }
 890
 891         if (self.movetype == MOVETYPE_NONE)
 892                 return;
 893
 894         // when we get here, disableclientprediction cannot be 2
 895         self.disableclientprediction = 0;
 896         if(time < self.ladder_time)
 897                 self.disableclientprediction = 1;
 898
 899         if(time < self.spider_slowness)
 900         {
 901                 self.stat_sv_maxspeed *= 0.5; // half speed while slow from spider
 902                 self.stat_sv_airspeedlimit_nonqw *= 0.5;
 903         }
 904
 905         if(self.frozen)
 906         {
 907                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 908                 {
 909                         self.movement_x = bound(-5, self.movement.x, 5);
 910                         self.movement_y = bound(-5, self.movement.y, 5);
 911                         self.movement_z = bound(-5, self.movement.z, 5);
 912                 }
 913                 else
 914                         self.movement = '0 0 0';
 915                 self.disableclientprediction = 1;
 916
 917                 vector midpoint = ((self.absmin + self.absmax) * 0.5);
 918                 if(pointcontents(midpoint) == CONTENT_WATER)
 919                 {
 920                         self.velocity = self.velocity * 0.5;
 921
 922                         if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 923                                 { self.velocity_z = 200; }
 924                 }
 925         }
 926
 927         MUTATOR_CALLHOOK(PlayerPhysics);
 928
 929         if(self.player_blocked)
 930         {
 931                 self.movement = '0 0 0';
 932                 self.disableclientprediction = 1;
 933         }
 934
 935         maxspd_mod = 1;
 936
 937         swampspd_mod = 1;
 938         if(self.in_swamp) {
 939                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 940         }
 941
 942         // conveyors: first fix velocity
 943         if(self.conveyor.state)
 944                 self.velocity -= self.conveyor.movedir;
 945
 946         if (!IS_PLAYER(self))
 947         {
 948                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 949                 if(!self.spectatorspeed)
 950                         self.spectatorspeed = maxspd_mod;
 951                 if(self.impulse && self.impulse <= 19 || (self.impulse >= 200 && self.impulse <= 209) || (self.impulse >= 220 && self.impulse <= 229))
 952                 {
 953                         if(self.lastclassname != "player")
 954                         {
 955                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209))
 956                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 957                                 else if(self.impulse == 11)
 958                                         self.spectatorspeed = maxspd_mod;
 959                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229))
 960                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 961                                 else if(self.impulse >= 1 && self.impulse <= 9)
 962                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 963                         } // otherwise just clear
 964                         self.impulse = 0;
 965                 }
 966                 maxspd_mod = self.spectatorspeed;
 967         }
 968
 969         spd = max(self.stat_sv_maxspeed, self.stat_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 970         if(self.speed != spd)
 971         {
 972                 self.speed = spd;
 973                 temps = ftos(spd);
 974                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 975                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 976                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 977                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 978         }
 979
 980         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 981         swampspd_mod = 1;
 982
 983         // if dead, behave differently
 984         if (self.deadflag)
 985                 goto end;
 986
 987         if (!self.fixangle && !g_bugrigs)
 988         {
 989                 self.angles_x = 0;
 990                 self.angles_y = self.v_angle.y;
 991                 self.angles_z = 0;
 992         }
 993
 994         if(self.flags & FL_ONGROUND)
 995         if(IS_PLAYER(self)) // no fall sounds for observers thank you very much
 996         if(self.wasFlying)
 997         {
 998                 self.wasFlying = 0;
 999
1000                 if(self.waterlevel < WATERLEVEL_SWIMMING)
1001                 if(time >= self.ladder_time)
1002                 if (!self.hook)
1003                 {
1004                         self.nextstep = time + 0.3 + random() * 0.1;
1005                         trace_dphitq3surfaceflags = 0;
1006                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
1007                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
1008                         {
1009                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
1010                                         GlobalSound(globalsound_metalfall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
1011                                 else
1012                                         GlobalSound(globalsound_fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
1013                         }
1014                 }
1015         }
1016
1017         if(IsFlying(self))
1018                 self.wasFlying = 1;
1019
1020         if(IS_PLAYER(self))
1021                 CheckPlayerJump();
1022
1023         if (self.flags & FL_WATERJUMP )
1024         {
1025                 self.velocity_x = self.movedir.x;
1026                 self.velocity_y = self.movedir.y;
1027                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
1028                 {
1029                         self.flags &= ~FL_WATERJUMP;
1030                         self.teleport_time = 0;
1031                 }
1032         }
1033         else if (g_bugrigs && IS_PLAYER(self))
1034         {
1035                 RaceCarPhysics();
1036         }
1037         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY)
1038         {
1039                 // noclipping or flying
1040                 self.flags &= ~FL_ONGROUND;
1041
1042                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1043                 makevectors(self.v_angle);
1044                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1045                 wishvel = v_forward * self.movement.x + v_right * self.movement.y + '0 0 1' * self.movement.z;
1046                 // acceleration
1047                 wishdir = normalize(wishvel);
1048                 wishspeed = vlen(wishvel);
1049                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1050                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1051                 if (time >= self.teleport_time)
1052                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1053         }
1054         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
1055         {
1056                 // swimming
1057                 self.flags &= ~FL_ONGROUND;
1058
1059                 makevectors(self.v_angle);
1060                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1061                 wishvel = v_forward * self.movement.x + v_right * self.movement.y + '0 0 1' * self.movement.z;
1062                 if (wishvel == '0 0 0')
1063                         wishvel = '0 0 -60'; // drift towards bottom
1064
1065                 wishdir = normalize(wishvel);
1066                 wishspeed = vlen(wishvel);
1067                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1068                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1069                 wishspeed = wishspeed * 0.7;
1070
1071                 // water friction
1072                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1073
1074                 // water acceleration
1075                 PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1076         }
1077         else if (time < self.ladder_time)
1078         {
1079                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1080                 self.flags &= ~FL_ONGROUND;
1081
1082                 float g;
1083                 g = autocvar_sv_gravity * frametime;
1084                 if(self.gravity)
1085                         g *= self.gravity;
1086                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1087                 {
1088                         g *= 0.5;
1089                         self.velocity_z += g;
1090                 }
1091
1092                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1093                 makevectors(self.v_angle);
1094                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1095                 wishvel = v_forward * self.movement.x + v_right * self.movement.y + '0 0 1' * self.movement.z;
1096                 self.velocity_z += g;
1097                 if (self.ladder_entity.classname == "func_water")
1098                 {
1099                         f = vlen(wishvel);
1100                         if (f > self.ladder_entity.speed)
1101                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1102
1103                         self.watertype = self.ladder_entity.skin;
1104                         f = self.ladder_entity.origin.z + self.ladder_entity.maxs.z;
1105                         if ((self.origin.z + self.view_ofs.z) < f)
1106                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1107                         else if ((self.origin.z + (self.mins.z + self.maxs.z) * 0.5) < f)
1108                                 self.waterlevel = WATERLEVEL_SWIMMING;
1109                         else if ((self.origin.z + self.mins.z + 1) < f)
1110                                 self.waterlevel = WATERLEVEL_WETFEET;
1111                         else
1112                         {
1113                                 self.waterlevel = WATERLEVEL_NONE;
1114                                 self.watertype = CONTENT_EMPTY;
1115                         }
1116                 }
1117                 // acceleration
1118                 wishdir = normalize(wishvel);
1119                 wishspeed = vlen(wishvel);
1120                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1121                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1122                 if (time >= self.teleport_time)
1123                 {
1124                         // water acceleration
1125                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1126                 }
1127         }
1128         else if (self.items & IT_USING_JETPACK)
1129         {
1130                 //makevectors(self.v_angle_y * '0 1 0');
1131                 makevectors(self.v_angle);
1132                 wishvel = v_forward * self.movement.x + v_right * self.movement.y;
1133                 // add remaining speed as Z component
1134                 maxairspd = self.stat_sv_maxairspeed*max(1, maxspd_mod);
1135                 // fix speedhacks :P
1136                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1137                 // add the unused velocity as up component
1138                 wishvel.z = 0;
1139
1140                 // if(self.BUTTON_JUMP)
1141                         wishvel.z = sqrt(max(0, 1 - wishvel * wishvel));
1142
1143                 // it is now normalized, so...
1144                 float a_side, a_up, a_add, a_diff;
1145                 a_side = autocvar_g_jetpack_acceleration_side;
1146                 a_up = autocvar_g_jetpack_acceleration_up;
1147                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1148
1149                 wishvel.x *= a_side;
1150                 wishvel.y *= a_side;
1151                 wishvel.z *= a_up;
1152                 wishvel.z += a_add;
1153
1154                 float best;
1155                 best = 0;
1156                 //////////////////////////////////////////////////////////////////////////////////////
1157                 // finding the maximum over all vectors of above form
1158                 // with wishvel having an absolute value of 1
1159                 //////////////////////////////////////////////////////////////////////////////////////
1160                 // we're finding the maximum over
1161                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1162                 // for z in the range from -1 to 1
1163                 //////////////////////////////////////////////////////////////////////////////////////
1164                 // maximum is EITHER attained at the single extreme point:
1165                 a_diff = a_side * a_side - a_up * a_up;
1166                 if(a_diff != 0)
1167                 {
1168                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1169                         if(f > -1 && f < 1) // can it be attained?
1170                         {
1171                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1172                                 //print("middle\n");
1173                         }
1174                 }
1175                 // OR attained at z = 1:
1176                 f = (a_up + a_add) * (a_up + a_add);
1177                 if(f > best)
1178                 {
1179                         best = f;
1180                         //print("top\n");
1181                 }
1182                 // OR attained at z = -1:
1183                 f = (a_up - a_add) * (a_up - a_add);
1184                 if(f > best)
1185                 {
1186                         best = f;
1187                         //print("bottom\n");
1188                 }
1189                 best = sqrt(best);
1190                 //////////////////////////////////////////////////////////////////////////////////////
1191
1192                 //print("best possible acceleration: ", ftos(best), "\n");
1193
1194                 float fxy, fz;
1195                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel.x * '1 0 0' + wishvel.y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1196                 if(wishvel.z - autocvar_sv_gravity > 0)
1197                         fz = bound(0, 1 - self.velocity.z / autocvar_g_jetpack_maxspeed_up, 1);
1198                 else
1199                         fz = bound(0, 1 + self.velocity.z / autocvar_g_jetpack_maxspeed_up, 1);
1200
1201                 wishvel.x *= fxy;
1202                 wishvel.y *= fxy;
1203                 wishvel.z = (wishvel.z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1204
1205                 float fvel;
1206                 fvel = min(1, vlen(wishvel) / best);
1207                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1208                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1209                 else
1210                         f = 1;
1211
1212                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1213
1214                 if (f > 0 && wishvel != '0 0 0')
1215                 {
1216                         self.velocity = self.velocity + wishvel * f * frametime;
1217                         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1218                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1219                         self.flags &= ~FL_ONGROUND;
1220                         self.items |= IT_USING_JETPACK;
1221
1222                         // jetpack also inhibits health regeneration, but only for 1 second
1223                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1224                 }
1225         }
1226         else if (self.flags & FL_ONGROUND)
1227         {
1228                 // we get here if we ran out of ammo
1229                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1230                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
1231
1232                 // walking
1233                 makevectors(self.v_angle.y * '0 1 0');
1234                 wishvel = v_forward * self.movement.x + v_right * self.movement.y;
1235
1236                 if(!(self.lastflags & FL_ONGROUND))
1237                 {
1238                         if(autocvar_speedmeter)
1239                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1240                         if(self.lastground < time - 0.3)
1241                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1242                         if(self.jumppadcount > 1)
1243                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1244                         self.jumppadcount = 0;
1245                 }
1246
1247                 v = self.velocity;
1248                 v.z = 0;
1249                 f = vlen(v);
1250                 if(f > 0)
1251                 {
1252                         if (f < self.stat_sv_stopspeed)
1253                                 f = 1 - frametime * (self.stat_sv_stopspeed / f) * self.stat_sv_friction;
1254                         else
1255                                 f = 1 - frametime * self.stat_sv_friction;
1256                         if (f > 0)
1257                                 self.velocity = self.velocity * f;
1258                         else
1259                                 self.velocity = '0 0 0';
1260                         /*
1261                            Mathematical analysis time!
1262
1263                            Our goal is to invert this mess.
1264
1265                            For the two cases we get:
1266                                 v = v0 * (1 - frametime * (autocvar_sv_stopspeed / v0) * autocvar_sv_friction)
1267                                   = v0 - frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1268                                 v0 = v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1269                            and
1270                                 v = v0 * (1 - frametime * autocvar_sv_friction)
1271                                 v0 = v / (1 - frametime * autocvar_sv_friction)
1272
1273                            These cases would be chosen ONLY if:
1274                                 v0 < autocvar_sv_stopspeed
1275                                 v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction < autocvar_sv_stopspeed
1276                                 v < autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1277                            and, respectively:
1278                                 v0 >= autocvar_sv_stopspeed
1279                                 v / (1 - frametime * autocvar_sv_friction) >= autocvar_sv_stopspeed
1280                                 v >= autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1281                          */
1282                 }
1283
1284                 // acceleration
1285                 wishdir = normalize(wishvel);
1286                 wishspeed = vlen(wishvel);
1287                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1288                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1289                 if (self.crouch)
1290                         wishspeed = wishspeed * 0.5;
1291                 if (time >= self.teleport_time)
1292                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1293         }
1294         else
1295         {
1296                 float wishspeed0;
1297                 // we get here if we ran out of ammo
1298                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1299                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
1300
1301                 if(maxspd_mod < 1)
1302                 {
1303                         maxairspd = self.stat_sv_maxairspeed*maxspd_mod;
1304                         airaccel = self.stat_sv_airaccelerate*maxspd_mod;
1305                 }
1306                 else
1307                 {
1308                         maxairspd = self.stat_sv_maxairspeed;
1309                         airaccel = self.stat_sv_airaccelerate;
1310                 }
1311                 // airborn
1312                 makevectors(self.v_angle.y * '0 1 0');
1313                 wishvel = v_forward * self.movement.x + v_right * self.movement.y;
1314                 // acceleration
1315                 wishdir = normalize(wishvel);
1316                 wishspeed = wishspeed0 = vlen(wishvel);
1317                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1318                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1319                 if (wishspeed > maxairspd)
1320                         wishspeed = maxairspd;
1321                 if (self.crouch)
1322                         wishspeed = wishspeed * 0.5;
1323                 if (time >= self.teleport_time)
1324                 {
1325                         float accelerating;
1326                         float wishspeed2;
1327                         float airaccelqw;
1328                         float strafity;
1329
1330                         airaccelqw = self.stat_sv_airaccel_qw;
1331                         accelerating = (self.velocity * wishdir > 0);
1332                         wishspeed2 = wishspeed;
1333
1334                         // CPM
1335                         if(self.stat_sv_airstopaccelerate)
1336                         {
1337                                 vector curdir;
1338                                 curdir = self.velocity;
1339                                 curdir.z = 0;
1340                                 curdir = normalize(curdir);
1341                                 airaccel = airaccel + (self.stat_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1342                         }
1343                         // note that for straight forward jumping:
1344                         // step = accel * frametime * wishspeed0;
1345                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1346                         // -->
1347                         // dv/dt = accel * maxspeed (when slow)
1348                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1349                         // log dv/dt = logaccel + logmaxspeed (when slow)
1350                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1351                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1352                         if(self.stat_sv_maxairstrafespeed)
1353                                 wishspeed = min(wishspeed, GeomLerp(self.stat_sv_maxairspeed*maxspd_mod, strafity, self.stat_sv_maxairstrafespeed*maxspd_mod));
1354                         if(self.stat_sv_airstrafeaccelerate)
1355                                 airaccel = GeomLerp(airaccel, strafity, self.stat_sv_airstrafeaccelerate*maxspd_mod);
1356                         if(self.stat_sv_airstrafeaccel_qw)
1357                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1358                         // !CPM
1359
1360                         if(self.stat_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement.x != 0)
1361                                 PM_AirAccelerate(wishdir, wishspeed);
1362                         else
1363                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, self.stat_sv_airaccel_qw_stretchfactor, self.stat_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1364
1365                         if(self.stat_sv_aircontrol)
1366                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1367                 }
1368         }
1369
1370         if((g_cts || g_race) && !IS_OBSERVER(self))
1371         {
1372                 if(vlen(self.velocity - self.velocity.z * '0 0 1') > speedaward_speed)
1373                 {
1374                         speedaward_speed = vlen(self.velocity - self.velocity.z * '0 0 1');
1375                         speedaward_holder = self.netname;
1376                         speedaward_uid = self.crypto_idfp;
1377                         speedaward_lastupdate = time;
1378                 }
1379                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
1380                 {
1381                         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
1382                         race_send_speedaward(MSG_ALL);
1383                         speedaward_lastsent = speedaward_speed;
1384                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
1385                         {
1386                                 speedaward_alltimebest = speedaward_speed;
1387                                 speedaward_alltimebest_holder = speedaward_holder;
1388                                 speedaward_alltimebest_uid = speedaward_uid;
1389                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1390                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1391                                 race_send_speedaward_alltimebest(MSG_ALL);
1392                         }
1393                 }
1394         }
1395
1396         // WEAPONTODO
1397         float xyspeed;
1398         xyspeed = vlen('1 0 0' * self.velocity.x + '0 1 0' * self.velocity.y);
1399         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && xyspeed > WEP_CVAR(vortex, charge_minspeed))
1400         {
1401                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1402                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
1403                 f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
1404                 // add the extra charge
1405                 self.vortex_charge = min(1, self.vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * frametime);
1406         }
1407 :end
1408         if(self.flags & FL_ONGROUND)
1409                 self.lastground = time;
1410
1411         // conveyors: then break velocity again
1412         if(self.conveyor.state)
1413                 self.velocity += self.conveyor.movedir;
1414
1415         self.lastflags = self.flags;
1416         self.lastclassname = self.classname;
1417 }