qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         return t;
  18 }
  19
  20 void W_SwitchWeapon_Force(entity e, float w)
  21 {
  22         e.cnt = e.switchweapon;
  23         e.switchweapon = w;
  24         e.selectweapon = w;
  25 }
  26
  27 .float antilag_debug;
  28
  29 // VorteX: static frame globals
  30 float WFRAME_DONTCHANGE = -1;
  31 float WFRAME_FIRE1 = 0;
  32 float WFRAME_FIRE2 = 1;
  33 float WFRAME_IDLE = 2;
  34 float WFRAME_RELOAD = 3;
  35 .float wframe;
  36
  37 void(float fr, float t, void() func) weapon_thinkf;
  38
  39 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  40 {
  41         vector ret;
  42         ret_x = screenright * v;
  43         ret_y = screenup * v;
  44         ret_z = screenforward * v;
  45         return ret;
  46 }
  47
  48 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  49 {
  50         float i, j, k;
  51         vector mi, ma, thisv, myv, ret;
  52
  53         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  54
  55         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  56
  57         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  58         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  59         {
  60                 thisv = targ.origin;
  61                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  62                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  63                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  64                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  65                 if(i || j || k)
  66                 {
  67                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  68                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  69                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  70                 }
  71                 else
  72                 {
  73                         // first run
  74                         mi = ma = thisv;
  75                 }
  76         }
  77
  78         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  79         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  80         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  81         ret_z = thisv_z - myv_z;
  82         return ret;
  83 }
  84
  85 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  86 {
  87         vector hitplot;
  88         vector org;
  89         float lag;
  90
  91         if(player.hitplotfh >= 0)
  92         {
  93                 lag = ANTILAG_LATENCY(player);
  94                 if(lag < 0.001)
  95                         lag = 0;
  96                 if not(IS_REAL_CLIENT(player))
  97                         lag = 0; // only antilag for clients
  98
  99                 org = player.origin + player.view_ofs;
 100                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 101                 if(IS_CLIENT(trace_ent))
 102                 {
 103                         antilag_takeback(trace_ent, time - lag);
 104                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 105                         antilag_restore(trace_ent);
 106                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 107                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 108                 }
 109         }
 110 }
 111
 112 vector w_shotorg;
 113 vector w_shotdir;
 114 vector w_shotend;
 115
 116 .float prevstrengthsound;
 117 .float prevstrengthsoundattempt;
 118 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 119 {
 120         if((player.items & IT_STRENGTH)
 121                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 122                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 123                 {
 124                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 125                         player.prevstrengthsound = time;
 126                 }
 127                 player.prevstrengthsoundattempt = time;
 128 }
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 134 {
 135         float nudge = 1; // added to traceline target and subtracted from result
 136         float oldsolid;
 137         vector vecs, dv;
 138         oldsolid = ent.dphitcontentsmask;
 139         if(ent.weapon == WEP_RIFLE)
 140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 141         else
 142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         if(antilag)
 144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 145                 // passing world, because we do NOT want it to touch dphitcontentsmask
 146         else
 147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149
 150         vector vf, vr, vu;
 151         vf = v_forward;
 152         vr = v_right;
 153         vu = v_up;
 154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 155         v_forward = vf;
 156         v_right = vr;
 157         v_up = vu;
 158
 159         // un-adjust trueaim if shotend is too close
 160         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 161                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 162
 163         // track max damage
 164         if(accuracy_canbegooddamage(ent))
 165                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 166
 167         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 168
 169         if(ent.weaponentity.movedir_x > 0)
 170                 vecs = ent.weaponentity.movedir;
 171         else
 172                 vecs = '0 0 0';
 173
 174         dv = v_right * -vecs_y + v_up * vecs_z;
 175         w_shotorg = ent.origin + ent.view_ofs + dv;
 176
 177         // now move the shotorg forward as much as requested if possible
 178         if(antilag)
 179         {
 180                 if(ent.antilag_debug)
 181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 182                 else
 183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 184         }
 185         else
 186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 187         w_shotorg = trace_endpos - v_forward * nudge;
 188         // calculate the shotdir from the chosen shotorg
 189         w_shotdir = normalize(w_shotend - w_shotorg);
 190
 191         if (antilag)
 192         if (!ent.cvar_cl_noantilag)
 193         {
 194                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 195                 {
 196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 197                         if (!trace_ent.takedamage)
 198                         {
 199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 201                                 {
 202                                         entity e;
 203                                         e = trace_ent;
 204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 205                                         if(trace_ent == e)
 206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 207                                 }
 208                         }
 209                 }
 210                 else if(autocvar_g_antilag == 3) // client side hitscan
 211                 {
 212                         // this part MUST use prydon cursor
 213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 214                         if (ent.cursor_trace_ent != ent)         // just to make sure
 215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 216                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 217                         {
 218                                 // verify that the shot would miss without antilag
 219                                 // (avoids an issue where guns would always shoot at their origin)
 220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 221                                 if (!trace_ent.takedamage)
 222                                 {
 223                                         // verify that the shot would hit if altered
 224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 225                                         if (trace_ent == ent.cursor_trace_ent)
 226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 227                                         else
 228                                                 print("antilag fail\n");
 229                                 }
 230                         }
 231                 }
 232         }
 233
 234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 235
 236         if (!g_norecoil)
 237                 ent.punchangle_x = recoil * -1;
 238
 239         if (snd != "")
 240         {
 241                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 242                 W_PlayStrengthSound(ent);
 243         }
 244
 245         // nudge w_shotend so a trace to w_shotend hits
 246         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 247 }
 248
 249 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 250 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 251 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 252 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 253 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 254
 255 float CL_Weaponentity_CustomizeEntityForClient()
 256 {
 257         self.viewmodelforclient = self.owner;
 258         if(IS_SPEC(other))
 259                 if(other.enemy == self.owner)
 260                         self.viewmodelforclient = other;
 261         return TRUE;
 262 }
 263
 264 /*
 265  * supported formats:
 266  *
 267  * 1. simple animated model, muzzle flash handling on h_ model:
 268  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 269  *      tags:
 270  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 271  *        shell = casings ejection point (must be on the right hand side of the gun)
 272  *        weapon = attachment for v_tuba.md3
 273  *    v_tuba.md3 - first and third person model
 274  *    g_tuba.md3 - pickup model
 275  *
 276  * 2. simple animated model, muzzle flash handling on v_ model:
 277  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 278  *      tags:
 279  *        weapon = attachment for v_tuba.md3
 280  *    v_tuba.md3 - first and third person model
 281  *      tags:
 282  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 283  *        shell = casings ejection point (must be on the right hand side of the gun)
 284  *    g_tuba.md3 - pickup model
 285  *
 286  * 3. fully animated model, muzzle flash handling on h_ model:
 287  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 288  *      tags:
 289  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 290  *        shell = casings ejection point (must be on the right hand side of the gun)
 291  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 292  *    v_tuba.md3 - third person model
 293  *    g_tuba.md3 - pickup model
 294  *
 295  * 4. fully animated model, muzzle flash handling on v_ model:
 296  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 297  *      tags:
 298  *        shot = muzzle end (shot origin)
 299  *        shell = casings ejection point (must be on the right hand side of the gun)
 300  *    v_tuba.md3 - third person model
 301  *      tags:
 302  *        shot = muzzle end (for muzzle flashes)
 303  *    g_tuba.md3 - pickup model
 304  */
 305
 306 // writes:
 307 //   self.origin, self.angles
 308 //   self.weaponentity
 309 //   self.movedir, self.view_ofs
 310 //   attachment stuff
 311 //   anim stuff
 312 // to free:
 313 //   call again with ""
 314 //   remove the ent
 315 void CL_WeaponEntity_SetModel(string name)
 316 {
 317         float v_shot_idx;
 318         if (name != "")
 319         {
 320                 // if there is a child entity, hide it until we're sure we use it
 321                 if (self.weaponentity)
 322                         self.weaponentity.model = "";
 323                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 324                 v_shot_idx = gettagindex(self, "shot"); // used later
 325                 if(!v_shot_idx)
 326                         v_shot_idx = gettagindex(self, "tag_shot");
 327
 328                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 329                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 330                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 331                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 332                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 333                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 334
 335                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 336                 // if we don't, this is a "real" animated model
 337                 if(gettagindex(self, "weapon"))
 338                 {
 339                         if (!self.weaponentity)
 340                                 self.weaponentity = spawn();
 341                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 342                         setattachment(self.weaponentity, self, "weapon");
 343                 }
 344                 else if(gettagindex(self, "tag_weapon"))
 345                 {
 346                         if (!self.weaponentity)
 347                                 self.weaponentity = spawn();
 348                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 349                         setattachment(self.weaponentity, self, "tag_weapon");
 350                 }
 351                 else
 352                 {
 353                         if(self.weaponentity)
 354                                 remove(self.weaponentity);
 355                         self.weaponentity = world;
 356                 }
 357
 358                 setorigin(self,'0 0 0');
 359                 self.angles = '0 0 0';
 360                 self.frame = 0;
 361                 self.viewmodelforclient = world;
 362
 363                 float idx;
 364
 365                 if(v_shot_idx) // v_ model attached to invisible h_ model
 366                 {
 367                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 368                 }
 369                 else
 370                 {
 371                         idx = gettagindex(self, "shot");
 372                         if(!idx)
 373                                 idx = gettagindex(self, "tag_shot");
 374                         if(idx)
 375                                 self.movedir = gettaginfo(self, idx);
 376                         else
 377                         {
 378                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 379                                 self.movedir = '0 0 0';
 380                         }
 381                 }
 382
 383                 if(self.weaponentity) // v_ model attached to invisible h_ model
 384                 {
 385                         idx = gettagindex(self.weaponentity, "shell");
 386                         if(!idx)
 387                                 idx = gettagindex(self.weaponentity, "tag_shell");
 388                         if(idx)
 389                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 390                 }
 391                 else
 392                         idx = 0;
 393                 if(!idx)
 394                 {
 395                         idx = gettagindex(self, "shell");
 396                         if(!idx)
 397                                 idx = gettagindex(self, "tag_shell");
 398                         if(idx)
 399                                 self.spawnorigin = gettaginfo(self, idx);
 400                         else
 401                         {
 402                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 403                                 self.spawnorigin = self.movedir;
 404                         }
 405                 }
 406
 407                 if(v_shot_idx)
 408                 {
 409                         self.oldorigin = '0 0 0'; // use regular attachment
 410                 }
 411                 else
 412                 {
 413                         if(self.weaponentity)
 414                         {
 415                                 idx = gettagindex(self, "weapon");
 416                                 if(!idx)
 417                                         idx = gettagindex(self, "tag_weapon");
 418                         }
 419                         else
 420                         {
 421                                 idx = gettagindex(self, "handle");
 422                                 if(!idx)
 423                                         idx = gettagindex(self, "tag_handle");
 424                         }
 425                         if(idx)
 426                         {
 427                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 428                         }
 429                         else
 430                         {
 431                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 432                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 433                         }
 434                 }
 435
 436                 self.viewmodelforclient = self.owner;
 437         }
 438         else
 439         {
 440                 self.model = "";
 441                 if(self.weaponentity)
 442                         remove(self.weaponentity);
 443                 self.weaponentity = world;
 444                 self.movedir = '0 0 0';
 445                 self.spawnorigin = '0 0 0';
 446                 self.oldorigin = '0 0 0';
 447                 self.anim_fire1  = '0 1 0.01';
 448                 self.anim_fire2  = '0 1 0.01';
 449                 self.anim_idle   = '0 1 0.01';
 450                 self.anim_reload = '0 1 0.01';
 451         }
 452
 453         self.view_ofs = '0 0 0';
 454
 455         if(self.movedir_x >= 0)
 456         {
 457                 vector v0;
 458                 v0 = self.movedir;
 459                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 460                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 461         }
 462         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 463         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 464
 465         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 466
 467         // check if an instant weapon switch occurred
 468         setorigin(self, self.view_ofs);
 469         // reset animstate now
 470         self.wframe = WFRAME_IDLE;
 471         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 472 }
 473
 474 vector CL_Weapon_GetShotOrg(float wpn)
 475 {
 476         entity wi, oldself;
 477         vector ret;
 478         wi = get_weaponinfo(wpn);
 479         oldself = self;
 480         self = spawn();
 481         CL_WeaponEntity_SetModel(wi.mdl);
 482         ret = self.movedir;
 483         CL_WeaponEntity_SetModel("");
 484         remove(self);
 485         self = oldself;
 486         return ret;
 487 }
 488
 489 void CL_Weaponentity_Think()
 490 {
 491         float tb;
 492         self.nextthink = time;
 493         if (intermission_running)
 494                 self.frame = self.anim_idle_x;
 495         if (self.owner.weaponentity != self)
 496         {
 497                 if (self.weaponentity)
 498                         remove(self.weaponentity);
 499                 remove(self);
 500                 return;
 501         }
 502         if (self.owner.deadflag != DEAD_NO)
 503         {
 504                 self.model = "";
 505                 if (self.weaponentity)
 506                         self.weaponentity.model = "";
 507                 return;
 508         }
 509         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 510         {
 511                 self.weaponname = self.owner.weaponname;
 512                 self.dmg = self.owner.modelindex;
 513                 self.deadflag = self.owner.deadflag;
 514
 515                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 516         }
 517
 518         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 519         self.effects = self.owner.effects & EFMASK_CHEAP;
 520         self.effects &~= EF_LOWPRECISION;
 521         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 522         self.effects &~= EF_TELEPORT_BIT;
 523         self.effects &~= EF_RESTARTANIM_BIT;
 524         self.effects |= tb;
 525
 526         if(self.owner.alpha == default_player_alpha)
 527                 self.alpha = default_weapon_alpha;
 528         else if(self.owner.alpha != 0)
 529                 self.alpha = self.owner.alpha;
 530         else
 531                 self.alpha = 1;
 532
 533         self.glowmod = self.owner.weaponentity_glowmod;
 534         self.colormap = self.owner.colormap;
 535         if (self.weaponentity)
 536         {
 537                 self.weaponentity.effects = self.effects;
 538                 self.weaponentity.alpha = self.alpha;
 539                 self.weaponentity.colormap = self.colormap;
 540                 self.weaponentity.glowmod = self.glowmod;
 541         }
 542
 543         self.angles = '0 0 0';
 544
 545         float f;
 546         if (self.state == WS_RAISE && !intermission_running)
 547         {
 548                 entity newwep = get_weaponinfo(self.owner.switchweapon);
 549                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname));
 550                 self.angles_x = -90 * f * f;
 551         }
 552         else if (self.state == WS_DROP && !intermission_running)
 553         {
 554                 entity oldwep = get_weaponinfo(self.owner.weapon);
 555                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname));
 556                 self.angles_x = -90 * f * f;
 557         }
 558         else if (self.state == WS_CLEAR)
 559         {
 560                 f = 1;
 561                 self.angles_x = -90 * f * f;
 562         }
 563 }
 564
 565 void CL_ExteriorWeaponentity_Think()
 566 {
 567         float tag_found;
 568         self.nextthink = time;
 569         if (self.owner.exteriorweaponentity != self)
 570         {
 571                 remove(self);
 572                 return;
 573         }
 574         if (self.owner.deadflag != DEAD_NO)
 575         {
 576                 self.model = "";
 577                 return;
 578         }
 579         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 580         {
 581                 self.weaponname = self.owner.weaponname;
 582                 self.dmg = self.owner.modelindex;
 583                 self.deadflag = self.owner.deadflag;
 584                 if (self.owner.weaponname != "")
 585                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 586                 else
 587                         self.model = "";
 588
 589                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 590                 {
 591                         self.tag_index = tag_found;
 592                         self.tag_entity = self.owner;
 593                 }
 594                 else
 595                         setattachment(self, self.owner, "bip01 r hand");
 596         }
 597         self.effects = self.owner.effects;
 598         self.effects |= EF_LOWPRECISION;
 599         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 600         if(self.owner.alpha == default_player_alpha)
 601                 self.alpha = default_weapon_alpha;
 602         else if(self.owner.alpha != 0)
 603                 self.alpha = self.owner.alpha;
 604         else
 605                 self.alpha = 1;
 606
 607         self.glowmod = self.owner.weaponentity_glowmod;
 608         self.colormap = self.owner.colormap;
 609
 610         CSQCMODEL_AUTOUPDATE();
 611 }
 612
 613 // spawning weaponentity for client
 614 void CL_SpawnWeaponentity()
 615 {
 616         self.weaponentity = spawn();
 617         self.weaponentity.classname = "weaponentity";
 618         self.weaponentity.solid = SOLID_NOT;
 619         self.weaponentity.owner = self;
 620         setmodel(self.weaponentity, ""); // precision set when changed
 621         setorigin(self.weaponentity, '0 0 0');
 622         self.weaponentity.angles = '0 0 0';
 623         self.weaponentity.viewmodelforclient = self;
 624         self.weaponentity.flags = 0;
 625         self.weaponentity.think = CL_Weaponentity_Think;
 626         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 627         self.weaponentity.nextthink = time;
 628
 629         self.exteriorweaponentity = spawn();
 630         self.exteriorweaponentity.classname = "exteriorweaponentity";
 631         self.exteriorweaponentity.solid = SOLID_NOT;
 632         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 633         self.exteriorweaponentity.owner = self;
 634         setorigin(self.exteriorweaponentity, '0 0 0');
 635         self.exteriorweaponentity.angles = '0 0 0';
 636         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 637         self.exteriorweaponentity.nextthink = time;
 638
 639         {
 640                 entity oldself = self;
 641                 self = self.exteriorweaponentity;
 642                 CSQCMODEL_AUTOINIT();
 643                 self = oldself;
 644         }
 645 }
 646
 647 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 648 {
 649         msg_entity = e;
 650         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 651         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 652         WriteByte(MSG_ONE, wpn);
 653         WriteString(MSG_ONE, wpnname);
 654         WriteByte(MSG_ONE, type);
 655 }
 656
 657 .float hasweapon_complain_spam;
 658
 659 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 660 {
 661         float f;
 662         entity oldself;
 663
 664         if(time < self.hasweapon_complain_spam)
 665                 complain = 0;
 666         if(complain)
 667                 self.hasweapon_complain_spam = time + 0.2;
 668
 669         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 670         {
 671                 if (complain)
 672                         sprint(self, "Invalid weapon\n");
 673                 return FALSE;
 674         }
 675         if (WEPSET_CONTAINS_EW(cl, wpn))
 676         {
 677                 if (andammo)
 678                 {
 679                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 680                         {
 681                                 f = 1;
 682                         }
 683                         else
 684                         {
 685                                 oldself = self;
 686                                 self = cl;
 687                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 688                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 689
 690                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 691                                 entity mine;
 692                                 if(wpn == WEP_MINE_LAYER)
 693                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 694                                         f = 1;
 695
 696                                 self = oldself;
 697                         }
 698                         if (!f)
 699                         {
 700                                 if (complain)
 701                                 if(IS_REAL_CLIENT(cl))
 702                                 {
 703                                         play2(cl, "weapons/unavailable.wav");
 704                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 705                                 }
 706                                 return FALSE;
 707                         }
 708                 }
 709                 return TRUE;
 710         }
 711         if (complain)
 712         {
 713                 // DRESK - 3/16/07
 714                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 715                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 716                 {
 717                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
 718
 719                         if(autocvar_g_showweaponspawns)
 720                         {
 721                                 entity e;
 722                                 string s;
 723
 724                                 e = get_weaponinfo(wpn);
 725                                 s = e.model2;
 726
 727                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 728                                 {
 729                                         if(e.classname == "droppedweapon")
 730                                                 continue;
 731                                         if not(e.flags & FL_ITEM)
 732                                                 continue;
 733                                         WaypointSprite_Spawn(
 734                                                 s,
 735                                                 1, 0,
 736                                                 world, e.origin,
 737                                                 self, 0,
 738                                                 world, enemy,
 739                                                 0,
 740                                                 RADARICON_NONE, '0 0 0'
 741                                         );
 742                                 }
 743                         }
 744                 }
 745                 else
 746                 {
 747                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 748                 }
 749
 750                 play2(cl, "weapons/unavailable.wav");
 751         }
 752         return FALSE;
 753 }
 754
 755 // Weapon subs
 756 void w_clear()
 757 {
 758         if (self.weapon != -1)
 759         {
 760                 self.weapon = 0;
 761                 self.switchingweapon = 0;
 762         }
 763         if (self.weaponentity)
 764         {
 765                 self.weaponentity.state = WS_CLEAR;
 766                 self.weaponentity.effects = 0;
 767         }
 768 }
 769
 770 void w_ready()
 771 {
 772         if (self.weaponentity)
 773                 self.weaponentity.state = WS_READY;
 774         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 775 }
 776
 777 // Setup weapon for client (after this raise frame will be launched)
 778 void weapon_setup(float windex)
 779 {
 780         entity e;
 781         e = get_weaponinfo(windex);
 782         self.items &~= IT_AMMO;
 783         self.items = self.items | (e.items & IT_AMMO);
 784
 785         // the two weapon entities will notice this has changed and update their models
 786         self.weapon = windex;
 787         self.switchingweapon = windex; // to make sure
 788         self.weaponname = e.mdl;
 789         self.bulletcounter = 0;
 790 }
 791
 792 // perform weapon to attack (weaponstate and attack_finished check is here)
 793 void W_SwitchToOtherWeapon(entity pl)
 794 {
 795         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 796         float w, ww;
 797         w = pl.weapon;
 798         if(WEPSET_CONTAINS_EW(pl, w))
 799         {
 800                 WEPSET_ANDNOT_EW(pl, w);
 801                 ww = w_getbestweapon(pl);
 802                 WEPSET_OR_EW(pl, w);
 803         }
 804         else
 805                 ww = w_getbestweapon(pl);
 806         if(ww)
 807                 W_SwitchWeapon_Force(pl, ww);
 808 }
 809
 810 .float prevdryfire;
 811 .float prevwarntime;
 812 float weapon_prepareattack_checkammo(float secondary)
 813 {
 814         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 815         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 816         {
 817                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 818                 entity mine;
 819                 if(self.weapon == WEP_MINE_LAYER)
 820                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 821                         return FALSE;
 822
 823                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 824                 {
 825                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 826                         self.prevdryfire = time;
 827                 }
 828
 829                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 830                 {
 831                         if(time - self.prevwarntime > 1)
 832                         {
 833                                 Send_Notification(
 834                                         NOTIF_ONE,
 835                                         self,
 836                                         MSG_MULTI,
 837                                         ITEM_WEAPON_PRIMORSEC,
 838                                         self.weapon,
 839                                         secondary,
 840                                         (1 - secondary)
 841                                 );
 842                         }
 843                         self.prevwarntime = time;
 844                 }
 845                 else // this weapon is totally unable to fire, switch to another one
 846                 {
 847                         W_SwitchToOtherWeapon(self);
 848                 }
 849
 850                 return FALSE;
 851         }
 852         return TRUE;
 853 }
 854 .float race_penalty;
 855 float weapon_prepareattack_check(float secondary, float attacktime)
 856 {
 857         if(!weapon_prepareattack_checkammo(secondary))
 858                 return FALSE;
 859
 860         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 861         //if all players readied up and the countdown is running
 862         if(time < game_starttime || time < self.race_penalty) {
 863                 return FALSE;
 864         }
 865
 866         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 867                 return FALSE;
 868
 869         // do not even think about shooting if switching
 870         if(self.switchweapon != self.weapon)
 871                 return FALSE;
 872
 873         if(attacktime >= 0)
 874         {
 875                 // don't fire if previous attack is not finished
 876                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 877                         return FALSE;
 878                 // don't fire while changing weapon
 879                 if (self.weaponentity.state != WS_READY)
 880                         return FALSE;
 881         }
 882
 883         return TRUE;
 884 }
 885 float weapon_prepareattack_do(float secondary, float attacktime)
 886 {
 887         self.weaponentity.state = WS_INUSE;
 888
 889         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 890
 891         // if the weapon hasn't been firing continuously, reset the timer
 892         if(attacktime >= 0)
 893         {
 894                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 895                 {
 896                         ATTACK_FINISHED(self) = time;
 897                         //dprint("resetting attack finished to ", ftos(time), "\n");
 898                 }
 899                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 900         }
 901         self.bulletcounter += 1;
 902         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 903         return TRUE;
 904 }
 905 float weapon_prepareattack(float secondary, float attacktime)
 906 {
 907         if(weapon_prepareattack_check(secondary, attacktime))
 908         {
 909                 weapon_prepareattack_do(secondary, attacktime);
 910                 return TRUE;
 911         }
 912         else
 913                 return FALSE;
 914 }
 915
 916 void weapon_thinkf(float fr, float t, void() func)
 917 {
 918         vector a;
 919         vector of, or, ou;
 920         float restartanim;
 921
 922         if(fr == WFRAME_DONTCHANGE)
 923         {
 924                 fr = self.weaponentity.wframe;
 925                 restartanim = FALSE;
 926         }
 927         else if (fr == WFRAME_IDLE)
 928                 restartanim = FALSE;
 929         else
 930                 restartanim = TRUE;
 931
 932         of = v_forward;
 933         or = v_right;
 934         ou = v_up;
 935
 936         if (self.weaponentity)
 937         {
 938                 self.weaponentity.wframe = fr;
 939                 a = '0 0 0';
 940                 if (fr == WFRAME_IDLE)
 941                         a = self.weaponentity.anim_idle;
 942                 else if (fr == WFRAME_FIRE1)
 943                         a = self.weaponentity.anim_fire1;
 944                 else if (fr == WFRAME_FIRE2)
 945                         a = self.weaponentity.anim_fire2;
 946                 else // if (fr == WFRAME_RELOAD)
 947                         a = self.weaponentity.anim_reload;
 948                 a_z *= g_weaponratefactor;
 949                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 950         }
 951
 952         v_forward = of;
 953         v_right = or;
 954         v_up = ou;
 955
 956         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 957         {
 958                 backtrace("Tried to override initial weapon think function - should this really happen?");
 959         }
 960
 961         t *= W_WeaponRateFactor();
 962
 963         // VorteX: haste can be added here
 964         if (self.weapon_think == w_ready)
 965         {
 966                 self.weapon_nextthink = time;
 967                 //dprint("started firing at ", ftos(time), "\n");
 968         }
 969         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 970         {
 971                 self.weapon_nextthink = time;
 972                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 973         }
 974         self.weapon_nextthink = self.weapon_nextthink + t;
 975         self.weapon_think = func;
 976         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 977
 978         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 979         {
 980                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 981                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 982                 else
 983                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 984         }
 985         else
 986         {
 987                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
 988                         self.anim_upper_action = 0;
 989         }
 990 }
 991
 992 void weapon_boblayer1(float spd, vector org)
 993 {
 994         // VorteX: haste can be added here
 995 }
 996
 997 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 998 {
 999         vector mdirection;
1000         float mspeed;
1001         vector outvelocity;
1002
1003         mvelocity = mvelocity * g_weaponspeedfactor;
1004
1005         mdirection = normalize(mvelocity);
1006         mspeed = vlen(mvelocity);
1007
1008         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1009
1010         return outvelocity;
1011 }
1012
1013 void W_AttachToShotorg(entity flash, vector offset)
1014 {
1015         entity xflash;
1016         flash.owner = self;
1017         flash.angles_z = random() * 360;
1018
1019         if(gettagindex(self.weaponentity, "shot"))
1020                 setattachment(flash, self.weaponentity, "shot");
1021         else
1022                 setattachment(flash, self.weaponentity, "tag_shot");
1023         setorigin(flash, offset);
1024
1025         xflash = spawn();
1026         copyentity(flash, xflash);
1027
1028         flash.viewmodelforclient = self;
1029
1030         if(self.weaponentity.oldorigin_x > 0)
1031         {
1032                 setattachment(xflash, self.exteriorweaponentity, "");
1033                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1034         }
1035         else
1036         {
1037                 if(gettagindex(self.exteriorweaponentity, "shot"))
1038                         setattachment(xflash, self.exteriorweaponentity, "shot");
1039                 else
1040                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1041                 setorigin(xflash, offset);
1042         }
1043 }
1044
1045 vector cliptoplane(vector v, vector p)
1046 {
1047         return v - (v * p) * p;
1048 }
1049
1050 vector solve_cubic_pq(float p, float q)
1051 {
1052         float D, u, v, a;
1053         D = q*q/4.0 + p*p*p/27.0;
1054         if(D < 0)
1055         {
1056                 // irreducibilis
1057                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1058                 u = sqrt(-4.0/3.0 * p);
1059                 // a in range 0..pi/3
1060                 // cos(a)
1061                 // cos(a + 2pi/3)
1062                 // cos(a + 4pi/3)
1063                 return
1064                         u *
1065                         (
1066                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1067                                 +
1068                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1069                                 +
1070                                 '0 0 1' * cos(a)
1071                         );
1072         }
1073         else if(D == 0)
1074         {
1075                 // simple
1076                 if(p == 0)
1077                         return '0 0 0';
1078                 u = 3*q/p;
1079                 v = -u/2;
1080                 if(u >= v)
1081                         return '1 1 0' * v + '0 0 1' * u;
1082                 else
1083                         return '0 1 1' * v + '1 0 0' * u;
1084         }
1085         else
1086         {
1087                 // cardano
1088                 u = cbrt(-q/2.0 + sqrt(D));
1089                 v = cbrt(-q/2.0 - sqrt(D));
1090                 return '1 1 1' * (u + v);
1091         }
1092 }
1093 vector solve_cubic_abcd(float a, float b, float c, float d)
1094 {
1095         // y = 3*a*x + b
1096         // x = (y - b) / 3a
1097         float p, q;
1098         vector v;
1099         p = (9*a*c - 3*b*b);
1100         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1101         v = solve_cubic_pq(p, q);
1102         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1103         if(a < 0)
1104                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1105         return v;
1106 }
1107
1108 vector findperpendicular(vector v)
1109 {
1110         vector p;
1111         p_x = v_z;
1112         p_y = -v_x;
1113         p_z = v_y;
1114         return normalize(cliptoplane(p, v));
1115 }
1116
1117 vector W_CalculateProjectileSpread(vector forward, float spread)
1118 {
1119         float sigma;
1120         vector v1 = '0 0 0', v2;
1121         float dx, dy, r;
1122         float sstyle;
1123         spread *= g_weaponspreadfactor;
1124         if(spread <= 0)
1125                 return forward;
1126         sstyle = autocvar_g_projectiles_spread_style;
1127
1128         if(sstyle == 0)
1129         {
1130                 // this is the baseline for the spread value!
1131                 // standard deviation: sqrt(2/5)
1132                 // density function: sqrt(1-r^2)
1133                 return forward + randomvec() * spread;
1134         }
1135         else if(sstyle == 1)
1136         {
1137                 // same thing, basically
1138                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1139         }
1140         else if(sstyle == 2)
1141         {
1142                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1143                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1144                 v1 = findperpendicular(forward);
1145                 v2 = cross(forward, v1);
1146                 // random point on unit circle
1147                 dx = random() * 2 * M_PI;
1148                 dy = sin(dx);
1149                 dx = cos(dx);
1150                 // radius in our dist function
1151                 r = random();
1152                 r = sqrt(r);
1153                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1154         }
1155         else if(sstyle == 3) // gauss 3d
1156         {
1157                 sigma = spread * 0.44721359549996; // match baseline stddev
1158                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1159                 v1 = forward;
1160                 v1_x += gsl_ran_gaussian(sigma);
1161                 v1_y += gsl_ran_gaussian(sigma);
1162                 v1_z += gsl_ran_gaussian(sigma);
1163                 return v1;
1164         }
1165         else if(sstyle == 4) // gauss 2d
1166         {
1167                 sigma = spread * 0.44721359549996; // match baseline stddev
1168                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1169                 v1_x = gsl_ran_gaussian(sigma);
1170                 v1_y = gsl_ran_gaussian(sigma);
1171                 v1_z = gsl_ran_gaussian(sigma);
1172                 return normalize(forward + cliptoplane(v1, forward));
1173         }
1174         else if(sstyle == 5) // 1-r
1175         {
1176                 sigma = spread * 1.154700538379252; // match baseline stddev
1177                 v1 = findperpendicular(forward);
1178                 v2 = cross(forward, v1);
1179                 // random point on unit circle
1180                 dx = random() * 2 * M_PI;
1181                 dy = sin(dx);
1182                 dx = cos(dx);
1183                 // radius in our dist function
1184                 r = random();
1185                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1186                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1187         }
1188         else if(sstyle == 6) // 1-r^2
1189         {
1190                 sigma = spread * 1.095445115010332; // match baseline stddev
1191                 v1 = findperpendicular(forward);
1192                 v2 = cross(forward, v1);
1193                 // random point on unit circle
1194                 dx = random() * 2 * M_PI;
1195                 dy = sin(dx);
1196                 dx = cos(dx);
1197                 // radius in our dist function
1198                 r = random();
1199                 r = sqrt(1 - r);
1200                 r = sqrt(1 - r);
1201                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1202         }
1203         else if(sstyle == 7) // (1-r) (2-r)
1204         {
1205                 sigma = spread * 1.224744871391589; // match baseline stddev
1206                 v1 = findperpendicular(forward);
1207                 v2 = cross(forward, v1);
1208                 // random point on unit circle
1209                 dx = random() * 2 * M_PI;
1210                 dy = sin(dx);
1211                 dx = cos(dx);
1212                 // radius in our dist function
1213                 r = random();
1214                 r = 1 - sqrt(r);
1215                 r = 1 - sqrt(r);
1216                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1217         }
1218         else
1219                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1220         return '0 0 0';
1221         /*
1222          * how to derive falloff functions:
1223          * rho(r) := (2-r) * (1-r);
1224          * a : 0;
1225          * b : 1;
1226          * rhor(r) := r * rho(r);
1227          * cr(t) := integrate(rhor(r), r, a, t);
1228          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1229          * variance : scr(b) / cr(b);
1230          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1231          * sqrt(0.4 / variance), numer;
1232          */
1233 }
1234
1235 #if 0
1236 float mspercallsum;
1237 float mspercallsstyle;
1238 float mspercallcount;
1239 #endif
1240 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1241 {
1242         if(missile.owner == world)
1243                 error("Unowned missile");
1244
1245         dir = dir + upDir * (pUpSpeed / pSpeed);
1246         dir_z += pZSpeed / pSpeed;
1247         pSpeed *= vlen(dir);
1248         dir = normalize(dir);
1249
1250 #if 0
1251         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1252         {
1253                 mspercallsum = mspercallcount = 0;
1254                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1255         }
1256         mspercallsum -= gettime(GETTIME_HIRES);
1257 #endif
1258         dir = W_CalculateProjectileSpread(dir, spread);
1259 #if 0
1260         mspercallsum += gettime(GETTIME_HIRES);
1261         mspercallcount += 1;
1262         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1263 #endif
1264
1265         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1266 }
1267
1268 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1269 {
1270         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1271 }
1272
1273 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1274 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1275
1276 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1277 {
1278         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1279                 return;
1280
1281         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1282         if(ammo_reload)
1283         {
1284                 self.clip_load -= ammo_use;
1285                 self.(weapon_load[self.weapon]) = self.clip_load;
1286         }
1287         else
1288                 self.(self.current_ammo) -= ammo_use;
1289 }
1290
1291 // weapon reloading code
1292
1293 .float reload_ammo_amount, reload_ammo_min, reload_time;
1294 .float reload_complain;
1295 .string reload_sound;
1296
1297 void W_ReloadedAndReady()
1298 {
1299         // finish the reloading process, and do the ammo transfer
1300
1301         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1302
1303         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1304         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1305                 self.clip_load = self.reload_ammo_amount;
1306         else
1307         {
1308                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1309                 {
1310                         self.clip_load += 1;
1311                         self.(self.current_ammo) -= 1;
1312                 }
1313         }
1314         self.(weapon_load[self.weapon]) = self.clip_load;
1315
1316         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1317         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1318         // so your weapon is disabled for a few seconds without reason
1319
1320         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1321
1322         w_ready();
1323 }
1324
1325 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1326 {
1327         // set global values to work with
1328
1329         self.reload_ammo_min = sent_ammo_min;
1330         self.reload_ammo_amount = sent_ammo_amount;
1331         self.reload_time = sent_time;
1332         self.reload_sound = sent_sound;
1333
1334         // check if we meet the necessary conditions to reload
1335
1336         entity e;
1337         e = get_weaponinfo(self.weapon);
1338
1339         // don't reload weapons that don't have the RELOADABLE flag
1340         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1341         {
1342                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1343                 return;
1344         }
1345
1346         // return if reloading is disabled for this weapon
1347         if(!self.reload_ammo_amount)
1348                 return;
1349
1350         // our weapon is fully loaded, no need to reload
1351         if (self.clip_load >= self.reload_ammo_amount)
1352                 return;
1353
1354         // no ammo, so nothing to load
1355         if(!self.(self.current_ammo) && self.reload_ammo_min)
1356         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1357         {
1358                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
1359                 {
1360                         play2(self, "weapons/unavailable.wav");
1361                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1362                         self.reload_complain = time + 1;
1363                 }
1364                 // switch away if the amount of ammo is not enough to keep using this weapon
1365                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1366                 {
1367                         self.clip_load = -1; // reload later
1368                         W_SwitchToOtherWeapon(self);
1369                 }
1370                 return;
1371         }
1372
1373         if (self.weaponentity)
1374         {
1375                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1376                         return;
1377
1378                 // allow switching away while reloading, but this will cause a new reload!
1379                 self.weaponentity.state = WS_READY;
1380         }
1381
1382         // now begin the reloading process
1383
1384         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1385
1386         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1387         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1388         // so your weapon is disabled for a few seconds without reason
1389
1390         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1391
1392         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1393
1394         if(self.clip_load < 0)
1395                 self.clip_load = 0;
1396         self.old_clip_load = self.clip_load;
1397         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1398 }