qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 .float prevstrengthsound;
 131 .float prevstrengthsoundattempt;
 132 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 133 {
 134                 if((!g_minstagib)
 135                         && (player.items & IT_STRENGTH)
 136                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 137                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 138                 {
 139                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 140                         player.prevstrengthsound = time;
 141                 }
 142                 player.prevstrengthsoundattempt = time;
 143 }
 144
 145 // this function calculates w_shotorg and w_shotdir based on the weapon model
 146 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 147 // make sure you call makevectors first (FIXME?)
 148 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 149 {
 150         float nudge = 1; // added to traceline target and subtracted from result
 151         local float oldsolid;
 152         vector vecs, dv;
 153         oldsolid = ent.dphitcontentsmask;
 154         if(ent.weapon == WEP_RIFLE)
 155                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 156         else
 157                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 158         if(antilag)
 159                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 160                 // passing world, because we do NOT want it to touch dphitcontentsmask
 161         else
 162                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 163         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 164
 165         vector vf, vr, vu;
 166         vf = v_forward;
 167         vr = v_right;
 168         vu = v_up;
 169         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 170         v_forward = vf;
 171         v_right = vr;
 172         v_up = vu;
 173
 174         // un-adjust trueaim if shotend is too close
 175         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 176                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 177
 178         // track max damage
 179         if(accuracy_canbegooddamage(ent))
 180                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 181
 182         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 183
 184         if(ent.weaponentity.movedir_x > 0)
 185                 vecs = ent.weaponentity.movedir;
 186         else
 187                 vecs = '0 0 0';
 188         if(debug_shotorg != '0 0 0')
 189                 vecs = debug_shotorg;
 190
 191         dv = v_right * -vecs_y + v_up * vecs_z;
 192         w_shotorg = ent.origin + ent.view_ofs + dv;
 193
 194         // now move the shotorg forward as much as requested if possible
 195         if(antilag)
 196         {
 197                 if(ent.antilag_debug)
 198                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 199                 else
 200                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 201         }
 202         else
 203                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 204         w_shotorg = trace_endpos - v_forward * nudge;
 205         // calculate the shotdir from the chosen shotorg
 206         w_shotdir = normalize(w_shotend - w_shotorg);
 207
 208         if (antilag)
 209         if (!ent.cvar_cl_noantilag)
 210         {
 211                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 212                 {
 213                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 214                         if (!trace_ent.takedamage)
 215                         {
 216                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 217                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 218                                 {
 219                                         entity e;
 220                                         e = trace_ent;
 221                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 222                                         if(trace_ent == e)
 223                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 224                                 }
 225                         }
 226                 }
 227                 else if(autocvar_g_antilag == 3) // client side hitscan
 228                 {
 229                         // this part MUST use prydon cursor
 230                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 231                         if (ent.cursor_trace_ent != ent)         // just to make sure
 232                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 233                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 234                         {
 235                                 // verify that the shot would miss without antilag
 236                                 // (avoids an issue where guns would always shoot at their origin)
 237                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 238                                 if (!trace_ent.takedamage)
 239                                 {
 240                                         // verify that the shot would hit if altered
 241                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 242                                         if (trace_ent == ent.cursor_trace_ent)
 243                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 244                                         else
 245                                                 print("antilag fail\n");
 246                                 }
 247                         }
 248                 }
 249         }
 250
 251         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 252
 253         if (!g_norecoil)
 254                 ent.punchangle_x = recoil * -1;
 255
 256         if (snd != "")
 257         {
 258                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 259                 W_PlayStrengthSound(ent);
 260         }
 261
 262         // nudge w_shotend so a trace to w_shotend hits
 263         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 264 };
 265
 266 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 267 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 270 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 271
 272 float CL_Weaponentity_CustomizeEntityForClient()
 273 {
 274         self.viewmodelforclient = self.owner;
 275         if(other.classname == "spectator")
 276                 if(other.enemy == self.owner)
 277                         self.viewmodelforclient = other;
 278         return TRUE;
 279 }
 280
 281 float qcweaponanimation;
 282 vector weapon_offset = '0 -10 0';
 283 vector weapon_adjust = '10 0 -15';
 284 .vector weapon_morph0origin;
 285 .vector weapon_morph0angles;
 286 .float  weapon_morph0time;
 287 .vector weapon_morph1origin;
 288 .vector weapon_morph1angles;
 289 .float  weapon_morph1time;
 290 .vector weapon_morph2origin;
 291 .vector weapon_morph2angles;
 292 .float  weapon_morph2time;
 293 .vector weapon_morph3origin;
 294 .vector weapon_morph3angles;
 295 .float  weapon_morph3time;
 296 .vector weapon_morph4origin;
 297 .vector weapon_morph4angles;
 298 .float  weapon_morph4time;
 299 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 300
 301 /*
 302  * supported formats:
 303  *
 304  * 1. simple animated model, muzzle flash handling on h_ model:
 305  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 306  *      tags:
 307  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 308  *        shell = casings ejection point (must be on the right hand side of the gun)
 309  *        weapon = attachment for v_tuba.md3
 310  *    v_tuba.md3 - first and third person model
 311  *    g_tuba.md3 - pickup model
 312  *
 313  * 2. simple animated model, muzzle flash handling on v_ model:
 314  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 315  *      tags:
 316  *        weapon = attachment for v_tuba.md3
 317  *    v_tuba.md3 - first and third person model
 318  *      tags:
 319  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 320  *        shell = casings ejection point (must be on the right hand side of the gun)
 321  *    g_tuba.md3 - pickup model
 322  *
 323  * 3. fully animated model, muzzle flash handling on h_ model:
 324  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 325  *      tags:
 326  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 327  *        shell = casings ejection point (must be on the right hand side of the gun)
 328  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 329  *    v_tuba.md3 - third person model
 330  *    g_tuba.md3 - pickup model
 331  *
 332  * 4. fully animated model, muzzle flash handling on v_ model:
 333  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 334  *      tags:
 335  *        shot = muzzle end (shot origin)
 336  *        shell = casings ejection point (must be on the right hand side of the gun)
 337  *    v_tuba.md3 - third person model
 338  *      tags:
 339  *        shot = muzzle end (for muzzle flashes)
 340  *    g_tuba.md3 - pickup model
 341  */
 342
 343 // writes:
 344 //   self.origin, self.angles
 345 //   self.weaponentity
 346 //   self.movedir, self.view_ofs
 347 //   attachment stuff
 348 //   anim stuff
 349 // to free:
 350 //   call again with ""
 351 //   remove the ent
 352 void CL_WeaponEntity_SetModel(string name)
 353 {
 354         string animfilename;
 355         float animfile;
 356         float v_shot_idx;
 357         if (name != "")
 358         {
 359                 // if there is a child entity, hide it until we're sure we use it
 360                 if (self.weaponentity)
 361                         self.weaponentity.model = "";
 362                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 363                 v_shot_idx = gettagindex(self, "shot"); // used later
 364                 if(!v_shot_idx)
 365                         v_shot_idx = gettagindex(self, "tag_shot");
 366
 367                 if(qcweaponanimation)
 368                 {
 369                         self.angles = '0 0 0';
 370                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 371                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 372                         self.movedir_x += 32;
 373                         self.spawnorigin = self.movedir;
 374                         // oldorigin - not calculated here
 375                 }
 376                 else
 377                 {
 378                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 379                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 380                         animfile = fopen(animfilename, FILE_READ);
 381                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 382                         self.anim_fire1  = '0 1 0.01';
 383                         self.anim_fire2  = '1 1 0.01';
 384                         self.anim_idle   = '2 1 0.01';
 385                         self.anim_reload = '3 1 0.01';
 386                         if (animfile >= 0)
 387                         {
 388                                 animparseerror = FALSE;
 389                                 self.anim_fire1  = animparseline(animfile);
 390                                 self.anim_fire2  = animparseline(animfile);
 391                                 self.anim_idle   = animparseline(animfile);
 392                                 self.anim_reload = animparseline(animfile);
 393                                 fclose(animfile);
 394                                 if (animparseerror)
 395                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 396                         }
 397
 398                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 399                         // if we don't, this is a "real" animated model
 400                         if(gettagindex(self, "weapon"))
 401                         {
 402                                 if (!self.weaponentity)
 403                                         self.weaponentity = spawn();
 404                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 405                                 setattachment(self.weaponentity, self, "weapon");
 406                         }
 407                         else if(gettagindex(self, "tag_weapon"))
 408                         {
 409                                 if (!self.weaponentity)
 410                                         self.weaponentity = spawn();
 411                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 412                                 setattachment(self.weaponentity, self, "tag_weapon");
 413                         }
 414                         else
 415                         {
 416                                 if(self.weaponentity)
 417                                         remove(self.weaponentity);
 418                                 self.weaponentity = world;
 419                         }
 420
 421                         setorigin(self,'0 0 0');
 422                         self.angles = '0 0 0';
 423                         self.frame = 0;
 424                         self.viewmodelforclient = world;
 425
 426                         float idx;
 427
 428                         if(v_shot_idx) // v_ model attached to invisible h_ model
 429                         {
 430                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 431                         }
 432                         else
 433                         {
 434                                 idx = gettagindex(self, "shot");
 435                                 if(!idx)
 436                                         idx = gettagindex(self, "tag_shot");
 437                                 if(idx)
 438                                         self.movedir = gettaginfo(self, idx);
 439                                 else
 440                                 {
 441                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 442                                         self.movedir = '0 0 0';
 443                                 }
 444                         }
 445
 446                         if(self.weaponentity) // v_ model attached to invisible h_ model
 447                         {
 448                                 idx = gettagindex(self.weaponentity, "shell");
 449                                 if(!idx)
 450                                         idx = gettagindex(self.weaponentity, "tag_shell");
 451                                 if(idx)
 452                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 453                         }
 454                         else
 455                                 idx = 0;
 456                         if(!idx)
 457                         {
 458                                 idx = gettagindex(self, "shell");
 459                                 if(!idx)
 460                                         idx = gettagindex(self, "tag_shell");
 461                                 if(idx)
 462                                         self.spawnorigin = gettaginfo(self, idx);
 463                                 else
 464                                 {
 465                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 466                                         self.spawnorigin = self.movedir;
 467                                 }
 468                         }
 469
 470                         if(v_shot_idx)
 471                         {
 472                                 self.oldorigin = '0 0 0'; // use regular attachment
 473                         }
 474                         else
 475                         {
 476                                 if(self.weaponentity)
 477                                 {
 478                                         idx = gettagindex(self, "weapon");
 479                                         if(!idx)
 480                                                 idx = gettagindex(self, "tag_weapon");
 481                                 }
 482                                 else
 483                                 {
 484                                         idx = gettagindex(self, "handle");
 485                                         if(!idx)
 486                                                 idx = gettagindex(self, "tag_handle");
 487                                 }
 488                                 if(idx)
 489                                 {
 490                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 491                                 }
 492                                 else
 493                                 {
 494                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 495                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 496                                 }
 497                         }
 498
 499                         self.viewmodelforclient = self.owner;
 500                 }
 501         }
 502         else
 503         {
 504                 self.model = "";
 505                 if(self.weaponentity)
 506                         remove(self.weaponentity);
 507                 self.weaponentity = world;
 508                 self.movedir = '0 0 0';
 509                 self.spawnorigin = '0 0 0';
 510                 self.oldorigin = '0 0 0';
 511                 self.anim_fire1  = '0 1 0.01';
 512                 self.anim_fire2  = '0 1 0.01';
 513                 self.anim_idle   = '0 1 0.01';
 514                 self.anim_reload = '0 1 0.01';
 515         }
 516
 517         self.view_ofs = '0 0 0';
 518
 519         if(self.movedir_x >= 0)
 520         {
 521                 vector v0;
 522                 v0 = self.movedir;
 523                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 524                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 525         }
 526         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 527         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 528
 529         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 530
 531         // check if an instant weapon switch occurred
 532         if (qcweaponanimation)
 533         {
 534                 if (self.state == WS_READY)
 535                 {
 536                         self.angles = '0 0 0';
 537                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 538                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 539                 }
 540         }
 541         else
 542                 setorigin(self, self.view_ofs);
 543         // reset animstate now
 544         self.wframe = WFRAME_IDLE;
 545         self.weapon_morph0time = 0;
 546         self.weapon_morph1time = 0;
 547         self.weapon_morph2time = 0;
 548         self.weapon_morph3time = 0;
 549         self.weapon_morph4time = 0;
 550         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 551 }
 552
 553 vector CL_Weapon_GetShotOrg(float wpn)
 554 {
 555         entity wi, oldself;
 556         vector ret;
 557         wi = get_weaponinfo(wpn);
 558         oldself = self;
 559         self = spawn();
 560         CL_WeaponEntity_SetModel(wi.mdl);
 561         ret = self.movedir;
 562         CL_WeaponEntity_SetModel("");
 563         remove(self);
 564         self = oldself;
 565         return ret;
 566 }
 567
 568 void CL_Weaponentity_Think()
 569 {
 570         float tb;
 571         self.nextthink = time;
 572         if (intermission_running)
 573                 self.frame = self.anim_idle_x;
 574         if (self.owner.weaponentity != self)
 575         {
 576                 if (self.weaponentity)
 577                         remove(self.weaponentity);
 578                 remove(self);
 579                 return;
 580         }
 581         if (self.owner.deadflag != DEAD_NO)
 582         {
 583                 self.model = "";
 584                 if (self.weaponentity)
 585                         self.weaponentity.model = "";
 586                 return;
 587         }
 588         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 589         {
 590                 self.weaponname = self.owner.weaponname;
 591                 self.dmg = self.owner.modelindex;
 592                 self.deadflag = self.owner.deadflag;
 593
 594                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 595         }
 596
 597         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 598         self.effects = self.owner.effects & EFMASK_CHEAP;
 599         self.effects &~= EF_LOWPRECISION;
 600         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 601         self.effects &~= EF_TELEPORT_BIT;
 602         self.effects &~= EF_RESTARTANIM_BIT;
 603         self.effects |= tb;
 604
 605         if(self.owner.alpha == default_player_alpha)
 606                 self.alpha = default_weapon_alpha;
 607         else if(self.owner.alpha != 0)
 608                 self.alpha = self.owner.alpha;
 609         else
 610                 self.alpha = 1;
 611
 612         self.glowmod = self.owner.weaponentity_glowmod;
 613         self.colormap = self.owner.colormap;
 614         if (self.weaponentity)
 615         {
 616                 self.weaponentity.effects = self.effects;
 617                 self.weaponentity.alpha = self.alpha;
 618                 self.weaponentity.colormap = self.colormap;
 619                 self.weaponentity.glowmod = self.glowmod;
 620         }
 621
 622         self.angles = '0 0 0';
 623         local float f;
 624         f = 0;
 625         if (self.state == WS_RAISE && !intermission_running)
 626         {
 627                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 628                 self.angles_x = -90 * f * f;
 629                 if (qcweaponanimation)
 630                 {
 631                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 632                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 633                 }
 634         }
 635         else if (self.state == WS_DROP && !intermission_running)
 636         {
 637                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 638                 self.angles_x = -90 * f * f;
 639                 if (qcweaponanimation)
 640                 {
 641                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 642                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 643                 }
 644         }
 645         else if (self.state == WS_CLEAR)
 646         {
 647                 f = 1;
 648                 self.angles_x = -90 * f * f;
 649                 if (qcweaponanimation)
 650                 {
 651                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 652                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 653                 }
 654         }
 655         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 656         {
 657                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 658                 f = 1 - pow(1 - f, 3);
 659                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 660                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 661         }
 662         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 663         {
 664                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 665                 f = 1 - pow(1 - f, 3);
 666                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 667                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 668         }
 669         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 670         {
 671                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 672                 f = 1 - pow(1 - f, 3);
 673                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 674                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 675         }
 676         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 677         {
 678                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 679                 f = 1 - pow(1 - f, 3);
 680                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 681                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 682         }
 683         else if (qcweaponanimation)
 684         {
 685                 // begin a new idle morph
 686                 self.owner.weapon_morph0time   = time;
 687                 self.owner.weapon_morph0angles = self.angles;
 688                 self.owner.weapon_morph0origin = self.origin;
 689
 690                 float r;
 691                 float t;
 692
 693                 r = random();
 694                 if (r < 0.1)
 695                 {
 696                         // turn gun to the left to look at it
 697                         t = 2;
 698                         self.owner.weapon_morph1time   = time + t * 0.2;
 699                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 700                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 701                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 702
 703                         self.owner.weapon_morph2time   = time + t * 0.6;
 704                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 705                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 706                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 707
 708                         self.owner.weapon_morph3time   = time + t;
 709                         self.owner.weapon_morph3angles = '0 0 0';
 710                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 711                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 712                 }
 713                 else if (r < 0.2)
 714                 {
 715                         // raise the gun a bit
 716                         t = 2;
 717                         self.owner.weapon_morph1time   = time + t * 0.2;
 718                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 719                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 720                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 721
 722                         self.owner.weapon_morph2time   = time + t * 0.5;
 723                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 724                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 725                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 726
 727                         self.owner.weapon_morph3time   = time + t;
 728                         self.owner.weapon_morph3angles = '0 0 0';
 729                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 730                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 731                 }
 732                 else if (r < 0.3)
 733                 {
 734                         // tweak it a bit
 735                         t = 5;
 736                         self.owner.weapon_morph1time   = time + t * 0.3;
 737                         self.owner.weapon_morph1angles = randomvec() * 6;
 738                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 739                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 740
 741                         self.owner.weapon_morph2time   = time + t * 0.7;
 742                         self.owner.weapon_morph2angles = randomvec() * 6;
 743                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 744                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 745
 746                         self.owner.weapon_morph3time   = time + t;
 747                         self.owner.weapon_morph3angles = '0 0 0';
 748                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 749                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 750                 }
 751                 else
 752                 {
 753                         // hold it mostly steady
 754                         t = random() * 6 + 4;
 755                         self.owner.weapon_morph1time   = time + t * 0.2;
 756                         self.owner.weapon_morph1angles = randomvec() * 1;
 757                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 758                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 759
 760                         self.owner.weapon_morph2time   = time + t * 0.5;
 761                         self.owner.weapon_morph2angles = randomvec() * 1;
 762                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 763                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 764
 765                         self.owner.weapon_morph3time   = time + t * 0.7;
 766                         self.owner.weapon_morph3angles = randomvec() * 1;
 767                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 768                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 769                 }
 770
 771                 self.owner.weapon_morph4time   = time + t;
 772                 self.owner.weapon_morph4angles = '0 0 0';
 773                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 774                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 775
 776         }
 777 };
 778
 779 void CL_ExteriorWeaponentity_Think()
 780 {
 781         float tag_found;
 782         vector ang;
 783         self.nextthink = time;
 784         if (self.owner.exteriorweaponentity != self)
 785         {
 786                 remove(self);
 787                 return;
 788         }
 789         if (self.owner.deadflag != DEAD_NO)
 790         {
 791                 self.model = "";
 792                 return;
 793         }
 794         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 795         {
 796                 self.weaponname = self.owner.weaponname;
 797                 self.dmg = self.owner.modelindex;
 798                 self.deadflag = self.owner.deadflag;
 799                 if (self.owner.weaponname != "")
 800                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 801                 else
 802                         self.model = "";
 803
 804                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 805                 {
 806                         self.tag_index = tag_found;
 807                         self.tag_entity = self.owner;
 808                 }
 809                 else
 810                         setattachment(self, self.owner, "bip01 r hand");
 811
 812                 // if that didn't find a tag, hide the exterior weapon model
 813                 if (!self.tag_index)
 814                         self.model = "";
 815         }
 816         self.effects = self.owner.effects;
 817         if(sv_pitch_min == sv_pitch_max)
 818                 self.effects |= EF_LOWPRECISION;
 819         else
 820                 self.effects &~= EF_LOWPRECISION;
 821         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 822         if(self.owner.alpha == default_player_alpha)
 823                 self.alpha = default_weapon_alpha;
 824         else if(self.owner.alpha != 0)
 825                 self.alpha = self.owner.alpha;
 826         else
 827                 self.alpha = 1;
 828
 829         if (!intermission_running)
 830         {
 831                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 832                 ang_y = 0;
 833                 ang_z = 0;
 834
 835                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 836                 {
 837                         ang_y = self.owner.v_angle_y;
 838                         makevectors(ang);
 839                         var vector v = v_forward;
 840                         var float t = self.tag_entity.frame1time;
 841                         var float f = self.tag_entity.frame;
 842                         self.tag_entity.frame1time = time;
 843                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 844                         gettaginfo(self.tag_entity, self.tag_index);
 845                         self.tag_entity.frame1time = t;
 846                         self.tag_entity.frame = f;
 847                         // untransform v according to this coordinate space
 848                         vector w;
 849                         w_x = v_forward * v;
 850                         w_y = -v_right * v;
 851                         w_z = v_up * v;
 852                         self.angles = vectoangles(w);
 853                 }
 854                 else
 855                 {
 856                         ang_x = -/* don't ask */ang_x;
 857                         self.angles = ang;
 858                 }
 859
 860                 if(autocvar_g_loituma)
 861                 {
 862                         vector moddir, modup;
 863                         vector modangles;
 864                         float t;
 865
 866                         t = time * autocvar_g_loituma;
 867
 868                         modangles_x = t * 360;
 869                         modangles_y = 90;
 870                         modangles_z = 0;
 871
 872                         self.angles =
 873                                 AnglesTransform_ToAngles(
 874                                         AnglesTransform_Multiply(
 875                                                 AnglesTransform_FromAngles(self.angles),
 876                                                 AnglesTransform_FromAngles(modangles)
 877                                         )
 878                                 );
 879                 }
 880         }
 881
 882         self.glowmod = self.owner.weaponentity_glowmod;
 883         self.colormap = self.owner.colormap;
 884 };
 885
 886 // spawning weaponentity for client
 887 void CL_SpawnWeaponentity()
 888 {
 889         self.weaponentity = spawn();
 890         self.weaponentity.classname = "weaponentity";
 891         self.weaponentity.solid = SOLID_NOT;
 892         self.weaponentity.owner = self;
 893         setmodel(self.weaponentity, ""); // precision set when changed
 894         setorigin(self.weaponentity, '0 0 0');
 895         self.weaponentity.angles = '0 0 0';
 896         self.weaponentity.viewmodelforclient = self;
 897         self.weaponentity.flags = 0;
 898         self.weaponentity.think = CL_Weaponentity_Think;
 899         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 900         self.weaponentity.nextthink = time;
 901
 902         self.exteriorweaponentity = spawn();
 903         self.exteriorweaponentity.classname = "exteriorweaponentity";
 904         self.exteriorweaponentity.solid = SOLID_NOT;
 905         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 906         self.exteriorweaponentity.owner = self;
 907         setorigin(self.exteriorweaponentity, '0 0 0');
 908         self.exteriorweaponentity.angles = '0 0 0';
 909         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 910         self.exteriorweaponentity.nextthink = time;
 911 };
 912
 913 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 914 {
 915         msg_entity = e;
 916         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 917         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 918         WriteByte(MSG_ONE, wpn);
 919         WriteString(MSG_ONE, wpnname);
 920         WriteByte(MSG_ONE, type);
 921 }
 922
 923 .float hasweapon_complain_spam;
 924
 925 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 926 {
 927         local float weaponbit, f;
 928         local entity oldself;
 929
 930         if(time < self.hasweapon_complain_spam)
 931                 complain = 0;
 932         if(complain)
 933                 self.hasweapon_complain_spam = time + 0.2;
 934
 935         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 936         {
 937                 if (complain)
 938                         sprint(self, "Invalid weapon\n");
 939                 return FALSE;
 940         }
 941         weaponbit = W_WeaponBit(wpn);
 942         if (cl.weapons & weaponbit)
 943         {
 944                 if (andammo)
 945                 {
 946                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 947                         {
 948                                 f = 1;
 949                         }
 950                         else
 951                         {
 952                                 oldself = self;
 953                                 self = cl;
 954                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 955                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 956
 957                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 958                                 local entity mine;
 959                                 if(wpn == WEP_MINE_LAYER)
 960                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 961                                         f = 1;
 962
 963                                 self = oldself;
 964                         }
 965                         if (!f)
 966                         {
 967                                 if (complain)
 968                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 969                                 {
 970                                         play2(cl, "weapons/unavailable.wav");
 971                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 972                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 973                                 }
 974                                 return FALSE;
 975                         }
 976                 }
 977                 return TRUE;
 978         }
 979         if (complain)
 980         {
 981                 // DRESK - 3/16/07
 982                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 983                 if(weaponsInMap & weaponbit)
 984                 {
 985                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 986                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 987
 988                         if(autocvar_g_showweaponspawns)
 989                         {
 990                                 entity e;
 991                                 string s;
 992
 993                                 e = get_weaponinfo(wpn);
 994                                 s = e.model2;
 995
 996                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 997                                 {
 998                                         if(e.classname == "droppedweapon")
 999                                                 continue;
1000                                         if not(e.flags & FL_ITEM)
1001                                                 continue;
1002                                         WaypointSprite_Spawn(
1003                                                 s,
1004                                                 1, 0,
1005                                                 world, e.origin,
1006                                                 self, 0,
1007                                                 world, enemy,
1008                                                 0,
1009                                                 RADARICON_NONE, '0 0 0'
1010                                         );
1011                                 }
1012                         }
1013                 }
1014                 else
1015                 {
1016                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1017                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1018                 }
1019
1020                 play2(cl, "weapons/unavailable.wav");
1021         }
1022         return FALSE;
1023 };
1024
1025 // Weapon subs
1026 void w_clear()
1027 {
1028         if (self.weapon != -1)
1029         {
1030                 self.weapon = 0;
1031                 self.switchingweapon = 0;
1032         }
1033         if (self.weaponentity)
1034         {
1035                 self.weaponentity.state = WS_CLEAR;
1036                 self.weaponentity.effects = 0;
1037         }
1038 };
1039
1040 void w_ready()
1041 {
1042         if (self.weaponentity)
1043                 self.weaponentity.state = WS_READY;
1044         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1045 };
1046
1047 // Setup weapon for client (after this raise frame will be launched)
1048 void weapon_setup(float windex)
1049 {
1050         entity e;
1051         qcweaponanimation = autocvar_sv_qcweaponanimation;
1052         e = get_weaponinfo(windex);
1053         self.items &~= IT_AMMO;
1054         self.items = self.items | e.items;
1055
1056         // the two weapon entities will notice this has changed and update their models
1057         self.weapon = windex;
1058         self.switchingweapon = windex; // to make sure
1059         self.weaponname = e.mdl;
1060         self.bulletcounter = 0;
1061 };
1062
1063 // perform weapon to attack (weaponstate and attack_finished check is here)
1064 void W_SwitchToOtherWeapon(entity pl)
1065 {
1066         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1067         float w, ww;
1068         w = W_WeaponBit(pl.weapon);
1069         pl.weapons &~= w;
1070         ww = w_getbestweapon(pl);
1071         pl.weapons |= w;
1072         if(ww)
1073                 W_SwitchWeapon_Force(pl, ww);
1074 }
1075 .float prevdryfire;
1076 float weapon_prepareattack_checkammo(float secondary)
1077 {
1078         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1079         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1080         {
1081                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1082                 local entity mine;
1083                 if(self.weapon == WEP_MINE_LAYER)
1084                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1085                         return FALSE;
1086
1087                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1088                 {
1089                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1090                         self.prevdryfire = time;
1091                 }
1092
1093                 W_SwitchToOtherWeapon(self);
1094                 return FALSE;
1095         }
1096         return TRUE;
1097 }
1098 .float race_penalty;
1099 float weapon_prepareattack_check(float secondary, float attacktime)
1100 {
1101         if(!weapon_prepareattack_checkammo(secondary))
1102                 return FALSE;
1103
1104         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1105         //if all players readied up and the countdown is running
1106         if(time < game_starttime || time < self.race_penalty) {
1107                 return FALSE;
1108         }
1109
1110         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1111                 return FALSE;
1112
1113         // do not even think about shooting if switching
1114         if(self.switchweapon != self.weapon)
1115                 return FALSE;
1116
1117         if(attacktime >= 0)
1118         {
1119                 // don't fire if previous attack is not finished
1120                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1121                         return FALSE;
1122                 // don't fire while changing weapon
1123                 if (self.weaponentity.state != WS_READY)
1124                         return FALSE;
1125         }
1126
1127         return TRUE;
1128 }
1129 float weapon_prepareattack_do(float secondary, float attacktime)
1130 {
1131         self.weaponentity.state = WS_INUSE;
1132
1133         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1134
1135         // if the weapon hasn't been firing continuously, reset the timer
1136         if(attacktime >= 0)
1137         {
1138                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1139                 {
1140                         ATTACK_FINISHED(self) = time;
1141                         //dprint("resetting attack finished to ", ftos(time), "\n");
1142                 }
1143                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1144         }
1145         self.bulletcounter += 1;
1146         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1147         return TRUE;
1148 }
1149 float weapon_prepareattack(float secondary, float attacktime)
1150 {
1151         if(weapon_prepareattack_check(secondary, attacktime))
1152         {
1153                 weapon_prepareattack_do(secondary, attacktime);
1154                 return TRUE;
1155         }
1156         else
1157                 return FALSE;
1158 }
1159
1160 void weapon_thinkf(float fr, float t, void() func)
1161 {
1162         vector a;
1163         vector of, or, ou;
1164         float restartanim;
1165
1166         if(fr == WFRAME_DONTCHANGE)
1167         {
1168                 fr = self.weaponentity.wframe;
1169                 restartanim = FALSE;
1170         }
1171         else if (fr == WFRAME_IDLE)
1172                 restartanim = FALSE;
1173         else
1174                 restartanim = TRUE;
1175
1176         of = v_forward;
1177         or = v_right;
1178         ou = v_up;
1179
1180         if (self.weaponentity)
1181         {
1182                 self.weaponentity.wframe = fr;
1183                 if (qcweaponanimation)
1184                 {
1185                         if (fr != WFRAME_IDLE)
1186                         {
1187                                 self.weapon_morph0time = time;
1188                                 self.weapon_morph0angles = self.weaponentity.angles;
1189                                 self.weapon_morph0origin = self.weaponentity.origin;
1190
1191                                 self.weapon_morph1angles = '0 0 0';
1192                                 self.weapon_morph1time = time + t;
1193                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1194                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1195
1196                                 self.weapon_morph2angles = '0 0 0';
1197                                 self.weapon_morph2time = time + t;
1198                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1199                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1200
1201                                 self.weapon_morph3angles = '0 0 0';
1202                                 self.weapon_morph3time = time + t;
1203                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1204                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1205
1206                                 self.weapon_morph4angles = '0 0 0';
1207                                 self.weapon_morph4time = time + t;
1208                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1209                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1210
1211                                 if (fr == WFRAME_FIRE1)
1212                                 {
1213                                         self.weapon_morph1angles = '5 0 0';
1214                                         self.weapon_morph1time = time + t * 0.1;
1215                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1216                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1217                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1218                                 }
1219                                 else if (fr == WFRAME_FIRE2)
1220                                 {
1221                                         self.weapon_morph1angles = '10 0 0';
1222                                         self.weapon_morph1time = time + t * 0.1;
1223                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1224                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1225                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1226                                 }
1227                                 else if (fr == WFRAME_RELOAD)
1228                                 {
1229                                         self.weapon_morph1time = time + t * 0.05;
1230                                         self.weapon_morph1angles = '-10 40 0';
1231                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1232                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1233
1234                                         self.weapon_morph2time = time + t * 0.15;
1235                                         self.weapon_morph2angles = '-10 40 5';
1236                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1237                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1238
1239                                         self.weapon_morph3time = time + t * 0.25;
1240                                         self.weapon_morph3angles = '-10 40 0';
1241                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1242                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1243                                 }
1244                         }
1245                 }
1246                 else
1247                 {
1248                         if (fr == WFRAME_IDLE)
1249                                 a = self.weaponentity.anim_idle;
1250                         else if (fr == WFRAME_FIRE1)
1251                                 a = self.weaponentity.anim_fire1;
1252                         else if (fr == WFRAME_FIRE2)
1253                                 a = self.weaponentity.anim_fire2;
1254                         else if (fr == WFRAME_RELOAD)
1255                                 a = self.weaponentity.anim_reload;
1256                         a_z *= g_weaponratefactor;
1257                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1258                 }
1259         }
1260
1261         v_forward = of;
1262         v_right = or;
1263         v_up = ou;
1264
1265         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1266         {
1267                 backtrace("Tried to override initial weapon think function - should this really happen?");
1268         }
1269
1270         t *= W_WeaponRateFactor();
1271
1272         // VorteX: haste can be added here
1273         if (self.weapon_think == w_ready)
1274         {
1275                 self.weapon_nextthink = time;
1276                 //dprint("started firing at ", ftos(time), "\n");
1277         }
1278         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1279         {
1280                 self.weapon_nextthink = time;
1281                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1282         }
1283         self.weapon_nextthink = self.weapon_nextthink + t;
1284         self.weapon_think = func;
1285         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1286
1287         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1288         //anim = self.anim_shoot;
1289         if (restartanim)
1290         if (t)
1291         if (!self.crouch) // shoot anim stands up, this looks bad
1292         {
1293                 vector anim;
1294                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1295                 {
1296                         anim = self.anim_melee;
1297                         anim_z = anim_y / (t + sys_frametime);
1298                         setanim(self, anim, FALSE, TRUE, TRUE);
1299                 }
1300         }
1301 };
1302
1303 void weapon_boblayer1(float spd, vector org)
1304 {
1305         // VorteX: haste can be added here
1306 };
1307
1308 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1309 {
1310         vector mdirection;
1311         float mspeed;
1312         float outspeed;
1313         float nstyle;
1314         vector outvelocity;
1315
1316         mvelocity = mvelocity * g_weaponspeedfactor;
1317
1318         mdirection = normalize(mvelocity);
1319         mspeed = vlen(mvelocity);
1320
1321         nstyle = autocvar_g_projectiles_newton_style;
1322         if(nstyle == 0 || forceAbsolute)
1323         {
1324                 // absolute velocity
1325                 outvelocity = mvelocity;
1326         }
1327         else if(nstyle == 1)
1328         {
1329                 // true Newtonian projectiles
1330                 outvelocity = pvelocity + mvelocity;
1331         }
1332         else if(nstyle == 2)
1333         {
1334                 // true Newtonian projectiles with automatic aim adjustment
1335                 //
1336                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1337                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1338                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1339                 // PLUS SIGN!
1340                 // not defined?
1341                 // then...
1342                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1343                 // velocity without mdirection component > mspeed
1344                 // fire at smallest possible mspeed that works?
1345                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1346
1347                 vector solution;
1348                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1349                 if(solution_z)
1350                         outspeed = solution_y; // the larger one
1351                 else
1352                 {
1353                         //outspeed = 0; // slowest possible shot
1354                         outspeed = solution_x; // the real part (that is, the average!)
1355                         //dprint("impossible shot, adjusting\n");
1356                 }
1357
1358                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1359                 outvelocity = mdirection * outspeed;
1360         }
1361         else if(nstyle == 3)
1362         {
1363                 // pseudo-Newtonian:
1364                 outspeed = mspeed + mdirection * pvelocity;
1365                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1366                 outvelocity = mdirection * outspeed;
1367         }
1368         else if(nstyle == 4)
1369         {
1370                 // tZorkian:
1371                 outspeed = mspeed + vlen(pvelocity);
1372                 outvelocity = mdirection * outspeed;
1373         }
1374         else
1375                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1376
1377         return outvelocity;
1378 }
1379
1380 void W_AttachToShotorg(entity flash, vector offset)
1381 {
1382         entity xflash;
1383         flash.owner = self;
1384         flash.angles_z = random() * 360;
1385         if(qcweaponanimation)
1386         {
1387                 setorigin(flash, w_shotorg + w_shotdir * 50);
1388                 flash.angles = vectoangles(w_shotdir);
1389                 flash.angles_z = random() * 360;
1390         }
1391         else
1392         {
1393                 if(gettagindex(self.weaponentity, "shot"))
1394                         setattachment(flash, self.weaponentity, "shot");
1395                 else
1396                         setattachment(flash, self.weaponentity, "tag_shot");
1397                 setorigin(flash, offset);
1398
1399                 xflash = spawn();
1400                 copyentity(flash, xflash);
1401
1402                 flash.viewmodelforclient = self;
1403
1404                 if(self.weaponentity.oldorigin_x > 0)
1405                 {
1406                         setattachment(xflash, self.exteriorweaponentity, "");
1407                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1408                 }
1409                 else
1410                 {
1411                         if(gettagindex(self.exteriorweaponentity, "shot"))
1412                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1413                         else
1414                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1415                         setorigin(xflash, offset);
1416                 }
1417         }
1418 }
1419
1420 vector cliptoplane(vector v, vector p)
1421 {
1422         return v - (v * p) * p;
1423 }
1424
1425 vector solve_cubic_pq(float p, float q)
1426 {
1427         float D, u, v, a;
1428         D = q*q/4.0 + p*p*p/27.0;
1429         if(D < 0)
1430         {
1431                 // irreducibilis
1432                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1433                 u = sqrt(-4.0/3.0 * p);
1434                 // a in range 0..pi/3
1435                 // cos(a)
1436                 // cos(a + 2pi/3)
1437                 // cos(a + 4pi/3)
1438                 return
1439                         u *
1440                         (
1441                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1442                                 +
1443                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1444                                 +
1445                                 '0 0 1' * cos(a)
1446                         );
1447         }
1448         else if(D == 0)
1449         {
1450                 // simple
1451                 if(p == 0)
1452                         return '0 0 0';
1453                 u = 3*q/p;
1454                 v = -u/2;
1455                 if(u >= v)
1456                         return '1 1 0' * v + '0 0 1' * u;
1457                 else
1458                         return '0 1 1' * v + '1 0 0' * u;
1459         }
1460         else
1461         {
1462                 // cardano
1463                 u = cbrt(-q/2.0 + sqrt(D));
1464                 v = cbrt(-q/2.0 - sqrt(D));
1465                 return '1 1 1' * (u + v);
1466         }
1467 }
1468 vector solve_cubic_abcd(float a, float b, float c, float d)
1469 {
1470         // y = 3*a*x + b
1471         // x = (y - b) / 3a
1472         float p, q;
1473         vector v;
1474         p = (9*a*c - 3*b*b);
1475         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1476         v = solve_cubic_pq(p, q);
1477         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1478         if(a < 0)
1479                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1480         return v;
1481 }
1482
1483 vector findperpendicular(vector v)
1484 {
1485         vector p;
1486         p_x = v_z;
1487         p_y = -v_x;
1488         p_z = v_y;
1489         return normalize(cliptoplane(p, v));
1490 }
1491
1492 vector W_CalculateProjectileSpread(vector forward, float spread)
1493 {
1494         float sigma;
1495         vector v1, v2;
1496         float dx, dy, r;
1497         float sstyle;
1498         spread *= g_weaponspreadfactor;
1499         if(spread <= 0)
1500                 return forward;
1501         sstyle = autocvar_g_projectiles_spread_style;
1502
1503         if(sstyle == 0)
1504         {
1505                 // this is the baseline for the spread value!
1506                 // standard deviation: sqrt(2/5)
1507                 // density function: sqrt(1-r^2)
1508                 return forward + randomvec() * spread;
1509         }
1510         else if(sstyle == 1)
1511         {
1512                 // same thing, basically
1513                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1514         }
1515         else if(sstyle == 2)
1516         {
1517                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1518                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1519                 v1 = findperpendicular(forward);
1520                 v2 = cross(forward, v1);
1521                 // random point on unit circle
1522                 dx = random() * 2 * M_PI;
1523                 dy = sin(dx);
1524                 dx = cos(dx);
1525                 // radius in our dist function
1526                 r = random();
1527                 r = sqrt(r);
1528                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1529         }
1530         else if(sstyle == 3) // gauss 3d
1531         {
1532                 sigma = spread * 0.44721359549996; // match baseline stddev
1533                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1534                 v1 = forward;
1535                 v1_x += gsl_ran_gaussian(sigma);
1536                 v1_y += gsl_ran_gaussian(sigma);
1537                 v1_z += gsl_ran_gaussian(sigma);
1538                 return v1;
1539         }
1540         else if(sstyle == 4) // gauss 2d
1541         {
1542                 sigma = spread * 0.44721359549996; // match baseline stddev
1543                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1544                 v1_x = gsl_ran_gaussian(sigma);
1545                 v1_y = gsl_ran_gaussian(sigma);
1546                 v1_z = gsl_ran_gaussian(sigma);
1547                 return normalize(forward + cliptoplane(v1, forward));
1548         }
1549         else if(sstyle == 5) // 1-r
1550         {
1551                 sigma = spread * 1.154700538379252; // match baseline stddev
1552                 v1 = findperpendicular(forward);
1553                 v2 = cross(forward, v1);
1554                 // random point on unit circle
1555                 dx = random() * 2 * M_PI;
1556                 dy = sin(dx);
1557                 dx = cos(dx);
1558                 // radius in our dist function
1559                 r = random();
1560                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1561                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1562         }
1563         else if(sstyle == 6) // 1-r^2
1564         {
1565                 sigma = spread * 1.095445115010332; // match baseline stddev
1566                 v1 = findperpendicular(forward);
1567                 v2 = cross(forward, v1);
1568                 // random point on unit circle
1569                 dx = random() * 2 * M_PI;
1570                 dy = sin(dx);
1571                 dx = cos(dx);
1572                 // radius in our dist function
1573                 r = random();
1574                 r = sqrt(1 - r);
1575                 r = sqrt(1 - r);
1576                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1577         }
1578         else if(sstyle == 7) // (1-r) (2-r)
1579         {
1580                 sigma = spread * 1.224744871391589; // match baseline stddev
1581                 v1 = findperpendicular(forward);
1582                 v2 = cross(forward, v1);
1583                 // random point on unit circle
1584                 dx = random() * 2 * M_PI;
1585                 dy = sin(dx);
1586                 dx = cos(dx);
1587                 // radius in our dist function
1588                 r = random();
1589                 r = 1 - sqrt(r);
1590                 r = 1 - sqrt(r);
1591                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1592         }
1593         else
1594                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1595         return '0 0 0';
1596         /*
1597          * how to derive falloff functions:
1598          * rho(r) := (2-r) * (1-r);
1599          * a : 0;
1600          * b : 1;
1601          * rhor(r) := r * rho(r);
1602          * cr(t) := integrate(rhor(r), r, a, t);
1603          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1604          * variance : scr(b) / cr(b);
1605          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1606          * sqrt(0.4 / variance), numer;
1607          */
1608 }
1609
1610 #if 0
1611 float mspercallsum;
1612 float mspercallsstyle;
1613 float mspercallcount;
1614 #endif
1615 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1616 {
1617         if(missile.owner == world)
1618                 error("Unowned missile");
1619
1620         dir = dir + upDir * (pUpSpeed / pSpeed);
1621         dir_z += pZSpeed / pSpeed;
1622         pSpeed *= vlen(dir);
1623         dir = normalize(dir);
1624
1625 #if 0
1626         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1627         {
1628                 mspercallsum = mspercallcount = 0;
1629                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1630         }
1631         mspercallsum -= gettime(GETTIME_HIRES);
1632 #endif
1633         dir = W_CalculateProjectileSpread(dir, spread);
1634 #if 0
1635         mspercallsum += gettime(GETTIME_HIRES);
1636         mspercallcount += 1;
1637         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1638 #endif
1639
1640         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1641 }
1642
1643 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1644 {
1645         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1646 }
1647
1648 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1649 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1650
1651 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1652 {
1653         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1654                 return;
1655
1656         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1657         if(ammo_reload)
1658         {
1659                 self.clip_load -= ammo_use;
1660                 self.(weapon_load[self.weapon]) = self.clip_load;
1661         }
1662         else
1663                 self.(self.current_ammo) -= ammo_use;
1664 }
1665
1666 // weapon reloading code
1667
1668 .float reload_ammo_amount, reload_ammo_min, reload_time;
1669 .float reload_complain;
1670 .string reload_sound;
1671
1672 void W_ReloadedAndReady()
1673 {
1674         // finish the reloading process, and do the ammo transfer
1675
1676         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1677
1678         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1679         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1680                 self.clip_load = self.reload_ammo_amount;
1681         else
1682         {
1683                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1684                 {
1685                         self.clip_load += 1;
1686                         self.(self.current_ammo) -= 1;
1687                 }
1688         }
1689         self.(weapon_load[self.weapon]) = self.clip_load;
1690
1691         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1692         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1693         // so your weapon is disabled for a few seconds without reason
1694
1695         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1696
1697         w_ready();
1698 }
1699
1700 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1701 {
1702         // set global values to work with
1703
1704         self.reload_ammo_min = sent_ammo_min;
1705         self.reload_ammo_amount = sent_ammo_amount;
1706         self.reload_time = sent_time;
1707         self.reload_sound = sent_sound;
1708
1709         // check if we meet the necessary conditions to reload
1710
1711         entity e;
1712         e = get_weaponinfo(self.weapon);
1713
1714         // don't reload weapons that don't have the RELOADABLE flag
1715         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1716         {
1717                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1718                 return;
1719         }
1720
1721         // return if reloading is disabled for this weapon
1722         if(!self.reload_ammo_amount)
1723                 return;
1724
1725         // our weapon is fully loaded, no need to reload
1726         if (self.clip_load >= self.reload_ammo_amount)
1727                 return;
1728
1729         // no ammo, so nothing to load
1730         if(!self.(self.current_ammo) && self.reload_ammo_min)
1731         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1732         {
1733                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1734                 {
1735                         play2(self, "weapons/unavailable.wav");
1736                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1737                         self.reload_complain = time + 1;
1738                 }
1739                 // switch away if the amount of ammo is not enough to keep using this weapon
1740                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1741                 {
1742                         self.clip_load = -1; // reload later
1743                         W_SwitchToOtherWeapon(self);
1744                 }
1745                 return;
1746         }
1747
1748         if (self.weaponentity)
1749         {
1750                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1751                         return;
1752
1753                 // allow switching away while reloading, but this will cause a new reload!
1754                 self.weaponentity.state = WS_READY;
1755         }
1756
1757         // now begin the reloading process
1758
1759         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1760
1761         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1762         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1763         // so your weapon is disabled for a few seconds without reason
1764
1765         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1766
1767         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1768
1769         if(self.clip_load < 0)
1770                 self.clip_load = 0;
1771         self.old_clip_load = self.clip_load;
1772         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1773 }