qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 .float prevstrengthsound;
 134 .float prevstrengthsoundattempt;
 135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 136 {
 137         float nudge = 1; // added to traceline target and subtracted from result
 138         local float oldsolid;
 139         vector vecs, dv;
 140         oldsolid = ent.dphitcontentsmask;
 141         if(ent.weapon == WEP_RIFLE)
 142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         else
 144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         if(antilag)
 146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 147                 // passing world, because we do NOT want it to touch dphitcontentsmask
 148         else
 149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 151
 152         vector vf, vr, vu;
 153         vf = v_forward;
 154         vr = v_right;
 155         vu = v_up;
 156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 157         v_forward = vf;
 158         v_right = vr;
 159         v_up = vu;
 160
 161         // un-adjust trueaim if shotend is too close
 162         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 163                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 164
 165         // track max damage
 166         if(accuracy_canbegooddamage(ent))
 167                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 168
 169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 170
 171         if(ent.weaponentity.movedir_x > 0)
 172                 vecs = ent.weaponentity.movedir;
 173         else
 174                 vecs = '0 0 0';
 175         if(debug_shotorg != '0 0 0')
 176                 vecs = debug_shotorg;
 177
 178         dv = v_right * -vecs_y + v_up * vecs_z;
 179         w_shotorg = ent.origin + ent.view_ofs + dv;
 180
 181         // now move the shotorg forward as much as requested if possible
 182         if(antilag)
 183         {
 184                 if(ent.antilag_debug)
 185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 186                 else
 187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 188         }
 189         else
 190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 191         w_shotorg = trace_endpos - v_forward * nudge;
 192         // calculate the shotdir from the chosen shotorg
 193         w_shotdir = normalize(w_shotend - w_shotorg);
 194
 195         if (antilag)
 196         if (!ent.cvar_cl_noantilag)
 197         {
 198                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 199                 {
 200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 201                         if (!trace_ent.takedamage)
 202                         {
 203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 204                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 205                                 {
 206                                         entity e;
 207                                         e = trace_ent;
 208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 209                                         if(trace_ent == e)
 210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 211                                 }
 212                         }
 213                 }
 214                 else if(autocvar_g_antilag == 3) // client side hitscan
 215                 {
 216                         // this part MUST use prydon cursor
 217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 218                         if (ent.cursor_trace_ent != ent)         // just to make sure
 219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 220                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 221                         {
 222                                 // verify that the shot would miss without antilag
 223                                 // (avoids an issue where guns would always shoot at their origin)
 224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 225                                 if (!trace_ent.takedamage)
 226                                 {
 227                                         // verify that the shot would hit if altered
 228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 229                                         if (trace_ent == ent.cursor_trace_ent)
 230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 231                                         else
 232                                                 print("antilag fail\n");
 233                                 }
 234                         }
 235                 }
 236         }
 237
 238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 239
 240         if (!g_norecoil)
 241                 ent.punchangle_x = recoil * -1;
 242
 243         if (snd != "")
 244         {
 245                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 246
 247                 if(ent.items & IT_STRENGTH)
 248                 if(!g_minstagib)
 249                 if(
 250                         (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
 251                         ||
 252                         (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
 253                 ) // prevent insane sound spam
 254                 {
 255                         sound(ent, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 256                         ent.prevstrengthsound = time;
 257                 }
 258                 ent.prevstrengthsoundattempt = time;
 259         }
 260
 261         // nudge w_shotend so a trace to w_shotend hits
 262         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 263 };
 264
 265 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 266 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 270
 271 float CL_Weaponentity_CustomizeEntityForClient()
 272 {
 273         self.viewmodelforclient = self.owner;
 274         if(other.classname == "spectator")
 275                 if(other.enemy == self.owner)
 276                         self.viewmodelforclient = other;
 277         return TRUE;
 278 }
 279
 280 float qcweaponanimation;
 281 vector weapon_offset = '0 -10 0';
 282 vector weapon_adjust = '10 0 -15';
 283 .vector weapon_morph0origin;
 284 .vector weapon_morph0angles;
 285 .float  weapon_morph0time;
 286 .vector weapon_morph1origin;
 287 .vector weapon_morph1angles;
 288 .float  weapon_morph1time;
 289 .vector weapon_morph2origin;
 290 .vector weapon_morph2angles;
 291 .float  weapon_morph2time;
 292 .vector weapon_morph3origin;
 293 .vector weapon_morph3angles;
 294 .float  weapon_morph3time;
 295 .vector weapon_morph4origin;
 296 .vector weapon_morph4angles;
 297 .float  weapon_morph4time;
 298 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 299
 300 /*
 301  * supported formats:
 302  *
 303  * 1. simple animated model, muzzle flash handling on h_ model:
 304  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 305  *      tags:
 306  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 307  *        shell = casings ejection point (must be on the right hand side of the gun)
 308  *        weapon = attachment for v_tuba.md3
 309  *    v_tuba.md3 - first and third person model
 310  *    g_tuba.md3 - pickup model
 311  *
 312  * 2. simple animated model, muzzle flash handling on v_ model:
 313  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 314  *      tags:
 315  *        weapon = attachment for v_tuba.md3
 316  *    v_tuba.md3 - first and third person model
 317  *      tags:
 318  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 319  *        shell = casings ejection point (must be on the right hand side of the gun)
 320  *    g_tuba.md3 - pickup model
 321  *
 322  * 3. fully animated model, muzzle flash handling on h_ model:
 323  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 324  *      tags:
 325  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 326  *        shell = casings ejection point (must be on the right hand side of the gun)
 327  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 328  *    v_tuba.md3 - third person model
 329  *    g_tuba.md3 - pickup model
 330  *
 331  * 4. fully animated model, muzzle flash handling on v_ model:
 332  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 333  *      tags:
 334  *        shot = muzzle end (shot origin)
 335  *        shell = casings ejection point (must be on the right hand side of the gun)
 336  *    v_tuba.md3 - third person model
 337  *      tags:
 338  *        shot = muzzle end (for muzzle flashes)
 339  *    g_tuba.md3 - pickup model
 340  */
 341
 342 // writes:
 343 //   self.origin, self.angles
 344 //   self.weaponentity
 345 //   self.movedir, self.view_ofs
 346 //   attachment stuff
 347 //   anim stuff
 348 // to free:
 349 //   call again with ""
 350 //   remove the ent
 351 void CL_WeaponEntity_SetModel(string name)
 352 {
 353         string animfilename;
 354         float animfile;
 355         float v_shot_idx;
 356         if (name != "")
 357         {
 358                 // if there is a child entity, hide it until we're sure we use it
 359                 if (self.weaponentity)
 360                         self.weaponentity.model = "";
 361                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 362                 v_shot_idx = gettagindex(self, "shot"); // used later
 363                 if(!v_shot_idx)
 364                         v_shot_idx = gettagindex(self, "tag_shot");
 365
 366                 if(qcweaponanimation)
 367                 {
 368                         self.angles = '0 0 0';
 369                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 370                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 371                         self.movedir_x += 32;
 372                         self.spawnorigin = self.movedir;
 373                         // oldorigin - not calculated here
 374                 }
 375                 else
 376                 {
 377                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 378                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 379                         animfile = fopen(animfilename, FILE_READ);
 380                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 381                         self.anim_fire1  = '0 1 0.01';
 382                         self.anim_fire2  = '1 1 0.01';
 383                         self.anim_idle   = '2 1 0.01';
 384                         self.anim_reload = '3 1 0.01';
 385                         if (animfile >= 0)
 386                         {
 387                                 animparseerror = FALSE;
 388                                 self.anim_fire1  = animparseline(animfile);
 389                                 self.anim_fire2  = animparseline(animfile);
 390                                 self.anim_idle   = animparseline(animfile);
 391                                 self.anim_reload = animparseline(animfile);
 392                                 fclose(animfile);
 393                                 if (animparseerror)
 394                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 395                         }
 396
 397                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 398                         // if we don't, this is a "real" animated model
 399                         if(gettagindex(self, "weapon"))
 400                         {
 401                                 if (!self.weaponentity)
 402                                         self.weaponentity = spawn();
 403                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 404                                 setattachment(self.weaponentity, self, "weapon");
 405                         }
 406                         else if(gettagindex(self, "tag_weapon"))
 407                         {
 408                                 if (!self.weaponentity)
 409                                         self.weaponentity = spawn();
 410                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 411                                 setattachment(self.weaponentity, self, "tag_weapon");
 412                         }
 413                         else
 414                         {
 415                                 if(self.weaponentity)
 416                                         remove(self.weaponentity);
 417                                 self.weaponentity = world;
 418                         }
 419
 420                         setorigin(self,'0 0 0');
 421                         self.angles = '0 0 0';
 422                         self.frame = 0;
 423                         self.viewmodelforclient = world;
 424
 425                         float idx;
 426
 427                         if(v_shot_idx) // v_ model attached to invisible h_ model
 428                         {
 429                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 430                         }
 431                         else
 432                         {
 433                                 idx = gettagindex(self, "shot");
 434                                 if(!idx)
 435                                         idx = gettagindex(self, "tag_shot");
 436                                 if(idx)
 437                                         self.movedir = gettaginfo(self, idx);
 438                                 else
 439                                 {
 440                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 441                                         self.movedir = '0 0 0';
 442                                 }
 443                         }
 444
 445                         if(self.weaponentity) // v_ model attached to invisible h_ model
 446                         {
 447                                 idx = gettagindex(self.weaponentity, "shell");
 448                                 if(!idx)
 449                                         idx = gettagindex(self.weaponentity, "tag_shell");
 450                                 if(idx)
 451                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 452                         }
 453                         else
 454                                 idx = 0;
 455                         if(!idx)
 456                         {
 457                                 idx = gettagindex(self, "shell");
 458                                 if(!idx)
 459                                         idx = gettagindex(self, "tag_shell");
 460                                 if(idx)
 461                                         self.spawnorigin = gettaginfo(self, idx);
 462                                 else
 463                                 {
 464                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 465                                         self.spawnorigin = self.movedir;
 466                                 }
 467                         }
 468
 469                         if(v_shot_idx)
 470                         {
 471                                 self.oldorigin = '0 0 0'; // use regular attachment
 472                         }
 473                         else
 474                         {
 475                                 if(self.weaponentity)
 476                                 {
 477                                         idx = gettagindex(self, "weapon");
 478                                         if(!idx)
 479                                                 idx = gettagindex(self, "tag_weapon");
 480                                 }
 481                                 else
 482                                 {
 483                                         idx = gettagindex(self, "handle");
 484                                         if(!idx)
 485                                                 idx = gettagindex(self, "tag_handle");
 486                                 }
 487                                 if(idx)
 488                                 {
 489                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 490                                 }
 491                                 else
 492                                 {
 493                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 494                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 495                                 }
 496                         }
 497
 498                         self.viewmodelforclient = self.owner;
 499                 }
 500         }
 501         else
 502         {
 503                 self.model = "";
 504                 if(self.weaponentity)
 505                         remove(self.weaponentity);
 506                 self.weaponentity = world;
 507                 self.movedir = '0 0 0';
 508                 self.spawnorigin = '0 0 0';
 509                 self.oldorigin = '0 0 0';
 510                 self.anim_fire1  = '0 1 0.01';
 511                 self.anim_fire2  = '0 1 0.01';
 512                 self.anim_idle   = '0 1 0.01';
 513                 self.anim_reload = '0 1 0.01';
 514         }
 515
 516         self.view_ofs = '0 0 0';
 517
 518         if(self.movedir_x >= 0)
 519         {
 520                 vector v0;
 521                 v0 = self.movedir;
 522                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 523                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 524         }
 525         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 526         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 527
 528         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 529
 530         // check if an instant weapon switch occurred
 531         if (qcweaponanimation)
 532         {
 533                 if (self.state == WS_READY)
 534                 {
 535                         self.angles = '0 0 0';
 536                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 537                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 538                 }
 539         }
 540         else
 541                 setorigin(self, self.view_ofs);
 542         // reset animstate now
 543         self.wframe = WFRAME_IDLE;
 544         self.weapon_morph0time = 0;
 545         self.weapon_morph1time = 0;
 546         self.weapon_morph2time = 0;
 547         self.weapon_morph3time = 0;
 548         self.weapon_morph4time = 0;
 549         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 550 }
 551
 552 vector CL_Weapon_GetShotOrg(float wpn)
 553 {
 554         entity wi, oldself;
 555         vector ret;
 556         wi = get_weaponinfo(wpn);
 557         oldself = self;
 558         self = spawn();
 559         CL_WeaponEntity_SetModel(wi.mdl);
 560         ret = self.movedir;
 561         CL_WeaponEntity_SetModel("");
 562         remove(self);
 563         self = oldself;
 564         return ret;
 565 }
 566
 567 void CL_Weaponentity_Think()
 568 {
 569         float tb;
 570         self.nextthink = time;
 571         if (intermission_running)
 572                 self.frame = self.anim_idle_x;
 573         if (self.owner.weaponentity != self)
 574         {
 575                 if (self.weaponentity)
 576                         remove(self.weaponentity);
 577                 remove(self);
 578                 return;
 579         }
 580         if (self.owner.deadflag != DEAD_NO)
 581         {
 582                 self.model = "";
 583                 if (self.weaponentity)
 584                         self.weaponentity.model = "";
 585                 return;
 586         }
 587         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 588         {
 589                 self.weaponname = self.owner.weaponname;
 590                 self.dmg = self.owner.modelindex;
 591                 self.deadflag = self.owner.deadflag;
 592
 593                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 594         }
 595
 596         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 597         self.effects = self.owner.effects & EFMASK_CHEAP;
 598         self.effects &~= EF_LOWPRECISION;
 599         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 600         self.effects &~= EF_TELEPORT_BIT;
 601         self.effects &~= EF_RESTARTANIM_BIT;
 602         self.effects |= tb;
 603
 604         if(self.owner.alpha == default_player_alpha)
 605                 self.alpha = default_weapon_alpha;
 606         else if(self.owner.alpha != 0)
 607                 self.alpha = self.owner.alpha;
 608         else
 609                 self.alpha = 1;
 610
 611         self.glowmod = self.owner.weaponentity_glowmod;
 612         self.colormap = self.owner.colormap;
 613         if (self.weaponentity)
 614         {
 615                 self.weaponentity.effects = self.effects;
 616                 self.weaponentity.alpha = self.alpha;
 617                 self.weaponentity.colormap = self.colormap;
 618                 self.weaponentity.glowmod = self.glowmod;
 619         }
 620
 621         self.angles = '0 0 0';
 622         local float f;
 623         f = 0;
 624         if (self.state == WS_RAISE && !intermission_running)
 625         {
 626                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 627                 self.angles_x = -90 * f * f;
 628                 if (qcweaponanimation)
 629                 {
 630                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 631                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 632                 }
 633         }
 634         else if (self.state == WS_DROP && !intermission_running)
 635         {
 636                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 637                 self.angles_x = -90 * f * f;
 638                 if (qcweaponanimation)
 639                 {
 640                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 641                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 642                 }
 643         }
 644         else if (self.state == WS_CLEAR)
 645         {
 646                 f = 1;
 647                 self.angles_x = -90 * f * f;
 648                 if (qcweaponanimation)
 649                 {
 650                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 651                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 652                 }
 653         }
 654         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 655         {
 656                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 657                 f = 1 - pow(1 - f, 3);
 658                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 659                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 660         }
 661         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 662         {
 663                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 664                 f = 1 - pow(1 - f, 3);
 665                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 666                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 667         }
 668         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 669         {
 670                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 671                 f = 1 - pow(1 - f, 3);
 672                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 673                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 674         }
 675         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 676         {
 677                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 678                 f = 1 - pow(1 - f, 3);
 679                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 680                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 681         }
 682         else if (qcweaponanimation)
 683         {
 684                 // begin a new idle morph
 685                 self.owner.weapon_morph0time   = time;
 686                 self.owner.weapon_morph0angles = self.angles;
 687                 self.owner.weapon_morph0origin = self.origin;
 688
 689                 float r;
 690                 float t;
 691
 692                 r = random();
 693                 if (r < 0.1)
 694                 {
 695                         // turn gun to the left to look at it
 696                         t = 2;
 697                         self.owner.weapon_morph1time   = time + t * 0.2;
 698                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 699                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 700                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 701
 702                         self.owner.weapon_morph2time   = time + t * 0.6;
 703                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 704                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 705                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 706
 707                         self.owner.weapon_morph3time   = time + t;
 708                         self.owner.weapon_morph3angles = '0 0 0';
 709                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 710                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 711                 }
 712                 else if (r < 0.2)
 713                 {
 714                         // raise the gun a bit
 715                         t = 2;
 716                         self.owner.weapon_morph1time   = time + t * 0.2;
 717                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 718                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 719                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 720
 721                         self.owner.weapon_morph2time   = time + t * 0.5;
 722                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 723                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 724                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 725
 726                         self.owner.weapon_morph3time   = time + t;
 727                         self.owner.weapon_morph3angles = '0 0 0';
 728                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 729                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 730                 }
 731                 else if (r < 0.3)
 732                 {
 733                         // tweak it a bit
 734                         t = 5;
 735                         self.owner.weapon_morph1time   = time + t * 0.3;
 736                         self.owner.weapon_morph1angles = randomvec() * 6;
 737                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 738                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 739
 740                         self.owner.weapon_morph2time   = time + t * 0.7;
 741                         self.owner.weapon_morph2angles = randomvec() * 6;
 742                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 743                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 744
 745                         self.owner.weapon_morph3time   = time + t;
 746                         self.owner.weapon_morph3angles = '0 0 0';
 747                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 748                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 749                 }
 750                 else
 751                 {
 752                         // hold it mostly steady
 753                         t = random() * 6 + 4;
 754                         self.owner.weapon_morph1time   = time + t * 0.2;
 755                         self.owner.weapon_morph1angles = randomvec() * 1;
 756                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 757                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 758
 759                         self.owner.weapon_morph2time   = time + t * 0.5;
 760                         self.owner.weapon_morph2angles = randomvec() * 1;
 761                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 762                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 763
 764                         self.owner.weapon_morph3time   = time + t * 0.7;
 765                         self.owner.weapon_morph3angles = randomvec() * 1;
 766                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 767                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 768                 }
 769
 770                 self.owner.weapon_morph4time   = time + t;
 771                 self.owner.weapon_morph4angles = '0 0 0';
 772                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 773                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 774
 775         }
 776 };
 777
 778 void CL_ExteriorWeaponentity_Think()
 779 {
 780         float tag_found;
 781         vector ang;
 782         self.nextthink = time;
 783         if (self.owner.exteriorweaponentity != self)
 784         {
 785                 remove(self);
 786                 return;
 787         }
 788         if (self.owner.deadflag != DEAD_NO)
 789         {
 790                 self.model = "";
 791                 return;
 792         }
 793         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 794         {
 795                 self.weaponname = self.owner.weaponname;
 796                 self.dmg = self.owner.modelindex;
 797                 self.deadflag = self.owner.deadflag;
 798                 if (self.owner.weaponname != "")
 799                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 800                 else
 801                         self.model = "";
 802
 803                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 804                 {
 805                         self.tag_index = tag_found;
 806                         self.tag_entity = self.owner;
 807                 }
 808                 else
 809                         setattachment(self, self.owner, "bip01 r hand");
 810
 811                 // if that didn't find a tag, hide the exterior weapon model
 812                 if (!self.tag_index)
 813                         self.model = "";
 814         }
 815         self.effects = self.owner.effects;
 816         if(sv_pitch_min == sv_pitch_max)
 817                 self.effects |= EF_LOWPRECISION;
 818         else
 819                 self.effects &~= EF_LOWPRECISION;
 820         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 821         if(self.owner.alpha == default_player_alpha)
 822                 self.alpha = default_weapon_alpha;
 823         else if(self.owner.alpha != 0)
 824                 self.alpha = self.owner.alpha;
 825         else
 826                 self.alpha = 1;
 827
 828         if (!intermission_running)
 829         {
 830                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 831                 ang_y = 0;
 832                 ang_z = 0;
 833
 834                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 835                 {
 836                         ang_y = self.owner.v_angle_y;
 837                         makevectors(ang);
 838                         var vector v = v_forward;
 839                         var float t = self.tag_entity.frame1time;
 840                         var float f = self.tag_entity.frame;
 841                         self.tag_entity.frame1time = time;
 842                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 843                         gettaginfo(self.tag_entity, self.tag_index);
 844                         self.tag_entity.frame1time = t;
 845                         self.tag_entity.frame = f;
 846                         // untransform v according to this coordinate space
 847                         vector w;
 848                         w_x = v_forward * v;
 849                         w_y = -v_right * v;
 850                         w_z = v_up * v;
 851                         self.angles = vectoangles(w);
 852                 }
 853                 else
 854                 {
 855                         ang_x = -/* don't ask */ang_x;
 856                         self.angles = ang;
 857                 }
 858
 859                 if(autocvar_g_loituma)
 860                 {
 861                         vector moddir, modup;
 862                         vector modangles;
 863                         float t;
 864
 865                         t = time * autocvar_g_loituma;
 866
 867                         modangles_x = t * 360;
 868                         modangles_y = 90;
 869                         modangles_z = 0;
 870
 871                         self.angles =
 872                                 AnglesTransform_ToAngles(
 873                                         AnglesTransform_Multiply(
 874                                                 AnglesTransform_FromAngles(self.angles),
 875                                                 AnglesTransform_FromAngles(modangles)
 876                                         )
 877                                 );
 878                 }
 879         }
 880
 881         self.glowmod = self.owner.weaponentity_glowmod;
 882         self.colormap = self.owner.colormap;
 883 };
 884
 885 // spawning weaponentity for client
 886 void CL_SpawnWeaponentity()
 887 {
 888         self.weaponentity = spawn();
 889         self.weaponentity.classname = "weaponentity";
 890         self.weaponentity.solid = SOLID_NOT;
 891         self.weaponentity.owner = self;
 892         setmodel(self.weaponentity, ""); // precision set when changed
 893         setorigin(self.weaponentity, '0 0 0');
 894         self.weaponentity.angles = '0 0 0';
 895         self.weaponentity.viewmodelforclient = self;
 896         self.weaponentity.flags = 0;
 897         self.weaponentity.think = CL_Weaponentity_Think;
 898         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 899         self.weaponentity.nextthink = time;
 900
 901         self.exteriorweaponentity = spawn();
 902         self.exteriorweaponentity.classname = "exteriorweaponentity";
 903         self.exteriorweaponentity.solid = SOLID_NOT;
 904         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 905         self.exteriorweaponentity.owner = self;
 906         setorigin(self.exteriorweaponentity, '0 0 0');
 907         self.exteriorweaponentity.angles = '0 0 0';
 908         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 909         self.exteriorweaponentity.nextthink = time;
 910 };
 911
 912 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 913 {
 914         msg_entity = e;
 915         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 916         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 917         WriteByte(MSG_ONE, wpn);
 918         WriteString(MSG_ONE, wpnname);
 919         WriteByte(MSG_ONE, type);
 920 }
 921
 922 .float hasweapon_complain_spam;
 923
 924 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 925 {
 926         local float weaponbit, f;
 927         local entity oldself;
 928
 929         if(time < self.hasweapon_complain_spam)
 930                 complain = 0;
 931         if(complain)
 932                 self.hasweapon_complain_spam = time + 0.2;
 933
 934         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 935         {
 936                 if (complain)
 937                         sprint(self, "Invalid weapon\n");
 938                 return FALSE;
 939         }
 940         weaponbit = W_WeaponBit(wpn);
 941         if (cl.weapons & weaponbit)
 942         {
 943                 if (andammo)
 944                 {
 945                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 946                         {
 947                                 f = 1;
 948                         }
 949                         else
 950                         {
 951                                 oldself = self;
 952                                 self = cl;
 953                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 954                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 955
 956                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 957                                 local entity mine;
 958                                 if(wpn == WEP_MINE_LAYER)
 959                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 960                                         f = 1;
 961
 962                                 self = oldself;
 963                         }
 964                         if (!f)
 965                         {
 966                                 if (complain)
 967                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 968                                 {
 969                                         play2(cl, "weapons/unavailable.wav");
 970                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 971                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 972                                 }
 973                                 return FALSE;
 974                         }
 975                 }
 976                 return TRUE;
 977         }
 978         if (complain)
 979         {
 980                 // DRESK - 3/16/07
 981                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 982                 if(weaponsInMap & weaponbit)
 983                 {
 984                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 985                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 986
 987                         if(autocvar_g_showweaponspawns)
 988                         {
 989                                 entity e;
 990                                 string s;
 991
 992                                 e = get_weaponinfo(wpn);
 993                                 s = e.model2;
 994
 995                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 996                                 {
 997                                         if(e.classname == "droppedweapon")
 998                                                 continue;
 999                                         if not(e.flags & FL_ITEM)
1000                                                 continue;
1001                                         WaypointSprite_Spawn(
1002                                                 s,
1003                                                 1, 0,
1004                                                 world, e.origin,
1005                                                 self, 0,
1006                                                 world, enemy,
1007                                                 0,
1008                                                 RADARICON_NONE, '0 0 0'
1009                                         );
1010                                 }
1011                         }
1012                 }
1013                 else
1014                 {
1015                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1016                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1017                 }
1018
1019                 play2(cl, "weapons/unavailable.wav");
1020         }
1021         return FALSE;
1022 };
1023
1024 // Weapon subs
1025 void w_clear()
1026 {
1027         if (self.weapon != -1)
1028         {
1029                 self.weapon = 0;
1030                 self.switchingweapon = 0;
1031         }
1032         if (self.weaponentity)
1033         {
1034                 self.weaponentity.state = WS_CLEAR;
1035                 self.weaponentity.effects = 0;
1036         }
1037 };
1038
1039 void w_ready()
1040 {
1041         if (self.weaponentity)
1042                 self.weaponentity.state = WS_READY;
1043         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1044 };
1045
1046 // Setup weapon for client (after this raise frame will be launched)
1047 void weapon_setup(float windex)
1048 {
1049         entity e;
1050         qcweaponanimation = autocvar_sv_qcweaponanimation;
1051         e = get_weaponinfo(windex);
1052         self.items &~= IT_AMMO;
1053         self.items = self.items | e.items;
1054
1055         // the two weapon entities will notice this has changed and update their models
1056         self.weapon = windex;
1057         self.switchingweapon = windex; // to make sure
1058         self.weaponname = e.mdl;
1059         self.bulletcounter = 0;
1060 };
1061
1062 // perform weapon to attack (weaponstate and attack_finished check is here)
1063 void W_SwitchToOtherWeapon(entity pl)
1064 {
1065         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1066         float w, ww;
1067         w = W_WeaponBit(pl.weapon);
1068         pl.weapons &~= w;
1069         ww = w_getbestweapon(pl);
1070         pl.weapons |= w;
1071         if(ww)
1072                 W_SwitchWeapon_Force(pl, ww);
1073 }
1074 .float prevdryfire;
1075 float weapon_prepareattack_checkammo(float secondary)
1076 {
1077         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1078         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1079         {
1080                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1081                 local entity mine;
1082                 if(self.weapon == WEP_MINE_LAYER)
1083                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1084                         return FALSE;
1085
1086                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1087                 {
1088                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1089                         self.prevdryfire = time;
1090                 }
1091
1092                 W_SwitchToOtherWeapon(self);
1093                 return FALSE;
1094         }
1095         return TRUE;
1096 }
1097 .float race_penalty;
1098 float weapon_prepareattack_check(float secondary, float attacktime)
1099 {
1100         if(!weapon_prepareattack_checkammo(secondary))
1101                 return FALSE;
1102
1103         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1104         //if all players readied up and the countdown is running
1105         if(time < game_starttime || time < self.race_penalty) {
1106                 return FALSE;
1107         }
1108
1109         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1110                 return FALSE;
1111
1112         // do not even think about shooting if switching
1113         if(self.switchweapon != self.weapon)
1114                 return FALSE;
1115
1116         if(attacktime >= 0)
1117         {
1118                 // don't fire if previous attack is not finished
1119                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1120                         return FALSE;
1121                 // don't fire while changing weapon
1122                 if (self.weaponentity.state != WS_READY)
1123                         return FALSE;
1124         }
1125
1126         return TRUE;
1127 }
1128 float weapon_prepareattack_do(float secondary, float attacktime)
1129 {
1130         self.weaponentity.state = WS_INUSE;
1131
1132         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1133
1134         // if the weapon hasn't been firing continuously, reset the timer
1135         if(attacktime >= 0)
1136         {
1137                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1138                 {
1139                         ATTACK_FINISHED(self) = time;
1140                         //dprint("resetting attack finished to ", ftos(time), "\n");
1141                 }
1142                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1143         }
1144         self.bulletcounter += 1;
1145         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1146         return TRUE;
1147 }
1148 float weapon_prepareattack(float secondary, float attacktime)
1149 {
1150         if(weapon_prepareattack_check(secondary, attacktime))
1151         {
1152                 weapon_prepareattack_do(secondary, attacktime);
1153                 return TRUE;
1154         }
1155         else
1156                 return FALSE;
1157 }
1158
1159 void weapon_thinkf(float fr, float t, void() func)
1160 {
1161         vector a;
1162         vector of, or, ou;
1163         float restartanim;
1164
1165         if(fr == WFRAME_DONTCHANGE)
1166         {
1167                 fr = self.weaponentity.wframe;
1168                 restartanim = FALSE;
1169         }
1170         else if (fr == WFRAME_IDLE)
1171                 restartanim = FALSE;
1172         else
1173                 restartanim = TRUE;
1174
1175         of = v_forward;
1176         or = v_right;
1177         ou = v_up;
1178
1179         if (self.weaponentity)
1180         {
1181                 self.weaponentity.wframe = fr;
1182                 if (qcweaponanimation)
1183                 {
1184                         if (fr != WFRAME_IDLE)
1185                         {
1186                                 self.weapon_morph0time = time;
1187                                 self.weapon_morph0angles = self.weaponentity.angles;
1188                                 self.weapon_morph0origin = self.weaponentity.origin;
1189
1190                                 self.weapon_morph1angles = '0 0 0';
1191                                 self.weapon_morph1time = time + t;
1192                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1193                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1194
1195                                 self.weapon_morph2angles = '0 0 0';
1196                                 self.weapon_morph2time = time + t;
1197                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1198                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1199
1200                                 self.weapon_morph3angles = '0 0 0';
1201                                 self.weapon_morph3time = time + t;
1202                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1203                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1204
1205                                 self.weapon_morph4angles = '0 0 0';
1206                                 self.weapon_morph4time = time + t;
1207                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1208                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1209
1210                                 if (fr == WFRAME_FIRE1)
1211                                 {
1212                                         self.weapon_morph1angles = '5 0 0';
1213                                         self.weapon_morph1time = time + t * 0.1;
1214                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1215                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1216                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1217                                 }
1218                                 else if (fr == WFRAME_FIRE2)
1219                                 {
1220                                         self.weapon_morph1angles = '10 0 0';
1221                                         self.weapon_morph1time = time + t * 0.1;
1222                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1223                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1224                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1225                                 }
1226                                 else if (fr == WFRAME_RELOAD)
1227                                 {
1228                                         self.weapon_morph1time = time + t * 0.05;
1229                                         self.weapon_morph1angles = '-10 40 0';
1230                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1231                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1232
1233                                         self.weapon_morph2time = time + t * 0.15;
1234                                         self.weapon_morph2angles = '-10 40 5';
1235                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1236                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1237
1238                                         self.weapon_morph3time = time + t * 0.25;
1239                                         self.weapon_morph3angles = '-10 40 0';
1240                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1241                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1242                                 }
1243                         }
1244                 }
1245                 else
1246                 {
1247                         if (fr == WFRAME_IDLE)
1248                                 a = self.weaponentity.anim_idle;
1249                         else if (fr == WFRAME_FIRE1)
1250                                 a = self.weaponentity.anim_fire1;
1251                         else if (fr == WFRAME_FIRE2)
1252                                 a = self.weaponentity.anim_fire2;
1253                         else if (fr == WFRAME_RELOAD)
1254                                 a = self.weaponentity.anim_reload;
1255                         a_z *= g_weaponratefactor;
1256                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1257                 }
1258         }
1259
1260         v_forward = of;
1261         v_right = or;
1262         v_up = ou;
1263
1264         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1265         {
1266                 backtrace("Tried to override initial weapon think function - should this really happen?");
1267         }
1268
1269         t *= W_WeaponRateFactor();
1270
1271         // VorteX: haste can be added here
1272         if (self.weapon_think == w_ready)
1273         {
1274                 self.weapon_nextthink = time;
1275                 //dprint("started firing at ", ftos(time), "\n");
1276         }
1277         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1278         {
1279                 self.weapon_nextthink = time;
1280                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1281         }
1282         self.weapon_nextthink = self.weapon_nextthink + t;
1283         self.weapon_think = func;
1284         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1285
1286         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1287         //anim = self.anim_shoot;
1288         if (restartanim)
1289         if (t)
1290         if (!self.crouch) // shoot anim stands up, this looks bad
1291         {
1292                 vector anim;
1293                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1294                 {
1295                         anim = self.anim_melee;
1296                         anim_z = anim_y / (t + sys_frametime);
1297                         setanim(self, anim, FALSE, TRUE, TRUE);
1298                 }
1299         }
1300 };
1301
1302 void weapon_boblayer1(float spd, vector org)
1303 {
1304         // VorteX: haste can be added here
1305 };
1306
1307 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1308 {
1309         vector mdirection;
1310         float mspeed;
1311         float outspeed;
1312         float nstyle;
1313         vector outvelocity;
1314
1315         mvelocity = mvelocity * g_weaponspeedfactor;
1316
1317         mdirection = normalize(mvelocity);
1318         mspeed = vlen(mvelocity);
1319
1320         nstyle = autocvar_g_projectiles_newton_style;
1321         if(nstyle == 0 || forceAbsolute)
1322         {
1323                 // absolute velocity
1324                 outvelocity = mvelocity;
1325         }
1326         else if(nstyle == 1)
1327         {
1328                 // true Newtonian projectiles
1329                 outvelocity = pvelocity + mvelocity;
1330         }
1331         else if(nstyle == 2)
1332         {
1333                 // true Newtonian projectiles with automatic aim adjustment
1334                 //
1335                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1336                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1337                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1338                 // PLUS SIGN!
1339                 // not defined?
1340                 // then...
1341                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1342                 // velocity without mdirection component > mspeed
1343                 // fire at smallest possible mspeed that works?
1344                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1345
1346                 vector solution;
1347                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1348                 if(solution_z)
1349                         outspeed = solution_y; // the larger one
1350                 else
1351                 {
1352                         //outspeed = 0; // slowest possible shot
1353                         outspeed = solution_x; // the real part (that is, the average!)
1354                         //dprint("impossible shot, adjusting\n");
1355                 }
1356
1357                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1358                 outvelocity = mdirection * outspeed;
1359         }
1360         else if(nstyle == 3)
1361         {
1362                 // pseudo-Newtonian:
1363                 outspeed = mspeed + mdirection * pvelocity;
1364                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1365                 outvelocity = mdirection * outspeed;
1366         }
1367         else if(nstyle == 4)
1368         {
1369                 // tZorkian:
1370                 outspeed = mspeed + vlen(pvelocity);
1371                 outvelocity = mdirection * outspeed;
1372         }
1373         else
1374                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1375
1376         return outvelocity;
1377 }
1378
1379 void W_AttachToShotorg(entity flash, vector offset)
1380 {
1381         entity xflash;
1382         flash.owner = self;
1383         flash.angles_z = random() * 360;
1384         if(qcweaponanimation)
1385         {
1386                 setorigin(flash, w_shotorg + w_shotdir * 50);
1387                 flash.angles = vectoangles(w_shotdir);
1388                 flash.angles_z = random() * 360;
1389         }
1390         else
1391         {
1392                 if(gettagindex(self.weaponentity, "shot"))
1393                         setattachment(flash, self.weaponentity, "shot");
1394                 else
1395                         setattachment(flash, self.weaponentity, "tag_shot");
1396                 setorigin(flash, offset);
1397
1398                 xflash = spawn();
1399                 copyentity(flash, xflash);
1400
1401                 flash.viewmodelforclient = self;
1402
1403                 if(self.weaponentity.oldorigin_x > 0)
1404                 {
1405                         setattachment(xflash, self.exteriorweaponentity, "");
1406                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1407                 }
1408                 else
1409                 {
1410                         if(gettagindex(self.exteriorweaponentity, "shot"))
1411                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1412                         else
1413                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1414                         setorigin(xflash, offset);
1415                 }
1416         }
1417 }
1418
1419 vector cliptoplane(vector v, vector p)
1420 {
1421         return v - (v * p) * p;
1422 }
1423
1424 vector solve_cubic_pq(float p, float q)
1425 {
1426         float D, u, v, a;
1427         D = q*q/4.0 + p*p*p/27.0;
1428         if(D < 0)
1429         {
1430                 // irreducibilis
1431                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1432                 u = sqrt(-4.0/3.0 * p);
1433                 // a in range 0..pi/3
1434                 // cos(a)
1435                 // cos(a + 2pi/3)
1436                 // cos(a + 4pi/3)
1437                 return
1438                         u *
1439                         (
1440                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1441                                 +
1442                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1443                                 +
1444                                 '0 0 1' * cos(a)
1445                         );
1446         }
1447         else if(D == 0)
1448         {
1449                 // simple
1450                 if(p == 0)
1451                         return '0 0 0';
1452                 u = 3*q/p;
1453                 v = -u/2;
1454                 if(u >= v)
1455                         return '1 1 0' * v + '0 0 1' * u;
1456                 else
1457                         return '0 1 1' * v + '1 0 0' * u;
1458         }
1459         else
1460         {
1461                 // cardano
1462                 u = cbrt(-q/2.0 + sqrt(D));
1463                 v = cbrt(-q/2.0 - sqrt(D));
1464                 return '1 1 1' * (u + v);
1465         }
1466 }
1467 vector solve_cubic_abcd(float a, float b, float c, float d)
1468 {
1469         // y = 3*a*x + b
1470         // x = (y - b) / 3a
1471         float p, q;
1472         vector v;
1473         p = (9*a*c - 3*b*b);
1474         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1475         v = solve_cubic_pq(p, q);
1476         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1477         if(a < 0)
1478                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1479         return v;
1480 }
1481
1482 vector findperpendicular(vector v)
1483 {
1484         vector p;
1485         p_x = v_z;
1486         p_y = -v_x;
1487         p_z = v_y;
1488         return normalize(cliptoplane(p, v));
1489 }
1490
1491 vector W_CalculateProjectileSpread(vector forward, float spread)
1492 {
1493         float sigma;
1494         vector v1, v2;
1495         float dx, dy, r;
1496         float sstyle;
1497         spread *= g_weaponspreadfactor;
1498         if(spread <= 0)
1499                 return forward;
1500         sstyle = autocvar_g_projectiles_spread_style;
1501
1502         if(sstyle == 0)
1503         {
1504                 // this is the baseline for the spread value!
1505                 // standard deviation: sqrt(2/5)
1506                 // density function: sqrt(1-r^2)
1507                 return forward + randomvec() * spread;
1508         }
1509         else if(sstyle == 1)
1510         {
1511                 // same thing, basically
1512                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1513         }
1514         else if(sstyle == 2)
1515         {
1516                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1517                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1518                 v1 = findperpendicular(forward);
1519                 v2 = cross(forward, v1);
1520                 // random point on unit circle
1521                 dx = random() * 2 * M_PI;
1522                 dy = sin(dx);
1523                 dx = cos(dx);
1524                 // radius in our dist function
1525                 r = random();
1526                 r = sqrt(r);
1527                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1528         }
1529         else if(sstyle == 3) // gauss 3d
1530         {
1531                 sigma = spread * 0.44721359549996; // match baseline stddev
1532                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1533                 v1 = forward;
1534                 v1_x += gsl_ran_gaussian(sigma);
1535                 v1_y += gsl_ran_gaussian(sigma);
1536                 v1_z += gsl_ran_gaussian(sigma);
1537                 return v1;
1538         }
1539         else if(sstyle == 4) // gauss 2d
1540         {
1541                 sigma = spread * 0.44721359549996; // match baseline stddev
1542                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1543                 v1_x = gsl_ran_gaussian(sigma);
1544                 v1_y = gsl_ran_gaussian(sigma);
1545                 v1_z = gsl_ran_gaussian(sigma);
1546                 return normalize(forward + cliptoplane(v1, forward));
1547         }
1548         else if(sstyle == 5) // 1-r
1549         {
1550                 sigma = spread * 1.154700538379252; // match baseline stddev
1551                 v1 = findperpendicular(forward);
1552                 v2 = cross(forward, v1);
1553                 // random point on unit circle
1554                 dx = random() * 2 * M_PI;
1555                 dy = sin(dx);
1556                 dx = cos(dx);
1557                 // radius in our dist function
1558                 r = random();
1559                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1560                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1561         }
1562         else if(sstyle == 6) // 1-r^2
1563         {
1564                 sigma = spread * 1.095445115010332; // match baseline stddev
1565                 v1 = findperpendicular(forward);
1566                 v2 = cross(forward, v1);
1567                 // random point on unit circle
1568                 dx = random() * 2 * M_PI;
1569                 dy = sin(dx);
1570                 dx = cos(dx);
1571                 // radius in our dist function
1572                 r = random();
1573                 r = sqrt(1 - r);
1574                 r = sqrt(1 - r);
1575                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1576         }
1577         else if(sstyle == 7) // (1-r) (2-r)
1578         {
1579                 sigma = spread * 1.224744871391589; // match baseline stddev
1580                 v1 = findperpendicular(forward);
1581                 v2 = cross(forward, v1);
1582                 // random point on unit circle
1583                 dx = random() * 2 * M_PI;
1584                 dy = sin(dx);
1585                 dx = cos(dx);
1586                 // radius in our dist function
1587                 r = random();
1588                 r = 1 - sqrt(r);
1589                 r = 1 - sqrt(r);
1590                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1591         }
1592         else
1593                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1594         return '0 0 0';
1595         /*
1596          * how to derive falloff functions:
1597          * rho(r) := (2-r) * (1-r);
1598          * a : 0;
1599          * b : 1;
1600          * rhor(r) := r * rho(r);
1601          * cr(t) := integrate(rhor(r), r, a, t);
1602          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1603          * variance : scr(b) / cr(b);
1604          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1605          * sqrt(0.4 / variance), numer;
1606          */
1607 }
1608
1609 #if 0
1610 float mspercallsum;
1611 float mspercallsstyle;
1612 float mspercallcount;
1613 #endif
1614 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1615 {
1616         if(missile.owner == world)
1617                 error("Unowned missile");
1618
1619         dir = dir + upDir * (pUpSpeed / pSpeed);
1620         dir_z += pZSpeed / pSpeed;
1621         pSpeed *= vlen(dir);
1622         dir = normalize(dir);
1623
1624 #if 0
1625         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1626         {
1627                 mspercallsum = mspercallcount = 0;
1628                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1629         }
1630         mspercallsum -= gettime(GETTIME_HIRES);
1631 #endif
1632         dir = W_CalculateProjectileSpread(dir, spread);
1633 #if 0
1634         mspercallsum += gettime(GETTIME_HIRES);
1635         mspercallcount += 1;
1636         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1637 #endif
1638
1639         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1640 }
1641
1642 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1643 {
1644         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1645 }
1646
1647 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1648 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1649
1650 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1651 {
1652         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1653                 return;
1654
1655         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1656         if(ammo_reload)
1657         {
1658                 self.clip_load -= ammo_use;
1659                 self.weapon_load[self.weapon] = self.clip_load;
1660         }
1661         else
1662                 self.(self.current_ammo) -= ammo_use;
1663 }
1664
1665 // weapon reloading code
1666
1667 .float reload_ammo_amount, reload_ammo_min, reload_time;
1668 .float reload_complain;
1669 .string reload_sound;
1670
1671 void W_ReloadedAndReady()
1672 {
1673         // finish the reloading process, and do the ammo transfer
1674
1675         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1676
1677         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1678         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1679                 self.clip_load = self.reload_ammo_amount;
1680         else
1681         {
1682                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1683                 {
1684                         self.clip_load += 1;
1685                         self.(self.current_ammo) -= 1;
1686                 }
1687         }
1688         self.weapon_load[self.weapon] = self.clip_load;
1689
1690         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1691         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1692         // so your weapon is disabled for a few seconds without reason
1693
1694         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1695
1696         w_ready();
1697 }
1698
1699 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1700 {
1701         // set global values to work with
1702
1703         self.reload_ammo_min = sent_ammo_min;
1704         self.reload_ammo_amount = sent_ammo_amount;
1705         self.reload_time = sent_time;
1706         self.reload_sound = sent_sound;
1707
1708         // check if we meet the necessary conditions to reload
1709
1710         entity e;
1711         e = get_weaponinfo(self.weapon);
1712
1713         // don't reload weapons that don't have the RELOADABLE flag
1714         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1715         {
1716                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1717                 return;
1718         }
1719
1720         // return if reloading is disabled for this weapon
1721         if(!self.reload_ammo_amount)
1722                 return;
1723
1724         // our weapon is fully loaded, no need to reload
1725         if (self.clip_load >= self.reload_ammo_amount)
1726                 return;
1727
1728         // no ammo, so nothing to load
1729         if(!self.(self.current_ammo) && self.reload_ammo_min)
1730         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1731         {
1732                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1733                 {
1734                         play2(self, "weapons/unavailable.wav");
1735                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1736                         self.reload_complain = time + 1;
1737                 }
1738                 // switch away if the amount of ammo is not enough to keep using this weapon
1739                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1740                 {
1741                         self.clip_load = -1; // reload later
1742                         W_SwitchToOtherWeapon(self);
1743                 }
1744                 return;
1745         }
1746
1747         if (self.weaponentity)
1748         {
1749                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1750                         return;
1751
1752                 // allow switching away while reloading, but this will cause a new reload!
1753                 self.weaponentity.state = WS_READY;
1754         }
1755
1756         // now begin the reloading process
1757
1758         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1759
1760         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1761         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1762         // so your weapon is disabled for a few seconds without reason
1763
1764         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1765
1766         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1767
1768         if(self.clip_load < 0)
1769                 self.clip_load = 0;
1770         self.old_clip_load = self.clip_load;
1771         self.clip_load = self.weapon_load[self.weapon] = -1;
1772 }