qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         return t;
  18 }
  19
  20 void W_SwitchWeapon_Force(entity e, float w)
  21 {
  22         e.cnt = e.switchweapon;
  23         e.switchweapon = w;
  24         e.selectweapon = w;
  25 }
  26
  27 .float antilag_debug;
  28
  29 // VorteX: static frame globals
  30 float WFRAME_DONTCHANGE = -1;
  31 float WFRAME_FIRE1 = 0;
  32 float WFRAME_FIRE2 = 1;
  33 float WFRAME_IDLE = 2;
  34 float WFRAME_RELOAD = 3;
  35 .float wframe;
  36
  37 void(float fr, float t, void() func) weapon_thinkf;
  38
  39 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  40 {
  41         vector ret;
  42         ret_x = screenright * v;
  43         ret_y = screenup * v;
  44         ret_z = screenforward * v;
  45         return ret;
  46 }
  47
  48 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  49 {
  50         float i, j, k;
  51         vector mi, ma, thisv, myv, ret;
  52
  53         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  54
  55         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  56
  57         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  58         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  59         {
  60                 thisv = targ.origin;
  61                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  62                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  63                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  64                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  65                 if(i || j || k)
  66                 {
  67                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  68                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  69                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  70                 }
  71                 else
  72                 {
  73                         // first run
  74                         mi = ma = thisv;
  75                 }
  76         }
  77
  78         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  79         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  80         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  81         ret_z = thisv_z - myv_z;
  82         return ret;
  83 }
  84
  85 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  86 {
  87         vector hitplot;
  88         vector org;
  89         float lag;
  90
  91         if(player.hitplotfh >= 0)
  92         {
  93                 lag = ANTILAG_LATENCY(player);
  94                 if(lag < 0.001)
  95                         lag = 0;
  96                 if(clienttype(player) != CLIENTTYPE_REAL)
  97                         lag = 0; // only antilag for clients
  98
  99                 org = player.origin + player.view_ofs;
 100                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 101                 if(trace_ent.flags & FL_CLIENT)
 102                 {
 103                         antilag_takeback(trace_ent, time - lag);
 104                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 105                         antilag_restore(trace_ent);
 106                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 107                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 108                 }
 109         }
 110 }
 111
 112 vector w_shotorg;
 113 vector w_shotdir;
 114 vector w_shotend;
 115
 116 .float prevstrengthsound;
 117 .float prevstrengthsoundattempt;
 118 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 119 {
 120                 if((!g_minstagib)
 121                         && (player.items & IT_STRENGTH)
 122                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 123                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 124                 {
 125                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 126                         player.prevstrengthsound = time;
 127                 }
 128                 player.prevstrengthsoundattempt = time;
 129 }
 130
 131 // this function calculates w_shotorg and w_shotdir based on the weapon model
 132 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 133 // make sure you call makevectors first (FIXME?)
 134 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 135 {
 136         float nudge = 1; // added to traceline target and subtracted from result
 137         float oldsolid;
 138         vector vecs, dv;
 139         oldsolid = ent.dphitcontentsmask;
 140         if(ent.weapon == WEP_RIFLE)
 141                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 142         else
 143                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 144         if(antilag)
 145                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 146                 // passing world, because we do NOT want it to touch dphitcontentsmask
 147         else
 148                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 149         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 150
 151         vector vf, vr, vu;
 152         vf = v_forward;
 153         vr = v_right;
 154         vu = v_up;
 155         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 156         v_forward = vf;
 157         v_right = vr;
 158         v_up = vu;
 159
 160         // un-adjust trueaim if shotend is too close
 161         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 162                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 163
 164         // track max damage
 165         if(accuracy_canbegooddamage(ent))
 166                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 167
 168         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 169
 170         if(ent.weaponentity.movedir_x > 0)
 171                 vecs = ent.weaponentity.movedir;
 172         else
 173                 vecs = '0 0 0';
 174
 175         dv = v_right * -vecs_y + v_up * vecs_z;
 176         w_shotorg = ent.origin + ent.view_ofs + dv;
 177
 178         // now move the shotorg forward as much as requested if possible
 179         if(antilag)
 180         {
 181                 if(ent.antilag_debug)
 182                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 183                 else
 184                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 185         }
 186         else
 187                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 188         w_shotorg = trace_endpos - v_forward * nudge;
 189         // calculate the shotdir from the chosen shotorg
 190         w_shotdir = normalize(w_shotend - w_shotorg);
 191
 192         if (antilag)
 193         if (!ent.cvar_cl_noantilag)
 194         {
 195                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 196                 {
 197                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 198                         if (!trace_ent.takedamage)
 199                         {
 200                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 201                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 202                                 {
 203                                         entity e;
 204                                         e = trace_ent;
 205                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 206                                         if(trace_ent == e)
 207                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 208                                 }
 209                         }
 210                 }
 211                 else if(autocvar_g_antilag == 3) // client side hitscan
 212                 {
 213                         // this part MUST use prydon cursor
 214                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 215                         if (ent.cursor_trace_ent != ent)         // just to make sure
 216                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 217                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 218                         {
 219                                 // verify that the shot would miss without antilag
 220                                 // (avoids an issue where guns would always shoot at their origin)
 221                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 222                                 if (!trace_ent.takedamage)
 223                                 {
 224                                         // verify that the shot would hit if altered
 225                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 226                                         if (trace_ent == ent.cursor_trace_ent)
 227                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 228                                         else
 229                                                 print("antilag fail\n");
 230                                 }
 231                         }
 232                 }
 233         }
 234
 235         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 236
 237         if (!g_norecoil)
 238                 ent.punchangle_x = recoil * -1;
 239
 240         if (snd != "")
 241         {
 242                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 243                 W_PlayStrengthSound(ent);
 244         }
 245
 246         // nudge w_shotend so a trace to w_shotend hits
 247         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 248 }
 249
 250 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 251 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 252 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 253 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 254 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 255
 256 float CL_Weaponentity_CustomizeEntityForClient()
 257 {
 258         self.viewmodelforclient = self.owner;
 259         if(other.classname == "spectator")
 260                 if(other.enemy == self.owner)
 261                         self.viewmodelforclient = other;
 262         return TRUE;
 263 }
 264
 265 /*
 266  * supported formats:
 267  *
 268  * 1. simple animated model, muzzle flash handling on h_ model:
 269  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 270  *      tags:
 271  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 272  *        shell = casings ejection point (must be on the right hand side of the gun)
 273  *        weapon = attachment for v_tuba.md3
 274  *    v_tuba.md3 - first and third person model
 275  *    g_tuba.md3 - pickup model
 276  *
 277  * 2. simple animated model, muzzle flash handling on v_ model:
 278  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 279  *      tags:
 280  *        weapon = attachment for v_tuba.md3
 281  *    v_tuba.md3 - first and third person model
 282  *      tags:
 283  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 284  *        shell = casings ejection point (must be on the right hand side of the gun)
 285  *    g_tuba.md3 - pickup model
 286  *
 287  * 3. fully animated model, muzzle flash handling on h_ model:
 288  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 289  *      tags:
 290  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 291  *        shell = casings ejection point (must be on the right hand side of the gun)
 292  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 293  *    v_tuba.md3 - third person model
 294  *    g_tuba.md3 - pickup model
 295  *
 296  * 4. fully animated model, muzzle flash handling on v_ model:
 297  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 298  *      tags:
 299  *        shot = muzzle end (shot origin)
 300  *        shell = casings ejection point (must be on the right hand side of the gun)
 301  *    v_tuba.md3 - third person model
 302  *      tags:
 303  *        shot = muzzle end (for muzzle flashes)
 304  *    g_tuba.md3 - pickup model
 305  */
 306
 307 // writes:
 308 //   self.origin, self.angles
 309 //   self.weaponentity
 310 //   self.movedir, self.view_ofs
 311 //   attachment stuff
 312 //   anim stuff
 313 // to free:
 314 //   call again with ""
 315 //   remove the ent
 316 void CL_WeaponEntity_SetModel(string name)
 317 {
 318         float v_shot_idx;
 319         if (name != "")
 320         {
 321                 // if there is a child entity, hide it until we're sure we use it
 322                 if (self.weaponentity)
 323                         self.weaponentity.model = "";
 324                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 325                 v_shot_idx = gettagindex(self, "shot"); // used later
 326                 if(!v_shot_idx)
 327                         v_shot_idx = gettagindex(self, "tag_shot");
 328
 329                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 330                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 331                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 332                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 333                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 334                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 335
 336                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 337                 // if we don't, this is a "real" animated model
 338                 if(gettagindex(self, "weapon"))
 339                 {
 340                         if (!self.weaponentity)
 341                                 self.weaponentity = spawn();
 342                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 343                         setattachment(self.weaponentity, self, "weapon");
 344                 }
 345                 else if(gettagindex(self, "tag_weapon"))
 346                 {
 347                         if (!self.weaponentity)
 348                                 self.weaponentity = spawn();
 349                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 350                         setattachment(self.weaponentity, self, "tag_weapon");
 351                 }
 352                 else
 353                 {
 354                         if(self.weaponentity)
 355                                 remove(self.weaponentity);
 356                         self.weaponentity = world;
 357                 }
 358
 359                 setorigin(self,'0 0 0');
 360                 self.angles = '0 0 0';
 361                 self.frame = 0;
 362                 self.viewmodelforclient = world;
 363
 364                 float idx;
 365
 366                 if(v_shot_idx) // v_ model attached to invisible h_ model
 367                 {
 368                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 369                 }
 370                 else
 371                 {
 372                         idx = gettagindex(self, "shot");
 373                         if(!idx)
 374                                 idx = gettagindex(self, "tag_shot");
 375                         if(idx)
 376                                 self.movedir = gettaginfo(self, idx);
 377                         else
 378                         {
 379                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 380                                 self.movedir = '0 0 0';
 381                         }
 382                 }
 383
 384                 if(self.weaponentity) // v_ model attached to invisible h_ model
 385                 {
 386                         idx = gettagindex(self.weaponentity, "shell");
 387                         if(!idx)
 388                                 idx = gettagindex(self.weaponentity, "tag_shell");
 389                         if(idx)
 390                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 391                 }
 392                 else
 393                         idx = 0;
 394                 if(!idx)
 395                 {
 396                         idx = gettagindex(self, "shell");
 397                         if(!idx)
 398                                 idx = gettagindex(self, "tag_shell");
 399                         if(idx)
 400                                 self.spawnorigin = gettaginfo(self, idx);
 401                         else
 402                         {
 403                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 404                                 self.spawnorigin = self.movedir;
 405                         }
 406                 }
 407
 408                 if(v_shot_idx)
 409                 {
 410                         self.oldorigin = '0 0 0'; // use regular attachment
 411                 }
 412                 else
 413                 {
 414                         if(self.weaponentity)
 415                         {
 416                                 idx = gettagindex(self, "weapon");
 417                                 if(!idx)
 418                                         idx = gettagindex(self, "tag_weapon");
 419                         }
 420                         else
 421                         {
 422                                 idx = gettagindex(self, "handle");
 423                                 if(!idx)
 424                                         idx = gettagindex(self, "tag_handle");
 425                         }
 426                         if(idx)
 427                         {
 428                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 429                         }
 430                         else
 431                         {
 432                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 433                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 434                         }
 435                 }
 436
 437                 self.viewmodelforclient = self.owner;
 438         }
 439         else
 440         {
 441                 self.model = "";
 442                 if(self.weaponentity)
 443                         remove(self.weaponentity);
 444                 self.weaponentity = world;
 445                 self.movedir = '0 0 0';
 446                 self.spawnorigin = '0 0 0';
 447                 self.oldorigin = '0 0 0';
 448                 self.anim_fire1  = '0 1 0.01';
 449                 self.anim_fire2  = '0 1 0.01';
 450                 self.anim_idle   = '0 1 0.01';
 451                 self.anim_reload = '0 1 0.01';
 452         }
 453
 454         self.view_ofs = '0 0 0';
 455
 456         if(self.movedir_x >= 0)
 457         {
 458                 vector v0;
 459                 v0 = self.movedir;
 460                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 461                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 462         }
 463         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 464         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 465
 466         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 467
 468         // check if an instant weapon switch occurred
 469         setorigin(self, self.view_ofs);
 470         // reset animstate now
 471         self.wframe = WFRAME_IDLE;
 472         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 473 }
 474
 475 vector CL_Weapon_GetShotOrg(float wpn)
 476 {
 477         entity wi, oldself;
 478         vector ret;
 479         wi = get_weaponinfo(wpn);
 480         oldself = self;
 481         self = spawn();
 482         CL_WeaponEntity_SetModel(wi.mdl);
 483         ret = self.movedir;
 484         CL_WeaponEntity_SetModel("");
 485         remove(self);
 486         self = oldself;
 487         return ret;
 488 }
 489
 490 void CL_Weaponentity_Think()
 491 {
 492         float tb;
 493         self.nextthink = time;
 494         if (intermission_running)
 495                 self.frame = self.anim_idle_x;
 496         if (self.owner.weaponentity != self)
 497         {
 498                 if (self.weaponentity)
 499                         remove(self.weaponentity);
 500                 remove(self);
 501                 return;
 502         }
 503         if (self.owner.deadflag != DEAD_NO)
 504         {
 505                 self.model = "";
 506                 if (self.weaponentity)
 507                         self.weaponentity.model = "";
 508                 return;
 509         }
 510         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 511         {
 512                 self.weaponname = self.owner.weaponname;
 513                 self.dmg = self.owner.modelindex;
 514                 self.deadflag = self.owner.deadflag;
 515
 516                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 517         }
 518
 519         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 520         self.effects = self.owner.effects & EFMASK_CHEAP;
 521         self.effects &~= EF_LOWPRECISION;
 522         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 523         self.effects &~= EF_TELEPORT_BIT;
 524         self.effects &~= EF_RESTARTANIM_BIT;
 525         self.effects |= tb;
 526
 527         if(self.owner.alpha == default_player_alpha)
 528                 self.alpha = default_weapon_alpha;
 529         else if(self.owner.alpha != 0)
 530                 self.alpha = self.owner.alpha;
 531         else
 532                 self.alpha = 1;
 533
 534         self.glowmod = self.owner.weaponentity_glowmod;
 535         self.colormap = self.owner.colormap;
 536         if (self.weaponentity)
 537         {
 538                 self.weaponentity.effects = self.effects;
 539                 self.weaponentity.alpha = self.alpha;
 540                 self.weaponentity.colormap = self.colormap;
 541                 self.weaponentity.glowmod = self.glowmod;
 542         }
 543
 544         self.angles = '0 0 0';
 545         float f;
 546         if (self.state == WS_RAISE && !intermission_running)
 547         {
 548                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 549                 self.angles_x = -90 * f * f;
 550         }
 551         else if (self.state == WS_DROP && !intermission_running)
 552         {
 553                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 554                 self.angles_x = -90 * f * f;
 555         }
 556         else if (self.state == WS_CLEAR)
 557         {
 558                 f = 1;
 559                 self.angles_x = -90 * f * f;
 560         }
 561 }
 562
 563 void CL_ExteriorWeaponentity_Think()
 564 {
 565         float tag_found;
 566         self.nextthink = time;
 567         if (self.owner.exteriorweaponentity != self)
 568         {
 569                 remove(self);
 570                 return;
 571         }
 572         if (self.owner.deadflag != DEAD_NO)
 573         {
 574                 self.model = "";
 575                 return;
 576         }
 577         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 578         {
 579                 self.weaponname = self.owner.weaponname;
 580                 self.dmg = self.owner.modelindex;
 581                 self.deadflag = self.owner.deadflag;
 582                 if (self.owner.weaponname != "")
 583                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 584                 else
 585                         self.model = "";
 586
 587                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 588                 {
 589                         self.tag_index = tag_found;
 590                         self.tag_entity = self.owner;
 591                 }
 592                 else
 593                         setattachment(self, self.owner, "bip01 r hand");
 594         }
 595         self.effects = self.owner.effects;
 596         self.effects |= EF_LOWPRECISION;
 597         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 598         if(self.owner.alpha == default_player_alpha)
 599                 self.alpha = default_weapon_alpha;
 600         else if(self.owner.alpha != 0)
 601                 self.alpha = self.owner.alpha;
 602         else
 603                 self.alpha = 1;
 604
 605         self.glowmod = self.owner.weaponentity_glowmod;
 606         self.colormap = self.owner.colormap;
 607
 608         CSQCMODEL_AUTOUPDATE();
 609 }
 610
 611 // spawning weaponentity for client
 612 void CL_SpawnWeaponentity()
 613 {
 614         self.weaponentity = spawn();
 615         self.weaponentity.classname = "weaponentity";
 616         self.weaponentity.solid = SOLID_NOT;
 617         self.weaponentity.owner = self;
 618         setmodel(self.weaponentity, ""); // precision set when changed
 619         setorigin(self.weaponentity, '0 0 0');
 620         self.weaponentity.angles = '0 0 0';
 621         self.weaponentity.viewmodelforclient = self;
 622         self.weaponentity.flags = 0;
 623         self.weaponentity.think = CL_Weaponentity_Think;
 624         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 625         self.weaponentity.nextthink = time;
 626
 627         self.exteriorweaponentity = spawn();
 628         self.exteriorweaponentity.classname = "exteriorweaponentity";
 629         self.exteriorweaponentity.solid = SOLID_NOT;
 630         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 631         self.exteriorweaponentity.owner = self;
 632         setorigin(self.exteriorweaponentity, '0 0 0');
 633         self.exteriorweaponentity.angles = '0 0 0';
 634         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 635         self.exteriorweaponentity.nextthink = time;
 636
 637         {
 638                 entity oldself = self;
 639                 self = self.exteriorweaponentity;
 640                 CSQCMODEL_AUTOINIT();
 641                 self = oldself;
 642         }
 643 }
 644
 645 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 646 {
 647         msg_entity = e;
 648         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 649         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 650         WriteByte(MSG_ONE, wpn);
 651         WriteString(MSG_ONE, wpnname);
 652         WriteByte(MSG_ONE, type);
 653 }
 654
 655 .float hasweapon_complain_spam;
 656
 657 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 658 {
 659         float f;
 660         entity oldself;
 661
 662         if(time < self.hasweapon_complain_spam)
 663                 complain = 0;
 664         if(complain)
 665                 self.hasweapon_complain_spam = time + 0.2;
 666
 667         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 668         {
 669                 if (complain)
 670                         sprint(self, "Invalid weapon\n");
 671                 return FALSE;
 672         }
 673         if (WEPSET_CONTAINS_EW(cl, wpn))
 674         {
 675                 if (andammo)
 676                 {
 677                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 678                         {
 679                                 f = 1;
 680                         }
 681                         else
 682                         {
 683                                 oldself = self;
 684                                 self = cl;
 685                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 686                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 687
 688                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 689                                 entity mine;
 690                                 if(wpn == WEP_MINE_LAYER)
 691                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 692                                         f = 1;
 693
 694                                 self = oldself;
 695                         }
 696                         if (!f)
 697                         {
 698                                 if (complain)
 699                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 700                                 {
 701                                         play2(cl, "weapons/unavailable.wav");
 702                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 703                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 704                                 }
 705                                 return FALSE;
 706                         }
 707                 }
 708                 return TRUE;
 709         }
 710         if (complain)
 711         {
 712                 // DRESK - 3/16/07
 713                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 714                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 715                 {
 716                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 717                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 718
 719                         if(autocvar_g_showweaponspawns)
 720                         {
 721                                 entity e;
 722                                 string s;
 723
 724                                 e = get_weaponinfo(wpn);
 725                                 s = e.model2;
 726
 727                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 728                                 {
 729                                         if(e.classname == "droppedweapon")
 730                                                 continue;
 731                                         if not(e.flags & FL_ITEM)
 732                                                 continue;
 733                                         WaypointSprite_Spawn(
 734                                                 s,
 735                                                 1, 0,
 736                                                 world, e.origin,
 737                                                 self, 0,
 738                                                 world, enemy,
 739                                                 0,
 740                                                 RADARICON_NONE, '0 0 0'
 741                                         );
 742                                 }
 743                         }
 744                 }
 745                 else
 746                 {
 747                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 748                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 749                 }
 750
 751                 play2(cl, "weapons/unavailable.wav");
 752         }
 753         return FALSE;
 754 }
 755
 756 // Weapon subs
 757 void w_clear()
 758 {
 759         if (self.weapon != -1)
 760         {
 761                 self.weapon = 0;
 762                 self.switchingweapon = 0;
 763         }
 764         if (self.weaponentity)
 765         {
 766                 self.weaponentity.state = WS_CLEAR;
 767                 self.weaponentity.effects = 0;
 768         }
 769 }
 770
 771 void w_ready()
 772 {
 773         if (self.weaponentity)
 774                 self.weaponentity.state = WS_READY;
 775         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 776 }
 777
 778 // Setup weapon for client (after this raise frame will be launched)
 779 void weapon_setup(float windex)
 780 {
 781         entity e;
 782         e = get_weaponinfo(windex);
 783         self.items &~= IT_AMMO;
 784         self.items = self.items | (e.items & IT_AMMO);
 785
 786         // the two weapon entities will notice this has changed and update their models
 787         self.weapon = windex;
 788         self.switchingweapon = windex; // to make sure
 789         self.weaponname = e.mdl;
 790         self.bulletcounter = 0;
 791 }
 792
 793 // perform weapon to attack (weaponstate and attack_finished check is here)
 794 void W_SwitchToOtherWeapon(entity pl)
 795 {
 796         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 797         float w, ww;
 798         w = pl.weapon;
 799         if(WEPSET_CONTAINS_EW(pl, w))
 800         {
 801                 WEPSET_ANDNOT_EW(pl, w);
 802                 ww = w_getbestweapon(pl);
 803                 WEPSET_OR_EW(pl, w);
 804         }
 805         else
 806                 ww = w_getbestweapon(pl);
 807         if(ww)
 808                 W_SwitchWeapon_Force(pl, ww);
 809 }
 810
 811 string PrimaryOrSecondary(float secondary)
 812 {
 813         if(secondary)
 814                 return "secondary";
 815         else
 816                 return "primary";
 817 }
 818
 819 .float prevdryfire;
 820 .float prevwarntime;
 821 float weapon_prepareattack_checkammo(float secondary)
 822 {
 823         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 824         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 825         {
 826                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 827                 entity mine;
 828                 if(self.weapon == WEP_MINE_LAYER)
 829                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 830                         return FALSE;
 831
 832                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 833                 {
 834                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 835                         self.prevdryfire = time;
 836                 }
 837
 838                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 839                 {
 840                         if(time - self.prevwarntime > 1)
 841                         {
 842                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
 843                         }
 844                         self.prevwarntime = time;
 845                 }
 846                 else // this weapon is totally unable to fire, switch to another one
 847                 {
 848                         W_SwitchToOtherWeapon(self);
 849                 }
 850
 851                 return FALSE;
 852         }
 853         return TRUE;
 854 }
 855 .float race_penalty;
 856 float weapon_prepareattack_check(float secondary, float attacktime)
 857 {
 858         if(!weapon_prepareattack_checkammo(secondary))
 859                 return FALSE;
 860
 861         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 862         //if all players readied up and the countdown is running
 863         if(time < game_starttime || time < self.race_penalty) {
 864                 return FALSE;
 865         }
 866
 867         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 868                 return FALSE;
 869
 870         // do not even think about shooting if switching
 871         if(self.switchweapon != self.weapon)
 872                 return FALSE;
 873
 874         if(attacktime >= 0)
 875         {
 876                 // don't fire if previous attack is not finished
 877                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 878                         return FALSE;
 879                 // don't fire while changing weapon
 880                 if (self.weaponentity.state != WS_READY)
 881                         return FALSE;
 882         }
 883
 884         return TRUE;
 885 }
 886 float weapon_prepareattack_do(float secondary, float attacktime)
 887 {
 888         self.weaponentity.state = WS_INUSE;
 889
 890         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 891
 892         // if the weapon hasn't been firing continuously, reset the timer
 893         if(attacktime >= 0)
 894         {
 895                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 896                 {
 897                         ATTACK_FINISHED(self) = time;
 898                         //dprint("resetting attack finished to ", ftos(time), "\n");
 899                 }
 900                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 901         }
 902         self.bulletcounter += 1;
 903         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 904         return TRUE;
 905 }
 906 float weapon_prepareattack(float secondary, float attacktime)
 907 {
 908         if(weapon_prepareattack_check(secondary, attacktime))
 909         {
 910                 weapon_prepareattack_do(secondary, attacktime);
 911                 return TRUE;
 912         }
 913         else
 914                 return FALSE;
 915 }
 916
 917 void weapon_thinkf(float fr, float t, void() func)
 918 {
 919         vector a;
 920         vector of, or, ou;
 921         float restartanim;
 922
 923         if(fr == WFRAME_DONTCHANGE)
 924         {
 925                 fr = self.weaponentity.wframe;
 926                 restartanim = FALSE;
 927         }
 928         else if (fr == WFRAME_IDLE)
 929                 restartanim = FALSE;
 930         else
 931                 restartanim = TRUE;
 932
 933         of = v_forward;
 934         or = v_right;
 935         ou = v_up;
 936
 937         if (self.weaponentity)
 938         {
 939                 self.weaponentity.wframe = fr;
 940                 a = '0 0 0';
 941                 if (fr == WFRAME_IDLE)
 942                         a = self.weaponentity.anim_idle;
 943                 else if (fr == WFRAME_FIRE1)
 944                         a = self.weaponentity.anim_fire1;
 945                 else if (fr == WFRAME_FIRE2)
 946                         a = self.weaponentity.anim_fire2;
 947                 else // if (fr == WFRAME_RELOAD)
 948                         a = self.weaponentity.anim_reload;
 949                 a_z *= g_weaponratefactor;
 950                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 951         }
 952
 953         v_forward = of;
 954         v_right = or;
 955         v_up = ou;
 956
 957         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 958         {
 959                 backtrace("Tried to override initial weapon think function - should this really happen?");
 960         }
 961
 962         t *= W_WeaponRateFactor();
 963
 964         // VorteX: haste can be added here
 965         if (self.weapon_think == w_ready)
 966         {
 967                 self.weapon_nextthink = time;
 968                 //dprint("started firing at ", ftos(time), "\n");
 969         }
 970         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 971         {
 972                 self.weapon_nextthink = time;
 973                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 974         }
 975         self.weapon_nextthink = self.weapon_nextthink + t;
 976         self.weapon_think = func;
 977         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 978
 979         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 980         {
 981                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 982                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 983                 else
 984                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 985         }
 986         else
 987         {
 988                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
 989                         self.anim_upper_action = 0;
 990         }
 991 }
 992
 993 void weapon_boblayer1(float spd, vector org)
 994 {
 995         // VorteX: haste can be added here
 996 }
 997
 998 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 999 {
1000         vector mdirection;
1001         float mspeed;
1002         vector outvelocity;
1003
1004         mvelocity = mvelocity * g_weaponspeedfactor;
1005
1006         mdirection = normalize(mvelocity);
1007         mspeed = vlen(mvelocity);
1008
1009         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1010
1011         return outvelocity;
1012 }
1013
1014 void W_AttachToShotorg(entity flash, vector offset)
1015 {
1016         entity xflash;
1017         flash.owner = self;
1018         flash.angles_z = random() * 360;
1019
1020         if(gettagindex(self.weaponentity, "shot"))
1021                 setattachment(flash, self.weaponentity, "shot");
1022         else
1023                 setattachment(flash, self.weaponentity, "tag_shot");
1024         setorigin(flash, offset);
1025
1026         xflash = spawn();
1027         copyentity(flash, xflash);
1028
1029         flash.viewmodelforclient = self;
1030
1031         if(self.weaponentity.oldorigin_x > 0)
1032         {
1033                 setattachment(xflash, self.exteriorweaponentity, "");
1034                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1035         }
1036         else
1037         {
1038                 if(gettagindex(self.exteriorweaponentity, "shot"))
1039                         setattachment(xflash, self.exteriorweaponentity, "shot");
1040                 else
1041                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1042                 setorigin(xflash, offset);
1043         }
1044 }
1045
1046 vector cliptoplane(vector v, vector p)
1047 {
1048         return v - (v * p) * p;
1049 }
1050
1051 vector solve_cubic_pq(float p, float q)
1052 {
1053         float D, u, v, a;
1054         D = q*q/4.0 + p*p*p/27.0;
1055         if(D < 0)
1056         {
1057                 // irreducibilis
1058                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1059                 u = sqrt(-4.0/3.0 * p);
1060                 // a in range 0..pi/3
1061                 // cos(a)
1062                 // cos(a + 2pi/3)
1063                 // cos(a + 4pi/3)
1064                 return
1065                         u *
1066                         (
1067                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1068                                 +
1069                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1070                                 +
1071                                 '0 0 1' * cos(a)
1072                         );
1073         }
1074         else if(D == 0)
1075         {
1076                 // simple
1077                 if(p == 0)
1078                         return '0 0 0';
1079                 u = 3*q/p;
1080                 v = -u/2;
1081                 if(u >= v)
1082                         return '1 1 0' * v + '0 0 1' * u;
1083                 else
1084                         return '0 1 1' * v + '1 0 0' * u;
1085         }
1086         else
1087         {
1088                 // cardano
1089                 u = cbrt(-q/2.0 + sqrt(D));
1090                 v = cbrt(-q/2.0 - sqrt(D));
1091                 return '1 1 1' * (u + v);
1092         }
1093 }
1094 vector solve_cubic_abcd(float a, float b, float c, float d)
1095 {
1096         // y = 3*a*x + b
1097         // x = (y - b) / 3a
1098         float p, q;
1099         vector v;
1100         p = (9*a*c - 3*b*b);
1101         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1102         v = solve_cubic_pq(p, q);
1103         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1104         if(a < 0)
1105                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1106         return v;
1107 }
1108
1109 vector findperpendicular(vector v)
1110 {
1111         vector p;
1112         p_x = v_z;
1113         p_y = -v_x;
1114         p_z = v_y;
1115         return normalize(cliptoplane(p, v));
1116 }
1117
1118 vector W_CalculateProjectileSpread(vector forward, float spread)
1119 {
1120         float sigma;
1121         vector v1 = '0 0 0', v2;
1122         float dx, dy, r;
1123         float sstyle;
1124         spread *= g_weaponspreadfactor;
1125         if(spread <= 0)
1126                 return forward;
1127         sstyle = autocvar_g_projectiles_spread_style;
1128
1129         if(sstyle == 0)
1130         {
1131                 // this is the baseline for the spread value!
1132                 // standard deviation: sqrt(2/5)
1133                 // density function: sqrt(1-r^2)
1134                 return forward + randomvec() * spread;
1135         }
1136         else if(sstyle == 1)
1137         {
1138                 // same thing, basically
1139                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1140         }
1141         else if(sstyle == 2)
1142         {
1143                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1144                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1145                 v1 = findperpendicular(forward);
1146                 v2 = cross(forward, v1);
1147                 // random point on unit circle
1148                 dx = random() * 2 * M_PI;
1149                 dy = sin(dx);
1150                 dx = cos(dx);
1151                 // radius in our dist function
1152                 r = random();
1153                 r = sqrt(r);
1154                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1155         }
1156         else if(sstyle == 3) // gauss 3d
1157         {
1158                 sigma = spread * 0.44721359549996; // match baseline stddev
1159                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1160                 v1 = forward;
1161                 v1_x += gsl_ran_gaussian(sigma);
1162                 v1_y += gsl_ran_gaussian(sigma);
1163                 v1_z += gsl_ran_gaussian(sigma);
1164                 return v1;
1165         }
1166         else if(sstyle == 4) // gauss 2d
1167         {
1168                 sigma = spread * 0.44721359549996; // match baseline stddev
1169                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1170                 v1_x = gsl_ran_gaussian(sigma);
1171                 v1_y = gsl_ran_gaussian(sigma);
1172                 v1_z = gsl_ran_gaussian(sigma);
1173                 return normalize(forward + cliptoplane(v1, forward));
1174         }
1175         else if(sstyle == 5) // 1-r
1176         {
1177                 sigma = spread * 1.154700538379252; // match baseline stddev
1178                 v1 = findperpendicular(forward);
1179                 v2 = cross(forward, v1);
1180                 // random point on unit circle
1181                 dx = random() * 2 * M_PI;
1182                 dy = sin(dx);
1183                 dx = cos(dx);
1184                 // radius in our dist function
1185                 r = random();
1186                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1187                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1188         }
1189         else if(sstyle == 6) // 1-r^2
1190         {
1191                 sigma = spread * 1.095445115010332; // match baseline stddev
1192                 v1 = findperpendicular(forward);
1193                 v2 = cross(forward, v1);
1194                 // random point on unit circle
1195                 dx = random() * 2 * M_PI;
1196                 dy = sin(dx);
1197                 dx = cos(dx);
1198                 // radius in our dist function
1199                 r = random();
1200                 r = sqrt(1 - r);
1201                 r = sqrt(1 - r);
1202                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1203         }
1204         else if(sstyle == 7) // (1-r) (2-r)
1205         {
1206                 sigma = spread * 1.224744871391589; // match baseline stddev
1207                 v1 = findperpendicular(forward);
1208                 v2 = cross(forward, v1);
1209                 // random point on unit circle
1210                 dx = random() * 2 * M_PI;
1211                 dy = sin(dx);
1212                 dx = cos(dx);
1213                 // radius in our dist function
1214                 r = random();
1215                 r = 1 - sqrt(r);
1216                 r = 1 - sqrt(r);
1217                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1218         }
1219         else
1220                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1221         return '0 0 0';
1222         /*
1223          * how to derive falloff functions:
1224          * rho(r) := (2-r) * (1-r);
1225          * a : 0;
1226          * b : 1;
1227          * rhor(r) := r * rho(r);
1228          * cr(t) := integrate(rhor(r), r, a, t);
1229          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1230          * variance : scr(b) / cr(b);
1231          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1232          * sqrt(0.4 / variance), numer;
1233          */
1234 }
1235
1236 #if 0
1237 float mspercallsum;
1238 float mspercallsstyle;
1239 float mspercallcount;
1240 #endif
1241 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1242 {
1243         if(missile.owner == world)
1244                 error("Unowned missile");
1245
1246         dir = dir + upDir * (pUpSpeed / pSpeed);
1247         dir_z += pZSpeed / pSpeed;
1248         pSpeed *= vlen(dir);
1249         dir = normalize(dir);
1250
1251 #if 0
1252         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1253         {
1254                 mspercallsum = mspercallcount = 0;
1255                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1256         }
1257         mspercallsum -= gettime(GETTIME_HIRES);
1258 #endif
1259         dir = W_CalculateProjectileSpread(dir, spread);
1260 #if 0
1261         mspercallsum += gettime(GETTIME_HIRES);
1262         mspercallcount += 1;
1263         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1264 #endif
1265
1266         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1267 }
1268
1269 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1270 {
1271         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1272 }
1273
1274 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1275 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1276
1277 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1278 {
1279         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1280                 return;
1281
1282         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1283         if(ammo_reload)
1284         {
1285                 self.clip_load -= ammo_use;
1286                 self.(weapon_load[self.weapon]) = self.clip_load;
1287         }
1288         else
1289                 self.(self.current_ammo) -= ammo_use;
1290 }
1291
1292 // weapon reloading code
1293
1294 .float reload_ammo_amount, reload_ammo_min, reload_time;
1295 .float reload_complain;
1296 .string reload_sound;
1297
1298 void W_ReloadedAndReady()
1299 {
1300         // finish the reloading process, and do the ammo transfer
1301
1302         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1303
1304         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1305         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1306                 self.clip_load = self.reload_ammo_amount;
1307         else
1308         {
1309                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1310                 {
1311                         self.clip_load += 1;
1312                         self.(self.current_ammo) -= 1;
1313                 }
1314         }
1315         self.(weapon_load[self.weapon]) = self.clip_load;
1316
1317         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1318         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1319         // so your weapon is disabled for a few seconds without reason
1320
1321         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1322
1323         w_ready();
1324 }
1325
1326 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1327 {
1328         // set global values to work with
1329
1330         self.reload_ammo_min = sent_ammo_min;
1331         self.reload_ammo_amount = sent_ammo_amount;
1332         self.reload_time = sent_time;
1333         self.reload_sound = sent_sound;
1334
1335         // check if we meet the necessary conditions to reload
1336
1337         entity e;
1338         e = get_weaponinfo(self.weapon);
1339
1340         // don't reload weapons that don't have the RELOADABLE flag
1341         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1342         {
1343                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1344                 return;
1345         }
1346
1347         // return if reloading is disabled for this weapon
1348         if(!self.reload_ammo_amount)
1349                 return;
1350
1351         // our weapon is fully loaded, no need to reload
1352         if (self.clip_load >= self.reload_ammo_amount)
1353                 return;
1354
1355         // no ammo, so nothing to load
1356         if(!self.(self.current_ammo) && self.reload_ammo_min)
1357         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1358         {
1359                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1360                 {
1361                         play2(self, "weapons/unavailable.wav");
1362                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1363                         self.reload_complain = time + 1;
1364                 }
1365                 // switch away if the amount of ammo is not enough to keep using this weapon
1366                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1367                 {
1368                         self.clip_load = -1; // reload later
1369                         W_SwitchToOtherWeapon(self);
1370                 }
1371                 return;
1372         }
1373
1374         if (self.weaponentity)
1375         {
1376                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1377                         return;
1378
1379                 // allow switching away while reloading, but this will cause a new reload!
1380                 self.weaponentity.state = WS_READY;
1381         }
1382
1383         // now begin the reloading process
1384
1385         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1386
1387         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1388         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1389         // so your weapon is disabled for a few seconds without reason
1390
1391         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1392
1393         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1394
1395         if(self.clip_load < 0)
1396                 self.clip_load = 0;
1397         self.old_clip_load = self.clip_load;
1398         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1399 }