qcsrc/server/cl_player.qc

   1 #include "cl_player.qh"
   2
   3 #include "bot/bot.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27
  28 #include "weapons/weaponstats.qh"
  29
  30 #include "../common/animdecide.qh"
  31
  32 void Drop_Special_Items(entity player)
  33 {
  34         // called when the player has become stuck or frozen
  35         // so objective items aren't stuck with the player
  36
  37         MUTATOR_CALLHOOK(DropSpecialItems, player);
  38 }
  39
  40 void CopyBody_Think()
  41 {SELFPARAM();
  42         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  43         {
  44                 self.CopyBody_think();
  45                 if(wasfreed(self))
  46                         return;
  47                 self.CopyBody_nextthink = self.nextthink;
  48                 self.CopyBody_think = self.think;
  49                 self.think = CopyBody_Think;
  50         }
  51         CSQCMODEL_AUTOUPDATE(self);
  52         self.nextthink = time;
  53 }
  54 void CopyBody(entity this, float keepvelocity)
  55 {
  56         if (this.effects & EF_NODRAW)
  57                 return;
  58         entity clone = new(body);
  59         clone.enemy = this;
  60         clone.lip = this.lip;
  61         clone.colormap = this.colormap;
  62         clone.iscreature = this.iscreature;
  63         clone.teleportable = this.teleportable;
  64         clone.damagedbycontents = this.damagedbycontents;
  65         clone.angles = this.angles;
  66         clone.v_angle = this.v_angle;
  67         clone.avelocity = this.avelocity;
  68         clone.damageforcescale = this.damageforcescale;
  69         clone.effects = this.effects;
  70         clone.glowmod = this.glowmod;
  71         clone.event_damage = this.event_damage;
  72         clone.anim_state = this.anim_state;
  73         clone.anim_time = this.anim_time;
  74         clone.anim_lower_action = this.anim_lower_action;
  75         clone.anim_lower_time = this.anim_lower_time;
  76         clone.anim_upper_action = this.anim_upper_action;
  77         clone.anim_upper_time = this.anim_upper_time;
  78         clone.anim_implicit_state = this.anim_implicit_state;
  79         clone.anim_implicit_time = this.anim_implicit_time;
  80         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  81         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  82         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  83         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  84         clone.dphitcontentsmask = this.dphitcontentsmask;
  85         clone.death_time = this.death_time;
  86         clone.pain_finished = this.pain_finished;
  87         clone.health = this.health;
  88         clone.armorvalue = this.armorvalue;
  89         clone.armortype = this.armortype;
  90         clone.model = this.model;
  91         clone.modelindex = this.modelindex;
  92         clone.skin = this.skin;
  93         clone.species = this.species;
  94         clone.movetype = this.movetype;
  95         clone.solid = this.solid;
  96         clone.ballistics_density = this.ballistics_density;
  97         clone.takedamage = this.takedamage;
  98         clone.customizeentityforclient = this.customizeentityforclient;
  99         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 100         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 101         if (keepvelocity == 1)
 102                 clone.velocity = this.velocity;
 103         clone.oldvelocity = clone.velocity;
 104         clone.alpha = this.alpha;
 105         clone.fade_time = this.fade_time;
 106         clone.fade_rate = this.fade_rate;
 107         //clone.weapon = this.weapon;
 108         setorigin(clone, this.origin);
 109         setsize(clone, this.mins, this.maxs);
 110         clone.prevorigin = this.origin;
 111         clone.reset = SUB_Remove;
 112         clone._ps = this._ps;
 113
 114         Drag_MoveDrag(this, clone);
 115
 116         if(clone.colormap <= maxclients && clone.colormap > 0)
 117                 clone.colormap = 1024 + this.clientcolors;
 118
 119         CSQCMODEL_AUTOINIT(clone);
 120         clone.CopyBody_nextthink = this.nextthink;
 121         clone.CopyBody_think = this.think;
 122         clone.nextthink = time;
 123         clone.think = CopyBody_Think;
 124         // "bake" the current animation frame for clones (they don't get clientside animation)
 125         animdecide_load_if_needed(clone);
 126         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 127 }
 128
 129 void player_setupanimsformodel()
 130 {SELFPARAM();
 131         // load animation info
 132         animdecide_load_if_needed(self);
 133         animdecide_setstate(self, 0, false);
 134 }
 135
 136 void player_anim ()
 137 {SELFPARAM();
 138         int deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 139         if(IS_DEAD(self)) {
 140                 if (!deadbits) {
 141                         // Decide on which death animation to use.
 142                         if(random() < 0.5)
 143                                 deadbits = ANIMSTATE_DEAD1;
 144                         else
 145                                 deadbits = ANIMSTATE_DEAD2;
 146                 }
 147         } else {
 148                 // Clear a previous death animation.
 149                 deadbits = 0;
 150         }
 151         int animbits = deadbits;
 152         if(STAT(FROZEN, self))
 153                 animbits |= ANIMSTATE_FROZEN;
 154         if(self.movetype == MOVETYPE_FOLLOW)
 155                 animbits |= ANIMSTATE_FOLLOW;
 156         if(self.crouch)
 157                 animbits |= ANIMSTATE_DUCK;
 158         animdecide_setstate(self, animbits, false);
 159         animdecide_setimplicitstate(self, IS_ONGROUND(self));
 160 }
 161
 162 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 163 {
 164         float take, save;
 165         vector v;
 166         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 167
 168         // damage resistance (ignore most of the damage from a bullet or similar)
 169         damage = max(damage - 5, 1);
 170
 171         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 172         take = v.x;
 173         save = v.y;
 174
 175         if(sound_allowed(MSG_BROADCAST, attacker))
 176         {
 177                 if (save > 10)
 178                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 179                 else if (take > 30)
 180                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 181                 else if (take > 10)
 182                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 183         }
 184
 185         if (take > 50)
 186                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 187         if (take > 100)
 188                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 189
 190         this.armorvalue = this.armorvalue - save;
 191         this.health = this.health - take;
 192         // pause regeneration for 5 seconds
 193         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 194
 195         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 196         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 197         this.dmg_inflictor = inflictor;
 198
 199         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 200         {
 201                 // don't use any animations as a gib
 202                 this.frame = 0;
 203                 // view just above the floor
 204                 this.view_ofs = '0 0 4';
 205
 206                 Violence_GibSplash(this, 1, 1, attacker);
 207                 this.alpha = -1;
 208                 this.solid = SOLID_NOT; // restore later
 209                 this.takedamage = DAMAGE_NO; // restore later
 210                 this.damagedbycontents = false;
 211         }
 212 }
 213
 214 void calculate_player_respawn_time(entity this)
 215 {
 216         if(g_ca)
 217                 return;
 218
 219         float gametype_setting_tmp;
 220         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 221         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 222         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 223         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 224         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 225         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 226
 227         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 228         if (teamplay)
 229         {
 230                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 231                         if(it.team == this.team)
 232                                 ++pcount;
 233                 ));
 234                 if (sdelay_small_count == 0)
 235                         sdelay_small_count = 1;
 236                 if (sdelay_large_count == 0)
 237                         sdelay_large_count = 1;
 238         }
 239         else
 240         {
 241                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 242                         ++pcount;
 243                 ));
 244                 if (sdelay_small_count == 0)
 245                 {
 246                         if (g_cts)
 247                         {
 248                                 // Players play independently. No point in requiring enemies.
 249                                 sdelay_small_count = 1;
 250                         }
 251                         else
 252                         {
 253                                 // Players play AGAINST each other. Enemies required.
 254                                 sdelay_small_count = 2;
 255                         }
 256                 }
 257                 if (sdelay_large_count == 0)
 258                 {
 259                         if (g_cts)
 260                         {
 261                                 // Players play independently. No point in requiring enemies.
 262                                 sdelay_large_count = 1;
 263                         }
 264                         else
 265                         {
 266                                 // Players play AGAINST each other. Enemies required.
 267                                 sdelay_large_count = 2;
 268                         }
 269                 }
 270         }
 271
 272         float sdelay;
 273
 274         if (pcount <= sdelay_small_count)
 275                 sdelay = sdelay_small;
 276         else if (pcount >= sdelay_large_count)
 277                 sdelay = sdelay_large;
 278         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 279                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 280
 281         if(waves)
 282                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 283         else
 284                 this.respawn_time = time + sdelay;
 285
 286         if(sdelay < sdelay_max)
 287                 this.respawn_time_max = time + sdelay_max;
 288         else
 289                 this.respawn_time_max = this.respawn_time;
 290
 291         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 292                 this.respawn_countdown = 10; // first number to count down from is 10
 293         else
 294                 this.respawn_countdown = -1; // do not count down
 295
 296         if(autocvar_g_forced_respawn)
 297                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 298 }
 299
 300 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 301 {
 302         float take, save, dh, da;
 303         vector v;
 304         float valid_damage_for_weaponstats;
 305         float excess;
 306
 307         dh = max(this.health, 0);
 308         da = max(this.armorvalue, 0);
 309
 310         if(!DEATH_ISSPECIAL(deathtype))
 311         {
 312                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
 313                 if(this != attacker)
 314                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 315         }
 316
 317         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 318         {
 319                 // tuba causes blood to come out of the ears
 320                 vector ear1, ear2;
 321                 vector d;
 322                 float f;
 323                 ear1 = this.origin;
 324                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 325                 ear2 = ear1;
 326                 makevectors(this.angles);
 327                 ear1 += v_right * -10;
 328                 ear2 += v_right * +10;
 329                 d = inflictor.origin - this.origin;
 330                 if (d)
 331                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 332                 else
 333                         f = 0;  // Assum ecenter.
 334                 force = v_right * vlen(force);
 335                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 336                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 337                 if(f > 0)
 338                 {
 339                         hitloc = ear1;
 340                         force = force * -1;
 341                 }
 342                 else
 343                 {
 344                         hitloc = ear2;
 345                         // force is already good
 346                 }
 347         }
 348         else
 349                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 350
 351
 352         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 353         take = v.x;
 354         save = v.y;
 355
 356         if(attacker == this)
 357         {
 358                 // don't reset pushltime for this damage as it may be an attempt to
 359                 // escape a lava pit or similar
 360                 //this.pushltime = 0;
 361                 this.istypefrag = 0;
 362         }
 363         else if(IS_PLAYER(attacker))
 364         {
 365                 this.pusher = attacker;
 366                 this.pushltime = time + autocvar_g_maxpushtime;
 367                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 368         }
 369         else if(time < this.pushltime)
 370         {
 371                 attacker = this.pusher;
 372                 this.pushltime = max(this.pushltime, time + 0.6);
 373         }
 374         else
 375         {
 376                 this.pushltime = 0;
 377                 this.istypefrag = 0;
 378         }
 379
 380         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 381         {
 382                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
 383                 take = v.x;
 384                 save = v.y;
 385         }
 386
 387         frag_damage = damage;
 388         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save);
 389         take = bound(0, damage_take, this.health);
 390         save = bound(0, damage_save, this.armorvalue);
 391         excess = max(0, damage - take - save);
 392
 393         if(sound_allowed(MSG_BROADCAST, attacker))
 394         {
 395                 if (save > 10)
 396                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 397                 else if (take > 30)
 398                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 399                 else if (take > 10)
 400                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 401         }
 402
 403         if (take > 50)
 404                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 405         if (take > 100)
 406                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 407
 408         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 409         {
 410                 if (!(this.flags & FL_GODMODE))
 411                 {
 412                         this.armorvalue = this.armorvalue - save;
 413                         this.health = this.health - take;
 414                         // pause regeneration for 5 seconds
 415                         if(take)
 416                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 417
 418                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 419                         {
 420                                 this.pain_finished = time + 0.5;        //Supajoe
 421
 422                                 if(autocvar_sv_gentle < 1) {
 423                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 424                                         {
 425                                                 if (!this.animstate_override)
 426                                                 {
 427                                                         if (random() > 0.5)
 428                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 429                                                         else
 430                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 431                                                 }
 432                                         }
 433
 434                                         if(sound_allowed(MSG_BROADCAST, attacker))
 435                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
 436                                         if(this.health > 1)
 437                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 438                                         {
 439                                                 if(deathtype == DEATH_FALL.m_id)
 440                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 441                                                 else if(this.health > 75)
 442                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 443                                                 else if(this.health > 50)
 444                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 445                                                 else if(this.health > 25)
 446                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 447                                                 else
 448                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 449                                         }
 450                                 }
 451                         }
 452
 453                         // throw off bot aim temporarily
 454                         float shake;
 455                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 456                         {
 457                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 458                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 459                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 460                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 461                         }
 462                 }
 463                 else
 464                         this.max_armorvalue += (save + take);
 465         }
 466         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 467         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 468         this.dmg_inflictor = inflictor;
 469
 470         if (this != attacker) {
 471                 float realdmg = damage - excess;
 472                 if (IS_PLAYER(attacker)) {
 473                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 474                 }
 475                 if (IS_PLAYER(this)) {
 476                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 477                 }
 478         }
 479
 480         bool abot = (IS_BOT_CLIENT(attacker));
 481         bool vbot = (IS_BOT_CLIENT(this));
 482
 483         valid_damage_for_weaponstats = 0;
 484         Weapon awep = WEP_Null;
 485
 486         if(vbot || IS_REAL_CLIENT(this))
 487         if(abot || IS_REAL_CLIENT(attacker))
 488         if(attacker && this != attacker)
 489         if(DIFF_TEAM(this, attacker))
 490         {
 491                 if(DEATH_ISSPECIAL(deathtype))
 492                         awep = PS(attacker).m_weapon;
 493                 else
 494                         awep = DEATH_WEAPONOF(deathtype);
 495                 valid_damage_for_weaponstats = 1;
 496         }
 497
 498         if(valid_damage_for_weaponstats)
 499         {
 500                 dh = dh - max(this.health, 0);
 501                 da = da - max(this.armorvalue, 0);
 502                 WeaponStats_LogDamage(awep.m_id, abot, PS(this).m_weapon.m_id, vbot, dh + da);
 503                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype);
 504         }
 505
 506         if (this.health < 1)
 507         {
 508                 float defer_ClientKill_Now_TeamChange;
 509                 defer_ClientKill_Now_TeamChange = false;
 510
 511                 if(this.alivetime)
 512                 {
 513                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 514                         this.alivetime = 0;
 515                 }
 516
 517                 if(valid_damage_for_weaponstats)
 518                         WeaponStats_LogKill(awep.m_id, abot, PS(this).m_weapon.m_id, vbot);
 519
 520                 if(autocvar_sv_gentle < 1)
 521                 if(sound_allowed(MSG_BROADCAST, attacker))
 522                 {
 523                         if(deathtype == DEATH_DROWN.m_id)
 524                                 PlayerSound(this, playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 525                         else
 526                                 PlayerSound(this, playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 527                 }
 528
 529                 // get rid of kill indicator
 530                 if(this.killindicator)
 531                 {
 532                         remove(this.killindicator);
 533                         this.killindicator = world;
 534                         if(this.killindicator_teamchange)
 535                                 defer_ClientKill_Now_TeamChange = true;
 536
 537                         if(this.classname == "body")
 538                         if(deathtype == DEATH_KILL.m_id)
 539                         {
 540                                 // for the lemmings fans, a small harmless explosion
 541                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 542                         }
 543                 }
 544
 545                 // print an obituary message
 546                 if(this.classname != "body")
 547                         Obituary (attacker, inflictor, this, deathtype);
 548
 549         // increment frag counter for used weapon type
 550         Weapon w = DEATH_WEAPONOF(deathtype);
 551         if(w != WEP_Null)
 552         if(accuracy_isgooddamage(attacker, this))
 553         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 554
 555                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype);
 556                 excess = frag_damage;
 557
 558                 Weapon wep = PS(this).m_weapon;
 559                 WITH(entity, self, this, wep.wr_playerdeath(wep));
 560
 561                 RemoveGrapplingHook(this);
 562
 563                 Portal_ClearAllLater(this);
 564
 565                 this.fixangle = true;
 566
 567                 if(defer_ClientKill_Now_TeamChange)
 568                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 569
 570                 // player could have been miraculously resuscitated ;)
 571                 // e.g. players in freezetag get frozen, they don't really die
 572                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 573                         return;
 574
 575                 // when we get here, player actually dies
 576
 577                 Unfreeze(this); // remove any icy remains
 578                 this.health = 0; // Unfreeze resets health, so we need to set it back
 579
 580                 // clear waypoints
 581                 WaypointSprite_PlayerDead(this);
 582                 // throw a weapon
 583                 SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, PS(this).m_switchweapon.m_id);
 584
 585                 // become fully visible
 586                 this.alpha = default_player_alpha;
 587                 // make the corpse upright (not tilted)
 588                 this.angles_x = 0;
 589                 this.angles_z = 0;
 590                 // don't spin
 591                 this.avelocity = '0 0 0';
 592                 // view from the floor
 593                 this.view_ofs = '0 0 -8';
 594                 // toss the corpse
 595                 this.movetype = MOVETYPE_TOSS;
 596                 // shootable corpse
 597                 this.solid = SOLID_CORPSE;
 598                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 599                 // don't stick to the floor
 600                 UNSET_ONGROUND(this);
 601                 // dying animation
 602                 this.deadflag = DEAD_DYING;
 603
 604                 // when to allow respawn
 605                 calculate_player_respawn_time(this);
 606
 607                 this.death_time = time;
 608                 if (random() < 0.5)
 609                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 610                 else
 611                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 612                 if (this.maxs.z > 5)
 613                 {
 614                         this.maxs_z = 5;
 615                         setsize(this, this.mins, this.maxs);
 616                 }
 617                 // set damage function to corpse damage
 618                 this.event_damage = PlayerCorpseDamage;
 619                 // call the corpse damage function just in case it wants to gib
 620                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 621
 622                 // set up to fade out later
 623                 SUB_SetFade (this, time + 6 + random (), 1);
 624                 // reset body think wrapper broken by SUB_SetFade
 625                 if(this.classname == "body" && this.think != CopyBody_Think) {
 626                         this.CopyBody_think = this.think;
 627                         this.CopyBody_nextthink = this.nextthink;
 628                         this.think = CopyBody_Think;
 629                         this.nextthink = time;
 630                 }
 631
 632                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 633                         // remove corpse
 634                         // clones don't run any animation code any more, so we must gib them when they die :(
 635                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 636                 }
 637
 638                 // reset fields the weapons may use just in case
 639                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 640                         WITH(entity, self, this, it.wr_resetplayer(it));
 641                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 642                         {
 643                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 644                         }
 645                 ));
 646         }
 647 }
 648
 649 void MoveToTeam(entity client, int team_colour, int type)
 650 {
 651         int lockteams_backup = lockteams;  // backup any team lock
 652         lockteams = 0;  // disable locked teams
 653         TeamchangeFrags(client);  // move the players frags
 654         SetPlayerColors(client, team_colour - 1);  // set the players colour
 655         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 656         lockteams = lockteams_backup;  // restore the team lock
 657         LogTeamchange(client.playerid, client.team, type);
 658 }
 659
 660 /**
 661  * message "": do not say, just test flood control
 662  * return value:
 663  *   1 = accept
 664  *   0 = reject
 665  *  -1 = fake accept
 666  */
 667 int Say(entity source, float teamsay, entity privatesay, string msgin, bool floodcontrol)
 668 {
 669         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 670         float flood;
 671         var .float flood_field;
 672         float ret;
 673         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 674
 675         if(!teamsay && !privatesay)
 676                 if(substring(msgin, 0, 1) == " ")
 677                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 678
 679         msgin = formatmessage(msgin);
 680
 681         if (!IS_PLAYER(source))
 682                 colorstr = "^0"; // black for spectators
 683         else if(teamplay)
 684                 colorstr = Team_ColorCode(source.team);
 685         else
 686         {
 687                 colorstr = "";
 688                 teamsay = false;
 689         }
 690
 691         if(intermission_running)
 692                 teamsay = false;
 693
 694         if(msgin != "")
 695                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 696
 697         /*
 698          * using bprint solves this... me stupid
 699         // how can we prevent the message from appearing in a listen server?
 700         // for now, just give "say" back and only handle say_team
 701         if(!teamsay)
 702         {
 703                 clientcommand(self, strcat("say ", msgin));
 704                 return;
 705         }
 706         */
 707
 708         if(autocvar_g_chat_teamcolors)
 709                 namestr = playername(source);
 710         else
 711                 namestr = source.netname;
 712
 713         if(strdecolorize(namestr) == namestr)
 714                 colorprefix = "^3";
 715         else
 716                 colorprefix = "^7";
 717
 718         if(msgin != "")
 719         {
 720                 if(privatesay)
 721                 {
 722                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 723                         privatemsgprefixlen = strlen(msgstr);
 724                         msgstr = strcat(msgstr, msgin);
 725                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 726                         if(autocvar_g_chat_teamcolors)
 727                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 728                         else
 729                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 730                 }
 731                 else if(teamsay)
 732                 {
 733                         if(strstrofs(msgin, "/me", 0) >= 0)
 734                         {
 735                                 //msgin = strreplace("/me", "", msgin);
 736                                 //msgin = substring(msgin, 3, strlen(msgin));
 737                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 738                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 739                         }
 740                         else
 741                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 742                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 743                 }
 744                 else
 745                 {
 746                         if(strstrofs(msgin, "/me", 0) >= 0)
 747                         {
 748                                 //msgin = strreplace("/me", "", msgin);
 749                                 //msgin = substring(msgin, 3, strlen(msgin));
 750                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 751                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 752                         }
 753                         else
 754                                 msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 755                         cmsgstr = "";
 756                 }
 757                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 758         }
 759         else
 760         {
 761                 msgstr = cmsgstr = "";
 762         }
 763
 764         fullmsgstr = msgstr;
 765         fullcmsgstr = cmsgstr;
 766
 767         // FLOOD CONTROL
 768         flood = 0;
 769         flood_field = floodcontrol_chat;
 770         if(floodcontrol)
 771         {
 772                 float flood_spl;
 773                 float flood_burst;
 774                 float flood_lmax;
 775                 float lines;
 776                 if(privatesay)
 777                 {
 778                         flood_spl = autocvar_g_chat_flood_spl_tell;
 779                         flood_burst = autocvar_g_chat_flood_burst_tell;
 780                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 781                         flood_field = floodcontrol_chattell;
 782                 }
 783                 else if(teamsay)
 784                 {
 785                         flood_spl = autocvar_g_chat_flood_spl_team;
 786                         flood_burst = autocvar_g_chat_flood_burst_team;
 787                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 788                         flood_field = floodcontrol_chatteam;
 789                 }
 790                 else
 791                 {
 792                         flood_spl = autocvar_g_chat_flood_spl;
 793                         flood_burst = autocvar_g_chat_flood_burst;
 794                         flood_lmax = autocvar_g_chat_flood_lmax;
 795                         flood_field = floodcontrol_chat;
 796                 }
 797                 flood_burst = max(0, flood_burst - 1);
 798                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 799
 800                 // do flood control for the default line size
 801                 if(msgstr != "")
 802                 {
 803                         getWrappedLine_remaining = msgstr;
 804                         msgstr = "";
 805                         lines = 0;
 806                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 807                         {
 808                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 809                                 ++lines;
 810                         }
 811                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 812
 813                         if(getWrappedLine_remaining != "")
 814                         {
 815                                 msgstr = strcat(msgstr, "\n");
 816                                 flood = 2;
 817                         }
 818
 819                         if (time >= source.(flood_field))
 820                         {
 821                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 822                         }
 823                         else
 824                         {
 825                                 flood = 1;
 826                                 msgstr = fullmsgstr;
 827                         }
 828                 }
 829                 else
 830                 {
 831                         if (time >= source.(flood_field))
 832                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 833                         else
 834                                 flood = 1;
 835                 }
 836
 837                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 838                         source.(flood_field) = flood = 0;
 839         }
 840
 841         if(flood == 2) // cannot happen for empty msgstr
 842         {
 843                 if(autocvar_g_chat_flood_notify_flooder)
 844                 {
 845                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 846                         sourcecmsgstr = "";
 847                 }
 848                 else
 849                 {
 850                         sourcemsgstr = fullmsgstr;
 851                         sourcecmsgstr = fullcmsgstr;
 852                 }
 853                 cmsgstr = "";
 854         }
 855         else
 856         {
 857                 sourcemsgstr = msgstr;
 858                 sourcecmsgstr = cmsgstr;
 859         }
 860
 861         if(!privatesay)
 862         if (!IS_PLAYER(source))
 863         {
 864                 if (!intermission_running)
 865                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 866                                 teamsay = -1; // spectators
 867         }
 868
 869         if(flood)
 870                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 871
 872         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 873         if(privatesay)
 874                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 875
 876         if(source.muted)
 877         {
 878                 // always fake the message
 879                 ret = -1;
 880         }
 881         else if(flood == 1)
 882         {
 883                 if (autocvar_g_chat_flood_notify_flooder)
 884                 {
 885                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 886                         ret = 0;
 887                 }
 888                 else
 889                         ret = -1;
 890         }
 891         else
 892         {
 893                 ret = 1;
 894         }
 895
 896         if(sourcemsgstr != "" && ret != 0)
 897         {
 898                 if(ret < 0) // faked message, because the player is muted
 899                 {
 900                         sprint(source, sourcemsgstr);
 901                         if(sourcecmsgstr != "" && !privatesay)
 902                                 centerprint(source, sourcecmsgstr);
 903                 }
 904                 else if(privatesay) // private message, between 2 people only
 905                 {
 906                         sprint(source, sourcemsgstr);
 907                         sprint(privatesay, msgstr);
 908                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 909                         if(cmsgstr != "")
 910                                 centerprint(privatesay, cmsgstr);
 911                 }
 912                 else if ( teamsay && source.active_minigame )
 913                 {
 914                         sprint(source, sourcemsgstr);
 915                         dedicated_print(msgstr); // send to server console too
 916                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, LAMBDA(sprint(it, msgstr)));
 917                 }
 918                 else if(teamsay > 0) // team message, only sent to team mates
 919                 {
 920                         sprint(source, sourcemsgstr);
 921                         dedicated_print(msgstr); // send to server console too
 922                         if(sourcecmsgstr != "")
 923                                 centerprint(source, sourcecmsgstr);
 924                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, LAMBDA(
 925                                 sprint(it, msgstr);
 926                                 if(cmsgstr != "")
 927                                         centerprint(it, cmsgstr);
 928                         ));
 929                 }
 930                 else if(teamsay < 0) // spectator message, only sent to spectators
 931                 {
 932                         sprint(source, sourcemsgstr);
 933                         dedicated_print(msgstr); // send to server console too
 934                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, LAMBDA(sprint(it, msgstr)));
 935                 }
 936                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 937                 {
 938                         sprint(source, sourcemsgstr);
 939                         dedicated_print(msgstr); // send to server console too
 940                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, LAMBDA(sprint(it, msgstr)));
 941                 }
 942                 else
 943                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 944         }
 945
 946         return ret;
 947 }