qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag && !deadbits)
 244                 if(random() < 0.5)
 245                         deadbits = ANIMSTATE_DEAD1;
 246                 else
 247                         deadbits = ANIMSTATE_DEAD2;
 248         float animbits = deadbits;
 249         if(self.frozen)
 250                 animbits |= ANIMSTATE_FROZEN;
 251         if(self.crouch)
 252                 animbits |= ANIMSTATE_DUCK;
 253         animdecide_setstate(self, animbits, FALSE);
 254         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 255
 256         if (self.weaponentity)
 257         {
 258                 updateanim(self.weaponentity);
 259                 if (!self.weaponentity.animstate_override)
 260                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 261         }
 262 }
 263
 264 void SpawnThrownWeapon (vector org, float w)
 265 {
 266         if(self.weapons & WepSet_FromWeapon(self.weapon))
 267                 if(W_IsWeaponThrowable(self.weapon))
 268                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 269 }
 270
 271 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         float take, save;
 274         vector v;
 275         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 276
 277         // damage resistance (ignore most of the damage from a bullet or similar)
 278         damage = max(damage - 5, 1);
 279
 280         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 281         take = v_x;
 282         save = v_y;
 283
 284         if(sound_allowed(MSG_BROADCAST, attacker))
 285         {
 286                 if (save > 10)
 287                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 288                 else if (take > 30)
 289                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 290                 else if (take > 10)
 291                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 292         }
 293
 294         if (take > 50)
 295                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 296         if (take > 100)
 297                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 298
 299         if (!(self.flags & FL_GODMODE))
 300         {
 301                 self.armorvalue = self.armorvalue - save;
 302                 self.health = self.health - take;
 303                 // pause regeneration for 5 seconds
 304                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 305         }
 306         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 307         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 308         self.dmg_inflictor = inflictor;
 309
 310         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 311         {
 312                 // don't use any animations as a gib
 313                 self.frame = 0;
 314                 // view just above the floor
 315                 self.view_ofs = '0 0 4';
 316
 317                 Violence_GibSplash(self, 1, 1, attacker);
 318                 self.alpha = -1;
 319                 self.solid = SOLID_NOT; // restore later
 320                 self.takedamage = DAMAGE_NO; // restore later
 321                 self.damagedbycontents = FALSE;
 322         }
 323 }
 324
 325 // g_<gametype>_str:
 326 // If 0, default is used.
 327 // If <0, 0 is used.
 328 // Otherwise, g_str (default value) is used.
 329 // For consistency, negative values there are mapped to zero too.
 330 #define GAMETYPE_DEFAULTED_SETTING(str) \
 331         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 332          (gametype_setting_tmp < 0) ? 0 : \
 333          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 334          gametype_setting_tmp)
 335
 336
 337 void calculate_player_respawn_time()
 338 {
 339         float gametype_setting_tmp;
 340         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 341         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 342         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 343         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 344         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 345         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 346
 347         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 348         entity pl;
 349         if (teamplay)
 350         {
 351                 FOR_EACH_PLAYER(pl)
 352                         if (pl != self)
 353                                 if (pl.team == self.team)
 354                                         ++pcount;
 355                 if (sdelay_small_count == 0)
 356                         sdelay_small_count = 1;
 357                 if (sdelay_large_count == 0)
 358                         sdelay_large_count = 1;
 359         }
 360         else
 361         {
 362                 FOR_EACH_PLAYER(pl)
 363                         if (pl != self)
 364                                 ++pcount;
 365                 if (sdelay_small_count == 0)
 366                 {
 367                         if (g_cts)
 368                         {
 369                                 // Players play independently. No point in requiring enemies.
 370                                 sdelay_small_count = 1;
 371                         }
 372                         else
 373                         {
 374                                 // Players play AGAINST each other. Enemies required.
 375                                 sdelay_small_count = 2;
 376                         }
 377                 }
 378                 if (sdelay_large_count == 0)
 379                 {
 380                         if (g_cts)
 381                         {
 382                                 // Players play independently. No point in requiring enemies.
 383                                 sdelay_large_count = 1;
 384                         }
 385                         else
 386                         {
 387                                 // Players play AGAINST each other. Enemies required.
 388                                 sdelay_large_count = 2;
 389                         }
 390                 }
 391         }
 392
 393         float sdelay;
 394
 395         if (pcount <= sdelay_small_count)
 396                 sdelay = sdelay_small;
 397         else if (pcount >= sdelay_large_count)
 398                 sdelay = sdelay_large;
 399         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 400                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 401
 402         if(waves)
 403                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 404         else
 405                 self.respawn_time = time + sdelay;
 406
 407         if(sdelay < sdelay_max)
 408                 self.respawn_time_max = time + sdelay_max;
 409         else
 410                 self.respawn_time_max = self.respawn_time;
 411
 412         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 413                 self.respawn_countdown = 10; // first number to count down from is 10
 414         else
 415                 self.respawn_countdown = -1; // do not count down
 416
 417         if(autocvar_g_forced_respawn)
 418                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 419 }
 420
 421 void ClientKill_Now_TeamChange();
 422
 423 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 424 {
 425         float take, save, dh, da, j;
 426         vector v;
 427         float valid_damage_for_weaponstats;
 428         float excess;
 429
 430         dh = max(self.health, 0);
 431         da = max(self.armorvalue, 0);
 432
 433         if(!DEATH_ISSPECIAL(deathtype))
 434         {
 435                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 436                 if(self != attacker)
 437                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 438         }
 439
 440         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 441         {
 442                 // tuba causes blood to come out of the ears
 443                 vector ear1, ear2;
 444                 vector d;
 445                 float f;
 446                 ear1 = self.origin;
 447                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 448                 ear2 = ear1;
 449                 makevectors(self.angles);
 450                 ear1 += v_right * -10;
 451                 ear2 += v_right * +10;
 452                 d = inflictor.origin - self.origin;
 453                 if (d)
 454                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 455                 else
 456                         f = 0;  // Assum ecenter.
 457                 force = v_right * vlen(force);
 458                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 459                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 460                 if(f > 0)
 461                 {
 462                         hitloc = ear1;
 463                         force = force * -1;
 464                 }
 465                 else
 466                 {
 467                         hitloc = ear2;
 468                         // force is already good
 469                 }
 470         }
 471         else
 472                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 473
 474
 475         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 476         take = v_x;
 477         save = v_y;
 478
 479         if(attacker == self)
 480         {
 481                 // don't reset pushltime for self damage as it may be an attempt to
 482                 // escape a lava pit or similar
 483                 //self.pushltime = 0;
 484                 self.istypefrag = 0;
 485         }
 486         else if(IS_PLAYER(attacker))
 487         {
 488                 self.pusher = attacker;
 489                 self.pushltime = time + autocvar_g_maxpushtime;
 490                 self.istypefrag = self.BUTTON_CHAT;
 491         }
 492         else if(time < self.pushltime)
 493         {
 494                 attacker = self.pusher;
 495                 self.pushltime = max(self.pushltime, time + 0.6);
 496         }
 497         else
 498         {
 499                 self.pushltime = 0;
 500                 self.istypefrag = 0;
 501         }
 502
 503         frag_inflictor = inflictor;
 504         frag_attacker = attacker;
 505         frag_target = self;
 506         frag_damage = damage;
 507         damage_take = take;
 508         damage_save = save;
 509         damage_force = force;
 510         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 511         take = bound(0, damage_take, self.health);
 512         save = bound(0, damage_save, self.armorvalue);
 513         excess = max(0, damage - take - save);
 514
 515         if(sound_allowed(MSG_BROADCAST, attacker))
 516         {
 517                 if (save > 10)
 518                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 519                 else if (take > 30)
 520                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 521                 else if (take > 10)
 522                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 523         }
 524
 525         if (take > 50)
 526                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 527         if (take > 100)
 528                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 529
 530         if (time >= self.spawnshieldtime)
 531         {
 532                 if (!(self.flags & FL_GODMODE))
 533                 {
 534                         self.armorvalue = self.armorvalue - save;
 535                         self.health = self.health - take;
 536                         // pause regeneration for 5 seconds
 537                         if(take)
 538                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 539
 540                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 541                         {
 542                                 self.pain_finished = time + 0.5;        //Supajoe
 543
 544                                 if(autocvar_sv_gentle < 1) {
 545                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 546                                         {
 547                                                 if (!self.animstate_override)
 548                                                 {
 549                                                         if (random() > 0.5)
 550                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 551                                                         else
 552                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 553                                                 }
 554                                         }
 555
 556                                         if(sound_allowed(MSG_BROADCAST, attacker))
 557                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 558                                         if(self.health > 1)
 559                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 560                                         {
 561                                                 if(deathtype == DEATH_FALL)
 562                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                                 else if(self.health > 75) // TODO make a "gentle" version?
 564                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 565                                                 else if(self.health > 50)
 566                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 567                                                 else if(self.health > 25)
 568                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 569                                                 else
 570                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 571                                         }
 572                                 }
 573                         }
 574
 575                         // throw off bot aim temporarily
 576                         float shake;
 577                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 578                         {
 579                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 580                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 581                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 582                         }
 583                 }
 584                 else
 585                         self.max_armorvalue += (save + take);
 586         }
 587         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 588         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 589         self.dmg_inflictor = inflictor;
 590
 591         float abot, vbot, awep;
 592         abot = (IS_BOT_CLIENT(attacker));
 593         vbot = (IS_BOT_CLIENT(self));
 594
 595         valid_damage_for_weaponstats = 0;
 596         awep = 0;
 597
 598         if(vbot || IS_REAL_CLIENT(self))
 599         if(abot || IS_REAL_CLIENT(attacker))
 600         if(attacker && self != attacker)
 601         if(DIFF_TEAM(self, attacker))
 602         {
 603                 if(DEATH_ISSPECIAL(deathtype))
 604                         awep = attacker.weapon;
 605                 else
 606                         awep = DEATH_WEAPONOF(deathtype);
 607                 valid_damage_for_weaponstats = 1;
 608         }
 609
 610         if(valid_damage_for_weaponstats)
 611         {
 612                 dh = dh - max(self.health, 0);
 613                 da = da - max(self.armorvalue, 0);
 614                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 615         }
 616
 617         if (self.health < 1)
 618         {
 619                 float defer_ClientKill_Now_TeamChange;
 620                 defer_ClientKill_Now_TeamChange = FALSE;
 621
 622                 if(self.alivetime)
 623                 {
 624                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                         self.alivetime = 0;
 626                 }
 627
 628                 if(valid_damage_for_weaponstats)
 629                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 630
 631                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 632                 if(sound_allowed(MSG_BROADCAST, attacker))
 633                 {
 634                         if(deathtype == DEATH_DROWN)
 635                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 636                         else
 637                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 638                 }
 639
 640                 // get rid of kill indicator
 641                 if(self.killindicator)
 642                 {
 643                         remove(self.killindicator);
 644                         self.killindicator = world;
 645                         if(self.killindicator_teamchange)
 646                                 defer_ClientKill_Now_TeamChange = TRUE;
 647
 648                         if(self.classname == "body")
 649                         if(deathtype == DEATH_KILL)
 650                         {
 651                                 // for the lemmings fans, a small harmless explosion
 652                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 653                         }
 654                 }
 655
 656                 // print an obituary message
 657                 Obituary (attacker, inflictor, self, deathtype);
 658
 659         // increment frag counter for used weapon type
 660         float w;
 661         w = DEATH_WEAPONOF(deathtype);
 662         if(WEP_VALID(w))
 663         if(accuracy_isgooddamage(attacker, self))
 664         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 665
 666                 frag_attacker = attacker;
 667                 frag_inflictor = inflictor;
 668                 frag_target = self;
 669                 frag_deathtype = deathtype;
 670                 MUTATOR_CALLHOOK(PlayerDies);
 671
 672                 weapon_action(self.weapon, WR_PLAYERDEATH);
 673
 674                 RemoveGrapplingHook(self);
 675
 676                 Portal_ClearAllLater(self);
 677
 678                 self.fixangle = TRUE;
 679
 680                 if(defer_ClientKill_Now_TeamChange)
 681                         ClientKill_Now_TeamChange(); // can turn player into spectator
 682
 683                 // player could have been miraculously resuscitated ;)
 684                 // e.g. players in freezetag get frozen, they don't really die
 685                 if(self.health >= 1 || !IS_PLAYER(self))
 686                         return;
 687
 688                 // when we get here, player actually dies
 689
 690                 Unfreeze(self); // remove any icy remains
 691                 self.health = 0; // Unfreeze resets health, so we need to set it back
 692
 693                 // clear waypoints
 694                 WaypointSprite_PlayerDead();
 695                 // throw a weapon
 696                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 697
 698                 // become fully visible
 699                 self.alpha = default_player_alpha;
 700                 // make the corpse upright (not tilted)
 701                 self.angles_x = 0;
 702                 self.angles_z = 0;
 703                 // don't spin
 704                 self.avelocity = '0 0 0';
 705                 // view from the floor
 706                 self.view_ofs = '0 0 -8';
 707                 // toss the corpse
 708                 self.movetype = MOVETYPE_TOSS;
 709                 // shootable corpse
 710                 self.solid = SOLID_CORPSE;
 711                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 712                 // don't stick to the floor
 713                 self.flags &= ~FL_ONGROUND;
 714                 // dying animation
 715                 self.deadflag = DEAD_DYING;
 716                 // when to allow respawn
 717                 calculate_player_respawn_time();
 718
 719                 self.death_time = time;
 720                 if (random() < 0.5)
 721                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 722                 else
 723                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 724                 if (self.maxs_z > 5)
 725                 {
 726                         self.maxs_z = 5;
 727                         setsize(self, self.mins, self.maxs);
 728                 }
 729                 // set damage function to corpse damage
 730                 self.event_damage = PlayerCorpseDamage;
 731                 // call the corpse damage function just in case it wants to gib
 732                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 733                 // set up to fade out later
 734                 SUB_SetFade (self, time + 6 + random (), 1);
 735
 736                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 737                         // remove corpse
 738                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 739                 }
 740
 741                 // reset fields the weapons may use just in case
 742                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 743                 {
 744                         weapon_action(j, WR_RESETPLAYER);
 745                         ATTACK_FINISHED_FOR(self, j) = 0;
 746                 }
 747         }
 748 }
 749
 750 .float muted; // to be used by prvm_edictset server playernumber muted 1
 751 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 752 // message "": do not say, just test flood control
 753 // return value:
 754 //   1 = accept
 755 //   0 = reject
 756 //  -1 = fake accept
 757 {
 758         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 759         float flood;
 760         var .float flood_field;
 761         entity head;
 762         float ret;
 763         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 764
 765         if(!teamsay && !privatesay)
 766                 if(substring(msgin, 0, 1) == " ")
 767                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 768
 769         msgin = formatmessage(msgin);
 770
 771         if (!IS_PLAYER(source))
 772                 colorstr = "^0"; // black for spectators
 773         else if(teamplay)
 774                 colorstr = Team_ColorCode(source.team);
 775         else
 776         {
 777                 colorstr = "";
 778                 teamsay = FALSE;
 779         }
 780
 781         if(intermission_running)
 782                 teamsay = FALSE;
 783
 784         if(msgin != "")
 785                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 786
 787         /*
 788          * using bprint solves this... me stupid
 789         // how can we prevent the message from appearing in a listen server?
 790         // for now, just give "say" back and only handle say_team
 791         if(!teamsay)
 792         {
 793                 clientcommand(self, strcat("say ", msgin));
 794                 return;
 795         }
 796         */
 797
 798         if(autocvar_g_chat_teamcolors)
 799                 namestr = playername(source);
 800         else
 801                 namestr = source.netname;
 802
 803         if(strdecolorize(namestr) == namestr)
 804                 colorprefix = "^3";
 805         else
 806                 colorprefix = "^7";
 807
 808         if(msgin != "")
 809         {
 810                 if(privatesay)
 811                 {
 812                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 813                         privatemsgprefixlen = strlen(msgstr);
 814                         msgstr = strcat(msgstr, msgin);
 815                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 816                         if(autocvar_g_chat_teamcolors)
 817                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 818                         else
 819                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 820                 }
 821                 else if(teamsay)
 822                 {
 823                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 824                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 825                 }
 826                 else
 827                 {
 828                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 829                         cmsgstr = "";
 830                 }
 831                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 832         }
 833         else
 834         {
 835                 msgstr = cmsgstr = "";
 836         }
 837
 838         fullmsgstr = msgstr;
 839         fullcmsgstr = cmsgstr;
 840
 841         // FLOOD CONTROL
 842         flood = 0;
 843         flood_field = floodcontrol_chat;
 844         if(floodcontrol)
 845         {
 846                 float flood_spl;
 847                 float flood_burst;
 848                 float flood_lmax;
 849                 float lines;
 850                 if(privatesay)
 851                 {
 852                         flood_spl = autocvar_g_chat_flood_spl_tell;
 853                         flood_burst = autocvar_g_chat_flood_burst_tell;
 854                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 855                         flood_field = floodcontrol_chattell;
 856                 }
 857                 else if(teamsay)
 858                 {
 859                         flood_spl = autocvar_g_chat_flood_spl_team;
 860                         flood_burst = autocvar_g_chat_flood_burst_team;
 861                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 862                         flood_field = floodcontrol_chatteam;
 863                 }
 864                 else
 865                 {
 866                         flood_spl = autocvar_g_chat_flood_spl;
 867                         flood_burst = autocvar_g_chat_flood_burst;
 868                         flood_lmax = autocvar_g_chat_flood_lmax;
 869                         flood_field = floodcontrol_chat;
 870                 }
 871                 flood_burst = max(0, flood_burst - 1);
 872                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 873
 874                 // do flood control for the default line size
 875                 if(msgstr != "")
 876                 {
 877                         getWrappedLine_remaining = msgstr;
 878                         msgstr = "";
 879                         lines = 0;
 880                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 881                         {
 882                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 883                                 ++lines;
 884                         }
 885                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 886
 887                         if(getWrappedLine_remaining != "")
 888                         {
 889                                 msgstr = strcat(msgstr, "\n");
 890                                 flood = 2;
 891                         }
 892
 893                         if(time >= source.flood_field)
 894                         {
 895                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 896                         }
 897                         else
 898                         {
 899                                 flood = 1;
 900                                 msgstr = fullmsgstr;
 901                         }
 902                 }
 903                 else
 904                 {
 905                         if(time >= source.flood_field)
 906                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 907                         else
 908                                 flood = 1;
 909                 }
 910
 911                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 912                         source.flood_field = flood = 0;
 913         }
 914
 915         if(flood == 2) // cannot happen for empty msgstr
 916         {
 917                 if(autocvar_g_chat_flood_notify_flooder)
 918                 {
 919                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 920                         sourcecmsgstr = "";
 921                 }
 922                 else
 923                 {
 924                         sourcemsgstr = fullmsgstr;
 925                         sourcecmsgstr = fullcmsgstr;
 926                 }
 927                 cmsgstr = "";
 928         }
 929         else
 930         {
 931                 sourcemsgstr = msgstr;
 932                 sourcecmsgstr = cmsgstr;
 933         }
 934
 935         if(!privatesay)
 936         if (!IS_PLAYER(source))
 937         {
 938                 if (!intermission_running)
 939                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 940                                 teamsay = -1; // spectators
 941         }
 942
 943         if(flood)
 944                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 945
 946         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 947         if(privatesay)
 948                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 949
 950         if(source.muted)
 951         {
 952                 // always fake the message
 953                 ret = -1;
 954         }
 955         else if(flood == 1)
 956         {
 957                 if(autocvar_g_chat_flood_notify_flooder)
 958                 {
 959                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 960                         ret = 0;
 961                 }
 962                 else
 963                         ret = -1;
 964         }
 965         else
 966         {
 967                 ret = 1;
 968         }
 969
 970         if(sourcemsgstr != "" && ret != 0)
 971         {
 972                 if(ret < 0) // faked message, because the player is muted
 973                 {
 974                         sprint(source, sourcemsgstr);
 975                         if(sourcecmsgstr != "" && !privatesay)
 976                                 centerprint(source, sourcecmsgstr);
 977                 }
 978                 else if(privatesay) // private message, between 2 people only
 979                 {
 980                         sprint(source, sourcemsgstr);
 981                         sprint(privatesay, msgstr);
 982                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 983                         if(cmsgstr != "")
 984                                 centerprint(privatesay, cmsgstr);
 985                 }
 986                 else if(teamsay > 0) // team message, only sent to team mates
 987                 {
 988                         sprint(source, sourcemsgstr);
 989                         dedicated_print(msgstr); // send to server console too
 990                         if(sourcecmsgstr != "")
 991                                 centerprint(source, sourcecmsgstr);
 992                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 993                                 if(head != source)
 994                                 {
 995                                         sprint(head, msgstr);
 996                                         if(cmsgstr != "")
 997                                                 centerprint(head, cmsgstr);
 998                                 }
 999                 }
1000                 else if(teamsay < 0) // spectator message, only sent to spectators
1001                 {
1002                         sprint(source, sourcemsgstr);
1003                         dedicated_print(msgstr); // send to server console too
1004                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1005                                 if(head != source)
1006                                         sprint(head, msgstr);
1007                 }
1008                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1009                 {
1010                         sprint(source, sourcemsgstr);
1011                         dedicated_print(msgstr); // send to server console too
1012                         FOR_EACH_REALCLIENT(head)
1013                                 if(head != source)
1014                                         sprint(head, msgstr);
1015                 }
1016                 else
1017                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1018         }
1019
1020         return ret;
1021 }
1022
1023 float GetVoiceMessageVoiceType(string type)
1024 {
1025         if(type == "taunt")
1026                 return VOICETYPE_TAUNT;
1027         if(type == "teamshoot")
1028                 return VOICETYPE_LASTATTACKER;
1029         return VOICETYPE_TEAMRADIO;
1030 }
1031
1032 string allvoicesamples;
1033 .string GetVoiceMessageSampleField(string type)
1034 {
1035         GetPlayerSoundSampleField_notFound = 0;
1036         switch(type)
1037         {
1038 #define _VOICEMSG(m) case #m: return playersound_##m;
1039                 ALLVOICEMSGS
1040 #undef _VOICEMSG
1041         }
1042         GetPlayerSoundSampleField_notFound = 1;
1043         return playersound_taunt;
1044 }
1045
1046 .string GetPlayerSoundSampleField(string type)
1047 {
1048         GetPlayerSoundSampleField_notFound = 0;
1049         switch(type)
1050         {
1051 #define _VOICEMSG(m) case #m: return playersound_##m;
1052                 ALLPLAYERSOUNDS
1053 #undef _VOICEMSG
1054         }
1055         GetPlayerSoundSampleField_notFound = 1;
1056         return playersound_taunt;
1057 }
1058
1059 void PrecacheGlobalSound(string samplestring)
1060 {
1061         float n, i;
1062         tokenize_console(samplestring);
1063         n = stof(argv(1));
1064         if(n > 0)
1065         {
1066                 for(i = 1; i <= n; ++i)
1067                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1068         }
1069         else
1070         {
1071                 precache_sound(strcat(argv(0), ".wav"));
1072         }
1073 }
1074
1075 void PrecachePlayerSounds(string f)
1076 {
1077         float fh;
1078         string s;
1079         fh = fopen(f, FILE_READ);
1080         if(fh < 0)
1081                 return;
1082         while((s = fgets(fh)))
1083         {
1084                 if(tokenize_console(s) != 3)
1085                 {
1086                         dprint("Invalid sound info line: ", s, "\n");
1087                         continue;
1088                 }
1089                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1090         }
1091         fclose(fh);
1092
1093         if (!allvoicesamples)
1094         {
1095 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1096                 ALLVOICEMSGS
1097 #undef _VOICEMSG
1098                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1099         }
1100 }
1101
1102 void ClearPlayerSounds()
1103 {
1104 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1105         ALLPLAYERSOUNDS
1106         ALLVOICEMSGS
1107 #undef _VOICEMSG
1108 }
1109
1110 float LoadPlayerSounds(string f, float first)
1111 {
1112         float fh;
1113         string s;
1114         var .string field;
1115         fh = fopen(f, FILE_READ);
1116         if(fh < 0)
1117         {
1118                 dprint("Player sound file not found: ", f, "\n");
1119                 return 0;
1120         }
1121         while((s = fgets(fh)))
1122         {
1123                 if(tokenize_console(s) != 3)
1124                         continue;
1125                 field = GetPlayerSoundSampleField(argv(0));
1126                 if(GetPlayerSoundSampleField_notFound)
1127                         field = GetVoiceMessageSampleField(argv(0));
1128                 if(GetPlayerSoundSampleField_notFound)
1129                         continue;
1130                 if(self.field)
1131                         strunzone(self.field);
1132                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1133         }
1134         fclose(fh);
1135         return 1;
1136 }
1137
1138 .float modelindex_for_playersound;
1139 .float skin_for_playersound;
1140 void UpdatePlayerSounds()
1141 {
1142         if(self.modelindex == self.modelindex_for_playersound)
1143         if(self.skin == self.skin_for_playersound)
1144                 return;
1145         self.modelindex_for_playersound = self.modelindex;
1146         self.skin_for_playersound = self.skin;
1147         ClearPlayerSounds();
1148         LoadPlayerSounds("sound/player/default.sounds", 1);
1149         if(!autocvar_g_debug_defaultsounds)
1150                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1151                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1152 }
1153
1154 void FakeGlobalSound(string sample, float chan, float voicetype)
1155 {
1156         float n;
1157         float tauntrand;
1158
1159         if(sample == "")
1160                 return;
1161
1162         tokenize_console(sample);
1163         n = stof(argv(1));
1164         if(n > 0)
1165                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1166         else
1167                 sample = strcat(argv(0), ".wav"); // randomization
1168
1169         switch(voicetype)
1170         {
1171                 case VOICETYPE_LASTATTACKER_ONLY:
1172                         break;
1173                 case VOICETYPE_LASTATTACKER:
1174                         if(self.pusher)
1175                         {
1176                                 msg_entity = self;
1177                                 if(IS_REAL_CLIENT(msg_entity))
1178                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1179                         }
1180                         break;
1181                 case VOICETYPE_TEAMRADIO:
1182                         msg_entity = self;
1183                         if(msg_entity.cvar_cl_voice_directional == 1)
1184                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1185                         else
1186                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1187                         break;
1188                 case VOICETYPE_AUTOTAUNT:
1189                         if(!sv_autotaunt)
1190                                 break;
1191                         if(!sv_taunt)
1192                                 break;
1193                         if(autocvar_sv_gentle)
1194                                 break;
1195                         tauntrand = random();
1196                         msg_entity = self;
1197                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1198                         {
1199                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1200                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1201                                 else
1202                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1203                         }
1204                         break;
1205                 case VOICETYPE_TAUNT:
1206                         if(IS_PLAYER(self))
1207                                 if(self.deadflag == DEAD_NO)
1208                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1209                         if(!sv_taunt)
1210                                 break;
1211                         if(autocvar_sv_gentle)
1212                                 break;
1213                         msg_entity = self;
1214                         if (msg_entity.cvar_cl_voice_directional >= 1)
1215                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1216                         else
1217                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1218                         break;
1219                 case VOICETYPE_PLAYERSOUND:
1220                         msg_entity = self;
1221                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1222                         break;
1223                 default:
1224                         backtrace("Invalid voice type!");
1225                         break;
1226         }
1227 }
1228
1229 void GlobalSound(string sample, float chan, float voicetype)
1230 {
1231         float n;
1232         float tauntrand;
1233
1234         if(sample == "")
1235                 return;
1236
1237         tokenize_console(sample);
1238         n = stof(argv(1));
1239         if(n > 0)
1240                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1241         else
1242                 sample = strcat(argv(0), ".wav"); // randomization
1243
1244         switch(voicetype)
1245         {
1246                 case VOICETYPE_LASTATTACKER_ONLY:
1247                         if(self.pusher)
1248                         {
1249                                 msg_entity = self.pusher;
1250                                 if(IS_REAL_CLIENT(msg_entity))
1251                                 {
1252                                         if(msg_entity.cvar_cl_voice_directional == 1)
1253                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1254                                         else
1255                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1256                                 }
1257                         }
1258                         break;
1259                 case VOICETYPE_LASTATTACKER:
1260                         if(self.pusher)
1261                         {
1262                                 msg_entity = self.pusher;
1263                                 if(IS_REAL_CLIENT(msg_entity))
1264                                 {
1265                                         if(msg_entity.cvar_cl_voice_directional == 1)
1266                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1267                                         else
1268                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1269                                 }
1270                                 msg_entity = self;
1271                                 if(IS_REAL_CLIENT(msg_entity))
1272                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1273                         }
1274                         break;
1275                 case VOICETYPE_TEAMRADIO:
1276                         FOR_EACH_REALCLIENT(msg_entity)
1277                                 if(!teamplay || msg_entity.team == self.team)
1278                                 {
1279                                         if(msg_entity.cvar_cl_voice_directional == 1)
1280                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1281                                         else
1282                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1283                                 }
1284                         break;
1285                 case VOICETYPE_AUTOTAUNT:
1286                         if(!sv_autotaunt)
1287                                 break;
1288                         if(!sv_taunt)
1289                                 break;
1290                         if(autocvar_sv_gentle)
1291                                 break;
1292                         tauntrand = random();
1293                         FOR_EACH_REALCLIENT(msg_entity)
1294                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1295                                 {
1296                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1297                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1298                                         else
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1300                                 }
1301                         break;
1302                 case VOICETYPE_TAUNT:
1303                         if(IS_PLAYER(self))
1304                                 if(self.deadflag == DEAD_NO)
1305                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1306                         if(!sv_taunt)
1307                                 break;
1308                         if(autocvar_sv_gentle)
1309                                 break;
1310                         FOR_EACH_REALCLIENT(msg_entity)
1311                         {
1312                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1313                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1314                                 else
1315                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1316                         }
1317                         break;
1318                 case VOICETYPE_PLAYERSOUND:
1319                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1320                         break;
1321                 default:
1322                         backtrace("Invalid voice type!");
1323                         break;
1324         }
1325 }
1326
1327 void PlayerSound(.string samplefield, float chan, float voicetype)
1328 {
1329         GlobalSound(self.samplefield, chan, voicetype);
1330 }
1331
1332 void VoiceMessage(string type, string msg)
1333 {
1334         var .string sample;
1335         float voicetype, ownteam;
1336         float flood;
1337         sample = GetVoiceMessageSampleField(type);
1338
1339         if(GetPlayerSoundSampleField_notFound)
1340         {
1341                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1342                 return;
1343         }
1344
1345         voicetype = GetVoiceMessageVoiceType(type);
1346         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1347
1348         flood = Say(self, ownteam, world, msg, 1);
1349
1350         if (flood > 0)
1351                 GlobalSound(self.sample, CH_VOICE, voicetype);
1352         else if (flood < 0)
1353                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1354 }
1355
1356 void MoveToTeam(entity client, float team_colour, float type)
1357 {
1358         float lockteams_backup;
1359
1360         lockteams_backup = lockteams;  // backup any team lock
1361
1362         lockteams = 0;  // disable locked teams
1363
1364         TeamchangeFrags(client);  // move the players frags
1365         SetPlayerColors(client, team_colour - 1);  // set the players colour
1366         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1367
1368         lockteams = lockteams_backup;  // restore the team lock
1369
1370         LogTeamchange(client.playerid, client.team, type);
1371 }