qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // load animation info
 229         animdecide_init(self);
 230         animdecide_setstate(self, 0, FALSE);
 231 }
 232
 233 void player_anim (void)
 234 {
 235         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 236         if(self.deadflag && !deadbits)
 237                 if(random() < 0.5)
 238                         deadbits = ANIMSTATE_DEAD1;
 239                 else
 240                         deadbits = ANIMSTATE_DEAD2;
 241         float animbits = deadbits;
 242         if(self.freezetag_frozen)
 243                 animbits |= ANIMSTATE_FROZEN;
 244         if(self.crouch)
 245                 animbits |= ANIMSTATE_DUCK;
 246         animdecide_setstate(self, animbits, FALSE);
 247
 248         animdecide_setframes(self, FALSE);
 249
 250         if (self.weaponentity)
 251         {
 252                 updateanim(self.weaponentity);
 253                 if (!self.weaponentity.animstate_override)
 254                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 255         }
 256 }
 257
 258 void SpawnThrownWeapon (vector org, float w)
 259 {
 260         if(g_minstagib)
 261         if(self.ammo_cells <= 0)
 262                 return;
 263
 264         if(g_pinata)
 265         {
 266                 float j;
 267                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 268                 {
 269                         if(WEPSET_CONTAINS_EW(self, j))
 270                                 if(W_IsWeaponThrowable(j))
 271                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 272                 }
 273         }
 274         else
 275         {
 276                 if(W_IsWeaponThrowable(self.weapon))
 277                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 278         }
 279 }
 280
 281 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 282 {
 283         float take, save;
 284         vector v;
 285         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 286
 287         // damage resistance (ignore most of the damage from a bullet or similar)
 288         damage = max(damage - 5, 1);
 289
 290         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 291         take = v_x;
 292         save = v_y;
 293
 294         if(sound_allowed(MSG_BROADCAST, attacker))
 295         {
 296                 if (save > 10)
 297                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 298                 else if (take > 30)
 299                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 300                 else if (take > 10)
 301                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 302         }
 303
 304         if (take > 50)
 305                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 306         if (take > 100)
 307                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 308
 309         if (!(self.flags & FL_GODMODE))
 310         {
 311                 self.armorvalue = self.armorvalue - save;
 312                 self.health = self.health - take;
 313                 // pause regeneration for 5 seconds
 314                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 315         }
 316         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 317         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 318         self.dmg_inflictor = inflictor;
 319
 320         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 321         {
 322                 // don't use any animations as a gib
 323                 self.frame = 0;
 324                 // view just above the floor
 325                 self.view_ofs = '0 0 4';
 326
 327                 Violence_GibSplash(self, 1, 1, attacker);
 328                 self.alpha = -1;
 329                 self.solid = SOLID_NOT; // restore later
 330                 self.takedamage = DAMAGE_NO; // restore later
 331                 self.damagedbycontents = FALSE;
 332         }
 333 }
 334
 335 void ClientKill_Now_TeamChange();
 336 void freezetag_CheckWinner();
 337
 338 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 339 {
 340         float take, save, waves, sdelay, dh, da, j;
 341         vector v;
 342         float valid_damage_for_weaponstats;
 343         float excess;
 344
 345         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 346                 return;
 347
 348         dh = max(self.health, 0);
 349         da = max(self.armorvalue, 0);
 350
 351         if(!DEATH_ISSPECIAL(deathtype))
 352         {
 353                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 354                 if(self != attacker)
 355                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 356         }
 357
 358         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 359         {
 360                 // tuba causes blood to come out of the ears
 361                 vector ear1, ear2;
 362                 vector d;
 363                 float f;
 364                 ear1 = self.origin;
 365                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 366                 ear2 = ear1;
 367                 makevectors(self.angles);
 368                 ear1 += v_right * -10;
 369                 ear2 += v_right * +10;
 370                 d = inflictor.origin - self.origin;
 371                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 372                 force = v_right * vlen(force);
 373                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 374                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 375                 if(f > 0)
 376                 {
 377                         hitloc = ear1;
 378                         force = force * -1;
 379                 }
 380                 else
 381                 {
 382                         hitloc = ear2;
 383                         // force is already good
 384                 }
 385         }
 386         else
 387                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 388
 389         if (!g_minstagib)
 390         {
 391                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 392                 take = v_x;
 393                 save = v_y;
 394         }
 395         else
 396         {
 397                 save = 0;
 398                 take = damage;
 399         }
 400
 401         frag_inflictor = inflictor;
 402         frag_attacker = attacker;
 403         frag_target = self;
 404         damage_take = take;
 405         damage_save = save;
 406         damage_force = force;
 407         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 408         take = bound(0, damage_take, self.health);
 409         save = bound(0, damage_save, self.armorvalue);
 410         excess = max(0, damage - take - save);
 411
 412         if(sound_allowed(MSG_BROADCAST, attacker))
 413         {
 414                 if (save > 10)
 415                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 416                 else if (take > 30)
 417                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 418                 else if (take > 10)
 419                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 420         }
 421
 422         if (take > 50)
 423                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 424         if (take > 100)
 425                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 426
 427         if (time >= self.spawnshieldtime)
 428         {
 429                 if (!(self.flags & FL_GODMODE))
 430                 {
 431                         self.armorvalue = self.armorvalue - save;
 432                         self.health = self.health - take;
 433                         // pause regeneration for 5 seconds
 434                         if(take)
 435                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 436
 437                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 438                         {
 439                                 self.pain_finished = time + 0.5;        //Supajoe
 440
 441                                 if(sv_gentle < 1) {
 442                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 443                                         {
 444                                                 if (!self.animstate_override)
 445                                                 {
 446                                                         if (random() > 0.5)
 447                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 448                                                         else
 449                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 450                                                 }
 451                                         }
 452
 453                                         if(sound_allowed(MSG_BROADCAST, attacker))
 454                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 455                                         if(self.health > 1)
 456                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 457                                         {
 458                                                 if(deathtype == DEATH_FALL)
 459                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 460                                                 else if(self.health > 75) // TODO make a "gentle" version?
 461                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 462                                                 else if(self.health > 50)
 463                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 464                                                 else if(self.health > 25)
 465                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 466                                                 else
 467                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 468                                         }
 469                                 }
 470
 471                                 // throw off bot aim temporarily
 472                                 float shake;
 473                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 474                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 475                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 476                         }
 477                 }
 478                 else
 479                         self.max_armorvalue += (save + take);
 480         }
 481         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 482         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 483         self.dmg_inflictor = inflictor;
 484
 485         if(attacker == self)
 486         {
 487                 // don't reset pushltime for self damage as it may be an attempt to
 488                 // escape a lava pit or similar
 489                 //self.pushltime = 0;
 490                 self.istypefrag = 0;
 491         }
 492         else if(attacker.classname == "player")
 493         {
 494                 self.pusher = attacker;
 495                 self.pushltime = time + autocvar_g_maxpushtime;
 496                 self.istypefrag = self.BUTTON_CHAT;
 497         }
 498         else if(time < self.pushltime)
 499         {
 500                 attacker = self.pusher;
 501                 self.pushltime = max(self.pushltime, time + 0.6);
 502         }
 503         else
 504         {
 505                 self.pushltime = 0;
 506                 self.istypefrag = 0;
 507         }
 508
 509         float abot, vbot, awep;
 510         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 511         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 512
 513         valid_damage_for_weaponstats = 0;
 514         awep = 0;
 515
 516         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 517         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 518         if(attacker && self != attacker)
 519         if(IsDifferentTeam(self, attacker))
 520         {
 521                 if(DEATH_ISSPECIAL(deathtype))
 522                         awep = attacker.weapon;
 523                 else
 524                         awep = DEATH_WEAPONOF(deathtype);
 525                 valid_damage_for_weaponstats = 1;
 526         }
 527
 528         if(valid_damage_for_weaponstats)
 529         {
 530                 dh = dh - max(self.health, 0);
 531                 da = da - max(self.armorvalue, 0);
 532                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 533         }
 534
 535         if (self.health < 1)
 536         {
 537                 float defer_ClientKill_Now_TeamChange;
 538                 defer_ClientKill_Now_TeamChange = FALSE;
 539
 540                 if(self.alivetime)
 541                 {
 542                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 543                         self.alivetime = 0;
 544                 }
 545
 546                 if(valid_damage_for_weaponstats)
 547                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 548
 549                 if(sv_gentle < 1) // TODO make a "gentle" version?
 550                 if(sound_allowed(MSG_BROADCAST, attacker))
 551                 {
 552                         if(deathtype == DEATH_DROWN)
 553                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 554                         else
 555                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 556                 }
 557
 558                 // get rid of kill indicator
 559                 if(self.killindicator)
 560                 {
 561                         remove(self.killindicator);
 562                         self.killindicator = world;
 563                         if(self.killindicator_teamchange)
 564                                 defer_ClientKill_Now_TeamChange = TRUE;
 565
 566                         if(self.classname == "body")
 567                         if(deathtype == DEATH_KILL)
 568                         {
 569                                 // for the lemmings fans, a small harmless explosion
 570                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 571                         }
 572                 }
 573
 574                 if(!g_freezetag)
 575                 {
 576                         // become fully visible
 577                         self.alpha = default_player_alpha;
 578                         // throw a weapon
 579                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 580                 }
 581
 582                 // print an obituary message
 583                 Obituary (attacker, inflictor, self, deathtype);
 584                 race_PreDie();
 585                 DropAllRunes(self);
 586
 587         // increment frag counter for used weapon type
 588         float w;
 589         w = DEATH_WEAPONOF(deathtype);
 590         if(WEP_VALID(w))
 591         if(accuracy_isgooddamage(attacker, self))
 592         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 593
 594                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 595                 {
 596                         PutClientInServer();
 597                         count_alive_players(); // re-count players
 598                         freezetag_CheckWinner();
 599                         return;
 600                 }
 601
 602                 frag_attacker = attacker;
 603                 frag_inflictor = inflictor;
 604                 frag_target = self;
 605                 MUTATOR_CALLHOOK(PlayerDies);
 606                 weapon_action(self.weapon, WR_PLAYERDEATH);
 607
 608                 RemoveGrapplingHook(self);
 609
 610                 Portal_ClearAllLater(self);
 611
 612                 if(clienttype(self) == CLIENTTYPE_REAL)
 613                 {
 614                         stuffcmd(self, "-zoom\n");
 615                         self.fixangle = TRUE;
 616                         //msg_entity = self;
 617                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 618                         //WriteAngle (MSG_ONE, self.v_angle_x);
 619                         //WriteAngle (MSG_ONE, self.v_angle_y);
 620                         //WriteAngle (MSG_ONE, 80);
 621                 }
 622
 623                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 624                         ClientKill_Now_TeamChange();
 625
 626                 if(g_arena)
 627                         Spawnqueue_Unmark(self);
 628
 629                 if(g_freezetag)
 630                         return;
 631
 632                 // when we get here, player actually dies
 633                 // clear waypoints (do this AFTER FreezeTag)
 634                 WaypointSprite_PlayerDead();
 635
 636                 // make the corpse upright (not tilted)
 637                 self.angles_x = 0;
 638                 self.angles_z = 0;
 639                 // don't spin
 640                 self.avelocity = '0 0 0';
 641                 // view from the floor
 642                 self.view_ofs = '0 0 -8';
 643                 // toss the corpse
 644                 self.movetype = MOVETYPE_TOSS;
 645                 // shootable corpse
 646                 self.solid = SOLID_CORPSE;
 647                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 648                 // don't stick to the floor
 649                 self.flags &~= FL_ONGROUND;
 650                 // dying animation
 651                 self.deadflag = DEAD_DYING;
 652                 // when to allow respawn
 653                 sdelay = 0;
 654                 waves = 0;
 655                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 656                 if(!sdelay)
 657                 {
 658                         if(g_cts)
 659                                 sdelay = 0; // no respawn delay in CTS
 660                         else
 661                                 sdelay = autocvar_g_respawn_delay;
 662                 }
 663                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 664                 if(!waves)
 665                         waves = autocvar_g_respawn_waves;
 666                 if(waves)
 667                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 668                 else
 669                         self.respawn_time = time + sdelay;
 670                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 671                         self.respawn_countdown = 10; // first number to count down from is 10
 672                 else
 673                         self.respawn_countdown = -1; // do not count down
 674                 self.death_time = time;
 675                 if (random() < 0.5)
 676                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 677                 else
 678                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 679                 if (self.maxs_z > 5)
 680                 {
 681                         self.maxs_z = 5;
 682                         setsize(self, self.mins, self.maxs);
 683                 }
 684                 // set damage function to corpse damage
 685                 self.event_damage = PlayerCorpseDamage;
 686                 // call the corpse damage function just in case it wants to gib
 687                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 688                 // set up to fade out later
 689                 SUB_SetFade (self, time + 6 + random (), 1);
 690
 691                 if(sv_gentle > 0 || autocvar_ekg) {
 692                         // remove corpse
 693                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 694                 }
 695
 696                 // reset fields the weapons may use just in case
 697                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 698                 {
 699                         weapon_action(j, WR_RESETPLAYER);
 700                         ATTACK_FINISHED_FOR(self, j) = 0;
 701                 }
 702         }
 703 }
 704
 705 .float muted; // to be used by prvm_edictset server playernumber muted 1
 706 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 707 // message "": do not say, just test flood control
 708 // return value:
 709 //   1 = accept
 710 //   0 = reject
 711 //  -1 = fake accept
 712 {
 713         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 714         float flood;
 715         var .float flood_field;
 716         entity head;
 717         float ret;
 718         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 719
 720         if(!teamsay && !privatesay)
 721                 if(substring(msgin, 0, 1) == " ")
 722                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 723
 724         msgin = formatmessage(msgin);
 725
 726         if(source.classname != "player")
 727                 colorstr = "^0"; // black for spectators
 728         else if(teamplay)
 729                 colorstr = Team_ColorCode(source.team);
 730         else
 731         {
 732                 colorstr = "";
 733                 teamsay = FALSE;
 734         }
 735
 736         if(intermission_running)
 737                 teamsay = FALSE;
 738
 739         if(msgin != "")
 740                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 741
 742         /*
 743          * using bprint solves this... me stupid
 744         // how can we prevent the message from appearing in a listen server?
 745         // for now, just give "say" back and only handle say_team
 746         if(!teamsay)
 747         {
 748                 clientcommand(self, strcat("say ", msgin));
 749                 return;
 750         }
 751         */
 752
 753         if(autocvar_g_chat_teamcolors)
 754                 namestr = playername(source);
 755         else
 756                 namestr = source.netname;
 757
 758         if(msgin != "")
 759         {
 760                 if(privatesay)
 761                 {
 762                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 763                         privatemsgprefixlen = strlen(msgstr);
 764                         msgstr = strcat(msgstr, msgin);
 765                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 766                         if(autocvar_g_chat_teamcolors)
 767                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 768                         else
 769                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 770                 }
 771                 else if(teamsay)
 772                 {
 773                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 774                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 775                 }
 776                 else
 777                 {
 778                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 779                         cmsgstr = "";
 780                 }
 781                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 782         }
 783         else
 784         {
 785                 msgstr = cmsgstr = "";
 786         }
 787
 788         fullmsgstr = msgstr;
 789         fullcmsgstr = cmsgstr;
 790
 791         // FLOOD CONTROL
 792         flood = 0;
 793         flood_field = floodcontrol_chat;
 794         if(floodcontrol)
 795         {
 796                 float flood_spl;
 797                 float flood_burst;
 798                 float flood_lmax;
 799                 float lines;
 800                 if(privatesay)
 801                 {
 802                         flood_spl = autocvar_g_chat_flood_spl_tell;
 803                         flood_burst = autocvar_g_chat_flood_burst_tell;
 804                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 805                         flood_field = floodcontrol_chattell;
 806                 }
 807                 else if(teamsay)
 808                 {
 809                         flood_spl = autocvar_g_chat_flood_spl_team;
 810                         flood_burst = autocvar_g_chat_flood_burst_team;
 811                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 812                         flood_field = floodcontrol_chatteam;
 813                 }
 814                 else
 815                 {
 816                         flood_spl = autocvar_g_chat_flood_spl;
 817                         flood_burst = autocvar_g_chat_flood_burst;
 818                         flood_lmax = autocvar_g_chat_flood_lmax;
 819                         flood_field = floodcontrol_chat;
 820                 }
 821                 flood_burst = max(0, flood_burst - 1);
 822                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 823
 824                 // do flood control for the default line size
 825                 if(msgstr != "")
 826                 {
 827                         getWrappedLine_remaining = msgstr;
 828                         msgstr = "";
 829                         lines = 0;
 830                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 831                         {
 832                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 833                                 ++lines;
 834                         }
 835                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 836
 837                         if(getWrappedLine_remaining != "")
 838                         {
 839                                 msgstr = strcat(msgstr, "\n");
 840                                 flood = 2;
 841                         }
 842
 843                         if(time >= source.flood_field)
 844                         {
 845                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 846                         }
 847                         else
 848                         {
 849                                 flood = 1;
 850                                 msgstr = fullmsgstr;
 851                         }
 852                 }
 853                 else
 854                 {
 855                         if(time >= source.flood_field)
 856                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 857                         else
 858                                 flood = 1;
 859                 }
 860
 861                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 862                         source.flood_field = flood = 0;
 863         }
 864
 865         if(flood == 2) // cannot happen for empty msgstr
 866         {
 867                 if(autocvar_g_chat_flood_notify_flooder)
 868                 {
 869                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 870                         sourcecmsgstr = "";
 871                 }
 872                 else
 873                 {
 874                         sourcemsgstr = fullmsgstr;
 875                         sourcecmsgstr = fullcmsgstr;
 876                 }
 877                 cmsgstr = "";
 878         }
 879         else
 880         {
 881                 sourcemsgstr = msgstr;
 882                 sourcecmsgstr = cmsgstr;
 883         }
 884
 885         if(!privatesay)
 886         if(source.classname != "player")
 887         {
 888                 if not(intermission_running)
 889                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 890                                 teamsay = -1; // spectators
 891         }
 892
 893         if(flood)
 894                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 895
 896         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 897         if(privatesay)
 898                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 899
 900         if(source.muted)
 901         {
 902                 // always fake the message
 903                 ret = -1;
 904         }
 905         else if(flood == 1)
 906         {
 907                 if(autocvar_g_chat_flood_notify_flooder)
 908                 {
 909                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 910                         ret = 0;
 911                 }
 912                 else
 913                         ret = -1;
 914         }
 915         else
 916         {
 917                 ret = 1;
 918         }
 919
 920         if(sourcemsgstr != "" && ret != 0)
 921         {
 922                 if(ret < 0) // faked message, because the player is muted
 923                 {
 924                         sprint(source, sourcemsgstr);
 925                         if(sourcecmsgstr != "" && !privatesay)
 926                                 centerprint(source, sourcecmsgstr);
 927                 }
 928                 else if(privatesay) // private message, between 2 people only, not sent to server console
 929                 {
 930                         sprint(source, sourcemsgstr);
 931                         sprint(privatesay, msgstr);
 932                         if(cmsgstr != "")
 933                                 centerprint(privatesay, cmsgstr);
 934                 }
 935                 else if(teamsay > 0) // team message, only sent to team mates
 936                 {
 937                         sprint(source, sourcemsgstr);
 938                         //print(msgstr); // send to server console too
 939                         if(sourcecmsgstr != "")
 940                                 centerprint(source, sourcecmsgstr);
 941                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 942                                 if(head != source)
 943                                 {
 944                                         sprint(head, msgstr);
 945                                         if(cmsgstr != "")
 946                                                 centerprint(head, cmsgstr);
 947                                 }
 948                 }
 949                 else if(teamsay < 0) // spectator message, only sent to spectators
 950                 {
 951                         sprint(source, sourcemsgstr);
 952                         //print(msgstr); // send to server console too
 953                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 954                                 if(head != source)
 955                                         sprint(head, msgstr);
 956                 }
 957                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 958                 {
 959                         sprint(source, sourcemsgstr);
 960                         //print(msgstr); // send to server console too
 961                         FOR_EACH_REALCLIENT(head)
 962                                 if(head != source)
 963                                         sprint(head, msgstr);
 964                 }
 965                 else
 966                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 967         }
 968
 969         return ret;
 970 }
 971
 972 float GetVoiceMessageVoiceType(string type)
 973 {
 974         if(type == "taunt")
 975                 return VOICETYPE_TAUNT;
 976         if(type == "teamshoot")
 977                 return VOICETYPE_LASTATTACKER;
 978         return VOICETYPE_TEAMRADIO;
 979 }
 980
 981 string allvoicesamples;
 982 .string GetVoiceMessageSampleField(string type)
 983 {
 984         GetPlayerSoundSampleField_notFound = 0;
 985         switch(type)
 986         {
 987 #define _VOICEMSG(m) case #m: return playersound_##m;
 988                 ALLVOICEMSGS
 989 #undef _VOICEMSG
 990         }
 991         GetPlayerSoundSampleField_notFound = 1;
 992         return playersound_taunt;
 993 }
 994
 995 .string GetPlayerSoundSampleField(string type)
 996 {
 997         GetPlayerSoundSampleField_notFound = 0;
 998         switch(type)
 999         {
1000 #define _VOICEMSG(m) case #m: return playersound_##m;
1001                 ALLPLAYERSOUNDS
1002 #undef _VOICEMSG
1003         }
1004         GetPlayerSoundSampleField_notFound = 1;
1005         return playersound_taunt;
1006 }
1007
1008 void PrecacheGlobalSound(string samplestring)
1009 {
1010         float n, i;
1011         tokenize_console(samplestring);
1012         n = stof(argv(1));
1013         if(n > 0)
1014         {
1015                 for(i = 1; i <= n; ++i)
1016                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1017         }
1018         else
1019         {
1020                 precache_sound(strcat(argv(0), ".wav"));
1021         }
1022 }
1023
1024 void PrecachePlayerSounds(string f)
1025 {
1026         float fh;
1027         string s;
1028         fh = fopen(f, FILE_READ);
1029         if(fh < 0)
1030                 return;
1031         while((s = fgets(fh)))
1032         {
1033                 if(tokenize_console(s) != 3)
1034                 {
1035                         dprint("Invalid sound info line: ", s, "\n");
1036                         continue;
1037                 }
1038                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1039         }
1040         fclose(fh);
1041
1042         if not(allvoicesamples)
1043         {
1044 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1045                 ALLVOICEMSGS
1046 #undef _VOICEMSG
1047                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1048         }
1049 }
1050
1051 void ClearPlayerSounds()
1052 {
1053 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1054         ALLPLAYERSOUNDS
1055         ALLVOICEMSGS
1056 #undef _VOICEMSG
1057 }
1058
1059 float LoadPlayerSounds(string f, float first)
1060 {
1061         float fh;
1062         string s;
1063         var .string field;
1064         fh = fopen(f, FILE_READ);
1065         if(fh < 0)
1066         {
1067                 dprint("Player sound file not found: ", f, "\n");
1068                 return 0;
1069         }
1070         while((s = fgets(fh)))
1071         {
1072                 if(tokenize_console(s) != 3)
1073                         continue;
1074                 field = GetPlayerSoundSampleField(argv(0));
1075                 if(GetPlayerSoundSampleField_notFound)
1076                         field = GetVoiceMessageSampleField(argv(0));
1077                 if(GetPlayerSoundSampleField_notFound)
1078                         continue;
1079                 if(self.field)
1080                         strunzone(self.field);
1081                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1082         }
1083         fclose(fh);
1084         return 1;
1085 }
1086
1087 .float modelindex_for_playersound;
1088 .float skin_for_playersound;
1089 void UpdatePlayerSounds()
1090 {
1091         if(self.modelindex == self.modelindex_for_playersound)
1092         if(self.skin == self.skin_for_playersound)
1093                 return;
1094         self.modelindex_for_playersound = self.modelindex;
1095         self.skin_for_playersound = self.skin;
1096         ClearPlayerSounds();
1097         LoadPlayerSounds("sound/player/default.sounds", 1);
1098         if(!autocvar_g_debug_defaultsounds)
1099                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1100                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1101 }
1102
1103 void FakeGlobalSound(string sample, float chan, float voicetype)
1104 {
1105         float n;
1106         float tauntrand;
1107
1108         if(sample == "")
1109                 return;
1110
1111         tokenize_console(sample);
1112         n = stof(argv(1));
1113         if(n > 0)
1114                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1115         else
1116                 sample = strcat(argv(0), ".wav"); // randomization
1117
1118         switch(voicetype)
1119         {
1120                 case VOICETYPE_LASTATTACKER_ONLY:
1121                         break;
1122                 case VOICETYPE_LASTATTACKER:
1123                         if(self.pusher)
1124                         {
1125                                 msg_entity = self;
1126                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1127                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1128                         }
1129                         break;
1130                 case VOICETYPE_TEAMRADIO:
1131                         msg_entity = self;
1132                         if(msg_entity.cvar_cl_voice_directional == 1)
1133                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1134                         else
1135                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1136                         break;
1137                 case VOICETYPE_AUTOTAUNT:
1138                         if(!sv_autotaunt)
1139                                 break;
1140                         if(!sv_taunt)
1141                                 break;
1142                         if(sv_gentle)
1143                                 break;
1144                         tauntrand = random();
1145                         msg_entity = self;
1146                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1147                         {
1148                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1149                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1150                                 else
1151                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1152                         }
1153                         break;
1154                 case VOICETYPE_TAUNT:
1155                         if(self.classname == "player")
1156                                 if(self.deadflag == DEAD_NO)
1157                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1158                         if(!sv_taunt)
1159                                 break;
1160                         if(sv_gentle)
1161                                 break;
1162                         msg_entity = self;
1163                         if (msg_entity.cvar_cl_voice_directional >= 1)
1164                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1165                         else
1166                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1167                         break;
1168                 case VOICETYPE_PLAYERSOUND:
1169                         msg_entity = self;
1170                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1171                         break;
1172                 default:
1173                         backtrace("Invalid voice type!");
1174                         break;
1175         }
1176 }
1177
1178 void GlobalSound(string sample, float chan, float voicetype)
1179 {
1180         float n;
1181         float tauntrand;
1182
1183         if(sample == "")
1184                 return;
1185
1186         tokenize_console(sample);
1187         n = stof(argv(1));
1188         if(n > 0)
1189                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1190         else
1191                 sample = strcat(argv(0), ".wav"); // randomization
1192
1193         switch(voicetype)
1194         {
1195                 case VOICETYPE_LASTATTACKER_ONLY:
1196                         if(self.pusher)
1197                         {
1198                                 msg_entity = self.pusher;
1199                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1200                                 {
1201                                         if(msg_entity.cvar_cl_voice_directional == 1)
1202                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1203                                         else
1204                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1205                                 }
1206                         }
1207                         break;
1208                 case VOICETYPE_LASTATTACKER:
1209                         if(self.pusher)
1210                         {
1211                                 msg_entity = self.pusher;
1212                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1213                                 {
1214                                         if(msg_entity.cvar_cl_voice_directional == 1)
1215                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1216                                         else
1217                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1218                                 }
1219                                 msg_entity = self;
1220                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1221                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1222                         }
1223                         break;
1224                 case VOICETYPE_TEAMRADIO:
1225                         FOR_EACH_REALCLIENT(msg_entity)
1226                                 if(!teamplay || msg_entity.team == self.team)
1227                                 {
1228                                         if(msg_entity.cvar_cl_voice_directional == 1)
1229                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1230                                         else
1231                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1232                                 }
1233                         break;
1234                 case VOICETYPE_AUTOTAUNT:
1235                         if(!sv_autotaunt)
1236                                 break;
1237                         if(!sv_taunt)
1238                                 break;
1239                         if(sv_gentle)
1240                                 break;
1241                         tauntrand = random();
1242                         FOR_EACH_REALCLIENT(msg_entity)
1243                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1244                                 {
1245                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1246                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1247                                         else
1248                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1249                                 }
1250                         break;
1251                 case VOICETYPE_TAUNT:
1252                         if(self.classname == "player")
1253                                 if(self.deadflag == DEAD_NO)
1254                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1255                         if(!sv_taunt)
1256                                 break;
1257                         if(sv_gentle)
1258                                 break;
1259                         FOR_EACH_REALCLIENT(msg_entity)
1260                         {
1261                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1262                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1263                                 else
1264                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1265                         }
1266                         break;
1267                 case VOICETYPE_PLAYERSOUND:
1268                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1269                         break;
1270                 default:
1271                         backtrace("Invalid voice type!");
1272                         break;
1273         }
1274 }
1275
1276 void PlayerSound(.string samplefield, float chan, float voicetype)
1277 {
1278         GlobalSound(self.samplefield, chan, voicetype);
1279 }
1280
1281 void VoiceMessage(string type, string msg)
1282 {
1283         var .string sample;
1284         float voicetype, ownteam;
1285         float flood;
1286         sample = GetVoiceMessageSampleField(type);
1287
1288         if(GetPlayerSoundSampleField_notFound)
1289         {
1290                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1291                 return;
1292         }
1293
1294         voicetype = GetVoiceMessageVoiceType(type);
1295         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1296
1297         flood = Say(self, ownteam, world, msg, 1);
1298
1299         if (flood > 0)
1300                 GlobalSound(self.sample, CH_VOICE, voicetype);
1301         else if (flood < 0)
1302                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1303 }
1304
1305 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1306 {
1307 //      show_message
1308 //      0 (00) automove centerprint, admin message
1309 //      1 (01) automove centerprint, no admin message
1310 //      2 (10) no centerprint, admin message
1311 //      3 (11) no centerprint, no admin message
1312
1313         float lockteams_backup;
1314
1315         lockteams_backup = lockteams;  // backup any team lock
1316
1317         lockteams = 0;  // disable locked teams
1318
1319         TeamchangeFrags(client);  // move the players frags
1320         SetPlayerColors(client, team_colour - 1);  // set the players colour
1321         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1322
1323         lockteams = lockteams_backup;  // restore the team lock
1324
1325         LogTeamchange(client.playerid, client.team, type);
1326
1327         if not(show_message & 1) // admin message
1328                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1329
1330         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1331 }